src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Scalar::Util 'weaken';
  28 use PVE::Syscall;
  29
  30 # avoid warning when parsing long hex values with hex()
  31 no warnings 'portable'; # Support for 64-bit ints required
  32
  33 our @EXPORT_OK = qw(
  34 $IPV6RE
  35 $IPV4RE
  36 lock_file
  37 lock_file_full
  38 run_command
  39 file_set_contents
  40 file_get_contents
  41 file_read_firstline
  42 dir_glob_regex
  43 dir_glob_foreach
  44 split_list
  45 template_replace
  46 safe_print
  47 trim
  48 extract_param
  49 file_copy
  50 get_host_arch
  51 O_PATH
  52 O_TMPFILE
  53 AT_EMPTY_PATH
  54 AT_FDCWD
  55 CLONE_NEWNS
  56 CLONE_NEWUTS
  57 CLONE_NEWIPC
  58 CLONE_NEWUSER
  59 CLONE_NEWPID
  60 CLONE_NEWNET
  61 );
  62
  63 my $pvelogdir = "/var/log/pve";
  64 my $pvetaskdir = "$pvelogdir/tasks";
  65
  66 mkdir $pvelogdir;
  67 mkdir $pvetaskdir;
  68
  69 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  70 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  71 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  72 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  73
  74 our $IPV6RE = "(?:" .
  75     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  76     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  77     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  78     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  79     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  80     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  81     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  84
  85 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  86
  87 use constant {CLONE_NEWNS   => 0x00020000,
  88               CLONE_NEWUTS  => 0x04000000,
  89               CLONE_NEWIPC  => 0x08000000,
  90               CLONE_NEWUSER => 0x10000000,
  91               CLONE_NEWPID  => 0x20000000,
  92               CLONE_NEWNET  => 0x40000000};
  93
  94 use constant {O_PATH    => 0x00200000,
  95               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  96
  97 use constant {AT_EMPTY_PATH => 0x1000,
  98               AT_FDCWD => -100};
  99
 100 sub run_with_timeout {
 101     my ($timeout, $code, @param) = @_;
 102
 103     die "got timeout\n" if $timeout <= 0;
 104
 105     my $prev_alarm = alarm 0; # suspend outer alarm early
 106
 107     my $sigcount = 0;
 108
 109     my $res;
 110
 111     eval {
 112         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 113         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 114         local $SIG{__DIE__};   # see SA bug 4631
 115
 116         alarm($timeout);
 117
 118         eval { $res = &$code(@param); };
 119
 120         alarm(0); # avoid race conditions
 121
 122         die $@ if $@;
 123     };
 124
 125     my $err = $@;
 126
 127     alarm $prev_alarm;
 128
 129     # this shouldn't happen anymore?
 130     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 131
 132     die $err if $err;
 133
 134     return $res;
 135 }
 136
 137 # flock: we use one file handle per process, so lock file
 138 # can be nested multiple times and succeeds for the same process.
 139 #
 140 # Since this is the only way we lock now and we don't have the old
 141 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 142 # count how deep we're nesting. Therefore this hash now stores a weak reference
 143 # to a boolean telling us whether we already have a lock.
 144
 145 my $lock_handles =  {};
 146
 147 sub lock_file_full {
 148     my ($filename, $timeout, $shared, $code, @param) = @_;
 149
 150     $timeout = 10 if !$timeout;
 151
 152     my $mode = $shared ? LOCK_SH : LOCK_EX;
 153
 154     my $lockhash = ($lock_handles->{$$} //= {});
 155
 156     # Returns a locked file handle.
 157     my $get_locked_file = sub {
 158         my $fh = IO::File->new(">>$filename")
 159             or die "can't open file - $!\n";
 160
 161         if (!flock($fh, $mode|LOCK_NB)) {
 162             print STDERR "trying to acquire lock...\n";
 163             my $success;
 164             while(1) {
 165                 $success = flock($fh, $mode);
 166                 # try again on EINTR (see bug #273)
 167                 if ($success || ($! != EINTR)) {
 168                     last;
 169                 }
 170             }
 171             if (!$success) {
 172                 print STDERR " failed\n";
 173                 die "can't acquire lock '$filename' - $!\n";
 174             }
 175             print STDERR " OK\n";
 176         }
 177
 178         return $fh;
 179     };
 180
 181     my $res;
 182     my $checkptr = $lockhash->{$filename};
 183     my $check = 0; # This must not go out of scope before running the code.
 184     my $local_fh; # This must stay local
 185     if (!$checkptr || !$$checkptr) {
 186         # We cannot create a weak reference in a single atomic step, so we first
 187         # create a false-value, then create a reference to it, then weaken it,
 188         # and after successfully locking the file we change the boolean value.
 189         #
 190         # The reason for this is that if an outer SIGALRM throws an exception
 191         # between creating the reference and weakening it, a subsequent call to
 192         # lock_file_full() will see a leftover full reference to a valid
 193         # variable. This variable must be 0 in order for said call to attempt to
 194         # lock the file anew.
 195         #
 196         # An externally triggered exception elsewhere in the code will cause the
 197         # weak reference to become 'undef', and since the file handle is only
 198         # stored in the local scope in $local_fh, the file will be closed by
 199         # perl's cleanup routines as well.
 200         #
 201         # This still assumes that an IO::File handle can properly deal with such
 202         # exceptions thrown during its own destruction, but that's up to perls
 203         # guts now.
 204         $lockhash->{$filename} = \$check;
 205         weaken $lockhash->{$filename};
 206         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 207         if ($@) {
 208             $@ = "can't lock file '$filename' - $@";
 209             return undef;
 210         }
 211         $check = 1;
 212     }
 213     $res = eval { &$code(@param); };
 214     return undef if $@;
 215     return $res;
 216 }
 217
 218
 219 sub lock_file {
 220     my ($filename, $timeout, $code, @param) = @_;
 221
 222     return lock_file_full($filename, $timeout, 0, $code, @param);
 223 }
 224
 225 sub file_set_contents {
 226     my ($filename, $data, $perm)  = @_;
 227
 228     $perm = 0644 if !defined($perm);
 229
 230     my $tmpname = "$filename.tmp.$$";
 231
 232     eval {
 233         my ($fh, $tries) = (undef, 0);
 234         while (!$fh && $tries++ < 3) {
 235             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 236             if (!$fh && $! == EEXIST) {
 237                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 238             }
 239         }
 240         die "unable to open file '$tmpname' - $!\n" if !$fh;
 241         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 242         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 243     };
 244     my $err = $@;
 245
 246     if ($err) {
 247         unlink $tmpname;
 248         die $err;
 249     }
 250
 251     if (!rename($tmpname, $filename)) {
 252         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 253         unlink $tmpname;
 254         die $msg;
 255     }
 256 }
 257
 258 sub file_get_contents {
 259     my ($filename, $max) = @_;
 260
 261     my $fh = IO::File->new($filename, "r") ||
 262         die "can't open '$filename' - $!\n";
 263
 264     my $content = safe_read_from($fh, $max, 0, $filename);
 265
 266     close $fh;
 267
 268     return $content;
 269 }
 270
 271 sub file_copy {
 272     my ($filename, $dst, $max, $perm) = @_;
 273
 274     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 275 }
 276
 277 sub file_read_firstline {
 278     my ($filename) = @_;
 279
 280     my $fh = IO::File->new ($filename, "r");
 281     return undef if !$fh;
 282     my $res = <$fh>;
 283     chomp $res if $res;
 284     $fh->close;
 285     return $res;
 286 }
 287
 288 sub safe_read_from {
 289     my ($fh, $max, $oneline, $filename) = @_;
 290
 291     # pmxcfs file size limit
 292     $max = 512*1024 if !$max;
 293
 294     my $subject = defined($filename) ? "file '$filename'" : 'input';
 295
 296     my $br = 0;
 297     my $input = '';
 298     my $count;
 299     while ($count = sysread($fh, $input, 8192, $br)) {
 300         $br += $count;
 301         die "$subject too long - aborting\n" if $br > $max;
 302         if ($oneline && $input =~ m/^(.*)\n/) {
 303             $input = $1;
 304             last;
 305         }
 306     }
 307     die "unable to read $subject - $!\n" if !defined($count);
 308
 309     return $input;
 310 }
 311
 312 # The $cmd parameter can be:
 313 #  -) a string
 314 #    This is generally executed by passing it to the shell with the -c option.
 315 #    However, it can be executed in one of two ways, depending on whether
 316 #    there's a pipe involved:
 317 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 318 #          set -o pipefail &&
 319 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 320 #      (Note that this may result in two different syntax requirements!)
 321 #      FIXME?
 322 #  -) an array of arguments (strings)
 323 #    Will be executed without interference from a shell. (Parameters are passed
 324 #    as is, no escape sequences of strings will be touched.)
 325 #  -) an array of arrays
 326 #    Each array represents a command, and each command's output is piped into
 327 #    the following command's standard input.
 328 #    For this a shell command string is created with pipe symbols between each
 329 #    command.
 330 #    Each command is a list of strings meant to end up in the final command
 331 #    unchanged. In order to achieve this, every argument is shell-quoted.
 332 #    Quoting can be disabled for a particular argument by turning it into a
 333 #    reference, this allows inserting arbitrary shell options.
 334 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 335 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 336 #    will literally print: hello >/dev/null
 337 sub run_command {
 338     my ($cmd, %param) = @_;
 339
 340     my $old_umask;
 341     my $cmdstr;
 342
 343     if (my $ref = ref($cmd)) {
 344         if (ref($cmd->[0])) {
 345             $cmdstr = 'set -o pipefail && ';
 346             my $pipe = '';
 347             foreach my $command (@$cmd) {
 348                 # concatenate quoted parameters
 349                 # strings which are passed by reference are NOT shell quoted
 350                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 351                 $pipe = ' | ';
 352             }
 353             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 354         } else {
 355             $cmdstr = cmd2string($cmd);
 356         }
 357     } else {
 358         $cmdstr = $cmd;
 359         if ($cmd =~ m/\|/) {
 360             # see 'man bash' for option pipefail
 361             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 362         } else {
 363             $cmd = [ $cmd ];
 364         }
 365     }
 366
 367     my $errmsg;
 368     my $laststderr;
 369     my $timeout;
 370     my $oldtimeout;
 371     my $pid;
 372     my $exitcode = -1;
 373
 374     my $outfunc;
 375     my $errfunc;
 376     my $logfunc;
 377     my $input;
 378     my $output;
 379     my $afterfork;
 380     my $noerr;
 381     my $keeplocale;
 382     my $quiet;
 383
 384     eval {
 385
 386         foreach my $p (keys %param) {
 387             if ($p eq 'timeout') {
 388                 $timeout = $param{$p};
 389             } elsif ($p eq 'umask') {
 390                 $old_umask = umask($param{$p});
 391             } elsif ($p eq 'errmsg') {
 392                 $errmsg = $param{$p};
 393             } elsif ($p eq 'input') {
 394                 $input = $param{$p};
 395             } elsif ($p eq 'output') {
 396                 $output = $param{$p};
 397             } elsif ($p eq 'outfunc') {
 398                 $outfunc = $param{$p};
 399             } elsif ($p eq 'errfunc') {
 400                 $errfunc = $param{$p};
 401             } elsif ($p eq 'logfunc') {
 402                 $logfunc = $param{$p};
 403             } elsif ($p eq 'afterfork') {
 404                 $afterfork = $param{$p};
 405             } elsif ($p eq 'noerr') {
 406                 $noerr = $param{$p};
 407             } elsif ($p eq 'keeplocale') {
 408                 $keeplocale = $param{$p};
 409             } elsif ($p eq 'quiet') {
 410                 $quiet = $param{$p};
 411             } else {
 412                 die "got unknown parameter '$p' for run_command\n";
 413             }
 414         }
 415
 416         if ($errmsg) {
 417             my $origerrfunc = $errfunc;
 418             $errfunc = sub {
 419                 if ($laststderr) {
 420                     if ($origerrfunc) {
 421                         &$origerrfunc("$laststderr\n");
 422                     } else {
 423                         print STDERR "$laststderr\n" if $laststderr;
 424                     }
 425                 }
 426                 $laststderr = shift;
 427             };
 428         }
 429
 430         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 431         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 432         my $error  = IO::File->new();
 433
 434         my $orig_pid = $$;
 435
 436         eval {
 437             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 438
 439             # suppress LVM warnings like: "File descriptor 3 left open";
 440             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 441
 442             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 443
 444             # if we pipe fron STDIN, open3 closes STDIN, so we we
 445             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 446             # as soon as we open a new file.
 447             # to avoid that we open /dev/null
 448             if (!ref($writer) && !defined(fileno(STDIN))) {
 449                 POSIX::close(0);
 450                 open(STDIN, "</dev/null");
 451             }
 452         };
 453
 454         my $err = $@;
 455
 456         # catch exec errors
 457         if ($orig_pid != $$) {
 458             warn "ERROR: $err";
 459             POSIX::_exit (1);
 460             kill ('KILL', $$);
 461         }
 462
 463         die $err if $err;
 464
 465         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 466         $oldtimeout = alarm($timeout) if $timeout;
 467
 468         &$afterfork() if $afterfork;
 469
 470         if (ref($writer)) {
 471             print $writer $input if defined $input;
 472             close $writer;
 473         }
 474
 475         my $select = new IO::Select;
 476         $select->add($reader) if ref($reader);
 477         $select->add($error);
 478
 479         my $outlog = '';
 480         my $errlog = '';
 481
 482         my $starttime = time();
 483
 484         while ($select->count) {
 485             my @handles = $select->can_read(1);
 486
 487             foreach my $h (@handles) {
 488                 my $buf = '';
 489                 my $count = sysread ($h, $buf, 4096);
 490                 if (!defined ($count)) {
 491                     my $err = $!;
 492                     kill (9, $pid);
 493                     waitpid ($pid, 0);
 494                     die $err;
 495                 }
 496                 $select->remove ($h) if !$count;
 497                 if ($h eq $reader) {
 498                     if ($outfunc || $logfunc) {
 499                         eval {
 500                             $outlog .= $buf;
 501                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 502                                 my $line = $1;
 503                                 &$outfunc($line) if $outfunc;
 504                                 &$logfunc($line) if $logfunc;
 505                             }
 506                         };
 507                         my $err = $@;
 508                         if ($err) {
 509                             kill (9, $pid);
 510                             waitpid ($pid, 0);
 511                             die $err;
 512                         }
 513                     } elsif (!$quiet) {
 514                         print $buf;
 515                         *STDOUT->flush();
 516                     }
 517                 } elsif ($h eq $error) {
 518                     if ($errfunc || $logfunc) {
 519                         eval {
 520                             $errlog .= $buf;
 521                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 522                                 my $line = $1;
 523                                 &$errfunc($line) if $errfunc;
 524                                 &$logfunc($line) if $logfunc;
 525                             }
 526                         };
 527                         my $err = $@;
 528                         if ($err) {
 529                             kill (9, $pid);
 530                             waitpid ($pid, 0);
 531                             die $err;
 532                         }
 533                     } elsif (!$quiet) {
 534                         print STDERR $buf;
 535                         *STDERR->flush();
 536                     }
 537                 }
 538             }
 539         }
 540
 541         &$outfunc($outlog) if $outfunc && $outlog;
 542         &$logfunc($outlog) if $logfunc && $outlog;
 543
 544         &$errfunc($errlog) if $errfunc && $errlog;
 545         &$logfunc($errlog) if $logfunc && $errlog;
 546
 547         waitpid ($pid, 0);
 548
 549         if ($? == -1) {
 550             die "failed to execute\n";
 551         } elsif (my $sig = ($? & 127)) {
 552             die "got signal $sig\n";
 553         } elsif ($exitcode = ($? >> 8)) {
 554             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 555                 if ($errmsg && $laststderr) {
 556                     my $lerr = $laststderr;
 557                     $laststderr = undef;
 558                     die "$lerr\n";
 559                 }
 560                 die "exit code $exitcode\n";
 561             }
 562         }
 563
 564         alarm(0);
 565     };
 566
 567     my $err = $@;
 568
 569     alarm(0);
 570
 571     if ($errmsg && $laststderr) {
 572         &$errfunc(undef); # flush laststderr
 573     }
 574
 575     umask ($old_umask) if defined($old_umask);
 576
 577     alarm($oldtimeout) if $oldtimeout;
 578
 579     if ($err) {
 580         if ($pid && ($err eq "got timeout\n")) {
 581             kill (9, $pid);
 582             waitpid ($pid, 0);
 583             die "command '$cmdstr' failed: $err";
 584         }
 585
 586         if ($errmsg) {
 587             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 588             die "$errmsg: $err";
 589         } elsif(!$noerr) {
 590             die "command '$cmdstr' failed: $err";
 591         }
 592     }
 593
 594     return $exitcode;
 595 }
 596
 597 # Run a command with a tcp socket as standard input.
 598 sub pipe_socket_to_command  {
 599     my ($cmd, $ip, $port) = @_;
 600
 601     my $params = {
 602         Listen => 1,
 603         ReuseAddr => 1,
 604         Proto => &Socket::IPPROTO_TCP,
 605         GetAddrInfoFlags => 0,
 606         LocalAddr => $ip,
 607         LocalPort => $port,
 608     };
 609     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 610
 611     print "$ip\n$port\n"; # tell remote where to connect
 612     *STDOUT->flush();
 613
 614     alarm 0;
 615     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 616     alarm 30;
 617     my $client = $socket->accept; # Wait for a client
 618     alarm 0;
 619     close($socket);
 620
 621     # We want that the command talks over the TCP socket and takes
 622     # ownership of it, so that when it closes it the connection is
 623     # terminated, so we need to be able to close the socket. So we
 624     # can't really use PVE::Tools::run_command().
 625     my $pid = fork() // die "fork failed: $!\n";
 626     if (!$pid) {
 627         POSIX::dup2(fileno($client), 0);
 628         POSIX::dup2(fileno($client), 1);
 629         close($client);
 630         exec {$cmd->[0]} @$cmd or do {
 631             warn "exec failed: $!\n";
 632             POSIX::_exit(1);
 633         };
 634     }
 635
 636     close($client);
 637     if (waitpid($pid, 0) != $pid) {
 638         kill(15 => $pid); # if we got interrupted terminate the child
 639         my $count = 0;
 640         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 641             usleep(100000);
 642             $count++;
 643             kill(9 => $pid), last if $count > 300; # 30 second timeout
 644         }
 645     }
 646     if (my $sig = ($? & 127)) {
 647         die "got signal $sig\n";
 648     } elsif (my $exitcode = ($? >> 8)) {
 649         die "exit code $exitcode\n";
 650     }
 651
 652     return undef;
 653 }
 654
 655 sub split_list {
 656     my $listtxt = shift // '';
 657
 658     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 659
 660     $listtxt =~ s/[,;]/ /g;
 661     $listtxt =~ s/^\s+//;
 662
 663     my @data = split (/\s+/, $listtxt);
 664
 665     return @data;
 666 }
 667
 668 sub trim {
 669     my $txt = shift;
 670
 671     return $txt if !defined($txt);
 672
 673     $txt =~ s/^\s+//;
 674     $txt =~ s/\s+$//;
 675
 676     return $txt;
 677 }
 678
 679 # simple uri templates like "/vms/{vmid}"
 680 sub template_replace {
 681     my ($tmpl, $data) = @_;
 682
 683     return $tmpl if !$tmpl;
 684
 685     my $res = '';
 686     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 687         $res .= $1 if $1;
 688         $res .= ($data->{$3} || '-') if $2;
 689     }
 690     return $res;
 691 }
 692
 693 sub safe_print {
 694     my ($filename, $fh, $data) = @_;
 695
 696     return if !$data;
 697
 698     my $res = print $fh $data;
 699
 700     die "write to '$filename' failed\n" if !$res;
 701 }
 702
 703 sub debmirrors {
 704
 705     return {
 706         'at' => 'ftp.at.debian.org',
 707         'au' => 'ftp.au.debian.org',
 708         'be' => 'ftp.be.debian.org',
 709         'bg' => 'ftp.bg.debian.org',
 710         'br' => 'ftp.br.debian.org',
 711         'ca' => 'ftp.ca.debian.org',
 712         'ch' => 'ftp.ch.debian.org',
 713         'cl' => 'ftp.cl.debian.org',
 714         'cz' => 'ftp.cz.debian.org',
 715         'de' => 'ftp.de.debian.org',
 716         'dk' => 'ftp.dk.debian.org',
 717         'ee' => 'ftp.ee.debian.org',
 718         'es' => 'ftp.es.debian.org',
 719         'fi' => 'ftp.fi.debian.org',
 720         'fr' => 'ftp.fr.debian.org',
 721         'gr' => 'ftp.gr.debian.org',
 722         'hk' => 'ftp.hk.debian.org',
 723         'hr' => 'ftp.hr.debian.org',
 724         'hu' => 'ftp.hu.debian.org',
 725         'ie' => 'ftp.ie.debian.org',
 726         'is' => 'ftp.is.debian.org',
 727         'it' => 'ftp.it.debian.org',
 728         'jp' => 'ftp.jp.debian.org',
 729         'kr' => 'ftp.kr.debian.org',
 730         'mx' => 'ftp.mx.debian.org',
 731         'nl' => 'ftp.nl.debian.org',
 732         'no' => 'ftp.no.debian.org',
 733         'nz' => 'ftp.nz.debian.org',
 734         'pl' => 'ftp.pl.debian.org',
 735         'pt' => 'ftp.pt.debian.org',
 736         'ro' => 'ftp.ro.debian.org',
 737         'ru' => 'ftp.ru.debian.org',
 738         'se' => 'ftp.se.debian.org',
 739         'si' => 'ftp.si.debian.org',
 740         'sk' => 'ftp.sk.debian.org',
 741         'tr' => 'ftp.tr.debian.org',
 742         'tw' => 'ftp.tw.debian.org',
 743         'gb' => 'ftp.uk.debian.org',
 744         'us' => 'ftp.us.debian.org',
 745     };
 746 }
 747
 748 my $keymaphash =  {
 749     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 750     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 751     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 752     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 753     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 754     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 755     #'et'     => [], # Ethopia or Estonia ??
 756     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 757     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 758     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 759     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 760     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 761     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 762     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 763     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 764     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 765     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 766     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 767     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 768     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 769     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 770     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 771     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 772     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 773     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 774     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 775     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 776     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 777     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 778     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 779     #'th'     => [],
 780     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 781 };
 782
 783 my $kvmkeymaparray = [];
 784 foreach my $lc (sort keys %$keymaphash) {
 785     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 786 }
 787
 788 sub kvmkeymaps {
 789     return $keymaphash;
 790 }
 791
 792 sub kvmkeymaplist {
 793     return $kvmkeymaparray;
 794 }
 795
 796 sub extract_param {
 797     my ($param, $key) = @_;
 798
 799     my $res = $param->{$key};
 800     delete $param->{$key};
 801
 802     return $res;
 803 }
 804
 805 # Note: we use this to wait until vncterm/spiceterm is ready
 806 sub wait_for_vnc_port {
 807     my ($port, $family, $timeout) = @_;
 808
 809     $timeout = 5 if !$timeout;
 810     my $sleeptime = 0;
 811     my $starttime = [gettimeofday];
 812     my $elapsed;
 813
 814     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 815     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 816
 817     my $found;
 818     while (($elapsed = tv_interval($starttime)) < $timeout) {
 819         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 820         run_command($cmd, outfunc => sub {
 821             my $line = shift;
 822             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 823                 $found = 1 if ($port == $1);
 824             }
 825         });
 826         return 1 if $found;
 827         $sleeptime += 100000 if  $sleeptime < 1000000;
 828         usleep($sleeptime);
 829     }
 830
 831     die "Timeout while waiting for port '$port' to get ready!\n";
 832 }
 833
 834 sub next_unused_port {
 835     my ($range_start, $range_end, $family, $address) = @_;
 836
 837     # We use a file to register allocated ports.
 838     # Those registrations expires after $expiretime.
 839     # We use this to avoid race conditions between
 840     # allocation and use of ports.
 841
 842     my $filename = "/var/tmp/pve-reserved-ports";
 843
 844     my $code = sub {
 845
 846         my $expiretime = 5;
 847         my $ctime = time();
 848
 849         my $ports = {};
 850
 851         if (my $fh = IO::File->new ($filename, "r")) {
 852             while (my $line = <$fh>) {
 853                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 854                     my ($port, $timestamp) = ($1, $2);
 855                     if (($timestamp + $expiretime) > $ctime) {
 856                         $ports->{$port} = $timestamp; # not expired
 857                     }
 858                 }
 859             }
 860         }
 861
 862         my $newport;
 863         my %sockargs = (Listen => 5,
 864                         ReuseAddr => 1,
 865                         Family    => $family,
 866                         Proto     => IPPROTO_TCP,
 867                         GetAddrInfoFlags => 0);
 868         $sockargs{LocalAddr} = $address if defined($address);
 869
 870         for (my $p = $range_start; $p < $range_end; $p++) {
 871             next if $ports->{$p}; # reserved
 872
 873             $sockargs{LocalPort} = $p;
 874             my $sock = IO::Socket::IP->new(%sockargs);
 875
 876             if ($sock) {
 877                 close($sock);
 878                 $newport = $p;
 879                 $ports->{$p} = $ctime;
 880                 last;
 881             }
 882         }
 883
 884         my $data = "";
 885         foreach my $p (keys %$ports) {
 886             $data .= "$p $ports->{$p}\n";
 887         }
 888
 889         file_set_contents($filename, $data);
 890
 891         return $newport;
 892     };
 893
 894     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 895     die $@ if $@;
 896
 897     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 898
 899     return $p;
 900 }
 901
 902 sub next_migrate_port {
 903     my ($family, $address) = @_;
 904     return next_unused_port(60000, 60050, $family, $address);
 905 }
 906
 907 sub next_vnc_port {
 908     my ($family, $address) = @_;
 909     return next_unused_port(5900, 6000, $family, $address);
 910 }
 911
 912 sub spice_port_range {
 913     return (61000, 61999);
 914 }
 915
 916 sub next_spice_port {
 917     my ($family, $address) = @_;
 918     return next_unused_port(spice_port_range(), $family, $address);
 919 }
 920
 921 sub must_stringify {
 922         my ($value) = @_;
 923         eval { $value = "$value" };
 924         return "error turning value into a string: $@" if $@;
 925         return $value;
 926 }
 927
 928 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 929 # the $sub has to return a single scalar
 930 sub run_fork_with_timeout {
 931     my ($timeout, $sub) = @_;
 932
 933     my $res;
 934     my $error;
 935     my $pipe_out = IO::Pipe->new();
 936
 937     # disable pending alarms, save their remaining time
 938     my $prev_alarm = alarm 0;
 939
 940     # avoid leaving a zombie if the parent gets interrupted
 941     my $sig_received;
 942
 943     my $child = fork();
 944     if (!defined($child)) {
 945         die "fork failed: $!\n";
 946         return $res;
 947     }
 948
 949     if (!$child) {
 950         $pipe_out->writer();
 951
 952         eval {
 953             $res = $sub->();
 954             print {$pipe_out} encode_json({ result => $res });
 955             $pipe_out->flush();
 956         };
 957         if (my $err = $@) {
 958             print {$pipe_out} encode_json({ error => must_stringify($err) });
 959             $pipe_out->flush();
 960             POSIX::_exit(1);
 961         }
 962         POSIX::_exit(0);
 963     }
 964
 965     local $SIG{INT} = sub { $sig_received++; };
 966     local $SIG{TERM} = sub {
 967         $error //= "interrupted by unexpected signal\n";
 968         kill('TERM', $child);
 969     };
 970
 971     $pipe_out->reader();
 972
 973     my $readvalues = sub {
 974         local $/ = undef;
 975         my $child_res = decode_json(readline_nointr($pipe_out));
 976         $res = $child_res->{result};
 977         $error = $child_res->{error};
 978     };
 979     eval {
 980         if (defined($timeout)) {
 981             run_with_timeout($timeout, $readvalues);
 982         } else {
 983             $readvalues->();
 984         }
 985     };
 986     warn $@ if $@;
 987     $pipe_out->close();
 988     kill('KILL', $child);
 989     waitpid($child, 0);
 990
 991     alarm $prev_alarm;
 992     die "interrupted by unexpected signal\n" if $sig_received;
 993
 994     die $error if $error;
 995     return $res;
 996 }
 997
 998 sub run_fork {
 999     my ($code) = @_;
1000     return run_fork_with_timeout(undef, $code);
1001 }
1002
1003 # NOTE: NFS syscall can't be interrupted, so alarm does
1004 # not work to provide timeouts.
1005 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1006 # So fork() before using Filesys::Df
1007 sub df {
1008     my ($path, $timeout) = @_;
1009
1010     my $df = sub { return Filesys::Df::df($path, 1) };
1011
1012     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1013     warn $@ if $@;
1014
1015     # untaint, but be flexible: PB usage can result in scientific notation
1016     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1017         $res->@{qw(blocks used bavail)};
1018
1019     return {
1020         total => $blocks,
1021         used => $used,
1022         avail => $bavail,
1023     };
1024 }
1025
1026 sub du {
1027     my ($path, $timeout) = @_;
1028
1029     my $size;
1030
1031     $timeout //= 10;
1032
1033     my $parser = sub {
1034         my $line = shift;
1035
1036         if ($line =~ m/^(\d+)\s+total$/) {
1037             $size = $1;
1038         }
1039     };
1040
1041     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1042
1043     return $size;
1044 }
1045
1046 # UPID helper
1047 # We use this to uniquely identify a process.
1048 # An 'Unique Process ID' has the following format:
1049 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1050
1051 sub upid_encode {
1052     my $d = shift;
1053
1054     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1055     # more that 8 characters for pstart
1056     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1057                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1058                    $d->{user});
1059 }
1060
1061 sub upid_decode {
1062     my ($upid, $noerr) = @_;
1063
1064     my $res;
1065     my $filename;
1066
1067     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1068     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1069     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1070         $res->{node} = $1;
1071         $res->{pid} = hex($3);
1072         $res->{pstart} = hex($4);
1073         $res->{starttime} = hex($5);
1074         $res->{type} = $6;
1075         $res->{id} = $7;
1076         $res->{user} = $8;
1077
1078         my $subdir = substr($5, 7, 8);
1079         $filename = "$pvetaskdir/$subdir/$upid";
1080
1081     } else {
1082         return undef if $noerr;
1083         die "unable to parse worker upid '$upid'\n";
1084     }
1085
1086     return wantarray ? ($res, $filename) : $res;
1087 }
1088
1089 sub upid_open {
1090     my ($upid) = @_;
1091
1092     my ($task, $filename) = upid_decode($upid);
1093
1094     my $dirname = dirname($filename);
1095     make_path($dirname);
1096
1097     my $wwwid = getpwnam('www-data') ||
1098         die "getpwnam failed";
1099
1100     my $perm = 0640;
1101
1102     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1103         die "unable to create output file '$filename' - $!\n";
1104     chown $wwwid, -1, $outfh;
1105
1106     return $outfh;
1107 };
1108
1109 sub upid_read_status {
1110     my ($upid) = @_;
1111
1112     my ($task, $filename) = upid_decode($upid);
1113     my $fh = IO::File->new($filename, "r");
1114     return "unable to open file - $!" if !$fh;
1115     my $maxlen = 4096;
1116     sysseek($fh, -$maxlen, 2);
1117     my $readbuf = '';
1118     my $br = sysread($fh, $readbuf, $maxlen);
1119     close($fh);
1120     if ($br) {
1121         return "unable to extract last line"
1122             if $readbuf !~ m/\n?(.+)$/;
1123         my $line = $1;
1124         if ($line =~ m/^TASK OK$/) {
1125             return 'OK';
1126         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1127             return $1;
1128         } else {
1129             return "unexpected status";
1130         }
1131     }
1132     return "unable to read tail (got $br bytes)";
1133 }
1134
1135 # useful functions to store comments in config files
1136 sub encode_text {
1137     my ($text) = @_;
1138
1139     # all control and hi-bit characters, and ':'
1140     my $unsafe = "^\x20-\x39\x3b-\x7e";
1141     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1142 }
1143
1144 sub decode_text {
1145     my ($data) = @_;
1146
1147     return Encode::decode("utf8", uri_unescape($data));
1148 }
1149
1150 # depreciated - do not use!
1151 # we now decode all parameters by default
1152 sub decode_utf8_parameters {
1153     my ($param) = @_;
1154
1155     foreach my $p (qw(comment description firstname lastname)) {
1156         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1157     }
1158
1159     return $param;
1160 }
1161
1162 sub random_ether_addr {
1163     my ($prefix) = @_;
1164
1165     my ($seconds, $microseconds) = gettimeofday;
1166
1167     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1168
1169     # clear multicast, set local id
1170     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1171
1172     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1173     if (defined($prefix)) {
1174         $addr = uc($prefix) . substr($addr, length($prefix));
1175     }
1176     return $addr;
1177 }
1178
1179 sub shellquote {
1180     my $str = shift;
1181
1182     return String::ShellQuote::shell_quote($str);
1183 }
1184
1185 sub cmd2string {
1186     my ($cmd) = @_;
1187
1188     die "no arguments" if !$cmd;
1189
1190     return $cmd if !ref($cmd);
1191
1192     my @qa = ();
1193     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1194
1195     return join (' ', @qa);
1196 }
1197
1198 # split an shell argument string into an array,
1199 sub split_args {
1200     my ($str) = @_;
1201
1202     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1203 }
1204
1205 sub dump_logfile {
1206     my ($filename, $start, $limit, $filter) = @_;
1207
1208     my $lines = [];
1209     my $count = 0;
1210
1211     my $fh = IO::File->new($filename, "r");
1212     if (!$fh) {
1213         $count++;
1214         push @$lines, { n => $count, t => "unable to open file - $!"};
1215         return ($count, $lines);
1216     }
1217
1218     $start = 0 if !$start;
1219     $limit = 50 if !$limit;
1220
1221     my $line;
1222
1223     if ($filter) {
1224         # duplicate code, so that we do not slow down normal path
1225         while (defined($line = <$fh>)) {
1226             next if $line !~ m/$filter/;
1227             next if $count++ < $start;
1228             next if $limit <= 0;
1229             chomp $line;
1230             push @$lines, { n => $count, t => $line};
1231             $limit--;
1232         }
1233     } else {
1234         while (defined($line = <$fh>)) {
1235             next if $count++ < $start;
1236             next if $limit <= 0;
1237             chomp $line;
1238             push @$lines, { n => $count, t => $line};
1239             $limit--;
1240         }
1241     }
1242
1243     close($fh);
1244
1245     # HACK: ExtJS store.guaranteeRange() does not like empty array
1246     # so we add a line
1247     if (!$count) {
1248         $count++;
1249         push @$lines, { n => $count, t => "no content"};
1250     }
1251
1252     return ($count, $lines);
1253 }
1254
1255 sub dump_journal {
1256     my ($start, $limit, $since, $until, $service) = @_;
1257
1258     my $lines = [];
1259     my $count = 0;
1260
1261     $start = 0 if !$start;
1262     $limit = 50 if !$limit;
1263
1264     my $parser = sub {
1265         my $line = shift;
1266
1267         return if $count++ < $start;
1268         return if $limit <= 0;
1269         push @$lines, { n => int($count), t => $line};
1270         $limit--;
1271     };
1272
1273     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1274
1275     push @$cmd, '--unit', $service if $service;
1276     push @$cmd, '--since', $since if $since;
1277     push @$cmd, '--until', $until if $until;
1278     run_command($cmd, outfunc => $parser);
1279
1280     # HACK: ExtJS store.guaranteeRange() does not like empty array
1281     # so we add a line
1282     if (!$count) {
1283         $count++;
1284         push @$lines, { n => $count, t => "no content"};
1285     }
1286
1287     return ($count, $lines);
1288 }
1289
1290 sub dir_glob_regex {
1291     my ($dir, $regex) = @_;
1292
1293     my $dh = IO::Dir->new ($dir);
1294     return wantarray ? () : undef if !$dh;
1295
1296     while (defined(my $tmp = $dh->read)) {
1297         if (my @res = $tmp =~ m/^($regex)$/) {
1298             $dh->close;
1299             return wantarray ? @res : $tmp;
1300         }
1301     }
1302     $dh->close;
1303
1304     return wantarray ? () : undef;
1305 }
1306
1307 sub dir_glob_foreach {
1308     my ($dir, $regex, $func) = @_;
1309
1310     my $dh = IO::Dir->new ($dir);
1311     if (defined $dh) {
1312         while (defined(my $tmp = $dh->read)) {
1313             if (my @res = $tmp =~ m/^($regex)$/) {
1314                 &$func (@res);
1315             }
1316         }
1317     }
1318 }
1319
1320 sub assert_if_modified {
1321     my ($digest1, $digest2) = @_;
1322
1323     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1324         die "detected modified configuration - file changed by other user? Try again.\n";
1325     }
1326 }
1327
1328 # Digest for short strings
1329 # like FNV32a, but we only return 31 bits (positive numbers)
1330 sub fnv31a {
1331     my ($string) = @_;
1332
1333     my $hval = 0x811c9dc5;
1334
1335     foreach my $c (unpack('C*', $string)) {
1336         $hval ^= $c;
1337         $hval += (
1338             (($hval << 1) ) +
1339             (($hval << 4) ) +
1340             (($hval << 7) ) +
1341             (($hval << 8) ) +
1342             (($hval << 24) ) );
1343         $hval = $hval & 0xffffffff;
1344     }
1345     return $hval & 0x7fffffff;
1346 }
1347
1348 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1349
1350 sub unpack_sockaddr_in46 {
1351     my ($sin) = @_;
1352     my $family = Socket::sockaddr_family($sin);
1353     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1354                                              : Socket::unpack_sockaddr_in($sin));
1355     return ($family, $port, $host);
1356 }
1357
1358 sub getaddrinfo_all {
1359     my ($hostname, @opts) = @_;
1360     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1361                   @opts );
1362     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1363     die "failed to get address info for: $hostname: $err\n" if $err;
1364     return @res;
1365 }
1366
1367 sub get_host_address_family {
1368     my ($hostname, $socktype) = @_;
1369     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1370     return $res[0]->{family};
1371 }
1372
1373 # get the fully qualified domain name of a host
1374 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1375 # given a nodename as a parameter
1376 sub get_fqdn {
1377     my ($nodename) = @_;
1378
1379     my $hints = {
1380         flags => AI_CANONNAME,
1381         socktype => SOCK_DGRAM
1382     };
1383
1384     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1385
1386     die "getaddrinfo: $err" if $err;
1387
1388     return $addrs[0]->{canonname};
1389 }
1390
1391 # Parses any sane kind of host, or host+port pair:
1392 # The port is always optional and thus may be undef.
1393 sub parse_host_and_port {
1394     my ($address) = @_;
1395     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1396         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1397         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1398     {
1399         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1400     }
1401     return; # nothing
1402 }
1403
1404 sub setresuid($$$) {
1405     my ($ruid, $euid, $suid) = @_;
1406     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1407 }
1408
1409 sub unshare($) {
1410     my ($flags) = @_;
1411     return 0 == syscall(PVE::Syscall::unshare, $flags);
1412 }
1413
1414 sub setns($$) {
1415     my ($fileno, $nstype) = @_;
1416     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1417 }
1418
1419 sub syncfs($) {
1420     my ($fileno) = @_;
1421     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1422 }
1423
1424 sub fsync($) {
1425     my ($fileno) = @_;
1426     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1427 }
1428
1429 sub sync_mountpoint {
1430     my ($path) = @_;
1431     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1432     my $result = syncfs(fileno($fd));
1433     close($fd);
1434     return $result;
1435 }
1436
1437 # support sending multi-part mail messages with a text and or a HTML part
1438 # mailto may be a single email string or an array of receivers
1439 sub sendmail {
1440     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1441     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1442
1443     $mailto = [ $mailto ] if !ref($mailto);
1444
1445     foreach (@$mailto) {
1446         die "illegal character in mailto address\n"
1447             if ($_ =~ $mail_re);
1448     }
1449
1450     my $rcvrtxt = join (', ', @$mailto);
1451
1452     $mailfrom = $mailfrom || "root";
1453     die "illegal character in mailfrom address\n"
1454         if $mailfrom =~ $mail_re;
1455
1456     $author = $author || 'Proxmox VE';
1457
1458     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, "--", @$mailto) ||
1459         die "unable to open 'sendmail' - $!";
1460
1461     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1462     my $boundary = "----_=_NextPart_001_".int(time).$$;
1463
1464     print MAIL "Content-Type: multipart/alternative;\n";
1465     print MAIL "\tboundary=\"$boundary\"\n";
1466     print MAIL "MIME-Version: 1.0\n";
1467
1468     print MAIL "FROM: $author <$mailfrom>\n";
1469     print MAIL "TO: $rcvrtxt\n";
1470     print MAIL "SUBJECT: $subject\n";
1471     print MAIL "\n";
1472     print MAIL "This is a multi-part message in MIME format.\n\n";
1473     print MAIL "--$boundary\n";
1474
1475     if (defined($text)) {
1476         print MAIL "Content-Type: text/plain;\n";
1477         print MAIL "\tcharset=\"UTF8\"\n";
1478         print MAIL "Content-Transfer-Encoding: 8bit\n";
1479         print MAIL "\n";
1480
1481         # avoid 'remove extra line breaks' issue (MS Outlook)
1482         my $fill = '  ';
1483         $text =~ s/^/$fill/gm;
1484
1485         print MAIL $text;
1486
1487         print MAIL "\n--$boundary\n";
1488     }
1489
1490     if (defined($html)) {
1491         print MAIL "Content-Type: text/html;\n";
1492         print MAIL "\tcharset=\"UTF8\"\n";
1493         print MAIL "Content-Transfer-Encoding: 8bit\n";
1494         print MAIL "\n";
1495
1496         print MAIL $html;
1497
1498         print MAIL "\n--$boundary--\n";
1499     }
1500
1501     close(MAIL);
1502 }
1503
1504 sub tempfile {
1505     my ($perm, %opts) = @_;
1506
1507     # default permissions are stricter than with file_set_contents
1508     $perm = 0600 if !defined($perm);
1509
1510     my $dir = $opts{dir} // '/run';
1511     my $mode = $opts{mode} // O_RDWR;
1512     $mode |= O_EXCL if !$opts{allow_links};
1513
1514     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1515     if (!$fh && $! == EOPNOTSUPP) {
1516         $dir = '/tmp' if !defined($opts{dir});
1517         $dir .= "/.tmpfile.$$";
1518         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1519         unlink($dir) if $fh;
1520     }
1521     die "failed to create tempfile: $!\n" if !$fh;
1522     return $fh;
1523 }
1524
1525 sub tempfile_contents {
1526     my ($data, $perm, %opts) = @_;
1527
1528     my $fh = tempfile($perm, %opts);
1529     eval {
1530         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1531         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1532     };
1533     if (my $err = $@) {
1534         close $fh;
1535         die $err;
1536     }
1537
1538     return ("/proc/$$/fd/".$fh->fileno, $fh);
1539 }
1540
1541 sub validate_ssh_public_keys {
1542     my ($raw) = @_;
1543     my @lines = split(/\n/, $raw);
1544
1545     foreach my $line (@lines) {
1546         next if $line =~ m/^\s*$/;
1547         eval {
1548             my ($filename, $handle) = tempfile_contents($line);
1549             run_command(["ssh-keygen", "-l", "-f", $filename],
1550                         outfunc => sub {}, errfunc => sub {});
1551         };
1552         die "SSH public key validation error\n" if $@;
1553     }
1554 }
1555
1556 sub openat($$$;$) {
1557     my ($dirfd, $pathname, $flags, $mode) = @_;
1558     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1559     return undef if $fd < 0;
1560     # sysopen() doesn't deal with numeric file descriptors apparently
1561     # so we need to convert to a mode string for IO::Handle->new_from_fd
1562     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1563     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1564     return $handle if $handle;
1565     my $err = $!; # save error before closing the raw fd
1566     syscall(PVE::Syscall::close, $fd); # close
1567     $! = $err;
1568     return undef;
1569 }
1570
1571 sub mkdirat($$$) {
1572     my ($dirfd, $name, $mode) = @_;
1573     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1574 }
1575
1576 sub fchownat($$$$$) {
1577     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1578     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1579 }
1580
1581 my $salt_starter = time();
1582
1583 sub encrypt_pw {
1584     my ($pw) = @_;
1585
1586     $salt_starter++;
1587     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1588
1589     # crypt does not want '+' in salt (see 'man crypt')
1590     $salt =~ s/\+/X/g;
1591
1592     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1593 }
1594
1595 # intended usage: convert_size($val, "kb" => "gb")
1596 # we round up to the next integer by default
1597 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1598 # use $no_round_up to switch this off, above example would then return 0
1599 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1600 # (0 if $no_round_up is true)
1601 # allowed formats for value:
1602 # 1234
1603 # 1234.
1604 # 1234.1234
1605 # .1234
1606 sub convert_size {
1607     my ($value, $from, $to, $no_round_up) = @_;
1608
1609     my $units = {
1610         b  => 0,
1611         kb => 1,
1612         mb => 2,
1613         gb => 3,
1614         tb => 4,
1615         pb => 5,
1616     };
1617
1618     die "no value given"
1619         if !defined($value) || $value eq "";
1620
1621     $from = lc($from // ''); $to = lc($to // '');
1622     die "unknown 'from' and/or 'to' units ($from => $to)"
1623         if !defined($units->{$from}) || !defined($units->{$to});
1624
1625     die "value '$value' is not a valid, positive number"
1626         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1627
1628     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1629
1630     $value *= 2**$shift_amount;
1631     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1632
1633     return int($value);
1634 }
1635
1636 # uninterruptible readline
1637 # retries on EINTR
1638 sub readline_nointr {
1639     my ($fh) = @_;
1640     my $line;
1641     while (1) {
1642         $line = <$fh>;
1643         last if defined($line) || ($! != EINTR);
1644     }
1645     return $line;
1646 }
1647
1648 my $host_arch;
1649 sub get_host_arch {
1650     $host_arch = (POSIX::uname())[4] if !$host_arch;
1651     return $host_arch;
1652 }
1653
1654 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1655 sub dev_t_major($) {
1656     my ($dev_t) = @_;
1657     return (int($dev_t) & 0xfff00) >> 8;
1658 }
1659
1660 sub dev_t_minor($) {
1661     my ($dev_t) = @_;
1662     $dev_t = int($dev_t);
1663     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1664 }
1665
1666 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1667 # Returns the intersection of elements as a single array [a b]
1668 sub array_intersect {
1669     my ($arrays) = @_;
1670
1671     if (!ref($arrays->[0])) {
1672         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1673     }
1674
1675     return [] if scalar(@$arrays) == 0;
1676     return $arrays->[0] if scalar(@$arrays) == 1;
1677
1678     my $array_unique = sub {
1679         my %seen = ();
1680         return grep { ! $seen{ $_ }++ } @_;
1681     };
1682
1683     # base idea is to get all unique members from the first array, then
1684     # check the common elements with the next (uniquely made) one, only keep
1685     # those. Repeat for every array and at the end we only have those left
1686     # which exist in all arrays
1687     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1688     for my $i (1 .. $#$arrays) {
1689         my %count = ();
1690         # $return_arr is already unique, explicit at before the loop, implicit below.
1691         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1692             $count{$element}++;
1693         }
1694         $return_arr = [];
1695         foreach my $element (keys %count) {
1696             push @$return_arr, $element if $count{$element} > 1;
1697         }
1698         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1699     }
1700
1701     return $return_arr;
1702 }
1703
1704 sub open_tree($$$) {
1705     my ($dfd, $pathname, $flags) = @_;
1706     return PVE::Syscall::file_handle_result(syscall(
1707         &PVE::Syscall::open_tree,
1708         $dfd,
1709         $pathname,
1710         $flags,
1711     ));
1712 }
1713
1714 sub move_mount($$$$$) {
1715     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1716     return 0 == syscall(
1717         &PVE::Syscall::move_mount,
1718         $from_dirfd,
1719         $from_pathname,
1720         $to_dirfd,
1721         $to_pathname,
1722         $flags,
1723     );
1724 }
1725
1726 sub fsopen($$) {
1727     my ($fsname, $flags) = @_;
1728     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
1729 }
1730
1731 sub fsmount($$$) {
1732     my ($fd, $flags, $mount_attrs) = @_;
1733     return PVE::Syscall::file_handle_result(syscall(
1734         &PVE::Syscall::fsmount,
1735         $fd,
1736         $flags,
1737         $mount_attrs,
1738     ));
1739 }
1740
1741 sub fspick($$$) {
1742     my ($dirfd, $pathname, $flags) = @_;
1743     return PVE::Syscall::file_handle_result(syscall(
1744         &PVE::Syscall::fspick,
1745         $dirfd,
1746         $pathname,
1747         $flags,
1748     ));
1749 }
1750
1751 sub fsconfig($$$$$) {
1752     my ($fd, $command, $key, $value, $aux) = @_;
1753     return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
1754 }
1755
1756 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1757 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1758 sub mount($$$$$) {
1759     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1760     return 0 == syscall(
1761         &PVE::Syscall::mount,
1762         $source,
1763         $target,
1764         $filesystemtype,
1765         $mountflags,
1766         $data,
1767     );
1768 }
1769
1770 sub safe_compare {
1771     my ($left, $right, $cmp) = @_;
1772
1773     return 0 if !defined($left) && !defined($right);
1774     return -1 if !defined($left);
1775     return 1 if !defined($right);
1776     return $cmp->($left, $right);
1777 }
1778
1779 1;