src/PVE/RESTHandler.pm

   1 package PVE::RESTHandler;
   2
   3 use strict;
   4 no strict 'refs'; # our autoload requires this
   5 use warnings;
   6 use PVE::SafeSyslog;
   7 use PVE::Exception qw(raise raise_param_exc);
   8 use PVE::JSONSchema;
   9 use PVE::PodParser;
  10 use HTTP::Status qw(:constants :is status_message);
  11 use Text::Wrap;
  12 use Clone qw(clone);
  13
  14 my $method_registry = {};
  15 my $method_by_name = {};
  16 my $method_path_lookup = {};
  17
  18 our $AUTOLOAD;  # it's a package global
  19
  20 sub api_clone_schema {
  21     my ($schema) = @_;
  22
  23     my $res = {};
  24     my $ref = ref($schema);
  25     die "not a HASH reference" if !($ref && $ref eq 'HASH');
  26
  27     foreach my $k (keys %$schema) {
  28         my $d = $schema->{$k};
  29         if ($k ne 'properties') {
  30             $res->{$k} = ref($d) ? clone($d) : $d;
  31             next;
  32         }
  33         # convert indexed parameters like -net\d+ to -net[n]
  34         foreach my $p (keys %$d) {
  35             my $pd = $d->{$p};
  36             if ($p =~ m/^([a-z]+)(\d+)$/) {
  37                 if ($2 == 0) {
  38                     $p = "$1\[n\]";
  39                 } else {
  40                     next;
  41                 }
  42             }
  43             $res->{$k}->{$p} = ref($pd) ? clone($pd) : $pd;
  44         }
  45     }
  46
  47     return $res;
  48 }
  49
  50 sub api_dump_full {
  51     my ($tree, $index, $class, $prefix) = @_;
  52
  53     $prefix = '' if !$prefix;
  54
  55     my $ma = $method_registry->{$class};
  56
  57     foreach my $info (@$ma) {
  58
  59         my $path = "$prefix/$info->{path}";
  60         $path =~ s/\/+$//;
  61
  62         if ($info->{subclass}) {
  63             api_dump_full($tree, $index, $info->{subclass}, $path);
  64         } else {
  65             next if !$path;
  66
  67             # check if method is unique
  68             my $realpath = $path;
  69             $realpath =~ s/\{[^\}]+\}/\{\}/g;
  70             my $fullpath = "$info->{method} $realpath";
  71             die "duplicate path '$realpath'" if $index->{$fullpath};
  72             $index->{$fullpath} = $info;
  73
  74             # insert into tree
  75             my $treedir = $tree;
  76             my $res;
  77             my $sp = '';
  78             foreach my $dir (split('/', $path)) {
  79                 next if !$dir;
  80                 $sp .= "/$dir";
  81                 $res = (grep { $_->{text} eq $dir } @$treedir)[0];
  82                 if ($res) {
  83                     $res->{children} = [] if !$res->{children};
  84                     $treedir = $res->{children};
  85                 } else {
  86                     $res = {
  87                         path => $sp,
  88                         text => $dir,
  89                         children => [],
  90                     };
  91                     push @$treedir, $res;
  92                     $treedir = $res->{children};
  93                 }
  94             }
  95
  96             if ($res) {
  97                 my $data = {};
  98                 foreach my $k (keys %$info) {
  99                     next if $k eq 'code' || $k eq "match_name" || $k eq "match_re" ||
 100                         $k eq "path";
 101
 102                     my $d = $info->{$k};
 103
 104                     if ($k eq 'parameters') {
 105                         $data->{$k} = api_clone_schema($d);
 106                     } else {
 107
 108                         $data->{$k} = ref($d) ? clone($d) : $d;
 109                     }
 110                 }
 111                 $res->{info}->{$info->{method}} = $data;
 112             };
 113         }
 114     }
 115 };
 116
 117 sub api_dump_cleanup_tree {
 118     my ($tree) = @_;
 119
 120     foreach my $rec (@$tree) {
 121         delete $rec->{children} if $rec->{children} && !scalar(@{$rec->{children}});
 122         if ($rec->{children}) {
 123             $rec->{leaf} = 0;
 124             api_dump_cleanup_tree($rec->{children});
 125         } else {
 126             $rec->{leaf} = 1;
 127         }
 128     }
 129
 130 }
 131
 132 sub api_dump {
 133     my ($class, $prefix) = @_;
 134
 135     my $tree = [];
 136
 137     my $index = {};
 138     api_dump_full($tree, $index, $class);
 139     api_dump_cleanup_tree($tree);
 140     return $tree;
 141 };
 142
 143 sub validate_method_schemas {
 144
 145     foreach my $class (keys %$method_registry) {
 146         my $ma = $method_registry->{$class};
 147
 148         foreach my $info (@$ma) {
 149             PVE::JSONSchema::validate_method_info($info);
 150         }
 151     }
 152 }
 153
 154 sub register_method {
 155     my ($self, $info) = @_;
 156
 157     my $match_re = [];
 158     my $match_name = [];
 159
 160     my $errprefix;
 161
 162     my $method;
 163     if ($info->{subclass}) {
 164         $errprefix = "register subclass $info->{subclass} at ${self}/$info->{path} -";
 165         $method = 'SUBCLASS';
 166     } else {
 167         $errprefix = "register method ${self}/$info->{path} -";
 168         $info->{method} = 'GET' if !$info->{method};
 169         $method = $info->{method};
 170     }
 171
 172     $method_path_lookup->{$self} = {} if !defined($method_path_lookup->{$self});
 173     my $path_lookup = $method_path_lookup->{$self};
 174
 175     die "$errprefix no path" if !defined($info->{path});
 176
 177     foreach my $comp (split(/\/+/, $info->{path})) {
 178         die "$errprefix path compoment has zero length\n" if $comp eq '';
 179         my ($name, $regex);
 180         if ($comp =~ m/^\{(\w+)(:(.*))?\}$/) {
 181             $name = $1;
 182             $regex = $3 ? $3 : '\S+';
 183             push @$match_re, $regex;
 184             push @$match_name, $name;
 185         } else {
 186             $name = $comp;
 187             push @$match_re, $name;
 188             push @$match_name, undef;
 189         }
 190
 191         if ($regex) {
 192             $path_lookup->{regex} = {} if !defined($path_lookup->{regex});
 193
 194             my $old_name = $path_lookup->{regex}->{match_name};
 195             die "$errprefix found changed regex match name\n"
 196                 if defined($old_name) && ($old_name ne $name);
 197             my $old_re = $path_lookup->{regex}->{match_re};
 198             die "$errprefix found changed regex\n"
 199                 if defined($old_re) && ($old_re ne $regex);
 200             $path_lookup->{regex}->{match_name} = $name;
 201             $path_lookup->{regex}->{match_re} = $regex;
 202
 203             die "$errprefix path match error - regex and fixed items\n"
 204                 if defined($path_lookup->{folders});
 205
 206             $path_lookup = $path_lookup->{regex};
 207
 208         } else {
 209             $path_lookup->{folders}->{$name} = {} if !defined($path_lookup->{folders}->{$name});
 210
 211             die "$errprefix path match error - regex and fixed items\n"
 212                 if defined($path_lookup->{regex});
 213
 214             $path_lookup = $path_lookup->{folders}->{$name};
 215         }
 216     }
 217
 218     die "$errprefix duplicate method definition\n"
 219         if defined($path_lookup->{$method});
 220
 221     if ($method eq 'SUBCLASS') {
 222         foreach my $m (qw(GET PUT POST DELETE)) {
 223             die "$errprefix duplicate method definition SUBCLASS and $m\n" if $path_lookup->{$m};
 224         }
 225     }
 226     $path_lookup->{$method} = $info;
 227
 228     $info->{match_re} = $match_re;
 229     $info->{match_name} = $match_name;
 230
 231     $method_by_name->{$self} = {} if !defined($method_by_name->{$self});
 232
 233     if ($info->{name}) {
 234         die "$errprefix method name already defined\n"
 235             if defined($method_by_name->{$self}->{$info->{name}});
 236
 237         $method_by_name->{$self}->{$info->{name}} = $info;
 238     }
 239
 240     push @{$method_registry->{$self}}, $info;
 241 }
 242
 243 sub register_page_formatter {
 244     my ($self, %config) = @_;
 245
 246     my $format = $config{format} ||
 247         die "missing format";
 248
 249     my $path = $config{path} ||
 250         die "missing path";
 251
 252     my $method = $config{method} ||
 253         die "missing method";
 254
 255     my $code = $config{code} ||
 256         die "missing formatter code";
 257
 258     my $uri_param = {};
 259     my ($handler, $info) = $self->find_handler($method, $path, $uri_param);
 260     die "unabe to find handler for '$method: $path'" if !($handler && $info);
 261
 262     die "duplicate formatter for '$method: $path'"
 263         if $info->{formatter} && $info->{formatter}->{$format};
 264
 265     $info->{formatter}->{$format} = $code;
 266 }
 267
 268 sub DESTROY {}; # avoid problems with autoload
 269
 270 sub AUTOLOAD {
 271     my ($this) = @_;
 272
 273     # also see "man perldiag"
 274
 275     my $sub = $AUTOLOAD;
 276     (my $method = $sub) =~ s/.*:://;
 277
 278     my $info = $this->map_method_by_name($method);
 279
 280     *{$sub} = sub {
 281         my $self = shift;
 282         return $self->handle($info, @_);
 283     };
 284     goto &$AUTOLOAD;
 285 }
 286
 287 sub method_attributes {
 288     my ($self) = @_;
 289
 290     return $method_registry->{$self};
 291 }
 292
 293 sub map_method_by_name {
 294     my ($self, $name) = @_;
 295
 296     my $info = $method_by_name->{$self}->{$name};
 297     die "no such method '${self}::$name'\n" if !$info;
 298
 299     return $info;
 300 }
 301
 302 sub map_path_to_methods {
 303     my ($class, $stack, $uri_param, $pathmatchref) = @_;
 304
 305     my $path_lookup = $method_path_lookup->{$class};
 306
 307     # Note: $pathmatchref can be used to obtain path including
 308     # uri patterns like '/cluster/firewall/groups/{group}'.
 309     # Used by pvesh to display help
 310     if (defined($pathmatchref)) {
 311         $$pathmatchref = '' if !$$pathmatchref;
 312     }
 313
 314     while (defined(my $comp = shift @$stack)) {
 315         return undef if !$path_lookup; # not registerd?
 316         if ($path_lookup->{regex}) {
 317             my $name = $path_lookup->{regex}->{match_name};
 318             my $regex = $path_lookup->{regex}->{match_re};
 319
 320             return undef if $comp !~ m/^($regex)$/;
 321             $uri_param->{$name} = $1;
 322             $path_lookup = $path_lookup->{regex};
 323             $$pathmatchref .= '/{' . $name . '}' if defined($pathmatchref);
 324         } elsif ($path_lookup->{folders}) {
 325             $path_lookup = $path_lookup->{folders}->{$comp};
 326             $$pathmatchref .= '/' . $comp if defined($pathmatchref);
 327         } else {
 328             die "internal error";
 329         }
 330
 331         return undef if !$path_lookup;
 332
 333         if (my $info = $path_lookup->{SUBCLASS}) {
 334             $class = $info->{subclass};
 335
 336             my $fd = $info->{fragmentDelimiter};
 337
 338             if (defined($fd)) {
 339                 # we only support the empty string '' (match whole URI)
 340                 die "unsupported fragmentDelimiter '$fd'"
 341                     if $fd ne '';
 342
 343                 $stack = [ join ('/', @$stack) ] if scalar(@$stack) > 1;
 344             }
 345             $path_lookup = $method_path_lookup->{$class};
 346         }
 347     }
 348
 349     return undef if !$path_lookup;
 350
 351     return ($class, $path_lookup);
 352 }
 353
 354 sub find_handler {
 355     my ($class, $method, $path, $uri_param, $pathmatchref) = @_;
 356
 357     my $stack = [ grep { length($_) > 0 }  split('\/+' , $path)]; # skip empty fragments
 358
 359     my ($handler_class, $path_info);
 360     eval {
 361         ($handler_class, $path_info) = $class->map_path_to_methods($stack, $uri_param, $pathmatchref);
 362     };
 363     my $err = $@;
 364     syslog('err', $err) if $err;
 365
 366     return undef if !($handler_class && $path_info);
 367
 368     my $method_info = $path_info->{$method};
 369
 370     return undef if !$method_info;
 371
 372     return ($handler_class, $method_info);
 373 }
 374
 375 sub handle {
 376     my ($self, $info, $param) = @_;
 377
 378     my $func = $info->{code};
 379
 380     if (!($info->{name} && $func)) {
 381         raise("Method lookup failed ('$info->{name}')\n",
 382               code => HTTP_INTERNAL_SERVER_ERROR);
 383     }
 384
 385     if (my $schema = $info->{parameters}) {
 386         # warn "validate ". Dumper($param}) . "\n" . Dumper($schema);
 387         PVE::JSONSchema::validate($param, $schema);
 388         # untaint data (already validated)
 389         my $extra = delete $param->{'extra-args'};
 390         while (my ($key, $val) = each %$param) {
 391             ($param->{$key}) = $val =~ /^(.*)$/s;
 392         }
 393         $param->{'extra-args'} = [map { /^(.*)$/ } @$extra] if $extra;
 394     }
 395
 396     my $result = &$func($param);
 397
 398     # todo: this is only to be safe - disable?
 399     if (my $schema = $info->{returns}) {
 400         PVE::JSONSchema::validate($result, $schema, "Result verification failed\n");
 401     }
 402
 403     return $result;
 404 }
 405
 406 # format option, display type and description
 407 # $name: option name
 408 # $display_name: for example "-$name" of "<$name>", pass undef to use "$name:"
 409 # $phash: json schema property hash
 410 # $format: 'asciidoc', 'pod' or 'text'
 411 # $style: 'config', 'arg' or 'fixed'
 412 my $get_property_description = sub {
 413     my ($name, $style, $phash, $format, $hidepw) = @_;
 414
 415     my $res = '';
 416
 417     $format = 'asciidoc' if !defined($format);
 418
 419     my $descr = $phash->{description} || "no description available";
 420
 421     chomp $descr;
 422
 423     my $type = PVE::PodParser::schema_get_type_text($phash);
 424
 425     if ($hidepw && $name eq 'password') {
 426         $type = '';
 427     }
 428
 429     if ($format eq 'asciidoc') {
 430
 431         if ($style eq 'config') {
 432             $res .= "`$name`: ";
 433         } elsif ($style eq 'arg') {
 434             $res .= "`-$name` ";
 435         } elsif ($style eq 'fixed') {
 436             $res .= "`<$name>` ";
 437         } else {
 438             die "unknown style '$style'";
 439         }
 440
 441         $res .= "`$type` " if $type;
 442
 443         if (defined(my $dv = $phash->{default})) {
 444             $res .= "(default=`$dv`)";
 445         }
 446         $res .= "::\n\n";
 447
 448         my $wdescr = Text::Wrap::wrap('', '', ($descr));
 449         chomp $wdescr;
 450         $wdescr =~ s/^$/+/mg;
 451
 452         $res .= $wdescr . "\n";
 453
 454         if (my $req = $phash->{requires}) {
 455             my $tmp .= ref($req) ? join(', ', @$req) : $req;
 456             $res .= "+\nNOTE: Requires option(s): `$tmp`\n";
 457         }
 458         $res .= "\n";
 459
 460     } elsif ($format eq 'pod' || $format eq 'text') {
 461
 462         my $defaulttxt = '';
 463         if (defined(my $dv = $phash->{default})) {
 464             $defaulttxt = "   (default=$dv)";
 465         }
 466
 467         my $display_name;
 468         if ($style eq 'config') {
 469             $display_name = "$name:";
 470         } elsif ($style eq 'arg') {
 471             $display_name = "-$name";
 472         } elsif ($style eq 'fixed') {
 473             $display_name = "<$name>";
 474         } else {
 475             die "unknown style '$style'";
 476         }
 477
 478         my $tmp = sprintf "  %-10s %s$defaulttxt\n", $display_name, "$type";
 479         my $indend = "             ";
 480
 481         $res .= Text::Wrap::wrap('', $indend, ($tmp));
 482         $res .= "\n",
 483         $res .= Text::Wrap::wrap($indend, $indend, ($descr)) . "\n\n";
 484
 485         if (my $req = $phash->{requires}) {
 486             my $tmp = "Requires option(s): ";
 487             $tmp .= ref($req) ? join(', ', @$req) : $req;
 488             $res .= Text::Wrap::wrap($indend, $indend, ($tmp)). "\n\n";
 489         }
 490
 491     } else {
 492         die "unknown format '$format'";
 493     }
 494
 495     return $res;
 496 };
 497
 498 # generate usage information for command line tools
 499 #
 500 # $name        ... the name of the method
 501 # $prefix      ... usually something like "$exename $cmd" ('pvesm add')
 502 # $arg_param   ... list of parameters we want to get as ordered arguments
 503 #                  on the command line (or single parameter name for lists)
 504 # $fixed_param ... do not generate and info about those parameters
 505 # $format:
 506 #   'long'     ... default (list all options)
 507 #   'short'    ... command line only (one line)
 508 #   'full'     ... also include description
 509 #   'asciidoc' ... generate asciidoc for man pages (like 'full')
 510 # $hidepw      ... hide password option (use this if you provide a read passwork callback)
 511 sub usage_str {
 512     my ($self, $name, $prefix, $arg_param, $fixed_param, $format, $hidepw) = @_;
 513
 514     $format = 'long' if !$format;
 515
 516     my $info = $self->map_method_by_name($name);
 517     my $schema = $info->{parameters};
 518     my $prop = $schema->{properties};
 519
 520     my $out = '';
 521
 522     my $arg_hash = {};
 523
 524     my $args = '';
 525
 526     $arg_param = [ $arg_param ] if $arg_param && !ref($arg_param);
 527
 528     foreach my $p (@$arg_param) {
 529         next if !$prop->{$p}; # just to be sure
 530         my $pd = $prop->{$p};
 531
 532         $arg_hash->{$p} = 1;
 533         $args .= " " if $args;
 534         if ($pd->{format} && $pd->{format} =~ m/-list/) {
 535             $args .= "{<$p>}";
 536         } else {
 537             $args .= $pd->{optional} ? "[<$p>]" : "<$p>";
 538         }
 539     }
 540
 541     my $argdescr = '';
 542     foreach my $k (@$arg_param) {
 543         next if defined($fixed_param->{$k}); # just to be sure
 544         next if !$prop->{$k}; # just to be sure
 545         $argdescr .= &$get_property_description($k, 'fixed', $prop->{$k}, 'text', 0);
 546     }
 547
 548     my $idx_param = {}; # -vlan\d+ -scsi\d+
 549
 550     my $opts = '';
 551     foreach my $k (sort keys %$prop) {
 552         next if $arg_hash->{$k};
 553         next if defined($fixed_param->{$k});
 554
 555         my $type = $prop->{$k}->{type} || 'string';
 556
 557         next if $hidepw && ($k eq 'password') && !$prop->{$k}->{optional};
 558
 559         my $base = $k;
 560         if ($k =~ m/^([a-z]+)(\d+)$/) {
 561             my $name = $1;
 562             next if $idx_param->{$name};
 563             $idx_param->{$name} = 1;
 564             $base = "${name}[n]";
 565         }
 566
 567         $opts .= &$get_property_description($base, 'arg', $prop->{$k}, 'text', $hidepw);
 568
 569         if (!$prop->{$k}->{optional}) {
 570             $args .= " " if $args;
 571             $args .= "-$base <$type>"
 572         }
 573     }
 574
 575     if ($format eq 'asciidoc') {
 576         $out .= "*${prefix}*";
 577         $out .= " `$args`" if $args;
 578         $out .= $opts ? " `[OPTIONS]`\n" : "\n";
 579     } else {
 580         $out .= "USAGE: " if $format ne 'short';
 581         $out .= "$prefix $args";
 582         $out .= $opts ? " [OPTIONS]\n" : "\n";
 583     }
 584
 585     return $out if $format eq 'short';
 586
 587     if ($info->{description}) {
 588         if ($format eq 'asciidoc') {
 589             my $desc = Text::Wrap::wrap('', '', ($info->{description}));
 590             $out .= "\n$desc\n\n";
 591         } elsif ($format eq 'full') {
 592             my $desc = Text::Wrap::wrap('  ', '  ', ($info->{description}));
 593             $out .= "\n$desc\n\n";
 594         }
 595     }
 596
 597     $out .= $argdescr if $argdescr;
 598
 599     $out .= $opts if $opts;
 600
 601     return $out;
 602 }
 603
 604 # generate docs from JSON schema properties
 605 sub dump_properties {
 606     my ($prop, $format, $style, $filterFn) = @_;
 607
 608     my $raw = '';
 609
 610     $style //= 'config';
 611
 612     my $idx_param = {}; # -vlan\d+ -scsi\d+
 613
 614     foreach my $k (sort keys %$prop) {
 615         my $phash = $prop->{$k};
 616
 617         next if defined($filterFn) && &$filterFn($k, $phash);
 618
 619         my $type = $phash->{type} || 'string';
 620
 621         my $base = $k;
 622         if ($k =~ m/^([a-z]+)(\d+)$/) {
 623             my $name = $1;
 624             next if $idx_param->{$name};
 625             $idx_param->{$name} = 1;
 626             $base = "${name}[n]";
 627         }
 628
 629         $raw .= &$get_property_description($base, $style, $phash, $format, 0);
 630     }
 631     return $raw;
 632 }
 633
 634 sub cli_handler {
 635     my ($self, $prefix, $name, $args, $arg_param, $fixed_param, $pwcallback) = @_;
 636
 637     my $info = $self->map_method_by_name($name);
 638
 639     my $res;
 640     eval {
 641         my $param = PVE::JSONSchema::get_options($info->{parameters}, $args, $arg_param, $fixed_param, $pwcallback);
 642         $res = $self->handle($info, $param);
 643     };
 644     if (my $err = $@) {
 645         my $ec = ref($err);
 646
 647         die $err if !$ec || $ec ne "PVE::Exception" || !$err->is_param_exc();
 648
 649         $err->{usage} = $self->usage_str($name, $prefix, $arg_param, $fixed_param, 'short', $pwcallback);
 650
 651         die $err;
 652     }
 653
 654     return $res;
 655 }
 656
 657 # utility methods
 658 # note: this modifies the original hash by adding the id property
 659 sub hash_to_array {
 660     my ($hash, $idprop) = @_;
 661
 662     my $res = [];
 663     return $res if !$hash;
 664
 665     foreach my $k (keys %$hash) {
 666         $hash->{$k}->{$idprop} = $k;
 667         push @$res, $hash->{$k};
 668     }
 669
 670     return $res;
 671 }
 672
 673 1;