src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Net::DBus qw(dbus_uint32 dbus_uint64);
  28 use Net::DBus::Callback;
  29 use Net::DBus::Reactor;
  30 use Scalar::Util 'weaken';
  31 use PVE::Syscall;
  32
  33 # avoid warning when parsing long hex values with hex()
  34 no warnings 'portable'; # Support for 64-bit ints required
  35
  36 our @EXPORT_OK = qw(
  37 $IPV6RE
  38 $IPV4RE
  39 lock_file
  40 lock_file_full
  41 run_command
  42 file_set_contents
  43 file_get_contents
  44 file_read_firstline
  45 dir_glob_regex
  46 dir_glob_foreach
  47 split_list
  48 template_replace
  49 safe_print
  50 trim
  51 extract_param
  52 file_copy
  53 O_PATH
  54 O_TMPFILE
  55 );
  56
  57 my $pvelogdir = "/var/log/pve";
  58 my $pvetaskdir = "$pvelogdir/tasks";
  59
  60 mkdir $pvelogdir;
  61 mkdir $pvetaskdir;
  62
  63 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  64 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  65 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  66 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  67
  68 our $IPV6RE = "(?:" .
  69     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  70     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  71     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  72     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  73     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  74     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  75     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  76     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  77     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  78
  79 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  80
  81 use constant {CLONE_NEWNS   => 0x00020000,
  82               CLONE_NEWUTS  => 0x04000000,
  83               CLONE_NEWIPC  => 0x08000000,
  84               CLONE_NEWUSER => 0x10000000,
  85               CLONE_NEWPID  => 0x20000000,
  86               CLONE_NEWNET  => 0x40000000};
  87
  88 use constant {O_PATH    => 0x00200000,
  89               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  90
  91 sub run_with_timeout {
  92     my ($timeout, $code, @param) = @_;
  93
  94     die "got timeout\n" if $timeout <= 0;
  95
  96     my $prev_alarm = alarm 0; # suspend outer alarm early
  97
  98     my $sigcount = 0;
  99
 100     my $res;
 101
 102     eval {
 103         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 104         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 105         local $SIG{__DIE__};   # see SA bug 4631
 106
 107         alarm($timeout);
 108
 109         eval { $res = &$code(@param); };
 110
 111         alarm(0); # avoid race conditions
 112
 113         die $@ if $@;
 114     };
 115
 116     my $err = $@;
 117
 118     alarm $prev_alarm;
 119
 120     # this shouldn't happen anymore?
 121     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 122
 123     die $err if $err;
 124
 125     return $res;
 126 }
 127
 128 # flock: we use one file handle per process, so lock file
 129 # can be nested multiple times and succeeds for the same process.
 130 #
 131 # Since this is the only way we lock now and we don't have the old
 132 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 133 # count how deep we're nesting. Therefore this hash now stores a weak reference
 134 # to a boolean telling us whether we already have a lock.
 135
 136 my $lock_handles =  {};
 137
 138 sub lock_file_full {
 139     my ($filename, $timeout, $shared, $code, @param) = @_;
 140
 141     $timeout = 10 if !$timeout;
 142
 143     my $mode = $shared ? LOCK_SH : LOCK_EX;
 144
 145     my $lockhash = ($lock_handles->{$$} //= {});
 146
 147     # Returns a locked file handle.
 148     my $get_locked_file = sub {
 149         my $fh = IO::File->new(">>$filename")
 150             or die "can't open file - $!\n";
 151
 152         if (!flock($fh, $mode|LOCK_NB)) {
 153             print STDERR "trying to acquire lock...\n";
 154             my $success;
 155             while(1) {
 156                 $success = flock($fh, $mode);
 157                 # try again on EINTR (see bug #273)
 158                 if ($success || ($! != EINTR)) {
 159                     last;
 160                 }
 161             }
 162             if (!$success) {
 163                 print STDERR " failed\n";
 164                 die "can't acquire lock '$filename' - $!\n";
 165             }
 166             print STDERR " OK\n";
 167         }
 168
 169         return $fh;
 170     };
 171
 172     my $res;
 173     my $checkptr = $lockhash->{$filename};
 174     my $check = 0; # This must not go out of scope before running the code.
 175     my $local_fh; # This must stay local
 176     if (!$checkptr || !$$checkptr) {
 177         # We cannot create a weak reference in a single atomic step, so we first
 178         # create a false-value, then create a reference to it, then weaken it,
 179         # and after successfully locking the file we change the boolean value.
 180         #
 181         # The reason for this is that if an outer SIGALRM throws an exception
 182         # between creating the reference and weakening it, a subsequent call to
 183         # lock_file_full() will see a leftover full reference to a valid
 184         # variable. This variable must be 0 in order for said call to attempt to
 185         # lock the file anew.
 186         #
 187         # An externally triggered exception elsewhere in the code will cause the
 188         # weak reference to become 'undef', and since the file handle is only
 189         # stored in the local scope in $local_fh, the file will be closed by
 190         # perl's cleanup routines as well.
 191         #
 192         # This still assumes that an IO::File handle can properly deal with such
 193         # exceptions thrown during its own destruction, but that's up to perls
 194         # guts now.
 195         $lockhash->{$filename} = \$check;
 196         weaken $lockhash->{$filename};
 197         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 198         if ($@) {
 199             $@ = "can't lock file '$filename' - $@";
 200             return undef;
 201         }
 202         $check = 1;
 203     }
 204     $res = eval { &$code(@param); };
 205     return undef if $@;
 206     return $res;
 207 }
 208
 209
 210 sub lock_file {
 211     my ($filename, $timeout, $code, @param) = @_;
 212
 213     return lock_file_full($filename, $timeout, 0, $code, @param);
 214 }
 215
 216 sub file_set_contents {
 217     my ($filename, $data, $perm)  = @_;
 218
 219     $perm = 0644 if !defined($perm);
 220
 221     my $tmpname = "$filename.tmp.$$";
 222
 223     eval {
 224         my ($fh, $tries) = (undef, 0);
 225         while (!$fh && $tries++ < 3) {
 226             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 227             if (!$fh && $! == EEXIST) {
 228                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 229             }
 230         }
 231         die "unable to open file '$tmpname' - $!\n" if !$fh;
 232         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 233         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 234     };
 235     my $err = $@;
 236
 237     if ($err) {
 238         unlink $tmpname;
 239         die $err;
 240     }
 241
 242     if (!rename($tmpname, $filename)) {
 243         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 244         unlink $tmpname;
 245         die $msg;
 246     }
 247 }
 248
 249 sub file_get_contents {
 250     my ($filename, $max) = @_;
 251
 252     my $fh = IO::File->new($filename, "r") ||
 253         die "can't open '$filename' - $!\n";
 254
 255     my $content = safe_read_from($fh, $max, 0, $filename);
 256
 257     close $fh;
 258
 259     return $content;
 260 }
 261
 262 sub file_copy {
 263     my ($filename, $dst, $max, $perm) = @_;
 264
 265     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 266 }
 267
 268 sub file_read_firstline {
 269     my ($filename) = @_;
 270
 271     my $fh = IO::File->new ($filename, "r");
 272     return undef if !$fh;
 273     my $res = <$fh>;
 274     chomp $res if $res;
 275     $fh->close;
 276     return $res;
 277 }
 278
 279 sub safe_read_from {
 280     my ($fh, $max, $oneline, $filename) = @_;
 281
 282     $max = 32768 if !$max;
 283
 284     my $subject = defined($filename) ? "file '$filename'" : 'input';
 285
 286     my $br = 0;
 287     my $input = '';
 288     my $count;
 289     while ($count = sysread($fh, $input, 8192, $br)) {
 290         $br += $count;
 291         die "$subject too long - aborting\n" if $br > $max;
 292         if ($oneline && $input =~ m/^(.*)\n/) {
 293             $input = $1;
 294             last;
 295         }
 296     }
 297     die "unable to read $subject - $!\n" if !defined($count);
 298
 299     return $input;
 300 }
 301
 302 # The $cmd parameter can be:
 303 #  -) a string
 304 #    This is generally executed by passing it to the shell with the -c option.
 305 #    However, it can be executed in one of two ways, depending on whether
 306 #    there's a pipe involved:
 307 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 308 #          set -o pipefail &&
 309 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 310 #      (Note that this may result in two different syntax requirements!)
 311 #      FIXME?
 312 #  -) an array of arguments (strings)
 313 #    Will be executed without interference from a shell. (Parameters are passed
 314 #    as is, no escape sequences of strings will be touched.)
 315 #  -) an array of arrays
 316 #    Each array represents a command, and each command's output is piped into
 317 #    the following command's standard input.
 318 #    For this a shell command string is created with pipe symbols between each
 319 #    command.
 320 #    Each command is a list of strings meant to end up in the final command
 321 #    unchanged. In order to achieve this, every argument is shell-quoted.
 322 #    Quoting can be disabled for a particular argument by turning it into a
 323 #    reference, this allows inserting arbitrary shell options.
 324 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 325 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 326 #    will literally print: hello >/dev/null
 327 sub run_command {
 328     my ($cmd, %param) = @_;
 329
 330     my $old_umask;
 331     my $cmdstr;
 332
 333     if (my $ref = ref($cmd)) {
 334         if (ref($cmd->[0])) {
 335             $cmdstr = 'set -o pipefail && ';
 336             my $pipe = '';
 337             foreach my $command (@$cmd) {
 338                 # concatenate quoted parameters
 339                 # strings which are passed by reference are NOT shell quoted
 340                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 341                 $pipe = ' | ';
 342             }
 343             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 344         } else {
 345             $cmdstr = cmd2string($cmd);
 346         }
 347     } else {
 348         $cmdstr = $cmd;
 349         if ($cmd =~ m/\|/) {
 350             # see 'man bash' for option pipefail
 351             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 352         } else {
 353             $cmd = [ $cmd ];
 354         }
 355     }
 356
 357     my $errmsg;
 358     my $laststderr;
 359     my $timeout;
 360     my $oldtimeout;
 361     my $pid;
 362     my $exitcode = -1;
 363
 364     my $outfunc;
 365     my $errfunc;
 366     my $logfunc;
 367     my $input;
 368     my $output;
 369     my $afterfork;
 370     my $noerr;
 371     my $keeplocale;
 372     my $quiet;
 373
 374     eval {
 375
 376         foreach my $p (keys %param) {
 377             if ($p eq 'timeout') {
 378                 $timeout = $param{$p};
 379             } elsif ($p eq 'umask') {
 380                 $old_umask = umask($param{$p});
 381             } elsif ($p eq 'errmsg') {
 382                 $errmsg = $param{$p};
 383             } elsif ($p eq 'input') {
 384                 $input = $param{$p};
 385             } elsif ($p eq 'output') {
 386                 $output = $param{$p};
 387             } elsif ($p eq 'outfunc') {
 388                 $outfunc = $param{$p};
 389             } elsif ($p eq 'errfunc') {
 390                 $errfunc = $param{$p};
 391             } elsif ($p eq 'logfunc') {
 392                 $logfunc = $param{$p};
 393             } elsif ($p eq 'afterfork') {
 394                 $afterfork = $param{$p};
 395             } elsif ($p eq 'noerr') {
 396                 $noerr = $param{$p};
 397             } elsif ($p eq 'keeplocale') {
 398                 $keeplocale = $param{$p};
 399             } elsif ($p eq 'quiet') {
 400                 $quiet = $param{$p};
 401             } else {
 402                 die "got unknown parameter '$p' for run_command\n";
 403             }
 404         }
 405
 406         if ($errmsg) {
 407             my $origerrfunc = $errfunc;
 408             $errfunc = sub {
 409                 if ($laststderr) {
 410                     if ($origerrfunc) {
 411                         &$origerrfunc("$laststderr\n");
 412                     } else {
 413                         print STDERR "$laststderr\n" if $laststderr;
 414                     }
 415                 }
 416                 $laststderr = shift;
 417             };
 418         }
 419
 420         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 421         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 422         my $error  = IO::File->new();
 423
 424         my $orig_pid = $$;
 425
 426         eval {
 427             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 428
 429             # suppress LVM warnings like: "File descriptor 3 left open";
 430             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 431
 432             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 433
 434             # if we pipe fron STDIN, open3 closes STDIN, so we we
 435             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 436             # as soon as we open a new file.
 437             # to avoid that we open /dev/null
 438             if (!ref($writer) && !defined(fileno(STDIN))) {
 439                 POSIX::close(0);
 440                 open(STDIN, "</dev/null");
 441             }
 442         };
 443
 444         my $err = $@;
 445
 446         # catch exec errors
 447         if ($orig_pid != $$) {
 448             warn "ERROR: $err";
 449             POSIX::_exit (1);
 450             kill ('KILL', $$);
 451         }
 452
 453         die $err if $err;
 454
 455         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 456         $oldtimeout = alarm($timeout) if $timeout;
 457
 458         &$afterfork() if $afterfork;
 459
 460         if (ref($writer)) {
 461             print $writer $input if defined $input;
 462             close $writer;
 463         }
 464
 465         my $select = new IO::Select;
 466         $select->add($reader) if ref($reader);
 467         $select->add($error);
 468
 469         my $outlog = '';
 470         my $errlog = '';
 471
 472         my $starttime = time();
 473
 474         while ($select->count) {
 475             my @handles = $select->can_read(1);
 476
 477             foreach my $h (@handles) {
 478                 my $buf = '';
 479                 my $count = sysread ($h, $buf, 4096);
 480                 if (!defined ($count)) {
 481                     my $err = $!;
 482                     kill (9, $pid);
 483                     waitpid ($pid, 0);
 484                     die $err;
 485                 }
 486                 $select->remove ($h) if !$count;
 487                 if ($h eq $reader) {
 488                     if ($outfunc || $logfunc) {
 489                         eval {
 490                             $outlog .= $buf;
 491                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 492                                 my $line = $1;
 493                                 &$outfunc($line) if $outfunc;
 494                                 &$logfunc($line) if $logfunc;
 495                             }
 496                         };
 497                         my $err = $@;
 498                         if ($err) {
 499                             kill (9, $pid);
 500                             waitpid ($pid, 0);
 501                             die $err;
 502                         }
 503                     } elsif (!$quiet) {
 504                         print $buf;
 505                         *STDOUT->flush();
 506                     }
 507                 } elsif ($h eq $error) {
 508                     if ($errfunc || $logfunc) {
 509                         eval {
 510                             $errlog .= $buf;
 511                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 512                                 my $line = $1;
 513                                 &$errfunc($line) if $errfunc;
 514                                 &$logfunc($line) if $logfunc;
 515                             }
 516                         };
 517                         my $err = $@;
 518                         if ($err) {
 519                             kill (9, $pid);
 520                             waitpid ($pid, 0);
 521                             die $err;
 522                         }
 523                     } elsif (!$quiet) {
 524                         print STDERR $buf;
 525                         *STDERR->flush();
 526                     }
 527                 }
 528             }
 529         }
 530
 531         &$outfunc($outlog) if $outfunc && $outlog;
 532         &$logfunc($outlog) if $logfunc && $outlog;
 533
 534         &$errfunc($errlog) if $errfunc && $errlog;
 535         &$logfunc($errlog) if $logfunc && $errlog;
 536
 537         waitpid ($pid, 0);
 538
 539         if ($? == -1) {
 540             die "failed to execute\n";
 541         } elsif (my $sig = ($? & 127)) {
 542             die "got signal $sig\n";
 543         } elsif ($exitcode = ($? >> 8)) {
 544             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 545                 if ($errmsg && $laststderr) {
 546                     my $lerr = $laststderr;
 547                     $laststderr = undef;
 548                     die "$lerr\n";
 549                 }
 550                 die "exit code $exitcode\n";
 551             }
 552         }
 553
 554         alarm(0);
 555     };
 556
 557     my $err = $@;
 558
 559     alarm(0);
 560
 561     if ($errmsg && $laststderr) {
 562         &$errfunc(undef); # flush laststderr
 563     }
 564
 565     umask ($old_umask) if defined($old_umask);
 566
 567     alarm($oldtimeout) if $oldtimeout;
 568
 569     if ($err) {
 570         if ($pid && ($err eq "got timeout\n")) {
 571             kill (9, $pid);
 572             waitpid ($pid, 0);
 573             die "command '$cmdstr' failed: $err";
 574         }
 575
 576         if ($errmsg) {
 577             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 578             die "$errmsg: $err";
 579         } elsif(!$noerr) {
 580             die "command '$cmdstr' failed: $err";
 581         }
 582     }
 583
 584     return $exitcode;
 585 }
 586
 587 # Run a command with a tcp socket as standard input.
 588 sub pipe_socket_to_command  {
 589     my ($cmd, $ip, $port) = @_;
 590
 591     my $params = {
 592         Listen => 1,
 593         ReuseAddr => 1,
 594         Proto => &Socket::IPPROTO_TCP,
 595         GetAddrInfoFlags => 0,
 596         LocalAddr => $ip,
 597         LocalPort => $port,
 598     };
 599     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 600
 601     print "$ip\n$port\n"; # tell remote where to connect
 602     *STDOUT->flush();
 603
 604     alarm 0;
 605     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 606     alarm 30;
 607     my $client = $socket->accept; # Wait for a client
 608     alarm 0;
 609     close($socket);
 610
 611     # We want that the command talks over the TCP socket and takes
 612     # ownership of it, so that when it closes it the connection is
 613     # terminated, so we need to be able to close the socket. So we
 614     # can't really use PVE::Tools::run_command().
 615     my $pid = fork() // die "fork failed: $!\n";
 616     if (!$pid) {
 617         POSIX::dup2(fileno($client), 0);
 618         POSIX::dup2(fileno($client), 1);
 619         close($client);
 620         exec {$cmd->[0]} @$cmd or do {
 621             warn "exec failed: $!\n";
 622             POSIX::_exit(1);
 623         };
 624     }
 625
 626     close($client);
 627     if (waitpid($pid, 0) != $pid) {
 628         kill(15 => $pid); # if we got interrupted terminate the child
 629         my $count = 0;
 630         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 631             usleep(100000);
 632             $count++;
 633             kill(9 => $pid), last if $count > 300; # 30 second timeout
 634         }
 635     }
 636     if (my $sig = ($? & 127)) {
 637         die "got signal $sig\n";
 638     } elsif (my $exitcode = ($? >> 8)) {
 639         die "exit code $exitcode\n";
 640     }
 641
 642     return undef;
 643 }
 644
 645 sub split_list {
 646     my $listtxt = shift || '';
 647
 648     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 649
 650     $listtxt =~ s/[,;]/ /g;
 651     $listtxt =~ s/^\s+//;
 652
 653     my @data = split (/\s+/, $listtxt);
 654
 655     return @data;
 656 }
 657
 658 sub trim {
 659     my $txt = shift;
 660
 661     return $txt if !defined($txt);
 662
 663     $txt =~ s/^\s+//;
 664     $txt =~ s/\s+$//;
 665
 666     return $txt;
 667 }
 668
 669 # simple uri templates like "/vms/{vmid}"
 670 sub template_replace {
 671     my ($tmpl, $data) = @_;
 672
 673     return $tmpl if !$tmpl;
 674
 675     my $res = '';
 676     while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) {
 677         $res .= $1 if $1;
 678         $res .= ($data->{$3} || '-') if $2;
 679     }
 680     return $res;
 681 }
 682
 683 sub safe_print {
 684     my ($filename, $fh, $data) = @_;
 685
 686     return if !$data;
 687
 688     my $res = print $fh $data;
 689
 690     die "write to '$filename' failed\n" if !$res;
 691 }
 692
 693 sub debmirrors {
 694
 695     return {
 696         'at' => 'ftp.at.debian.org',
 697         'au' => 'ftp.au.debian.org',
 698         'be' => 'ftp.be.debian.org',
 699         'bg' => 'ftp.bg.debian.org',
 700         'br' => 'ftp.br.debian.org',
 701         'ca' => 'ftp.ca.debian.org',
 702         'ch' => 'ftp.ch.debian.org',
 703         'cl' => 'ftp.cl.debian.org',
 704         'cz' => 'ftp.cz.debian.org',
 705         'de' => 'ftp.de.debian.org',
 706         'dk' => 'ftp.dk.debian.org',
 707         'ee' => 'ftp.ee.debian.org',
 708         'es' => 'ftp.es.debian.org',
 709         'fi' => 'ftp.fi.debian.org',
 710         'fr' => 'ftp.fr.debian.org',
 711         'gr' => 'ftp.gr.debian.org',
 712         'hk' => 'ftp.hk.debian.org',
 713         'hr' => 'ftp.hr.debian.org',
 714         'hu' => 'ftp.hu.debian.org',
 715         'ie' => 'ftp.ie.debian.org',
 716         'is' => 'ftp.is.debian.org',
 717         'it' => 'ftp.it.debian.org',
 718         'jp' => 'ftp.jp.debian.org',
 719         'kr' => 'ftp.kr.debian.org',
 720         'mx' => 'ftp.mx.debian.org',
 721         'nl' => 'ftp.nl.debian.org',
 722         'no' => 'ftp.no.debian.org',
 723         'nz' => 'ftp.nz.debian.org',
 724         'pl' => 'ftp.pl.debian.org',
 725         'pt' => 'ftp.pt.debian.org',
 726         'ro' => 'ftp.ro.debian.org',
 727         'ru' => 'ftp.ru.debian.org',
 728         'se' => 'ftp.se.debian.org',
 729         'si' => 'ftp.si.debian.org',
 730         'sk' => 'ftp.sk.debian.org',
 731         'tr' => 'ftp.tr.debian.org',
 732         'tw' => 'ftp.tw.debian.org',
 733         'gb' => 'ftp.uk.debian.org',
 734         'us' => 'ftp.us.debian.org',
 735     };
 736 }
 737
 738 my $keymaphash =  {
 739     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 740     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 741     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 742     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 743     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 744     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 745     #'et'     => [], # Ethopia or Estonia ??
 746     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 747     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 748     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 749     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 750     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 751     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 752     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 753     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 754     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 755     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 756     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 757     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 758     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 759     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 760     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 761     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 762     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 763     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 764     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 765     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 766     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know?
 767     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 768     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 769     #'th'     => [],
 770     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 771 };
 772
 773 my $kvmkeymaparray = [];
 774 foreach my $lc (sort keys %$keymaphash) {
 775     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 776 }
 777
 778 sub kvmkeymaps {
 779     return $keymaphash;
 780 }
 781
 782 sub kvmkeymaplist {
 783     return $kvmkeymaparray;
 784 }
 785
 786 sub extract_param {
 787     my ($param, $key) = @_;
 788
 789     my $res = $param->{$key};
 790     delete $param->{$key};
 791
 792     return $res;
 793 }
 794
 795 # Note: we use this to wait until vncterm/spiceterm is ready
 796 sub wait_for_vnc_port {
 797     my ($port, $family, $timeout) = @_;
 798
 799     $timeout = 5 if !$timeout;
 800     my $sleeptime = 0;
 801     my $starttime = [gettimeofday];
 802     my $elapsed;
 803
 804     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 805     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 806
 807     my $found;
 808     while (($elapsed = tv_interval($starttime)) < $timeout) {
 809         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 810         run_command($cmd, outfunc => sub {
 811             my $line = shift;
 812             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 813                 $found = 1 if ($port == $1);
 814             }
 815         });
 816         return 1 if $found;
 817         $sleeptime += 100000 if  $sleeptime < 1000000;
 818         usleep($sleeptime);
 819     }
 820
 821     die "Timeout while waiting for port '$port' to get ready!\n";
 822 }
 823
 824 sub next_unused_port {
 825     my ($range_start, $range_end, $family, $address) = @_;
 826
 827     # We use a file to register allocated ports.
 828     # Those registrations expires after $expiretime.
 829     # We use this to avoid race conditions between
 830     # allocation and use of ports.
 831
 832     my $filename = "/var/tmp/pve-reserved-ports";
 833
 834     my $code = sub {
 835
 836         my $expiretime = 5;
 837         my $ctime = time();
 838
 839         my $ports = {};
 840
 841         if (my $fh = IO::File->new ($filename, "r")) {
 842             while (my $line = <$fh>) {
 843                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 844                     my ($port, $timestamp) = ($1, $2);
 845                     if (($timestamp + $expiretime) > $ctime) {
 846                         $ports->{$port} = $timestamp; # not expired
 847                     }
 848                 }
 849             }
 850         }
 851
 852         my $newport;
 853         my %sockargs = (Listen => 5,
 854                         ReuseAddr => 1,
 855                         Family    => $family,
 856                         Proto     => IPPROTO_TCP,
 857                         GetAddrInfoFlags => 0);
 858         $sockargs{LocalAddr} = $address if defined($address);
 859
 860         for (my $p = $range_start; $p < $range_end; $p++) {
 861             next if $ports->{$p}; # reserved
 862
 863             $sockargs{LocalPort} = $p;
 864             my $sock = IO::Socket::IP->new(%sockargs);
 865
 866             if ($sock) {
 867                 close($sock);
 868                 $newport = $p;
 869                 $ports->{$p} = $ctime;
 870                 last;
 871             }
 872         }
 873
 874         my $data = "";
 875         foreach my $p (keys %$ports) {
 876             $data .= "$p $ports->{$p}\n";
 877         }
 878
 879         file_set_contents($filename, $data);
 880
 881         return $newport;
 882     };
 883
 884     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 885     die $@ if $@;
 886
 887     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 888
 889     return $p;
 890 }
 891
 892 sub next_migrate_port {
 893     my ($family, $address) = @_;
 894     return next_unused_port(60000, 60050, $family, $address);
 895 }
 896
 897 sub next_vnc_port {
 898     my ($family, $address) = @_;
 899     return next_unused_port(5900, 6000, $family, $address);
 900 }
 901
 902 sub next_spice_port {
 903     my ($family, $address) = @_;
 904     return next_unused_port(61000, 61099, $family, $address);
 905 }
 906
 907 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 908 # the $sub has to return a single scalar
 909 sub run_fork_with_timeout {
 910     my ($timeout, $sub) = @_;
 911
 912     my $res;
 913     my $error;
 914     my $pipe_out = IO::Pipe->new();
 915
 916     # disable pending alarms, save their remaining time
 917     my $prev_alarm = alarm 0;
 918
 919     # avoid leaving a zombie if the parent gets interrupted
 920     my $sig_received;
 921     local $SIG{INT} = sub { $sig_received++; };
 922
 923     my $child = fork();
 924     if (!defined($child)) {
 925         die "fork failed: $!\n";
 926         return $res;
 927     }
 928
 929     if (!$child) {
 930         $pipe_out->writer();
 931
 932         eval {
 933             $res = $sub->();
 934             print {$pipe_out} encode_json({ result => $res });
 935             $pipe_out->flush();
 936         };
 937         if (my $err = $@) {
 938             print {$pipe_out} encode_json({ error => $err });
 939             $pipe_out->flush();
 940             POSIX::_exit(1);
 941         }
 942         POSIX::_exit(0);
 943     }
 944
 945     $pipe_out->reader();
 946
 947     my $readvalues = sub {
 948         local $/ = undef;
 949         my $child_res = decode_json(scalar<$pipe_out>);
 950         $res = $child_res->{result};
 951         $error = $child_res->{error};
 952     };
 953     eval {
 954         if (defined($timeout)) {
 955             run_with_timeout($timeout, $readvalues);
 956         } else {
 957             $readvalues->();
 958         }
 959     };
 960     warn $@ if $@;
 961     $pipe_out->close();
 962     kill('KILL', $child);
 963     waitpid($child, 0);
 964
 965     alarm $prev_alarm;
 966     die "interrupted by unexpected signal\n" if $sig_received;
 967
 968     die $error if $error;
 969     return $res;
 970 }
 971
 972 sub run_fork {
 973     my ($code) = @_;
 974     return run_fork_with_timeout(undef, $code);
 975 }
 976
 977 # NOTE: NFS syscall can't be interrupted, so alarm does
 978 # not work to provide timeouts.
 979 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
 980 # So fork() before using Filesys::Df
 981 sub df {
 982     my ($path, $timeout) = @_;
 983
 984     my $df = sub { return Filesys::Df::df($path, 1) };
 985
 986     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
 987     warn $@ if $@;
 988
 989     # untaint the values
 990     my ($blocks, $used, $bavail) = map { defined($_) ? (/^(\d+)$/) : 0 }
 991         $res->@{qw(blocks used bavail)};
 992
 993     return {
 994         total => $blocks,
 995         used => $used,
 996         avail => $bavail,
 997     };
 998 }
 999
1000 sub du {
1001     my ($path, $timeout) = @_;
1002
1003     my $size;
1004
1005     $timeout //= 10;
1006
1007     my $parser = sub {
1008         my $line = shift;
1009
1010         if ($line =~ m/^(\d+)\s+total$/) {
1011             $size = $1;
1012         }
1013     };
1014
1015     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1016
1017     return $size;
1018 }
1019
1020 # UPID helper
1021 # We use this to uniquely identify a process.
1022 # An 'Unique Process ID' has the following format:
1023 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1024
1025 sub upid_encode {
1026     my $d = shift;
1027
1028     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1029     # more that 8 characters for pstart
1030     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1031                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1032                    $d->{user});
1033 }
1034
1035 sub upid_decode {
1036     my ($upid, $noerr) = @_;
1037
1038     my $res;
1039     my $filename;
1040
1041     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1042     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1043     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1044         $res->{node} = $1;
1045         $res->{pid} = hex($3);
1046         $res->{pstart} = hex($4);
1047         $res->{starttime} = hex($5);
1048         $res->{type} = $6;
1049         $res->{id} = $7;
1050         $res->{user} = $8;
1051
1052         my $subdir = substr($5, 7, 8);
1053         $filename = "$pvetaskdir/$subdir/$upid";
1054
1055     } else {
1056         return undef if $noerr;
1057         die "unable to parse worker upid '$upid'\n";
1058     }
1059
1060     return wantarray ? ($res, $filename) : $res;
1061 }
1062
1063 sub upid_open {
1064     my ($upid) = @_;
1065
1066     my ($task, $filename) = upid_decode($upid);
1067
1068     my $dirname = dirname($filename);
1069     make_path($dirname);
1070
1071     my $wwwid = getpwnam('www-data') ||
1072         die "getpwnam failed";
1073
1074     my $perm = 0640;
1075
1076     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1077         die "unable to create output file '$filename' - $!\n";
1078     chown $wwwid, -1, $outfh;
1079
1080     return $outfh;
1081 };
1082
1083 sub upid_read_status {
1084     my ($upid) = @_;
1085
1086     my ($task, $filename) = upid_decode($upid);
1087     my $fh = IO::File->new($filename, "r");
1088     return "unable to open file - $!" if !$fh;
1089     my $maxlen = 4096;
1090     sysseek($fh, -$maxlen, 2);
1091     my $readbuf = '';
1092     my $br = sysread($fh, $readbuf, $maxlen);
1093     close($fh);
1094     if ($br) {
1095         return "unable to extract last line"
1096             if $readbuf !~ m/\n?(.+)$/;
1097         my $line = $1;
1098         if ($line =~ m/^TASK OK$/) {
1099             return 'OK';
1100         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1101             return $1;
1102         } else {
1103             return "unexpected status";
1104         }
1105     }
1106     return "unable to read tail (got $br bytes)";
1107 }
1108
1109 # useful functions to store comments in config files
1110 sub encode_text {
1111     my ($text) = @_;
1112
1113     # all control and hi-bit characters, and ':'
1114     my $unsafe = "^\x20-\x39\x3b-\x7e";
1115     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1116 }
1117
1118 sub decode_text {
1119     my ($data) = @_;
1120
1121     return Encode::decode("utf8", uri_unescape($data));
1122 }
1123
1124 # depreciated - do not use!
1125 # we now decode all parameters by default
1126 sub decode_utf8_parameters {
1127     my ($param) = @_;
1128
1129     foreach my $p (qw(comment description firstname lastname)) {
1130         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1131     }
1132
1133     return $param;
1134 }
1135
1136 sub random_ether_addr {
1137     my ($prefix) = @_;
1138
1139     my ($seconds, $microseconds) = gettimeofday;
1140
1141     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1142
1143     # clear multicast, set local id
1144     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1145
1146     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1147     if (defined($prefix)) {
1148         $addr = uc($prefix) . substr($addr, length($prefix));
1149     }
1150     return $addr;
1151 }
1152
1153 sub shellquote {
1154     my $str = shift;
1155
1156     return String::ShellQuote::shell_quote($str);
1157 }
1158
1159 sub cmd2string {
1160     my ($cmd) = @_;
1161
1162     die "no arguments" if !$cmd;
1163
1164     return $cmd if !ref($cmd);
1165
1166     my @qa = ();
1167     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1168
1169     return join (' ', @qa);
1170 }
1171
1172 # split an shell argument string into an array,
1173 sub split_args {
1174     my ($str) = @_;
1175
1176     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1177 }
1178
1179 sub dump_logfile {
1180     my ($filename, $start, $limit, $filter) = @_;
1181
1182     my $lines = [];
1183     my $count = 0;
1184
1185     my $fh = IO::File->new($filename, "r");
1186     if (!$fh) {
1187         $count++;
1188         push @$lines, { n => $count, t => "unable to open file - $!"};
1189         return ($count, $lines);
1190     }
1191
1192     $start = 0 if !$start;
1193     $limit = 50 if !$limit;
1194
1195     my $line;
1196
1197     if ($filter) {
1198         # duplicate code, so that we do not slow down normal path
1199         while (defined($line = <$fh>)) {
1200             next if $line !~ m/$filter/;
1201             next if $count++ < $start;
1202             next if $limit <= 0;
1203             chomp $line;
1204             push @$lines, { n => $count, t => $line};
1205             $limit--;
1206         }
1207     } else {
1208         while (defined($line = <$fh>)) {
1209             next if $count++ < $start;
1210             next if $limit <= 0;
1211             chomp $line;
1212             push @$lines, { n => $count, t => $line};
1213             $limit--;
1214         }
1215     }
1216
1217     close($fh);
1218
1219     # HACK: ExtJS store.guaranteeRange() does not like empty array
1220     # so we add a line
1221     if (!$count) {
1222         $count++;
1223         push @$lines, { n => $count, t => "no content"};
1224     }
1225
1226     return ($count, $lines);
1227 }
1228
1229 sub dump_journal {
1230     my ($start, $limit, $since, $until, $service) = @_;
1231
1232     my $lines = [];
1233     my $count = 0;
1234
1235     $start = 0 if !$start;
1236     $limit = 50 if !$limit;
1237
1238     my $parser = sub {
1239         my $line = shift;
1240
1241         return if $count++ < $start;
1242         return if $limit <= 0;
1243         push @$lines, { n => int($count), t => $line};
1244         $limit--;
1245     };
1246
1247     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1248
1249     push @$cmd, '--unit', $service if $service;
1250     push @$cmd, '--since', $since if $since;
1251     push @$cmd, '--until', $until if $until;
1252     run_command($cmd, outfunc => $parser);
1253
1254     # HACK: ExtJS store.guaranteeRange() does not like empty array
1255     # so we add a line
1256     if (!$count) {
1257         $count++;
1258         push @$lines, { n => $count, t => "no content"};
1259     }
1260
1261     return ($count, $lines);
1262 }
1263
1264 sub dir_glob_regex {
1265     my ($dir, $regex) = @_;
1266
1267     my $dh = IO::Dir->new ($dir);
1268     return wantarray ? () : undef if !$dh;
1269
1270     while (defined(my $tmp = $dh->read)) {
1271         if (my @res = $tmp =~ m/^($regex)$/) {
1272             $dh->close;
1273             return wantarray ? @res : $tmp;
1274         }
1275     }
1276     $dh->close;
1277
1278     return wantarray ? () : undef;
1279 }
1280
1281 sub dir_glob_foreach {
1282     my ($dir, $regex, $func) = @_;
1283
1284     my $dh = IO::Dir->new ($dir);
1285     if (defined $dh) {
1286         while (defined(my $tmp = $dh->read)) {
1287             if (my @res = $tmp =~ m/^($regex)$/) {
1288                 &$func (@res);
1289             }
1290         }
1291     }
1292 }
1293
1294 sub assert_if_modified {
1295     my ($digest1, $digest2) = @_;
1296
1297     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1298         die "detected modified configuration - file changed by other user? Try again.\n";
1299     }
1300 }
1301
1302 # Digest for short strings
1303 # like FNV32a, but we only return 31 bits (positive numbers)
1304 sub fnv31a {
1305     my ($string) = @_;
1306
1307     my $hval = 0x811c9dc5;
1308
1309     foreach my $c (unpack('C*', $string)) {
1310         $hval ^= $c;
1311         $hval += (
1312             (($hval << 1) ) +
1313             (($hval << 4) ) +
1314             (($hval << 7) ) +
1315             (($hval << 8) ) +
1316             (($hval << 24) ) );
1317         $hval = $hval & 0xffffffff;
1318     }
1319     return $hval & 0x7fffffff;
1320 }
1321
1322 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1323
1324 sub unpack_sockaddr_in46 {
1325     my ($sin) = @_;
1326     my $family = Socket::sockaddr_family($sin);
1327     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1328                                              : Socket::unpack_sockaddr_in($sin));
1329     return ($family, $port, $host);
1330 }
1331
1332 sub getaddrinfo_all {
1333     my ($hostname, @opts) = @_;
1334     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1335                   @opts );
1336     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1337     die "failed to get address info for: $hostname: $err\n" if $err;
1338     return @res;
1339 }
1340
1341 sub get_host_address_family {
1342     my ($hostname, $socktype) = @_;
1343     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1344     return $res[0]->{family};
1345 }
1346
1347 # get the fully qualified domain name of a host
1348 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1349 # given a nodename as a parameter
1350 sub get_fqdn {
1351     my ($nodename) = @_;
1352
1353     my $hints = {
1354         flags => AI_CANONNAME,
1355         socktype => SOCK_DGRAM
1356     };
1357
1358     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1359
1360     die "getaddrinfo: $err" if $err;
1361
1362     return $addrs[0]->{canonname};
1363 }
1364
1365 # Parses any sane kind of host, or host+port pair:
1366 # The port is always optional and thus may be undef.
1367 sub parse_host_and_port {
1368     my ($address) = @_;
1369     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1370         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1371         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1372     {
1373         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1374     }
1375     return; # nothing
1376 }
1377
1378 sub unshare($) {
1379     my ($flags) = @_;
1380     return 0 == syscall(PVE::Syscall::unshare, $flags);
1381 }
1382
1383 sub setns($$) {
1384     my ($fileno, $nstype) = @_;
1385     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1386 }
1387
1388 sub syncfs($) {
1389     my ($fileno) = @_;
1390     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1391 }
1392
1393 sub sync_mountpoint {
1394     my ($path) = @_;
1395     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1396     my $result = syncfs(fileno($fd));
1397     close($fd);
1398     return $result;
1399 }
1400
1401 # support sending multi-part mail messages with a text and or a HTML part
1402 # mailto may be a single email string or an array of receivers
1403 sub sendmail {
1404     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1405     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1406
1407     $mailto = [ $mailto ] if !ref($mailto);
1408
1409     foreach (@$mailto) {
1410         die "illegal character in mailto address\n"
1411             if ($_ =~ $mail_re);
1412     }
1413
1414     my $rcvrtxt = join (', ', @$mailto);
1415
1416     $mailfrom = $mailfrom || "root";
1417     die "illegal character in mailfrom address\n"
1418         if $mailfrom =~ $mail_re;
1419
1420     $author = $author || 'Proxmox VE';
1421
1422     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1423         die "unable to open 'sendmail' - $!";
1424
1425     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1426     my $boundary = "----_=_NextPart_001_".int(time).$$;
1427
1428     print MAIL "Content-Type: multipart/alternative;\n";
1429     print MAIL "\tboundary=\"$boundary\"\n";
1430     print MAIL "MIME-Version: 1.0\n";
1431
1432     print MAIL "FROM: $author <$mailfrom>\n";
1433     print MAIL "TO: $rcvrtxt\n";
1434     print MAIL "SUBJECT: $subject\n";
1435     print MAIL "\n";
1436     print MAIL "This is a multi-part message in MIME format.\n\n";
1437     print MAIL "--$boundary\n";
1438
1439     if (defined($text)) {
1440         print MAIL "Content-Type: text/plain;\n";
1441         print MAIL "\tcharset=\"UTF8\"\n";
1442         print MAIL "Content-Transfer-Encoding: 8bit\n";
1443         print MAIL "\n";
1444
1445         # avoid 'remove extra line breaks' issue (MS Outlook)
1446         my $fill = '  ';
1447         $text =~ s/^/$fill/gm;
1448
1449         print MAIL $text;
1450
1451         print MAIL "\n--$boundary\n";
1452     }
1453
1454     if (defined($html)) {
1455         print MAIL "Content-Type: text/html;\n";
1456         print MAIL "\tcharset=\"UTF8\"\n";
1457         print MAIL "Content-Transfer-Encoding: 8bit\n";
1458         print MAIL "\n";
1459
1460         print MAIL $html;
1461
1462         print MAIL "\n--$boundary--\n";
1463     }
1464
1465     close(MAIL);
1466 }
1467
1468 sub tempfile {
1469     my ($perm, %opts) = @_;
1470
1471     # default permissions are stricter than with file_set_contents
1472     $perm = 0600 if !defined($perm);
1473
1474     my $dir = $opts{dir} // '/run';
1475     my $mode = $opts{mode} // O_RDWR;
1476     $mode |= O_EXCL if !$opts{allow_links};
1477
1478     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1479     if (!$fh && $! == EOPNOTSUPP) {
1480         $dir = '/tmp' if !defined($opts{dir});
1481         $dir .= "/.tmpfile.$$";
1482         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1483         unlink($dir) if $fh;
1484     }
1485     die "failed to create tempfile: $!\n" if !$fh;
1486     return $fh;
1487 }
1488
1489 sub tempfile_contents {
1490     my ($data, $perm, %opts) = @_;
1491
1492     my $fh = tempfile($perm, %opts);
1493     eval {
1494         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1495         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1496     };
1497     if (my $err = $@) {
1498         close $fh;
1499         die $err;
1500     }
1501
1502     return ("/proc/$$/fd/".$fh->fileno, $fh);
1503 }
1504
1505 sub validate_ssh_public_keys {
1506     my ($raw) = @_;
1507     my @lines = split(/\n/, $raw);
1508
1509     foreach my $line (@lines) {
1510         next if $line =~ m/^\s*$/;
1511         eval {
1512             my ($filename, $handle) = tempfile_contents($line);
1513             run_command(["ssh-keygen", "-l", "-f", $filename],
1514                         outfunc => sub {}, errfunc => sub {});
1515         };
1516         die "SSH public key validation error\n" if $@;
1517     }
1518 }
1519
1520 sub openat($$$;$) {
1521     my ($dirfd, $pathname, $flags, $mode) = @_;
1522     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1523     return undef if $fd < 0;
1524     # sysopen() doesn't deal with numeric file descriptors apparently
1525     # so we need to convert to a mode string for IO::Handle->new_from_fd
1526     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1527     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1528     return $handle if $handle;
1529     my $err = $!; # save error before closing the raw fd
1530     syscall(PVE::Syscall::close, $fd); # close
1531     $! = $err;
1532     return undef;
1533 }
1534
1535 sub mkdirat($$$) {
1536     my ($dirfd, $name, $mode) = @_;
1537     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1538 }
1539
1540 # NOTE: This calls the dbus main loop and must not be used when another dbus
1541 # main loop is being used as we need to wait for the JobRemoved signal.
1542 # Polling the job status instead doesn't work because this doesn't give us the
1543 # distinction between success and failure.
1544 #
1545 # Note that the description is mandatory for security reasons.
1546 sub enter_systemd_scope {
1547     my ($unit, $description, %extra) = @_;
1548     die "missing description\n" if !defined($description);
1549
1550     my $timeout = delete $extra{timeout};
1551
1552     $unit .= '.scope';
1553     my $properties = [ [PIDs => [dbus_uint32($$)]] ];
1554
1555     foreach my $key (keys %extra) {
1556         if ($key eq 'Slice' || $key eq 'KillMode') {
1557             push @$properties, [$key, $extra{$key}];
1558         } elsif ($key eq 'CPUShares') {
1559             push @$properties, [$key, dbus_uint64($extra{$key})];
1560         } elsif ($key eq 'CPUQuota') {
1561             push @$properties, ['CPUQuotaPerSecUSec',
1562                                 dbus_uint64($extra{$key} * 10000)];
1563         } else {
1564             die "Don't know how to encode $key for systemd scope\n";
1565         }
1566     }
1567
1568     my $job;
1569     my $done = 0;
1570
1571     my $bus = Net::DBus->system();
1572     my $reactor = Net::DBus::Reactor->main();
1573
1574     my $service = $bus->get_service('org.freedesktop.systemd1');
1575     my $if = $service->get_object('/org/freedesktop/systemd1', 'org.freedesktop.systemd1.Manager');
1576     # Connect to the JobRemoved signal since we want to wait for it to finish
1577     my $sigid;
1578     my $timer;
1579     my $cleanup = sub {
1580         my ($no_shutdown) = @_;
1581         $if->disconnect_from_signal('JobRemoved', $sigid) if defined($if);
1582         $if = undef;
1583         $sigid = undef;
1584         $reactor->remove_timeout($timer) if defined($timer);
1585         $timer = undef;
1586         return if $no_shutdown;
1587         $reactor->shutdown();
1588     };
1589
1590     $sigid = $if->connect_to_signal('JobRemoved', sub {
1591         my ($id, $removed_job, $signaled_unit, $result) = @_;
1592         return if $signaled_unit ne $unit || $removed_job ne $job;
1593         $cleanup->(0);
1594         die "systemd job failed\n" if $result ne 'done';
1595         $done = 1;
1596     });
1597
1598     my $on_timeout = sub {
1599         $cleanup->(0);
1600         die "systemd job timed out\n";
1601     };
1602
1603     $timer = $reactor->add_timeout($timeout * 1000, Net::DBus::Callback->new(method => $on_timeout))
1604         if defined($timeout);
1605     $job = $if->StartTransientUnit($unit, 'fail', $properties, []);
1606     $reactor->run();
1607     $cleanup->(1);
1608     die "systemd job never completed\n" if !$done;
1609 }
1610
1611 my $salt_starter = time();
1612
1613 sub encrypt_pw {
1614     my ($pw) = @_;
1615
1616     $salt_starter++;
1617     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1618
1619     # crypt does not want '+' in salt (see 'man crypt')
1620     $salt =~ s/\+/X/g;
1621
1622     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1623 }
1624
1625 # intended usage: convert_size($val, "kb" => "gb")
1626 # we round up to the next integer by default
1627 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1628 # use $no_round_up to switch this off, above example would then return 0
1629 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1630 # (0 if $no_round_up is true)
1631 # allowed formats for value:
1632 # 1234
1633 # 1234.
1634 # 1234.1234
1635 # .1234
1636 sub convert_size {
1637     my ($value, $from, $to, $no_round_up) = @_;
1638
1639     my $units = {
1640         b  => 0,
1641         kb => 1,
1642         mb => 2,
1643         gb => 3,
1644         tb => 4,
1645         pb => 5,
1646     };
1647
1648     die "no value given"
1649         if !defined($value) || $value eq "";
1650
1651     $from = lc($from // ''); $to = lc($to // '');
1652     die "unknown 'from' and/or 'to' units ($from => $to)"
1653         if !defined($units->{$from}) || !defined($units->{$to});
1654
1655     die "value '$value' is not a valid, positive number"
1656         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1657
1658     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1659
1660     $value *= 2**$shift_amount;
1661     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1662
1663     return int($value);
1664 }
1665
1666 1;