src/PVE/RESTHandler.pm

   1 package PVE::RESTHandler;
   2
   3 use strict;
   4 no strict 'refs'; # our autoload requires this
   5 use warnings;
   6 use PVE::SafeSyslog;
   7 use PVE::Exception qw(raise raise_param_exc);
   8 use PVE::JSONSchema;
   9 use PVE::Tools;
  10 use HTTP::Status qw(:constants :is status_message);
  11 use Text::Wrap;
  12 use Clone qw(clone);
  13
  14 my $method_registry = {};
  15 my $method_by_name = {};
  16 my $method_path_lookup = {};
  17
  18 our $AUTOLOAD;  # it's a package global
  19
  20 sub api_clone_schema {
  21     my ($schema) = @_;
  22
  23     my $res = {};
  24     my $ref = ref($schema);
  25     die "not a HASH reference" if !($ref && $ref eq 'HASH');
  26
  27     foreach my $k (keys %$schema) {
  28         my $d = $schema->{$k};
  29         if ($k ne 'properties') {
  30             $res->{$k} = ref($d) ? clone($d) : $d;
  31             next;
  32         }
  33         # convert indexed parameters like -net\d+ to -net[n]
  34         foreach my $p (keys %$d) {
  35             my $pd = $d->{$p};
  36             if ($p =~ m/^([a-z]+)(\d+)$/) {
  37                 my ($name, $idx) = ($1, $2);
  38                 if ($idx == 0 && defined($d->{"${name}1"})) {
  39                     $p = "${name}[n]";
  40                 } elsif (defined($d->{"${name}0"})) {
  41                     next; # only handle once for -xx0, but only if -xx0 exists
  42                 }
  43             }
  44             my $tmp = ref($pd) ? clone($pd) : $pd;
  45             # NOTE: add typetext property for more complex types, to
  46             # make the web api viewer code simpler
  47             if (!(defined($tmp->{enum}) || defined($tmp->{pattern}))) {
  48                 my $typetext = PVE::JSONSchema::schema_get_type_text($tmp);
  49                 if ($tmp->{type} && ($tmp->{type} ne $typetext)) {
  50                     $tmp->{typetext} = $typetext;
  51                 }
  52             }
  53             $res->{$k}->{$p} = $tmp;
  54         }
  55     }
  56
  57     return $res;
  58 }
  59
  60 sub api_dump_full {
  61     my ($tree, $index, $class, $prefix, $raw_dump) = @_;
  62
  63     $prefix = '' if !$prefix;
  64
  65     my $ma = $method_registry->{$class};
  66
  67     foreach my $info (@$ma) {
  68
  69         my $path = "$prefix/$info->{path}";
  70         $path =~ s/\/+$//;
  71
  72         if ($info->{subclass}) {
  73             api_dump_full($tree, $index, $info->{subclass}, $path, $raw_dump);
  74         } else {
  75             next if !$path;
  76
  77             # check if method is unique
  78             my $realpath = $path;
  79             $realpath =~ s/\{[^\}]+\}/\{\}/g;
  80             my $fullpath = "$info->{method} $realpath";
  81             die "duplicate path '$realpath'" if $index->{$fullpath};
  82             $index->{$fullpath} = $info;
  83
  84             # insert into tree
  85             my $treedir = $tree;
  86             my $res;
  87             my $sp = '';
  88             foreach my $dir (split('/', $path)) {
  89                 next if !$dir;
  90                 $sp .= "/$dir";
  91                 $res = (grep { $_->{text} eq $dir } @$treedir)[0];
  92                 if ($res) {
  93                     $res->{children} = [] if !$res->{children};
  94                     $treedir = $res->{children};
  95                 } else {
  96                     $res = {
  97                         path => $sp,
  98                         text => $dir,
  99                         children => [],
 100                     };
 101                     push @$treedir, $res;
 102                     $treedir = $res->{children};
 103                 }
 104             }
 105
 106             if ($res) {
 107                 my $data = {};
 108                 foreach my $k (keys %$info) {
 109                     next if $k eq 'code' || $k eq "match_name" || $k eq "match_re" ||
 110                         $k eq "path";
 111
 112                     my $d = $info->{$k};
 113
 114                     if ($raw_dump) {
 115                         $data->{$k} = $d;
 116                     } else {
 117                         if ($k eq 'parameters') {
 118                             $data->{$k} = api_clone_schema($d);
 119                         } else {
 120                             $data->{$k} = ref($d) ? clone($d) : $d;
 121                         }
 122                     }
 123                 }
 124                 $res->{info}->{$info->{method}} = $data;
 125             };
 126         }
 127     }
 128 };
 129
 130 sub api_dump_cleanup_tree {
 131     my ($tree) = @_;
 132
 133     foreach my $rec (@$tree) {
 134         delete $rec->{children} if $rec->{children} && !scalar(@{$rec->{children}});
 135         if ($rec->{children}) {
 136             $rec->{leaf} = 0;
 137             api_dump_cleanup_tree($rec->{children});
 138         } else {
 139             $rec->{leaf} = 1;
 140         }
 141     }
 142
 143 }
 144
 145 # api_dump_remove_refs: prepare API tree for use with to_json($tree)
 146 sub api_dump_remove_refs {
 147     my ($tree) = @_;
 148
 149     my $class = ref($tree);
 150     return $tree if !$class;
 151
 152     if ($class eq 'ARRAY') {
 153         my $res = [];
 154         foreach my $el (@$tree) {
 155             push @$res, api_dump_remove_refs($el);
 156         }
 157         return $res;
 158     } elsif ($class eq 'HASH') {
 159         my $res = {};
 160         foreach my $k (keys %$tree) {
 161             if (my $itemclass = ref($tree->{$k})) {
 162                 if ($itemclass eq 'CODE') {
 163                     next if $k eq 'completion';
 164                 }
 165                 $res->{$k} = api_dump_remove_refs($tree->{$k});
 166             } else {
 167                 $res->{$k} = $tree->{$k};
 168             }
 169         }
 170         return $res;
 171     } elsif ($class eq 'Regexp') {
 172         return "$tree"; # return string representation
 173     } else {
 174         die "unknown class '$class'\n";
 175     }
 176 }
 177
 178 sub api_dump {
 179     my ($class, $prefix, $raw_dump) = @_;
 180
 181     my $tree = [];
 182
 183     my $index = {};
 184     api_dump_full($tree, $index, $class, $prefix, $raw_dump);
 185     api_dump_cleanup_tree($tree);
 186     return $tree;
 187 };
 188
 189 sub validate_method_schemas {
 190
 191     foreach my $class (keys %$method_registry) {
 192         my $ma = $method_registry->{$class};
 193
 194         foreach my $info (@$ma) {
 195             PVE::JSONSchema::validate_method_info($info);
 196         }
 197     }
 198 }
 199
 200 sub register_method {
 201     my ($self, $info) = @_;
 202
 203     my $match_re = [];
 204     my $match_name = [];
 205
 206     my $errprefix;
 207
 208     my $method;
 209     if ($info->{subclass}) {
 210         $errprefix = "register subclass $info->{subclass} at ${self}/$info->{path} -";
 211         $method = 'SUBCLASS';
 212     } else {
 213         $errprefix = "register method ${self}/$info->{path} -";
 214         $info->{method} = 'GET' if !$info->{method};
 215         $method = $info->{method};
 216     }
 217
 218     $method_path_lookup->{$self} = {} if !defined($method_path_lookup->{$self});
 219     my $path_lookup = $method_path_lookup->{$self};
 220
 221     die "$errprefix no path" if !defined($info->{path});
 222
 223     foreach my $comp (split(/\/+/, $info->{path})) {
 224         die "$errprefix path compoment has zero length\n" if $comp eq '';
 225         my ($name, $regex);
 226         if ($comp =~ m/^\{(\w+)(:(.*))?\}$/) {
 227             $name = $1;
 228             $regex = $3 ? $3 : '\S+';
 229             push @$match_re, $regex;
 230             push @$match_name, $name;
 231         } else {
 232             $name = $comp;
 233             push @$match_re, $name;
 234             push @$match_name, undef;
 235         }
 236
 237         if ($regex) {
 238             $path_lookup->{regex} = {} if !defined($path_lookup->{regex});
 239
 240             my $old_name = $path_lookup->{regex}->{match_name};
 241             die "$errprefix found changed regex match name\n"
 242                 if defined($old_name) && ($old_name ne $name);
 243             my $old_re = $path_lookup->{regex}->{match_re};
 244             die "$errprefix found changed regex\n"
 245                 if defined($old_re) && ($old_re ne $regex);
 246             $path_lookup->{regex}->{match_name} = $name;
 247             $path_lookup->{regex}->{match_re} = $regex;
 248
 249             die "$errprefix path match error - regex and fixed items\n"
 250                 if defined($path_lookup->{folders});
 251
 252             $path_lookup = $path_lookup->{regex};
 253
 254         } else {
 255             $path_lookup->{folders}->{$name} = {} if !defined($path_lookup->{folders}->{$name});
 256
 257             die "$errprefix path match error - regex and fixed items\n"
 258                 if defined($path_lookup->{regex});
 259
 260             $path_lookup = $path_lookup->{folders}->{$name};
 261         }
 262     }
 263
 264     die "$errprefix duplicate method definition\n"
 265         if defined($path_lookup->{$method});
 266
 267     if ($method eq 'SUBCLASS') {
 268         foreach my $m (qw(GET PUT POST DELETE)) {
 269             die "$errprefix duplicate method definition SUBCLASS and $m\n" if $path_lookup->{$m};
 270         }
 271     }
 272     $path_lookup->{$method} = $info;
 273
 274     $info->{match_re} = $match_re;
 275     $info->{match_name} = $match_name;
 276
 277     $method_by_name->{$self} = {} if !defined($method_by_name->{$self});
 278
 279     if ($info->{name}) {
 280         die "$errprefix method name already defined\n"
 281             if defined($method_by_name->{$self}->{$info->{name}});
 282
 283         $method_by_name->{$self}->{$info->{name}} = $info;
 284     }
 285
 286     push @{$method_registry->{$self}}, $info;
 287 }
 288
 289 sub DESTROY {}; # avoid problems with autoload
 290
 291 sub AUTOLOAD {
 292     my ($this) = @_;
 293
 294     # also see "man perldiag"
 295
 296     my $sub = $AUTOLOAD;
 297     (my $method = $sub) =~ s/.*:://;
 298
 299     my $info = $this->map_method_by_name($method);
 300
 301     *{$sub} = sub {
 302         my $self = shift;
 303         return $self->handle($info, @_);
 304     };
 305     goto &$AUTOLOAD;
 306 }
 307
 308 sub method_attributes {
 309     my ($self) = @_;
 310
 311     return $method_registry->{$self};
 312 }
 313
 314 sub map_method_by_name {
 315     my ($self, $name) = @_;
 316
 317     my $info = $method_by_name->{$self}->{$name};
 318     die "no such method '${self}::$name'\n" if !$info;
 319
 320     return $info;
 321 }
 322
 323 sub map_path_to_methods {
 324     my ($class, $stack, $uri_param, $pathmatchref) = @_;
 325
 326     my $path_lookup = $method_path_lookup->{$class};
 327
 328     # Note: $pathmatchref can be used to obtain path including
 329     # uri patterns like '/cluster/firewall/groups/{group}'.
 330     # Used by pvesh to display help
 331     if (defined($pathmatchref)) {
 332         $$pathmatchref = '' if !$$pathmatchref;
 333     }
 334
 335     while (defined(my $comp = shift @$stack)) {
 336         return undef if !$path_lookup; # not registerd?
 337         if ($path_lookup->{regex}) {
 338             my $name = $path_lookup->{regex}->{match_name};
 339             my $regex = $path_lookup->{regex}->{match_re};
 340
 341             return undef if $comp !~ m/^($regex)$/;
 342             $uri_param->{$name} = $1;
 343             $path_lookup = $path_lookup->{regex};
 344             $$pathmatchref .= '/{' . $name . '}' if defined($pathmatchref);
 345         } elsif ($path_lookup->{folders}) {
 346             $path_lookup = $path_lookup->{folders}->{$comp};
 347             $$pathmatchref .= '/' . $comp if defined($pathmatchref);
 348         } else {
 349             die "internal error";
 350         }
 351
 352         return undef if !$path_lookup;
 353
 354         if (my $info = $path_lookup->{SUBCLASS}) {
 355             $class = $info->{subclass};
 356
 357             my $fd = $info->{fragmentDelimiter};
 358
 359             if (defined($fd)) {
 360                 # we only support the empty string '' (match whole URI)
 361                 die "unsupported fragmentDelimiter '$fd'"
 362                     if $fd ne '';
 363
 364                 $stack = [ join ('/', @$stack) ] if scalar(@$stack) > 1;
 365             }
 366             $path_lookup = $method_path_lookup->{$class};
 367         }
 368     }
 369
 370     return undef if !$path_lookup;
 371
 372     return ($class, $path_lookup);
 373 }
 374
 375 sub find_handler {
 376     my ($class, $method, $path, $uri_param, $pathmatchref) = @_;
 377
 378     my $stack = [ grep { length($_) > 0 }  split('\/+' , $path)]; # skip empty fragments
 379
 380     my ($handler_class, $path_info);
 381     eval {
 382         ($handler_class, $path_info) = $class->map_path_to_methods($stack, $uri_param, $pathmatchref);
 383     };
 384     my $err = $@;
 385     syslog('err', $err) if $err;
 386
 387     return undef if !($handler_class && $path_info);
 388
 389     my $method_info = $path_info->{$method};
 390
 391     return undef if !$method_info;
 392
 393     return ($handler_class, $method_info);
 394 }
 395
 396 sub handle {
 397     my ($self, $info, $param, $output_options) = @_;
 398
 399     my $func = $info->{code};
 400
 401     if (!($info->{name} && $func)) {
 402         raise("Method lookup failed ('$info->{name}')\n",
 403               code => HTTP_INTERNAL_SERVER_ERROR);
 404     }
 405
 406     if (my $schema = $info->{parameters}) {
 407         # warn "validate ". Dumper($param}) . "\n" . Dumper($schema);
 408         PVE::JSONSchema::validate($param, $schema);
 409         # untaint data (already validated)
 410         my $extra = delete $param->{'extra-args'};
 411         while (my ($key, $val) = each %$param) {
 412             ($param->{$key}) = $val =~ /^(.*)$/s;
 413         }
 414         $param->{'extra-args'} = [map { /^(.*)$/ } @$extra] if $extra;
 415     }
 416
 417     $output_options //= {};
 418     my $result = &$func($param, $output_options);
 419
 420     # todo: this is only to be safe - disable?
 421     if (my $schema = $info->{returns}) {
 422         PVE::JSONSchema::validate($result, $schema, "Result verification failed\n");
 423     }
 424
 425     return $result;
 426 }
 427
 428 # format option, display type and description
 429 # $name: option name
 430 # $display_name: for example "-$name" of "<$name>", pass undef to use "$name:"
 431 # $phash: json schema property hash
 432 # $format: 'asciidoc', 'short', 'long' or 'full'
 433 # $style: 'config', 'config-sub', 'arg' or 'fixed'
 434 # $mapdef: parameter mapping ({ desc => XXX, func => sub {...} })
 435 my $get_property_description = sub {
 436     my ($name, $style, $phash, $format, $mapdef) = @_;
 437
 438     my $res = '';
 439
 440     $format = 'asciidoc' if !defined($format);
 441
 442     my $descr = $phash->{description} || "no description available";
 443
 444     if ($phash->{verbose_description} &&
 445         ($style eq 'config' || $style eq 'config-sub')) {
 446         $descr = $phash->{verbose_description};
 447     }
 448
 449     chomp $descr;
 450
 451     my $type_text = PVE::JSONSchema::schema_get_type_text($phash, $style);
 452
 453     if ($mapdef && $phash->{type} eq 'string') {
 454         $type_text = $mapdef->{desc};
 455     }
 456
 457     if ($format eq 'asciidoc') {
 458
 459         if ($style eq 'config') {
 460             $res .= "`$name`: ";
 461         } elsif ($style eq 'config-sub') {
 462             $res .= "`$name`=";
 463         } elsif ($style eq 'arg') {
 464             $res .= "`--$name` ";
 465         } elsif ($style eq 'fixed') {
 466             $res .= "`<$name>`: ";
 467         } else {
 468             die "unknown style '$style'";
 469         }
 470
 471         $res .= "`$type_text` " if $type_text;
 472
 473         if (defined(my $dv = $phash->{default})) {
 474             $res .= "('default =' `$dv`)";
 475         }
 476
 477         if ($style eq 'config-sub') {
 478             $res .= ";;\n\n";
 479         } else {
 480             $res .= "::\n\n";
 481         }
 482
 483         my $wdescr = $descr;
 484         chomp $wdescr;
 485         $wdescr =~ s/^$/+/mg;
 486
 487         $res .= $wdescr . "\n";
 488
 489         if (my $req = $phash->{requires}) {
 490             my $tmp .= ref($req) ? join(', ', @$req) : $req;
 491             $res .= "+\nNOTE: Requires option(s): `$tmp`\n";
 492         }
 493         $res .= "\n";
 494
 495     } elsif ($format eq 'short' || $format eq 'long' || $format eq 'full') {
 496
 497         my $defaulttxt = '';
 498         if (defined(my $dv = $phash->{default})) {
 499             $defaulttxt = "   (default=$dv)";
 500         }
 501
 502         my $display_name;
 503         if ($style eq 'config') {
 504             $display_name = "$name:";
 505         } elsif ($style eq 'arg') {
 506             $display_name = "-$name";
 507         } elsif ($style eq 'fixed') {
 508             $display_name = "<$name>";
 509         } else {
 510             die "unknown style '$style'";
 511         }
 512
 513         my $tmp = sprintf "  %-10s %s$defaulttxt\n", $display_name, "$type_text";
 514         my $indend = "             ";
 515
 516         $res .= Text::Wrap::wrap('', $indend, ($tmp));
 517         $res .= "\n",
 518         $res .= Text::Wrap::wrap($indend, $indend, ($descr)) . "\n\n";
 519
 520         if (my $req = $phash->{requires}) {
 521             my $tmp = "Requires option(s): ";
 522             $tmp .= ref($req) ? join(', ', @$req) : $req;
 523             $res .= Text::Wrap::wrap($indend, $indend, ($tmp)). "\n\n";
 524         }
 525
 526     } else {
 527         die "unknown format '$format'";
 528     }
 529
 530     return $res;
 531 };
 532
 533 # translate parameter mapping definition
 534 # $mapping_array is a array which can contain:
 535 #   strings ... in that case we assume it is a parameter name, and
 536 #      we want to load that parameter from a file
 537 #   [ param_name, func, desc] ... allows you to specify a arbitrary
 538 #      mapping func for any param
 539 #
 540 # Returns: a hash indexed by parameter_name,
 541 # i.e.  { param_name => { func => .., desc => ... } }
 542 my $compute_param_mapping_hash = sub {
 543     my ($mapping_array) = @_;
 544
 545     my $res = {};
 546
 547     return $res if !defined($mapping_array);
 548
 549     foreach my $item (@$mapping_array) {
 550         my ($name, $func, $desc, $interactive);
 551         if (ref($item) eq 'ARRAY') {
 552             ($name, $func, $desc, $interactive) = @$item;
 553         } elsif (ref($item) eq 'HASH') {
 554             # just use the hash
 555             $res->{$item->{name}} = $item;
 556             next;
 557         } else {
 558             $name = $item;
 559             $func = sub { return PVE::Tools::file_get_contents($_[0]) };
 560         }
 561         $desc //= '<filepath>';
 562         $res->{$name} = { desc => $desc, func => $func, interactive => $interactive };
 563     }
 564
 565     return $res;
 566 };
 567
 568 # generate usage information for command line tools
 569 #
 570 # $info        ... method info
 571 # $prefix      ... usually something like "$exename $cmd" ('pvesm add')
 572 # $arg_param   ... list of parameters we want to get as ordered arguments
 573 #                  on the command line (or single parameter name for lists)
 574 # $fixed_param ... do not generate and info about those parameters
 575 # $format:
 576 #   'long'     ... default (text, list all options)
 577 #   'short'    ... command line only (text, one line)
 578 #   'full'     ... text, include description
 579 #   'asciidoc' ... generate asciidoc for man pages (like 'full')
 580 # $param_cb ... mapping for string parameters to file path parameters
 581 sub getopt_usage {
 582     my ($info, $prefix, $arg_param, $fixed_param, $format, $param_cb) = @_;
 583
 584     $format = 'long' if !$format;
 585
 586     my $schema = $info->{parameters};
 587     my $name = $info->{name};
 588     my $prop = $schema->{properties};
 589
 590     my $out = '';
 591
 592     my $arg_hash = {};
 593
 594     my $args = '';
 595
 596     $arg_param = [ $arg_param ] if $arg_param && !ref($arg_param);
 597
 598     foreach my $p (@$arg_param) {
 599         next if !$prop->{$p}; # just to be sure
 600         my $pd = $prop->{$p};
 601
 602         $arg_hash->{$p} = 1;
 603         $args .= " " if $args;
 604         if ($pd->{format} && $pd->{format} =~ m/-list/) {
 605             $args .= "{<$p>}";
 606         } else {
 607             $args .= $pd->{optional} ? "[<$p>]" : "<$p>";
 608         }
 609     }
 610
 611     my $argdescr = '';
 612     foreach my $k (@$arg_param) {
 613         next if defined($fixed_param->{$k}); # just to be sure
 614         next if !$prop->{$k}; # just to be sure
 615         $argdescr .= $get_property_description->($k, 'fixed', $prop->{$k}, $format);
 616     }
 617
 618     my $idx_param = {}; # -vlan\d+ -scsi\d+
 619
 620     my $opts = '';
 621     foreach my $k (sort keys %$prop) {
 622         next if $arg_hash->{$k};
 623         next if defined($fixed_param->{$k});
 624
 625         my $type_text = $prop->{$k}->{type} || 'string';
 626
 627         my $param_map = {};
 628
 629         if (defined($param_cb)) {
 630             my $mapping = $param_cb->($name);
 631             $param_map = $compute_param_mapping_hash->($mapping);
 632             next if $k eq 'password' && $param_map->{$k} && !$prop->{$k}->{optional};
 633         }
 634
 635         my $base = $k;
 636         if ($k =~ m/^([a-z]+)(\d+)$/) {
 637             my ($name, $idx) = ($1, $2);
 638             next if $idx_param->{$name};
 639             if ($idx == 0 && defined($prop->{"${name}1"})) {
 640                 $idx_param->{$name} = 1;
 641                 $base = "${name}[n]";
 642             }
 643         }
 644
 645
 646         $opts .= $get_property_description->($base, 'arg', $prop->{$k}, $format, $param_map->{$k});
 647
 648         if (!$prop->{$k}->{optional}) {
 649             $args .= " " if $args;
 650             $args .= "--$base <$type_text>"
 651         }
 652     }
 653
 654     if ($format eq 'asciidoc') {
 655         $out .= "*${prefix}*";
 656         $out .= " `$args`" if $args;
 657         $out .= $opts ? " `[OPTIONS]`\n" : "\n";
 658     } else {
 659         $out .= "USAGE: " if $format ne 'short';
 660         $out .= "$prefix $args";
 661         $out .= $opts ? " [OPTIONS]\n" : "\n";
 662     }
 663
 664     return $out if $format eq 'short';
 665
 666     if ($info->{description}) {
 667         if ($format eq 'asciidoc') {
 668             my $desc = Text::Wrap::wrap('', '', ($info->{description}));
 669             $out .= "\n$desc\n\n";
 670         } elsif ($format eq 'full') {
 671             my $desc = Text::Wrap::wrap('  ', '  ', ($info->{description}));
 672             $out .= "\n$desc\n\n";
 673         }
 674     }
 675
 676     $out .= $argdescr if $argdescr;
 677
 678     $out .= $opts if $opts;
 679
 680     return $out;
 681 }
 682
 683 sub usage_str {
 684     my ($self, $name, $prefix, $arg_param, $fixed_param, $format, $param_cb) = @_;
 685
 686     my $info = $self->map_method_by_name($name);
 687
 688     return getopt_usage($info, $prefix, $arg_param, $fixed_param, $format, $param_cb);
 689 }
 690
 691 # generate docs from JSON schema properties
 692 sub dump_properties {
 693     my ($prop, $format, $style, $filterFn) = @_;
 694
 695     my $raw = '';
 696
 697     $style //= 'config';
 698
 699     my $idx_param = {}; # -vlan\d+ -scsi\d+
 700
 701     foreach my $k (sort keys %$prop) {
 702         my $phash = $prop->{$k};
 703
 704         next if defined($filterFn) && &$filterFn($k, $phash);
 705         next if $phash->{alias};
 706
 707         my $base = $k;
 708         if ($k =~ m/^([a-z]+)(\d+)$/) {
 709             my ($name, $idx) = ($1, $2);
 710             next if $idx_param->{$name};
 711             if ($idx == 0 && defined($prop->{"${name}1"})) {
 712                 $idx_param->{$name} = 1;
 713                 $base = "${name}[n]";
 714             }
 715         }
 716
 717         $raw .= $get_property_description->($base, $style, $phash, $format);
 718
 719         next if $style ne 'config';
 720
 721         my $prop_fmt = $phash->{format};
 722         next if !$prop_fmt;
 723
 724         if (ref($prop_fmt) ne 'HASH') {
 725             $prop_fmt = PVE::JSONSchema::get_format($prop_fmt);
 726         }
 727
 728         next if !(ref($prop_fmt) && (ref($prop_fmt) eq 'HASH'));
 729
 730         $raw .= dump_properties($prop_fmt, $format, 'config-sub')
 731
 732     }
 733
 734     return $raw;
 735 }
 736
 737 my $replace_file_names_with_contents = sub {
 738     my ($param, $param_map) = @_;
 739
 740     while (my ($k, $d) = each %$param_map) {
 741         next if $d->{interactive}; # handled by the JSONSchema's get_options code
 742         $param->{$k} = $d->{func}->($param->{$k})
 743             if defined($param->{$k});
 744     }
 745
 746     return $param;
 747 };
 748
 749 our $standard_output_options = {
 750     format => PVE::JSONSchema::get_standard_option('pve-output-format'),
 751     noheader => {
 752         description => "Do not show column headers (for 'text' format).",
 753         type => 'boolean',
 754         optional => 1,
 755         default => 1,
 756     },
 757     noborder => {
 758         description => "Do not draw borders (for 'text' format).",
 759         type => 'boolean',
 760         optional => 1,
 761         default => 1,
 762     },
 763     quiet => {
 764         description => "Suppress printing results.",
 765         type => 'boolean',
 766         optional => 1,
 767     },
 768     'human-readable' => {
 769         description => "Call output rendering functions to produce human readable text.",
 770         type => 'boolean',
 771         optional => 1,
 772         default => 1,
 773     }
 774 };
 775
 776 sub add_standard_output_parameters {
 777     my ($org_schema) = @_;
 778
 779     my $schema = { %$org_schema };
 780     $schema->{properties} = { %{$schema->{properties}}, %$standard_output_options };
 781
 782     return $schema;
 783 };
 784
 785 sub cli_handler {
 786     my ($self, $prefix, $name, $args, $arg_param, $fixed_param, $param_cb, $options) = @_;
 787
 788     my $info = $self->map_method_by_name($name);
 789     $options //= {};
 790
 791     my $add_stdopts = $options->{'std-output-opts'};
 792
 793     my $res;
 794     eval {
 795         my $param_map = {};
 796         $param_map = $compute_param_mapping_hash->($param_cb->($name)) if $param_cb;
 797         my $schema = $add_stdopts ? add_standard_output_parameters($info->{parameters}) : $info->{properties} ;
 798         my $param = PVE::JSONSchema::get_options($schema, $args, $arg_param, $fixed_param, $param_map);
 799
 800         if ($add_stdopts) {
 801             foreach my $opt (keys %$standard_output_options) {
 802                 $options->{$opt} = delete $param->{$opt} if defined($param->{$opt});
 803             }
 804         }
 805
 806         if (defined($param_map)) {
 807             $replace_file_names_with_contents->($param, $param_map);
 808         }
 809
 810         $res = $self->handle($info, $param, $options);
 811     };
 812     if (my $err = $@) {
 813         my $ec = ref($err);
 814
 815         die $err if !$ec || $ec ne "PVE::Exception" || !$err->is_param_exc();
 816
 817         $err->{usage} = $self->usage_str($name, $prefix, $arg_param, $fixed_param, 'short',  $param_cb);
 818
 819         die $err;
 820     }
 821
 822     return $res;
 823 }
 824
 825 # utility methods
 826 # note: this modifies the original hash by adding the id property
 827 sub hash_to_array {
 828     my ($hash, $idprop) = @_;
 829
 830     my $res = [];
 831     return $res if !$hash;
 832
 833     foreach my $k (keys %$hash) {
 834         $hash->{$k}->{$idprop} = $k;
 835         push @$res, $hash->{$k};
 836     }
 837
 838     return $res;
 839 }
 840
 841 1;