src/PVE/SysFSTools.pm

   1 package PVE::SysFSTools;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7
   8 use PVE::Tools qw(file_read_firstline dir_glob_foreach);
   9
  10 my $pcisysfs = "/sys/bus/pci";
  11 my $domainregex = "[a-f0-9]{4,}";
  12 my $pciregex = "($domainregex):([a-f0-9]{2}):([a-f0-9]{2})\.([a-f0-9])";
  13
  14 my $parse_pci_ids = sub {
  15     my $ids = {};
  16
  17     open(my $fh, '<', "/usr/share/misc/pci.ids")
  18         or return $ids;
  19
  20     my $curvendor;
  21     my $curdevice;
  22     while (my $line = <$fh>) {
  23         if ($line =~ m/^([0-9a-fA-F]{4})\s+(.*)$/) {
  24             $curvendor = ($ids->{"0x$1"} = {});
  25             $curvendor->{name} = $2;
  26         } elsif ($line =~ m/^\t([0-9a-fA-F]{4})\s+(.*)$/) {
  27             $curdevice = ($curvendor->{devices}->{"0x$1"} = {});
  28             $curdevice->{name} = $2;
  29         } elsif ($line =~ m/^\t\t([0-9a-fA-F]{4}) ([0-9a-fA-F]{4})\s+(.*)$/) {
  30             $curdevice->{subs}->{"0x$1"}->{"0x$2"} = $3;
  31         }
  32     }
  33
  34     return $ids;
  35 };
  36
  37 my sub normalize_pci_id {
  38     my ($id) = @_;
  39     $id = "0000:$id" if $id !~ m/^${domainregex}:/;
  40     return $id;
  41 };
  42
  43 # returns a list of pci devices
  44 #
  45 # filter is either a string (then it tries to match to the id)
  46 # or a sub ref (then it adds the device if the sub returns truthy)
  47 #
  48 # verbose also returns iommu groups, subvendor/device and the
  49 # human readable names from /usr/share/misc/pci.ids
  50 #
  51 # return format:
  52 # [
  53 #     {
  54 #         id => '00:00.0',
  55 #         vendor => '0xabab',
  56 #         device => '0xefef',
  57 #         class => '0x012345',
  58 #
  59 #         # optional
  60 #         iommugroup => '14',
  61 #         mdev => 1,
  62 #         vendor_name => 'Foo Inc.',
  63 #         device_name => 'Bar 9000AF',
  64 #         subsystem_vendor => '0xacac',
  65 #         subsystem_device => '0xfefe',
  66 #         subsystem_vendor_name => 'Foo Europe GmbH',
  67 #         subsystem_device_name => 'Bar 9001AF OC',
  68 #     },
  69 #     ...
  70 # ]
  71 #
  72 sub lspci {
  73     my ($filter, $verbose) = @_;
  74
  75     my $devices = [];
  76     my $ids = {};
  77     if ($verbose) {
  78         $ids = $parse_pci_ids->();
  79     }
  80
  81     dir_glob_foreach("$pcisysfs/devices", $pciregex, sub {
  82         my ($fullid, $domain, $bus, $slot, $function) = @_;
  83         my $id = "$domain:$bus:$slot.$function";
  84
  85         if (defined($filter) && !ref($filter) && $id !~ m/^(0000:)?\Q$filter\E/) {
  86             return; # filter ids early
  87         }
  88
  89         my $devdir = "$pcisysfs/devices/$fullid";
  90
  91         my $vendor = file_read_firstline("$devdir/vendor");
  92         my $device = file_read_firstline("$devdir/device");
  93         my $class = file_read_firstline("$devdir/class");
  94
  95         my $res = {
  96             id => $id,
  97             vendor => $vendor,
  98             device => $device,
  99             class => $class,
 100         };
 101
 102         if (defined($filter) && ref($filter) eq 'CODE' && !$filter->($res)) {
 103             return;
 104         }
 105
 106         if ($verbose) {
 107             $res->{iommugroup} = -1;
 108             if (-e "$devdir/iommu_group") {
 109                 my ($iommugroup) = (readlink("$devdir/iommu_group") =~ m/\/(\d+)$/);
 110                 $res->{iommugroup} = int($iommugroup);
 111             }
 112
 113             if (-d "$devdir/mdev_supported_types") {
 114                 $res->{mdev} = 1;
 115             }
 116
 117             my $device_hash = $ids->{$vendor}->{devices}->{$device} // {};
 118
 119             my $sub_vendor = file_read_firstline("$devdir/subsystem_vendor");
 120             my $sub_device = file_read_firstline("$devdir/subsystem_device");
 121
 122             my $vendor_name = $ids->{$vendor}->{name};
 123             my $device_name = $device_hash->{name};
 124             my $sub_vendor_name = $ids->{$sub_vendor}->{name};
 125             my $sub_device_name = $device_hash->{subs}->{$sub_vendor}->{$sub_device};
 126
 127             $res->{vendor_name} = $vendor_name if defined($vendor_name);
 128             $res->{device_name} = $device_name if defined($device_name);
 129             $res->{subsystem_vendor} = $sub_vendor if defined($sub_vendor);
 130             $res->{subsystem_device} = $sub_device if defined($sub_device);
 131             $res->{subsystem_vendor_name} = $sub_vendor_name if defined($sub_vendor_name);
 132             $res->{subsystem_device_name} = $sub_device_name if defined($sub_device_name);
 133         }
 134
 135         push @$devices, $res;
 136     });
 137
 138     # Entries should be sorted by ids
 139     $devices = [ sort { $a->{id} cmp $b->{id} } @$devices ];
 140
 141     return $devices;
 142 }
 143
 144 #
 145 # return format:
 146 # [
 147 #     {
 148 #         type => 'FooType_1',
 149 #         description => "a longer description with custom format\nand newlines",
 150 #         available => 5,
 151 #     },
 152 #     ...
 153 # ]
 154 #
 155 sub get_mdev_types {
 156     my ($id) = @_;
 157
 158     $id = normalize_pci_id($id);
 159
 160     my $types = [];
 161
 162     my $mdev_path = "$pcisysfs/devices/$id/mdev_supported_types";
 163     if (!-d $mdev_path) {
 164         return $types;
 165     }
 166
 167     dir_glob_foreach($mdev_path, '[^\.].*', sub {
 168         my ($type) = @_;
 169
 170         my $type_path = "$mdev_path/$type";
 171
 172         my $available = int(file_read_firstline("$type_path/available_instances"));
 173         my $description = PVE::Tools::file_get_contents("$type_path/description");
 174
 175         my $entry = {
 176             type => $type,
 177             description => $description,
 178             available => $available,
 179         };
 180
 181         my $name = file_read_firstline("$type_path/name");
 182         $entry->{name} = $name if defined($name);
 183
 184         push @$types, $entry;
 185     });
 186
 187     return $types;
 188 }
 189
 190 sub check_iommu_support{
 191     # we have IOMMU support if /sys/class/iommu/ is populated
 192     return PVE::Tools::dir_glob_regex('/sys/class/iommu/', "[^\.].*");
 193 }
 194
 195 sub file_write {
 196     my ($filename, $buf) = @_;
 197
 198     my $fh = IO::File->new($filename, "w");
 199     return undef if !$fh;
 200
 201     my $res = print $fh $buf;
 202
 203     $fh->close();
 204
 205     return $res;
 206 }
 207
 208 sub pci_device_info {
 209     my ($name, $verbose) = @_;
 210
 211     my $res;
 212
 213     return undef if $name !~ m/^${pciregex}$/;
 214     my ($domain, $bus, $slot, $func) = ($1, $2, $3, $4);
 215
 216     my $devdir = "$pcisysfs/devices/$name";
 217
 218     my $irq = file_read_firstline("$devdir/irq");
 219     return undef if !defined($irq) || $irq !~ m/^\d+$/;
 220
 221     my $vendor = file_read_firstline("$devdir/vendor");
 222     return undef if !defined($vendor) || $vendor !~ s/^0x//;
 223
 224     my $product = file_read_firstline("$devdir/device");
 225     return undef if !defined($product) || $product !~ s/^0x//;
 226
 227     $res = {
 228         name => $name,
 229         vendor => $vendor,
 230         device => $product,
 231         domain => $domain,
 232         bus => $bus,
 233         slot => $slot,
 234         func => $func,
 235         irq => $irq,
 236         has_fl_reset => -f "$pcisysfs/devices/$name/reset" || 0,
 237     };
 238
 239     if ($verbose) {
 240         my $sub_vendor = file_read_firstline("$devdir/subsystem_vendor");
 241         $sub_vendor =~ s/^0x// if defined($sub_vendor);
 242         my $sub_device = file_read_firstline("$devdir/subsystem_device");
 243         $sub_device =~ s/^0x// if defined($sub_device);
 244
 245         $res->{subsystem_vendor} = $sub_vendor if defined($sub_vendor);
 246         $res->{subsystem_device} = $sub_device if defined($sub_device);
 247
 248         if (-e "$devdir/iommu_group") {
 249             my ($iommugroup) = (readlink("$devdir/iommu_group") =~ m/\/(\d+)$/);
 250             $res->{iommugroup} = int($iommugroup);
 251         }
 252
 253         if (-d "$devdir/mdev_supported_types") {
 254             $res->{mdev} = 1;
 255         }
 256     }
 257
 258     return $res;
 259 }
 260
 261 sub pci_dev_reset {
 262     my ($dev) = @_;
 263
 264     my $name = $dev->{name};
 265
 266     my $fn = "$pcisysfs/devices/$name/reset";
 267
 268     return file_write($fn, "1");
 269 }
 270
 271 sub pci_dev_bind_to_vfio {
 272     my ($dev) = @_;
 273
 274     my $name = $dev->{name};
 275
 276     my $vfio_basedir = "$pcisysfs/drivers/vfio-pci";
 277
 278     if (!-d $vfio_basedir) {
 279         system("/sbin/modprobe vfio-pci >/dev/null 2>/dev/null");
 280     }
 281     die "Cannot find vfio-pci module!\n" if !-d $vfio_basedir;
 282
 283     my $testdir = "$vfio_basedir/$name";
 284     return 1 if -d $testdir;
 285
 286     my $data = "$dev->{vendor} $dev->{device}";
 287     return undef if !file_write("$vfio_basedir/new_id", $data);
 288
 289     my $fn = "$pcisysfs/devices/$name/driver/unbind";
 290     if (!file_write($fn, $name)) {
 291         return undef if -f $fn;
 292     }
 293
 294     $fn = "$vfio_basedir/bind";
 295     if (! -d $testdir) {
 296         return undef if !file_write($fn, $name);
 297     }
 298
 299     return -d $testdir;
 300 }
 301
 302 sub pci_dev_group_bind_to_vfio {
 303     my ($pciid) = @_;
 304
 305     my $vfio_basedir = "$pcisysfs/drivers/vfio-pci";
 306
 307     if (!-d $vfio_basedir) {
 308         system("/sbin/modprobe vfio-pci >/dev/null 2>/dev/null");
 309     }
 310     die "Cannot find vfio-pci module!\n" if !-d $vfio_basedir;
 311
 312     $pciid = normalize_pci_id($pciid);
 313
 314     # get IOMMU group devices
 315     opendir(my $D, "$pcisysfs/devices/$pciid/iommu_group/devices/") || die "Cannot open iommu_group: $!\n";
 316     my @devs = grep /^${domainregex}:/, readdir($D);
 317     closedir($D);
 318
 319     foreach my $pciid (@devs) {
 320         $pciid =~ m/^([:\.0-9a-f]+)$/ or die "PCI ID $pciid not valid!\n";
 321
 322         # PCI bridges, switches or root-ports aren't supported and all have a pci_bus dir we can test
 323         next if (-e "$pcisysfs/devices/$pciid/pci_bus");
 324
 325         my $info = pci_device_info($1);
 326         pci_dev_bind_to_vfio($info) || die "Cannot bind $pciid to vfio\n";
 327     }
 328
 329     return 1;
 330 }
 331
 332 sub pci_create_mdev_device {
 333     my ($pciid, $uuid, $type) = @_;
 334
 335     $pciid = normalize_pci_id($pciid);
 336
 337     my $basedir = "$pcisysfs/devices/$pciid";
 338     my $mdev_dir = "$basedir/mdev_supported_types";
 339
 340     die "pci device '$pciid' does not support mediated devices \n"
 341         if !-d $mdev_dir;
 342
 343     die "pci device '$pciid' has no type '$type'\n"
 344         if !-d "$mdev_dir/$type";
 345
 346     if (-d "$basedir/$uuid") {
 347         # it already exists, checking type
 348         my $typelink = readlink("$basedir/$uuid/mdev_type");
 349         my ($existingtype) = $typelink =~ m|/([^/]+)$|;
 350         die "mdev instance '$uuid' already exits, but type is not '$type'\n"
 351             if $type ne $existingtype;
 352
 353         # instance exists, so use it but warn the user
 354         warn "mdev instance '$uuid' already existed, using it.\n";
 355         return undef;
 356     }
 357
 358     my $instances = file_read_firstline("$mdev_dir/$type/available_instances");
 359     my ($avail) = $instances =~ m/^(\d+)$/;
 360     die "pci device '$pciid' has no available instances of '$type'\n"
 361         if $avail < 1;
 362
 363     die "could not create 'type' for pci devices '$pciid'\n"
 364         if !file_write("$mdev_dir/$type/create", $uuid);
 365
 366     return undef;
 367 }
 368
 369 # encode the hostpci index and vmid into the uuid
 370 sub generate_mdev_uuid {
 371     my ($vmid, $index) = @_;
 372
 373     my $string = sprintf("%08d-0000-0000-0000-%012d", $index, $vmid);
 374
 375     return $string;
 376 }
 377
 378 # idea is from usbutils package (/usr/bin/usb-devices) script
 379 sub __scan_usb_device {
 380     my ($res, $devpath, $parent, $level) = @_;
 381
 382     return if ! -d $devpath;
 383     return if $level && $devpath !~ m/^.*[-.](\d+)$/;
 384     my $port = $level ? int($1 - 1) : 0;
 385
 386     my $busnum = int(file_read_firstline("$devpath/busnum"));
 387     my $devnum = int(file_read_firstline("$devpath/devnum"));
 388
 389     my $d = {
 390         port => $port,
 391         level => $level,
 392         busnum => $busnum,
 393         devnum => $devnum,
 394         speed => file_read_firstline("$devpath/speed"),
 395         class => hex(file_read_firstline("$devpath/bDeviceClass")),
 396         vendid => file_read_firstline("$devpath/idVendor"),
 397         prodid => file_read_firstline("$devpath/idProduct"),
 398     };
 399
 400     if ($level) {
 401         my $usbpath = $devpath;
 402         $usbpath =~ s|^.*/\d+\-||;
 403         $d->{usbpath} = $usbpath;
 404     }
 405
 406     my $product = file_read_firstline("$devpath/product");
 407     $d->{product} = $product if $product;
 408
 409     my $manu = file_read_firstline("$devpath/manufacturer");
 410     $d->{manufacturer} = $manu if $manu;
 411
 412     my $serial => file_read_firstline("$devpath/serial");
 413     $d->{serial} = $serial if $serial;
 414
 415     push @$res, $d;
 416
 417     foreach my $subdev (<$devpath/$busnum-*>) {
 418         next if $subdev !~ m|/$busnum-[0-9]+(\.[0-9]+)*$|;
 419         __scan_usb_device($res, $subdev, $devnum, $level + 1);
 420     }
 421
 422 };
 423
 424 sub scan_usb {
 425
 426     my $devlist = [];
 427
 428     foreach my $device (</sys/bus/usb/devices/usb*>) {
 429         __scan_usb_device($devlist, $device, 0, 0);
 430     }
 431
 432     return $devlist;
 433 }
 434
 435 1;