remove superfluous substitution
[pve-common.git] / src / PVE / RESTHandler.pm
1 package PVE::RESTHandler;
2
3 use strict;
4 no strict 'refs'; # our autoload requires this
5 use warnings;
6 use PVE::SafeSyslog;
7 use PVE::Exception qw(raise raise_param_exc);
8 use PVE::JSONSchema;
9 use PVE::PodParser;
10 use HTTP::Status qw(:constants :is status_message);
11 use Text::Wrap;
12 use Storable qw(dclone);
13
14 my $method_registry = {};
15 my $method_by_name = {};
16 my $method_path_lookup = {};
17
18 our $AUTOLOAD; # it's a package global
19
20 sub api_clone_schema {
21 my ($schema) = @_;
22
23 my $res = {};
24 my $ref = ref($schema);
25 die "not a HASH reference" if !($ref && $ref eq 'HASH');
26
27 foreach my $k (keys %$schema) {
28 my $d = $schema->{$k};
29 if ($k ne 'properties') {
30 $res->{$k} = ref($d) ? dclone($d) : $d;
31 next;
32 }
33 # convert indexed parameters like -net\d+ to -net[n]
34 foreach my $p (keys %$d) {
35 my $pd = $d->{$p};
36 if ($p =~ m/^([a-z]+)(\d+)$/) {
37 if ($2 == 0) {
38 $p = "$1\[n\]";
39 } else {
40 next;
41 }
42 }
43 $res->{$k}->{$p} = ref($pd) ? dclone($pd) : $pd;
44 }
45 }
46
47 return $res;
48 }
49
50 sub api_dump_full {
51 my ($tree, $index, $class, $prefix) = @_;
52
53 $prefix = '' if !$prefix;
54
55 my $ma = $method_registry->{$class};
56
57 foreach my $info (@$ma) {
58
59 my $path = "$prefix/$info->{path}";
60 $path =~ s/\/+$//;
61
62 if ($info->{subclass}) {
63 api_dump_full($tree, $index, $info->{subclass}, $path);
64 } else {
65 next if !$path;
66
67 # check if method is unique
68 my $realpath = $path;
69 $realpath =~ s/\{[^\}]+\}/\{\}/g;
70 my $fullpath = "$info->{method} $realpath";
71 die "duplicate path '$realpath'" if $index->{$fullpath};
72 $index->{$fullpath} = $info;
73
74 # insert into tree
75 my $treedir = $tree;
76 my $res;
77 my $sp = '';
78 foreach my $dir (split('/', $path)) {
79 next if !$dir;
80 $sp .= "/$dir";
81 $res = (grep { $_->{text} eq $dir } @$treedir)[0];
82 if ($res) {
83 $res->{children} = [] if !$res->{children};
84 $treedir = $res->{children};
85 } else {
86 $res = {
87 path => $sp,
88 text => $dir,
89 children => [],
90 };
91 push @$treedir, $res;
92 $treedir = $res->{children};
93 }
94 }
95
96 if ($res) {
97 my $data = {};
98 foreach my $k (keys %$info) {
99 next if $k eq 'code' || $k eq "match_name" || $k eq "match_re" ||
100 $k eq "path";
101
102 my $d = $info->{$k};
103
104 if ($k eq 'parameters') {
105 $data->{$k} = api_clone_schema($d);
106 } else {
107
108 $data->{$k} = ref($d) ? dclone($d) : $d;
109 }
110 }
111 $res->{info}->{$info->{method}} = $data;
112 };
113 }
114 }
115 };
116
117 sub api_dump_cleanup_tree {
118 my ($tree) = @_;
119
120 foreach my $rec (@$tree) {
121 delete $rec->{children} if $rec->{children} && !scalar(@{$rec->{children}});
122 if ($rec->{children}) {
123 $rec->{leaf} = 0;
124 api_dump_cleanup_tree($rec->{children});
125 } else {
126 $rec->{leaf} = 1;
127 }
128 }
129
130 }
131
132 sub api_dump {
133 my ($class, $prefix) = @_;
134
135 my $tree = [];
136
137 my $index = {};
138 api_dump_full($tree, $index, $class);
139 api_dump_cleanup_tree($tree);
140 return $tree;
141 };
142
143 sub validate_method_schemas {
144
145 foreach my $class (keys %$method_registry) {
146 my $ma = $method_registry->{$class};
147
148 foreach my $info (@$ma) {
149 PVE::JSONSchema::validate_method_info($info);
150 }
151 }
152 }
153
154 sub register_method {
155 my ($self, $info) = @_;
156
157 my $match_re = [];
158 my $match_name = [];
159
160 my $errprefix;
161
162 my $method;
163 if ($info->{subclass}) {
164 $errprefix = "register subclass $info->{subclass} at ${self}/$info->{path} -";
165 $method = 'SUBCLASS';
166 } else {
167 $errprefix = "register method ${self}/$info->{path} -";
168 $info->{method} = 'GET' if !$info->{method};
169 $method = $info->{method};
170 }
171
172 $method_path_lookup->{$self} = {} if !defined($method_path_lookup->{$self});
173 my $path_lookup = $method_path_lookup->{$self};
174
175 die "$errprefix no path" if !defined($info->{path});
176
177 foreach my $comp (split(/\/+/, $info->{path})) {
178 die "$errprefix path compoment has zero length\n" if $comp eq '';
179 my ($name, $regex);
180 if ($comp =~ m/^\{(\w+)(:(.*))?\}$/) {
181 $name = $1;
182 $regex = $3 ? $3 : '\S+';
183 push @$match_re, $regex;
184 push @$match_name, $name;
185 } else {
186 $name = $comp;
187 push @$match_re, $name;
188 push @$match_name, undef;
189 }
190
191 if ($regex) {
192 $path_lookup->{regex} = {} if !defined($path_lookup->{regex});
193
194 my $old_name = $path_lookup->{regex}->{match_name};
195 die "$errprefix found changed regex match name\n"
196 if defined($old_name) && ($old_name ne $name);
197 my $old_re = $path_lookup->{regex}->{match_re};
198 die "$errprefix found changed regex\n"
199 if defined($old_re) && ($old_re ne $regex);
200 $path_lookup->{regex}->{match_name} = $name;
201 $path_lookup->{regex}->{match_re} = $regex;
202
203 die "$errprefix path match error - regex and fixed items\n"
204 if defined($path_lookup->{folders});
205
206 $path_lookup = $path_lookup->{regex};
207
208 } else {
209 $path_lookup->{folders}->{$name} = {} if !defined($path_lookup->{folders}->{$name});
210
211 die "$errprefix path match error - regex and fixed items\n"
212 if defined($path_lookup->{regex});
213
214 $path_lookup = $path_lookup->{folders}->{$name};
215 }
216 }
217
218 die "$errprefix duplicate method definition\n"
219 if defined($path_lookup->{$method});
220
221 if ($method eq 'SUBCLASS') {
222 foreach my $m (qw(GET PUT POST DELETE)) {
223 die "$errprefix duplicate method definition SUBCLASS and $m\n" if $path_lookup->{$m};
224 }
225 }
226 $path_lookup->{$method} = $info;
227
228 $info->{match_re} = $match_re;
229 $info->{match_name} = $match_name;
230
231 $method_by_name->{$self} = {} if !defined($method_by_name->{$self});
232
233 if ($info->{name}) {
234 die "$errprefix method name already defined\n"
235 if defined($method_by_name->{$self}->{$info->{name}});
236
237 $method_by_name->{$self}->{$info->{name}} = $info;
238 }
239
240 push @{$method_registry->{$self}}, $info;
241 }
242
243 sub register_page_formatter {
244 my ($self, %config) = @_;
245
246 my $format = $config{format} ||
247 die "missing format";
248
249 my $path = $config{path} ||
250 die "missing path";
251
252 my $method = $config{method} ||
253 die "missing method";
254
255 my $code = $config{code} ||
256 die "missing formatter code";
257
258 my $uri_param = {};
259 my ($handler, $info) = $self->find_handler($method, $path, $uri_param);
260 die "unabe to find handler for '$method: $path'" if !($handler && $info);
261
262 die "duplicate formatter for '$method: $path'"
263 if $info->{formatter} && $info->{formatter}->{$format};
264
265 $info->{formatter}->{$format} = $code;
266 }
267
268 sub DESTROY {}; # avoid problems with autoload
269
270 sub AUTOLOAD {
271 my ($this) = @_;
272
273 # also see "man perldiag"
274
275 my $sub = $AUTOLOAD;
276 (my $method = $sub) =~ s/.*:://;
277
278 my $info = $this->map_method_by_name($method);
279
280 *{$sub} = sub {
281 my $self = shift;
282 return $self->handle($info, @_);
283 };
284 goto &$AUTOLOAD;
285 }
286
287 sub method_attributes {
288 my ($self) = @_;
289
290 return $method_registry->{$self};
291 }
292
293 sub map_method_by_name {
294 my ($self, $name) = @_;
295
296 my $info = $method_by_name->{$self}->{$name};
297 die "no such method '${self}::$name'\n" if !$info;
298
299 return $info;
300 }
301
302 sub map_path_to_methods {
303 my ($class, $stack, $uri_param, $pathmatchref) = @_;
304
305 my $path_lookup = $method_path_lookup->{$class};
306
307 # Note: $pathmatchref can be used to obtain path including
308 # uri patterns like '/cluster/firewall/groups/{group}'.
309 # Used by pvesh to display help
310 if (defined($pathmatchref)) {
311 $$pathmatchref = '' if !$$pathmatchref;
312 }
313
314 while (defined(my $comp = shift @$stack)) {
315 return undef if !$path_lookup; # not registerd?
316 if ($path_lookup->{regex}) {
317 my $name = $path_lookup->{regex}->{match_name};
318 my $regex = $path_lookup->{regex}->{match_re};
319
320 return undef if $comp !~ m/^($regex)$/;
321 $uri_param->{$name} = $1;
322 $path_lookup = $path_lookup->{regex};
323 $$pathmatchref .= '/{' . $name . '}' if defined($pathmatchref);
324 } elsif ($path_lookup->{folders}) {
325 $path_lookup = $path_lookup->{folders}->{$comp};
326 $$pathmatchref .= '/' . $comp if defined($pathmatchref);
327 } else {
328 die "internal error";
329 }
330
331 return undef if !$path_lookup;
332
333 if (my $info = $path_lookup->{SUBCLASS}) {
334 $class = $info->{subclass};
335
336 my $fd = $info->{fragmentDelimiter};
337
338 if (defined($fd)) {
339 # we only support the empty string '' (match whole URI)
340 die "unsupported fragmentDelimiter '$fd'"
341 if $fd ne '';
342
343 $stack = [ join ('/', @$stack) ] if scalar(@$stack) > 1;
344 }
345 $path_lookup = $method_path_lookup->{$class};
346 }
347 }
348
349 return undef if !$path_lookup;
350
351 return ($class, $path_lookup);
352 }
353
354 sub find_handler {
355 my ($class, $method, $path, $uri_param, $pathmatchref) = @_;
356
357 my $stack = [ grep { length($_) > 0 } split('\/+' , $path)]; # skip empty fragments
358
359 my ($handler_class, $path_info);
360 eval {
361 ($handler_class, $path_info) = $class->map_path_to_methods($stack, $uri_param, $pathmatchref);
362 };
363 my $err = $@;
364 syslog('err', $err) if $err;
365
366 return undef if !($handler_class && $path_info);
367
368 my $method_info = $path_info->{$method};
369
370 return undef if !$method_info;
371
372 return ($handler_class, $method_info);
373 }
374
375 sub handle {
376 my ($self, $info, $param) = @_;
377
378 my $func = $info->{code};
379
380 if (!($info->{name} && $func)) {
381 raise("Method lookup failed ('$info->{name}')\n",
382 code => HTTP_INTERNAL_SERVER_ERROR);
383 }
384
385 if (my $schema = $info->{parameters}) {
386 # warn "validate ". Dumper($param}) . "\n" . Dumper($schema);
387 PVE::JSONSchema::validate($param, $schema);
388 # untaint data (already validated)
389 while (my ($key, $val) = each %$param) {
390 ($param->{$key}) = $val =~ /^(.*)$/s;
391 }
392 }
393
394 my $result = &$func($param);
395
396 # todo: this is only to be safe - disable?
397 if (my $schema = $info->{returns}) {
398 PVE::JSONSchema::validate($result, $schema, "Result verification vailed\n");
399 }
400
401 return $result;
402 }
403
404 # generate usage information for command line tools
405 #
406 # $name ... the name of the method
407 # $prefix ... usually something like "$exename $cmd" ('pvesm add')
408 # $arg_param ... list of parameters we want to get as ordered arguments
409 # on the command line (or single parameter name for lists)
410 # $fixed_param ... do not generate and info about those parameters
411 # $format:
412 # 'long' ... default (list all options)
413 # 'short' ... command line only (one line)
414 # 'full' ... also include description
415 # $hidepw ... hide password option (use this if you provide a read passwork callback)
416 sub usage_str {
417 my ($self, $name, $prefix, $arg_param, $fixed_param, $format, $hidepw) = @_;
418
419 $format = 'long' if !$format;
420
421 my $info = $self->map_method_by_name($name);
422 my $schema = $info->{parameters};
423 my $prop = $schema->{properties};
424
425 my $out = '';
426
427 my $arg_hash = {};
428
429 my $args = '';
430
431 $arg_param = [ $arg_param ] if $arg_param && !ref($arg_param);
432
433 foreach my $p (@$arg_param) {
434 next if !$prop->{$p}; # just to be sure
435 my $pd = $prop->{$p};
436
437 $arg_hash->{$p} = 1;
438 $args .= " " if $args;
439 if ($pd->{format} && $pd->{format} =~ m/-list/) {
440 $args .= "{<$p>}";
441 } else {
442 $args .= $pd->{optional} ? "[<$p>]" : "<$p>";
443 }
444 }
445
446 my $get_prop_descr = sub {
447 my ($k, $display_name) = @_;
448
449 my $phash = $prop->{$k};
450
451 my $res = '';
452
453 my $descr = $phash->{description} || "no description available";
454 chomp $descr;
455
456 my $type = PVE::PodParser::schema_get_type_text($phash);
457
458 if ($hidepw && $k eq 'password') {
459 $type = '';
460 }
461
462 my $defaulttxt = '';
463 if (defined(my $dv = $phash->{default})) {
464 $defaulttxt = " (default=$dv)";
465 }
466 my $tmp = sprintf " %-10s %s$defaulttxt\n", $display_name, "$type";
467 my $indend = " ";
468
469 $res .= Text::Wrap::wrap('', $indend, ($tmp));
470 $res .= "\n",
471 $res .= Text::Wrap::wrap($indend, $indend, ($descr)) . "\n\n";
472
473 if (my $req = $phash->{requires}) {
474 my $tmp = "Requires option(s): ";
475 $tmp .= ref($req) ? join(', ', @$req) : $req;
476 $res .= Text::Wrap::wrap($indend, $indend, ($tmp)). "\n\n";
477 }
478
479 return $res;
480 };
481
482 my $argdescr = '';
483 foreach my $k (@$arg_param) {
484 next if defined($fixed_param->{$k}); # just to be sure
485 next if !$prop->{$k}; # just to be sure
486 $argdescr .= &$get_prop_descr($k, "<$k>");
487 }
488
489 my $idx_param = {}; # -vlan\d+ -scsi\d+
490
491 my $opts = '';
492 foreach my $k (sort keys %$prop) {
493 next if $arg_hash->{$k};
494 next if defined($fixed_param->{$k});
495
496 my $type = $prop->{$k}->{type} || 'string';
497
498 next if $hidepw && ($k eq 'password') && !$prop->{$k}->{optional};
499
500 my $base = $k;
501 if ($k =~ m/^([a-z]+)(\d+)$/) {
502 my $name = $1;
503 next if $idx_param->{$name};
504 $idx_param->{$name} = 1;
505 $base = "${name}[n]";
506 }
507
508 $opts .= &$get_prop_descr($k, "-$base");
509
510 if (!$prop->{$k}->{optional}) {
511 $args .= " " if $args;
512 $args .= "-$base <$type>"
513 }
514 }
515
516 $out .= "USAGE: " if $format ne 'short';
517
518 $out .= "$prefix $args";
519
520 $out .= $opts ? " [OPTIONS]\n" : "\n";
521
522 return $out if $format eq 'short';
523
524 if ($info->{description} && $format eq 'full') {
525 my $desc = Text::Wrap::wrap(' ', ' ', ($info->{description}));
526 $out .= "\n$desc\n\n";
527 }
528
529 $out .= $argdescr if $argdescr;
530
531 $out .= $opts if $opts;
532
533 return $out;
534 }
535
536 sub cli_handler {
537 my ($self, $prefix, $name, $args, $arg_param, $fixed_param, $pwcallback) = @_;
538
539 my $info = $self->map_method_by_name($name);
540
541 my $res;
542 eval {
543 my $param = PVE::JSONSchema::get_options($info->{parameters}, $args, $arg_param, $fixed_param, $pwcallback);
544 $res = $self->handle($info, $param);
545 };
546 if (my $err = $@) {
547 my $ec = ref($err);
548
549 die $err if !$ec || $ec ne "PVE::Exception" || !$err->is_param_exc();
550
551 $err->{usage} = $self->usage_str($name, $prefix, $arg_param, $fixed_param, 'short', $pwcallback);
552
553 die $err;
554 }
555
556 return $res;
557 }
558
559 # utility methods
560 # note: this modifies the original hash by adding the id property
561 sub hash_to_array {
562 my ($hash, $idprop) = @_;
563
564 my $res = [];
565 return $res if !$hash;
566
567 foreach my $k (keys %$hash) {
568 $hash->{$k}->{$idprop} = $k;
569 push @$res, $hash->{$k};
570 }
571
572 return $res;
573 }
574
575 1;