fix #1819: fork_worker: ensure sync'ed workers control terminal
[pve-common.git] / src / PVE / Tools.pm
1 package PVE::Tools;
2
3 use strict;
4 use warnings;
5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
6 use IO::Socket::IP;
7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
8 IPPROTO_TCP);
9 use IO::Select;
10 use File::Basename;
11 use File::Path qw(make_path);
12 use Filesys::Df (); # don't overwrite our df()
13 use IO::Pipe;
14 use IO::File;
15 use IO::Dir;
16 use IO::Handle;
17 use IPC::Open3;
18 use Fcntl qw(:DEFAULT :flock);
19 use base 'Exporter';
20 use URI::Escape;
21 use Encode;
22 use Digest::SHA;
23 use JSON;
24 use Text::ParseWords;
25 use String::ShellQuote;
26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
27 use Scalar::Util 'weaken';
28 use PVE::Syscall;
29
30 # avoid warning when parsing long hex values with hex()
31 no warnings 'portable'; # Support for 64-bit ints required
32
33 our @EXPORT_OK = qw(
34 $IPV6RE
35 $IPV4RE
36 lock_file
37 lock_file_full
38 run_command
39 file_set_contents
40 file_get_contents
41 file_read_firstline
42 dir_glob_regex
43 dir_glob_foreach
44 split_list
45 template_replace
46 safe_print
47 trim
48 extract_param
49 file_copy
50 O_PATH
51 O_TMPFILE
52 );
53
54 my $pvelogdir = "/var/log/pve";
55 my $pvetaskdir = "$pvelogdir/tasks";
56
57 mkdir $pvelogdir;
58 mkdir $pvetaskdir;
59
60 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
61 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
62 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
63 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
64
65 our $IPV6RE = "(?:" .
66 "(?:(?:" . "(?:$IPV6H16:){6})$IPV6LS32)|" .
67 "(?:(?:" . "::(?:$IPV6H16:){5})$IPV6LS32)|" .
68 "(?:(?:(?:" . "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
69 "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
70 "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
71 "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
72 "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" . ")$IPV6LS32)|" .
73 "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" . ")$IPV6H16)|" .
74 "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" . ")))";
75
76 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
77
78 use constant {CLONE_NEWNS => 0x00020000,
79 CLONE_NEWUTS => 0x04000000,
80 CLONE_NEWIPC => 0x08000000,
81 CLONE_NEWUSER => 0x10000000,
82 CLONE_NEWPID => 0x20000000,
83 CLONE_NEWNET => 0x40000000};
84
85 use constant {O_PATH => 0x00200000,
86 O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
87
88 sub run_with_timeout {
89 my ($timeout, $code, @param) = @_;
90
91 die "got timeout\n" if $timeout <= 0;
92
93 my $prev_alarm = alarm 0; # suspend outer alarm early
94
95 my $sigcount = 0;
96
97 my $res;
98
99 eval {
100 local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
101 local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
102 local $SIG{__DIE__}; # see SA bug 4631
103
104 alarm($timeout);
105
106 eval { $res = &$code(@param); };
107
108 alarm(0); # avoid race conditions
109
110 die $@ if $@;
111 };
112
113 my $err = $@;
114
115 alarm $prev_alarm;
116
117 # this shouldn't happen anymore?
118 die "unknown error" if $sigcount && !$err; # seems to happen sometimes
119
120 die $err if $err;
121
122 return $res;
123 }
124
125 # flock: we use one file handle per process, so lock file
126 # can be nested multiple times and succeeds for the same process.
127 #
128 # Since this is the only way we lock now and we don't have the old
129 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
130 # count how deep we're nesting. Therefore this hash now stores a weak reference
131 # to a boolean telling us whether we already have a lock.
132
133 my $lock_handles = {};
134
135 sub lock_file_full {
136 my ($filename, $timeout, $shared, $code, @param) = @_;
137
138 $timeout = 10 if !$timeout;
139
140 my $mode = $shared ? LOCK_SH : LOCK_EX;
141
142 my $lockhash = ($lock_handles->{$$} //= {});
143
144 # Returns a locked file handle.
145 my $get_locked_file = sub {
146 my $fh = IO::File->new(">>$filename")
147 or die "can't open file - $!\n";
148
149 if (!flock($fh, $mode|LOCK_NB)) {
150 print STDERR "trying to acquire lock...\n";
151 my $success;
152 while(1) {
153 $success = flock($fh, $mode);
154 # try again on EINTR (see bug #273)
155 if ($success || ($! != EINTR)) {
156 last;
157 }
158 }
159 if (!$success) {
160 print STDERR " failed\n";
161 die "can't acquire lock '$filename' - $!\n";
162 }
163 print STDERR " OK\n";
164 }
165
166 return $fh;
167 };
168
169 my $res;
170 my $checkptr = $lockhash->{$filename};
171 my $check = 0; # This must not go out of scope before running the code.
172 my $local_fh; # This must stay local
173 if (!$checkptr || !$$checkptr) {
174 # We cannot create a weak reference in a single atomic step, so we first
175 # create a false-value, then create a reference to it, then weaken it,
176 # and after successfully locking the file we change the boolean value.
177 #
178 # The reason for this is that if an outer SIGALRM throws an exception
179 # between creating the reference and weakening it, a subsequent call to
180 # lock_file_full() will see a leftover full reference to a valid
181 # variable. This variable must be 0 in order for said call to attempt to
182 # lock the file anew.
183 #
184 # An externally triggered exception elsewhere in the code will cause the
185 # weak reference to become 'undef', and since the file handle is only
186 # stored in the local scope in $local_fh, the file will be closed by
187 # perl's cleanup routines as well.
188 #
189 # This still assumes that an IO::File handle can properly deal with such
190 # exceptions thrown during its own destruction, but that's up to perls
191 # guts now.
192 $lockhash->{$filename} = \$check;
193 weaken $lockhash->{$filename};
194 $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
195 if ($@) {
196 $@ = "can't lock file '$filename' - $@";
197 return undef;
198 }
199 $check = 1;
200 }
201 $res = eval { &$code(@param); };
202 return undef if $@;
203 return $res;
204 }
205
206
207 sub lock_file {
208 my ($filename, $timeout, $code, @param) = @_;
209
210 return lock_file_full($filename, $timeout, 0, $code, @param);
211 }
212
213 sub file_set_contents {
214 my ($filename, $data, $perm) = @_;
215
216 $perm = 0644 if !defined($perm);
217
218 my $tmpname = "$filename.tmp.$$";
219
220 eval {
221 my ($fh, $tries) = (undef, 0);
222 while (!$fh && $tries++ < 3) {
223 $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
224 if (!$fh && $! == EEXIST) {
225 unlink($tmpname) or die "unable to delete old temp file: $!\n";
226 }
227 }
228 die "unable to open file '$tmpname' - $!\n" if !$fh;
229 die "unable to write '$tmpname' - $!\n" unless print $fh $data;
230 die "closing file '$tmpname' failed - $!\n" unless close $fh;
231 };
232 my $err = $@;
233
234 if ($err) {
235 unlink $tmpname;
236 die $err;
237 }
238
239 if (!rename($tmpname, $filename)) {
240 my $msg = "close (rename) atomic file '$filename' failed: $!\n";
241 unlink $tmpname;
242 die $msg;
243 }
244 }
245
246 sub file_get_contents {
247 my ($filename, $max) = @_;
248
249 my $fh = IO::File->new($filename, "r") ||
250 die "can't open '$filename' - $!\n";
251
252 my $content = safe_read_from($fh, $max, 0, $filename);
253
254 close $fh;
255
256 return $content;
257 }
258
259 sub file_copy {
260 my ($filename, $dst, $max, $perm) = @_;
261
262 file_set_contents ($dst, file_get_contents($filename, $max), $perm);
263 }
264
265 sub file_read_firstline {
266 my ($filename) = @_;
267
268 my $fh = IO::File->new ($filename, "r");
269 return undef if !$fh;
270 my $res = <$fh>;
271 chomp $res if $res;
272 $fh->close;
273 return $res;
274 }
275
276 sub safe_read_from {
277 my ($fh, $max, $oneline, $filename) = @_;
278
279 $max = 32768 if !$max;
280
281 my $subject = defined($filename) ? "file '$filename'" : 'input';
282
283 my $br = 0;
284 my $input = '';
285 my $count;
286 while ($count = sysread($fh, $input, 8192, $br)) {
287 $br += $count;
288 die "$subject too long - aborting\n" if $br > $max;
289 if ($oneline && $input =~ m/^(.*)\n/) {
290 $input = $1;
291 last;
292 }
293 }
294 die "unable to read $subject - $!\n" if !defined($count);
295
296 return $input;
297 }
298
299 # The $cmd parameter can be:
300 # -) a string
301 # This is generally executed by passing it to the shell with the -c option.
302 # However, it can be executed in one of two ways, depending on whether
303 # there's a pipe involved:
304 # *) with pipe: passed explicitly to bash -c, prefixed with:
305 # set -o pipefail &&
306 # *) without a pipe: passed to perl's open3 which uses 'sh -c'
307 # (Note that this may result in two different syntax requirements!)
308 # FIXME?
309 # -) an array of arguments (strings)
310 # Will be executed without interference from a shell. (Parameters are passed
311 # as is, no escape sequences of strings will be touched.)
312 # -) an array of arrays
313 # Each array represents a command, and each command's output is piped into
314 # the following command's standard input.
315 # For this a shell command string is created with pipe symbols between each
316 # command.
317 # Each command is a list of strings meant to end up in the final command
318 # unchanged. In order to achieve this, every argument is shell-quoted.
319 # Quoting can be disabled for a particular argument by turning it into a
320 # reference, this allows inserting arbitrary shell options.
321 # For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
322 # produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
323 # will literally print: hello >/dev/null
324 sub run_command {
325 my ($cmd, %param) = @_;
326
327 my $old_umask;
328 my $cmdstr;
329
330 if (my $ref = ref($cmd)) {
331 if (ref($cmd->[0])) {
332 $cmdstr = 'set -o pipefail && ';
333 my $pipe = '';
334 foreach my $command (@$cmd) {
335 # concatenate quoted parameters
336 # strings which are passed by reference are NOT shell quoted
337 $cmdstr .= $pipe . join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
338 $pipe = ' | ';
339 }
340 $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
341 } else {
342 $cmdstr = cmd2string($cmd);
343 }
344 } else {
345 $cmdstr = $cmd;
346 if ($cmd =~ m/\|/) {
347 # see 'man bash' for option pipefail
348 $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
349 } else {
350 $cmd = [ $cmd ];
351 }
352 }
353
354 my $errmsg;
355 my $laststderr;
356 my $timeout;
357 my $oldtimeout;
358 my $pid;
359 my $exitcode = -1;
360
361 my $outfunc;
362 my $errfunc;
363 my $logfunc;
364 my $input;
365 my $output;
366 my $afterfork;
367 my $noerr;
368 my $keeplocale;
369 my $quiet;
370
371 eval {
372
373 foreach my $p (keys %param) {
374 if ($p eq 'timeout') {
375 $timeout = $param{$p};
376 } elsif ($p eq 'umask') {
377 $old_umask = umask($param{$p});
378 } elsif ($p eq 'errmsg') {
379 $errmsg = $param{$p};
380 } elsif ($p eq 'input') {
381 $input = $param{$p};
382 } elsif ($p eq 'output') {
383 $output = $param{$p};
384 } elsif ($p eq 'outfunc') {
385 $outfunc = $param{$p};
386 } elsif ($p eq 'errfunc') {
387 $errfunc = $param{$p};
388 } elsif ($p eq 'logfunc') {
389 $logfunc = $param{$p};
390 } elsif ($p eq 'afterfork') {
391 $afterfork = $param{$p};
392 } elsif ($p eq 'noerr') {
393 $noerr = $param{$p};
394 } elsif ($p eq 'keeplocale') {
395 $keeplocale = $param{$p};
396 } elsif ($p eq 'quiet') {
397 $quiet = $param{$p};
398 } else {
399 die "got unknown parameter '$p' for run_command\n";
400 }
401 }
402
403 if ($errmsg) {
404 my $origerrfunc = $errfunc;
405 $errfunc = sub {
406 if ($laststderr) {
407 if ($origerrfunc) {
408 &$origerrfunc("$laststderr\n");
409 } else {
410 print STDERR "$laststderr\n" if $laststderr;
411 }
412 }
413 $laststderr = shift;
414 };
415 }
416
417 my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
418 my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
419 my $error = IO::File->new();
420
421 my $orig_pid = $$;
422
423 eval {
424 local $ENV{LC_ALL} = 'C' if !$keeplocale;
425
426 # suppress LVM warnings like: "File descriptor 3 left open";
427 local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
428
429 $pid = open3($writer, $reader, $error, @$cmd) || die $!;
430
431 # if we pipe fron STDIN, open3 closes STDIN, so we we
432 # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
433 # as soon as we open a new file.
434 # to avoid that we open /dev/null
435 if (!ref($writer) && !defined(fileno(STDIN))) {
436 POSIX::close(0);
437 open(STDIN, "</dev/null");
438 }
439 };
440
441 my $err = $@;
442
443 # catch exec errors
444 if ($orig_pid != $$) {
445 warn "ERROR: $err";
446 POSIX::_exit (1);
447 kill ('KILL', $$);
448 }
449
450 die $err if $err;
451
452 local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
453 $oldtimeout = alarm($timeout) if $timeout;
454
455 &$afterfork() if $afterfork;
456
457 if (ref($writer)) {
458 print $writer $input if defined $input;
459 close $writer;
460 }
461
462 my $select = new IO::Select;
463 $select->add($reader) if ref($reader);
464 $select->add($error);
465
466 my $outlog = '';
467 my $errlog = '';
468
469 my $starttime = time();
470
471 while ($select->count) {
472 my @handles = $select->can_read(1);
473
474 foreach my $h (@handles) {
475 my $buf = '';
476 my $count = sysread ($h, $buf, 4096);
477 if (!defined ($count)) {
478 my $err = $!;
479 kill (9, $pid);
480 waitpid ($pid, 0);
481 die $err;
482 }
483 $select->remove ($h) if !$count;
484 if ($h eq $reader) {
485 if ($outfunc || $logfunc) {
486 eval {
487 $outlog .= $buf;
488 while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
489 my $line = $1;
490 &$outfunc($line) if $outfunc;
491 &$logfunc($line) if $logfunc;
492 }
493 };
494 my $err = $@;
495 if ($err) {
496 kill (9, $pid);
497 waitpid ($pid, 0);
498 die $err;
499 }
500 } elsif (!$quiet) {
501 print $buf;
502 *STDOUT->flush();
503 }
504 } elsif ($h eq $error) {
505 if ($errfunc || $logfunc) {
506 eval {
507 $errlog .= $buf;
508 while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
509 my $line = $1;
510 &$errfunc($line) if $errfunc;
511 &$logfunc($line) if $logfunc;
512 }
513 };
514 my $err = $@;
515 if ($err) {
516 kill (9, $pid);
517 waitpid ($pid, 0);
518 die $err;
519 }
520 } elsif (!$quiet) {
521 print STDERR $buf;
522 *STDERR->flush();
523 }
524 }
525 }
526 }
527
528 &$outfunc($outlog) if $outfunc && $outlog;
529 &$logfunc($outlog) if $logfunc && $outlog;
530
531 &$errfunc($errlog) if $errfunc && $errlog;
532 &$logfunc($errlog) if $logfunc && $errlog;
533
534 waitpid ($pid, 0);
535
536 if ($? == -1) {
537 die "failed to execute\n";
538 } elsif (my $sig = ($? & 127)) {
539 die "got signal $sig\n";
540 } elsif ($exitcode = ($? >> 8)) {
541 if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
542 if ($errmsg && $laststderr) {
543 my $lerr = $laststderr;
544 $laststderr = undef;
545 die "$lerr\n";
546 }
547 die "exit code $exitcode\n";
548 }
549 }
550
551 alarm(0);
552 };
553
554 my $err = $@;
555
556 alarm(0);
557
558 if ($errmsg && $laststderr) {
559 &$errfunc(undef); # flush laststderr
560 }
561
562 umask ($old_umask) if defined($old_umask);
563
564 alarm($oldtimeout) if $oldtimeout;
565
566 if ($err) {
567 if ($pid && ($err eq "got timeout\n")) {
568 kill (9, $pid);
569 waitpid ($pid, 0);
570 die "command '$cmdstr' failed: $err";
571 }
572
573 if ($errmsg) {
574 $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
575 die "$errmsg: $err";
576 } elsif(!$noerr) {
577 die "command '$cmdstr' failed: $err";
578 }
579 }
580
581 return $exitcode;
582 }
583
584 # Run a command with a tcp socket as standard input.
585 sub pipe_socket_to_command {
586 my ($cmd, $ip, $port) = @_;
587
588 my $params = {
589 Listen => 1,
590 ReuseAddr => 1,
591 Proto => &Socket::IPPROTO_TCP,
592 GetAddrInfoFlags => 0,
593 LocalAddr => $ip,
594 LocalPort => $port,
595 };
596 my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
597
598 print "$ip\n$port\n"; # tell remote where to connect
599 *STDOUT->flush();
600
601 alarm 0;
602 local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
603 alarm 30;
604 my $client = $socket->accept; # Wait for a client
605 alarm 0;
606 close($socket);
607
608 # We want that the command talks over the TCP socket and takes
609 # ownership of it, so that when it closes it the connection is
610 # terminated, so we need to be able to close the socket. So we
611 # can't really use PVE::Tools::run_command().
612 my $pid = fork() // die "fork failed: $!\n";
613 if (!$pid) {
614 POSIX::dup2(fileno($client), 0);
615 POSIX::dup2(fileno($client), 1);
616 close($client);
617 exec {$cmd->[0]} @$cmd or do {
618 warn "exec failed: $!\n";
619 POSIX::_exit(1);
620 };
621 }
622
623 close($client);
624 if (waitpid($pid, 0) != $pid) {
625 kill(15 => $pid); # if we got interrupted terminate the child
626 my $count = 0;
627 while (waitpid($pid, POSIX::WNOHANG) != $pid) {
628 usleep(100000);
629 $count++;
630 kill(9 => $pid), last if $count > 300; # 30 second timeout
631 }
632 }
633 if (my $sig = ($? & 127)) {
634 die "got signal $sig\n";
635 } elsif (my $exitcode = ($? >> 8)) {
636 die "exit code $exitcode\n";
637 }
638
639 return undef;
640 }
641
642 sub split_list {
643 my $listtxt = shift || '';
644
645 return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
646
647 $listtxt =~ s/[,;]/ /g;
648 $listtxt =~ s/^\s+//;
649
650 my @data = split (/\s+/, $listtxt);
651
652 return @data;
653 }
654
655 sub trim {
656 my $txt = shift;
657
658 return $txt if !defined($txt);
659
660 $txt =~ s/^\s+//;
661 $txt =~ s/\s+$//;
662
663 return $txt;
664 }
665
666 # simple uri templates like "/vms/{vmid}"
667 sub template_replace {
668 my ($tmpl, $data) = @_;
669
670 return $tmpl if !$tmpl;
671
672 my $res = '';
673 while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) {
674 $res .= $1 if $1;
675 $res .= ($data->{$3} || '-') if $2;
676 }
677 return $res;
678 }
679
680 sub safe_print {
681 my ($filename, $fh, $data) = @_;
682
683 return if !$data;
684
685 my $res = print $fh $data;
686
687 die "write to '$filename' failed\n" if !$res;
688 }
689
690 sub debmirrors {
691
692 return {
693 'at' => 'ftp.at.debian.org',
694 'au' => 'ftp.au.debian.org',
695 'be' => 'ftp.be.debian.org',
696 'bg' => 'ftp.bg.debian.org',
697 'br' => 'ftp.br.debian.org',
698 'ca' => 'ftp.ca.debian.org',
699 'ch' => 'ftp.ch.debian.org',
700 'cl' => 'ftp.cl.debian.org',
701 'cz' => 'ftp.cz.debian.org',
702 'de' => 'ftp.de.debian.org',
703 'dk' => 'ftp.dk.debian.org',
704 'ee' => 'ftp.ee.debian.org',
705 'es' => 'ftp.es.debian.org',
706 'fi' => 'ftp.fi.debian.org',
707 'fr' => 'ftp.fr.debian.org',
708 'gr' => 'ftp.gr.debian.org',
709 'hk' => 'ftp.hk.debian.org',
710 'hr' => 'ftp.hr.debian.org',
711 'hu' => 'ftp.hu.debian.org',
712 'ie' => 'ftp.ie.debian.org',
713 'is' => 'ftp.is.debian.org',
714 'it' => 'ftp.it.debian.org',
715 'jp' => 'ftp.jp.debian.org',
716 'kr' => 'ftp.kr.debian.org',
717 'mx' => 'ftp.mx.debian.org',
718 'nl' => 'ftp.nl.debian.org',
719 'no' => 'ftp.no.debian.org',
720 'nz' => 'ftp.nz.debian.org',
721 'pl' => 'ftp.pl.debian.org',
722 'pt' => 'ftp.pt.debian.org',
723 'ro' => 'ftp.ro.debian.org',
724 'ru' => 'ftp.ru.debian.org',
725 'se' => 'ftp.se.debian.org',
726 'si' => 'ftp.si.debian.org',
727 'sk' => 'ftp.sk.debian.org',
728 'tr' => 'ftp.tr.debian.org',
729 'tw' => 'ftp.tw.debian.org',
730 'gb' => 'ftp.uk.debian.org',
731 'us' => 'ftp.us.debian.org',
732 };
733 }
734
735 my $keymaphash = {
736 'dk' => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
737 'de' => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
738 'de-ch' => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz', 'ch', 'de_nodeadkeys' ],
739 'en-gb' => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
740 'en-us' => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz', 'us', undef ],
741 'es' => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
742 #'et' => [], # Ethopia or Estonia ??
743 'fi' => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
744 #'fo' => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
745 'fr' => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
746 'fr-be' => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
747 'fr-ca' => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
748 'fr-ch' => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
749 #'hr' => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
750 'hu' => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
751 'is' => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
752 'it' => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
753 'jp' => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
754 'lt' => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
755 #'lv' => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
756 'mk' => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
757 'nl' => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
758 #'nl-be' => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
759 'no' => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
760 'pl' => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
761 'pt' => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
762 'pt-br' => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
763 #'ru' => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know?
764 'si' => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
765 'se' => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
766 #'th' => [],
767 'tr' => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
768 };
769
770 my $kvmkeymaparray = [];
771 foreach my $lc (sort keys %$keymaphash) {
772 push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
773 }
774
775 sub kvmkeymaps {
776 return $keymaphash;
777 }
778
779 sub kvmkeymaplist {
780 return $kvmkeymaparray;
781 }
782
783 sub extract_param {
784 my ($param, $key) = @_;
785
786 my $res = $param->{$key};
787 delete $param->{$key};
788
789 return $res;
790 }
791
792 # Note: we use this to wait until vncterm/spiceterm is ready
793 sub wait_for_vnc_port {
794 my ($port, $family, $timeout) = @_;
795
796 $timeout = 5 if !$timeout;
797 my $sleeptime = 0;
798 my $starttime = [gettimeofday];
799 my $elapsed;
800
801 my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
802 push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
803
804 my $found;
805 while (($elapsed = tv_interval($starttime)) < $timeout) {
806 # -Htln = don't print header, tcp, listening sockets only, numeric ports
807 run_command($cmd, outfunc => sub {
808 my $line = shift;
809 if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
810 $found = 1 if ($port == $1);
811 }
812 });
813 return 1 if $found;
814 $sleeptime += 100000 if $sleeptime < 1000000;
815 usleep($sleeptime);
816 }
817
818 die "Timeout while waiting for port '$port' to get ready!\n";
819 }
820
821 sub next_unused_port {
822 my ($range_start, $range_end, $family, $address) = @_;
823
824 # We use a file to register allocated ports.
825 # Those registrations expires after $expiretime.
826 # We use this to avoid race conditions between
827 # allocation and use of ports.
828
829 my $filename = "/var/tmp/pve-reserved-ports";
830
831 my $code = sub {
832
833 my $expiretime = 5;
834 my $ctime = time();
835
836 my $ports = {};
837
838 if (my $fh = IO::File->new ($filename, "r")) {
839 while (my $line = <$fh>) {
840 if ($line =~ m/^(\d+)\s(\d+)$/) {
841 my ($port, $timestamp) = ($1, $2);
842 if (($timestamp + $expiretime) > $ctime) {
843 $ports->{$port} = $timestamp; # not expired
844 }
845 }
846 }
847 }
848
849 my $newport;
850 my %sockargs = (Listen => 5,
851 ReuseAddr => 1,
852 Family => $family,
853 Proto => IPPROTO_TCP,
854 GetAddrInfoFlags => 0);
855 $sockargs{LocalAddr} = $address if defined($address);
856
857 for (my $p = $range_start; $p < $range_end; $p++) {
858 next if $ports->{$p}; # reserved
859
860 $sockargs{LocalPort} = $p;
861 my $sock = IO::Socket::IP->new(%sockargs);
862
863 if ($sock) {
864 close($sock);
865 $newport = $p;
866 $ports->{$p} = $ctime;
867 last;
868 }
869 }
870
871 my $data = "";
872 foreach my $p (keys %$ports) {
873 $data .= "$p $ports->{$p}\n";
874 }
875
876 file_set_contents($filename, $data);
877
878 return $newport;
879 };
880
881 my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
882 die $@ if $@;
883
884 die "unable to find free port (${range_start}-${range_end})\n" if !$p;
885
886 return $p;
887 }
888
889 sub next_migrate_port {
890 my ($family, $address) = @_;
891 return next_unused_port(60000, 60050, $family, $address);
892 }
893
894 sub next_vnc_port {
895 my ($family, $address) = @_;
896 return next_unused_port(5900, 6000, $family, $address);
897 }
898
899 sub next_spice_port {
900 my ($family, $address) = @_;
901 return next_unused_port(61000, 61099, $family, $address);
902 }
903
904 sub must_stringify {
905 my ($value) = @_;
906 eval { $value = "$value" };
907 return "error turning value into a string: $@" if $@;
908 return $value;
909 }
910
911 # sigkill after $timeout a $sub running in a fork if it can't write a pipe
912 # the $sub has to return a single scalar
913 sub run_fork_with_timeout {
914 my ($timeout, $sub) = @_;
915
916 my $res;
917 my $error;
918 my $pipe_out = IO::Pipe->new();
919
920 # disable pending alarms, save their remaining time
921 my $prev_alarm = alarm 0;
922
923 # avoid leaving a zombie if the parent gets interrupted
924 my $sig_received;
925 local $SIG{INT} = sub { $sig_received++; };
926
927 my $child = fork();
928 if (!defined($child)) {
929 die "fork failed: $!\n";
930 return $res;
931 }
932
933 if (!$child) {
934 $pipe_out->writer();
935
936 eval {
937 $res = $sub->();
938 print {$pipe_out} encode_json({ result => $res });
939 $pipe_out->flush();
940 };
941 if (my $err = $@) {
942 print {$pipe_out} encode_json({ error => must_stringify($err) });
943 $pipe_out->flush();
944 POSIX::_exit(1);
945 }
946 POSIX::_exit(0);
947 }
948
949 $pipe_out->reader();
950
951 my $readvalues = sub {
952 local $/ = undef;
953 my $child_res = decode_json(scalar<$pipe_out>);
954 $res = $child_res->{result};
955 $error = $child_res->{error};
956 };
957 eval {
958 if (defined($timeout)) {
959 run_with_timeout($timeout, $readvalues);
960 } else {
961 $readvalues->();
962 }
963 };
964 warn $@ if $@;
965 $pipe_out->close();
966 kill('KILL', $child);
967 waitpid($child, 0);
968
969 alarm $prev_alarm;
970 die "interrupted by unexpected signal\n" if $sig_received;
971
972 die $error if $error;
973 return $res;
974 }
975
976 sub run_fork {
977 my ($code) = @_;
978 return run_fork_with_timeout(undef, $code);
979 }
980
981 # NOTE: NFS syscall can't be interrupted, so alarm does
982 # not work to provide timeouts.
983 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
984 # So fork() before using Filesys::Df
985 sub df {
986 my ($path, $timeout) = @_;
987
988 my $df = sub { return Filesys::Df::df($path, 1) };
989
990 my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
991 warn $@ if $@;
992
993 # untaint the values
994 my ($blocks, $used, $bavail) = map { defined($_) ? (/^(\d+)$/) : 0 }
995 $res->@{qw(blocks used bavail)};
996
997 return {
998 total => $blocks,
999 used => $used,
1000 avail => $bavail,
1001 };
1002 }
1003
1004 sub du {
1005 my ($path, $timeout) = @_;
1006
1007 my $size;
1008
1009 $timeout //= 10;
1010
1011 my $parser = sub {
1012 my $line = shift;
1013
1014 if ($line =~ m/^(\d+)\s+total$/) {
1015 $size = $1;
1016 }
1017 };
1018
1019 run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1020
1021 return $size;
1022 }
1023
1024 # UPID helper
1025 # We use this to uniquely identify a process.
1026 # An 'Unique Process ID' has the following format:
1027 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1028
1029 sub upid_encode {
1030 my $d = shift;
1031
1032 # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1033 # more that 8 characters for pstart
1034 return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1035 $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1036 $d->{user});
1037 }
1038
1039 sub upid_decode {
1040 my ($upid, $noerr) = @_;
1041
1042 my $res;
1043 my $filename;
1044
1045 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1046 # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1047 if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1048 $res->{node} = $1;
1049 $res->{pid} = hex($3);
1050 $res->{pstart} = hex($4);
1051 $res->{starttime} = hex($5);
1052 $res->{type} = $6;
1053 $res->{id} = $7;
1054 $res->{user} = $8;
1055
1056 my $subdir = substr($5, 7, 8);
1057 $filename = "$pvetaskdir/$subdir/$upid";
1058
1059 } else {
1060 return undef if $noerr;
1061 die "unable to parse worker upid '$upid'\n";
1062 }
1063
1064 return wantarray ? ($res, $filename) : $res;
1065 }
1066
1067 sub upid_open {
1068 my ($upid) = @_;
1069
1070 my ($task, $filename) = upid_decode($upid);
1071
1072 my $dirname = dirname($filename);
1073 make_path($dirname);
1074
1075 my $wwwid = getpwnam('www-data') ||
1076 die "getpwnam failed";
1077
1078 my $perm = 0640;
1079
1080 my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1081 die "unable to create output file '$filename' - $!\n";
1082 chown $wwwid, -1, $outfh;
1083
1084 return $outfh;
1085 };
1086
1087 sub upid_read_status {
1088 my ($upid) = @_;
1089
1090 my ($task, $filename) = upid_decode($upid);
1091 my $fh = IO::File->new($filename, "r");
1092 return "unable to open file - $!" if !$fh;
1093 my $maxlen = 4096;
1094 sysseek($fh, -$maxlen, 2);
1095 my $readbuf = '';
1096 my $br = sysread($fh, $readbuf, $maxlen);
1097 close($fh);
1098 if ($br) {
1099 return "unable to extract last line"
1100 if $readbuf !~ m/\n?(.+)$/;
1101 my $line = $1;
1102 if ($line =~ m/^TASK OK$/) {
1103 return 'OK';
1104 } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1105 return $1;
1106 } else {
1107 return "unexpected status";
1108 }
1109 }
1110 return "unable to read tail (got $br bytes)";
1111 }
1112
1113 # useful functions to store comments in config files
1114 sub encode_text {
1115 my ($text) = @_;
1116
1117 # all control and hi-bit characters, and ':'
1118 my $unsafe = "^\x20-\x39\x3b-\x7e";
1119 return uri_escape(Encode::encode("utf8", $text), $unsafe);
1120 }
1121
1122 sub decode_text {
1123 my ($data) = @_;
1124
1125 return Encode::decode("utf8", uri_unescape($data));
1126 }
1127
1128 # depreciated - do not use!
1129 # we now decode all parameters by default
1130 sub decode_utf8_parameters {
1131 my ($param) = @_;
1132
1133 foreach my $p (qw(comment description firstname lastname)) {
1134 $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1135 }
1136
1137 return $param;
1138 }
1139
1140 sub random_ether_addr {
1141 my ($prefix) = @_;
1142
1143 my ($seconds, $microseconds) = gettimeofday;
1144
1145 my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1146
1147 # clear multicast, set local id
1148 vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1149
1150 my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1151 if (defined($prefix)) {
1152 $addr = uc($prefix) . substr($addr, length($prefix));
1153 }
1154 return $addr;
1155 }
1156
1157 sub shellquote {
1158 my $str = shift;
1159
1160 return String::ShellQuote::shell_quote($str);
1161 }
1162
1163 sub cmd2string {
1164 my ($cmd) = @_;
1165
1166 die "no arguments" if !$cmd;
1167
1168 return $cmd if !ref($cmd);
1169
1170 my @qa = ();
1171 foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1172
1173 return join (' ', @qa);
1174 }
1175
1176 # split an shell argument string into an array,
1177 sub split_args {
1178 my ($str) = @_;
1179
1180 return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1181 }
1182
1183 sub dump_logfile {
1184 my ($filename, $start, $limit, $filter) = @_;
1185
1186 my $lines = [];
1187 my $count = 0;
1188
1189 my $fh = IO::File->new($filename, "r");
1190 if (!$fh) {
1191 $count++;
1192 push @$lines, { n => $count, t => "unable to open file - $!"};
1193 return ($count, $lines);
1194 }
1195
1196 $start = 0 if !$start;
1197 $limit = 50 if !$limit;
1198
1199 my $line;
1200
1201 if ($filter) {
1202 # duplicate code, so that we do not slow down normal path
1203 while (defined($line = <$fh>)) {
1204 next if $line !~ m/$filter/;
1205 next if $count++ < $start;
1206 next if $limit <= 0;
1207 chomp $line;
1208 push @$lines, { n => $count, t => $line};
1209 $limit--;
1210 }
1211 } else {
1212 while (defined($line = <$fh>)) {
1213 next if $count++ < $start;
1214 next if $limit <= 0;
1215 chomp $line;
1216 push @$lines, { n => $count, t => $line};
1217 $limit--;
1218 }
1219 }
1220
1221 close($fh);
1222
1223 # HACK: ExtJS store.guaranteeRange() does not like empty array
1224 # so we add a line
1225 if (!$count) {
1226 $count++;
1227 push @$lines, { n => $count, t => "no content"};
1228 }
1229
1230 return ($count, $lines);
1231 }
1232
1233 sub dump_journal {
1234 my ($start, $limit, $since, $until, $service) = @_;
1235
1236 my $lines = [];
1237 my $count = 0;
1238
1239 $start = 0 if !$start;
1240 $limit = 50 if !$limit;
1241
1242 my $parser = sub {
1243 my $line = shift;
1244
1245 return if $count++ < $start;
1246 return if $limit <= 0;
1247 push @$lines, { n => int($count), t => $line};
1248 $limit--;
1249 };
1250
1251 my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1252
1253 push @$cmd, '--unit', $service if $service;
1254 push @$cmd, '--since', $since if $since;
1255 push @$cmd, '--until', $until if $until;
1256 run_command($cmd, outfunc => $parser);
1257
1258 # HACK: ExtJS store.guaranteeRange() does not like empty array
1259 # so we add a line
1260 if (!$count) {
1261 $count++;
1262 push @$lines, { n => $count, t => "no content"};
1263 }
1264
1265 return ($count, $lines);
1266 }
1267
1268 sub dir_glob_regex {
1269 my ($dir, $regex) = @_;
1270
1271 my $dh = IO::Dir->new ($dir);
1272 return wantarray ? () : undef if !$dh;
1273
1274 while (defined(my $tmp = $dh->read)) {
1275 if (my @res = $tmp =~ m/^($regex)$/) {
1276 $dh->close;
1277 return wantarray ? @res : $tmp;
1278 }
1279 }
1280 $dh->close;
1281
1282 return wantarray ? () : undef;
1283 }
1284
1285 sub dir_glob_foreach {
1286 my ($dir, $regex, $func) = @_;
1287
1288 my $dh = IO::Dir->new ($dir);
1289 if (defined $dh) {
1290 while (defined(my $tmp = $dh->read)) {
1291 if (my @res = $tmp =~ m/^($regex)$/) {
1292 &$func (@res);
1293 }
1294 }
1295 }
1296 }
1297
1298 sub assert_if_modified {
1299 my ($digest1, $digest2) = @_;
1300
1301 if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1302 die "detected modified configuration - file changed by other user? Try again.\n";
1303 }
1304 }
1305
1306 # Digest for short strings
1307 # like FNV32a, but we only return 31 bits (positive numbers)
1308 sub fnv31a {
1309 my ($string) = @_;
1310
1311 my $hval = 0x811c9dc5;
1312
1313 foreach my $c (unpack('C*', $string)) {
1314 $hval ^= $c;
1315 $hval += (
1316 (($hval << 1) ) +
1317 (($hval << 4) ) +
1318 (($hval << 7) ) +
1319 (($hval << 8) ) +
1320 (($hval << 24) ) );
1321 $hval = $hval & 0xffffffff;
1322 }
1323 return $hval & 0x7fffffff;
1324 }
1325
1326 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1327
1328 sub unpack_sockaddr_in46 {
1329 my ($sin) = @_;
1330 my $family = Socket::sockaddr_family($sin);
1331 my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1332 : Socket::unpack_sockaddr_in($sin));
1333 return ($family, $port, $host);
1334 }
1335
1336 sub getaddrinfo_all {
1337 my ($hostname, @opts) = @_;
1338 my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1339 @opts );
1340 my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1341 die "failed to get address info for: $hostname: $err\n" if $err;
1342 return @res;
1343 }
1344
1345 sub get_host_address_family {
1346 my ($hostname, $socktype) = @_;
1347 my @res = getaddrinfo_all($hostname, socktype => $socktype);
1348 return $res[0]->{family};
1349 }
1350
1351 # get the fully qualified domain name of a host
1352 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1353 # given a nodename as a parameter
1354 sub get_fqdn {
1355 my ($nodename) = @_;
1356
1357 my $hints = {
1358 flags => AI_CANONNAME,
1359 socktype => SOCK_DGRAM
1360 };
1361
1362 my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1363
1364 die "getaddrinfo: $err" if $err;
1365
1366 return $addrs[0]->{canonname};
1367 }
1368
1369 # Parses any sane kind of host, or host+port pair:
1370 # The port is always optional and thus may be undef.
1371 sub parse_host_and_port {
1372 my ($address) = @_;
1373 if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ || # ipv4 or host with optional ':port'
1374 $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1375 $address =~ /^($IPV6RE)(?:\.(\d+))?$/) # ipv6 with optional port separated by dot
1376 {
1377 return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1378 }
1379 return; # nothing
1380 }
1381
1382 sub unshare($) {
1383 my ($flags) = @_;
1384 return 0 == syscall(PVE::Syscall::unshare, $flags);
1385 }
1386
1387 sub setns($$) {
1388 my ($fileno, $nstype) = @_;
1389 return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1390 }
1391
1392 sub syncfs($) {
1393 my ($fileno) = @_;
1394 return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1395 }
1396
1397 sub sync_mountpoint {
1398 my ($path) = @_;
1399 sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1400 my $result = syncfs(fileno($fd));
1401 close($fd);
1402 return $result;
1403 }
1404
1405 # support sending multi-part mail messages with a text and or a HTML part
1406 # mailto may be a single email string or an array of receivers
1407 sub sendmail {
1408 my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1409 my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1410
1411 $mailto = [ $mailto ] if !ref($mailto);
1412
1413 foreach (@$mailto) {
1414 die "illegal character in mailto address\n"
1415 if ($_ =~ $mail_re);
1416 }
1417
1418 my $rcvrtxt = join (', ', @$mailto);
1419
1420 $mailfrom = $mailfrom || "root";
1421 die "illegal character in mailfrom address\n"
1422 if $mailfrom =~ $mail_re;
1423
1424 $author = $author || 'Proxmox VE';
1425
1426 open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1427 die "unable to open 'sendmail' - $!";
1428
1429 # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1430 my $boundary = "----_=_NextPart_001_".int(time).$$;
1431
1432 print MAIL "Content-Type: multipart/alternative;\n";
1433 print MAIL "\tboundary=\"$boundary\"\n";
1434 print MAIL "MIME-Version: 1.0\n";
1435
1436 print MAIL "FROM: $author <$mailfrom>\n";
1437 print MAIL "TO: $rcvrtxt\n";
1438 print MAIL "SUBJECT: $subject\n";
1439 print MAIL "\n";
1440 print MAIL "This is a multi-part message in MIME format.\n\n";
1441 print MAIL "--$boundary\n";
1442
1443 if (defined($text)) {
1444 print MAIL "Content-Type: text/plain;\n";
1445 print MAIL "\tcharset=\"UTF8\"\n";
1446 print MAIL "Content-Transfer-Encoding: 8bit\n";
1447 print MAIL "\n";
1448
1449 # avoid 'remove extra line breaks' issue (MS Outlook)
1450 my $fill = ' ';
1451 $text =~ s/^/$fill/gm;
1452
1453 print MAIL $text;
1454
1455 print MAIL "\n--$boundary\n";
1456 }
1457
1458 if (defined($html)) {
1459 print MAIL "Content-Type: text/html;\n";
1460 print MAIL "\tcharset=\"UTF8\"\n";
1461 print MAIL "Content-Transfer-Encoding: 8bit\n";
1462 print MAIL "\n";
1463
1464 print MAIL $html;
1465
1466 print MAIL "\n--$boundary--\n";
1467 }
1468
1469 close(MAIL);
1470 }
1471
1472 sub tempfile {
1473 my ($perm, %opts) = @_;
1474
1475 # default permissions are stricter than with file_set_contents
1476 $perm = 0600 if !defined($perm);
1477
1478 my $dir = $opts{dir} // '/run';
1479 my $mode = $opts{mode} // O_RDWR;
1480 $mode |= O_EXCL if !$opts{allow_links};
1481
1482 my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1483 if (!$fh && $! == EOPNOTSUPP) {
1484 $dir = '/tmp' if !defined($opts{dir});
1485 $dir .= "/.tmpfile.$$";
1486 $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1487 unlink($dir) if $fh;
1488 }
1489 die "failed to create tempfile: $!\n" if !$fh;
1490 return $fh;
1491 }
1492
1493 sub tempfile_contents {
1494 my ($data, $perm, %opts) = @_;
1495
1496 my $fh = tempfile($perm, %opts);
1497 eval {
1498 die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1499 die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1500 };
1501 if (my $err = $@) {
1502 close $fh;
1503 die $err;
1504 }
1505
1506 return ("/proc/$$/fd/".$fh->fileno, $fh);
1507 }
1508
1509 sub validate_ssh_public_keys {
1510 my ($raw) = @_;
1511 my @lines = split(/\n/, $raw);
1512
1513 foreach my $line (@lines) {
1514 next if $line =~ m/^\s*$/;
1515 eval {
1516 my ($filename, $handle) = tempfile_contents($line);
1517 run_command(["ssh-keygen", "-l", "-f", $filename],
1518 outfunc => sub {}, errfunc => sub {});
1519 };
1520 die "SSH public key validation error\n" if $@;
1521 }
1522 }
1523
1524 sub openat($$$;$) {
1525 my ($dirfd, $pathname, $flags, $mode) = @_;
1526 my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1527 return undef if $fd < 0;
1528 # sysopen() doesn't deal with numeric file descriptors apparently
1529 # so we need to convert to a mode string for IO::Handle->new_from_fd
1530 my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1531 my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1532 return $handle if $handle;
1533 my $err = $!; # save error before closing the raw fd
1534 syscall(PVE::Syscall::close, $fd); # close
1535 $! = $err;
1536 return undef;
1537 }
1538
1539 sub mkdirat($$$) {
1540 my ($dirfd, $name, $mode) = @_;
1541 return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1542 }
1543
1544 my $salt_starter = time();
1545
1546 sub encrypt_pw {
1547 my ($pw) = @_;
1548
1549 $salt_starter++;
1550 my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1551
1552 # crypt does not want '+' in salt (see 'man crypt')
1553 $salt =~ s/\+/X/g;
1554
1555 return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1556 }
1557
1558 # intended usage: convert_size($val, "kb" => "gb")
1559 # we round up to the next integer by default
1560 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1561 # use $no_round_up to switch this off, above example would then return 0
1562 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1563 # (0 if $no_round_up is true)
1564 # allowed formats for value:
1565 # 1234
1566 # 1234.
1567 # 1234.1234
1568 # .1234
1569 sub convert_size {
1570 my ($value, $from, $to, $no_round_up) = @_;
1571
1572 my $units = {
1573 b => 0,
1574 kb => 1,
1575 mb => 2,
1576 gb => 3,
1577 tb => 4,
1578 pb => 5,
1579 };
1580
1581 die "no value given"
1582 if !defined($value) || $value eq "";
1583
1584 $from = lc($from // ''); $to = lc($to // '');
1585 die "unknown 'from' and/or 'to' units ($from => $to)"
1586 if !defined($units->{$from}) || !defined($units->{$to});
1587
1588 die "value '$value' is not a valid, positive number"
1589 if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1590
1591 my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1592
1593 $value *= 2**$shift_amount;
1594 $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1595
1596 return int($value);
1597 }
1598
1599 1;