src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Scalar::Util 'weaken';
  28 use PVE::Syscall;
  29
  30 # avoid warning when parsing long hex values with hex()
  31 no warnings 'portable'; # Support for 64-bit ints required
  32
  33 our @EXPORT_OK = qw(
  34 $IPV6RE
  35 $IPV4RE
  36 lock_file
  37 lock_file_full
  38 run_command
  39 file_set_contents
  40 file_get_contents
  41 file_read_firstline
  42 dir_glob_regex
  43 dir_glob_foreach
  44 split_list
  45 template_replace
  46 safe_print
  47 trim
  48 extract_param
  49 file_copy
  50 O_PATH
  51 O_TMPFILE
  52 );
  53
  54 my $pvelogdir = "/var/log/pve";
  55 my $pvetaskdir = "$pvelogdir/tasks";
  56
  57 mkdir $pvelogdir;
  58 mkdir $pvetaskdir;
  59
  60 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  61 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  62 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  63 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  64
  65 our $IPV6RE = "(?:" .
  66     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  67     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  68     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  69     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  70     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  71     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  72     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  73     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  74     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  75
  76 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  77
  78 use constant {CLONE_NEWNS   => 0x00020000,
  79               CLONE_NEWUTS  => 0x04000000,
  80               CLONE_NEWIPC  => 0x08000000,
  81               CLONE_NEWUSER => 0x10000000,
  82               CLONE_NEWPID  => 0x20000000,
  83               CLONE_NEWNET  => 0x40000000};
  84
  85 use constant {O_PATH    => 0x00200000,
  86               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  87
  88 sub run_with_timeout {
  89     my ($timeout, $code, @param) = @_;
  90
  91     die "got timeout\n" if $timeout <= 0;
  92
  93     my $prev_alarm = alarm 0; # suspend outer alarm early
  94
  95     my $sigcount = 0;
  96
  97     my $res;
  98
  99     eval {
 100         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 101         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 102         local $SIG{__DIE__};   # see SA bug 4631
 103
 104         alarm($timeout);
 105
 106         eval { $res = &$code(@param); };
 107
 108         alarm(0); # avoid race conditions
 109
 110         die $@ if $@;
 111     };
 112
 113     my $err = $@;
 114
 115     alarm $prev_alarm;
 116
 117     # this shouldn't happen anymore?
 118     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 119
 120     die $err if $err;
 121
 122     return $res;
 123 }
 124
 125 # flock: we use one file handle per process, so lock file
 126 # can be nested multiple times and succeeds for the same process.
 127 #
 128 # Since this is the only way we lock now and we don't have the old
 129 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 130 # count how deep we're nesting. Therefore this hash now stores a weak reference
 131 # to a boolean telling us whether we already have a lock.
 132
 133 my $lock_handles =  {};
 134
 135 sub lock_file_full {
 136     my ($filename, $timeout, $shared, $code, @param) = @_;
 137
 138     $timeout = 10 if !$timeout;
 139
 140     my $mode = $shared ? LOCK_SH : LOCK_EX;
 141
 142     my $lockhash = ($lock_handles->{$$} //= {});
 143
 144     # Returns a locked file handle.
 145     my $get_locked_file = sub {
 146         my $fh = IO::File->new(">>$filename")
 147             or die "can't open file - $!\n";
 148
 149         if (!flock($fh, $mode|LOCK_NB)) {
 150             print STDERR "trying to acquire lock...\n";
 151             my $success;
 152             while(1) {
 153                 $success = flock($fh, $mode);
 154                 # try again on EINTR (see bug #273)
 155                 if ($success || ($! != EINTR)) {
 156                     last;
 157                 }
 158             }
 159             if (!$success) {
 160                 print STDERR " failed\n";
 161                 die "can't acquire lock '$filename' - $!\n";
 162             }
 163             print STDERR " OK\n";
 164         }
 165
 166         return $fh;
 167     };
 168
 169     my $res;
 170     my $checkptr = $lockhash->{$filename};
 171     my $check = 0; # This must not go out of scope before running the code.
 172     my $local_fh; # This must stay local
 173     if (!$checkptr || !$$checkptr) {
 174         # We cannot create a weak reference in a single atomic step, so we first
 175         # create a false-value, then create a reference to it, then weaken it,
 176         # and after successfully locking the file we change the boolean value.
 177         #
 178         # The reason for this is that if an outer SIGALRM throws an exception
 179         # between creating the reference and weakening it, a subsequent call to
 180         # lock_file_full() will see a leftover full reference to a valid
 181         # variable. This variable must be 0 in order for said call to attempt to
 182         # lock the file anew.
 183         #
 184         # An externally triggered exception elsewhere in the code will cause the
 185         # weak reference to become 'undef', and since the file handle is only
 186         # stored in the local scope in $local_fh, the file will be closed by
 187         # perl's cleanup routines as well.
 188         #
 189         # This still assumes that an IO::File handle can properly deal with such
 190         # exceptions thrown during its own destruction, but that's up to perls
 191         # guts now.
 192         $lockhash->{$filename} = \$check;
 193         weaken $lockhash->{$filename};
 194         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 195         if ($@) {
 196             $@ = "can't lock file '$filename' - $@";
 197             return undef;
 198         }
 199         $check = 1;
 200     }
 201     $res = eval { &$code(@param); };
 202     return undef if $@;
 203     return $res;
 204 }
 205
 206
 207 sub lock_file {
 208     my ($filename, $timeout, $code, @param) = @_;
 209
 210     return lock_file_full($filename, $timeout, 0, $code, @param);
 211 }
 212
 213 sub file_set_contents {
 214     my ($filename, $data, $perm)  = @_;
 215
 216     $perm = 0644 if !defined($perm);
 217
 218     my $tmpname = "$filename.tmp.$$";
 219
 220     eval {
 221         my ($fh, $tries) = (undef, 0);
 222         while (!$fh && $tries++ < 3) {
 223             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 224             if (!$fh && $! == EEXIST) {
 225                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 226             }
 227         }
 228         die "unable to open file '$tmpname' - $!\n" if !$fh;
 229         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 230         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 231     };
 232     my $err = $@;
 233
 234     if ($err) {
 235         unlink $tmpname;
 236         die $err;
 237     }
 238
 239     if (!rename($tmpname, $filename)) {
 240         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 241         unlink $tmpname;
 242         die $msg;
 243     }
 244 }
 245
 246 sub file_get_contents {
 247     my ($filename, $max) = @_;
 248
 249     my $fh = IO::File->new($filename, "r") ||
 250         die "can't open '$filename' - $!\n";
 251
 252     my $content = safe_read_from($fh, $max, 0, $filename);
 253
 254     close $fh;
 255
 256     return $content;
 257 }
 258
 259 sub file_copy {
 260     my ($filename, $dst, $max, $perm) = @_;
 261
 262     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 263 }
 264
 265 sub file_read_firstline {
 266     my ($filename) = @_;
 267
 268     my $fh = IO::File->new ($filename, "r");
 269     return undef if !$fh;
 270     my $res = <$fh>;
 271     chomp $res if $res;
 272     $fh->close;
 273     return $res;
 274 }
 275
 276 sub safe_read_from {
 277     my ($fh, $max, $oneline, $filename) = @_;
 278
 279     $max = 32768 if !$max;
 280
 281     my $subject = defined($filename) ? "file '$filename'" : 'input';
 282
 283     my $br = 0;
 284     my $input = '';
 285     my $count;
 286     while ($count = sysread($fh, $input, 8192, $br)) {
 287         $br += $count;
 288         die "$subject too long - aborting\n" if $br > $max;
 289         if ($oneline && $input =~ m/^(.*)\n/) {
 290             $input = $1;
 291             last;
 292         }
 293     }
 294     die "unable to read $subject - $!\n" if !defined($count);
 295
 296     return $input;
 297 }
 298
 299 # The $cmd parameter can be:
 300 #  -) a string
 301 #    This is generally executed by passing it to the shell with the -c option.
 302 #    However, it can be executed in one of two ways, depending on whether
 303 #    there's a pipe involved:
 304 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 305 #          set -o pipefail &&
 306 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 307 #      (Note that this may result in two different syntax requirements!)
 308 #      FIXME?
 309 #  -) an array of arguments (strings)
 310 #    Will be executed without interference from a shell. (Parameters are passed
 311 #    as is, no escape sequences of strings will be touched.)
 312 #  -) an array of arrays
 313 #    Each array represents a command, and each command's output is piped into
 314 #    the following command's standard input.
 315 #    For this a shell command string is created with pipe symbols between each
 316 #    command.
 317 #    Each command is a list of strings meant to end up in the final command
 318 #    unchanged. In order to achieve this, every argument is shell-quoted.
 319 #    Quoting can be disabled for a particular argument by turning it into a
 320 #    reference, this allows inserting arbitrary shell options.
 321 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 322 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 323 #    will literally print: hello >/dev/null
 324 sub run_command {
 325     my ($cmd, %param) = @_;
 326
 327     my $old_umask;
 328     my $cmdstr;
 329
 330     if (my $ref = ref($cmd)) {
 331         if (ref($cmd->[0])) {
 332             $cmdstr = 'set -o pipefail && ';
 333             my $pipe = '';
 334             foreach my $command (@$cmd) {
 335                 # concatenate quoted parameters
 336                 # strings which are passed by reference are NOT shell quoted
 337                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 338                 $pipe = ' | ';
 339             }
 340             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 341         } else {
 342             $cmdstr = cmd2string($cmd);
 343         }
 344     } else {
 345         $cmdstr = $cmd;
 346         if ($cmd =~ m/\|/) {
 347             # see 'man bash' for option pipefail
 348             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 349         } else {
 350             $cmd = [ $cmd ];
 351         }
 352     }
 353
 354     my $errmsg;
 355     my $laststderr;
 356     my $timeout;
 357     my $oldtimeout;
 358     my $pid;
 359     my $exitcode = -1;
 360
 361     my $outfunc;
 362     my $errfunc;
 363     my $logfunc;
 364     my $input;
 365     my $output;
 366     my $afterfork;
 367     my $noerr;
 368     my $keeplocale;
 369     my $quiet;
 370
 371     eval {
 372
 373         foreach my $p (keys %param) {
 374             if ($p eq 'timeout') {
 375                 $timeout = $param{$p};
 376             } elsif ($p eq 'umask') {
 377                 $old_umask = umask($param{$p});
 378             } elsif ($p eq 'errmsg') {
 379                 $errmsg = $param{$p};
 380             } elsif ($p eq 'input') {
 381                 $input = $param{$p};
 382             } elsif ($p eq 'output') {
 383                 $output = $param{$p};
 384             } elsif ($p eq 'outfunc') {
 385                 $outfunc = $param{$p};
 386             } elsif ($p eq 'errfunc') {
 387                 $errfunc = $param{$p};
 388             } elsif ($p eq 'logfunc') {
 389                 $logfunc = $param{$p};
 390             } elsif ($p eq 'afterfork') {
 391                 $afterfork = $param{$p};
 392             } elsif ($p eq 'noerr') {
 393                 $noerr = $param{$p};
 394             } elsif ($p eq 'keeplocale') {
 395                 $keeplocale = $param{$p};
 396             } elsif ($p eq 'quiet') {
 397                 $quiet = $param{$p};
 398             } else {
 399                 die "got unknown parameter '$p' for run_command\n";
 400             }
 401         }
 402
 403         if ($errmsg) {
 404             my $origerrfunc = $errfunc;
 405             $errfunc = sub {
 406                 if ($laststderr) {
 407                     if ($origerrfunc) {
 408                         &$origerrfunc("$laststderr\n");
 409                     } else {
 410                         print STDERR "$laststderr\n" if $laststderr;
 411                     }
 412                 }
 413                 $laststderr = shift;
 414             };
 415         }
 416
 417         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 418         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 419         my $error  = IO::File->new();
 420
 421         my $orig_pid = $$;
 422
 423         eval {
 424             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 425
 426             # suppress LVM warnings like: "File descriptor 3 left open";
 427             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 428
 429             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 430
 431             # if we pipe fron STDIN, open3 closes STDIN, so we we
 432             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 433             # as soon as we open a new file.
 434             # to avoid that we open /dev/null
 435             if (!ref($writer) && !defined(fileno(STDIN))) {
 436                 POSIX::close(0);
 437                 open(STDIN, "</dev/null");
 438             }
 439         };
 440
 441         my $err = $@;
 442
 443         # catch exec errors
 444         if ($orig_pid != $$) {
 445             warn "ERROR: $err";
 446             POSIX::_exit (1);
 447             kill ('KILL', $$);
 448         }
 449
 450         die $err if $err;
 451
 452         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 453         $oldtimeout = alarm($timeout) if $timeout;
 454
 455         &$afterfork() if $afterfork;
 456
 457         if (ref($writer)) {
 458             print $writer $input if defined $input;
 459             close $writer;
 460         }
 461
 462         my $select = new IO::Select;
 463         $select->add($reader) if ref($reader);
 464         $select->add($error);
 465
 466         my $outlog = '';
 467         my $errlog = '';
 468
 469         my $starttime = time();
 470
 471         while ($select->count) {
 472             my @handles = $select->can_read(1);
 473
 474             foreach my $h (@handles) {
 475                 my $buf = '';
 476                 my $count = sysread ($h, $buf, 4096);
 477                 if (!defined ($count)) {
 478                     my $err = $!;
 479                     kill (9, $pid);
 480                     waitpid ($pid, 0);
 481                     die $err;
 482                 }
 483                 $select->remove ($h) if !$count;
 484                 if ($h eq $reader) {
 485                     if ($outfunc || $logfunc) {
 486                         eval {
 487                             $outlog .= $buf;
 488                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 489                                 my $line = $1;
 490                                 &$outfunc($line) if $outfunc;
 491                                 &$logfunc($line) if $logfunc;
 492                             }
 493                         };
 494                         my $err = $@;
 495                         if ($err) {
 496                             kill (9, $pid);
 497                             waitpid ($pid, 0);
 498                             die $err;
 499                         }
 500                     } elsif (!$quiet) {
 501                         print $buf;
 502                         *STDOUT->flush();
 503                     }
 504                 } elsif ($h eq $error) {
 505                     if ($errfunc || $logfunc) {
 506                         eval {
 507                             $errlog .= $buf;
 508                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 509                                 my $line = $1;
 510                                 &$errfunc($line) if $errfunc;
 511                                 &$logfunc($line) if $logfunc;
 512                             }
 513                         };
 514                         my $err = $@;
 515                         if ($err) {
 516                             kill (9, $pid);
 517                             waitpid ($pid, 0);
 518                             die $err;
 519                         }
 520                     } elsif (!$quiet) {
 521                         print STDERR $buf;
 522                         *STDERR->flush();
 523                     }
 524                 }
 525             }
 526         }
 527
 528         &$outfunc($outlog) if $outfunc && $outlog;
 529         &$logfunc($outlog) if $logfunc && $outlog;
 530
 531         &$errfunc($errlog) if $errfunc && $errlog;
 532         &$logfunc($errlog) if $logfunc && $errlog;
 533
 534         waitpid ($pid, 0);
 535
 536         if ($? == -1) {
 537             die "failed to execute\n";
 538         } elsif (my $sig = ($? & 127)) {
 539             die "got signal $sig\n";
 540         } elsif ($exitcode = ($? >> 8)) {
 541             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 542                 if ($errmsg && $laststderr) {
 543                     my $lerr = $laststderr;
 544                     $laststderr = undef;
 545                     die "$lerr\n";
 546                 }
 547                 die "exit code $exitcode\n";
 548             }
 549         }
 550
 551         alarm(0);
 552     };
 553
 554     my $err = $@;
 555
 556     alarm(0);
 557
 558     if ($errmsg && $laststderr) {
 559         &$errfunc(undef); # flush laststderr
 560     }
 561
 562     umask ($old_umask) if defined($old_umask);
 563
 564     alarm($oldtimeout) if $oldtimeout;
 565
 566     if ($err) {
 567         if ($pid && ($err eq "got timeout\n")) {
 568             kill (9, $pid);
 569             waitpid ($pid, 0);
 570             die "command '$cmdstr' failed: $err";
 571         }
 572
 573         if ($errmsg) {
 574             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 575             die "$errmsg: $err";
 576         } elsif(!$noerr) {
 577             die "command '$cmdstr' failed: $err";
 578         }
 579     }
 580
 581     return $exitcode;
 582 }
 583
 584 # Run a command with a tcp socket as standard input.
 585 sub pipe_socket_to_command  {
 586     my ($cmd, $ip, $port) = @_;
 587
 588     my $params = {
 589         Listen => 1,
 590         ReuseAddr => 1,
 591         Proto => &Socket::IPPROTO_TCP,
 592         GetAddrInfoFlags => 0,
 593         LocalAddr => $ip,
 594         LocalPort => $port,
 595     };
 596     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 597
 598     print "$ip\n$port\n"; # tell remote where to connect
 599     *STDOUT->flush();
 600
 601     alarm 0;
 602     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 603     alarm 30;
 604     my $client = $socket->accept; # Wait for a client
 605     alarm 0;
 606     close($socket);
 607
 608     # We want that the command talks over the TCP socket and takes
 609     # ownership of it, so that when it closes it the connection is
 610     # terminated, so we need to be able to close the socket. So we
 611     # can't really use PVE::Tools::run_command().
 612     my $pid = fork() // die "fork failed: $!\n";
 613     if (!$pid) {
 614         POSIX::dup2(fileno($client), 0);
 615         POSIX::dup2(fileno($client), 1);
 616         close($client);
 617         exec {$cmd->[0]} @$cmd or do {
 618             warn "exec failed: $!\n";
 619             POSIX::_exit(1);
 620         };
 621     }
 622
 623     close($client);
 624     if (waitpid($pid, 0) != $pid) {
 625         kill(15 => $pid); # if we got interrupted terminate the child
 626         my $count = 0;
 627         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 628             usleep(100000);
 629             $count++;
 630             kill(9 => $pid), last if $count > 300; # 30 second timeout
 631         }
 632     }
 633     if (my $sig = ($? & 127)) {
 634         die "got signal $sig\n";
 635     } elsif (my $exitcode = ($? >> 8)) {
 636         die "exit code $exitcode\n";
 637     }
 638
 639     return undef;
 640 }
 641
 642 sub split_list {
 643     my $listtxt = shift || '';
 644
 645     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 646
 647     $listtxt =~ s/[,;]/ /g;
 648     $listtxt =~ s/^\s+//;
 649
 650     my @data = split (/\s+/, $listtxt);
 651
 652     return @data;
 653 }
 654
 655 sub trim {
 656     my $txt = shift;
 657
 658     return $txt if !defined($txt);
 659
 660     $txt =~ s/^\s+//;
 661     $txt =~ s/\s+$//;
 662
 663     return $txt;
 664 }
 665
 666 # simple uri templates like "/vms/{vmid}"
 667 sub template_replace {
 668     my ($tmpl, $data) = @_;
 669
 670     return $tmpl if !$tmpl;
 671
 672     my $res = '';
 673     while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) {
 674         $res .= $1 if $1;
 675         $res .= ($data->{$3} || '-') if $2;
 676     }
 677     return $res;
 678 }
 679
 680 sub safe_print {
 681     my ($filename, $fh, $data) = @_;
 682
 683     return if !$data;
 684
 685     my $res = print $fh $data;
 686
 687     die "write to '$filename' failed\n" if !$res;
 688 }
 689
 690 sub debmirrors {
 691
 692     return {
 693         'at' => 'ftp.at.debian.org',
 694         'au' => 'ftp.au.debian.org',
 695         'be' => 'ftp.be.debian.org',
 696         'bg' => 'ftp.bg.debian.org',
 697         'br' => 'ftp.br.debian.org',
 698         'ca' => 'ftp.ca.debian.org',
 699         'ch' => 'ftp.ch.debian.org',
 700         'cl' => 'ftp.cl.debian.org',
 701         'cz' => 'ftp.cz.debian.org',
 702         'de' => 'ftp.de.debian.org',
 703         'dk' => 'ftp.dk.debian.org',
 704         'ee' => 'ftp.ee.debian.org',
 705         'es' => 'ftp.es.debian.org',
 706         'fi' => 'ftp.fi.debian.org',
 707         'fr' => 'ftp.fr.debian.org',
 708         'gr' => 'ftp.gr.debian.org',
 709         'hk' => 'ftp.hk.debian.org',
 710         'hr' => 'ftp.hr.debian.org',
 711         'hu' => 'ftp.hu.debian.org',
 712         'ie' => 'ftp.ie.debian.org',
 713         'is' => 'ftp.is.debian.org',
 714         'it' => 'ftp.it.debian.org',
 715         'jp' => 'ftp.jp.debian.org',
 716         'kr' => 'ftp.kr.debian.org',
 717         'mx' => 'ftp.mx.debian.org',
 718         'nl' => 'ftp.nl.debian.org',
 719         'no' => 'ftp.no.debian.org',
 720         'nz' => 'ftp.nz.debian.org',
 721         'pl' => 'ftp.pl.debian.org',
 722         'pt' => 'ftp.pt.debian.org',
 723         'ro' => 'ftp.ro.debian.org',
 724         'ru' => 'ftp.ru.debian.org',
 725         'se' => 'ftp.se.debian.org',
 726         'si' => 'ftp.si.debian.org',
 727         'sk' => 'ftp.sk.debian.org',
 728         'tr' => 'ftp.tr.debian.org',
 729         'tw' => 'ftp.tw.debian.org',
 730         'gb' => 'ftp.uk.debian.org',
 731         'us' => 'ftp.us.debian.org',
 732     };
 733 }
 734
 735 my $keymaphash =  {
 736     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 737     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 738     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 739     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 740     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 741     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 742     #'et'     => [], # Ethopia or Estonia ??
 743     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 744     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 745     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 746     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 747     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 748     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 749     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 750     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 751     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 752     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 753     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 754     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 755     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 756     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 757     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 758     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 759     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 760     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 761     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 762     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 763     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know?
 764     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 765     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 766     #'th'     => [],
 767     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 768 };
 769
 770 my $kvmkeymaparray = [];
 771 foreach my $lc (sort keys %$keymaphash) {
 772     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 773 }
 774
 775 sub kvmkeymaps {
 776     return $keymaphash;
 777 }
 778
 779 sub kvmkeymaplist {
 780     return $kvmkeymaparray;
 781 }
 782
 783 sub extract_param {
 784     my ($param, $key) = @_;
 785
 786     my $res = $param->{$key};
 787     delete $param->{$key};
 788
 789     return $res;
 790 }
 791
 792 # Note: we use this to wait until vncterm/spiceterm is ready
 793 sub wait_for_vnc_port {
 794     my ($port, $family, $timeout) = @_;
 795
 796     $timeout = 5 if !$timeout;
 797     my $sleeptime = 0;
 798     my $starttime = [gettimeofday];
 799     my $elapsed;
 800
 801     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 802     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 803
 804     my $found;
 805     while (($elapsed = tv_interval($starttime)) < $timeout) {
 806         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 807         run_command($cmd, outfunc => sub {
 808             my $line = shift;
 809             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 810                 $found = 1 if ($port == $1);
 811             }
 812         });
 813         return 1 if $found;
 814         $sleeptime += 100000 if  $sleeptime < 1000000;
 815         usleep($sleeptime);
 816     }
 817
 818     die "Timeout while waiting for port '$port' to get ready!\n";
 819 }
 820
 821 sub next_unused_port {
 822     my ($range_start, $range_end, $family, $address) = @_;
 823
 824     # We use a file to register allocated ports.
 825     # Those registrations expires after $expiretime.
 826     # We use this to avoid race conditions between
 827     # allocation and use of ports.
 828
 829     my $filename = "/var/tmp/pve-reserved-ports";
 830
 831     my $code = sub {
 832
 833         my $expiretime = 5;
 834         my $ctime = time();
 835
 836         my $ports = {};
 837
 838         if (my $fh = IO::File->new ($filename, "r")) {
 839             while (my $line = <$fh>) {
 840                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 841                     my ($port, $timestamp) = ($1, $2);
 842                     if (($timestamp + $expiretime) > $ctime) {
 843                         $ports->{$port} = $timestamp; # not expired
 844                     }
 845                 }
 846             }
 847         }
 848
 849         my $newport;
 850         my %sockargs = (Listen => 5,
 851                         ReuseAddr => 1,
 852                         Family    => $family,
 853                         Proto     => IPPROTO_TCP,
 854                         GetAddrInfoFlags => 0);
 855         $sockargs{LocalAddr} = $address if defined($address);
 856
 857         for (my $p = $range_start; $p < $range_end; $p++) {
 858             next if $ports->{$p}; # reserved
 859
 860             $sockargs{LocalPort} = $p;
 861             my $sock = IO::Socket::IP->new(%sockargs);
 862
 863             if ($sock) {
 864                 close($sock);
 865                 $newport = $p;
 866                 $ports->{$p} = $ctime;
 867                 last;
 868             }
 869         }
 870
 871         my $data = "";
 872         foreach my $p (keys %$ports) {
 873             $data .= "$p $ports->{$p}\n";
 874         }
 875
 876         file_set_contents($filename, $data);
 877
 878         return $newport;
 879     };
 880
 881     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 882     die $@ if $@;
 883
 884     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 885
 886     return $p;
 887 }
 888
 889 sub next_migrate_port {
 890     my ($family, $address) = @_;
 891     return next_unused_port(60000, 60050, $family, $address);
 892 }
 893
 894 sub next_vnc_port {
 895     my ($family, $address) = @_;
 896     return next_unused_port(5900, 6000, $family, $address);
 897 }
 898
 899 sub next_spice_port {
 900     my ($family, $address) = @_;
 901     return next_unused_port(61000, 61099, $family, $address);
 902 }
 903
 904 sub must_stringify {
 905         my ($value) = @_;
 906         eval { $value = "$value" };
 907         return "error turning value into a string: $@" if $@;
 908         return $value;
 909 }
 910
 911 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 912 # the $sub has to return a single scalar
 913 sub run_fork_with_timeout {
 914     my ($timeout, $sub) = @_;
 915
 916     my $res;
 917     my $error;
 918     my $pipe_out = IO::Pipe->new();
 919
 920     # disable pending alarms, save their remaining time
 921     my $prev_alarm = alarm 0;
 922
 923     # avoid leaving a zombie if the parent gets interrupted
 924     my $sig_received;
 925
 926     my $child = fork();
 927     if (!defined($child)) {
 928         die "fork failed: $!\n";
 929         return $res;
 930     }
 931
 932     if (!$child) {
 933         $pipe_out->writer();
 934
 935         eval {
 936             $res = $sub->();
 937             print {$pipe_out} encode_json({ result => $res });
 938             $pipe_out->flush();
 939         };
 940         if (my $err = $@) {
 941             print {$pipe_out} encode_json({ error => must_stringify($err) });
 942             $pipe_out->flush();
 943             POSIX::_exit(1);
 944         }
 945         POSIX::_exit(0);
 946     }
 947
 948     local $SIG{INT} = sub { $sig_received++; };
 949     local $SIG{TERM} = sub {
 950         $error //= "interrupted by unexpected signal\n";
 951         kill('TERM', $child);
 952     };
 953
 954     $pipe_out->reader();
 955
 956     my $readvalues = sub {
 957         local $/ = undef;
 958         my $child_res = decode_json(readline_nointr($pipe_out));
 959         $res = $child_res->{result};
 960         $error = $child_res->{error};
 961     };
 962     eval {
 963         if (defined($timeout)) {
 964             run_with_timeout($timeout, $readvalues);
 965         } else {
 966             $readvalues->();
 967         }
 968     };
 969     warn $@ if $@;
 970     $pipe_out->close();
 971     kill('KILL', $child);
 972     waitpid($child, 0);
 973
 974     alarm $prev_alarm;
 975     die "interrupted by unexpected signal\n" if $sig_received;
 976
 977     die $error if $error;
 978     return $res;
 979 }
 980
 981 sub run_fork {
 982     my ($code) = @_;
 983     return run_fork_with_timeout(undef, $code);
 984 }
 985
 986 # NOTE: NFS syscall can't be interrupted, so alarm does
 987 # not work to provide timeouts.
 988 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
 989 # So fork() before using Filesys::Df
 990 sub df {
 991     my ($path, $timeout) = @_;
 992
 993     my $df = sub { return Filesys::Df::df($path, 1) };
 994
 995     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
 996     warn $@ if $@;
 997
 998     # untaint the values
 999     my ($blocks, $used, $bavail) = map { defined($_) ? (/^(\d+)$/) : 0 }
1000         $res->@{qw(blocks used bavail)};
1001
1002     return {
1003         total => $blocks,
1004         used => $used,
1005         avail => $bavail,
1006     };
1007 }
1008
1009 sub du {
1010     my ($path, $timeout) = @_;
1011
1012     my $size;
1013
1014     $timeout //= 10;
1015
1016     my $parser = sub {
1017         my $line = shift;
1018
1019         if ($line =~ m/^(\d+)\s+total$/) {
1020             $size = $1;
1021         }
1022     };
1023
1024     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1025
1026     return $size;
1027 }
1028
1029 # UPID helper
1030 # We use this to uniquely identify a process.
1031 # An 'Unique Process ID' has the following format:
1032 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1033
1034 sub upid_encode {
1035     my $d = shift;
1036
1037     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1038     # more that 8 characters for pstart
1039     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1040                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1041                    $d->{user});
1042 }
1043
1044 sub upid_decode {
1045     my ($upid, $noerr) = @_;
1046
1047     my $res;
1048     my $filename;
1049
1050     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1051     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1052     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1053         $res->{node} = $1;
1054         $res->{pid} = hex($3);
1055         $res->{pstart} = hex($4);
1056         $res->{starttime} = hex($5);
1057         $res->{type} = $6;
1058         $res->{id} = $7;
1059         $res->{user} = $8;
1060
1061         my $subdir = substr($5, 7, 8);
1062         $filename = "$pvetaskdir/$subdir/$upid";
1063
1064     } else {
1065         return undef if $noerr;
1066         die "unable to parse worker upid '$upid'\n";
1067     }
1068
1069     return wantarray ? ($res, $filename) : $res;
1070 }
1071
1072 sub upid_open {
1073     my ($upid) = @_;
1074
1075     my ($task, $filename) = upid_decode($upid);
1076
1077     my $dirname = dirname($filename);
1078     make_path($dirname);
1079
1080     my $wwwid = getpwnam('www-data') ||
1081         die "getpwnam failed";
1082
1083     my $perm = 0640;
1084
1085     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1086         die "unable to create output file '$filename' - $!\n";
1087     chown $wwwid, -1, $outfh;
1088
1089     return $outfh;
1090 };
1091
1092 sub upid_read_status {
1093     my ($upid) = @_;
1094
1095     my ($task, $filename) = upid_decode($upid);
1096     my $fh = IO::File->new($filename, "r");
1097     return "unable to open file - $!" if !$fh;
1098     my $maxlen = 4096;
1099     sysseek($fh, -$maxlen, 2);
1100     my $readbuf = '';
1101     my $br = sysread($fh, $readbuf, $maxlen);
1102     close($fh);
1103     if ($br) {
1104         return "unable to extract last line"
1105             if $readbuf !~ m/\n?(.+)$/;
1106         my $line = $1;
1107         if ($line =~ m/^TASK OK$/) {
1108             return 'OK';
1109         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1110             return $1;
1111         } else {
1112             return "unexpected status";
1113         }
1114     }
1115     return "unable to read tail (got $br bytes)";
1116 }
1117
1118 # useful functions to store comments in config files
1119 sub encode_text {
1120     my ($text) = @_;
1121
1122     # all control and hi-bit characters, and ':'
1123     my $unsafe = "^\x20-\x39\x3b-\x7e";
1124     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1125 }
1126
1127 sub decode_text {
1128     my ($data) = @_;
1129
1130     return Encode::decode("utf8", uri_unescape($data));
1131 }
1132
1133 # depreciated - do not use!
1134 # we now decode all parameters by default
1135 sub decode_utf8_parameters {
1136     my ($param) = @_;
1137
1138     foreach my $p (qw(comment description firstname lastname)) {
1139         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1140     }
1141
1142     return $param;
1143 }
1144
1145 sub random_ether_addr {
1146     my ($prefix) = @_;
1147
1148     my ($seconds, $microseconds) = gettimeofday;
1149
1150     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1151
1152     # clear multicast, set local id
1153     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1154
1155     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1156     if (defined($prefix)) {
1157         $addr = uc($prefix) . substr($addr, length($prefix));
1158     }
1159     return $addr;
1160 }
1161
1162 sub shellquote {
1163     my $str = shift;
1164
1165     return String::ShellQuote::shell_quote($str);
1166 }
1167
1168 sub cmd2string {
1169     my ($cmd) = @_;
1170
1171     die "no arguments" if !$cmd;
1172
1173     return $cmd if !ref($cmd);
1174
1175     my @qa = ();
1176     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1177
1178     return join (' ', @qa);
1179 }
1180
1181 # split an shell argument string into an array,
1182 sub split_args {
1183     my ($str) = @_;
1184
1185     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1186 }
1187
1188 sub dump_logfile {
1189     my ($filename, $start, $limit, $filter) = @_;
1190
1191     my $lines = [];
1192     my $count = 0;
1193
1194     my $fh = IO::File->new($filename, "r");
1195     if (!$fh) {
1196         $count++;
1197         push @$lines, { n => $count, t => "unable to open file - $!"};
1198         return ($count, $lines);
1199     }
1200
1201     $start = 0 if !$start;
1202     $limit = 50 if !$limit;
1203
1204     my $line;
1205
1206     if ($filter) {
1207         # duplicate code, so that we do not slow down normal path
1208         while (defined($line = <$fh>)) {
1209             next if $line !~ m/$filter/;
1210             next if $count++ < $start;
1211             next if $limit <= 0;
1212             chomp $line;
1213             push @$lines, { n => $count, t => $line};
1214             $limit--;
1215         }
1216     } else {
1217         while (defined($line = <$fh>)) {
1218             next if $count++ < $start;
1219             next if $limit <= 0;
1220             chomp $line;
1221             push @$lines, { n => $count, t => $line};
1222             $limit--;
1223         }
1224     }
1225
1226     close($fh);
1227
1228     # HACK: ExtJS store.guaranteeRange() does not like empty array
1229     # so we add a line
1230     if (!$count) {
1231         $count++;
1232         push @$lines, { n => $count, t => "no content"};
1233     }
1234
1235     return ($count, $lines);
1236 }
1237
1238 sub dump_journal {
1239     my ($start, $limit, $since, $until, $service) = @_;
1240
1241     my $lines = [];
1242     my $count = 0;
1243
1244     $start = 0 if !$start;
1245     $limit = 50 if !$limit;
1246
1247     my $parser = sub {
1248         my $line = shift;
1249
1250         return if $count++ < $start;
1251         return if $limit <= 0;
1252         push @$lines, { n => int($count), t => $line};
1253         $limit--;
1254     };
1255
1256     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1257
1258     push @$cmd, '--unit', $service if $service;
1259     push @$cmd, '--since', $since if $since;
1260     push @$cmd, '--until', $until if $until;
1261     run_command($cmd, outfunc => $parser);
1262
1263     # HACK: ExtJS store.guaranteeRange() does not like empty array
1264     # so we add a line
1265     if (!$count) {
1266         $count++;
1267         push @$lines, { n => $count, t => "no content"};
1268     }
1269
1270     return ($count, $lines);
1271 }
1272
1273 sub dir_glob_regex {
1274     my ($dir, $regex) = @_;
1275
1276     my $dh = IO::Dir->new ($dir);
1277     return wantarray ? () : undef if !$dh;
1278
1279     while (defined(my $tmp = $dh->read)) {
1280         if (my @res = $tmp =~ m/^($regex)$/) {
1281             $dh->close;
1282             return wantarray ? @res : $tmp;
1283         }
1284     }
1285     $dh->close;
1286
1287     return wantarray ? () : undef;
1288 }
1289
1290 sub dir_glob_foreach {
1291     my ($dir, $regex, $func) = @_;
1292
1293     my $dh = IO::Dir->new ($dir);
1294     if (defined $dh) {
1295         while (defined(my $tmp = $dh->read)) {
1296             if (my @res = $tmp =~ m/^($regex)$/) {
1297                 &$func (@res);
1298             }
1299         }
1300     }
1301 }
1302
1303 sub assert_if_modified {
1304     my ($digest1, $digest2) = @_;
1305
1306     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1307         die "detected modified configuration - file changed by other user? Try again.\n";
1308     }
1309 }
1310
1311 # Digest for short strings
1312 # like FNV32a, but we only return 31 bits (positive numbers)
1313 sub fnv31a {
1314     my ($string) = @_;
1315
1316     my $hval = 0x811c9dc5;
1317
1318     foreach my $c (unpack('C*', $string)) {
1319         $hval ^= $c;
1320         $hval += (
1321             (($hval << 1) ) +
1322             (($hval << 4) ) +
1323             (($hval << 7) ) +
1324             (($hval << 8) ) +
1325             (($hval << 24) ) );
1326         $hval = $hval & 0xffffffff;
1327     }
1328     return $hval & 0x7fffffff;
1329 }
1330
1331 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1332
1333 sub unpack_sockaddr_in46 {
1334     my ($sin) = @_;
1335     my $family = Socket::sockaddr_family($sin);
1336     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1337                                              : Socket::unpack_sockaddr_in($sin));
1338     return ($family, $port, $host);
1339 }
1340
1341 sub getaddrinfo_all {
1342     my ($hostname, @opts) = @_;
1343     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1344                   @opts );
1345     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1346     die "failed to get address info for: $hostname: $err\n" if $err;
1347     return @res;
1348 }
1349
1350 sub get_host_address_family {
1351     my ($hostname, $socktype) = @_;
1352     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1353     return $res[0]->{family};
1354 }
1355
1356 # get the fully qualified domain name of a host
1357 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1358 # given a nodename as a parameter
1359 sub get_fqdn {
1360     my ($nodename) = @_;
1361
1362     my $hints = {
1363         flags => AI_CANONNAME,
1364         socktype => SOCK_DGRAM
1365     };
1366
1367     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1368
1369     die "getaddrinfo: $err" if $err;
1370
1371     return $addrs[0]->{canonname};
1372 }
1373
1374 # Parses any sane kind of host, or host+port pair:
1375 # The port is always optional and thus may be undef.
1376 sub parse_host_and_port {
1377     my ($address) = @_;
1378     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1379         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1380         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1381     {
1382         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1383     }
1384     return; # nothing
1385 }
1386
1387 sub unshare($) {
1388     my ($flags) = @_;
1389     return 0 == syscall(PVE::Syscall::unshare, $flags);
1390 }
1391
1392 sub setns($$) {
1393     my ($fileno, $nstype) = @_;
1394     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1395 }
1396
1397 sub syncfs($) {
1398     my ($fileno) = @_;
1399     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1400 }
1401
1402 sub sync_mountpoint {
1403     my ($path) = @_;
1404     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1405     my $result = syncfs(fileno($fd));
1406     close($fd);
1407     return $result;
1408 }
1409
1410 # support sending multi-part mail messages with a text and or a HTML part
1411 # mailto may be a single email string or an array of receivers
1412 sub sendmail {
1413     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1414     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1415
1416     $mailto = [ $mailto ] if !ref($mailto);
1417
1418     foreach (@$mailto) {
1419         die "illegal character in mailto address\n"
1420             if ($_ =~ $mail_re);
1421     }
1422
1423     my $rcvrtxt = join (', ', @$mailto);
1424
1425     $mailfrom = $mailfrom || "root";
1426     die "illegal character in mailfrom address\n"
1427         if $mailfrom =~ $mail_re;
1428
1429     $author = $author || 'Proxmox VE';
1430
1431     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1432         die "unable to open 'sendmail' - $!";
1433
1434     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1435     my $boundary = "----_=_NextPart_001_".int(time).$$;
1436
1437     print MAIL "Content-Type: multipart/alternative;\n";
1438     print MAIL "\tboundary=\"$boundary\"\n";
1439     print MAIL "MIME-Version: 1.0\n";
1440
1441     print MAIL "FROM: $author <$mailfrom>\n";
1442     print MAIL "TO: $rcvrtxt\n";
1443     print MAIL "SUBJECT: $subject\n";
1444     print MAIL "\n";
1445     print MAIL "This is a multi-part message in MIME format.\n\n";
1446     print MAIL "--$boundary\n";
1447
1448     if (defined($text)) {
1449         print MAIL "Content-Type: text/plain;\n";
1450         print MAIL "\tcharset=\"UTF8\"\n";
1451         print MAIL "Content-Transfer-Encoding: 8bit\n";
1452         print MAIL "\n";
1453
1454         # avoid 'remove extra line breaks' issue (MS Outlook)
1455         my $fill = '  ';
1456         $text =~ s/^/$fill/gm;
1457
1458         print MAIL $text;
1459
1460         print MAIL "\n--$boundary\n";
1461     }
1462
1463     if (defined($html)) {
1464         print MAIL "Content-Type: text/html;\n";
1465         print MAIL "\tcharset=\"UTF8\"\n";
1466         print MAIL "Content-Transfer-Encoding: 8bit\n";
1467         print MAIL "\n";
1468
1469         print MAIL $html;
1470
1471         print MAIL "\n--$boundary--\n";
1472     }
1473
1474     close(MAIL);
1475 }
1476
1477 sub tempfile {
1478     my ($perm, %opts) = @_;
1479
1480     # default permissions are stricter than with file_set_contents
1481     $perm = 0600 if !defined($perm);
1482
1483     my $dir = $opts{dir} // '/run';
1484     my $mode = $opts{mode} // O_RDWR;
1485     $mode |= O_EXCL if !$opts{allow_links};
1486
1487     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1488     if (!$fh && $! == EOPNOTSUPP) {
1489         $dir = '/tmp' if !defined($opts{dir});
1490         $dir .= "/.tmpfile.$$";
1491         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1492         unlink($dir) if $fh;
1493     }
1494     die "failed to create tempfile: $!\n" if !$fh;
1495     return $fh;
1496 }
1497
1498 sub tempfile_contents {
1499     my ($data, $perm, %opts) = @_;
1500
1501     my $fh = tempfile($perm, %opts);
1502     eval {
1503         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1504         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1505     };
1506     if (my $err = $@) {
1507         close $fh;
1508         die $err;
1509     }
1510
1511     return ("/proc/$$/fd/".$fh->fileno, $fh);
1512 }
1513
1514 sub validate_ssh_public_keys {
1515     my ($raw) = @_;
1516     my @lines = split(/\n/, $raw);
1517
1518     foreach my $line (@lines) {
1519         next if $line =~ m/^\s*$/;
1520         eval {
1521             my ($filename, $handle) = tempfile_contents($line);
1522             run_command(["ssh-keygen", "-l", "-f", $filename],
1523                         outfunc => sub {}, errfunc => sub {});
1524         };
1525         die "SSH public key validation error\n" if $@;
1526     }
1527 }
1528
1529 sub openat($$$;$) {
1530     my ($dirfd, $pathname, $flags, $mode) = @_;
1531     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1532     return undef if $fd < 0;
1533     # sysopen() doesn't deal with numeric file descriptors apparently
1534     # so we need to convert to a mode string for IO::Handle->new_from_fd
1535     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1536     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1537     return $handle if $handle;
1538     my $err = $!; # save error before closing the raw fd
1539     syscall(PVE::Syscall::close, $fd); # close
1540     $! = $err;
1541     return undef;
1542 }
1543
1544 sub mkdirat($$$) {
1545     my ($dirfd, $name, $mode) = @_;
1546     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1547 }
1548
1549 my $salt_starter = time();
1550
1551 sub encrypt_pw {
1552     my ($pw) = @_;
1553
1554     $salt_starter++;
1555     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1556
1557     # crypt does not want '+' in salt (see 'man crypt')
1558     $salt =~ s/\+/X/g;
1559
1560     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1561 }
1562
1563 # intended usage: convert_size($val, "kb" => "gb")
1564 # we round up to the next integer by default
1565 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1566 # use $no_round_up to switch this off, above example would then return 0
1567 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1568 # (0 if $no_round_up is true)
1569 # allowed formats for value:
1570 # 1234
1571 # 1234.
1572 # 1234.1234
1573 # .1234
1574 sub convert_size {
1575     my ($value, $from, $to, $no_round_up) = @_;
1576
1577     my $units = {
1578         b  => 0,
1579         kb => 1,
1580         mb => 2,
1581         gb => 3,
1582         tb => 4,
1583         pb => 5,
1584     };
1585
1586     die "no value given"
1587         if !defined($value) || $value eq "";
1588
1589     $from = lc($from // ''); $to = lc($to // '');
1590     die "unknown 'from' and/or 'to' units ($from => $to)"
1591         if !defined($units->{$from}) || !defined($units->{$to});
1592
1593     die "value '$value' is not a valid, positive number"
1594         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1595
1596     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1597
1598     $value *= 2**$shift_amount;
1599     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1600
1601     return int($value);
1602 }
1603
1604 # uninterruptible readline
1605 # retries on EINTR
1606 sub readline_nointr {
1607     my ($fh) = @_;
1608     my $line;
1609     while (1) {
1610         $line = <$fh>;
1611         last if defined($line) || ($! != EINTR);
1612     }
1613     return $line;
1614 }
1615
1616 1;