src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Net::DBus qw(dbus_uint32 dbus_uint64);
  28 use Net::DBus::Callback;
  29 use Net::DBus::Reactor;
  30 use Scalar::Util 'weaken';
  31 use PVE::Syscall;
  32
  33 # avoid warning when parsing long hex values with hex()
  34 no warnings 'portable'; # Support for 64-bit ints required
  35
  36 our @EXPORT_OK = qw(
  37 $IPV6RE
  38 $IPV4RE
  39 lock_file
  40 lock_file_full
  41 run_command
  42 file_set_contents
  43 file_get_contents
  44 file_read_firstline
  45 dir_glob_regex
  46 dir_glob_foreach
  47 split_list
  48 template_replace
  49 safe_print
  50 trim
  51 extract_param
  52 file_copy
  53 O_PATH
  54 O_TMPFILE
  55 );
  56
  57 my $pvelogdir = "/var/log/pve";
  58 my $pvetaskdir = "$pvelogdir/tasks";
  59
  60 mkdir $pvelogdir;
  61 mkdir $pvetaskdir;
  62
  63 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  64 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  65 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  66 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  67
  68 our $IPV6RE = "(?:" .
  69     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  70     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  71     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  72     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  73     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  74     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  75     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  76     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  77     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  78
  79 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  80
  81 use constant {CLONE_NEWNS   => 0x00020000,
  82               CLONE_NEWUTS  => 0x04000000,
  83               CLONE_NEWIPC  => 0x08000000,
  84               CLONE_NEWUSER => 0x10000000,
  85               CLONE_NEWPID  => 0x20000000,
  86               CLONE_NEWNET  => 0x40000000};
  87
  88 use constant {O_PATH    => 0x00200000,
  89               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  90
  91 sub run_with_timeout {
  92     my ($timeout, $code, @param) = @_;
  93
  94     die "got timeout\n" if $timeout <= 0;
  95
  96     my $prev_alarm = alarm 0; # suspend outer alarm early
  97
  98     my $sigcount = 0;
  99
 100     my $res;
 101
 102     eval {
 103         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 104         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 105         local $SIG{__DIE__};   # see SA bug 4631
 106
 107         alarm($timeout);
 108
 109         eval { $res = &$code(@param); };
 110
 111         alarm(0); # avoid race conditions
 112
 113         die $@ if $@;
 114     };
 115
 116     my $err = $@;
 117
 118     alarm $prev_alarm;
 119
 120     # this shouldn't happen anymore?
 121     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 122
 123     die $err if $err;
 124
 125     return $res;
 126 }
 127
 128 # flock: we use one file handle per process, so lock file
 129 # can be nested multiple times and succeeds for the same process.
 130 #
 131 # Since this is the only way we lock now and we don't have the old
 132 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 133 # count how deep we're nesting. Therefore this hash now stores a weak reference
 134 # to a boolean telling us whether we already have a lock.
 135
 136 my $lock_handles =  {};
 137
 138 sub lock_file_full {
 139     my ($filename, $timeout, $shared, $code, @param) = @_;
 140
 141     $timeout = 10 if !$timeout;
 142
 143     my $mode = $shared ? LOCK_SH : LOCK_EX;
 144
 145     my $lockhash = ($lock_handles->{$$} //= {});
 146
 147     # Returns a locked file handle.
 148     my $get_locked_file = sub {
 149         my $fh = IO::File->new(">>$filename")
 150             or die "can't open file - $!\n";
 151
 152         if (!flock($fh, $mode|LOCK_NB)) {
 153             print STDERR "trying to acquire lock...";
 154             my $success;
 155             while(1) {
 156                 $success = flock($fh, $mode);
 157                 # try again on EINTR (see bug #273)
 158                 if ($success || ($! != EINTR)) {
 159                     last;
 160                 }
 161             }
 162             if (!$success) {
 163                 print STDERR " failed\n";
 164                 die "can't acquire lock '$filename' - $!\n";
 165             }
 166             print STDERR " OK\n";
 167         }
 168
 169         return $fh;
 170     };
 171
 172     my $res;
 173     my $checkptr = $lockhash->{$filename};
 174     my $check = 0; # This must not go out of scope before running the code.
 175     my $local_fh; # This must stay local
 176     if (!$checkptr || !$$checkptr) {
 177         # We cannot create a weak reference in a single atomic step, so we first
 178         # create a false-value, then create a reference to it, then weaken it,
 179         # and after successfully locking the file we change the boolean value.
 180         #
 181         # The reason for this is that if an outer SIGALRM throws an exception
 182         # between creating the reference and weakening it, a subsequent call to
 183         # lock_file_full() will see a leftover full reference to a valid
 184         # variable. This variable must be 0 in order for said call to attempt to
 185         # lock the file anew.
 186         #
 187         # An externally triggered exception elsewhere in the code will cause the
 188         # weak reference to become 'undef', and since the file handle is only
 189         # stored in the local scope in $local_fh, the file will be closed by
 190         # perl's cleanup routines as well.
 191         #
 192         # This still assumes that an IO::File handle can properly deal with such
 193         # exceptions thrown during its own destruction, but that's up to perls
 194         # guts now.
 195         $lockhash->{$filename} = \$check;
 196         weaken $lockhash->{$filename};
 197         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 198         if ($@) {
 199             $@ = "can't lock file '$filename' - $@";
 200             return undef;
 201         }
 202         $check = 1;
 203     }
 204     $res = eval { &$code(@param); };
 205     return undef if $@;
 206     return $res;
 207 }
 208
 209
 210 sub lock_file {
 211     my ($filename, $timeout, $code, @param) = @_;
 212
 213     return lock_file_full($filename, $timeout, 0, $code, @param);
 214 }
 215
 216 sub file_set_contents {
 217     my ($filename, $data, $perm)  = @_;
 218
 219     $perm = 0644 if !defined($perm);
 220
 221     my $tmpname = "$filename.tmp.$$";
 222
 223     eval {
 224         my ($fh, $tries) = (undef, 0);
 225         while (!$fh && $tries++ < 3) {
 226             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 227             if (!$fh && $! == EEXIST) {
 228                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 229             }
 230         }
 231         die "unable to open file '$tmpname' - $!\n" if !$fh;
 232         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 233         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 234     };
 235     my $err = $@;
 236
 237     if ($err) {
 238         unlink $tmpname;
 239         die $err;
 240     }
 241
 242     if (!rename($tmpname, $filename)) {
 243         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 244         unlink $tmpname;
 245         die $msg;
 246     }
 247 }
 248
 249 sub file_get_contents {
 250     my ($filename, $max) = @_;
 251
 252     my $fh = IO::File->new($filename, "r") ||
 253         die "can't open '$filename' - $!\n";
 254
 255     my $content = safe_read_from($fh, $max, 0, $filename);
 256
 257     close $fh;
 258
 259     return $content;
 260 }
 261
 262 sub file_copy {
 263     my ($filename, $dst, $max, $perm) = @_;
 264
 265     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 266 }
 267
 268 sub file_read_firstline {
 269     my ($filename) = @_;
 270
 271     my $fh = IO::File->new ($filename, "r");
 272     return undef if !$fh;
 273     my $res = <$fh>;
 274     chomp $res if $res;
 275     $fh->close;
 276     return $res;
 277 }
 278
 279 sub safe_read_from {
 280     my ($fh, $max, $oneline, $filename) = @_;
 281
 282     $max = 32768 if !$max;
 283
 284     my $subject = defined($filename) ? "file '$filename'" : 'input';
 285
 286     my $br = 0;
 287     my $input = '';
 288     my $count;
 289     while ($count = sysread($fh, $input, 8192, $br)) {
 290         $br += $count;
 291         die "$subject too long - aborting\n" if $br > $max;
 292         if ($oneline && $input =~ m/^(.*)\n/) {
 293             $input = $1;
 294             last;
 295         }
 296     }
 297     die "unable to read $subject - $!\n" if !defined($count);
 298
 299     return $input;
 300 }
 301
 302 # The $cmd parameter can be:
 303 #  -) a string
 304 #    This is generally executed by passing it to the shell with the -c option.
 305 #    However, it can be executed in one of two ways, depending on whether
 306 #    there's a pipe involved:
 307 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 308 #          set -o pipefail &&
 309 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 310 #      (Note that this may result in two different syntax requirements!)
 311 #      FIXME?
 312 #  -) an array of arguments (strings)
 313 #    Will be executed without interference from a shell. (Parameters are passed
 314 #    as is, no escape sequences of strings will be touched.)
 315 #  -) an array of arrays
 316 #    Each array represents a command, and each command's output is piped into
 317 #    the following command's standard input.
 318 #    For this a shell command string is created with pipe symbols between each
 319 #    command.
 320 #    Each command is a list of strings meant to end up in the final command
 321 #    unchanged. In order to achieve this, every argument is shell-quoted.
 322 #    Quoting can be disabled for a particular argument by turning it into a
 323 #    reference, this allows inserting arbitrary shell options.
 324 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 325 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 326 #    will literally print: hello >/dev/null
 327 sub run_command {
 328     my ($cmd, %param) = @_;
 329
 330     my $old_umask;
 331     my $cmdstr;
 332
 333     if (my $ref = ref($cmd)) {
 334         if (ref($cmd->[0])) {
 335             $cmdstr = 'set -o pipefail && ';
 336             my $pipe = '';
 337             foreach my $command (@$cmd) {
 338                 # concatenate quoted parameters
 339                 # strings which are passed by reference are NOT shell quoted
 340                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 341                 $pipe = ' | ';
 342             }
 343             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 344         } else {
 345             $cmdstr = cmd2string($cmd);
 346         }
 347     } else {
 348         $cmdstr = $cmd;
 349         if ($cmd =~ m/\|/) {
 350             # see 'man bash' for option pipefail
 351             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 352         } else {
 353             $cmd = [ $cmd ];
 354         }
 355     }
 356
 357     my $errmsg;
 358     my $laststderr;
 359     my $timeout;
 360     my $oldtimeout;
 361     my $pid;
 362     my $exitcode = -1;
 363
 364     my $outfunc;
 365     my $errfunc;
 366     my $logfunc;
 367     my $input;
 368     my $output;
 369     my $afterfork;
 370     my $noerr;
 371     my $keeplocale;
 372
 373     eval {
 374
 375         foreach my $p (keys %param) {
 376             if ($p eq 'timeout') {
 377                 $timeout = $param{$p};
 378             } elsif ($p eq 'umask') {
 379                 $old_umask = umask($param{$p});
 380             } elsif ($p eq 'errmsg') {
 381                 $errmsg = $param{$p};
 382             } elsif ($p eq 'input') {
 383                 $input = $param{$p};
 384             } elsif ($p eq 'output') {
 385                 $output = $param{$p};
 386             } elsif ($p eq 'outfunc') {
 387                 $outfunc = $param{$p};
 388             } elsif ($p eq 'errfunc') {
 389                 $errfunc = $param{$p};
 390             } elsif ($p eq 'logfunc') {
 391                 $logfunc = $param{$p};
 392             } elsif ($p eq 'afterfork') {
 393                 $afterfork = $param{$p};
 394             } elsif ($p eq 'noerr') {
 395                 $noerr = $param{$p};
 396             } elsif ($p eq 'keeplocale') {
 397                 $keeplocale = $param{$p};
 398             } else {
 399                 die "got unknown parameter '$p' for run_command\n";
 400             }
 401         }
 402
 403         if ($errmsg) {
 404             my $origerrfunc = $errfunc;
 405             $errfunc = sub {
 406                 if ($laststderr) {
 407                     if ($origerrfunc) {
 408                         &$origerrfunc("$laststderr\n");
 409                     } else {
 410                         print STDERR "$laststderr\n" if $laststderr;
 411                     }
 412                 }
 413                 $laststderr = shift;
 414             };
 415         }
 416
 417         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 418         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 419         my $error  = IO::File->new();
 420
 421         my $orig_pid = $$;
 422
 423         eval {
 424             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 425
 426             # suppress LVM warnings like: "File descriptor 3 left open";
 427             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 428
 429             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 430
 431             # if we pipe fron STDIN, open3 closes STDIN, so we we
 432             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 433             # as soon as we open a new file.
 434             # to avoid that we open /dev/null
 435             if (!ref($writer) && !defined(fileno(STDIN))) {
 436                 POSIX::close(0);
 437                 open(STDIN, "</dev/null");
 438             }
 439         };
 440
 441         my $err = $@;
 442
 443         # catch exec errors
 444         if ($orig_pid != $$) {
 445             warn "ERROR: $err";
 446             POSIX::_exit (1);
 447             kill ('KILL', $$);
 448         }
 449
 450         die $err if $err;
 451
 452         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 453         $oldtimeout = alarm($timeout) if $timeout;
 454
 455         &$afterfork() if $afterfork;
 456
 457         if (ref($writer)) {
 458             print $writer $input if defined $input;
 459             close $writer;
 460         }
 461
 462         my $select = new IO::Select;
 463         $select->add($reader) if ref($reader);
 464         $select->add($error);
 465
 466         my $outlog = '';
 467         my $errlog = '';
 468
 469         my $starttime = time();
 470
 471         while ($select->count) {
 472             my @handles = $select->can_read(1);
 473
 474             foreach my $h (@handles) {
 475                 my $buf = '';
 476                 my $count = sysread ($h, $buf, 4096);
 477                 if (!defined ($count)) {
 478                     my $err = $!;
 479                     kill (9, $pid);
 480                     waitpid ($pid, 0);
 481                     die $err;
 482                 }
 483                 $select->remove ($h) if !$count;
 484                 if ($h eq $reader) {
 485                     if ($outfunc || $logfunc) {
 486                         eval {
 487                             $outlog .= $buf;
 488                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 489                                 my $line = $1;
 490                                 &$outfunc($line) if $outfunc;
 491                                 &$logfunc($line) if $logfunc;
 492                             }
 493                         };
 494                         my $err = $@;
 495                         if ($err) {
 496                             kill (9, $pid);
 497                             waitpid ($pid, 0);
 498                             die $err;
 499                         }
 500                     } else {
 501                         print $buf;
 502                         *STDOUT->flush();
 503                     }
 504                 } elsif ($h eq $error) {
 505                     if ($errfunc || $logfunc) {
 506                         eval {
 507                             $errlog .= $buf;
 508                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 509                                 my $line = $1;
 510                                 &$errfunc($line) if $errfunc;
 511                                 &$logfunc($line) if $logfunc;
 512                             }
 513                         };
 514                         my $err = $@;
 515                         if ($err) {
 516                             kill (9, $pid);
 517                             waitpid ($pid, 0);
 518                             die $err;
 519                         }
 520                     } else {
 521                         print STDERR $buf;
 522                         *STDERR->flush();
 523                     }
 524                 }
 525             }
 526         }
 527
 528         &$outfunc($outlog) if $outfunc && $outlog;
 529         &$logfunc($outlog) if $logfunc && $outlog;
 530
 531         &$errfunc($errlog) if $errfunc && $errlog;
 532         &$logfunc($errlog) if $logfunc && $errlog;
 533
 534         waitpid ($pid, 0);
 535
 536         if ($? == -1) {
 537             die "failed to execute\n";
 538         } elsif (my $sig = ($? & 127)) {
 539             die "got signal $sig\n";
 540         } elsif ($exitcode = ($? >> 8)) {
 541             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 542                 if ($errmsg && $laststderr) {
 543                     my $lerr = $laststderr;
 544                     $laststderr = undef;
 545                     die "$lerr\n";
 546                 }
 547                 die "exit code $exitcode\n";
 548             }
 549         }
 550
 551         alarm(0);
 552     };
 553
 554     my $err = $@;
 555
 556     alarm(0);
 557
 558     if ($errmsg && $laststderr) {
 559         &$errfunc(undef); # flush laststderr
 560     }
 561
 562     umask ($old_umask) if defined($old_umask);
 563
 564     alarm($oldtimeout) if $oldtimeout;
 565
 566     if ($err) {
 567         if ($pid && ($err eq "got timeout\n")) {
 568             kill (9, $pid);
 569             waitpid ($pid, 0);
 570             die "command '$cmdstr' failed: $err";
 571         }
 572
 573         if ($errmsg) {
 574             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 575             die "$errmsg: $err";
 576         } elsif(!$noerr) {
 577             die "command '$cmdstr' failed: $err";
 578         }
 579     }
 580
 581     return $exitcode;
 582 }
 583
 584 # Run a command with a tcp socket as standard input.
 585 sub pipe_socket_to_command  {
 586     my ($cmd, $ip, $port) = @_;
 587
 588     my $params = {
 589         Listen => 1,
 590         ReuseAddr => 1,
 591         Proto => &Socket::IPPROTO_TCP,
 592         GetAddrInfoFlags => 0,
 593         LocalAddr => $ip,
 594         LocalPort => $port,
 595     };
 596     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 597
 598     print "$ip\n$port\n"; # tell remote where to connect
 599     *STDOUT->flush();
 600
 601     alarm 0;
 602     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 603     alarm 30;
 604     my $client = $socket->accept; # Wait for a client
 605     alarm 0;
 606     close($socket);
 607
 608     # We want that the command talks over the TCP socket and takes
 609     # ownership of it, so that when it closes it the connection is
 610     # terminated, so we need to be able to close the socket. So we
 611     # can't really use PVE::Tools::run_command().
 612     my $pid = fork() // die "fork failed: $!\n";
 613     if (!$pid) {
 614         POSIX::dup2(fileno($client), 0);
 615         POSIX::dup2(fileno($client), 1);
 616         close($client);
 617         exec {$cmd->[0]} @$cmd or do {
 618             warn "exec failed: $!\n";
 619             POSIX::_exit(1);
 620         };
 621     }
 622
 623     close($client);
 624     if (waitpid($pid, 0) != $pid) {
 625         kill(15 => $pid); # if we got interrupted terminate the child
 626         my $count = 0;
 627         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 628             usleep(100000);
 629             $count++;
 630             kill(9 => $pid), last if $count > 300; # 30 second timeout
 631         }
 632     }
 633     if (my $sig = ($? & 127)) {
 634         die "got signal $sig\n";
 635     } elsif (my $exitcode = ($? >> 8)) {
 636         die "exit code $exitcode\n";
 637     }
 638
 639     return undef;
 640 }
 641
 642 sub split_list {
 643     my $listtxt = shift || '';
 644
 645     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 646
 647     $listtxt =~ s/[,;]/ /g;
 648     $listtxt =~ s/^\s+//;
 649
 650     my @data = split (/\s+/, $listtxt);
 651
 652     return @data;
 653 }
 654
 655 sub trim {
 656     my $txt = shift;
 657
 658     return $txt if !defined($txt);
 659
 660     $txt =~ s/^\s+//;
 661     $txt =~ s/\s+$//;
 662
 663     return $txt;
 664 }
 665
 666 # simple uri templates like "/vms/{vmid}"
 667 sub template_replace {
 668     my ($tmpl, $data) = @_;
 669
 670     return $tmpl if !$tmpl;
 671
 672     my $res = '';
 673     while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) {
 674         $res .= $1 if $1;
 675         $res .= ($data->{$3} || '-') if $2;
 676     }
 677     return $res;
 678 }
 679
 680 sub safe_print {
 681     my ($filename, $fh, $data) = @_;
 682
 683     return if !$data;
 684
 685     my $res = print $fh $data;
 686
 687     die "write to '$filename' failed\n" if !$res;
 688 }
 689
 690 sub debmirrors {
 691
 692     return {
 693         'at' => 'ftp.at.debian.org',
 694         'au' => 'ftp.au.debian.org',
 695         'be' => 'ftp.be.debian.org',
 696         'bg' => 'ftp.bg.debian.org',
 697         'br' => 'ftp.br.debian.org',
 698         'ca' => 'ftp.ca.debian.org',
 699         'ch' => 'ftp.ch.debian.org',
 700         'cl' => 'ftp.cl.debian.org',
 701         'cz' => 'ftp.cz.debian.org',
 702         'de' => 'ftp.de.debian.org',
 703         'dk' => 'ftp.dk.debian.org',
 704         'ee' => 'ftp.ee.debian.org',
 705         'es' => 'ftp.es.debian.org',
 706         'fi' => 'ftp.fi.debian.org',
 707         'fr' => 'ftp.fr.debian.org',
 708         'gr' => 'ftp.gr.debian.org',
 709         'hk' => 'ftp.hk.debian.org',
 710         'hr' => 'ftp.hr.debian.org',
 711         'hu' => 'ftp.hu.debian.org',
 712         'ie' => 'ftp.ie.debian.org',
 713         'is' => 'ftp.is.debian.org',
 714         'it' => 'ftp.it.debian.org',
 715         'jp' => 'ftp.jp.debian.org',
 716         'kr' => 'ftp.kr.debian.org',
 717         'mx' => 'ftp.mx.debian.org',
 718         'nl' => 'ftp.nl.debian.org',
 719         'no' => 'ftp.no.debian.org',
 720         'nz' => 'ftp.nz.debian.org',
 721         'pl' => 'ftp.pl.debian.org',
 722         'pt' => 'ftp.pt.debian.org',
 723         'ro' => 'ftp.ro.debian.org',
 724         'ru' => 'ftp.ru.debian.org',
 725         'se' => 'ftp.se.debian.org',
 726         'si' => 'ftp.si.debian.org',
 727         'sk' => 'ftp.sk.debian.org',
 728         'tr' => 'ftp.tr.debian.org',
 729         'tw' => 'ftp.tw.debian.org',
 730         'gb' => 'ftp.uk.debian.org',
 731         'us' => 'ftp.us.debian.org',
 732     };
 733 }
 734
 735 my $keymaphash =  {
 736     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 737     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 738     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 739     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 740     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 741     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 742     #'et'     => [], # Ethopia or Estonia ??
 743     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 744     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 745     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 746     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 747     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 748     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 749     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 750     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 751     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 752     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 753     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 754     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 755     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 756     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 757     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 758     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 759     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 760     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 761     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 762     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 763     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know?
 764     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 765     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 766     #'th'     => [],
 767     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 768 };
 769
 770 my $kvmkeymaparray = [];
 771 foreach my $lc (sort keys %$keymaphash) {
 772     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 773 }
 774
 775 sub kvmkeymaps {
 776     return $keymaphash;
 777 }
 778
 779 sub kvmkeymaplist {
 780     return $kvmkeymaparray;
 781 }
 782
 783 sub extract_param {
 784     my ($param, $key) = @_;
 785
 786     my $res = $param->{$key};
 787     delete $param->{$key};
 788
 789     return $res;
 790 }
 791
 792 # Note: we use this to wait until vncterm/spiceterm is ready
 793 sub wait_for_vnc_port {
 794     my ($port, $timeout) = @_;
 795
 796     $timeout = 5 if !$timeout;
 797     my $sleeptime = 0;
 798     my $starttime = [gettimeofday];
 799     my $elapsed;
 800
 801     my $found;
 802     while (($elapsed = tv_interval($starttime)) < $timeout) {
 803         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 804         run_command(['/bin/ss', '-Htln', "sport = :$port"], outfunc => sub {
 805             my $line = shift;
 806             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 807                 $found = 1 if ($port == $1);
 808             }
 809         });
 810         return 1 if $found;
 811         $sleeptime += 100000 if  $sleeptime < 1000000;
 812         usleep($sleeptime);
 813     }
 814
 815     return undef;
 816 }
 817
 818 sub next_unused_port {
 819     my ($range_start, $range_end, $family, $address) = @_;
 820
 821     # We use a file to register allocated ports.
 822     # Those registrations expires after $expiretime.
 823     # We use this to avoid race conditions between
 824     # allocation and use of ports.
 825
 826     my $filename = "/var/tmp/pve-reserved-ports";
 827
 828     my $code = sub {
 829
 830         my $expiretime = 5;
 831         my $ctime = time();
 832
 833         my $ports = {};
 834
 835         if (my $fh = IO::File->new ($filename, "r")) {
 836             while (my $line = <$fh>) {
 837                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 838                     my ($port, $timestamp) = ($1, $2);
 839                     if (($timestamp + $expiretime) > $ctime) {
 840                         $ports->{$port} = $timestamp; # not expired
 841                     }
 842                 }
 843             }
 844         }
 845
 846         my $newport;
 847         my %sockargs = (Listen => 5,
 848                         ReuseAddr => 1,
 849                         Family    => $family,
 850                         Proto     => IPPROTO_TCP,
 851                         GetAddrInfoFlags => 0);
 852         $sockargs{LocalAddr} = $address if defined($address);
 853
 854         for (my $p = $range_start; $p < $range_end; $p++) {
 855             next if $ports->{$p}; # reserved
 856
 857             $sockargs{LocalPort} = $p;
 858             my $sock = IO::Socket::IP->new(%sockargs);
 859
 860             if ($sock) {
 861                 close($sock);
 862                 $newport = $p;
 863                 $ports->{$p} = $ctime;
 864                 last;
 865             }
 866         }
 867
 868         my $data = "";
 869         foreach my $p (keys %$ports) {
 870             $data .= "$p $ports->{$p}\n";
 871         }
 872
 873         file_set_contents($filename, $data);
 874
 875         return $newport;
 876     };
 877
 878     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 879     die $@ if $@;
 880
 881     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 882
 883     return $p;
 884 }
 885
 886 sub next_migrate_port {
 887     my ($family, $address) = @_;
 888     return next_unused_port(60000, 60050, $family, $address);
 889 }
 890
 891 sub next_vnc_port {
 892     my ($family, $address) = @_;
 893     return next_unused_port(5900, 6000, $family, $address);
 894 }
 895
 896 sub next_spice_port {
 897     my ($family, $address) = @_;
 898     return next_unused_port(61000, 61099, $family, $address);
 899 }
 900
 901 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 902 # the $sub has to return a single scalar
 903 sub run_fork_with_timeout {
 904     my ($timeout, $sub) = @_;
 905
 906     my $res;
 907     my $error;
 908     my $pipe_out = IO::Pipe->new();
 909
 910     # disable pending alarms, save their remaining time
 911     my $prev_alarm = alarm 0;
 912
 913     # avoid leaving a zombie if the parent gets interrupted
 914     my $sig_received;
 915     local $SIG{INT} = sub { $sig_received++; };
 916
 917     my $child = fork();
 918     if (!defined($child)) {
 919         die "fork failed: $!\n";
 920         return $res;
 921     }
 922
 923     if (!$child) {
 924         $pipe_out->writer();
 925
 926         eval {
 927             $res = $sub->();
 928             print {$pipe_out} encode_json({ result => $res });
 929             $pipe_out->flush();
 930         };
 931         if (my $err = $@) {
 932             print {$pipe_out} encode_json({ error => $err });
 933             $pipe_out->flush();
 934             POSIX::_exit(1);
 935         }
 936         POSIX::_exit(0);
 937     }
 938
 939     $pipe_out->reader();
 940
 941     my $readvalues = sub {
 942         local $/ = undef;
 943         my $child_res = decode_json(scalar<$pipe_out>);
 944         $res = $child_res->{result};
 945         $error = $child_res->{error};
 946     };
 947     eval {
 948         run_with_timeout($timeout, $readvalues);
 949     };
 950     warn $@ if $@;
 951     $pipe_out->close();
 952     kill('KILL', $child);
 953     waitpid($child, 0);
 954
 955     alarm $prev_alarm;
 956     die "interrupted by unexpected signal\n" if $sig_received;
 957
 958     die $error if $error;
 959     return $res;
 960 }
 961
 962 # NOTE: NFS syscall can't be interrupted, so alarm does
 963 # not work to provide timeouts.
 964 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
 965 # So fork() before using Filesys::Df
 966 sub df {
 967     my ($path, $timeout) = @_;
 968
 969     my $res = {
 970         total => 0,
 971         used => 0,
 972         avail => 0,
 973     };
 974
 975     my $pipe = IO::Pipe->new();
 976     my $child = fork();
 977     if (!defined($child)) {
 978         warn "fork failed: $!\n";
 979         return $res;
 980     }
 981
 982     if (!$child) {
 983         $pipe->writer();
 984         eval {
 985             my $df = Filesys::Df::df($path, 1);
 986             print {$pipe} "$df->{blocks}\n$df->{used}\n$df->{bavail}\n"
 987                 if defined($df);
 988             $pipe->close();
 989         };
 990         if (my $err = $@) {
 991             warn $err;
 992             POSIX::_exit(1);
 993         }
 994         POSIX::_exit(0);
 995     }
 996
 997     $pipe->reader();
 998
 999     my $readvalues = sub {
1000         $res->{total} = int(((<$pipe> // 0) =~ /^(\d*)$/)[0]);
1001         $res->{used}  = int(((<$pipe> // 0) =~ /^(\d*)$/)[0]);
1002         $res->{avail} = int(((<$pipe> // 0) =~ /^(\d*)$/)[0]);
1003     };
1004     eval {
1005         run_with_timeout($timeout, $readvalues);
1006     };
1007     warn $@ if $@;
1008     $pipe->close();
1009     kill('KILL', $child);
1010     waitpid($child, 0);
1011     return $res;
1012 }
1013
1014 # UPID helper
1015 # We use this to uniquely identify a process.
1016 # An 'Unique Process ID' has the following format:
1017 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1018
1019 sub upid_encode {
1020     my $d = shift;
1021
1022     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1023     # more that 8 characters for pstart
1024     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1025                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1026                    $d->{user});
1027 }
1028
1029 sub upid_decode {
1030     my ($upid, $noerr) = @_;
1031
1032     my $res;
1033     my $filename;
1034
1035     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1036     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1037     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1038         $res->{node} = $1;
1039         $res->{pid} = hex($3);
1040         $res->{pstart} = hex($4);
1041         $res->{starttime} = hex($5);
1042         $res->{type} = $6;
1043         $res->{id} = $7;
1044         $res->{user} = $8;
1045
1046         my $subdir = substr($5, 7, 8);
1047         $filename = "$pvetaskdir/$subdir/$upid";
1048
1049     } else {
1050         return undef if $noerr;
1051         die "unable to parse worker upid '$upid'\n";
1052     }
1053
1054     return wantarray ? ($res, $filename) : $res;
1055 }
1056
1057 sub upid_open {
1058     my ($upid) = @_;
1059
1060     my ($task, $filename) = upid_decode($upid);
1061
1062     my $dirname = dirname($filename);
1063     make_path($dirname);
1064
1065     my $wwwid = getpwnam('www-data') ||
1066         die "getpwnam failed";
1067
1068     my $perm = 0640;
1069
1070     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1071         die "unable to create output file '$filename' - $!\n";
1072     chown $wwwid, -1, $outfh;
1073
1074     return $outfh;
1075 };
1076
1077 sub upid_read_status {
1078     my ($upid) = @_;
1079
1080     my ($task, $filename) = upid_decode($upid);
1081     my $fh = IO::File->new($filename, "r");
1082     return "unable to open file - $!" if !$fh;
1083     my $maxlen = 4096;
1084     sysseek($fh, -$maxlen, 2);
1085     my $readbuf = '';
1086     my $br = sysread($fh, $readbuf, $maxlen);
1087     close($fh);
1088     if ($br) {
1089         return "unable to extract last line"
1090             if $readbuf !~ m/\n?(.+)$/;
1091         my $line = $1;
1092         if ($line =~ m/^TASK OK$/) {
1093             return 'OK';
1094         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1095             return $1;
1096         } else {
1097             return "unexpected status";
1098         }
1099     }
1100     return "unable to read tail (got $br bytes)";
1101 }
1102
1103 # useful functions to store comments in config files
1104 sub encode_text {
1105     my ($text) = @_;
1106
1107     # all control and hi-bit characters, and ':'
1108     my $unsafe = "^\x20-\x39\x3b-\x7e";
1109     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1110 }
1111
1112 sub decode_text {
1113     my ($data) = @_;
1114
1115     return Encode::decode("utf8", uri_unescape($data));
1116 }
1117
1118 # depreciated - do not use!
1119 # we now decode all parameters by default
1120 sub decode_utf8_parameters {
1121     my ($param) = @_;
1122
1123     foreach my $p (qw(comment description firstname lastname)) {
1124         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1125     }
1126
1127     return $param;
1128 }
1129
1130 sub random_ether_addr {
1131     my ($prefix) = @_;
1132
1133     my ($seconds, $microseconds) = gettimeofday;
1134
1135     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1136
1137     # clear multicast, set local id
1138     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1139
1140     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1141     if (defined($prefix)) {
1142         $addr = uc($prefix) . substr($addr, length($prefix));
1143     }
1144     return $addr;
1145 }
1146
1147 sub shellquote {
1148     my $str = shift;
1149
1150     return String::ShellQuote::shell_quote($str);
1151 }
1152
1153 sub cmd2string {
1154     my ($cmd) = @_;
1155
1156     die "no arguments" if !$cmd;
1157
1158     return $cmd if !ref($cmd);
1159
1160     my @qa = ();
1161     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1162
1163     return join (' ', @qa);
1164 }
1165
1166 # split an shell argument string into an array,
1167 sub split_args {
1168     my ($str) = @_;
1169
1170     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1171 }
1172
1173 sub dump_logfile {
1174     my ($filename, $start, $limit, $filter) = @_;
1175
1176     my $lines = [];
1177     my $count = 0;
1178
1179     my $fh = IO::File->new($filename, "r");
1180     if (!$fh) {
1181         $count++;
1182         push @$lines, { n => $count, t => "unable to open file - $!"};
1183         return ($count, $lines);
1184     }
1185
1186     $start = 0 if !$start;
1187     $limit = 50 if !$limit;
1188
1189     my $line;
1190
1191     if ($filter) {
1192         # duplicate code, so that we do not slow down normal path
1193         while (defined($line = <$fh>)) {
1194             next if $line !~ m/$filter/;
1195             next if $count++ < $start;
1196             next if $limit <= 0;
1197             chomp $line;
1198             push @$lines, { n => $count, t => $line};
1199             $limit--;
1200         }
1201     } else {
1202         while (defined($line = <$fh>)) {
1203             next if $count++ < $start;
1204             next if $limit <= 0;
1205             chomp $line;
1206             push @$lines, { n => $count, t => $line};
1207             $limit--;
1208         }
1209     }
1210
1211     close($fh);
1212
1213     # HACK: ExtJS store.guaranteeRange() does not like empty array
1214     # so we add a line
1215     if (!$count) {
1216         $count++;
1217         push @$lines, { n => $count, t => "no content"};
1218     }
1219
1220     return ($count, $lines);
1221 }
1222
1223 sub dump_journal {
1224     my ($start, $limit, $since, $until, $service) = @_;
1225
1226     my $lines = [];
1227     my $count = 0;
1228
1229     $start = 0 if !$start;
1230     $limit = 50 if !$limit;
1231
1232     my $parser = sub {
1233         my $line = shift;
1234
1235         return if $count++ < $start;
1236         return if $limit <= 0;
1237         push @$lines, { n => int($count), t => $line};
1238         $limit--;
1239     };
1240
1241     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1242
1243     push @$cmd, '--unit', $service if $service;
1244     push @$cmd, '--since', $since if $since;
1245     push @$cmd, '--until', $until if $until;
1246     run_command($cmd, outfunc => $parser);
1247
1248     # HACK: ExtJS store.guaranteeRange() does not like empty array
1249     # so we add a line
1250     if (!$count) {
1251         $count++;
1252         push @$lines, { n => $count, t => "no content"};
1253     }
1254
1255     return ($count, $lines);
1256 }
1257
1258 sub dir_glob_regex {
1259     my ($dir, $regex) = @_;
1260
1261     my $dh = IO::Dir->new ($dir);
1262     return wantarray ? () : undef if !$dh;
1263
1264     while (defined(my $tmp = $dh->read)) {
1265         if (my @res = $tmp =~ m/^($regex)$/) {
1266             $dh->close;
1267             return wantarray ? @res : $tmp;
1268         }
1269     }
1270     $dh->close;
1271
1272     return wantarray ? () : undef;
1273 }
1274
1275 sub dir_glob_foreach {
1276     my ($dir, $regex, $func) = @_;
1277
1278     my $dh = IO::Dir->new ($dir);
1279     if (defined $dh) {
1280         while (defined(my $tmp = $dh->read)) {
1281             if (my @res = $tmp =~ m/^($regex)$/) {
1282                 &$func (@res);
1283             }
1284         }
1285     }
1286 }
1287
1288 sub assert_if_modified {
1289     my ($digest1, $digest2) = @_;
1290
1291     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1292         die "detected modified configuration - file changed by other user? Try again.\n";
1293     }
1294 }
1295
1296 # Digest for short strings
1297 # like FNV32a, but we only return 31 bits (positive numbers)
1298 sub fnv31a {
1299     my ($string) = @_;
1300
1301     my $hval = 0x811c9dc5;
1302
1303     foreach my $c (unpack('C*', $string)) {
1304         $hval ^= $c;
1305         $hval += (
1306             (($hval << 1) ) +
1307             (($hval << 4) ) +
1308             (($hval << 7) ) +
1309             (($hval << 8) ) +
1310             (($hval << 24) ) );
1311         $hval = $hval & 0xffffffff;
1312     }
1313     return $hval & 0x7fffffff;
1314 }
1315
1316 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1317
1318 sub unpack_sockaddr_in46 {
1319     my ($sin) = @_;
1320     my $family = Socket::sockaddr_family($sin);
1321     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1322                                              : Socket::unpack_sockaddr_in($sin));
1323     return ($family, $port, $host);
1324 }
1325
1326 sub getaddrinfo_all {
1327     my ($hostname, @opts) = @_;
1328     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1329                   @opts );
1330     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1331     die "failed to get address info for: $hostname: $err\n" if $err;
1332     return @res;
1333 }
1334
1335 sub get_host_address_family {
1336     my ($hostname, $socktype) = @_;
1337     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1338     return $res[0]->{family};
1339 }
1340
1341 # get the fully qualified domain name of a host
1342 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1343 # given a nodename as a parameter
1344 sub get_fqdn {
1345     my ($nodename) = @_;
1346
1347     my $hints = {
1348         flags => AI_CANONNAME,
1349         socktype => SOCK_DGRAM
1350     };
1351
1352     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1353
1354     die "getaddrinfo: $err" if $err;
1355
1356     return $addrs[0]->{canonname};
1357 }
1358
1359 # Parses any sane kind of host, or host+port pair:
1360 # The port is always optional and thus may be undef.
1361 sub parse_host_and_port {
1362     my ($address) = @_;
1363     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1364         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1365         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1366     {
1367         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1368     }
1369     return; # nothing
1370 }
1371
1372 sub unshare($) {
1373     my ($flags) = @_;
1374     return 0 == syscall(PVE::Syscall::unshare, $flags);
1375 }
1376
1377 sub setns($$) {
1378     my ($fileno, $nstype) = @_;
1379     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1380 }
1381
1382 sub syncfs($) {
1383     my ($fileno) = @_;
1384     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1385 }
1386
1387 sub sync_mountpoint {
1388     my ($path) = @_;
1389     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1390     my $result = syncfs(fileno($fd));
1391     close($fd);
1392     return $result;
1393 }
1394
1395 # support sending multi-part mail messages with a text and or a HTML part
1396 # mailto may be a single email string or an array of receivers
1397 sub sendmail {
1398     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1399     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1400
1401     $mailto = [ $mailto ] if !ref($mailto);
1402
1403     foreach (@$mailto) {
1404         die "illegal character in mailto address\n"
1405             if ($_ =~ $mail_re);
1406     }
1407
1408     my $rcvrtxt = join (', ', @$mailto);
1409
1410     $mailfrom = $mailfrom || "root";
1411     die "illegal character in mailfrom address\n"
1412         if $mailfrom =~ $mail_re;
1413
1414     $author = $author || 'Proxmox VE';
1415
1416     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1417         die "unable to open 'sendmail' - $!";
1418
1419     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1420     my $boundary = "----_=_NextPart_001_".int(time).$$;
1421
1422     print MAIL "Content-Type: multipart/alternative;\n";
1423     print MAIL "\tboundary=\"$boundary\"\n";
1424     print MAIL "MIME-Version: 1.0\n";
1425
1426     print MAIL "FROM: $author <$mailfrom>\n";
1427     print MAIL "TO: $rcvrtxt\n";
1428     print MAIL "SUBJECT: $subject\n";
1429     print MAIL "\n";
1430     print MAIL "This is a multi-part message in MIME format.\n\n";
1431     print MAIL "--$boundary\n";
1432
1433     if (defined($text)) {
1434         print MAIL "Content-Type: text/plain;\n";
1435         print MAIL "\tcharset=\"UTF8\"\n";
1436         print MAIL "Content-Transfer-Encoding: 8bit\n";
1437         print MAIL "\n";
1438
1439         # avoid 'remove extra line breaks' issue (MS Outlook)
1440         my $fill = '  ';
1441         $text =~ s/^/$fill/gm;
1442
1443         print MAIL $text;
1444
1445         print MAIL "\n--$boundary\n";
1446     }
1447
1448     if (defined($html)) {
1449         print MAIL "Content-Type: text/html;\n";
1450         print MAIL "\tcharset=\"UTF8\"\n";
1451         print MAIL "Content-Transfer-Encoding: 8bit\n";
1452         print MAIL "\n";
1453
1454         print MAIL $html;
1455
1456         print MAIL "\n--$boundary--\n";
1457     }
1458
1459     close(MAIL);
1460 }
1461
1462 sub tempfile {
1463     my ($perm, %opts) = @_;
1464
1465     # default permissions are stricter than with file_set_contents
1466     $perm = 0600 if !defined($perm);
1467
1468     my $dir = $opts{dir} // '/run';
1469     my $mode = $opts{mode} // O_RDWR;
1470     $mode |= O_EXCL if !$opts{allow_links};
1471
1472     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1473     if (!$fh && $! == EOPNOTSUPP) {
1474         $dir = '/tmp' if !defined($opts{dir});
1475         $dir .= "/.tmpfile.$$";
1476         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1477         unlink($dir) if $fh;
1478     }
1479     die "failed to create tempfile: $!\n" if !$fh;
1480     return $fh;
1481 }
1482
1483 sub tempfile_contents {
1484     my ($data, $perm, %opts) = @_;
1485
1486     my $fh = tempfile($perm, %opts);
1487     eval {
1488         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1489         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1490     };
1491     if (my $err = $@) {
1492         close $fh;
1493         die $err;
1494     }
1495
1496     return ("/proc/$$/fd/".$fh->fileno, $fh);
1497 }
1498
1499 sub validate_ssh_public_keys {
1500     my ($raw) = @_;
1501     my @lines = split(/\n/, $raw);
1502
1503     foreach my $line (@lines) {
1504         next if $line =~ m/^\s*$/;
1505         eval {
1506             my ($filename, $handle) = tempfile_contents($line);
1507             run_command(["ssh-keygen", "-l", "-f", $filename],
1508                         outfunc => sub {}, errfunc => sub {});
1509         };
1510         die "SSH public key validation error\n" if $@;
1511     }
1512 }
1513
1514 sub openat($$$;$) {
1515     my ($dirfd, $pathname, $flags, $mode) = @_;
1516     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1517     return undef if $fd < 0;
1518     # sysopen() doesn't deal with numeric file descriptors apparently
1519     # so we need to convert to a mode string for IO::Handle->new_from_fd
1520     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1521     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1522     return $handle if $handle;
1523     my $err = $!; # save error before closing the raw fd
1524     syscall(PVE::Syscall::close, $fd); # close
1525     $! = $err;
1526     return undef;
1527 }
1528
1529 sub mkdirat($$$) {
1530     my ($dirfd, $name, $mode) = @_;
1531     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1532 }
1533
1534 # NOTE: This calls the dbus main loop and must not be used when another dbus
1535 # main loop is being used as we need to wait for the JobRemoved signal.
1536 # Polling the job status instead doesn't work because this doesn't give us the
1537 # distinction between success and failure.
1538 #
1539 # Note that the description is mandatory for security reasons.
1540 sub enter_systemd_scope {
1541     my ($unit, $description, %extra) = @_;
1542     die "missing description\n" if !defined($description);
1543
1544     my $timeout = delete $extra{timeout};
1545
1546     $unit .= '.scope';
1547     my $properties = [ [PIDs => [dbus_uint32($$)]] ];
1548
1549     foreach my $key (keys %extra) {
1550         if ($key eq 'Slice' || $key eq 'KillMode') {
1551             push @$properties, [$key, $extra{$key}];
1552         } elsif ($key eq 'CPUShares') {
1553             push @$properties, [$key, dbus_uint64($extra{$key})];
1554         } elsif ($key eq 'CPUQuota') {
1555             push @$properties, ['CPUQuotaPerSecUSec',
1556                                 dbus_uint64($extra{$key} * 10000)];
1557         } else {
1558             die "Don't know how to encode $key for systemd scope\n";
1559         }
1560     }
1561
1562     my $job;
1563     my $done = 0;
1564
1565     my $bus = Net::DBus->system();
1566     my $reactor = Net::DBus::Reactor->main();
1567
1568     my $service = $bus->get_service('org.freedesktop.systemd1');
1569     my $if = $service->get_object('/org/freedesktop/systemd1', 'org.freedesktop.systemd1.Manager');
1570     # Connect to the JobRemoved signal since we want to wait for it to finish
1571     my $sigid;
1572     my $timer;
1573     my $cleanup = sub {
1574         my ($no_shutdown) = @_;
1575         $if->disconnect_from_signal('JobRemoved', $sigid) if defined($if);
1576         $if = undef;
1577         $sigid = undef;
1578         $reactor->remove_timeout($timer) if defined($timer);
1579         $timer = undef;
1580         return if $no_shutdown;
1581         $reactor->shutdown();
1582     };
1583
1584     $sigid = $if->connect_to_signal('JobRemoved', sub {
1585         my ($id, $removed_job, $signaled_unit, $result) = @_;
1586         return if $signaled_unit ne $unit || $removed_job ne $job;
1587         $cleanup->(0);
1588         die "systemd job failed\n" if $result ne 'done';
1589         $done = 1;
1590     });
1591
1592     my $on_timeout = sub {
1593         $cleanup->(0);
1594         die "systemd job timed out\n";
1595     };
1596
1597     $timer = $reactor->add_timeout($timeout * 1000, Net::DBus::Callback->new(method => $on_timeout))
1598         if defined($timeout);
1599     $job = $if->StartTransientUnit($unit, 'fail', $properties, []);
1600     $reactor->run();
1601     $cleanup->(1);
1602     die "systemd job never completed\n" if !$done;
1603 }
1604
1605 my $salt_starter = time();
1606
1607 sub encrypt_pw {
1608     my ($pw) = @_;
1609
1610     $salt_starter++;
1611     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1612
1613     # crypt does not want '+' in salt (see 'man crypt')
1614     $salt =~ s/\+/X/g;
1615
1616     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1617 }
1618
1619 # intended usage: convert_size($val, "kb" => "gb")
1620 # on reduction (converting to a bigger unit) we round up by default if
1621 # information got lost. E.g. `convert_size(1023, "b" => "kb")` returns 1
1622 # use $no_round_up to switch this off, above example would then return 0
1623 sub convert_size {
1624     my ($value, $from, $to, $no_round_up) = @_;
1625
1626     my $units = {
1627         b  => 0,
1628         kb => 1,
1629         mb => 2,
1630         gb => 3,
1631         tb => 4,
1632         pb => 5,
1633     };
1634
1635     $from = lc($from); $to = lc($to);
1636     die "unknown 'from' and/or 'to' units ($from => $to)"
1637         if !(defined($units->{$from}) && defined($units->{$to}));
1638
1639     my $shift_amount = $units->{$from} - $units->{$to};
1640
1641     if ($shift_amount > 0) {
1642         $value <<= ($shift_amount * 10);
1643     } elsif ($shift_amount < 0) {
1644         my $remainder = ($value & (1 << abs($shift_amount)*10) - 1);
1645         $value >>= abs($shift_amount) * 10;
1646         $value++ if $remainder && !$no_round_up;
1647     }
1648
1649     return $value;
1650 }
1651
1652 1;