src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Date::Format qw(time2str);
   7 use Digest::MD5;
   8 use Digest::SHA;
   9 use Encode;
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::Path qw(make_path);
  13 use Filesys::Df (); # don't overwrite our df()
  14 use IO::Dir;
  15 use IO::File;
  16 use IO::Handle;
  17 use IO::Pipe;
  18 use IO::Select;
  19 use IO::Socket::IP;
  20 use IPC::Open3;
  21 use JSON;
  22 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
  23 use Scalar::Util 'weaken';
  24 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM IPPROTO_TCP);
  25 use String::ShellQuote;
  26 use Text::ParseWords;
  27 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  28 use URI::Escape;
  29 use base 'Exporter';
  30
  31 use PVE::Syscall;
  32
  33 # avoid warning when parsing long hex values with hex()
  34 no warnings 'portable'; # Support for 64-bit ints required
  35
  36 our @EXPORT_OK = qw(
  37 $IPV6RE
  38 $IPV4RE
  39 lock_file
  40 lock_file_full
  41 run_command
  42 file_set_contents
  43 file_get_contents
  44 file_read_firstline
  45 dir_glob_regex
  46 dir_glob_foreach
  47 split_list
  48 template_replace
  49 safe_print
  50 trim
  51 extract_param
  52 extract_sensitive_params
  53 file_copy
  54 get_host_arch
  55 O_PATH
  56 O_TMPFILE
  57 AT_EMPTY_PATH
  58 AT_FDCWD
  59 CLONE_NEWNS
  60 CLONE_NEWUTS
  61 CLONE_NEWIPC
  62 CLONE_NEWUSER
  63 CLONE_NEWPID
  64 CLONE_NEWNET
  65 );
  66
  67 my $pvelogdir = "/var/log/pve";
  68 my $pvetaskdir = "$pvelogdir/tasks";
  69
  70 mkdir $pvelogdir;
  71 mkdir $pvetaskdir;
  72
  73 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  74 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  75 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  76 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  77
  78 our $IPV6RE = "(?:" .
  79     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  80     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  81     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  84     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  85     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  86     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  87     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  88
  89 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  90
  91 our $EMAIL_USER_RE = qr/[\w\+\-\~]+(\.[\w\+\-\~]+)*/;
  92 our $EMAIL_RE = qr/$EMAIL_USER_RE@[a-zA-Z0-9\-]+(\.[a-zA-Z0-9\-]+)*/;
  93
  94 use constant {CLONE_NEWNS   => 0x00020000,
  95               CLONE_NEWUTS  => 0x04000000,
  96               CLONE_NEWIPC  => 0x08000000,
  97               CLONE_NEWUSER => 0x10000000,
  98               CLONE_NEWPID  => 0x20000000,
  99               CLONE_NEWNET  => 0x40000000};
 100
 101 use constant {O_PATH    => 0x00200000,
 102               O_CLOEXEC => 0x00080000,
 103               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
 104
 105 use constant {AT_EMPTY_PATH => 0x1000,
 106               AT_FDCWD => -100};
 107
 108 # from <linux/fs.h>
 109 use constant {RENAME_NOREPLACE => (1 << 0),
 110               RENAME_EXCHANGE  => (1 << 1),
 111               RENAME_WHITEOUT  => (1 << 2)};
 112
 113 sub run_with_timeout {
 114     my ($timeout, $code, @param) = @_;
 115
 116     die "got timeout\n" if $timeout <= 0;
 117
 118     my $prev_alarm = alarm 0; # suspend outer alarm early
 119
 120     my $sigcount = 0;
 121
 122     my $res;
 123
 124     eval {
 125         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 126         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 127         local $SIG{__DIE__};   # see SA bug 4631
 128
 129         alarm($timeout);
 130
 131         eval { $res = &$code(@param); };
 132
 133         alarm(0); # avoid race conditions
 134
 135         die $@ if $@;
 136     };
 137
 138     my $err = $@;
 139
 140     alarm $prev_alarm;
 141
 142     # this shouldn't happen anymore?
 143     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 144
 145     die $err if $err;
 146
 147     return $res;
 148 }
 149
 150 # flock: we use one file handle per process, so lock file
 151 # can be nested multiple times and succeeds for the same process.
 152 #
 153 # Since this is the only way we lock now and we don't have the old
 154 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 155 # count how deep we're nesting. Therefore this hash now stores a weak reference
 156 # to a boolean telling us whether we already have a lock.
 157
 158 my $lock_handles =  {};
 159
 160 sub lock_file_full {
 161     my ($filename, $timeout, $shared, $code, @param) = @_;
 162
 163     $timeout = 10 if !$timeout;
 164
 165     my $mode = $shared ? LOCK_SH : LOCK_EX;
 166
 167     my $lockhash = ($lock_handles->{$$} //= {});
 168
 169     # Returns a locked file handle.
 170     my $get_locked_file = sub {
 171         my $fh = IO::File->new(">>$filename")
 172             or die "can't open file - $!\n";
 173
 174         if (!flock($fh, $mode|LOCK_NB)) {
 175             print STDERR "trying to acquire lock...\n";
 176             my $success;
 177             while(1) {
 178                 $success = flock($fh, $mode);
 179                 # try again on EINTR (see bug #273)
 180                 if ($success || ($! != EINTR)) {
 181                     last;
 182                 }
 183             }
 184             if (!$success) {
 185                 print STDERR " failed\n";
 186                 die "can't acquire lock '$filename' - $!\n";
 187             }
 188             print STDERR " OK\n";
 189         }
 190
 191         return $fh;
 192     };
 193
 194     my $res;
 195     my $checkptr = $lockhash->{$filename};
 196     my $check = 0; # This must not go out of scope before running the code.
 197     my $local_fh; # This must stay local
 198     if (!$checkptr || !$$checkptr) {
 199         # We cannot create a weak reference in a single atomic step, so we first
 200         # create a false-value, then create a reference to it, then weaken it,
 201         # and after successfully locking the file we change the boolean value.
 202         #
 203         # The reason for this is that if an outer SIGALRM throws an exception
 204         # between creating the reference and weakening it, a subsequent call to
 205         # lock_file_full() will see a leftover full reference to a valid
 206         # variable. This variable must be 0 in order for said call to attempt to
 207         # lock the file anew.
 208         #
 209         # An externally triggered exception elsewhere in the code will cause the
 210         # weak reference to become 'undef', and since the file handle is only
 211         # stored in the local scope in $local_fh, the file will be closed by
 212         # perl's cleanup routines as well.
 213         #
 214         # This still assumes that an IO::File handle can properly deal with such
 215         # exceptions thrown during its own destruction, but that's up to perls
 216         # guts now.
 217         $lockhash->{$filename} = \$check;
 218         weaken $lockhash->{$filename};
 219         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 220         if ($@) {
 221             $@ = "can't lock file '$filename' - $@";
 222             return undef;
 223         }
 224         $check = 1;
 225     }
 226     $res = eval { &$code(@param); };
 227     return undef if $@;
 228     return $res;
 229 }
 230
 231
 232 sub lock_file {
 233     my ($filename, $timeout, $code, @param) = @_;
 234
 235     return lock_file_full($filename, $timeout, 0, $code, @param);
 236 }
 237
 238 sub file_set_contents {
 239     my ($filename, $data, $perm)  = @_;
 240
 241     $perm = 0644 if !defined($perm);
 242
 243     my $tmpname = "$filename.tmp.$$";
 244
 245     eval {
 246         my ($fh, $tries) = (undef, 0);
 247         while (!$fh && $tries++ < 3) {
 248             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 249             if (!$fh && $! == EEXIST) {
 250                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 251             }
 252         }
 253         die "unable to open file '$tmpname' - $!\n" if !$fh;
 254         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 255         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 256     };
 257     my $err = $@;
 258
 259     if ($err) {
 260         unlink $tmpname;
 261         die $err;
 262     }
 263
 264     if (!rename($tmpname, $filename)) {
 265         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 266         unlink $tmpname;
 267         die $msg;
 268     }
 269 }
 270
 271 sub file_get_contents {
 272     my ($filename, $max) = @_;
 273
 274     my $fh = IO::File->new($filename, "r") ||
 275         die "can't open '$filename' - $!\n";
 276
 277     my $content = safe_read_from($fh, $max, 0, $filename);
 278
 279     close $fh;
 280
 281     return $content;
 282 }
 283
 284 sub file_copy {
 285     my ($filename, $dst, $max, $perm) = @_;
 286
 287     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 288 }
 289
 290 sub file_read_firstline {
 291     my ($filename) = @_;
 292
 293     my $fh = IO::File->new ($filename, "r");
 294     return undef if !$fh;
 295     my $res = <$fh>;
 296     chomp $res if $res;
 297     $fh->close;
 298     return $res;
 299 }
 300
 301 sub safe_read_from {
 302     my ($fh, $max, $oneline, $filename) = @_;
 303
 304     # pmxcfs file size limit
 305     $max = 1024 * 1024 if !$max;
 306
 307     my $subject = defined($filename) ? "file '$filename'" : 'input';
 308
 309     my $br = 0;
 310     my $input = '';
 311     my $count;
 312     while ($count = sysread($fh, $input, 8192, $br)) {
 313         $br += $count;
 314         die "$subject too long - aborting\n" if $br > $max;
 315         if ($oneline && $input =~ m/^(.*)\n/) {
 316             $input = $1;
 317             last;
 318         }
 319     }
 320     die "unable to read $subject - $!\n" if !defined($count);
 321
 322     return $input;
 323 }
 324
 325 # The $cmd parameter can be:
 326 #  -) a string
 327 #    This is generally executed by passing it to the shell with the -c option.
 328 #    However, it can be executed in one of two ways, depending on whether
 329 #    there's a pipe involved:
 330 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 331 #          set -o pipefail &&
 332 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 333 #      (Note that this may result in two different syntax requirements!)
 334 #      FIXME?
 335 #  -) an array of arguments (strings)
 336 #    Will be executed without interference from a shell. (Parameters are passed
 337 #    as is, no escape sequences of strings will be touched.)
 338 #  -) an array of arrays
 339 #    Each array represents a command, and each command's output is piped into
 340 #    the following command's standard input.
 341 #    For this a shell command string is created with pipe symbols between each
 342 #    command.
 343 #    Each command is a list of strings meant to end up in the final command
 344 #    unchanged. In order to achieve this, every argument is shell-quoted.
 345 #    Quoting can be disabled for a particular argument by turning it into a
 346 #    reference, this allows inserting arbitrary shell options.
 347 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 348 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 349 #    will literally print: hello >/dev/null
 350 sub run_command {
 351     my ($cmd, %param) = @_;
 352
 353     my $old_umask;
 354     my $cmdstr;
 355
 356     if (my $ref = ref($cmd)) {
 357         if (ref($cmd->[0])) {
 358             $cmdstr = 'set -o pipefail && ';
 359             my $pipe = '';
 360             foreach my $command (@$cmd) {
 361                 # concatenate quoted parameters
 362                 # strings which are passed by reference are NOT shell quoted
 363                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 364                 $pipe = ' | ';
 365             }
 366             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 367         } else {
 368             $cmdstr = cmd2string($cmd);
 369         }
 370     } else {
 371         $cmdstr = $cmd;
 372         if ($cmd =~ m/\|/) {
 373             # see 'man bash' for option pipefail
 374             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 375         } else {
 376             $cmd = [ $cmd ];
 377         }
 378     }
 379
 380     my $errmsg;
 381     my $laststderr;
 382     my $timeout;
 383     my $oldtimeout;
 384     my $pid;
 385     my $exitcode = -1;
 386
 387     my $outfunc;
 388     my $errfunc;
 389     my $logfunc;
 390     my $input;
 391     my $output;
 392     my $afterfork;
 393     my $noerr;
 394     my $keeplocale;
 395     my $quiet;
 396
 397     eval {
 398
 399         foreach my $p (keys %param) {
 400             if ($p eq 'timeout') {
 401                 $timeout = $param{$p};
 402             } elsif ($p eq 'umask') {
 403                 $old_umask = umask($param{$p});
 404             } elsif ($p eq 'errmsg') {
 405                 $errmsg = $param{$p};
 406             } elsif ($p eq 'input') {
 407                 $input = $param{$p};
 408             } elsif ($p eq 'output') {
 409                 $output = $param{$p};
 410             } elsif ($p eq 'outfunc') {
 411                 $outfunc = $param{$p};
 412             } elsif ($p eq 'errfunc') {
 413                 $errfunc = $param{$p};
 414             } elsif ($p eq 'logfunc') {
 415                 $logfunc = $param{$p};
 416             } elsif ($p eq 'afterfork') {
 417                 $afterfork = $param{$p};
 418             } elsif ($p eq 'noerr') {
 419                 $noerr = $param{$p};
 420             } elsif ($p eq 'keeplocale') {
 421                 $keeplocale = $param{$p};
 422             } elsif ($p eq 'quiet') {
 423                 $quiet = $param{$p};
 424             } else {
 425                 die "got unknown parameter '$p' for run_command\n";
 426             }
 427         }
 428
 429         if ($errmsg) {
 430             my $origerrfunc = $errfunc;
 431             $errfunc = sub {
 432                 if ($laststderr) {
 433                     if ($origerrfunc) {
 434                         &$origerrfunc("$laststderr\n");
 435                     } else {
 436                         print STDERR "$laststderr\n" if $laststderr;
 437                     }
 438                 }
 439                 $laststderr = shift;
 440             };
 441         }
 442
 443         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 444         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 445         my $error  = IO::File->new();
 446
 447         my $orig_pid = $$;
 448
 449         eval {
 450             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 451
 452             # suppress LVM warnings like: "File descriptor 3 left open";
 453             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 454
 455             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 456
 457             # if we pipe fron STDIN, open3 closes STDIN, so we get a perl warning like
 458             # "Filehandle STDIN reopened as GENXYZ .. " as soon as we open a new file.
 459             # to avoid that we open /dev/null
 460             if (!ref($writer) && !defined(fileno(STDIN))) {
 461                 POSIX::close(0);
 462                 open(STDIN, '<', '/dev/null');
 463             }
 464         };
 465
 466         my $err = $@;
 467
 468         # catch exec errors
 469         if ($orig_pid != $$) {
 470             warn "ERROR: $err";
 471             POSIX::_exit (1);
 472             kill ('KILL', $$);
 473         }
 474
 475         die $err if $err;
 476
 477         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 478         $oldtimeout = alarm($timeout) if $timeout;
 479
 480         &$afterfork() if $afterfork;
 481
 482         if (ref($writer)) {
 483             print $writer $input if defined $input;
 484             close $writer;
 485         }
 486
 487         my $select = IO::Select->new();
 488         $select->add($reader) if ref($reader);
 489         $select->add($error);
 490
 491         my $outlog = '';
 492         my $errlog = '';
 493
 494         my $starttime = time();
 495
 496         while ($select->count) {
 497             my @handles = $select->can_read(1);
 498
 499             foreach my $h (@handles) {
 500                 my $buf = '';
 501                 my $count = sysread ($h, $buf, 4096);
 502                 if (!defined ($count)) {
 503                     my $err = $!;
 504                     kill (9, $pid);
 505                     waitpid ($pid, 0);
 506                     die $err;
 507                 }
 508                 $select->remove ($h) if !$count;
 509                 if ($h eq $reader) {
 510                     if ($outfunc || $logfunc) {
 511                         eval {
 512                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 513                                 my $line = $outlog . $1;
 514                                 $outlog = '';
 515                                 &$outfunc($line) if $outfunc;
 516                                 &$logfunc($line) if $logfunc;
 517                             }
 518                             $outlog .= $buf;
 519                         };
 520                         my $err = $@;
 521                         if ($err) {
 522                             kill (9, $pid);
 523                             waitpid ($pid, 0);
 524                             die $err;
 525                         }
 526                     } elsif (!$quiet) {
 527                         print $buf;
 528                         *STDOUT->flush();
 529                     }
 530                 } elsif ($h eq $error) {
 531                     if ($errfunc || $logfunc) {
 532                         eval {
 533                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 534                                 my $line = $errlog . $1;
 535                                 $errlog = '';
 536                                 &$errfunc($line) if $errfunc;
 537                                 &$logfunc($line) if $logfunc;
 538                             }
 539                             $errlog .= $buf;
 540                         };
 541                         my $err = $@;
 542                         if ($err) {
 543                             kill (9, $pid);
 544                             waitpid ($pid, 0);
 545                             die $err;
 546                         }
 547                     } elsif (!$quiet) {
 548                         print STDERR $buf;
 549                         *STDERR->flush();
 550                     }
 551                 }
 552             }
 553         }
 554
 555         &$outfunc($outlog) if $outfunc && $outlog;
 556         &$logfunc($outlog) if $logfunc && $outlog;
 557
 558         &$errfunc($errlog) if $errfunc && $errlog;
 559         &$logfunc($errlog) if $logfunc && $errlog;
 560
 561         waitpid ($pid, 0);
 562
 563         if ($? == -1) {
 564             die "failed to execute\n";
 565         } elsif (my $sig = ($? & 127)) {
 566             die "got signal $sig\n";
 567         } elsif ($exitcode = ($? >> 8)) {
 568             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 569                 if ($errmsg && $laststderr) {
 570                     my $lerr = $laststderr;
 571                     $laststderr = undef;
 572                     die "$lerr\n";
 573                 }
 574                 die "exit code $exitcode\n";
 575             }
 576         }
 577
 578         alarm(0);
 579     };
 580
 581     my $err = $@;
 582
 583     alarm(0);
 584
 585     if ($errmsg && $laststderr) {
 586         &$errfunc(undef); # flush laststderr
 587     }
 588
 589     umask ($old_umask) if defined($old_umask);
 590
 591     alarm($oldtimeout) if $oldtimeout;
 592
 593     if ($err) {
 594         if ($pid && ($err eq "got timeout\n")) {
 595             kill (9, $pid);
 596             waitpid ($pid, 0);
 597             die "command '$cmdstr' failed: $err";
 598         }
 599
 600         if ($errmsg) {
 601             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 602             die "$errmsg: $err";
 603         } elsif(!$noerr) {
 604             die "command '$cmdstr' failed: $err";
 605         }
 606     }
 607
 608     return $exitcode;
 609 }
 610
 611 # Run a command with a tcp socket as standard input.
 612 sub pipe_socket_to_command  {
 613     my ($cmd, $ip, $port) = @_;
 614
 615     my $params = {
 616         Listen => 1,
 617         ReuseAddr => 1,
 618         Proto => &Socket::IPPROTO_TCP,
 619         GetAddrInfoFlags => 0,
 620         LocalAddr => $ip,
 621         LocalPort => $port,
 622     };
 623     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 624
 625     print "$ip\n$port\n"; # tell remote where to connect
 626     *STDOUT->flush();
 627
 628     alarm 0;
 629     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 630     alarm 30;
 631     my $client = $socket->accept; # Wait for a client
 632     alarm 0;
 633     close($socket);
 634
 635     # We want that the command talks over the TCP socket and takes
 636     # ownership of it, so that when it closes it the connection is
 637     # terminated, so we need to be able to close the socket. So we
 638     # can't really use PVE::Tools::run_command().
 639     my $pid = fork() // die "fork failed: $!\n";
 640     if (!$pid) {
 641         POSIX::dup2(fileno($client), 0);
 642         POSIX::dup2(fileno($client), 1);
 643         close($client);
 644         exec {$cmd->[0]} @$cmd or do {
 645             warn "exec failed: $!\n";
 646             POSIX::_exit(1);
 647         };
 648     }
 649
 650     close($client);
 651     if (waitpid($pid, 0) != $pid) {
 652         kill(15 => $pid); # if we got interrupted terminate the child
 653         my $count = 0;
 654         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 655             usleep(100000);
 656             $count++;
 657             kill(9 => $pid), last if $count > 300; # 30 second timeout
 658         }
 659     }
 660     if (my $sig = ($? & 127)) {
 661         die "got signal $sig\n";
 662     } elsif (my $exitcode = ($? >> 8)) {
 663         die "exit code $exitcode\n";
 664     }
 665
 666     return undef;
 667 }
 668
 669 sub split_list {
 670     my $listtxt = shift // '';
 671
 672     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 673
 674     $listtxt =~ s/[,;]/ /g;
 675     $listtxt =~ s/^\s+//;
 676
 677     my @data = split (/\s+/, $listtxt);
 678
 679     return @data;
 680 }
 681
 682 sub trim {
 683     my $txt = shift;
 684
 685     return $txt if !defined($txt);
 686
 687     $txt =~ s/^\s+//;
 688     $txt =~ s/\s+$//;
 689
 690     return $txt;
 691 }
 692
 693 # simple uri templates like "/vms/{vmid}"
 694 sub template_replace {
 695     my ($tmpl, $data) = @_;
 696
 697     return $tmpl if !$tmpl;
 698
 699     my $res = '';
 700     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 701         $res .= $1 if $1;
 702         $res .= ($data->{$3} || '-') if $2;
 703     }
 704     return $res;
 705 }
 706
 707 sub safe_print {
 708     my ($filename, $fh, $data) = @_;
 709
 710     return if !$data;
 711
 712     my $res = print $fh $data;
 713
 714     die "write to '$filename' failed\n" if !$res;
 715 }
 716
 717 sub debmirrors {
 718
 719     return {
 720         'at' => 'ftp.at.debian.org',
 721         'au' => 'ftp.au.debian.org',
 722         'be' => 'ftp.be.debian.org',
 723         'bg' => 'ftp.bg.debian.org',
 724         'br' => 'ftp.br.debian.org',
 725         'ca' => 'ftp.ca.debian.org',
 726         'ch' => 'ftp.ch.debian.org',
 727         'cl' => 'ftp.cl.debian.org',
 728         'cz' => 'ftp.cz.debian.org',
 729         'de' => 'ftp.de.debian.org',
 730         'dk' => 'ftp.dk.debian.org',
 731         'ee' => 'ftp.ee.debian.org',
 732         'es' => 'ftp.es.debian.org',
 733         'fi' => 'ftp.fi.debian.org',
 734         'fr' => 'ftp.fr.debian.org',
 735         'gr' => 'ftp.gr.debian.org',
 736         'hk' => 'ftp.hk.debian.org',
 737         'hr' => 'ftp.hr.debian.org',
 738         'hu' => 'ftp.hu.debian.org',
 739         'ie' => 'ftp.ie.debian.org',
 740         'is' => 'ftp.is.debian.org',
 741         'it' => 'ftp.it.debian.org',
 742         'jp' => 'ftp.jp.debian.org',
 743         'kr' => 'ftp.kr.debian.org',
 744         'mx' => 'ftp.mx.debian.org',
 745         'nl' => 'ftp.nl.debian.org',
 746         'no' => 'ftp.no.debian.org',
 747         'nz' => 'ftp.nz.debian.org',
 748         'pl' => 'ftp.pl.debian.org',
 749         'pt' => 'ftp.pt.debian.org',
 750         'ro' => 'ftp.ro.debian.org',
 751         'ru' => 'ftp.ru.debian.org',
 752         'se' => 'ftp.se.debian.org',
 753         'si' => 'ftp.si.debian.org',
 754         'sk' => 'ftp.sk.debian.org',
 755         'tr' => 'ftp.tr.debian.org',
 756         'tw' => 'ftp.tw.debian.org',
 757         'gb' => 'ftp.uk.debian.org',
 758         'us' => 'ftp.us.debian.org',
 759     };
 760 }
 761
 762 my $keymaphash =  {
 763     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 764     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 765     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 766     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 767     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 768     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 769     #'et'     => [], # Ethopia or Estonia ??
 770     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 771     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 772     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 773     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 774     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 775     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 776     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 777     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 778     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 779     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 780     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 781     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 782     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 783     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 784     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 785     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 786     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 787     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 788     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 789     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 790     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 791     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 792     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 793     #'th'     => [],
 794     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 795 };
 796
 797 my $kvmkeymaparray = [];
 798 foreach my $lc (sort keys %$keymaphash) {
 799     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 800 }
 801
 802 sub kvmkeymaps {
 803     return $keymaphash;
 804 }
 805
 806 sub kvmkeymaplist {
 807     return $kvmkeymaparray;
 808 }
 809
 810 sub extract_param {
 811     my ($param, $key) = @_;
 812
 813     my $res = $param->{$key};
 814     delete $param->{$key};
 815
 816     return $res;
 817 }
 818
 819 # For extracting sensitive keys (e.g. password), to avoid writing them to www-data owned configs
 820 sub extract_sensitive_params :prototype($$$) {
 821     my ($param, $sensitive_list, $delete_list) = @_;
 822
 823     my %delete = map { $_ => 1 } ($delete_list || [])->@*;
 824
 825     my $sensitive = {};
 826     for my $opt (@$sensitive_list) {
 827         # handle deletions as explicitly setting `undef`, so subs which only have $param but not
 828         # $delete_list available can recognize them. Afterwards new values  may override.
 829         if (exists($delete{$opt})) {
 830             $sensitive->{$opt} = undef;
 831         }
 832
 833         if (defined(my $value = extract_param($param, $opt))) {
 834             $sensitive->{$opt} = $value;
 835         }
 836     }
 837
 838     return $sensitive;
 839 }
 840
 841 # Note: we use this to wait until vncterm/spiceterm is ready
 842 sub wait_for_vnc_port {
 843     my ($port, $family, $timeout) = @_;
 844
 845     $timeout = 5 if !$timeout;
 846     my $sleeptime = 0;
 847     my $starttime = [gettimeofday];
 848     my $elapsed;
 849
 850     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 851     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 852
 853     my $found;
 854     while (($elapsed = tv_interval($starttime)) < $timeout) {
 855         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 856         run_command($cmd, outfunc => sub {
 857             my $line = shift;
 858             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 859                 $found = 1 if ($port == $1);
 860             }
 861         });
 862         return 1 if $found;
 863         $sleeptime += 100000 if  $sleeptime < 1000000;
 864         usleep($sleeptime);
 865     }
 866
 867     die "Timeout while waiting for port '$port' to get ready!\n";
 868 }
 869
 870 sub next_unused_port {
 871     my ($range_start, $range_end, $family, $address) = @_;
 872
 873     # We use a file to register allocated ports.
 874     # Those registrations expires after $expiretime.
 875     # We use this to avoid race conditions between
 876     # allocation and use of ports.
 877
 878     my $filename = "/var/tmp/pve-reserved-ports";
 879
 880     my $code = sub {
 881
 882         my $expiretime = 5;
 883         my $ctime = time();
 884
 885         my $ports = {};
 886
 887         if (my $fh = IO::File->new ($filename, "r")) {
 888             while (my $line = <$fh>) {
 889                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 890                     my ($port, $timestamp) = ($1, $2);
 891                     if (($timestamp + $expiretime) > $ctime) {
 892                         $ports->{$port} = $timestamp; # not expired
 893                     }
 894                 }
 895             }
 896         }
 897
 898         my $newport;
 899         my %sockargs = (Listen => 5,
 900                         ReuseAddr => 1,
 901                         Family    => $family,
 902                         Proto     => IPPROTO_TCP,
 903                         GetAddrInfoFlags => 0);
 904         $sockargs{LocalAddr} = $address if defined($address);
 905
 906         for (my $p = $range_start; $p < $range_end; $p++) {
 907             next if $ports->{$p}; # reserved
 908
 909             $sockargs{LocalPort} = $p;
 910             my $sock = IO::Socket::IP->new(%sockargs);
 911
 912             if ($sock) {
 913                 close($sock);
 914                 $newport = $p;
 915                 $ports->{$p} = $ctime;
 916                 last;
 917             }
 918         }
 919
 920         my $data = "";
 921         foreach my $p (keys %$ports) {
 922             $data .= "$p $ports->{$p}\n";
 923         }
 924
 925         file_set_contents($filename, $data);
 926
 927         return $newport;
 928     };
 929
 930     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 931     die $@ if $@;
 932
 933     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 934
 935     return $p;
 936 }
 937
 938 sub next_migrate_port {
 939     my ($family, $address) = @_;
 940     return next_unused_port(60000, 60050, $family, $address);
 941 }
 942
 943 sub next_vnc_port {
 944     my ($family, $address) = @_;
 945     return next_unused_port(5900, 6000, $family, $address);
 946 }
 947
 948 sub spice_port_range {
 949     return (61000, 61999);
 950 }
 951
 952 sub next_spice_port {
 953     my ($family, $address) = @_;
 954     return next_unused_port(spice_port_range(), $family, $address);
 955 }
 956
 957 sub must_stringify {
 958         my ($value) = @_;
 959         eval { $value = "$value" };
 960         return "error turning value into a string: $@" if $@;
 961         return $value;
 962 }
 963
 964 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 965 # the $sub has to return a single scalar
 966 sub run_fork_with_timeout {
 967     my ($timeout, $sub) = @_;
 968
 969     my $res;
 970     my $error;
 971     my $pipe_out = IO::Pipe->new();
 972
 973     # disable pending alarms, save their remaining time
 974     my $prev_alarm = alarm 0;
 975
 976     # avoid leaving a zombie if the parent gets interrupted
 977     my $sig_received;
 978
 979     my $child = fork();
 980     if (!defined($child)) {
 981         die "fork failed: $!\n";
 982         return $res;
 983     }
 984
 985     if (!$child) {
 986         $pipe_out->writer();
 987
 988         eval {
 989             $res = $sub->();
 990             print {$pipe_out} encode_json({ result => $res });
 991             $pipe_out->flush();
 992         };
 993         if (my $err = $@) {
 994             print {$pipe_out} encode_json({ error => must_stringify($err) });
 995             $pipe_out->flush();
 996             POSIX::_exit(1);
 997         }
 998         POSIX::_exit(0);
 999     }
1000
1001     local $SIG{INT} = sub { $sig_received++; };
1002     local $SIG{TERM} = sub {
1003         $error //= "interrupted by unexpected signal\n";
1004         kill('TERM', $child);
1005     };
1006
1007     $pipe_out->reader();
1008
1009     my $readvalues = sub {
1010         local $/ = undef;
1011         my $child_res = decode_json(readline_nointr($pipe_out));
1012         $res = $child_res->{result};
1013         $error = $child_res->{error};
1014     };
1015     eval {
1016         if (defined($timeout)) {
1017             run_with_timeout($timeout, $readvalues);
1018         } else {
1019             $readvalues->();
1020         }
1021     };
1022     warn $@ if $@;
1023     $pipe_out->close();
1024     kill('KILL', $child);
1025     waitpid($child, 0);
1026
1027     alarm $prev_alarm;
1028     die "interrupted by unexpected signal\n" if $sig_received;
1029
1030     die $error if $error;
1031     return $res;
1032 }
1033
1034 sub run_fork {
1035     my ($code) = @_;
1036     return run_fork_with_timeout(undef, $code);
1037 }
1038
1039 # NOTE: NFS syscall can't be interrupted, so alarm does
1040 # not work to provide timeouts.
1041 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1042 # So fork() before using Filesys::Df
1043 sub df {
1044     my ($path, $timeout) = @_;
1045
1046     my $df = sub { return Filesys::Df::df($path, 1) };
1047
1048     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1049     warn $@ if $@;
1050
1051     # untaint, but be flexible: PB usage can result in scientific notation
1052     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1053         $res->@{qw(blocks used bavail)};
1054
1055     return {
1056         total => $blocks,
1057         used => $used,
1058         avail => $bavail,
1059     };
1060 }
1061
1062 sub du {
1063     my ($path, $timeout) = @_;
1064
1065     my $size;
1066
1067     $timeout //= 10;
1068
1069     my $parser = sub {
1070         my $line = shift;
1071
1072         if ($line =~ m/^(\d+)\s+total$/) {
1073             $size = $1;
1074         }
1075     };
1076
1077     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1078
1079     return $size;
1080 }
1081
1082 # UPID helper
1083 # We use this to uniquely identify a process.
1084 # An 'Unique Process ID' has the following format:
1085 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1086
1087 sub upid_encode {
1088     my $d = shift;
1089
1090     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1091     # more that 8 characters for pstart
1092     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1093                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1094                    $d->{user});
1095 }
1096
1097 sub upid_decode {
1098     my ($upid, $noerr) = @_;
1099
1100     my $res;
1101     my $filename;
1102
1103     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1104     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1105     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1106         $res->{node} = $1;
1107         $res->{pid} = hex($3);
1108         $res->{pstart} = hex($4);
1109         $res->{starttime} = hex($5);
1110         $res->{type} = $6;
1111         $res->{id} = $7;
1112         $res->{user} = $8;
1113
1114         my $subdir = substr($5, 7, 8);
1115         $filename = "$pvetaskdir/$subdir/$upid";
1116
1117     } else {
1118         return undef if $noerr;
1119         die "unable to parse worker upid '$upid'\n";
1120     }
1121
1122     return wantarray ? ($res, $filename) : $res;
1123 }
1124
1125 sub upid_open {
1126     my ($upid) = @_;
1127
1128     my ($task, $filename) = upid_decode($upid);
1129
1130     my $dirname = dirname($filename);
1131     make_path($dirname);
1132
1133     my $wwwid = getpwnam('www-data') ||
1134         die "getpwnam failed";
1135
1136     my $perm = 0640;
1137
1138     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1139         die "unable to create output file '$filename' - $!\n";
1140     chown $wwwid, -1, $outfh;
1141
1142     return $outfh;
1143 };
1144
1145 sub upid_read_status {
1146     my ($upid) = @_;
1147
1148     my ($task, $filename) = upid_decode($upid);
1149     my $fh = IO::File->new($filename, "r");
1150     return "unable to open file - $!" if !$fh;
1151     my $maxlen = 4096;
1152     sysseek($fh, -$maxlen, 2);
1153     my $readbuf = '';
1154     my $br = sysread($fh, $readbuf, $maxlen);
1155     close($fh);
1156     if ($br) {
1157         return "unable to extract last line"
1158             if $readbuf !~ m/\n?(.+)$/;
1159         my $line = $1;
1160         if ($line =~ m/^TASK OK$/) {
1161             return 'OK';
1162         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1163             return $1;
1164         } elsif ($line =~ m/^TASK (WARNINGS: \d+)$/) {
1165             return $1;
1166         } else {
1167             return "unexpected status";
1168         }
1169     }
1170     return "unable to read tail (got $br bytes)";
1171 }
1172
1173 # Check if the status returned by upid_read_status is an error status.
1174 # If the status could not be parsed it's also treated as an error.
1175 sub upid_status_is_error {
1176     my ($status) = @_;
1177
1178     return !($status eq 'OK' || $status =~ m/^WARNINGS: \d+$/);
1179 }
1180
1181 # takes the parsed status and returns the type, either ok, warning, error or unknown
1182 sub upid_normalize_status_type {
1183     my ($status) = @_;
1184
1185     if (!$status) {
1186         return 'unknown';
1187     } elsif ($status eq 'OK') {
1188         return 'ok';
1189     } elsif ($status =~ m/^WARNINGS: \d+$/) {
1190         return 'warning';
1191     } elsif ($status eq 'unexpected status') {
1192         return 'unknown';
1193     } else {
1194         return 'error';
1195     }
1196 }
1197
1198 # useful functions to store comments in config files
1199 sub encode_text {
1200     my ($text) = @_;
1201
1202     # all control and hi-bit characters, and ':'
1203     my $unsafe = "^\x20-\x39\x3b-\x7e";
1204     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1205 }
1206
1207 sub decode_text {
1208     my ($data) = @_;
1209
1210     return Encode::decode("utf8", uri_unescape($data));
1211 }
1212
1213 # depreciated - do not use!
1214 # we now decode all parameters by default
1215 sub decode_utf8_parameters {
1216     my ($param) = @_;
1217
1218     foreach my $p (qw(comment description firstname lastname)) {
1219         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1220     }
1221
1222     return $param;
1223 }
1224
1225 sub random_ether_addr {
1226     my ($prefix) = @_;
1227
1228     my ($seconds, $microseconds) = gettimeofday;
1229
1230     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1231
1232     # clear multicast, set local id
1233     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1234
1235     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1236     if (defined($prefix)) {
1237         $addr = uc($prefix) . substr($addr, length($prefix));
1238     }
1239     return $addr;
1240 }
1241
1242 sub shellquote {
1243     my $str = shift;
1244
1245     return String::ShellQuote::shell_quote($str);
1246 }
1247
1248 sub cmd2string {
1249     my ($cmd) = @_;
1250
1251     die "no arguments" if !$cmd;
1252
1253     return $cmd if !ref($cmd);
1254
1255     my @qa = ();
1256     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1257
1258     return join (' ', @qa);
1259 }
1260
1261 # split an shell argument string into an array,
1262 sub split_args {
1263     my ($str) = @_;
1264
1265     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1266 }
1267
1268 sub dump_logfile {
1269     my ($filename, $start, $limit, $filter) = @_;
1270
1271     my $lines = [];
1272     my $count = 0;
1273
1274     my $fh = IO::File->new($filename, "r");
1275     if (!$fh) {
1276         $count++;
1277         push @$lines, { n => $count, t => "unable to open file - $!"};
1278         return ($count, $lines);
1279     }
1280
1281     $start = 0 if !$start;
1282     $limit = 50 if !$limit;
1283
1284     my $line;
1285
1286     if ($filter) {
1287         # duplicate code, so that we do not slow down normal path
1288         while (defined($line = <$fh>)) {
1289             next if $line !~ m/$filter/;
1290             next if $count++ < $start;
1291             next if $limit <= 0;
1292             chomp $line;
1293             push @$lines, { n => $count, t => $line};
1294             $limit--;
1295         }
1296     } else {
1297         while (defined($line = <$fh>)) {
1298             next if $count++ < $start;
1299             next if $limit <= 0;
1300             chomp $line;
1301             push @$lines, { n => $count, t => $line};
1302             $limit--;
1303         }
1304     }
1305
1306     close($fh);
1307
1308     # HACK: ExtJS store.guaranteeRange() does not like empty array
1309     # so we add a line
1310     if (!$count) {
1311         $count++;
1312         push @$lines, { n => $count, t => "no content"};
1313     }
1314
1315     return ($count, $lines);
1316 }
1317
1318 sub dump_journal {
1319     my ($start, $limit, $since, $until, $service) = @_;
1320
1321     my $lines = [];
1322     my $count = 0;
1323
1324     $start = 0 if !$start;
1325     $limit = 50 if !$limit;
1326
1327     my $parser = sub {
1328         my $line = shift;
1329
1330         return if $count++ < $start;
1331         return if $limit <= 0;
1332         push @$lines, { n => int($count), t => $line};
1333         $limit--;
1334     };
1335
1336     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1337
1338     push @$cmd, '--unit', $service if $service;
1339     push @$cmd, '--since', $since if $since;
1340     push @$cmd, '--until', $until if $until;
1341     run_command($cmd, outfunc => $parser);
1342
1343     # HACK: ExtJS store.guaranteeRange() does not like empty array
1344     # so we add a line
1345     if (!$count) {
1346         $count++;
1347         push @$lines, { n => $count, t => "no content"};
1348     }
1349
1350     return ($count, $lines);
1351 }
1352
1353 sub dir_glob_regex {
1354     my ($dir, $regex) = @_;
1355
1356     my $dh = IO::Dir->new ($dir);
1357     return wantarray ? () : undef if !$dh;
1358
1359     while (defined(my $tmp = $dh->read)) {
1360         if (my @res = $tmp =~ m/^($regex)$/) {
1361             $dh->close;
1362             return wantarray ? @res : $tmp;
1363         }
1364     }
1365     $dh->close;
1366
1367     return wantarray ? () : undef;
1368 }
1369
1370 sub dir_glob_foreach {
1371     my ($dir, $regex, $func) = @_;
1372
1373     my $dh = IO::Dir->new ($dir);
1374     if (defined $dh) {
1375         while (defined(my $tmp = $dh->read)) {
1376             if (my @res = $tmp =~ m/^($regex)$/) {
1377                 &$func (@res);
1378             }
1379         }
1380     }
1381 }
1382
1383 sub assert_if_modified {
1384     my ($digest1, $digest2) = @_;
1385
1386     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1387         die "detected modified configuration - file changed by other user? Try again.\n";
1388     }
1389 }
1390
1391 # Digest for short strings
1392 # like FNV32a, but we only return 31 bits (positive numbers)
1393 sub fnv31a {
1394     my ($string) = @_;
1395
1396     my $hval = 0x811c9dc5;
1397
1398     foreach my $c (unpack('C*', $string)) {
1399         $hval ^= $c;
1400         $hval += (
1401             (($hval << 1) ) +
1402             (($hval << 4) ) +
1403             (($hval << 7) ) +
1404             (($hval << 8) ) +
1405             (($hval << 24) ) );
1406         $hval = $hval & 0xffffffff;
1407     }
1408     return $hval & 0x7fffffff;
1409 }
1410
1411 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1412
1413 sub unpack_sockaddr_in46 {
1414     my ($sin) = @_;
1415     my $family = Socket::sockaddr_family($sin);
1416     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1417                                              : Socket::unpack_sockaddr_in($sin));
1418     return ($family, $port, $host);
1419 }
1420
1421 sub getaddrinfo_all {
1422     my ($hostname, @opts) = @_;
1423     my %hints = (
1424         flags => AI_V4MAPPED | AI_ALL,
1425         @opts,
1426     );
1427     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1428     die "failed to get address info for: $hostname: $err\n" if $err;
1429     return @res;
1430 }
1431
1432 sub get_host_address_family {
1433     my ($hostname, $socktype) = @_;
1434     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1435     return $res[0]->{family};
1436 }
1437
1438 # get the fully qualified domain name of a host
1439 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1440 # given a nodename as a parameter
1441 sub get_fqdn {
1442     my ($nodename) = @_;
1443
1444     my $hints = {
1445         flags => AI_CANONNAME,
1446         socktype => SOCK_DGRAM
1447     };
1448
1449     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1450
1451     die "getaddrinfo: $err" if $err;
1452
1453     return $addrs[0]->{canonname};
1454 }
1455
1456 # Parses any sane kind of host, or host+port pair:
1457 # The port is always optional and thus may be undef.
1458 sub parse_host_and_port {
1459     my ($address) = @_;
1460     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1461         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1462         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1463     {
1464         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1465     }
1466     return; # nothing
1467 }
1468
1469 sub setresuid($$$) {
1470     my ($ruid, $euid, $suid) = @_;
1471     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1472 }
1473
1474 sub unshare($) {
1475     my ($flags) = @_;
1476     return 0 == syscall(PVE::Syscall::unshare, $flags);
1477 }
1478
1479 sub setns($$) {
1480     my ($fileno, $nstype) = @_;
1481     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1482 }
1483
1484 sub syncfs($) {
1485     my ($fileno) = @_;
1486     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1487 }
1488
1489 sub fsync($) {
1490     my ($fileno) = @_;
1491     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1492 }
1493
1494 sub renameat2($$$$$) {
1495     my ($olddirfd, $oldpath, $newdirfd, $newpath, $flags) = @_;
1496     return 0 == syscall(PVE::Syscall::renameat2, $olddirfd, $oldpath, $newdirfd, $newpath, $flags);
1497 }
1498
1499 sub sync_mountpoint {
1500     my ($path) = @_;
1501     sysopen my $fd, $path, O_RDONLY|O_CLOEXEC or die "failed to open $path: $!\n";
1502     my $syncfs_err;
1503     if (!syncfs(fileno($fd))) {
1504         $syncfs_err = "$!";
1505     }
1506     close($fd);
1507     die "syncfs '$path' failed - $syncfs_err\n" if defined $syncfs_err;
1508 }
1509
1510 my sub check_mail_addr {
1511     my ($addr) = @_;
1512     die "'$addr' does not look like a valid email address or username\n"
1513         if $addr !~ /^$EMAIL_RE$/ && $addr !~ /^$EMAIL_USER_RE$/;
1514 }
1515
1516 # support sending multi-part mail messages with a text and or a HTML part
1517 # mailto may be a single email string or an array of receivers
1518 sub sendmail {
1519     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1520
1521     $mailto = [ $mailto ] if !ref($mailto);
1522
1523     check_mail_addr($_) for $mailto->@*;
1524     my $to_quoted = [ map { shellquote($_) } $mailto->@* ];
1525
1526     $mailfrom = $mailfrom || "root";
1527     check_mail_addr($mailfrom);
1528     my $from_quoted = shellquote($mailfrom);
1529
1530     $author = $author // 'Proxmox VE';
1531
1532     open (my $mail, "|-", "sendmail", "-B", "8BITMIME", "-f", $from_quoted, "--", $to_quoted->@*)
1533         or die "unable to open 'sendmail' - $!";
1534
1535     my $is_multipart = $text && $html;
1536     my $boundary = "----_=_NextPart_001_" . int(time()) . $$; # multipart spec, see rfc 1521
1537
1538     $subject = Encode::encode('MIME-Header', $subject) if $subject =~ /[^[:ascii:]]/;
1539
1540     print $mail "MIME-Version: 1.0\n" if $subject =~ /[^[:ascii:]]/ || $is_multipart;
1541
1542     print $mail "From: $author <$mailfrom>\n";
1543     print $mail "To: " . join(', ', @$mailto) ."\n";
1544     print $mail "Date: " . time2str('%a, %d %b %Y %H:%M:%S %z', time()) . "\n";
1545     print $mail "Subject: $subject\n";
1546
1547     if ($is_multipart) {
1548         print $mail "Content-Type: multipart/alternative;\n";
1549         print $mail "\tboundary=\"$boundary\"\n";
1550         print $mail "\n";
1551         print $mail "This is a multi-part message in MIME format.\n\n";
1552         print $mail "--$boundary\n";
1553     }
1554
1555     if (defined($text)) {
1556         print $mail "Content-Type: text/plain;\n";
1557         print $mail "\tcharset=\"UTF-8\"\n";
1558         print $mail "Content-Transfer-Encoding: 8bit\n";
1559         print $mail "\n";
1560
1561         # avoid 'remove extra line breaks' issue (MS Outlook)
1562         my $fill = '  ';
1563         $text =~ s/^/$fill/gm;
1564
1565         print $mail $text;
1566
1567         print $mail "\n--$boundary\n" if $is_multipart;
1568     }
1569
1570     if (defined($html)) {
1571         print $mail "Content-Type: text/html;\n";
1572         print $mail "\tcharset=\"UTF-8\"\n";
1573         print $mail "Content-Transfer-Encoding: 8bit\n";
1574         print $mail "\n";
1575
1576         print $mail $html;
1577
1578         print $mail "\n--$boundary--\n" if $is_multipart;
1579     }
1580
1581     close($mail);
1582 }
1583
1584 # creates a temporary file that does not shows up on the file system hierarchy.
1585 #
1586 # Uses O_TMPFILE if available, which makes it just an anon inode that never shows up in the FS.
1587 # If O_TMPFILE is not available, which unlikely nowadays (added in 3.11 kernel and all FS relevant
1588 # for us support it) back to open-create + immediate unlink while still holding the file  handle.
1589 #
1590 # TODO: to avoid FS dependent features we could (transparently) switch to memfd_create as backend
1591 sub tempfile {
1592     my ($perm, %opts) = @_;
1593
1594     # default permissions are stricter than with file_set_contents
1595     $perm = 0600 if !defined($perm);
1596
1597     my $dir = $opts{dir};
1598     if (!$dir) {
1599         if (-d "/run/user/$<") {
1600             $dir = "/run/user/$<";
1601         } elsif ($< == 0) {
1602             $dir = "/run";
1603         } else {
1604             $dir = "/tmp";
1605         }
1606     }
1607     my $mode = $opts{mode} // O_RDWR;
1608     $mode |= O_EXCL if !$opts{allow_links};
1609
1610     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1611     if (!$fh && $! == EOPNOTSUPP) {
1612         $dir = '/tmp' if !defined($opts{dir});
1613         $dir .= "/.tmpfile.$$";
1614         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1615         unlink($dir) if $fh;
1616     }
1617     die "failed to create tempfile: $!\n" if !$fh;
1618     return $fh;
1619 }
1620
1621 # create an (ideally) anon file with the $data as content and return its FD-path and FH
1622 sub tempfile_contents {
1623     my ($data, $perm, %opts) = @_;
1624
1625     my $fh = tempfile($perm, %opts);
1626     eval {
1627         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1628         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1629     };
1630     if (my $err = $@) {
1631         close $fh;
1632         die $err;
1633     }
1634
1635     return ("/proc/$$/fd/".$fh->fileno, $fh);
1636 }
1637
1638 sub validate_ssh_public_keys {
1639     my ($raw) = @_;
1640     my @lines = split(/\n/, $raw);
1641
1642     foreach my $line (@lines) {
1643         next if $line =~ m/^\s*$/;
1644         eval {
1645             my ($filename, $handle) = tempfile_contents($line);
1646             run_command(["ssh-keygen", "-l", "-f", $filename],
1647                         outfunc => sub {}, errfunc => sub {});
1648         };
1649         die "SSH public key validation error\n" if $@;
1650     }
1651 }
1652
1653 sub openat($$$;$) {
1654     my ($dirfd, $pathname, $flags, $mode) = @_;
1655     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1656     return undef if $fd < 0;
1657     # sysopen() doesn't deal with numeric file descriptors apparently
1658     # so we need to convert to a mode string for IO::Handle->new_from_fd
1659     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1660     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1661     return $handle if $handle;
1662     my $err = $!; # save error before closing the raw fd
1663     syscall(PVE::Syscall::close, $fd); # close
1664     $! = $err;
1665     return undef;
1666 }
1667
1668 sub mkdirat($$$) {
1669     my ($dirfd, $name, $mode) = @_;
1670     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1671 }
1672
1673 sub fchownat($$$$$) {
1674     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1675     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1676 }
1677
1678 my $salt_starter = time();
1679
1680 sub encrypt_pw {
1681     my ($pw) = @_;
1682
1683     $salt_starter++;
1684     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1685
1686     # crypt does not want '+' in salt (see 'man crypt')
1687     $salt =~ s/\+/X/g;
1688
1689     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1690 }
1691
1692 # intended usage: convert_size($val, "kb" => "gb")
1693 # we round up to the next integer by default
1694 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1695 # use $no_round_up to switch this off, above example would then return 0
1696 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1697 # (0 if $no_round_up is true)
1698 # allowed formats for value:
1699 # 1234
1700 # 1234.
1701 # 1234.1234
1702 # .1234
1703 sub convert_size {
1704     my ($value, $from, $to, $no_round_up) = @_;
1705
1706     my $units = {
1707         b  => 0,
1708         kb => 1,
1709         mb => 2,
1710         gb => 3,
1711         tb => 4,
1712         pb => 5,
1713     };
1714
1715     die "no value given"
1716         if !defined($value) || $value eq "";
1717
1718     $from = lc($from // ''); $to = lc($to // '');
1719     die "unknown 'from' and/or 'to' units ($from => $to)"
1720         if !defined($units->{$from}) || !defined($units->{$to});
1721
1722     die "value '$value' is not a valid, positive number"
1723         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1724
1725     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1726
1727     $value *= 2**$shift_amount;
1728     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1729
1730     return int($value);
1731 }
1732
1733 # uninterruptible readline
1734 # retries on EINTR
1735 sub readline_nointr {
1736     my ($fh) = @_;
1737     my $line;
1738     while (1) {
1739         $line = <$fh>;
1740         last if defined($line) || ($! != EINTR);
1741     }
1742     return $line;
1743 }
1744
1745 my $host_arch;
1746 sub get_host_arch {
1747     $host_arch = (POSIX::uname())[4] if !$host_arch;
1748     return $host_arch;
1749 }
1750
1751 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1752 sub dev_t_major($) {
1753     my ($dev_t) = @_;
1754     return (int($dev_t) & 0xfff00) >> 8;
1755 }
1756
1757 sub dev_t_minor($) {
1758     my ($dev_t) = @_;
1759     $dev_t = int($dev_t);
1760     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1761 }
1762
1763 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1764 # Returns the intersection of elements as a single array [a b]
1765 sub array_intersect {
1766     my ($arrays) = @_;
1767
1768     if (!ref($arrays->[0])) {
1769         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1770     }
1771
1772     return [] if scalar(@$arrays) == 0;
1773     return $arrays->[0] if scalar(@$arrays) == 1;
1774
1775     my $array_unique = sub {
1776         my %seen = ();
1777         return grep { ! $seen{ $_ }++ } @_;
1778     };
1779
1780     # base idea is to get all unique members from the first array, then
1781     # check the common elements with the next (uniquely made) one, only keep
1782     # those. Repeat for every array and at the end we only have those left
1783     # which exist in all arrays
1784     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1785     for my $i (1 .. $#$arrays) {
1786         my %count = ();
1787         # $return_arr is already unique, explicit at before the loop, implicit below.
1788         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1789             $count{$element}++;
1790         }
1791         $return_arr = [];
1792         foreach my $element (keys %count) {
1793             push @$return_arr, $element if $count{$element} > 1;
1794         }
1795         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1796     }
1797
1798     return $return_arr;
1799 }
1800
1801 sub open_tree($$$) {
1802     my ($dfd, $pathname, $flags) = @_;
1803     return PVE::Syscall::file_handle_result(syscall(
1804         &PVE::Syscall::open_tree,
1805         $dfd,
1806         $pathname,
1807         $flags,
1808     ));
1809 }
1810
1811 sub move_mount($$$$$) {
1812     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1813     return 0 == syscall(
1814         &PVE::Syscall::move_mount,
1815         $from_dirfd,
1816         $from_pathname,
1817         $to_dirfd,
1818         $to_pathname,
1819         $flags,
1820     );
1821 }
1822
1823 sub fsopen($$) {
1824     my ($fsname, $flags) = @_;
1825     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
1826 }
1827
1828 sub fsmount($$$) {
1829     my ($fd, $flags, $mount_attrs) = @_;
1830     return PVE::Syscall::file_handle_result(syscall(
1831         &PVE::Syscall::fsmount,
1832         $fd,
1833         $flags,
1834         $mount_attrs,
1835     ));
1836 }
1837
1838 sub fspick($$$) {
1839     my ($dirfd, $pathname, $flags) = @_;
1840     return PVE::Syscall::file_handle_result(syscall(
1841         &PVE::Syscall::fspick,
1842         $dirfd,
1843         $pathname,
1844         $flags,
1845     ));
1846 }
1847
1848 sub fsconfig($$$$$) {
1849     my ($fd, $command, $key, $value, $aux) = @_;
1850     return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
1851 }
1852
1853 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1854 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1855 sub mount($$$$$) {
1856     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1857     return 0 == syscall(
1858         &PVE::Syscall::mount,
1859         $source,
1860         $target,
1861         $filesystemtype,
1862         $mountflags,
1863         $data,
1864     );
1865 }
1866
1867 # size is optional and defaults to 256, note that xattr limits are FS specific and that xattrs can
1868 # get arbitrary long. pass `0` for $size in array context to get the actual size of a value
1869 sub getxattr($$;$) {
1870     my ($path_or_handle, $name, $size) = @_;
1871     $size //= 256;
1872     my $buf = pack("x${size}");
1873
1874     my $xattr_size = -1; # the actual size of the xattr, can be zero
1875     if (defined(my $fd = fileno($path_or_handle))) {
1876         $xattr_size = syscall(&PVE::Syscall::fgetxattr, $fd, $name, $buf, $size);
1877     } else {
1878         $xattr_size = syscall(&PVE::Syscall::getxattr, $path_or_handle, $name, $buf, $size);
1879     }
1880     if ($xattr_size < 0) {
1881         return undef;
1882     }
1883     return wantarray ? ($buf, $xattr_size) : $buf;
1884 }
1885
1886 # NOTE: can take either a path or an open file handle, i.e., its multiplexing setxattr and fsetxattr
1887 sub setxattr($$$;$) {
1888     my ($path_or_handle, $name, $value, $flags) = @_;
1889     my $size = length($value); # NOTE: seems to get correct length also for wide-characters in text..
1890
1891     if (defined(my $fd = fileno($path_or_handle))) {
1892         return 0 == syscall(&PVE::Syscall::fsetxattr, $fd, $name, $value, $size, $flags // 0);
1893     } else {
1894         return 0 == syscall(&PVE::Syscall::setxattr, $path_or_handle, $name, $value, $size, $flags // 0);
1895     }
1896 }
1897
1898 sub safe_compare {
1899     my ($left, $right, $cmp) = @_;
1900
1901     return 0 if !defined($left) && !defined($right);
1902     return -1 if !defined($left);
1903     return 1 if !defined($right);
1904     return $cmp->($left, $right);
1905 }
1906
1907
1908 # opts is a hash ref with the following known properties
1909 #  allow_overwrite - if 1, overwriting existing files is allowed, use with care. Default to false
1910 #  hash_required - if 1, at least one checksum has to be specified otherwise an error will be thrown
1911 #  http_proxy
1912 #  https_proxy
1913 #  verify_certificates - if 0 (false) we tell wget to ignore untrusted TLS certs. Default to true
1914 #  md5sum|sha(1|224|256|384|512)sum - the respective expected checksum string
1915 sub download_file_from_url {
1916     my ($dest, $url, $opts) = @_;
1917
1918     my ($checksum_algorithm, $checksum_expected);
1919     for ('sha512', 'sha384', 'sha256', 'sha224', 'sha1', 'md5') {
1920         if (defined($opts->{"${_}sum"})) {
1921             $checksum_algorithm = $_;
1922             $checksum_expected = $opts->{"${_}sum"};
1923             last;
1924         }
1925     }
1926     die "checksum required but not specified\n" if ($opts->{hash_required} && !$checksum_algorithm);
1927
1928     print "downloading $url to $dest\n";
1929
1930     if (-f $dest) {
1931         if ($checksum_algorithm) {
1932             print "calculating checksum of existing file...";
1933             my $checksum_got = get_file_hash($checksum_algorithm, $dest);
1934
1935             if (lc($checksum_got) eq lc($checksum_expected)) {
1936                 print "OK, got correct file already, no need to download\n";
1937                 return;
1938             } elsif ($opts->{allow_overwrite}) {
1939                 print "checksum mismatch: got '$checksum_got' != expect '$checksum_expected', re-download\n";
1940             } else {
1941                 print "\n";  # the front end expects the error to reside at the last line without any noise
1942                 die "checksum mismatch: got '$checksum_got' != expect '$checksum_expected', aborting\n";
1943             }
1944         } elsif (!$opts->{allow_overwrite}) {
1945             die "refusing to override existing file '$dest'\n";
1946         }
1947     }
1948
1949     my $tmpdest = "$dest.tmp.$$";
1950     eval {
1951         local $SIG{INT} = sub {
1952             unlink $tmpdest or warn "could not cleanup temporary file: $!";
1953             die "got interrupted by signal\n";
1954         };
1955
1956         { # limit the scope of the ENV change
1957             local %ENV;
1958             if ($opts->{http_proxy}) {
1959                 $ENV{http_proxy} = $opts->{http_proxy};
1960             }
1961             if ($opts->{https_proxy}) {
1962                 $ENV{https_proxy} = $opts->{https_proxy};
1963             }
1964
1965             my $cmd = ['wget', '--progress=dot:giga', '-O', $tmpdest, $url];
1966
1967             if (!($opts->{verify_certificates} // 1)) { # default to true
1968                 push @$cmd, '--no-check-certificate';
1969             }
1970
1971             run_command($cmd, errmsg => "download failed");
1972         }
1973
1974         if ($checksum_algorithm) {
1975             print "calculating checksum...";
1976
1977             my $checksum_got = get_file_hash($checksum_algorithm, $tmpdest);
1978
1979             if (lc($checksum_got) eq lc($checksum_expected)) {
1980                 print "OK, checksum verified\n";
1981             } else {
1982                 print "\n";  # the front end expects the error to reside at the last line without any noise
1983                 die "checksum mismatch: got '$checksum_got' != expect '$checksum_expected'\n";
1984             }
1985         }
1986
1987         rename($tmpdest, $dest) or die "unable to rename temporary file: $!\n";
1988     };
1989     if (my $err = $@) {
1990         unlink $tmpdest or warn "could not cleanup temporary file: $!";
1991         die $err;
1992     }
1993
1994     print "download of '$url' to '$dest' finished\n";
1995 }
1996
1997 sub get_file_hash {
1998     my ($algorithm, $filename) = @_;
1999
2000     my $algorithm_map = {
2001         'md5' => sub { Digest::MD5->new },
2002         'sha1' => sub { Digest::SHA->new(1) },
2003         'sha224' => sub { Digest::SHA->new(224) },
2004         'sha256' => sub { Digest::SHA->new(256) },
2005         'sha384' => sub { Digest::SHA->new(384) },
2006         'sha512' => sub { Digest::SHA->new(512) },
2007     };
2008
2009     my $digester = $algorithm_map->{$algorithm}->() or die "unknown algorithm '$algorithm'\n";
2010
2011     open(my $fh, '<', $filename) or die "unable to open '$filename': $!\n";
2012     binmode($fh);
2013
2014     my $digest = $digester->addfile($fh)->hexdigest;
2015
2016     return lc($digest);
2017 }
2018
2019 1;