src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Net::DBus qw(dbus_uint32 dbus_uint64);
  28 use Net::DBus::Callback;
  29 use Net::DBus::Reactor;
  30 use Scalar::Util 'weaken';
  31 use PVE::Syscall;
  32
  33 # avoid warning when parsing long hex values with hex()
  34 no warnings 'portable'; # Support for 64-bit ints required
  35
  36 our @EXPORT_OK = qw(
  37 $IPV6RE
  38 $IPV4RE
  39 lock_file
  40 lock_file_full
  41 run_command
  42 file_set_contents
  43 file_get_contents
  44 file_read_firstline
  45 dir_glob_regex
  46 dir_glob_foreach
  47 split_list
  48 template_replace
  49 safe_print
  50 trim
  51 extract_param
  52 file_copy
  53 O_PATH
  54 O_TMPFILE
  55 );
  56
  57 my $pvelogdir = "/var/log/pve";
  58 my $pvetaskdir = "$pvelogdir/tasks";
  59
  60 mkdir $pvelogdir;
  61 mkdir $pvetaskdir;
  62
  63 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  64 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  65 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  66 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  67
  68 our $IPV6RE = "(?:" .
  69     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  70     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  71     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  72     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  73     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  74     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  75     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  76     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  77     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  78
  79 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  80
  81 use constant {CLONE_NEWNS   => 0x00020000,
  82               CLONE_NEWUTS  => 0x04000000,
  83               CLONE_NEWIPC  => 0x08000000,
  84               CLONE_NEWUSER => 0x10000000,
  85               CLONE_NEWPID  => 0x20000000,
  86               CLONE_NEWNET  => 0x40000000};
  87
  88 use constant {O_PATH    => 0x00200000,
  89               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  90
  91 sub run_with_timeout {
  92     my ($timeout, $code, @param) = @_;
  93
  94     die "got timeout\n" if $timeout <= 0;
  95
  96     my $prev_alarm = alarm 0; # suspend outer alarm early
  97
  98     my $sigcount = 0;
  99
 100     my $res;
 101
 102     eval {
 103         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 104         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 105         local $SIG{__DIE__};   # see SA bug 4631
 106
 107         alarm($timeout);
 108
 109         eval { $res = &$code(@param); };
 110
 111         alarm(0); # avoid race conditions
 112
 113         die $@ if $@;
 114     };
 115
 116     my $err = $@;
 117
 118     alarm $prev_alarm;
 119
 120     # this shouldn't happen anymore?
 121     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 122
 123     die $err if $err;
 124
 125     return $res;
 126 }
 127
 128 # flock: we use one file handle per process, so lock file
 129 # can be nested multiple times and succeeds for the same process.
 130 #
 131 # Since this is the only way we lock now and we don't have the old
 132 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 133 # count how deep we're nesting. Therefore this hash now stores a weak reference
 134 # to a boolean telling us whether we already have a lock.
 135
 136 my $lock_handles =  {};
 137
 138 sub lock_file_full {
 139     my ($filename, $timeout, $shared, $code, @param) = @_;
 140
 141     $timeout = 10 if !$timeout;
 142
 143     my $mode = $shared ? LOCK_SH : LOCK_EX;
 144
 145     my $lockhash = ($lock_handles->{$$} //= {});
 146
 147     # Returns a locked file handle.
 148     my $get_locked_file = sub {
 149         my $fh = IO::File->new(">>$filename")
 150             or die "can't open file - $!\n";
 151
 152         if (!flock($fh, $mode|LOCK_NB)) {
 153             print STDERR "trying to acquire lock...";
 154             my $success;
 155             while(1) {
 156                 $success = flock($fh, $mode);
 157                 # try again on EINTR (see bug #273)
 158                 if ($success || ($! != EINTR)) {
 159                     last;
 160                 }
 161             }
 162             if (!$success) {
 163                 print STDERR " failed\n";
 164                 die "can't acquire lock '$filename' - $!\n";
 165             }
 166             print STDERR " OK\n";
 167         }
 168
 169         return $fh;
 170     };
 171
 172     my $res;
 173     my $checkptr = $lockhash->{$filename};
 174     my $check = 0; # This must not go out of scope before running the code.
 175     my $local_fh; # This must stay local
 176     if (!$checkptr || !$$checkptr) {
 177         # We cannot create a weak reference in a single atomic step, so we first
 178         # create a false-value, then create a reference to it, then weaken it,
 179         # and after successfully locking the file we change the boolean value.
 180         #
 181         # The reason for this is that if an outer SIGALRM throws an exception
 182         # between creating the reference and weakening it, a subsequent call to
 183         # lock_file_full() will see a leftover full reference to a valid
 184         # variable. This variable must be 0 in order for said call to attempt to
 185         # lock the file anew.
 186         #
 187         # An externally triggered exception elsewhere in the code will cause the
 188         # weak reference to become 'undef', and since the file handle is only
 189         # stored in the local scope in $local_fh, the file will be closed by
 190         # perl's cleanup routines as well.
 191         #
 192         # This still assumes that an IO::File handle can properly deal with such
 193         # exceptions thrown during its own destruction, but that's up to perls
 194         # guts now.
 195         $lockhash->{$filename} = \$check;
 196         weaken $lockhash->{$filename};
 197         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 198         if ($@) {
 199             $@ = "can't lock file '$filename' - $@";
 200             return undef;
 201         }
 202         $check = 1;
 203     }
 204     $res = eval { &$code(@param); };
 205     return undef if $@;
 206     return $res;
 207 }
 208
 209
 210 sub lock_file {
 211     my ($filename, $timeout, $code, @param) = @_;
 212
 213     return lock_file_full($filename, $timeout, 0, $code, @param);
 214 }
 215
 216 sub file_set_contents {
 217     my ($filename, $data, $perm)  = @_;
 218
 219     $perm = 0644 if !defined($perm);
 220
 221     my $tmpname = "$filename.tmp.$$";
 222
 223     eval {
 224         my ($fh, $tries) = (undef, 0);
 225         while (!$fh && $tries++ < 3) {
 226             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 227             if (!$fh && $! == EEXIST) {
 228                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 229             }
 230         }
 231         die "unable to open file '$tmpname' - $!\n" if !$fh;
 232         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 233         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 234     };
 235     my $err = $@;
 236
 237     if ($err) {
 238         unlink $tmpname;
 239         die $err;
 240     }
 241
 242     if (!rename($tmpname, $filename)) {
 243         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 244         unlink $tmpname;
 245         die $msg;
 246     }
 247 }
 248
 249 sub file_get_contents {
 250     my ($filename, $max) = @_;
 251
 252     my $fh = IO::File->new($filename, "r") ||
 253         die "can't open '$filename' - $!\n";
 254
 255     my $content = safe_read_from($fh, $max, 0, $filename);
 256
 257     close $fh;
 258
 259     return $content;
 260 }
 261
 262 sub file_copy {
 263     my ($filename, $dst, $max, $perm) = @_;
 264
 265     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 266 }
 267
 268 sub file_read_firstline {
 269     my ($filename) = @_;
 270
 271     my $fh = IO::File->new ($filename, "r");
 272     return undef if !$fh;
 273     my $res = <$fh>;
 274     chomp $res if $res;
 275     $fh->close;
 276     return $res;
 277 }
 278
 279 sub safe_read_from {
 280     my ($fh, $max, $oneline, $filename) = @_;
 281
 282     $max = 32768 if !$max;
 283
 284     my $subject = defined($filename) ? "file '$filename'" : 'input';
 285
 286     my $br = 0;
 287     my $input = '';
 288     my $count;
 289     while ($count = sysread($fh, $input, 8192, $br)) {
 290         $br += $count;
 291         die "$subject too long - aborting\n" if $br > $max;
 292         if ($oneline && $input =~ m/^(.*)\n/) {
 293             $input = $1;
 294             last;
 295         }
 296     }
 297     die "unable to read $subject - $!\n" if !defined($count);
 298
 299     return $input;
 300 }
 301
 302 # The $cmd parameter can be:
 303 #  -) a string
 304 #    This is generally executed by passing it to the shell with the -c option.
 305 #    However, it can be executed in one of two ways, depending on whether
 306 #    there's a pipe involved:
 307 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 308 #          set -o pipefail &&
 309 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 310 #      (Note that this may result in two different syntax requirements!)
 311 #      FIXME?
 312 #  -) an array of arguments (strings)
 313 #    Will be executed without interference from a shell. (Parameters are passed
 314 #    as is, no escape sequences of strings will be touched.)
 315 #  -) an array of arrays
 316 #    Each array represents a command, and each command's output is piped into
 317 #    the following command's standard input.
 318 #    For this a shell command string is created with pipe symbols between each
 319 #    command.
 320 #    Each command is a list of strings meant to end up in the final command
 321 #    unchanged. In order to achieve this, every argument is shell-quoted.
 322 #    Quoting can be disabled for a particular argument by turning it into a
 323 #    reference, this allows inserting arbitrary shell options.
 324 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 325 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 326 #    will literally print: hello >/dev/null
 327 sub run_command {
 328     my ($cmd, %param) = @_;
 329
 330     my $old_umask;
 331     my $cmdstr;
 332
 333     if (my $ref = ref($cmd)) {
 334         if (ref($cmd->[0])) {
 335             $cmdstr = 'set -o pipefail && ';
 336             my $pipe = '';
 337             foreach my $command (@$cmd) {
 338                 # concatenate quoted parameters
 339                 # strings which are passed by reference are NOT shell quoted
 340                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 341                 $pipe = ' | ';
 342             }
 343             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 344         } else {
 345             $cmdstr = cmd2string($cmd);
 346         }
 347     } else {
 348         $cmdstr = $cmd;
 349         if ($cmd =~ m/\|/) {
 350             # see 'man bash' for option pipefail
 351             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 352         } else {
 353             $cmd = [ $cmd ];
 354         }
 355     }
 356
 357     my $errmsg;
 358     my $laststderr;
 359     my $timeout;
 360     my $oldtimeout;
 361     my $pid;
 362     my $exitcode = -1;
 363
 364     my $outfunc;
 365     my $errfunc;
 366     my $logfunc;
 367     my $input;
 368     my $output;
 369     my $afterfork;
 370     my $noerr;
 371     my $keeplocale;
 372
 373     eval {
 374
 375         foreach my $p (keys %param) {
 376             if ($p eq 'timeout') {
 377                 $timeout = $param{$p};
 378             } elsif ($p eq 'umask') {
 379                 $old_umask = umask($param{$p});
 380             } elsif ($p eq 'errmsg') {
 381                 $errmsg = $param{$p};
 382             } elsif ($p eq 'input') {
 383                 $input = $param{$p};
 384             } elsif ($p eq 'output') {
 385                 $output = $param{$p};
 386             } elsif ($p eq 'outfunc') {
 387                 $outfunc = $param{$p};
 388             } elsif ($p eq 'errfunc') {
 389                 $errfunc = $param{$p};
 390             } elsif ($p eq 'logfunc') {
 391                 $logfunc = $param{$p};
 392             } elsif ($p eq 'afterfork') {
 393                 $afterfork = $param{$p};
 394             } elsif ($p eq 'noerr') {
 395                 $noerr = $param{$p};
 396             } elsif ($p eq 'keeplocale') {
 397                 $keeplocale = $param{$p};
 398             } else {
 399                 die "got unknown parameter '$p' for run_command\n";
 400             }
 401         }
 402
 403         if ($errmsg) {
 404             my $origerrfunc = $errfunc;
 405             $errfunc = sub {
 406                 if ($laststderr) {
 407                     if ($origerrfunc) {
 408                         &$origerrfunc("$laststderr\n");
 409                     } else {
 410                         print STDERR "$laststderr\n" if $laststderr;
 411                     }
 412                 }
 413                 $laststderr = shift;
 414             };
 415         }
 416
 417         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 418         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 419         my $error  = IO::File->new();
 420
 421         my $orig_pid = $$;
 422
 423         eval {
 424             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 425
 426             # suppress LVM warnings like: "File descriptor 3 left open";
 427             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 428
 429             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 430
 431             # if we pipe fron STDIN, open3 closes STDIN, so we we
 432             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 433             # as soon as we open a new file.
 434             # to avoid that we open /dev/null
 435             if (!ref($writer) && !defined(fileno(STDIN))) {
 436                 POSIX::close(0);
 437                 open(STDIN, "</dev/null");
 438             }
 439         };
 440
 441         my $err = $@;
 442
 443         # catch exec errors
 444         if ($orig_pid != $$) {
 445             warn "ERROR: $err";
 446             POSIX::_exit (1);
 447             kill ('KILL', $$);
 448         }
 449
 450         die $err if $err;
 451
 452         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 453         $oldtimeout = alarm($timeout) if $timeout;
 454
 455         &$afterfork() if $afterfork;
 456
 457         if (ref($writer)) {
 458             print $writer $input if defined $input;
 459             close $writer;
 460         }
 461
 462         my $select = new IO::Select;
 463         $select->add($reader) if ref($reader);
 464         $select->add($error);
 465
 466         my $outlog = '';
 467         my $errlog = '';
 468
 469         my $starttime = time();
 470
 471         while ($select->count) {
 472             my @handles = $select->can_read(1);
 473
 474             foreach my $h (@handles) {
 475                 my $buf = '';
 476                 my $count = sysread ($h, $buf, 4096);
 477                 if (!defined ($count)) {
 478                     my $err = $!;
 479                     kill (9, $pid);
 480                     waitpid ($pid, 0);
 481                     die $err;
 482                 }
 483                 $select->remove ($h) if !$count;
 484                 if ($h eq $reader) {
 485                     if ($outfunc || $logfunc) {
 486                         eval {
 487                             $outlog .= $buf;
 488                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 489                                 my $line = $1;
 490                                 &$outfunc($line) if $outfunc;
 491                                 &$logfunc($line) if $logfunc;
 492                             }
 493                         };
 494                         my $err = $@;
 495                         if ($err) {
 496                             kill (9, $pid);
 497                             waitpid ($pid, 0);
 498                             die $err;
 499                         }
 500                     } else {
 501                         print $buf;
 502                         *STDOUT->flush();
 503                     }
 504                 } elsif ($h eq $error) {
 505                     if ($errfunc || $logfunc) {
 506                         eval {
 507                             $errlog .= $buf;
 508                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 509                                 my $line = $1;
 510                                 &$errfunc($line) if $errfunc;
 511                                 &$logfunc($line) if $logfunc;
 512                             }
 513                         };
 514                         my $err = $@;
 515                         if ($err) {
 516                             kill (9, $pid);
 517                             waitpid ($pid, 0);
 518                             die $err;
 519                         }
 520                     } else {
 521                         print STDERR $buf;
 522                         *STDERR->flush();
 523                     }
 524                 }
 525             }
 526         }
 527
 528         &$outfunc($outlog) if $outfunc && $outlog;
 529         &$logfunc($outlog) if $logfunc && $outlog;
 530
 531         &$errfunc($errlog) if $errfunc && $errlog;
 532         &$logfunc($errlog) if $logfunc && $errlog;
 533
 534         waitpid ($pid, 0);
 535
 536         if ($? == -1) {
 537             die "failed to execute\n";
 538         } elsif (my $sig = ($? & 127)) {
 539             die "got signal $sig\n";
 540         } elsif ($exitcode = ($? >> 8)) {
 541             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 542                 if ($errmsg && $laststderr) {
 543                     my $lerr = $laststderr;
 544                     $laststderr = undef;
 545                     die "$lerr\n";
 546                 }
 547                 die "exit code $exitcode\n";
 548             }
 549         }
 550
 551         alarm(0);
 552     };
 553
 554     my $err = $@;
 555
 556     alarm(0);
 557
 558     if ($errmsg && $laststderr) {
 559         &$errfunc(undef); # flush laststderr
 560     }
 561
 562     umask ($old_umask) if defined($old_umask);
 563
 564     alarm($oldtimeout) if $oldtimeout;
 565
 566     if ($err) {
 567         if ($pid && ($err eq "got timeout\n")) {
 568             kill (9, $pid);
 569             waitpid ($pid, 0);
 570             die "command '$cmdstr' failed: $err";
 571         }
 572
 573         if ($errmsg) {
 574             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 575             die "$errmsg: $err";
 576         } elsif(!$noerr) {
 577             die "command '$cmdstr' failed: $err";
 578         }
 579     }
 580
 581     return $exitcode;
 582 }
 583
 584 # Run a command with a tcp socket as standard input.
 585 sub pipe_socket_to_command  {
 586     my ($cmd, $ip, $port) = @_;
 587
 588     my $params = {
 589         Listen => 1,
 590         ReuseAddr => 1,
 591         Proto => &Socket::IPPROTO_TCP,
 592         GetAddrInfoFlags => 0,
 593         LocalAddr => $ip,
 594         LocalPort => $port,
 595     };
 596     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 597
 598     print "$ip\n$port\n"; # tell remote where to connect
 599     *STDOUT->flush();
 600
 601     alarm 0;
 602     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 603     alarm 30;
 604     my $client = $socket->accept; # Wait for a client
 605     alarm 0;
 606     close($socket);
 607
 608     # We want that the command talks over the TCP socket and takes
 609     # ownership of it, so that when it closes it the connection is
 610     # terminated, so we need to be able to close the socket. So we
 611     # can't really use PVE::Tools::run_command().
 612     my $pid = fork() // die "fork failed: $!\n";
 613     if (!$pid) {
 614         POSIX::dup2(fileno($client), 0);
 615         POSIX::dup2(fileno($client), 1);
 616         close($client);
 617         exec {$cmd->[0]} @$cmd or do {
 618             warn "exec failed: $!\n";
 619             POSIX::_exit(1);
 620         };
 621     }
 622
 623     close($client);
 624     if (waitpid($pid, 0) != $pid) {
 625         kill(15 => $pid); # if we got interrupted terminate the child
 626         my $count = 0;
 627         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 628             usleep(100000);
 629             $count++;
 630             kill(9 => $pid), last if $count > 300; # 30 second timeout
 631         }
 632     }
 633     if (my $sig = ($? & 127)) {
 634         die "got signal $sig\n";
 635     } elsif (my $exitcode = ($? >> 8)) {
 636         die "exit code $exitcode\n";
 637     }
 638
 639     return undef;
 640 }
 641
 642 sub split_list {
 643     my $listtxt = shift || '';
 644
 645     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 646
 647     $listtxt =~ s/[,;]/ /g;
 648     $listtxt =~ s/^\s+//;
 649
 650     my @data = split (/\s+/, $listtxt);
 651
 652     return @data;
 653 }
 654
 655 sub trim {
 656     my $txt = shift;
 657
 658     return $txt if !defined($txt);
 659
 660     $txt =~ s/^\s+//;
 661     $txt =~ s/\s+$//;
 662
 663     return $txt;
 664 }
 665
 666 # simple uri templates like "/vms/{vmid}"
 667 sub template_replace {
 668     my ($tmpl, $data) = @_;
 669
 670     return $tmpl if !$tmpl;
 671
 672     my $res = '';
 673     while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) {
 674         $res .= $1 if $1;
 675         $res .= ($data->{$3} || '-') if $2;
 676     }
 677     return $res;
 678 }
 679
 680 sub safe_print {
 681     my ($filename, $fh, $data) = @_;
 682
 683     return if !$data;
 684
 685     my $res = print $fh $data;
 686
 687     die "write to '$filename' failed\n" if !$res;
 688 }
 689
 690 sub debmirrors {
 691
 692     return {
 693         'at' => 'ftp.at.debian.org',
 694         'au' => 'ftp.au.debian.org',
 695         'be' => 'ftp.be.debian.org',
 696         'bg' => 'ftp.bg.debian.org',
 697         'br' => 'ftp.br.debian.org',
 698         'ca' => 'ftp.ca.debian.org',
 699         'ch' => 'ftp.ch.debian.org',
 700         'cl' => 'ftp.cl.debian.org',
 701         'cz' => 'ftp.cz.debian.org',
 702         'de' => 'ftp.de.debian.org',
 703         'dk' => 'ftp.dk.debian.org',
 704         'ee' => 'ftp.ee.debian.org',
 705         'es' => 'ftp.es.debian.org',
 706         'fi' => 'ftp.fi.debian.org',
 707         'fr' => 'ftp.fr.debian.org',
 708         'gr' => 'ftp.gr.debian.org',
 709         'hk' => 'ftp.hk.debian.org',
 710         'hr' => 'ftp.hr.debian.org',
 711         'hu' => 'ftp.hu.debian.org',
 712         'ie' => 'ftp.ie.debian.org',
 713         'is' => 'ftp.is.debian.org',
 714         'it' => 'ftp.it.debian.org',
 715         'jp' => 'ftp.jp.debian.org',
 716         'kr' => 'ftp.kr.debian.org',
 717         'mx' => 'ftp.mx.debian.org',
 718         'nl' => 'ftp.nl.debian.org',
 719         'no' => 'ftp.no.debian.org',
 720         'nz' => 'ftp.nz.debian.org',
 721         'pl' => 'ftp.pl.debian.org',
 722         'pt' => 'ftp.pt.debian.org',
 723         'ro' => 'ftp.ro.debian.org',
 724         'ru' => 'ftp.ru.debian.org',
 725         'se' => 'ftp.se.debian.org',
 726         'si' => 'ftp.si.debian.org',
 727         'sk' => 'ftp.sk.debian.org',
 728         'tr' => 'ftp.tr.debian.org',
 729         'tw' => 'ftp.tw.debian.org',
 730         'gb' => 'ftp.uk.debian.org',
 731         'us' => 'ftp.us.debian.org',
 732     };
 733 }
 734
 735 my $keymaphash =  {
 736     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 737     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 738     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 739     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 740     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 741     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 742     #'et'     => [], # Ethopia or Estonia ??
 743     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 744     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 745     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 746     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 747     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 748     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 749     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 750     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 751     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 752     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 753     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 754     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 755     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 756     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 757     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 758     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 759     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 760     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 761     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 762     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 763     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know?
 764     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 765     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 766     #'th'     => [],
 767     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 768 };
 769
 770 my $kvmkeymaparray = [];
 771 foreach my $lc (sort keys %$keymaphash) {
 772     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 773 }
 774
 775 sub kvmkeymaps {
 776     return $keymaphash;
 777 }
 778
 779 sub kvmkeymaplist {
 780     return $kvmkeymaparray;
 781 }
 782
 783 sub extract_param {
 784     my ($param, $key) = @_;
 785
 786     my $res = $param->{$key};
 787     delete $param->{$key};
 788
 789     return $res;
 790 }
 791
 792 # Note: we use this to wait until vncterm/spiceterm is ready
 793 sub wait_for_vnc_port {
 794     my ($port, $timeout) = @_;
 795
 796     $timeout = 5 if !$timeout;
 797     my $sleeptime = 0;
 798     my $starttime = [gettimeofday];
 799     my $elapsed;
 800
 801     my $found;
 802     while (($elapsed = tv_interval($starttime)) < $timeout) {
 803         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 804         run_command(['/bin/ss', '-Htln', "sport = :$port"], outfunc => sub {
 805             my $line = shift;
 806             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 807                 $found = 1 if ($port == $1);
 808             }
 809         });
 810         return 1 if $found;
 811         $sleeptime += 100000 if  $sleeptime < 1000000;
 812         usleep($sleeptime);
 813     }
 814
 815     return undef;
 816 }
 817
 818 sub next_unused_port {
 819     my ($range_start, $range_end, $family, $address) = @_;
 820
 821     # We use a file to register allocated ports.
 822     # Those registrations expires after $expiretime.
 823     # We use this to avoid race conditions between
 824     # allocation and use of ports.
 825
 826     my $filename = "/var/tmp/pve-reserved-ports";
 827
 828     my $code = sub {
 829
 830         my $expiretime = 5;
 831         my $ctime = time();
 832
 833         my $ports = {};
 834
 835         if (my $fh = IO::File->new ($filename, "r")) {
 836             while (my $line = <$fh>) {
 837                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 838                     my ($port, $timestamp) = ($1, $2);
 839                     if (($timestamp + $expiretime) > $ctime) {
 840                         $ports->{$port} = $timestamp; # not expired
 841                     }
 842                 }
 843             }
 844         }
 845
 846         my $newport;
 847         my %sockargs = (Listen => 5,
 848                         ReuseAddr => 1,
 849                         Family    => $family,
 850                         Proto     => IPPROTO_TCP,
 851                         GetAddrInfoFlags => 0);
 852         $sockargs{LocalAddr} = $address if defined($address);
 853
 854         for (my $p = $range_start; $p < $range_end; $p++) {
 855             next if $ports->{$p}; # reserved
 856
 857             $sockargs{LocalPort} = $p;
 858             my $sock = IO::Socket::IP->new(%sockargs);
 859
 860             if ($sock) {
 861                 close($sock);
 862                 $newport = $p;
 863                 $ports->{$p} = $ctime;
 864                 last;
 865             }
 866         }
 867
 868         my $data = "";
 869         foreach my $p (keys %$ports) {
 870             $data .= "$p $ports->{$p}\n";
 871         }
 872
 873         file_set_contents($filename, $data);
 874
 875         return $newport;
 876     };
 877
 878     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 879     die $@ if $@;
 880
 881     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 882
 883     return $p;
 884 }
 885
 886 sub next_migrate_port {
 887     my ($family, $address) = @_;
 888     return next_unused_port(60000, 60050, $family, $address);
 889 }
 890
 891 sub next_vnc_port {
 892     my ($family, $address) = @_;
 893     return next_unused_port(5900, 6000, $family, $address);
 894 }
 895
 896 sub next_spice_port {
 897     my ($family, $address) = @_;
 898     return next_unused_port(61000, 61099, $family, $address);
 899 }
 900
 901 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 902 # the $sub has to return a single scalar
 903 sub run_fork_with_timeout {
 904     my ($timeout, $sub) = @_;
 905
 906     my $res;
 907     my $error;
 908     my $pipe_out = IO::Pipe->new();
 909
 910     # disable pending alarms, save their remaining time
 911     my $prev_alarm = alarm 0;
 912
 913     # avoid leaving a zombie if the parent gets interrupted
 914     my $sig_received;
 915     local $SIG{INT} = sub { $sig_received++; };
 916
 917     my $child = fork();
 918     if (!defined($child)) {
 919         die "fork failed: $!\n";
 920         return $res;
 921     }
 922
 923     if (!$child) {
 924         $pipe_out->writer();
 925
 926         eval {
 927             $res = $sub->();
 928             print {$pipe_out} encode_json({ result => $res });
 929             $pipe_out->flush();
 930         };
 931         if (my $err = $@) {
 932             print {$pipe_out} encode_json({ error => $err });
 933             $pipe_out->flush();
 934             POSIX::_exit(1);
 935         }
 936         POSIX::_exit(0);
 937     }
 938
 939     $pipe_out->reader();
 940
 941     my $readvalues = sub {
 942         local $/ = undef;
 943         my $child_res = decode_json(scalar<$pipe_out>);
 944         $res = $child_res->{result};
 945         $error = $child_res->{error};
 946     };
 947     eval {
 948         run_with_timeout($timeout, $readvalues);
 949     };
 950     warn $@ if $@;
 951     $pipe_out->close();
 952     kill('KILL', $child);
 953     waitpid($child, 0);
 954
 955     alarm $prev_alarm;
 956     die "interrupted by unexpected signal\n" if $sig_received;
 957
 958     die $error if $error;
 959     return $res;
 960 }
 961
 962 # NOTE: NFS syscall can't be interrupted, so alarm does
 963 # not work to provide timeouts.
 964 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
 965 # So fork() before using Filesys::Df
 966 sub df {
 967     my ($path, $timeout) = @_;
 968
 969     my $res = {
 970         total => 0,
 971         used => 0,
 972         avail => 0,
 973     };
 974
 975     my $pipe = IO::Pipe->new();
 976     my $child = fork();
 977     if (!defined($child)) {
 978         warn "fork failed: $!\n";
 979         return $res;
 980     }
 981
 982     if (!$child) {
 983         $pipe->writer();
 984         eval {
 985             my $df = Filesys::Df::df($path, 1);
 986             print {$pipe} "$df->{blocks}\n$df->{used}\n$df->{bavail}\n";
 987             $pipe->close();
 988         };
 989         if (my $err = $@) {
 990             warn $err;
 991             POSIX::_exit(1);
 992         }
 993         POSIX::_exit(0);
 994     }
 995
 996     $pipe->reader();
 997
 998     my $readvalues = sub {
 999         $res->{total} = int((<$pipe> =~ /^(\d*)$/)[0]);
1000         $res->{used}  = int((<$pipe> =~ /^(\d*)$/)[0]);
1001         $res->{avail} = int((<$pipe> =~ /^(\d*)$/)[0]);
1002     };
1003     eval {
1004         run_with_timeout($timeout, $readvalues);
1005     };
1006     warn $@ if $@;
1007     $pipe->close();
1008     kill('KILL', $child);
1009     waitpid($child, 0);
1010     return $res;
1011 }
1012
1013 # UPID helper
1014 # We use this to uniquely identify a process.
1015 # An 'Unique Process ID' has the following format:
1016 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1017
1018 sub upid_encode {
1019     my $d = shift;
1020
1021     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1022     # more that 8 characters for pstart
1023     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1024                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1025                    $d->{user});
1026 }
1027
1028 sub upid_decode {
1029     my ($upid, $noerr) = @_;
1030
1031     my $res;
1032     my $filename;
1033
1034     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1035     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1036     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1037         $res->{node} = $1;
1038         $res->{pid} = hex($3);
1039         $res->{pstart} = hex($4);
1040         $res->{starttime} = hex($5);
1041         $res->{type} = $6;
1042         $res->{id} = $7;
1043         $res->{user} = $8;
1044
1045         my $subdir = substr($5, 7, 8);
1046         $filename = "$pvetaskdir/$subdir/$upid";
1047
1048     } else {
1049         return undef if $noerr;
1050         die "unable to parse worker upid '$upid'\n";
1051     }
1052
1053     return wantarray ? ($res, $filename) : $res;
1054 }
1055
1056 sub upid_open {
1057     my ($upid) = @_;
1058
1059     my ($task, $filename) = upid_decode($upid);
1060
1061     my $dirname = dirname($filename);
1062     make_path($dirname);
1063
1064     my $wwwid = getpwnam('www-data') ||
1065         die "getpwnam failed";
1066
1067     my $perm = 0640;
1068
1069     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1070         die "unable to create output file '$filename' - $!\n";
1071     chown $wwwid, -1, $outfh;
1072
1073     return $outfh;
1074 };
1075
1076 sub upid_read_status {
1077     my ($upid) = @_;
1078
1079     my ($task, $filename) = upid_decode($upid);
1080     my $fh = IO::File->new($filename, "r");
1081     return "unable to open file - $!" if !$fh;
1082     my $maxlen = 4096;
1083     sysseek($fh, -$maxlen, 2);
1084     my $readbuf = '';
1085     my $br = sysread($fh, $readbuf, $maxlen);
1086     close($fh);
1087     if ($br) {
1088         return "unable to extract last line"
1089             if $readbuf !~ m/\n?(.+)$/;
1090         my $line = $1;
1091         if ($line =~ m/^TASK OK$/) {
1092             return 'OK';
1093         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1094             return $1;
1095         } else {
1096             return "unexpected status";
1097         }
1098     }
1099     return "unable to read tail (got $br bytes)";
1100 }
1101
1102 # useful functions to store comments in config files
1103 sub encode_text {
1104     my ($text) = @_;
1105
1106     # all control and hi-bit characters, and ':'
1107     my $unsafe = "^\x20-\x39\x3b-\x7e";
1108     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1109 }
1110
1111 sub decode_text {
1112     my ($data) = @_;
1113
1114     return Encode::decode("utf8", uri_unescape($data));
1115 }
1116
1117 # depreciated - do not use!
1118 # we now decode all parameters by default
1119 sub decode_utf8_parameters {
1120     my ($param) = @_;
1121
1122     foreach my $p (qw(comment description firstname lastname)) {
1123         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1124     }
1125
1126     return $param;
1127 }
1128
1129 sub random_ether_addr {
1130     my ($prefix) = @_;
1131
1132     my ($seconds, $microseconds) = gettimeofday;
1133
1134     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1135
1136     # clear multicast, set local id
1137     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1138
1139     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1140     if (defined($prefix)) {
1141         $addr = uc($prefix) . substr($addr, length($prefix));
1142     }
1143     return $addr;
1144 }
1145
1146 sub shellquote {
1147     my $str = shift;
1148
1149     return String::ShellQuote::shell_quote($str);
1150 }
1151
1152 sub cmd2string {
1153     my ($cmd) = @_;
1154
1155     die "no arguments" if !$cmd;
1156
1157     return $cmd if !ref($cmd);
1158
1159     my @qa = ();
1160     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1161
1162     return join (' ', @qa);
1163 }
1164
1165 # split an shell argument string into an array,
1166 sub split_args {
1167     my ($str) = @_;
1168
1169     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1170 }
1171
1172 sub dump_logfile {
1173     my ($filename, $start, $limit, $filter) = @_;
1174
1175     my $lines = [];
1176     my $count = 0;
1177
1178     my $fh = IO::File->new($filename, "r");
1179     if (!$fh) {
1180         $count++;
1181         push @$lines, { n => $count, t => "unable to open file - $!"};
1182         return ($count, $lines);
1183     }
1184
1185     $start = 0 if !$start;
1186     $limit = 50 if !$limit;
1187
1188     my $line;
1189
1190     if ($filter) {
1191         # duplicate code, so that we do not slow down normal path
1192         while (defined($line = <$fh>)) {
1193             next if $line !~ m/$filter/;
1194             next if $count++ < $start;
1195             next if $limit <= 0;
1196             chomp $line;
1197             push @$lines, { n => $count, t => $line};
1198             $limit--;
1199         }
1200     } else {
1201         while (defined($line = <$fh>)) {
1202             next if $count++ < $start;
1203             next if $limit <= 0;
1204             chomp $line;
1205             push @$lines, { n => $count, t => $line};
1206             $limit--;
1207         }
1208     }
1209
1210     close($fh);
1211
1212     # HACK: ExtJS store.guaranteeRange() does not like empty array
1213     # so we add a line
1214     if (!$count) {
1215         $count++;
1216         push @$lines, { n => $count, t => "no content"};
1217     }
1218
1219     return ($count, $lines);
1220 }
1221
1222 sub dump_journal {
1223     my ($start, $limit, $since, $until, $service) = @_;
1224
1225     my $lines = [];
1226     my $count = 0;
1227
1228     $start = 0 if !$start;
1229     $limit = 50 if !$limit;
1230
1231     my $parser = sub {
1232         my $line = shift;
1233
1234         return if $count++ < $start;
1235         return if $limit <= 0;
1236         push @$lines, { n => int($count), t => $line};
1237         $limit--;
1238     };
1239
1240     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1241
1242     push @$cmd, '--unit', $service if $service;
1243     push @$cmd, '--since', $since if $since;
1244     push @$cmd, '--until', $until if $until;
1245     run_command($cmd, outfunc => $parser);
1246
1247     # HACK: ExtJS store.guaranteeRange() does not like empty array
1248     # so we add a line
1249     if (!$count) {
1250         $count++;
1251         push @$lines, { n => $count, t => "no content"};
1252     }
1253
1254     return ($count, $lines);
1255 }
1256
1257 sub dir_glob_regex {
1258     my ($dir, $regex) = @_;
1259
1260     my $dh = IO::Dir->new ($dir);
1261     return wantarray ? () : undef if !$dh;
1262
1263     while (defined(my $tmp = $dh->read)) {
1264         if (my @res = $tmp =~ m/^($regex)$/) {
1265             $dh->close;
1266             return wantarray ? @res : $tmp;
1267         }
1268     }
1269     $dh->close;
1270
1271     return wantarray ? () : undef;
1272 }
1273
1274 sub dir_glob_foreach {
1275     my ($dir, $regex, $func) = @_;
1276
1277     my $dh = IO::Dir->new ($dir);
1278     if (defined $dh) {
1279         while (defined(my $tmp = $dh->read)) {
1280             if (my @res = $tmp =~ m/^($regex)$/) {
1281                 &$func (@res);
1282             }
1283         }
1284     }
1285 }
1286
1287 sub assert_if_modified {
1288     my ($digest1, $digest2) = @_;
1289
1290     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1291         die "detected modified configuration - file changed by other user? Try again.\n";
1292     }
1293 }
1294
1295 # Digest for short strings
1296 # like FNV32a, but we only return 31 bits (positive numbers)
1297 sub fnv31a {
1298     my ($string) = @_;
1299
1300     my $hval = 0x811c9dc5;
1301
1302     foreach my $c (unpack('C*', $string)) {
1303         $hval ^= $c;
1304         $hval += (
1305             (($hval << 1) ) +
1306             (($hval << 4) ) +
1307             (($hval << 7) ) +
1308             (($hval << 8) ) +
1309             (($hval << 24) ) );
1310         $hval = $hval & 0xffffffff;
1311     }
1312     return $hval & 0x7fffffff;
1313 }
1314
1315 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1316
1317 sub unpack_sockaddr_in46 {
1318     my ($sin) = @_;
1319     my $family = Socket::sockaddr_family($sin);
1320     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1321                                              : Socket::unpack_sockaddr_in($sin));
1322     return ($family, $port, $host);
1323 }
1324
1325 sub getaddrinfo_all {
1326     my ($hostname, @opts) = @_;
1327     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1328                   @opts );
1329     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1330     die "failed to get address info for: $hostname: $err\n" if $err;
1331     return @res;
1332 }
1333
1334 sub get_host_address_family {
1335     my ($hostname, $socktype) = @_;
1336     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1337     return $res[0]->{family};
1338 }
1339
1340 # get the fully qualified domain name of a host
1341 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1342 # given a nodename as a parameter
1343 sub get_fqdn {
1344     my ($nodename) = @_;
1345
1346     my $hints = {
1347         flags => AI_CANONNAME,
1348         socktype => SOCK_DGRAM
1349     };
1350
1351     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1352
1353     die "getaddrinfo: $err" if $err;
1354
1355     return $addrs[0]->{canonname};
1356 }
1357
1358 # Parses any sane kind of host, or host+port pair:
1359 # The port is always optional and thus may be undef.
1360 sub parse_host_and_port {
1361     my ($address) = @_;
1362     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1363         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1364         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1365     {
1366         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1367     }
1368     return; # nothing
1369 }
1370
1371 sub unshare($) {
1372     my ($flags) = @_;
1373     return 0 == syscall(PVE::Syscall::unshare, $flags);
1374 }
1375
1376 sub setns($$) {
1377     my ($fileno, $nstype) = @_;
1378     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1379 }
1380
1381 sub syncfs($) {
1382     my ($fileno) = @_;
1383     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1384 }
1385
1386 sub sync_mountpoint {
1387     my ($path) = @_;
1388     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1389     my $result = syncfs(fileno($fd));
1390     close($fd);
1391     return $result;
1392 }
1393
1394 # support sending multi-part mail messages with a text and or a HTML part
1395 # mailto may be a single email string or an array of receivers
1396 sub sendmail {
1397     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1398     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1399
1400     $mailto = [ $mailto ] if !ref($mailto);
1401
1402     foreach (@$mailto) {
1403         die "illegal character in mailto address\n"
1404             if ($_ =~ $mail_re);
1405     }
1406
1407     my $rcvrtxt = join (', ', @$mailto);
1408
1409     $mailfrom = $mailfrom || "root";
1410     die "illegal character in mailfrom address\n"
1411         if $mailfrom =~ $mail_re;
1412
1413     $author = $author || 'Proxmox VE';
1414
1415     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1416         die "unable to open 'sendmail' - $!";
1417
1418     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1419     my $boundary = "----_=_NextPart_001_".int(time).$$;
1420
1421     print MAIL "Content-Type: multipart/alternative;\n";
1422     print MAIL "\tboundary=\"$boundary\"\n";
1423     print MAIL "MIME-Version: 1.0\n";
1424
1425     print MAIL "FROM: $author <$mailfrom>\n";
1426     print MAIL "TO: $rcvrtxt\n";
1427     print MAIL "SUBJECT: $subject\n";
1428     print MAIL "\n";
1429     print MAIL "This is a multi-part message in MIME format.\n\n";
1430     print MAIL "--$boundary\n";
1431
1432     if (defined($text)) {
1433         print MAIL "Content-Type: text/plain;\n";
1434         print MAIL "\tcharset=\"UTF8\"\n";
1435         print MAIL "Content-Transfer-Encoding: 8bit\n";
1436         print MAIL "\n";
1437
1438         # avoid 'remove extra line breaks' issue (MS Outlook)
1439         my $fill = '  ';
1440         $text =~ s/^/$fill/gm;
1441
1442         print MAIL $text;
1443
1444         print MAIL "\n--$boundary\n";
1445     }
1446
1447     if (defined($html)) {
1448         print MAIL "Content-Type: text/html;\n";
1449         print MAIL "\tcharset=\"UTF8\"\n";
1450         print MAIL "Content-Transfer-Encoding: 8bit\n";
1451         print MAIL "\n";
1452
1453         print MAIL $html;
1454
1455         print MAIL "\n--$boundary--\n";
1456     }
1457
1458     close(MAIL);
1459 }
1460
1461 sub tempfile {
1462     my ($perm, %opts) = @_;
1463
1464     # default permissions are stricter than with file_set_contents
1465     $perm = 0600 if !defined($perm);
1466
1467     my $dir = $opts{dir} // '/run';
1468     my $mode = $opts{mode} // O_RDWR;
1469     $mode |= O_EXCL if !$opts{allow_links};
1470
1471     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1472     if (!$fh && $! == EOPNOTSUPP) {
1473         $dir = '/tmp' if !defined($opts{dir});
1474         $dir .= "/.tmpfile.$$";
1475         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1476         unlink($dir) if $fh;
1477     }
1478     die "failed to create tempfile: $!\n" if !$fh;
1479     return $fh;
1480 }
1481
1482 sub tempfile_contents {
1483     my ($data, $perm, %opts) = @_;
1484
1485     my $fh = tempfile($perm, %opts);
1486     eval {
1487         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1488         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1489     };
1490     if (my $err = $@) {
1491         close $fh;
1492         die $err;
1493     }
1494
1495     return ("/proc/$$/fd/".$fh->fileno, $fh);
1496 }
1497
1498 sub validate_ssh_public_keys {
1499     my ($raw) = @_;
1500     my @lines = split(/\n/, $raw);
1501
1502     foreach my $line (@lines) {
1503         next if $line =~ m/^\s*$/;
1504         eval {
1505             my ($filename, $handle) = tempfile_contents($line);
1506             run_command(["ssh-keygen", "-l", "-f", $filename],
1507                         outfunc => sub {}, errfunc => sub {});
1508         };
1509         die "SSH public key validation error\n" if $@;
1510     }
1511 }
1512
1513 sub openat($$$;$) {
1514     my ($dirfd, $pathname, $flags, $mode) = @_;
1515     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1516     return undef if $fd < 0;
1517     # sysopen() doesn't deal with numeric file descriptors apparently
1518     # so we need to convert to a mode string for IO::Handle->new_from_fd
1519     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1520     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1521     return $handle if $handle;
1522     my $err = $!; # save error before closing the raw fd
1523     syscall(PVE::Syscall::close, $fd); # close
1524     $! = $err;
1525     return undef;
1526 }
1527
1528 sub mkdirat($$$) {
1529     my ($dirfd, $name, $mode) = @_;
1530     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1531 }
1532
1533 # NOTE: This calls the dbus main loop and must not be used when another dbus
1534 # main loop is being used as we need to wait for the JobRemoved signal.
1535 # Polling the job status instead doesn't work because this doesn't give us the
1536 # distinction between success and failure.
1537 #
1538 # Note that the description is mandatory for security reasons.
1539 sub enter_systemd_scope {
1540     my ($unit, $description, %extra) = @_;
1541     die "missing description\n" if !defined($description);
1542
1543     my $timeout = delete $extra{timeout};
1544
1545     $unit .= '.scope';
1546     my $properties = [ [PIDs => [dbus_uint32($$)]] ];
1547
1548     foreach my $key (keys %extra) {
1549         if ($key eq 'Slice' || $key eq 'KillMode') {
1550             push @$properties, [$key, $extra{$key}];
1551         } elsif ($key eq 'CPUShares') {
1552             push @$properties, [$key, dbus_uint64($extra{$key})];
1553         } elsif ($key eq 'CPUQuota') {
1554             push @$properties, ['CPUQuotaPerSecUSec',
1555                                 dbus_uint64($extra{$key} * 10000)];
1556         } else {
1557             die "Don't know how to encode $key for systemd scope\n";
1558         }
1559     }
1560
1561     my $job;
1562     my $done = 0;
1563
1564     my $bus = Net::DBus->system();
1565     my $reactor = Net::DBus::Reactor->main();
1566
1567     my $service = $bus->get_service('org.freedesktop.systemd1');
1568     my $if = $service->get_object('/org/freedesktop/systemd1', 'org.freedesktop.systemd1.Manager');
1569     # Connect to the JobRemoved signal since we want to wait for it to finish
1570     my $sigid;
1571     my $timer;
1572     my $cleanup = sub {
1573         my ($no_shutdown) = @_;
1574         $if->disconnect_from_signal('JobRemoved', $sigid) if defined($if);
1575         $if = undef;
1576         $sigid = undef;
1577         $reactor->remove_timeout($timer) if defined($timer);
1578         $timer = undef;
1579         return if $no_shutdown;
1580         $reactor->shutdown();
1581     };
1582
1583     $sigid = $if->connect_to_signal('JobRemoved', sub {
1584         my ($id, $removed_job, $signaled_unit, $result) = @_;
1585         return if $signaled_unit ne $unit || $removed_job ne $job;
1586         $cleanup->(0);
1587         die "systemd job failed\n" if $result ne 'done';
1588         $done = 1;
1589     });
1590
1591     my $on_timeout = sub {
1592         $cleanup->(0);
1593         die "systemd job timed out\n";
1594     };
1595
1596     $timer = $reactor->add_timeout($timeout * 1000, Net::DBus::Callback->new(method => $on_timeout))
1597         if defined($timeout);
1598     $job = $if->StartTransientUnit($unit, 'fail', $properties, []);
1599     $reactor->run();
1600     $cleanup->(1);
1601     die "systemd job never completed\n" if !$done;
1602 }
1603
1604 my $salt_starter = time();
1605
1606 sub encrypt_pw {
1607     my ($pw) = @_;
1608
1609     $salt_starter++;
1610     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1611
1612     # crypt does not want '+' in salt (see 'man crypt')
1613     $salt =~ s/\+/X/g;
1614
1615     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1616 }
1617
1618 # intended usage: convert_size($val, "kb" => "gb")
1619 # on reduction (converting to a bigger unit) we round up by default if
1620 # information got lost. E.g. `convert_size(1023, "b" => "kb")` returns 1
1621 # use $no_round_up to switch this off, above example would then return 0
1622 sub convert_size {
1623     my ($value, $from, $to, $no_round_up) = @_;
1624
1625     my $units = {
1626         b  => 0,
1627         kb => 1,
1628         mb => 2,
1629         gb => 3,
1630         tb => 4,
1631         pb => 5,
1632     };
1633
1634     $from = lc($from); $to = lc($to);
1635     die "unknown 'from' and/or 'to' units ($from => $to)"
1636         if !(defined($units->{$from}) && defined($units->{$to}));
1637
1638     my $shift_amount = $units->{$from} - $units->{$to};
1639
1640     if ($shift_amount > 0) {
1641         $value <<= ($shift_amount * 10);
1642     } elsif ($shift_amount < 0) {
1643         my $remainder = ($value & (1 << abs($shift_amount)*10) - 1);
1644         $value >>= abs($shift_amount) * 10;
1645         $value++ if $remainder && !$no_round_up;
1646     }
1647
1648     return $value;
1649 }
1650
1651 1;