src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Scalar::Util 'weaken';
  28 use Date::Format qw(time2str);
  29
  30 use PVE::Syscall;
  31
  32 # avoid warning when parsing long hex values with hex()
  33 no warnings 'portable'; # Support for 64-bit ints required
  34
  35 our @EXPORT_OK = qw(
  36 $IPV6RE
  37 $IPV4RE
  38 lock_file
  39 lock_file_full
  40 run_command
  41 file_set_contents
  42 file_get_contents
  43 file_read_firstline
  44 dir_glob_regex
  45 dir_glob_foreach
  46 split_list
  47 template_replace
  48 safe_print
  49 trim
  50 extract_param
  51 file_copy
  52 get_host_arch
  53 O_PATH
  54 O_TMPFILE
  55 AT_EMPTY_PATH
  56 AT_FDCWD
  57 CLONE_NEWNS
  58 CLONE_NEWUTS
  59 CLONE_NEWIPC
  60 CLONE_NEWUSER
  61 CLONE_NEWPID
  62 CLONE_NEWNET
  63 );
  64
  65 my $pvelogdir = "/var/log/pve";
  66 my $pvetaskdir = "$pvelogdir/tasks";
  67
  68 mkdir $pvelogdir;
  69 mkdir $pvetaskdir;
  70
  71 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  72 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  73 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  74 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  75
  76 our $IPV6RE = "(?:" .
  77     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  78     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  79     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  80     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  81     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  84     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  85     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  86
  87 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  88
  89 use constant {CLONE_NEWNS   => 0x00020000,
  90               CLONE_NEWUTS  => 0x04000000,
  91               CLONE_NEWIPC  => 0x08000000,
  92               CLONE_NEWUSER => 0x10000000,
  93               CLONE_NEWPID  => 0x20000000,
  94               CLONE_NEWNET  => 0x40000000};
  95
  96 use constant {O_PATH    => 0x00200000,
  97               O_CLOEXEC => 0x00080000,
  98               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  99
 100 use constant {AT_EMPTY_PATH => 0x1000,
 101               AT_FDCWD => -100};
 102
 103 sub run_with_timeout {
 104     my ($timeout, $code, @param) = @_;
 105
 106     die "got timeout\n" if $timeout <= 0;
 107
 108     my $prev_alarm = alarm 0; # suspend outer alarm early
 109
 110     my $sigcount = 0;
 111
 112     my $res;
 113
 114     eval {
 115         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 116         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 117         local $SIG{__DIE__};   # see SA bug 4631
 118
 119         alarm($timeout);
 120
 121         eval { $res = &$code(@param); };
 122
 123         alarm(0); # avoid race conditions
 124
 125         die $@ if $@;
 126     };
 127
 128     my $err = $@;
 129
 130     alarm $prev_alarm;
 131
 132     # this shouldn't happen anymore?
 133     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 134
 135     die $err if $err;
 136
 137     return $res;
 138 }
 139
 140 # flock: we use one file handle per process, so lock file
 141 # can be nested multiple times and succeeds for the same process.
 142 #
 143 # Since this is the only way we lock now and we don't have the old
 144 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 145 # count how deep we're nesting. Therefore this hash now stores a weak reference
 146 # to a boolean telling us whether we already have a lock.
 147
 148 my $lock_handles =  {};
 149
 150 sub lock_file_full {
 151     my ($filename, $timeout, $shared, $code, @param) = @_;
 152
 153     $timeout = 10 if !$timeout;
 154
 155     my $mode = $shared ? LOCK_SH : LOCK_EX;
 156
 157     my $lockhash = ($lock_handles->{$$} //= {});
 158
 159     # Returns a locked file handle.
 160     my $get_locked_file = sub {
 161         my $fh = IO::File->new(">>$filename")
 162             or die "can't open file - $!\n";
 163
 164         if (!flock($fh, $mode|LOCK_NB)) {
 165             print STDERR "trying to acquire lock...\n";
 166             my $success;
 167             while(1) {
 168                 $success = flock($fh, $mode);
 169                 # try again on EINTR (see bug #273)
 170                 if ($success || ($! != EINTR)) {
 171                     last;
 172                 }
 173             }
 174             if (!$success) {
 175                 print STDERR " failed\n";
 176                 die "can't acquire lock '$filename' - $!\n";
 177             }
 178             print STDERR " OK\n";
 179         }
 180
 181         return $fh;
 182     };
 183
 184     my $res;
 185     my $checkptr = $lockhash->{$filename};
 186     my $check = 0; # This must not go out of scope before running the code.
 187     my $local_fh; # This must stay local
 188     if (!$checkptr || !$$checkptr) {
 189         # We cannot create a weak reference in a single atomic step, so we first
 190         # create a false-value, then create a reference to it, then weaken it,
 191         # and after successfully locking the file we change the boolean value.
 192         #
 193         # The reason for this is that if an outer SIGALRM throws an exception
 194         # between creating the reference and weakening it, a subsequent call to
 195         # lock_file_full() will see a leftover full reference to a valid
 196         # variable. This variable must be 0 in order for said call to attempt to
 197         # lock the file anew.
 198         #
 199         # An externally triggered exception elsewhere in the code will cause the
 200         # weak reference to become 'undef', and since the file handle is only
 201         # stored in the local scope in $local_fh, the file will be closed by
 202         # perl's cleanup routines as well.
 203         #
 204         # This still assumes that an IO::File handle can properly deal with such
 205         # exceptions thrown during its own destruction, but that's up to perls
 206         # guts now.
 207         $lockhash->{$filename} = \$check;
 208         weaken $lockhash->{$filename};
 209         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 210         if ($@) {
 211             $@ = "can't lock file '$filename' - $@";
 212             return undef;
 213         }
 214         $check = 1;
 215     }
 216     $res = eval { &$code(@param); };
 217     return undef if $@;
 218     return $res;
 219 }
 220
 221
 222 sub lock_file {
 223     my ($filename, $timeout, $code, @param) = @_;
 224
 225     return lock_file_full($filename, $timeout, 0, $code, @param);
 226 }
 227
 228 sub file_set_contents {
 229     my ($filename, $data, $perm)  = @_;
 230
 231     $perm = 0644 if !defined($perm);
 232
 233     my $tmpname = "$filename.tmp.$$";
 234
 235     eval {
 236         my ($fh, $tries) = (undef, 0);
 237         while (!$fh && $tries++ < 3) {
 238             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 239             if (!$fh && $! == EEXIST) {
 240                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 241             }
 242         }
 243         die "unable to open file '$tmpname' - $!\n" if !$fh;
 244         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 245         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 246     };
 247     my $err = $@;
 248
 249     if ($err) {
 250         unlink $tmpname;
 251         die $err;
 252     }
 253
 254     if (!rename($tmpname, $filename)) {
 255         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 256         unlink $tmpname;
 257         die $msg;
 258     }
 259 }
 260
 261 sub file_get_contents {
 262     my ($filename, $max) = @_;
 263
 264     my $fh = IO::File->new($filename, "r") ||
 265         die "can't open '$filename' - $!\n";
 266
 267     my $content = safe_read_from($fh, $max, 0, $filename);
 268
 269     close $fh;
 270
 271     return $content;
 272 }
 273
 274 sub file_copy {
 275     my ($filename, $dst, $max, $perm) = @_;
 276
 277     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 278 }
 279
 280 sub file_read_firstline {
 281     my ($filename) = @_;
 282
 283     my $fh = IO::File->new ($filename, "r");
 284     return undef if !$fh;
 285     my $res = <$fh>;
 286     chomp $res if $res;
 287     $fh->close;
 288     return $res;
 289 }
 290
 291 sub safe_read_from {
 292     my ($fh, $max, $oneline, $filename) = @_;
 293
 294     # pmxcfs file size limit
 295     $max = 512*1024 if !$max;
 296
 297     my $subject = defined($filename) ? "file '$filename'" : 'input';
 298
 299     my $br = 0;
 300     my $input = '';
 301     my $count;
 302     while ($count = sysread($fh, $input, 8192, $br)) {
 303         $br += $count;
 304         die "$subject too long - aborting\n" if $br > $max;
 305         if ($oneline && $input =~ m/^(.*)\n/) {
 306             $input = $1;
 307             last;
 308         }
 309     }
 310     die "unable to read $subject - $!\n" if !defined($count);
 311
 312     return $input;
 313 }
 314
 315 # The $cmd parameter can be:
 316 #  -) a string
 317 #    This is generally executed by passing it to the shell with the -c option.
 318 #    However, it can be executed in one of two ways, depending on whether
 319 #    there's a pipe involved:
 320 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 321 #          set -o pipefail &&
 322 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 323 #      (Note that this may result in two different syntax requirements!)
 324 #      FIXME?
 325 #  -) an array of arguments (strings)
 326 #    Will be executed without interference from a shell. (Parameters are passed
 327 #    as is, no escape sequences of strings will be touched.)
 328 #  -) an array of arrays
 329 #    Each array represents a command, and each command's output is piped into
 330 #    the following command's standard input.
 331 #    For this a shell command string is created with pipe symbols between each
 332 #    command.
 333 #    Each command is a list of strings meant to end up in the final command
 334 #    unchanged. In order to achieve this, every argument is shell-quoted.
 335 #    Quoting can be disabled for a particular argument by turning it into a
 336 #    reference, this allows inserting arbitrary shell options.
 337 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 338 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 339 #    will literally print: hello >/dev/null
 340 sub run_command {
 341     my ($cmd, %param) = @_;
 342
 343     my $old_umask;
 344     my $cmdstr;
 345
 346     if (my $ref = ref($cmd)) {
 347         if (ref($cmd->[0])) {
 348             $cmdstr = 'set -o pipefail && ';
 349             my $pipe = '';
 350             foreach my $command (@$cmd) {
 351                 # concatenate quoted parameters
 352                 # strings which are passed by reference are NOT shell quoted
 353                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 354                 $pipe = ' | ';
 355             }
 356             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 357         } else {
 358             $cmdstr = cmd2string($cmd);
 359         }
 360     } else {
 361         $cmdstr = $cmd;
 362         if ($cmd =~ m/\|/) {
 363             # see 'man bash' for option pipefail
 364             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 365         } else {
 366             $cmd = [ $cmd ];
 367         }
 368     }
 369
 370     my $errmsg;
 371     my $laststderr;
 372     my $timeout;
 373     my $oldtimeout;
 374     my $pid;
 375     my $exitcode = -1;
 376
 377     my $outfunc;
 378     my $errfunc;
 379     my $logfunc;
 380     my $input;
 381     my $output;
 382     my $afterfork;
 383     my $noerr;
 384     my $keeplocale;
 385     my $quiet;
 386
 387     eval {
 388
 389         foreach my $p (keys %param) {
 390             if ($p eq 'timeout') {
 391                 $timeout = $param{$p};
 392             } elsif ($p eq 'umask') {
 393                 $old_umask = umask($param{$p});
 394             } elsif ($p eq 'errmsg') {
 395                 $errmsg = $param{$p};
 396             } elsif ($p eq 'input') {
 397                 $input = $param{$p};
 398             } elsif ($p eq 'output') {
 399                 $output = $param{$p};
 400             } elsif ($p eq 'outfunc') {
 401                 $outfunc = $param{$p};
 402             } elsif ($p eq 'errfunc') {
 403                 $errfunc = $param{$p};
 404             } elsif ($p eq 'logfunc') {
 405                 $logfunc = $param{$p};
 406             } elsif ($p eq 'afterfork') {
 407                 $afterfork = $param{$p};
 408             } elsif ($p eq 'noerr') {
 409                 $noerr = $param{$p};
 410             } elsif ($p eq 'keeplocale') {
 411                 $keeplocale = $param{$p};
 412             } elsif ($p eq 'quiet') {
 413                 $quiet = $param{$p};
 414             } else {
 415                 die "got unknown parameter '$p' for run_command\n";
 416             }
 417         }
 418
 419         if ($errmsg) {
 420             my $origerrfunc = $errfunc;
 421             $errfunc = sub {
 422                 if ($laststderr) {
 423                     if ($origerrfunc) {
 424                         &$origerrfunc("$laststderr\n");
 425                     } else {
 426                         print STDERR "$laststderr\n" if $laststderr;
 427                     }
 428                 }
 429                 $laststderr = shift;
 430             };
 431         }
 432
 433         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 434         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 435         my $error  = IO::File->new();
 436
 437         my $orig_pid = $$;
 438
 439         eval {
 440             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 441
 442             # suppress LVM warnings like: "File descriptor 3 left open";
 443             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 444
 445             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 446
 447             # if we pipe fron STDIN, open3 closes STDIN, so we we
 448             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 449             # as soon as we open a new file.
 450             # to avoid that we open /dev/null
 451             if (!ref($writer) && !defined(fileno(STDIN))) {
 452                 POSIX::close(0);
 453                 open(STDIN, "</dev/null");
 454             }
 455         };
 456
 457         my $err = $@;
 458
 459         # catch exec errors
 460         if ($orig_pid != $$) {
 461             warn "ERROR: $err";
 462             POSIX::_exit (1);
 463             kill ('KILL', $$);
 464         }
 465
 466         die $err if $err;
 467
 468         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 469         $oldtimeout = alarm($timeout) if $timeout;
 470
 471         &$afterfork() if $afterfork;
 472
 473         if (ref($writer)) {
 474             print $writer $input if defined $input;
 475             close $writer;
 476         }
 477
 478         my $select = new IO::Select;
 479         $select->add($reader) if ref($reader);
 480         $select->add($error);
 481
 482         my $outlog = '';
 483         my $errlog = '';
 484
 485         my $starttime = time();
 486
 487         while ($select->count) {
 488             my @handles = $select->can_read(1);
 489
 490             foreach my $h (@handles) {
 491                 my $buf = '';
 492                 my $count = sysread ($h, $buf, 4096);
 493                 if (!defined ($count)) {
 494                     my $err = $!;
 495                     kill (9, $pid);
 496                     waitpid ($pid, 0);
 497                     die $err;
 498                 }
 499                 $select->remove ($h) if !$count;
 500                 if ($h eq $reader) {
 501                     if ($outfunc || $logfunc) {
 502                         eval {
 503                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 504                                 my $line = $outlog . $1;
 505                                 $outlog = '';
 506                                 &$outfunc($line) if $outfunc;
 507                                 &$logfunc($line) if $logfunc;
 508                             }
 509                             $outlog .= $buf;
 510                         };
 511                         my $err = $@;
 512                         if ($err) {
 513                             kill (9, $pid);
 514                             waitpid ($pid, 0);
 515                             die $err;
 516                         }
 517                     } elsif (!$quiet) {
 518                         print $buf;
 519                         *STDOUT->flush();
 520                     }
 521                 } elsif ($h eq $error) {
 522                     if ($errfunc || $logfunc) {
 523                         eval {
 524                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 525                                 my $line = $errlog . $1;
 526                                 $errlog = '';
 527                                 &$errfunc($line) if $errfunc;
 528                                 &$logfunc($line) if $logfunc;
 529                             }
 530                             $errlog .= $buf;
 531                         };
 532                         my $err = $@;
 533                         if ($err) {
 534                             kill (9, $pid);
 535                             waitpid ($pid, 0);
 536                             die $err;
 537                         }
 538                     } elsif (!$quiet) {
 539                         print STDERR $buf;
 540                         *STDERR->flush();
 541                     }
 542                 }
 543             }
 544         }
 545
 546         &$outfunc($outlog) if $outfunc && $outlog;
 547         &$logfunc($outlog) if $logfunc && $outlog;
 548
 549         &$errfunc($errlog) if $errfunc && $errlog;
 550         &$logfunc($errlog) if $logfunc && $errlog;
 551
 552         waitpid ($pid, 0);
 553
 554         if ($? == -1) {
 555             die "failed to execute\n";
 556         } elsif (my $sig = ($? & 127)) {
 557             die "got signal $sig\n";
 558         } elsif ($exitcode = ($? >> 8)) {
 559             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 560                 if ($errmsg && $laststderr) {
 561                     my $lerr = $laststderr;
 562                     $laststderr = undef;
 563                     die "$lerr\n";
 564                 }
 565                 die "exit code $exitcode\n";
 566             }
 567         }
 568
 569         alarm(0);
 570     };
 571
 572     my $err = $@;
 573
 574     alarm(0);
 575
 576     if ($errmsg && $laststderr) {
 577         &$errfunc(undef); # flush laststderr
 578     }
 579
 580     umask ($old_umask) if defined($old_umask);
 581
 582     alarm($oldtimeout) if $oldtimeout;
 583
 584     if ($err) {
 585         if ($pid && ($err eq "got timeout\n")) {
 586             kill (9, $pid);
 587             waitpid ($pid, 0);
 588             die "command '$cmdstr' failed: $err";
 589         }
 590
 591         if ($errmsg) {
 592             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 593             die "$errmsg: $err";
 594         } elsif(!$noerr) {
 595             die "command '$cmdstr' failed: $err";
 596         }
 597     }
 598
 599     return $exitcode;
 600 }
 601
 602 # Run a command with a tcp socket as standard input.
 603 sub pipe_socket_to_command  {
 604     my ($cmd, $ip, $port) = @_;
 605
 606     my $params = {
 607         Listen => 1,
 608         ReuseAddr => 1,
 609         Proto => &Socket::IPPROTO_TCP,
 610         GetAddrInfoFlags => 0,
 611         LocalAddr => $ip,
 612         LocalPort => $port,
 613     };
 614     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 615
 616     print "$ip\n$port\n"; # tell remote where to connect
 617     *STDOUT->flush();
 618
 619     alarm 0;
 620     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 621     alarm 30;
 622     my $client = $socket->accept; # Wait for a client
 623     alarm 0;
 624     close($socket);
 625
 626     # We want that the command talks over the TCP socket and takes
 627     # ownership of it, so that when it closes it the connection is
 628     # terminated, so we need to be able to close the socket. So we
 629     # can't really use PVE::Tools::run_command().
 630     my $pid = fork() // die "fork failed: $!\n";
 631     if (!$pid) {
 632         POSIX::dup2(fileno($client), 0);
 633         POSIX::dup2(fileno($client), 1);
 634         close($client);
 635         exec {$cmd->[0]} @$cmd or do {
 636             warn "exec failed: $!\n";
 637             POSIX::_exit(1);
 638         };
 639     }
 640
 641     close($client);
 642     if (waitpid($pid, 0) != $pid) {
 643         kill(15 => $pid); # if we got interrupted terminate the child
 644         my $count = 0;
 645         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 646             usleep(100000);
 647             $count++;
 648             kill(9 => $pid), last if $count > 300; # 30 second timeout
 649         }
 650     }
 651     if (my $sig = ($? & 127)) {
 652         die "got signal $sig\n";
 653     } elsif (my $exitcode = ($? >> 8)) {
 654         die "exit code $exitcode\n";
 655     }
 656
 657     return undef;
 658 }
 659
 660 sub split_list {
 661     my $listtxt = shift // '';
 662
 663     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 664
 665     $listtxt =~ s/[,;]/ /g;
 666     $listtxt =~ s/^\s+//;
 667
 668     my @data = split (/\s+/, $listtxt);
 669
 670     return @data;
 671 }
 672
 673 sub trim {
 674     my $txt = shift;
 675
 676     return $txt if !defined($txt);
 677
 678     $txt =~ s/^\s+//;
 679     $txt =~ s/\s+$//;
 680
 681     return $txt;
 682 }
 683
 684 # simple uri templates like "/vms/{vmid}"
 685 sub template_replace {
 686     my ($tmpl, $data) = @_;
 687
 688     return $tmpl if !$tmpl;
 689
 690     my $res = '';
 691     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 692         $res .= $1 if $1;
 693         $res .= ($data->{$3} || '-') if $2;
 694     }
 695     return $res;
 696 }
 697
 698 sub safe_print {
 699     my ($filename, $fh, $data) = @_;
 700
 701     return if !$data;
 702
 703     my $res = print $fh $data;
 704
 705     die "write to '$filename' failed\n" if !$res;
 706 }
 707
 708 sub debmirrors {
 709
 710     return {
 711         'at' => 'ftp.at.debian.org',
 712         'au' => 'ftp.au.debian.org',
 713         'be' => 'ftp.be.debian.org',
 714         'bg' => 'ftp.bg.debian.org',
 715         'br' => 'ftp.br.debian.org',
 716         'ca' => 'ftp.ca.debian.org',
 717         'ch' => 'ftp.ch.debian.org',
 718         'cl' => 'ftp.cl.debian.org',
 719         'cz' => 'ftp.cz.debian.org',
 720         'de' => 'ftp.de.debian.org',
 721         'dk' => 'ftp.dk.debian.org',
 722         'ee' => 'ftp.ee.debian.org',
 723         'es' => 'ftp.es.debian.org',
 724         'fi' => 'ftp.fi.debian.org',
 725         'fr' => 'ftp.fr.debian.org',
 726         'gr' => 'ftp.gr.debian.org',
 727         'hk' => 'ftp.hk.debian.org',
 728         'hr' => 'ftp.hr.debian.org',
 729         'hu' => 'ftp.hu.debian.org',
 730         'ie' => 'ftp.ie.debian.org',
 731         'is' => 'ftp.is.debian.org',
 732         'it' => 'ftp.it.debian.org',
 733         'jp' => 'ftp.jp.debian.org',
 734         'kr' => 'ftp.kr.debian.org',
 735         'mx' => 'ftp.mx.debian.org',
 736         'nl' => 'ftp.nl.debian.org',
 737         'no' => 'ftp.no.debian.org',
 738         'nz' => 'ftp.nz.debian.org',
 739         'pl' => 'ftp.pl.debian.org',
 740         'pt' => 'ftp.pt.debian.org',
 741         'ro' => 'ftp.ro.debian.org',
 742         'ru' => 'ftp.ru.debian.org',
 743         'se' => 'ftp.se.debian.org',
 744         'si' => 'ftp.si.debian.org',
 745         'sk' => 'ftp.sk.debian.org',
 746         'tr' => 'ftp.tr.debian.org',
 747         'tw' => 'ftp.tw.debian.org',
 748         'gb' => 'ftp.uk.debian.org',
 749         'us' => 'ftp.us.debian.org',
 750     };
 751 }
 752
 753 my $keymaphash =  {
 754     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 755     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 756     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 757     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 758     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 759     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 760     #'et'     => [], # Ethopia or Estonia ??
 761     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 762     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 763     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 764     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 765     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 766     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 767     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 768     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 769     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 770     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 771     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 772     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 773     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 774     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 775     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 776     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 777     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 778     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 779     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 780     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 781     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 782     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 783     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 784     #'th'     => [],
 785     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 786 };
 787
 788 my $kvmkeymaparray = [];
 789 foreach my $lc (sort keys %$keymaphash) {
 790     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 791 }
 792
 793 sub kvmkeymaps {
 794     return $keymaphash;
 795 }
 796
 797 sub kvmkeymaplist {
 798     return $kvmkeymaparray;
 799 }
 800
 801 sub extract_param {
 802     my ($param, $key) = @_;
 803
 804     my $res = $param->{$key};
 805     delete $param->{$key};
 806
 807     return $res;
 808 }
 809
 810 # Note: we use this to wait until vncterm/spiceterm is ready
 811 sub wait_for_vnc_port {
 812     my ($port, $family, $timeout) = @_;
 813
 814     $timeout = 5 if !$timeout;
 815     my $sleeptime = 0;
 816     my $starttime = [gettimeofday];
 817     my $elapsed;
 818
 819     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 820     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 821
 822     my $found;
 823     while (($elapsed = tv_interval($starttime)) < $timeout) {
 824         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 825         run_command($cmd, outfunc => sub {
 826             my $line = shift;
 827             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 828                 $found = 1 if ($port == $1);
 829             }
 830         });
 831         return 1 if $found;
 832         $sleeptime += 100000 if  $sleeptime < 1000000;
 833         usleep($sleeptime);
 834     }
 835
 836     die "Timeout while waiting for port '$port' to get ready!\n";
 837 }
 838
 839 sub next_unused_port {
 840     my ($range_start, $range_end, $family, $address) = @_;
 841
 842     # We use a file to register allocated ports.
 843     # Those registrations expires after $expiretime.
 844     # We use this to avoid race conditions between
 845     # allocation and use of ports.
 846
 847     my $filename = "/var/tmp/pve-reserved-ports";
 848
 849     my $code = sub {
 850
 851         my $expiretime = 5;
 852         my $ctime = time();
 853
 854         my $ports = {};
 855
 856         if (my $fh = IO::File->new ($filename, "r")) {
 857             while (my $line = <$fh>) {
 858                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 859                     my ($port, $timestamp) = ($1, $2);
 860                     if (($timestamp + $expiretime) > $ctime) {
 861                         $ports->{$port} = $timestamp; # not expired
 862                     }
 863                 }
 864             }
 865         }
 866
 867         my $newport;
 868         my %sockargs = (Listen => 5,
 869                         ReuseAddr => 1,
 870                         Family    => $family,
 871                         Proto     => IPPROTO_TCP,
 872                         GetAddrInfoFlags => 0);
 873         $sockargs{LocalAddr} = $address if defined($address);
 874
 875         for (my $p = $range_start; $p < $range_end; $p++) {
 876             next if $ports->{$p}; # reserved
 877
 878             $sockargs{LocalPort} = $p;
 879             my $sock = IO::Socket::IP->new(%sockargs);
 880
 881             if ($sock) {
 882                 close($sock);
 883                 $newport = $p;
 884                 $ports->{$p} = $ctime;
 885                 last;
 886             }
 887         }
 888
 889         my $data = "";
 890         foreach my $p (keys %$ports) {
 891             $data .= "$p $ports->{$p}\n";
 892         }
 893
 894         file_set_contents($filename, $data);
 895
 896         return $newport;
 897     };
 898
 899     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 900     die $@ if $@;
 901
 902     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 903
 904     return $p;
 905 }
 906
 907 sub next_migrate_port {
 908     my ($family, $address) = @_;
 909     return next_unused_port(60000, 60050, $family, $address);
 910 }
 911
 912 sub next_vnc_port {
 913     my ($family, $address) = @_;
 914     return next_unused_port(5900, 6000, $family, $address);
 915 }
 916
 917 sub spice_port_range {
 918     return (61000, 61999);
 919 }
 920
 921 sub next_spice_port {
 922     my ($family, $address) = @_;
 923     return next_unused_port(spice_port_range(), $family, $address);
 924 }
 925
 926 sub must_stringify {
 927         my ($value) = @_;
 928         eval { $value = "$value" };
 929         return "error turning value into a string: $@" if $@;
 930         return $value;
 931 }
 932
 933 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 934 # the $sub has to return a single scalar
 935 sub run_fork_with_timeout {
 936     my ($timeout, $sub) = @_;
 937
 938     my $res;
 939     my $error;
 940     my $pipe_out = IO::Pipe->new();
 941
 942     # disable pending alarms, save their remaining time
 943     my $prev_alarm = alarm 0;
 944
 945     # avoid leaving a zombie if the parent gets interrupted
 946     my $sig_received;
 947
 948     my $child = fork();
 949     if (!defined($child)) {
 950         die "fork failed: $!\n";
 951         return $res;
 952     }
 953
 954     if (!$child) {
 955         $pipe_out->writer();
 956
 957         eval {
 958             $res = $sub->();
 959             print {$pipe_out} encode_json({ result => $res });
 960             $pipe_out->flush();
 961         };
 962         if (my $err = $@) {
 963             print {$pipe_out} encode_json({ error => must_stringify($err) });
 964             $pipe_out->flush();
 965             POSIX::_exit(1);
 966         }
 967         POSIX::_exit(0);
 968     }
 969
 970     local $SIG{INT} = sub { $sig_received++; };
 971     local $SIG{TERM} = sub {
 972         $error //= "interrupted by unexpected signal\n";
 973         kill('TERM', $child);
 974     };
 975
 976     $pipe_out->reader();
 977
 978     my $readvalues = sub {
 979         local $/ = undef;
 980         my $child_res = decode_json(readline_nointr($pipe_out));
 981         $res = $child_res->{result};
 982         $error = $child_res->{error};
 983     };
 984     eval {
 985         if (defined($timeout)) {
 986             run_with_timeout($timeout, $readvalues);
 987         } else {
 988             $readvalues->();
 989         }
 990     };
 991     warn $@ if $@;
 992     $pipe_out->close();
 993     kill('KILL', $child);
 994     waitpid($child, 0);
 995
 996     alarm $prev_alarm;
 997     die "interrupted by unexpected signal\n" if $sig_received;
 998
 999     die $error if $error;
1000     return $res;
1001 }
1002
1003 sub run_fork {
1004     my ($code) = @_;
1005     return run_fork_with_timeout(undef, $code);
1006 }
1007
1008 # NOTE: NFS syscall can't be interrupted, so alarm does
1009 # not work to provide timeouts.
1010 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1011 # So fork() before using Filesys::Df
1012 sub df {
1013     my ($path, $timeout) = @_;
1014
1015     my $df = sub { return Filesys::Df::df($path, 1) };
1016
1017     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1018     warn $@ if $@;
1019
1020     # untaint, but be flexible: PB usage can result in scientific notation
1021     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1022         $res->@{qw(blocks used bavail)};
1023
1024     return {
1025         total => $blocks,
1026         used => $used,
1027         avail => $bavail,
1028     };
1029 }
1030
1031 sub du {
1032     my ($path, $timeout) = @_;
1033
1034     my $size;
1035
1036     $timeout //= 10;
1037
1038     my $parser = sub {
1039         my $line = shift;
1040
1041         if ($line =~ m/^(\d+)\s+total$/) {
1042             $size = $1;
1043         }
1044     };
1045
1046     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1047
1048     return $size;
1049 }
1050
1051 # UPID helper
1052 # We use this to uniquely identify a process.
1053 # An 'Unique Process ID' has the following format:
1054 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1055
1056 sub upid_encode {
1057     my $d = shift;
1058
1059     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1060     # more that 8 characters for pstart
1061     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1062                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1063                    $d->{user});
1064 }
1065
1066 sub upid_decode {
1067     my ($upid, $noerr) = @_;
1068
1069     my $res;
1070     my $filename;
1071
1072     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1073     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1074     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1075         $res->{node} = $1;
1076         $res->{pid} = hex($3);
1077         $res->{pstart} = hex($4);
1078         $res->{starttime} = hex($5);
1079         $res->{type} = $6;
1080         $res->{id} = $7;
1081         $res->{user} = $8;
1082
1083         my $subdir = substr($5, 7, 8);
1084         $filename = "$pvetaskdir/$subdir/$upid";
1085
1086     } else {
1087         return undef if $noerr;
1088         die "unable to parse worker upid '$upid'\n";
1089     }
1090
1091     return wantarray ? ($res, $filename) : $res;
1092 }
1093
1094 sub upid_open {
1095     my ($upid) = @_;
1096
1097     my ($task, $filename) = upid_decode($upid);
1098
1099     my $dirname = dirname($filename);
1100     make_path($dirname);
1101
1102     my $wwwid = getpwnam('www-data') ||
1103         die "getpwnam failed";
1104
1105     my $perm = 0640;
1106
1107     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1108         die "unable to create output file '$filename' - $!\n";
1109     chown $wwwid, -1, $outfh;
1110
1111     return $outfh;
1112 };
1113
1114 sub upid_read_status {
1115     my ($upid) = @_;
1116
1117     my ($task, $filename) = upid_decode($upid);
1118     my $fh = IO::File->new($filename, "r");
1119     return "unable to open file - $!" if !$fh;
1120     my $maxlen = 4096;
1121     sysseek($fh, -$maxlen, 2);
1122     my $readbuf = '';
1123     my $br = sysread($fh, $readbuf, $maxlen);
1124     close($fh);
1125     if ($br) {
1126         return "unable to extract last line"
1127             if $readbuf !~ m/\n?(.+)$/;
1128         my $line = $1;
1129         if ($line =~ m/^TASK OK$/) {
1130             return 'OK';
1131         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1132             return $1;
1133         } else {
1134             return "unexpected status";
1135         }
1136     }
1137     return "unable to read tail (got $br bytes)";
1138 }
1139
1140 # useful functions to store comments in config files
1141 sub encode_text {
1142     my ($text) = @_;
1143
1144     # all control and hi-bit characters, and ':'
1145     my $unsafe = "^\x20-\x39\x3b-\x7e";
1146     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1147 }
1148
1149 sub decode_text {
1150     my ($data) = @_;
1151
1152     return Encode::decode("utf8", uri_unescape($data));
1153 }
1154
1155 # depreciated - do not use!
1156 # we now decode all parameters by default
1157 sub decode_utf8_parameters {
1158     my ($param) = @_;
1159
1160     foreach my $p (qw(comment description firstname lastname)) {
1161         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1162     }
1163
1164     return $param;
1165 }
1166
1167 sub random_ether_addr {
1168     my ($prefix) = @_;
1169
1170     my ($seconds, $microseconds) = gettimeofday;
1171
1172     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1173
1174     # clear multicast, set local id
1175     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1176
1177     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1178     if (defined($prefix)) {
1179         $addr = uc($prefix) . substr($addr, length($prefix));
1180     }
1181     return $addr;
1182 }
1183
1184 sub shellquote {
1185     my $str = shift;
1186
1187     return String::ShellQuote::shell_quote($str);
1188 }
1189
1190 sub cmd2string {
1191     my ($cmd) = @_;
1192
1193     die "no arguments" if !$cmd;
1194
1195     return $cmd if !ref($cmd);
1196
1197     my @qa = ();
1198     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1199
1200     return join (' ', @qa);
1201 }
1202
1203 # split an shell argument string into an array,
1204 sub split_args {
1205     my ($str) = @_;
1206
1207     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1208 }
1209
1210 sub dump_logfile {
1211     my ($filename, $start, $limit, $filter) = @_;
1212
1213     my $lines = [];
1214     my $count = 0;
1215
1216     my $fh = IO::File->new($filename, "r");
1217     if (!$fh) {
1218         $count++;
1219         push @$lines, { n => $count, t => "unable to open file - $!"};
1220         return ($count, $lines);
1221     }
1222
1223     $start = 0 if !$start;
1224     $limit = 50 if !$limit;
1225
1226     my $line;
1227
1228     if ($filter) {
1229         # duplicate code, so that we do not slow down normal path
1230         while (defined($line = <$fh>)) {
1231             next if $line !~ m/$filter/;
1232             next if $count++ < $start;
1233             next if $limit <= 0;
1234             chomp $line;
1235             push @$lines, { n => $count, t => $line};
1236             $limit--;
1237         }
1238     } else {
1239         while (defined($line = <$fh>)) {
1240             next if $count++ < $start;
1241             next if $limit <= 0;
1242             chomp $line;
1243             push @$lines, { n => $count, t => $line};
1244             $limit--;
1245         }
1246     }
1247
1248     close($fh);
1249
1250     # HACK: ExtJS store.guaranteeRange() does not like empty array
1251     # so we add a line
1252     if (!$count) {
1253         $count++;
1254         push @$lines, { n => $count, t => "no content"};
1255     }
1256
1257     return ($count, $lines);
1258 }
1259
1260 sub dump_journal {
1261     my ($start, $limit, $since, $until, $service) = @_;
1262
1263     my $lines = [];
1264     my $count = 0;
1265
1266     $start = 0 if !$start;
1267     $limit = 50 if !$limit;
1268
1269     my $parser = sub {
1270         my $line = shift;
1271
1272         return if $count++ < $start;
1273         return if $limit <= 0;
1274         push @$lines, { n => int($count), t => $line};
1275         $limit--;
1276     };
1277
1278     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1279
1280     push @$cmd, '--unit', $service if $service;
1281     push @$cmd, '--since', $since if $since;
1282     push @$cmd, '--until', $until if $until;
1283     run_command($cmd, outfunc => $parser);
1284
1285     # HACK: ExtJS store.guaranteeRange() does not like empty array
1286     # so we add a line
1287     if (!$count) {
1288         $count++;
1289         push @$lines, { n => $count, t => "no content"};
1290     }
1291
1292     return ($count, $lines);
1293 }
1294
1295 sub dir_glob_regex {
1296     my ($dir, $regex) = @_;
1297
1298     my $dh = IO::Dir->new ($dir);
1299     return wantarray ? () : undef if !$dh;
1300
1301     while (defined(my $tmp = $dh->read)) {
1302         if (my @res = $tmp =~ m/^($regex)$/) {
1303             $dh->close;
1304             return wantarray ? @res : $tmp;
1305         }
1306     }
1307     $dh->close;
1308
1309     return wantarray ? () : undef;
1310 }
1311
1312 sub dir_glob_foreach {
1313     my ($dir, $regex, $func) = @_;
1314
1315     my $dh = IO::Dir->new ($dir);
1316     if (defined $dh) {
1317         while (defined(my $tmp = $dh->read)) {
1318             if (my @res = $tmp =~ m/^($regex)$/) {
1319                 &$func (@res);
1320             }
1321         }
1322     }
1323 }
1324
1325 sub assert_if_modified {
1326     my ($digest1, $digest2) = @_;
1327
1328     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1329         die "detected modified configuration - file changed by other user? Try again.\n";
1330     }
1331 }
1332
1333 # Digest for short strings
1334 # like FNV32a, but we only return 31 bits (positive numbers)
1335 sub fnv31a {
1336     my ($string) = @_;
1337
1338     my $hval = 0x811c9dc5;
1339
1340     foreach my $c (unpack('C*', $string)) {
1341         $hval ^= $c;
1342         $hval += (
1343             (($hval << 1) ) +
1344             (($hval << 4) ) +
1345             (($hval << 7) ) +
1346             (($hval << 8) ) +
1347             (($hval << 24) ) );
1348         $hval = $hval & 0xffffffff;
1349     }
1350     return $hval & 0x7fffffff;
1351 }
1352
1353 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1354
1355 sub unpack_sockaddr_in46 {
1356     my ($sin) = @_;
1357     my $family = Socket::sockaddr_family($sin);
1358     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1359                                              : Socket::unpack_sockaddr_in($sin));
1360     return ($family, $port, $host);
1361 }
1362
1363 sub getaddrinfo_all {
1364     my ($hostname, @opts) = @_;
1365     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1366                   @opts );
1367     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1368     die "failed to get address info for: $hostname: $err\n" if $err;
1369     return @res;
1370 }
1371
1372 sub get_host_address_family {
1373     my ($hostname, $socktype) = @_;
1374     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1375     return $res[0]->{family};
1376 }
1377
1378 # get the fully qualified domain name of a host
1379 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1380 # given a nodename as a parameter
1381 sub get_fqdn {
1382     my ($nodename) = @_;
1383
1384     my $hints = {
1385         flags => AI_CANONNAME,
1386         socktype => SOCK_DGRAM
1387     };
1388
1389     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1390
1391     die "getaddrinfo: $err" if $err;
1392
1393     return $addrs[0]->{canonname};
1394 }
1395
1396 # Parses any sane kind of host, or host+port pair:
1397 # The port is always optional and thus may be undef.
1398 sub parse_host_and_port {
1399     my ($address) = @_;
1400     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1401         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1402         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1403     {
1404         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1405     }
1406     return; # nothing
1407 }
1408
1409 sub setresuid($$$) {
1410     my ($ruid, $euid, $suid) = @_;
1411     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1412 }
1413
1414 sub unshare($) {
1415     my ($flags) = @_;
1416     return 0 == syscall(PVE::Syscall::unshare, $flags);
1417 }
1418
1419 sub setns($$) {
1420     my ($fileno, $nstype) = @_;
1421     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1422 }
1423
1424 sub syncfs($) {
1425     my ($fileno) = @_;
1426     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1427 }
1428
1429 sub fsync($) {
1430     my ($fileno) = @_;
1431     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1432 }
1433
1434 sub sync_mountpoint {
1435     my ($path) = @_;
1436     sysopen my $fd, $path, O_RDONLY|O_CLOEXEC or die "failed to open $path: $!\n";
1437     my $syncfs_err;
1438     if (!syncfs(fileno($fd))) {
1439         $syncfs_err = "$!";
1440     }
1441     close($fd);
1442     die "syncfs '$path' failed - $syncfs_err\n" if defined $syncfs_err;
1443 }
1444
1445 # support sending multi-part mail messages with a text and or a HTML part
1446 # mailto may be a single email string or an array of receivers
1447 sub sendmail {
1448     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1449     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1450
1451     $mailto = [ $mailto ] if !ref($mailto);
1452
1453     foreach (@$mailto) {
1454         die "illegal character in mailto address\n"
1455             if ($_ =~ $mail_re);
1456     }
1457
1458     my $rcvrtxt = join (', ', @$mailto);
1459
1460     $mailfrom = $mailfrom || "root";
1461     die "illegal character in mailfrom address\n"
1462         if $mailfrom =~ $mail_re;
1463
1464     $author = $author // 'Proxmox VE';
1465
1466     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, "--", @$mailto) ||
1467         die "unable to open 'sendmail' - $!";
1468
1469     my $date = time2str('%a, %d %b %Y %H:%M:%S %z', time());
1470
1471     my $is_multipart = $text && $html;
1472
1473     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1474     my $boundary = "----_=_NextPart_001_".int(time).$$;
1475
1476     if ($subject =~ /[^[:ascii:]]/) {
1477         $subject = Encode::encode('MIME-Header', $subject);
1478     }
1479
1480     if ($subject =~ /[^[:ascii:]]/ || $is_multipart) {
1481         print MAIL "MIME-Version: 1.0\n";
1482     }
1483     print MAIL "From: $author <$mailfrom>\n";
1484     print MAIL "To: $rcvrtxt\n";
1485     print MAIL "Date: $date\n";
1486     print MAIL "Subject: $subject\n";
1487
1488     if ($is_multipart) {
1489         print MAIL "Content-Type: multipart/alternative;\n";
1490         print MAIL "\tboundary=\"$boundary\"\n";
1491         print MAIL "\n";
1492         print MAIL "This is a multi-part message in MIME format.\n\n";
1493         print MAIL "--$boundary\n";
1494     }
1495
1496     if (defined($text)) {
1497         print MAIL "Content-Type: text/plain;\n";
1498         print MAIL "\tcharset=\"UTF-8\"\n";
1499         print MAIL "Content-Transfer-Encoding: 8bit\n";
1500         print MAIL "\n";
1501
1502         # avoid 'remove extra line breaks' issue (MS Outlook)
1503         my $fill = '  ';
1504         $text =~ s/^/$fill/gm;
1505
1506         print MAIL $text;
1507
1508         print MAIL "\n--$boundary\n" if $is_multipart;
1509     }
1510
1511     if (defined($html)) {
1512         print MAIL "Content-Type: text/html;\n";
1513         print MAIL "\tcharset=\"UTF-8\"\n";
1514         print MAIL "Content-Transfer-Encoding: 8bit\n";
1515         print MAIL "\n";
1516
1517         print MAIL $html;
1518
1519         print MAIL "\n--$boundary--\n" if $is_multipart;
1520     }
1521
1522     close(MAIL);
1523 }
1524
1525 sub tempfile {
1526     my ($perm, %opts) = @_;
1527
1528     # default permissions are stricter than with file_set_contents
1529     $perm = 0600 if !defined($perm);
1530
1531     my $dir = $opts{dir} // '/run';
1532     my $mode = $opts{mode} // O_RDWR;
1533     $mode |= O_EXCL if !$opts{allow_links};
1534
1535     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1536     if (!$fh && $! == EOPNOTSUPP) {
1537         $dir = '/tmp' if !defined($opts{dir});
1538         $dir .= "/.tmpfile.$$";
1539         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1540         unlink($dir) if $fh;
1541     }
1542     die "failed to create tempfile: $!\n" if !$fh;
1543     return $fh;
1544 }
1545
1546 sub tempfile_contents {
1547     my ($data, $perm, %opts) = @_;
1548
1549     my $fh = tempfile($perm, %opts);
1550     eval {
1551         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1552         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1553     };
1554     if (my $err = $@) {
1555         close $fh;
1556         die $err;
1557     }
1558
1559     return ("/proc/$$/fd/".$fh->fileno, $fh);
1560 }
1561
1562 sub validate_ssh_public_keys {
1563     my ($raw) = @_;
1564     my @lines = split(/\n/, $raw);
1565
1566     foreach my $line (@lines) {
1567         next if $line =~ m/^\s*$/;
1568         eval {
1569             my ($filename, $handle) = tempfile_contents($line);
1570             run_command(["ssh-keygen", "-l", "-f", $filename],
1571                         outfunc => sub {}, errfunc => sub {});
1572         };
1573         die "SSH public key validation error\n" if $@;
1574     }
1575 }
1576
1577 sub openat($$$;$) {
1578     my ($dirfd, $pathname, $flags, $mode) = @_;
1579     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1580     return undef if $fd < 0;
1581     # sysopen() doesn't deal with numeric file descriptors apparently
1582     # so we need to convert to a mode string for IO::Handle->new_from_fd
1583     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1584     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1585     return $handle if $handle;
1586     my $err = $!; # save error before closing the raw fd
1587     syscall(PVE::Syscall::close, $fd); # close
1588     $! = $err;
1589     return undef;
1590 }
1591
1592 sub mkdirat($$$) {
1593     my ($dirfd, $name, $mode) = @_;
1594     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1595 }
1596
1597 sub fchownat($$$$$) {
1598     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1599     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1600 }
1601
1602 my $salt_starter = time();
1603
1604 sub encrypt_pw {
1605     my ($pw) = @_;
1606
1607     $salt_starter++;
1608     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1609
1610     # crypt does not want '+' in salt (see 'man crypt')
1611     $salt =~ s/\+/X/g;
1612
1613     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1614 }
1615
1616 # intended usage: convert_size($val, "kb" => "gb")
1617 # we round up to the next integer by default
1618 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1619 # use $no_round_up to switch this off, above example would then return 0
1620 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1621 # (0 if $no_round_up is true)
1622 # allowed formats for value:
1623 # 1234
1624 # 1234.
1625 # 1234.1234
1626 # .1234
1627 sub convert_size {
1628     my ($value, $from, $to, $no_round_up) = @_;
1629
1630     my $units = {
1631         b  => 0,
1632         kb => 1,
1633         mb => 2,
1634         gb => 3,
1635         tb => 4,
1636         pb => 5,
1637     };
1638
1639     die "no value given"
1640         if !defined($value) || $value eq "";
1641
1642     $from = lc($from // ''); $to = lc($to // '');
1643     die "unknown 'from' and/or 'to' units ($from => $to)"
1644         if !defined($units->{$from}) || !defined($units->{$to});
1645
1646     die "value '$value' is not a valid, positive number"
1647         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1648
1649     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1650
1651     $value *= 2**$shift_amount;
1652     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1653
1654     return int($value);
1655 }
1656
1657 # uninterruptible readline
1658 # retries on EINTR
1659 sub readline_nointr {
1660     my ($fh) = @_;
1661     my $line;
1662     while (1) {
1663         $line = <$fh>;
1664         last if defined($line) || ($! != EINTR);
1665     }
1666     return $line;
1667 }
1668
1669 my $host_arch;
1670 sub get_host_arch {
1671     $host_arch = (POSIX::uname())[4] if !$host_arch;
1672     return $host_arch;
1673 }
1674
1675 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1676 sub dev_t_major($) {
1677     my ($dev_t) = @_;
1678     return (int($dev_t) & 0xfff00) >> 8;
1679 }
1680
1681 sub dev_t_minor($) {
1682     my ($dev_t) = @_;
1683     $dev_t = int($dev_t);
1684     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1685 }
1686
1687 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1688 # Returns the intersection of elements as a single array [a b]
1689 sub array_intersect {
1690     my ($arrays) = @_;
1691
1692     if (!ref($arrays->[0])) {
1693         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1694     }
1695
1696     return [] if scalar(@$arrays) == 0;
1697     return $arrays->[0] if scalar(@$arrays) == 1;
1698
1699     my $array_unique = sub {
1700         my %seen = ();
1701         return grep { ! $seen{ $_ }++ } @_;
1702     };
1703
1704     # base idea is to get all unique members from the first array, then
1705     # check the common elements with the next (uniquely made) one, only keep
1706     # those. Repeat for every array and at the end we only have those left
1707     # which exist in all arrays
1708     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1709     for my $i (1 .. $#$arrays) {
1710         my %count = ();
1711         # $return_arr is already unique, explicit at before the loop, implicit below.
1712         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1713             $count{$element}++;
1714         }
1715         $return_arr = [];
1716         foreach my $element (keys %count) {
1717             push @$return_arr, $element if $count{$element} > 1;
1718         }
1719         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1720     }
1721
1722     return $return_arr;
1723 }
1724
1725 sub open_tree($$$) {
1726     my ($dfd, $pathname, $flags) = @_;
1727     return PVE::Syscall::file_handle_result(syscall(
1728         &PVE::Syscall::open_tree,
1729         $dfd,
1730         $pathname,
1731         $flags,
1732     ));
1733 }
1734
1735 sub move_mount($$$$$) {
1736     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1737     return 0 == syscall(
1738         &PVE::Syscall::move_mount,
1739         $from_dirfd,
1740         $from_pathname,
1741         $to_dirfd,
1742         $to_pathname,
1743         $flags,
1744     );
1745 }
1746
1747 sub fsopen($$) {
1748     my ($fsname, $flags) = @_;
1749     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
1750 }
1751
1752 sub fsmount($$$) {
1753     my ($fd, $flags, $mount_attrs) = @_;
1754     return PVE::Syscall::file_handle_result(syscall(
1755         &PVE::Syscall::fsmount,
1756         $fd,
1757         $flags,
1758         $mount_attrs,
1759     ));
1760 }
1761
1762 sub fspick($$$) {
1763     my ($dirfd, $pathname, $flags) = @_;
1764     return PVE::Syscall::file_handle_result(syscall(
1765         &PVE::Syscall::fspick,
1766         $dirfd,
1767         $pathname,
1768         $flags,
1769     ));
1770 }
1771
1772 sub fsconfig($$$$$) {
1773     my ($fd, $command, $key, $value, $aux) = @_;
1774     return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
1775 }
1776
1777 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1778 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1779 sub mount($$$$$) {
1780     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1781     return 0 == syscall(
1782         &PVE::Syscall::mount,
1783         $source,
1784         $target,
1785         $filesystemtype,
1786         $mountflags,
1787         $data,
1788     );
1789 }
1790
1791 sub safe_compare {
1792     my ($left, $right, $cmp) = @_;
1793
1794     return 0 if !defined($left) && !defined($right);
1795     return -1 if !defined($left);
1796     return 1 if !defined($right);
1797     return $cmp->($left, $right);
1798 }
1799
1800 1;