src/PVE/RESTEnvironment.pm

   1 package PVE::RESTEnvironment;
   2
   3 # NOTE: you can/should provide your own specialice class, and
   4 # use this a bas class (as example see PVE::RPCEnvironment).
   5
   6 # we use this singleton class to pass RPC related environment values
   7
   8 use strict;
   9 use warnings;
  10 use POSIX qw(:sys_wait_h EINTR);
  11 use IO::Handle;
  12 use IO::File;
  13 use IO::Select;
  14 use Fcntl qw(:flock);
  15 use PVE::Exception qw(raise raise_perm_exc);
  16 use PVE::SafeSyslog;
  17 use PVE::Tools;
  18 use PVE::INotify;
  19 use PVE::ProcFSTools;
  20
  21
  22 my $rest_env;
  23
  24 # save $SIG{CHLD} handler implementation.
  25 # simply set $SIG{CHLD} = $worker_reaper;
  26 # and register forked processes with &$register_worker(pid)
  27 # Note: using $SIG{CHLD} = 'IGNORE' or $SIG{CHLD} = sub { wait (); } or ...
  28 # has serious side effects, because perls built in system() and open()
  29 # functions can't get the correct exit status of a child. So we cant use
  30 # that (also see perlipc)
  31
  32 my $WORKER_PIDS;
  33 my $WORKER_FLAG = 0;
  34
  35 my $log_task_result = sub {
  36     my ($upid, $user, $status) = @_;
  37
  38     return if !$rest_env;
  39
  40     my $msg = 'successful';
  41     my $pri = 'info';
  42     if ($status != 0) {
  43         my $ec = $status >> 8;
  44         my $ic = $status & 255;
  45         $msg = $ec ? "failed ($ec)" : "interrupted ($ic)";
  46         $pri = 'err';
  47     }
  48
  49     my $tlist = $rest_env->active_workers($upid);
  50     eval { $rest_env->broadcast_tasklist($tlist); };
  51     syslog('err', $@) if $@;
  52
  53     my $task;
  54     foreach my $t (@$tlist) {
  55         if ($t->{upid} eq $upid) {
  56             $task = $t;
  57             last;
  58         }
  59     }
  60     if ($task && $task->{status}) {
  61         $msg = $task->{status};
  62     }
  63
  64     $rest_env->log_cluster_msg($pri, $user, "end task $upid $msg");
  65 };
  66
  67 my $worker_reaper = sub {
  68     local $!; local $?;
  69     foreach my $pid (keys %$WORKER_PIDS) {
  70         my $waitpid = waitpid ($pid, WNOHANG);
  71         if (defined($waitpid) && ($waitpid == $pid)) {
  72             my $info = $WORKER_PIDS->{$pid};
  73             if ($info && $info->{upid} && $info->{user}) {
  74                 &$log_task_result($info->{upid}, $info->{user}, $?);
  75             }
  76             delete ($WORKER_PIDS->{$pid});
  77         }
  78     }
  79 };
  80
  81 my $register_worker = sub {
  82     my ($pid, $user, $upid) = @_;
  83
  84     return if !$pid;
  85
  86     # do not register if already finished
  87     my $waitpid = waitpid ($pid, WNOHANG);
  88     if (defined($waitpid) && ($waitpid == $pid)) {
  89         delete ($WORKER_PIDS->{$pid});
  90         return;
  91     }
  92
  93     $WORKER_PIDS->{$pid} = {
  94         user => $user,
  95         upid => $upid,
  96     };
  97 };
  98
  99 # initialize environment - must be called once at program startup
 100 sub init {
 101     my ($class, $type, %params) = @_;
 102
 103     $class = ref($class) || $class;
 104
 105     die "already initialized" if $rest_env;
 106
 107     die "unknown environment type"
 108         if !$type || $type !~ m/^(cli|pub|priv|ha)$/;
 109
 110     $SIG{CHLD} = $worker_reaper;
 111
 112     # environment types
 113     # cli  ... command started fron command line
 114     # pub  ... access from public server (apache)
 115     # priv ... access from private server (pvedaemon)
 116     # ha   ... access from HA resource manager agent (rgmanager)
 117
 118     my $self = { type => $type };
 119
 120     bless $self, $class;
 121
 122     foreach my $p (keys %params) {
 123         if ($p eq 'atfork') {
 124             $self->{$p} = $params{$p};
 125         } else {
 126             die "unknown option '$p'";
 127         }
 128     }
 129
 130     $rest_env = $self;
 131
 132     my ($sysname, $nodename) = POSIX::uname();
 133
 134     $nodename =~ s/\..*$//; # strip domain part, if any
 135
 136     $self->{nodename} = $nodename;
 137
 138     return $self;
 139 };
 140
 141 # convenience function for command line tools
 142 sub setup_default_cli_env {
 143     my ($class, $username) = @_;
 144
 145     $class = ref($class) || $class;
 146
 147     $username //= 'root@pam';
 148
 149     PVE::INotify::inotify_init();
 150
 151     my $rpcenv = $class->init('cli');
 152     $rpcenv->init_request();
 153     $rpcenv->set_language($ENV{LANG});
 154     $rpcenv->set_user($username);
 155
 156     die "please run as root\n"
 157         if ($username eq 'root@pam') && ($> != 0);
 158 }
 159
 160 # get the singleton
 161 sub get {
 162
 163     die "REST environment not initialized" if !$rest_env;
 164
 165     return $rest_env;
 166 }
 167
 168 sub set_client_ip {
 169     my ($self, $ip) = @_;
 170
 171     $self->{client_ip} = $ip;
 172 }
 173
 174 sub get_client_ip {
 175     my ($self) = @_;
 176
 177     return $self->{client_ip};
 178 }
 179
 180 sub set_result_attrib {
 181     my ($self, $key, $value) = @_;
 182
 183     $self->{result_attributes}->{$key} = $value;
 184 }
 185
 186 sub get_result_attrib {
 187     my ($self, $key) = @_;
 188
 189     return $self->{result_attributes}->{$key};
 190 }
 191
 192 sub set_language {
 193     my ($self, $lang) = @_;
 194
 195     # fixme: initialize I18N
 196
 197     $self->{language} = $lang;
 198 }
 199
 200 sub get_language {
 201     my ($self) = @_;
 202
 203     return $self->{language};
 204 }
 205
 206 sub set_user {
 207     my ($self, $user) = @_;
 208
 209     $self->{user} = $user;
 210 }
 211
 212 sub get_user {
 213     my ($self, $noerr) = @_;
 214
 215     return $self->{user} if defined($self->{user}) || $noerr;
 216
 217     die "user name not set\n";
 218 }
 219
 220 sub is_worker {
 221     my ($class) = @_;
 222
 223     return $WORKER_FLAG;
 224 }
 225
 226 # read/update list of active workers
 227 # we move all finished tasks to the archive index,
 228 # but keep aktive and most recent task in the active file.
 229 # $nocheck ... consider $new_upid still running (avoid that
 230 # we try to read the reult to early.
 231 sub active_workers  {
 232     my ($self, $new_upid, $nocheck) = @_;
 233
 234     my $lkfn = "/var/log/pve/tasks/.active.lock";
 235
 236     my $timeout = 10;
 237
 238     my $code = sub {
 239
 240         my $tasklist = PVE::INotify::read_file('active');
 241
 242         my @ta;
 243         my $tlist = [];
 244         my $thash = {}; # only list task once
 245
 246         my $check_task = sub {
 247             my ($task, $running) = @_;
 248
 249             if ($running || PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart})) {
 250                 push @$tlist, $task;
 251             } else {
 252                 delete $task->{pid};
 253                 push @ta, $task;
 254             }
 255             delete $task->{pstart};
 256         };
 257
 258         foreach my $task (@$tasklist) {
 259             my $upid = $task->{upid};
 260             next if $thash->{$upid};
 261             $thash->{$upid} = $task;
 262             &$check_task($task);
 263         }
 264
 265         if ($new_upid && !(my $task = $thash->{$new_upid})) {
 266             $task = PVE::Tools::upid_decode($new_upid);
 267             $task->{upid} = $new_upid;
 268             $thash->{$new_upid} = $task;
 269             &$check_task($task, $nocheck);
 270         }
 271
 272
 273         @ta = sort { $b->{starttime} cmp $a->{starttime} } @ta;
 274
 275         my $save = defined($new_upid);
 276
 277         foreach my $task (@ta) {
 278             next if $task->{endtime};
 279             $task->{endtime} = time();
 280             $task->{status} = PVE::Tools::upid_read_status($task->{upid});
 281             $save = 1;
 282         }
 283
 284         my $archive = '';
 285         my @arlist = ();
 286         foreach my $task (@ta) {
 287             if (!$task->{saved}) {
 288                 $archive .= sprintf("%s %08X %s\n", $task->{upid}, $task->{endtime}, $task->{status});
 289                 $save = 1;
 290                 push @arlist, $task;
 291                 $task->{saved} = 1;
 292             }
 293         }
 294
 295         if ($archive) {
 296             my $size = 0;
 297             my $filename = "/var/log/pve/tasks/index";
 298             eval {
 299                 my $fh = IO::File->new($filename, '>>', 0644) ||
 300                     die "unable to open file '$filename' - $!\n";
 301                 PVE::Tools::safe_print($filename, $fh, $archive);
 302                 $size = -s $fh;
 303                 close($fh) ||
 304                     die "unable to close file '$filename' - $!\n";
 305             };
 306             my $err = $@;
 307             if ($err) {
 308                 syslog('err', $err);
 309                 foreach my $task (@arlist) { # mark as not saved
 310                     $task->{saved} = 0;
 311                 }
 312             }
 313             my $maxsize = 50000; # about 1000 entries
 314             if ($size > $maxsize) {
 315                 rename($filename, "$filename.1");
 316             }
 317         }
 318
 319         # we try to reduce the amount of data
 320         # list all running tasks and task and a few others
 321         # try to limit to 25 tasks
 322         my $max = 25 - scalar(@$tlist);
 323         foreach my $task (@ta) {
 324             last if $max <= 0;
 325             push @$tlist, $task;
 326             $max--;
 327         }
 328
 329         PVE::INotify::write_file('active', $tlist) if $save;
 330
 331         return $tlist;
 332     };
 333
 334     my $res = PVE::Tools::lock_file($lkfn, $timeout, $code);
 335     die $@ if $@;
 336
 337     return $res;
 338 }
 339
 340 my $kill_process_group = sub {
 341     my ($pid, $pstart) = @_;
 342
 343     # send kill to process group (negative pid)
 344     my $kpid = -$pid;
 345
 346     # always send signal to all pgrp members
 347     kill(15, $kpid); # send TERM signal
 348
 349     # give max 5 seconds to shut down
 350     for (my $i = 0; $i < 5; $i++) {
 351         return if !PVE::ProcFSTools::check_process_running($pid, $pstart);
 352         sleep (1);
 353     }
 354
 355     # to be sure
 356     kill(9, $kpid);
 357 };
 358
 359 sub check_worker {
 360     my ($self, $upid, $killit) = @_;
 361
 362     my $task = PVE::Tools::upid_decode($upid);
 363
 364     my $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
 365
 366     return 0 if !$running;
 367
 368     if ($killit) {
 369         &$kill_process_group($task->{pid});
 370         return 0;
 371     }
 372
 373     return 1;
 374 }
 375
 376 # start long running workers
 377 # STDIN is redirected to /dev/null
 378 # STDOUT,STDERR are redirected to the filename returned by upid_decode
 379 # NOTE: we simulate running in foreground if ($self->{type} eq 'cli')
 380 sub fork_worker {
 381     my ($self, $dtype, $id, $user, $function, $background) = @_;
 382
 383     $dtype = 'unknown' if !defined ($dtype);
 384     $id = '' if !defined ($id);
 385
 386     $user = 'root@pve' if !defined ($user);
 387
 388     my $sync = ($self->{type} eq 'cli' && !$background) ? 1 : 0;
 389
 390     local $SIG{INT} =
 391         local $SIG{QUIT} =
 392         local $SIG{PIPE} =
 393         local $SIG{TERM} = 'IGNORE';
 394
 395     my $starttime = time ();
 396
 397     my @psync = POSIX::pipe();
 398     my @csync = POSIX::pipe();
 399
 400     my $node = $self->{nodename};
 401
 402     my $cpid = fork();
 403     die "unable to fork worker - $!" if !defined($cpid);
 404
 405     my $workerpuid = $cpid ? $cpid : $$;
 406
 407     my $pstart = PVE::ProcFSTools::read_proc_starttime($workerpuid) ||
 408         die "unable to read process start time";
 409
 410     my $upid = PVE::Tools::upid_encode ({
 411         node => $node, pid => $workerpuid, pstart => $pstart,
 412         starttime => $starttime, type => $dtype, id => $id, user => $user });
 413
 414     my $outfh;
 415
 416     if (!$cpid) { # child
 417
 418         $0 = "task $upid";
 419         $WORKER_FLAG = 1;
 420
 421         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub { die "received interrupt\n"; };
 422
 423         $SIG{CHLD} = $SIG{PIPE} = 'DEFAULT';
 424
 425         # set sess/process group - we want to be able to kill the
 426         # whole process group
 427         POSIX::setsid();
 428
 429         POSIX::close ($psync[0]);
 430         POSIX::close ($csync[1]);
 431
 432         $outfh = $sync ? $psync[1] : undef;
 433
 434         eval {
 435             PVE::INotify::inotify_close();
 436
 437             if (my $atfork = $self->{atfork}) {
 438                 &$atfork();
 439             }
 440
 441             # same algorythm as used inside SA
 442             # STDIN = /dev/null
 443             my $fd = fileno (STDIN);
 444
 445             if (!$sync) {
 446                 close STDIN;
 447                 POSIX::close(0) if $fd != 0;
 448
 449                 die "unable to redirect STDIN - $!"
 450                     if !open(STDIN, "</dev/null");
 451
 452                 $outfh = PVE::Tools::upid_open($upid);
 453             }
 454
 455
 456             # redirect STDOUT
 457             $fd = fileno(STDOUT);
 458             close STDOUT;
 459             POSIX::close (1) if $fd != 1;
 460
 461             die "unable to redirect STDOUT - $!"
 462                 if !open(STDOUT, ">&", $outfh);
 463
 464             STDOUT->autoflush (1);
 465
 466             #  redirect STDERR to STDOUT
 467             $fd = fileno (STDERR);
 468             close STDERR;
 469             POSIX::close(2) if $fd != 2;
 470
 471             die "unable to redirect STDERR - $!"
 472                 if !open(STDERR, ">&1");
 473
 474             STDERR->autoflush(1);
 475         };
 476         if (my $err = $@) {
 477             my $msg =  "ERROR: $err";
 478             POSIX::write($psync[1], $msg, length ($msg));
 479             POSIX::close($psync[1]);
 480             POSIX::_exit(1);
 481             kill(-9, $$);
 482         }
 483
 484         # sync with parent (signal that we are ready)
 485         if ($sync) {
 486             print "$upid\n";
 487         } else {
 488             POSIX::write($psync[1], $upid, length ($upid));
 489             POSIX::close($psync[1]);
 490         }
 491
 492         my $readbuf = '';
 493         # sync with parent (wait until parent is ready)
 494         POSIX::read($csync[0], $readbuf, 4096);
 495         die "parent setup error\n" if $readbuf ne 'OK';
 496
 497         if ($self->{type} eq 'ha') {
 498             print "task started by HA resource agent\n";
 499         }
 500         eval { &$function($upid); };
 501         my $err = $@;
 502         if ($err) {
 503             chomp $err;
 504             $err =~ s/\n/ /mg;
 505             syslog('err', $err);
 506             print STDERR "TASK ERROR: $err\n";
 507             POSIX::_exit(-1);
 508         } else {
 509             print STDERR "TASK OK\n";
 510             POSIX::_exit(0);
 511         }
 512         kill(-9, $$);
 513     }
 514
 515     # parent
 516
 517     POSIX::close ($psync[1]);
 518     POSIX::close ($csync[0]);
 519
 520     my $readbuf = '';
 521     # sync with child (wait until child starts)
 522     POSIX::read($psync[0], $readbuf, 4096);
 523
 524     if (!$sync) {
 525         POSIX::close($psync[0]);
 526         &$register_worker($cpid, $user, $upid);
 527     } else {
 528         chomp $readbuf;
 529     }
 530
 531     eval {
 532         die "got no worker upid - start worker failed\n" if !$readbuf;
 533
 534         if ($readbuf =~ m/^ERROR:\s*(.+)$/m) {
 535             die "starting worker failed: $1\n";
 536         }
 537
 538         if ($readbuf ne $upid) {
 539             die "got strange worker upid ('$readbuf' != '$upid') - start worker failed\n";
 540         }
 541
 542         if ($sync) {
 543             $outfh = PVE::Tools::upid_open($upid);
 544         }
 545     };
 546     my $err = $@;
 547
 548     if (!$err) {
 549         my $msg = 'OK';
 550         POSIX::write($csync[1], $msg, length ($msg));
 551         POSIX::close($csync[1]);
 552
 553     } else {
 554         POSIX::close($csync[1]);
 555         kill(-9, $cpid); # make sure it gets killed
 556         die $err;
 557     }
 558
 559     $self->log_cluster_msg('info', $user, "starting task $upid");
 560
 561     my $tlist = $self->active_workers($upid, $sync);
 562     eval { $self->broadcast_tasklist($tlist); };
 563     syslog('err', $@) if $@;
 564
 565     my $res = 0;
 566
 567     if ($sync) {
 568         my $count;
 569         my $outbuf = '';
 570         my $int_count = 0;
 571         eval {
 572             local $SIG{INT} = local $SIG{QUIT} = local $SIG{TERM} = sub {
 573                 # always send signal to all pgrp members
 574                 my $kpid = -$cpid;
 575                 if ($int_count < 3) {
 576                     kill(15, $kpid); # send TERM signal
 577                 } else {
 578                     kill(9, $kpid); # send KILL signal
 579                 }
 580                 $int_count++;
 581             };
 582             local $SIG{PIPE} = sub { die "broken pipe\n"; };
 583
 584             my $select = new IO::Select;
 585             my $fh = IO::Handle->new_from_fd($psync[0], 'r');
 586             $select->add($fh);
 587
 588             while ($select->count) {
 589                 my @handles = $select->can_read(1);
 590                 if (scalar(@handles)) {
 591                     my $count = sysread ($handles[0], $readbuf, 4096);
 592                     if (!defined ($count)) {
 593                         my $err = $!;
 594                         die "sync pipe read error: $err\n";
 595                     }
 596                     last if $count == 0; # eof
 597
 598                     $outbuf .= $readbuf;
 599                     while ($outbuf =~ s/^(([^\010\r\n]*)(\r|\n|(\010)+|\r\n))//s) {
 600                         my $line = $1;
 601                         my $data = $2;
 602                         if ($data =~ m/^TASK OK$/) {
 603                             # skip
 604                         } elsif ($data =~ m/^TASK ERROR: (.+)$/) {
 605                             print STDERR "$1\n";
 606                         } else {
 607                             print $line;
 608                         }
 609                         if ($outfh) {
 610                             print $outfh $line;
 611                             $outfh->flush();
 612                         }
 613                     }
 614                 } else {
 615                     # some commands daemonize without closing stdout
 616                     last if !PVE::ProcFSTools::check_process_running($cpid);
 617                 }
 618             }
 619         };
 620         my $err = $@;
 621
 622         POSIX::close($psync[0]);
 623
 624         if ($outbuf) { # just to be sure
 625             print $outbuf;
 626             if ($outfh) {
 627                 print $outfh $outbuf;
 628             }
 629         }
 630
 631         if ($err) {
 632             $err =~ s/\n/ /mg;
 633             print STDERR "$err\n";
 634             if ($outfh) {
 635                 print $outfh "TASK ERROR: $err\n";
 636             }
 637         }
 638
 639         &$kill_process_group($cpid, $pstart); # make sure it gets killed
 640
 641         close($outfh);
 642
 643         waitpid($cpid, 0);
 644         $res = $?;
 645         &$log_task_result($upid, $user, $res);
 646     }
 647
 648     return wantarray ? ($upid, $res) : $upid;
 649 }
 650
 651 # Abstract function
 652
 653 sub log_cluster_msg {
 654     my ($self, $pri, $user, $msg) = @_;
 655
 656     syslog($pri, "%s", $msg);
 657
 658     # PVE::Cluster::log_msg($pri, $user, $msg);
 659 }
 660
 661 sub broadcast_tasklist {
 662     my ($self, $tlist) = @_;
 663
 664     # PVE::Cluster::broadcast_tasklist($tlist);
 665 }
 666
 667 sub check_api2_permissions {
 668     my ($self, $perm, $username, $param) = @_;
 669
 670     return 1 if !$username && $perm->{user} eq 'world';
 671
 672     raise_perm_exc("user != null") if !$username;
 673
 674     return 1 if $username eq 'root@pam';
 675
 676     raise_perm_exc('user != root@pam') if !$perm;
 677
 678     return 1 if $perm->{user} && $perm->{user} eq 'all';
 679
 680     ##return $self->exec_api2_perm_check($perm->{check}, $username, $param)
 681     ##if $perm->{check};
 682
 683     raise_perm_exc();
 684 }
 685
 686 # init_request - should be called before each REST/CLI request
 687 sub init_request {
 688     my ($self, %params) = @_;
 689
 690     $self->{result_attributes} = {}
 691
 692     # if you nedd more, implement in subclass
 693 }
 694
 695 1;