fork_worker: use separate pipe for status messages
[pve-common.git] / src / PVE / RESTEnvironment.pm
1 package PVE::RESTEnvironment;
2
3 # NOTE: you can/should provide your own specialice class, and
4 # use this a bas class (as example see PVE::RPCEnvironment).
5
6 # we use this singleton class to pass RPC related environment values
7
8 use strict;
9 use warnings;
10 use POSIX qw(:sys_wait_h EINTR);
11 use IO::Handle;
12 use IO::File;
13 use IO::Select;
14 use Fcntl qw(:flock);
15 use PVE::Exception qw(raise raise_perm_exc);
16 use PVE::SafeSyslog;
17 use PVE::Tools;
18 use PVE::INotify;
19 use PVE::ProcFSTools;
20
21
22 my $rest_env;
23
24 # save $SIG{CHLD} handler implementation.
25 # simply set $SIG{CHLD} = $worker_reaper;
26 # and register forked processes with &$register_worker(pid)
27 # Note: using $SIG{CHLD} = 'IGNORE' or $SIG{CHLD} = sub { wait (); } or ...
28 # has serious side effects, because perls built in system() and open()
29 # functions can't get the correct exit status of a child. So we cant use
30 # that (also see perlipc)
31
32 my $WORKER_PIDS;
33 my $WORKER_FLAG = 0;
34
35 my $log_task_result = sub {
36     my ($upid, $user, $status) = @_;
37
38     return if !$rest_env;
39
40     my $msg = 'successful';
41     my $pri = 'info';
42     if ($status != 0) {
43         my $ec = $status >> 8;
44         my $ic = $status & 255;
45         $msg = $ec ? "failed ($ec)" : "interrupted ($ic)";
46         $pri = 'err';
47     }
48
49     my $tlist = $rest_env->active_workers($upid);
50     eval { $rest_env->broadcast_tasklist($tlist); };
51     syslog('err', $@) if $@;
52
53     my $task;
54     foreach my $t (@$tlist) {
55         if ($t->{upid} eq $upid) {
56             $task = $t;
57             last;
58         }
59     }
60     if ($task && $task->{status}) {
61         $msg = $task->{status};
62     }
63
64     $rest_env->log_cluster_msg($pri, $user, "end task $upid $msg");
65 };
66
67 my $worker_reaper = sub {
68     local $!; local $?;
69     foreach my $pid (keys %$WORKER_PIDS) {
70         my $waitpid = waitpid ($pid, WNOHANG);
71         if (defined($waitpid) && ($waitpid == $pid)) {
72             my $info = $WORKER_PIDS->{$pid};
73             if ($info && $info->{upid} && $info->{user}) {
74                 &$log_task_result($info->{upid}, $info->{user}, $?);
75             }
76             delete ($WORKER_PIDS->{$pid});
77         }
78     }
79 };
80
81 my $register_worker = sub {
82     my ($pid, $user, $upid) = @_;
83
84     return if !$pid;
85
86     # do not register if already finished
87     my $waitpid = waitpid ($pid, WNOHANG);
88     if (defined($waitpid) && ($waitpid == $pid)) {
89         delete ($WORKER_PIDS->{$pid});
90         return;
91     }
92
93     $WORKER_PIDS->{$pid} = {
94         user => $user,
95         upid => $upid,
96     };
97 };
98
99 # initialize environment - must be called once at program startup
100 sub init {
101     my ($class, $type, %params) = @_;
102
103     $class = ref($class) || $class;
104
105     die "already initialized" if $rest_env;
106
107     die "unknown environment type"
108         if !$type || $type !~ m/^(cli|pub|priv|ha)$/;
109
110     $SIG{CHLD} = $worker_reaper;
111
112     # environment types
113     # cli  ... command started fron command line
114     # pub  ... access from public server (apache)
115     # priv ... access from private server (pvedaemon)
116     # ha   ... access from HA resource manager agent (rgmanager)
117
118     my $self = { type => $type };
119
120     bless $self, $class;
121
122     foreach my $p (keys %params) {
123         if ($p eq 'atfork') {
124             $self->{$p} = $params{$p};
125         } else {
126             die "unknown option '$p'";
127         }
128     }
129
130     $rest_env = $self;
131
132     my ($sysname, $nodename) = POSIX::uname();
133
134     $nodename =~ s/\..*$//; # strip domain part, if any
135
136     $self->{nodename} = $nodename;
137
138     return $self;
139 };
140
141 # convenience function for command line tools
142 sub setup_default_cli_env {
143     my ($class, $username) = @_;
144
145     $class = ref($class) || $class;
146
147     $username //= 'root@pam';
148
149     PVE::INotify::inotify_init();
150
151     my $rpcenv = $class->init('cli');
152     $rpcenv->init_request();
153     $rpcenv->set_language($ENV{LANG});
154     $rpcenv->set_user($username);
155
156     die "please run as root\n"
157         if ($username eq 'root@pam') && ($> != 0);
158 }
159
160 # get the singleton
161 sub get {
162
163     die "REST environment not initialized" if !$rest_env;
164
165     return $rest_env;
166 }
167
168 sub set_client_ip {
169     my ($self, $ip) = @_;
170
171     $self->{client_ip} = $ip;
172 }
173
174 sub get_client_ip {
175     my ($self) = @_;
176
177     return $self->{client_ip};
178 }
179
180 sub set_result_attrib {
181     my ($self, $key, $value) = @_;
182
183     $self->{result_attributes}->{$key} = $value;
184 }
185
186 sub get_result_attrib {
187     my ($self, $key) = @_;
188
189     return $self->{result_attributes}->{$key};
190 }
191
192 sub set_language {
193     my ($self, $lang) = @_;
194
195     # fixme: initialize I18N
196
197     $self->{language} = $lang;
198 }
199
200 sub get_language {
201     my ($self) = @_;
202
203     return $self->{language};
204 }
205
206 sub set_user {
207     my ($self, $user) = @_;
208
209     $self->{user} = $user;
210 }
211
212 sub get_user {
213     my ($self, $noerr) = @_;
214
215     return $self->{user} if defined($self->{user}) || $noerr;
216
217     die "user name not set\n";
218 }
219
220 sub is_worker {
221     my ($class) = @_;
222
223     return $WORKER_FLAG;
224 }
225
226 # read/update list of active workers
227 # we move all finished tasks to the archive index,
228 # but keep aktive and most recent task in the active file.
229 # $nocheck ... consider $new_upid still running (avoid that
230 # we try to read the reult to early.
231 sub active_workers  {
232     my ($self, $new_upid, $nocheck) = @_;
233
234     my $lkfn = "/var/log/pve/tasks/.active.lock";
235
236     my $timeout = 10;
237
238     my $code = sub {
239
240         my $tasklist = PVE::INotify::read_file('active');
241
242         my @ta;
243         my $tlist = [];
244         my $thash = {}; # only list task once
245
246         my $check_task = sub {
247             my ($task, $running) = @_;
248
249             if ($running || PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart})) {
250                 push @$tlist, $task;
251             } else {
252                 delete $task->{pid};
253                 push @ta, $task;
254             }
255             delete $task->{pstart};
256         };
257
258         foreach my $task (@$tasklist) {
259             my $upid = $task->{upid};
260             next if $thash->{$upid};
261             $thash->{$upid} = $task;
262             &$check_task($task);
263         }
264
265         if ($new_upid && !(my $task = $thash->{$new_upid})) {
266             $task = PVE::Tools::upid_decode($new_upid);
267             $task->{upid} = $new_upid;
268             $thash->{$new_upid} = $task;
269             &$check_task($task, $nocheck);
270         }
271
272
273         @ta = sort { $b->{starttime} cmp $a->{starttime} } @ta;
274
275         my $save = defined($new_upid);
276
277         foreach my $task (@ta) {
278             next if $task->{endtime};
279             $task->{endtime} = time();
280             $task->{status} = PVE::Tools::upid_read_status($task->{upid});
281             $save = 1;
282         }
283
284         my $archive = '';
285         my @arlist = ();
286         foreach my $task (@ta) {
287             if (!$task->{saved}) {
288                 $archive .= sprintf("%s %08X %s\n", $task->{upid}, $task->{endtime}, $task->{status});
289                 $save = 1;
290                 push @arlist, $task;
291                 $task->{saved} = 1;
292             }
293         }
294
295         if ($archive) {
296             my $size = 0;
297             my $filename = "/var/log/pve/tasks/index";
298             eval {
299                 my $fh = IO::File->new($filename, '>>', 0644) ||
300                     die "unable to open file '$filename' - $!\n";
301                 PVE::Tools::safe_print($filename, $fh, $archive);
302                 $size = -s $fh;
303                 close($fh) ||
304                     die "unable to close file '$filename' - $!\n";
305             };
306             my $err = $@;
307             if ($err) {
308                 syslog('err', $err);
309                 foreach my $task (@arlist) { # mark as not saved
310                     $task->{saved} = 0;
311                 }
312             }
313             my $maxsize = 50000; # about 1000 entries
314             if ($size > $maxsize) {
315                 rename($filename, "$filename.1");
316             }
317         }
318
319         # we try to reduce the amount of data
320         # list all running tasks and task and a few others
321         # try to limit to 25 tasks
322         my $max = 25 - scalar(@$tlist);
323         foreach my $task (@ta) {
324             last if $max <= 0;
325             push @$tlist, $task;
326             $max--;
327         }
328
329         PVE::INotify::write_file('active', $tlist) if $save;
330
331         return $tlist;
332     };
333
334     my $res = PVE::Tools::lock_file($lkfn, $timeout, $code);
335     die $@ if $@;
336
337     return $res;
338 }
339
340 my $kill_process_group = sub {
341     my ($pid, $pstart) = @_;
342
343     # send kill to process group (negative pid)
344     my $kpid = -$pid;
345
346     # always send signal to all pgrp members
347     kill(15, $kpid); # send TERM signal
348
349     # give max 5 seconds to shut down
350     for (my $i = 0; $i < 5; $i++) {
351         return if !PVE::ProcFSTools::check_process_running($pid, $pstart);
352         sleep (1);
353     }
354
355     # to be sure
356     kill(9, $kpid);
357 };
358
359 sub check_worker {
360     my ($self, $upid, $killit) = @_;
361
362     my $task = PVE::Tools::upid_decode($upid);
363
364     my $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
365
366     return 0 if !$running;
367
368     if ($killit) {
369         &$kill_process_group($task->{pid});
370         return 0;
371     }
372
373     return 1;
374 }
375
376 # start long running workers
377 # STDIN is redirected to /dev/null
378 # STDOUT,STDERR are redirected to the filename returned by upid_decode
379 # NOTE: we simulate running in foreground if ($self->{type} eq 'cli')
380 sub fork_worker {
381     my ($self, $dtype, $id, $user, $function, $background) = @_;
382
383     $dtype = 'unknown' if !defined ($dtype);
384     $id = '' if !defined ($id);
385
386     $user = 'root@pve' if !defined ($user);
387
388     my $sync = ($self->{type} eq 'cli' && !$background) ? 1 : 0;
389
390     local $SIG{INT} =
391         local $SIG{QUIT} =
392         local $SIG{PIPE} =
393         local $SIG{TERM} = 'IGNORE';
394
395     my $starttime = time ();
396
397     my @psync = POSIX::pipe();
398     my @csync = POSIX::pipe();
399     my @ctrlfd = POSIX::pipe() if $sync;
400
401     my $node = $self->{nodename};
402
403     my $cpid = fork();
404     die "unable to fork worker - $!" if !defined($cpid);
405
406     my $workerpuid = $cpid ? $cpid : $$;
407
408     my $pstart = PVE::ProcFSTools::read_proc_starttime($workerpuid) ||
409         die "unable to read process start time";
410
411     my $upid = PVE::Tools::upid_encode ({
412         node => $node, pid => $workerpuid, pstart => $pstart,
413         starttime => $starttime, type => $dtype, id => $id, user => $user });
414
415     my $outfh;
416
417     if (!$cpid) { # child
418
419         $0 = "task $upid";
420         $WORKER_FLAG = 1;
421
422         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub { die "received interrupt\n"; };
423
424         $SIG{CHLD} = $SIG{PIPE} = 'DEFAULT';
425
426         # set sess/process group - we want to be able to kill the
427         # whole process group
428         POSIX::setsid();
429
430         POSIX::close ($psync[0]);
431         POSIX::close ($ctrlfd[0]) if $sync;
432         POSIX::close ($csync[1]);
433
434         $outfh = $sync ? $psync[1] : undef;
435         my $resfh = $sync ? $ctrlfd[1] : undef;
436
437         eval {
438             PVE::INotify::inotify_close();
439
440             if (my $atfork = $self->{atfork}) {
441                 &$atfork();
442             }
443
444             # same algorythm as used inside SA
445             # STDIN = /dev/null
446             my $fd = fileno (STDIN);
447
448             if (!$sync) {
449                 close STDIN;
450                 POSIX::close(0) if $fd != 0;
451
452                 die "unable to redirect STDIN - $!"
453                     if !open(STDIN, "</dev/null");
454
455                 $outfh = PVE::Tools::upid_open($upid);
456                 $resfh = $outfh;
457             }
458
459
460             # redirect STDOUT
461             $fd = fileno(STDOUT);
462             close STDOUT;
463             POSIX::close (1) if $fd != 1;
464
465             die "unable to redirect STDOUT - $!"
466                 if !open(STDOUT, ">&", $outfh);
467
468             STDOUT->autoflush (1);
469
470             #  redirect STDERR to STDOUT
471             $fd = fileno (STDERR);
472             close STDERR;
473             POSIX::close(2) if $fd != 2;
474
475             die "unable to redirect STDERR - $!"
476                 if !open(STDERR, ">&1");
477
478             STDERR->autoflush(1);
479         };
480         if (my $err = $@) {
481             my $msg =  "ERROR: $err";
482             POSIX::write($psync[1], $msg, length ($msg));
483             POSIX::close($psync[1]);
484             POSIX::_exit(1);
485             kill(-9, $$);
486         }
487
488         # sync with parent (signal that we are ready)
489         POSIX::write($psync[1], $upid, length ($upid));
490         POSIX::close($psync[1]) if !$sync; # don't need output pipe if async
491
492         my $readbuf = '';
493         # sync with parent (wait until parent is ready)
494         POSIX::read($csync[0], $readbuf, 4096);
495         die "parent setup error\n" if $readbuf ne 'OK';
496
497         if ($self->{type} eq 'ha') {
498             print "task started by HA resource agent\n";
499         }
500         eval { &$function($upid); };
501         my $err = $@;
502         if ($err) {
503             chomp $err;
504             $err =~ s/\n/ /mg;
505             syslog('err', $err);
506             my $msg = "TASK ERROR: $err\n";
507             POSIX::write($resfh, $msg, length($msg));
508             POSIX::close($resfh) if $sync;
509             POSIX::_exit(-1);
510         } else {
511             my $msg = "TASK OK\n";
512             POSIX::write($resfh, $msg, length($msg));
513             POSIX::close($resfh) if $sync;
514             POSIX::_exit(0);
515         }
516         kill(-9, $$);
517     }
518
519     # parent
520
521     POSIX::close ($psync[1]);
522     POSIX::close ($ctrlfd[1]) if $sync;
523     POSIX::close ($csync[0]);
524
525     my $readbuf = '';
526     # sync with child (wait until child starts)
527     POSIX::read($psync[0], $readbuf, 4096);
528
529     if (!$sync) {
530         POSIX::close($psync[0]);
531         &$register_worker($cpid, $user, $upid);
532     } else {
533         chomp $readbuf;
534     }
535
536     eval {
537         die "got no worker upid - start worker failed\n" if !$readbuf;
538
539         if ($readbuf =~ m/^ERROR:\s*(.+)$/m) {
540             die "starting worker failed: $1\n";
541         }
542
543         if ($readbuf ne $upid) {
544             die "got strange worker upid ('$readbuf' != '$upid') - start worker failed\n";
545         }
546
547         if ($sync) {
548             $outfh = PVE::Tools::upid_open($upid);
549         }
550     };
551     my $err = $@;
552
553     if (!$err) {
554         my $msg = 'OK';
555         POSIX::write($csync[1], $msg, length ($msg));
556         POSIX::close($csync[1]);
557
558     } else {
559         POSIX::close($csync[1]);
560         kill(-9, $cpid); # make sure it gets killed
561         die $err;
562     }
563
564     $self->log_cluster_msg('info', $user, "starting task $upid");
565
566     my $tlist = $self->active_workers($upid, $sync);
567     eval { $self->broadcast_tasklist($tlist); };
568     syslog('err', $@) if $@;
569
570     my $res = 0;
571
572     if ($sync) {
573         my $count;
574         my $int_count = 0;
575         eval {
576             local $SIG{INT} = local $SIG{QUIT} = local $SIG{TERM} = sub {
577                 # always send signal to all pgrp members
578                 my $kpid = -$cpid;
579                 if ($int_count < 3) {
580                     kill(15, $kpid); # send TERM signal
581                 } else {
582                     kill(9, $kpid); # send KILL signal
583                 }
584                 $int_count++;
585             };
586             local $SIG{PIPE} = sub { die "broken pipe\n"; };
587
588             my $select = new IO::Select;
589             my $fh = IO::Handle->new_from_fd($psync[0], 'r');
590             $select->add($fh);
591
592             while ($select->count) {
593                 my @handles = $select->can_read(1);
594                 if (scalar(@handles)) {
595                     my $count = sysread ($handles[0], $readbuf, 4096);
596                     if (!defined ($count)) {
597                         my $err = $!;
598                         die "sync pipe read error: $err\n";
599                     }
600                     last if $count == 0; # eof
601
602                     print $readbuf;
603                     select->flush();
604
605                     print $outfh $readbuf;
606                     $outfh->flush();
607                 } else {
608                     # some commands daemonize without closing stdout
609                     last if !PVE::ProcFSTools::check_process_running($cpid);
610                 }
611             }
612
613             # get status (error or OK)
614             POSIX::read($ctrlfd[0], $readbuf, 4096);
615             if ($readbuf =~ m/^TASK OK\n?$/) {
616                 print $outfh $readbuf;
617             } elsif ($readbuf =~ m/^TASK ERROR: (.*)\n?$/) {
618                 print STDERR "$1\n";
619                 print $outfh "\n$readbuf";
620             } else {
621                 die "got unexpected control message: $readbuf\n";
622             }
623             $outfh->flush();
624         };
625         my $err = $@;
626
627         POSIX::close($psync[0]);
628         POSIX::close($ctrlfd[0]);
629
630         if ($err) {
631             $err =~ s/\n/ /mg;
632             print STDERR "$err\n";
633             if ($outfh) {
634                 print $outfh "TASK ERROR: $err\n";
635             }
636         }
637
638         &$kill_process_group($cpid, $pstart); # make sure it gets killed
639
640         close($outfh);
641
642         waitpid($cpid, 0);
643         $res = $?;
644         &$log_task_result($upid, $user, $res);
645     }
646
647     return wantarray ? ($upid, $res) : $upid;
648 }
649
650 # Abstract function
651
652 sub log_cluster_msg {
653     my ($self, $pri, $user, $msg) = @_;
654
655     syslog($pri, "%s", $msg);
656
657     # PVE::Cluster::log_msg($pri, $user, $msg);
658 }
659
660 sub broadcast_tasklist {
661     my ($self, $tlist) = @_;
662
663     # PVE::Cluster::broadcast_tasklist($tlist);
664 }
665
666 sub check_api2_permissions {
667     my ($self, $perm, $username, $param) = @_;
668
669     return 1 if !$username && $perm->{user} eq 'world';
670
671     raise_perm_exc("user != null") if !$username;
672
673     return 1 if $username eq 'root@pam';
674
675     raise_perm_exc('user != root@pam') if !$perm;
676
677     return 1 if $perm->{user} && $perm->{user} eq 'all';
678
679     ##return $self->exec_api2_perm_check($perm->{check}, $username, $param)
680     ##if $perm->{check};
681
682     raise_perm_exc();
683 }
684
685 # init_request - should be called before each REST/CLI request
686 sub init_request {
687     my ($self, %params) = @_;
688
689     $self->{result_attributes} = {}
690
691     # if you nedd more, implement in subclass
692 }
693
694 1;