src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Scalar::Util 'weaken';
  28 use PVE::Syscall;
  29
  30 # avoid warning when parsing long hex values with hex()
  31 no warnings 'portable'; # Support for 64-bit ints required
  32
  33 our @EXPORT_OK = qw(
  34 $IPV6RE
  35 $IPV4RE
  36 lock_file
  37 lock_file_full
  38 run_command
  39 file_set_contents
  40 file_get_contents
  41 file_read_firstline
  42 dir_glob_regex
  43 dir_glob_foreach
  44 split_list
  45 template_replace
  46 safe_print
  47 trim
  48 extract_param
  49 file_copy
  50 get_host_arch
  51 O_PATH
  52 O_TMPFILE
  53 AT_EMPTY_PATH
  54 AT_FDCWD
  55 CLONE_NEWNS
  56 CLONE_NEWUTS
  57 CLONE_NEWIPC
  58 CLONE_NEWUSER
  59 CLONE_NEWPID
  60 CLONE_NEWNET
  61 );
  62
  63 my $pvelogdir = "/var/log/pve";
  64 my $pvetaskdir = "$pvelogdir/tasks";
  65
  66 mkdir $pvelogdir;
  67 mkdir $pvetaskdir;
  68
  69 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  70 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  71 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  72 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  73
  74 our $IPV6RE = "(?:" .
  75     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  76     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  77     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  78     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  79     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  80     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  81     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  84
  85 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  86
  87 use constant {CLONE_NEWNS   => 0x00020000,
  88               CLONE_NEWUTS  => 0x04000000,
  89               CLONE_NEWIPC  => 0x08000000,
  90               CLONE_NEWUSER => 0x10000000,
  91               CLONE_NEWPID  => 0x20000000,
  92               CLONE_NEWNET  => 0x40000000};
  93
  94 use constant {O_PATH    => 0x00200000,
  95               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  96
  97 use constant {AT_EMPTY_PATH => 0x1000,
  98               AT_FDCWD => -100};
  99
 100 sub run_with_timeout {
 101     my ($timeout, $code, @param) = @_;
 102
 103     die "got timeout\n" if $timeout <= 0;
 104
 105     my $prev_alarm = alarm 0; # suspend outer alarm early
 106
 107     my $sigcount = 0;
 108
 109     my $res;
 110
 111     eval {
 112         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 113         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 114         local $SIG{__DIE__};   # see SA bug 4631
 115
 116         alarm($timeout);
 117
 118         eval { $res = &$code(@param); };
 119
 120         alarm(0); # avoid race conditions
 121
 122         die $@ if $@;
 123     };
 124
 125     my $err = $@;
 126
 127     alarm $prev_alarm;
 128
 129     # this shouldn't happen anymore?
 130     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 131
 132     die $err if $err;
 133
 134     return $res;
 135 }
 136
 137 # flock: we use one file handle per process, so lock file
 138 # can be nested multiple times and succeeds for the same process.
 139 #
 140 # Since this is the only way we lock now and we don't have the old
 141 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 142 # count how deep we're nesting. Therefore this hash now stores a weak reference
 143 # to a boolean telling us whether we already have a lock.
 144
 145 my $lock_handles =  {};
 146
 147 sub lock_file_full {
 148     my ($filename, $timeout, $shared, $code, @param) = @_;
 149
 150     $timeout = 10 if !$timeout;
 151
 152     my $mode = $shared ? LOCK_SH : LOCK_EX;
 153
 154     my $lockhash = ($lock_handles->{$$} //= {});
 155
 156     # Returns a locked file handle.
 157     my $get_locked_file = sub {
 158         my $fh = IO::File->new(">>$filename")
 159             or die "can't open file - $!\n";
 160
 161         if (!flock($fh, $mode|LOCK_NB)) {
 162             print STDERR "trying to acquire lock...\n";
 163             my $success;
 164             while(1) {
 165                 $success = flock($fh, $mode);
 166                 # try again on EINTR (see bug #273)
 167                 if ($success || ($! != EINTR)) {
 168                     last;
 169                 }
 170             }
 171             if (!$success) {
 172                 print STDERR " failed\n";
 173                 die "can't acquire lock '$filename' - $!\n";
 174             }
 175             print STDERR " OK\n";
 176         }
 177
 178         return $fh;
 179     };
 180
 181     my $res;
 182     my $checkptr = $lockhash->{$filename};
 183     my $check = 0; # This must not go out of scope before running the code.
 184     my $local_fh; # This must stay local
 185     if (!$checkptr || !$$checkptr) {
 186         # We cannot create a weak reference in a single atomic step, so we first
 187         # create a false-value, then create a reference to it, then weaken it,
 188         # and after successfully locking the file we change the boolean value.
 189         #
 190         # The reason for this is that if an outer SIGALRM throws an exception
 191         # between creating the reference and weakening it, a subsequent call to
 192         # lock_file_full() will see a leftover full reference to a valid
 193         # variable. This variable must be 0 in order for said call to attempt to
 194         # lock the file anew.
 195         #
 196         # An externally triggered exception elsewhere in the code will cause the
 197         # weak reference to become 'undef', and since the file handle is only
 198         # stored in the local scope in $local_fh, the file will be closed by
 199         # perl's cleanup routines as well.
 200         #
 201         # This still assumes that an IO::File handle can properly deal with such
 202         # exceptions thrown during its own destruction, but that's up to perls
 203         # guts now.
 204         $lockhash->{$filename} = \$check;
 205         weaken $lockhash->{$filename};
 206         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 207         if ($@) {
 208             $@ = "can't lock file '$filename' - $@";
 209             return undef;
 210         }
 211         $check = 1;
 212     }
 213     $res = eval { &$code(@param); };
 214     return undef if $@;
 215     return $res;
 216 }
 217
 218
 219 sub lock_file {
 220     my ($filename, $timeout, $code, @param) = @_;
 221
 222     return lock_file_full($filename, $timeout, 0, $code, @param);
 223 }
 224
 225 sub file_set_contents {
 226     my ($filename, $data, $perm)  = @_;
 227
 228     $perm = 0644 if !defined($perm);
 229
 230     my $tmpname = "$filename.tmp.$$";
 231
 232     eval {
 233         my ($fh, $tries) = (undef, 0);
 234         while (!$fh && $tries++ < 3) {
 235             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 236             if (!$fh && $! == EEXIST) {
 237                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 238             }
 239         }
 240         die "unable to open file '$tmpname' - $!\n" if !$fh;
 241         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 242         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 243     };
 244     my $err = $@;
 245
 246     if ($err) {
 247         unlink $tmpname;
 248         die $err;
 249     }
 250
 251     if (!rename($tmpname, $filename)) {
 252         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 253         unlink $tmpname;
 254         die $msg;
 255     }
 256 }
 257
 258 sub file_get_contents {
 259     my ($filename, $max) = @_;
 260
 261     my $fh = IO::File->new($filename, "r") ||
 262         die "can't open '$filename' - $!\n";
 263
 264     my $content = safe_read_from($fh, $max, 0, $filename);
 265
 266     close $fh;
 267
 268     return $content;
 269 }
 270
 271 sub file_copy {
 272     my ($filename, $dst, $max, $perm) = @_;
 273
 274     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 275 }
 276
 277 sub file_read_firstline {
 278     my ($filename) = @_;
 279
 280     my $fh = IO::File->new ($filename, "r");
 281     return undef if !$fh;
 282     my $res = <$fh>;
 283     chomp $res if $res;
 284     $fh->close;
 285     return $res;
 286 }
 287
 288 sub safe_read_from {
 289     my ($fh, $max, $oneline, $filename) = @_;
 290
 291     # pmxcfs file size limit
 292     $max = 512*1024 if !$max;
 293
 294     my $subject = defined($filename) ? "file '$filename'" : 'input';
 295
 296     my $br = 0;
 297     my $input = '';
 298     my $count;
 299     while ($count = sysread($fh, $input, 8192, $br)) {
 300         $br += $count;
 301         die "$subject too long - aborting\n" if $br > $max;
 302         if ($oneline && $input =~ m/^(.*)\n/) {
 303             $input = $1;
 304             last;
 305         }
 306     }
 307     die "unable to read $subject - $!\n" if !defined($count);
 308
 309     return $input;
 310 }
 311
 312 # The $cmd parameter can be:
 313 #  -) a string
 314 #    This is generally executed by passing it to the shell with the -c option.
 315 #    However, it can be executed in one of two ways, depending on whether
 316 #    there's a pipe involved:
 317 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 318 #          set -o pipefail &&
 319 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 320 #      (Note that this may result in two different syntax requirements!)
 321 #      FIXME?
 322 #  -) an array of arguments (strings)
 323 #    Will be executed without interference from a shell. (Parameters are passed
 324 #    as is, no escape sequences of strings will be touched.)
 325 #  -) an array of arrays
 326 #    Each array represents a command, and each command's output is piped into
 327 #    the following command's standard input.
 328 #    For this a shell command string is created with pipe symbols between each
 329 #    command.
 330 #    Each command is a list of strings meant to end up in the final command
 331 #    unchanged. In order to achieve this, every argument is shell-quoted.
 332 #    Quoting can be disabled for a particular argument by turning it into a
 333 #    reference, this allows inserting arbitrary shell options.
 334 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 335 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 336 #    will literally print: hello >/dev/null
 337 sub run_command {
 338     my ($cmd, %param) = @_;
 339
 340     my $old_umask;
 341     my $cmdstr;
 342
 343     if (my $ref = ref($cmd)) {
 344         if (ref($cmd->[0])) {
 345             $cmdstr = 'set -o pipefail && ';
 346             my $pipe = '';
 347             foreach my $command (@$cmd) {
 348                 # concatenate quoted parameters
 349                 # strings which are passed by reference are NOT shell quoted
 350                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 351                 $pipe = ' | ';
 352             }
 353             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 354         } else {
 355             $cmdstr = cmd2string($cmd);
 356         }
 357     } else {
 358         $cmdstr = $cmd;
 359         if ($cmd =~ m/\|/) {
 360             # see 'man bash' for option pipefail
 361             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 362         } else {
 363             $cmd = [ $cmd ];
 364         }
 365     }
 366
 367     my $errmsg;
 368     my $laststderr;
 369     my $timeout;
 370     my $oldtimeout;
 371     my $pid;
 372     my $exitcode = -1;
 373
 374     my $outfunc;
 375     my $errfunc;
 376     my $logfunc;
 377     my $input;
 378     my $output;
 379     my $afterfork;
 380     my $noerr;
 381     my $keeplocale;
 382     my $quiet;
 383
 384     eval {
 385
 386         foreach my $p (keys %param) {
 387             if ($p eq 'timeout') {
 388                 $timeout = $param{$p};
 389             } elsif ($p eq 'umask') {
 390                 $old_umask = umask($param{$p});
 391             } elsif ($p eq 'errmsg') {
 392                 $errmsg = $param{$p};
 393             } elsif ($p eq 'input') {
 394                 $input = $param{$p};
 395             } elsif ($p eq 'output') {
 396                 $output = $param{$p};
 397             } elsif ($p eq 'outfunc') {
 398                 $outfunc = $param{$p};
 399             } elsif ($p eq 'errfunc') {
 400                 $errfunc = $param{$p};
 401             } elsif ($p eq 'logfunc') {
 402                 $logfunc = $param{$p};
 403             } elsif ($p eq 'afterfork') {
 404                 $afterfork = $param{$p};
 405             } elsif ($p eq 'noerr') {
 406                 $noerr = $param{$p};
 407             } elsif ($p eq 'keeplocale') {
 408                 $keeplocale = $param{$p};
 409             } elsif ($p eq 'quiet') {
 410                 $quiet = $param{$p};
 411             } else {
 412                 die "got unknown parameter '$p' for run_command\n";
 413             }
 414         }
 415
 416         if ($errmsg) {
 417             my $origerrfunc = $errfunc;
 418             $errfunc = sub {
 419                 if ($laststderr) {
 420                     if ($origerrfunc) {
 421                         &$origerrfunc("$laststderr\n");
 422                     } else {
 423                         print STDERR "$laststderr\n" if $laststderr;
 424                     }
 425                 }
 426                 $laststderr = shift;
 427             };
 428         }
 429
 430         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 431         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 432         my $error  = IO::File->new();
 433
 434         my $orig_pid = $$;
 435
 436         eval {
 437             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 438
 439             # suppress LVM warnings like: "File descriptor 3 left open";
 440             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 441
 442             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 443
 444             # if we pipe fron STDIN, open3 closes STDIN, so we we
 445             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 446             # as soon as we open a new file.
 447             # to avoid that we open /dev/null
 448             if (!ref($writer) && !defined(fileno(STDIN))) {
 449                 POSIX::close(0);
 450                 open(STDIN, "</dev/null");
 451             }
 452         };
 453
 454         my $err = $@;
 455
 456         # catch exec errors
 457         if ($orig_pid != $$) {
 458             warn "ERROR: $err";
 459             POSIX::_exit (1);
 460             kill ('KILL', $$);
 461         }
 462
 463         die $err if $err;
 464
 465         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 466         $oldtimeout = alarm($timeout) if $timeout;
 467
 468         &$afterfork() if $afterfork;
 469
 470         if (ref($writer)) {
 471             print $writer $input if defined $input;
 472             close $writer;
 473         }
 474
 475         my $select = new IO::Select;
 476         $select->add($reader) if ref($reader);
 477         $select->add($error);
 478
 479         my $outlog = '';
 480         my $errlog = '';
 481
 482         my $starttime = time();
 483
 484         while ($select->count) {
 485             my @handles = $select->can_read(1);
 486
 487             foreach my $h (@handles) {
 488                 my $buf = '';
 489                 my $count = sysread ($h, $buf, 4096);
 490                 if (!defined ($count)) {
 491                     my $err = $!;
 492                     kill (9, $pid);
 493                     waitpid ($pid, 0);
 494                     die $err;
 495                 }
 496                 $select->remove ($h) if !$count;
 497                 if ($h eq $reader) {
 498                     if ($outfunc || $logfunc) {
 499                         eval {
 500                             while ($buf =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//) {
 501                                 my $line = $outlog . $1;
 502                                 $outlog = '';
 503                                 &$outfunc($line) if $outfunc;
 504                                 &$logfunc($line) if $logfunc;
 505                             }
 506                             $outlog .= $buf;
 507                         };
 508                         my $err = $@;
 509                         if ($err) {
 510                             kill (9, $pid);
 511                             waitpid ($pid, 0);
 512                             die $err;
 513                         }
 514                     } elsif (!$quiet) {
 515                         print $buf;
 516                         *STDOUT->flush();
 517                     }
 518                 } elsif ($h eq $error) {
 519                     if ($errfunc || $logfunc) {
 520                         eval {
 521                             while ($buf =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
 522                                 my $line = $errlog . $1;
 523                                 $errlog = '';
 524                                 &$errfunc($line) if $errfunc;
 525                                 &$logfunc($line) if $logfunc;
 526                             }
 527                             $errlog .= $buf;
 528                         };
 529                         my $err = $@;
 530                         if ($err) {
 531                             kill (9, $pid);
 532                             waitpid ($pid, 0);
 533                             die $err;
 534                         }
 535                     } elsif (!$quiet) {
 536                         print STDERR $buf;
 537                         *STDERR->flush();
 538                     }
 539                 }
 540             }
 541         }
 542
 543         &$outfunc($outlog) if $outfunc && $outlog;
 544         &$logfunc($outlog) if $logfunc && $outlog;
 545
 546         &$errfunc($errlog) if $errfunc && $errlog;
 547         &$logfunc($errlog) if $logfunc && $errlog;
 548
 549         waitpid ($pid, 0);
 550
 551         if ($? == -1) {
 552             die "failed to execute\n";
 553         } elsif (my $sig = ($? & 127)) {
 554             die "got signal $sig\n";
 555         } elsif ($exitcode = ($? >> 8)) {
 556             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 557                 if ($errmsg && $laststderr) {
 558                     my $lerr = $laststderr;
 559                     $laststderr = undef;
 560                     die "$lerr\n";
 561                 }
 562                 die "exit code $exitcode\n";
 563             }
 564         }
 565
 566         alarm(0);
 567     };
 568
 569     my $err = $@;
 570
 571     alarm(0);
 572
 573     if ($errmsg && $laststderr) {
 574         &$errfunc(undef); # flush laststderr
 575     }
 576
 577     umask ($old_umask) if defined($old_umask);
 578
 579     alarm($oldtimeout) if $oldtimeout;
 580
 581     if ($err) {
 582         if ($pid && ($err eq "got timeout\n")) {
 583             kill (9, $pid);
 584             waitpid ($pid, 0);
 585             die "command '$cmdstr' failed: $err";
 586         }
 587
 588         if ($errmsg) {
 589             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 590             die "$errmsg: $err";
 591         } elsif(!$noerr) {
 592             die "command '$cmdstr' failed: $err";
 593         }
 594     }
 595
 596     return $exitcode;
 597 }
 598
 599 # Run a command with a tcp socket as standard input.
 600 sub pipe_socket_to_command  {
 601     my ($cmd, $ip, $port) = @_;
 602
 603     my $params = {
 604         Listen => 1,
 605         ReuseAddr => 1,
 606         Proto => &Socket::IPPROTO_TCP,
 607         GetAddrInfoFlags => 0,
 608         LocalAddr => $ip,
 609         LocalPort => $port,
 610     };
 611     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 612
 613     print "$ip\n$port\n"; # tell remote where to connect
 614     *STDOUT->flush();
 615
 616     alarm 0;
 617     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 618     alarm 30;
 619     my $client = $socket->accept; # Wait for a client
 620     alarm 0;
 621     close($socket);
 622
 623     # We want that the command talks over the TCP socket and takes
 624     # ownership of it, so that when it closes it the connection is
 625     # terminated, so we need to be able to close the socket. So we
 626     # can't really use PVE::Tools::run_command().
 627     my $pid = fork() // die "fork failed: $!\n";
 628     if (!$pid) {
 629         POSIX::dup2(fileno($client), 0);
 630         POSIX::dup2(fileno($client), 1);
 631         close($client);
 632         exec {$cmd->[0]} @$cmd or do {
 633             warn "exec failed: $!\n";
 634             POSIX::_exit(1);
 635         };
 636     }
 637
 638     close($client);
 639     if (waitpid($pid, 0) != $pid) {
 640         kill(15 => $pid); # if we got interrupted terminate the child
 641         my $count = 0;
 642         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 643             usleep(100000);
 644             $count++;
 645             kill(9 => $pid), last if $count > 300; # 30 second timeout
 646         }
 647     }
 648     if (my $sig = ($? & 127)) {
 649         die "got signal $sig\n";
 650     } elsif (my $exitcode = ($? >> 8)) {
 651         die "exit code $exitcode\n";
 652     }
 653
 654     return undef;
 655 }
 656
 657 sub split_list {
 658     my $listtxt = shift // '';
 659
 660     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 661
 662     $listtxt =~ s/[,;]/ /g;
 663     $listtxt =~ s/^\s+//;
 664
 665     my @data = split (/\s+/, $listtxt);
 666
 667     return @data;
 668 }
 669
 670 sub trim {
 671     my $txt = shift;
 672
 673     return $txt if !defined($txt);
 674
 675     $txt =~ s/^\s+//;
 676     $txt =~ s/\s+$//;
 677
 678     return $txt;
 679 }
 680
 681 # simple uri templates like "/vms/{vmid}"
 682 sub template_replace {
 683     my ($tmpl, $data) = @_;
 684
 685     return $tmpl if !$tmpl;
 686
 687     my $res = '';
 688     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 689         $res .= $1 if $1;
 690         $res .= ($data->{$3} || '-') if $2;
 691     }
 692     return $res;
 693 }
 694
 695 sub safe_print {
 696     my ($filename, $fh, $data) = @_;
 697
 698     return if !$data;
 699
 700     my $res = print $fh $data;
 701
 702     die "write to '$filename' failed\n" if !$res;
 703 }
 704
 705 sub debmirrors {
 706
 707     return {
 708         'at' => 'ftp.at.debian.org',
 709         'au' => 'ftp.au.debian.org',
 710         'be' => 'ftp.be.debian.org',
 711         'bg' => 'ftp.bg.debian.org',
 712         'br' => 'ftp.br.debian.org',
 713         'ca' => 'ftp.ca.debian.org',
 714         'ch' => 'ftp.ch.debian.org',
 715         'cl' => 'ftp.cl.debian.org',
 716         'cz' => 'ftp.cz.debian.org',
 717         'de' => 'ftp.de.debian.org',
 718         'dk' => 'ftp.dk.debian.org',
 719         'ee' => 'ftp.ee.debian.org',
 720         'es' => 'ftp.es.debian.org',
 721         'fi' => 'ftp.fi.debian.org',
 722         'fr' => 'ftp.fr.debian.org',
 723         'gr' => 'ftp.gr.debian.org',
 724         'hk' => 'ftp.hk.debian.org',
 725         'hr' => 'ftp.hr.debian.org',
 726         'hu' => 'ftp.hu.debian.org',
 727         'ie' => 'ftp.ie.debian.org',
 728         'is' => 'ftp.is.debian.org',
 729         'it' => 'ftp.it.debian.org',
 730         'jp' => 'ftp.jp.debian.org',
 731         'kr' => 'ftp.kr.debian.org',
 732         'mx' => 'ftp.mx.debian.org',
 733         'nl' => 'ftp.nl.debian.org',
 734         'no' => 'ftp.no.debian.org',
 735         'nz' => 'ftp.nz.debian.org',
 736         'pl' => 'ftp.pl.debian.org',
 737         'pt' => 'ftp.pt.debian.org',
 738         'ro' => 'ftp.ro.debian.org',
 739         'ru' => 'ftp.ru.debian.org',
 740         'se' => 'ftp.se.debian.org',
 741         'si' => 'ftp.si.debian.org',
 742         'sk' => 'ftp.sk.debian.org',
 743         'tr' => 'ftp.tr.debian.org',
 744         'tw' => 'ftp.tw.debian.org',
 745         'gb' => 'ftp.uk.debian.org',
 746         'us' => 'ftp.us.debian.org',
 747     };
 748 }
 749
 750 my $keymaphash =  {
 751     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 752     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 753     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 754     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 755     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 756     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 757     #'et'     => [], # Ethopia or Estonia ??
 758     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 759     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 760     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 761     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 762     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 763     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 764     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 765     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 766     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 767     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 768     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 769     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 770     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 771     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 772     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 773     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 774     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 775     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 776     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 777     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 778     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 779     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 780     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 781     #'th'     => [],
 782     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 783 };
 784
 785 my $kvmkeymaparray = [];
 786 foreach my $lc (sort keys %$keymaphash) {
 787     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 788 }
 789
 790 sub kvmkeymaps {
 791     return $keymaphash;
 792 }
 793
 794 sub kvmkeymaplist {
 795     return $kvmkeymaparray;
 796 }
 797
 798 sub extract_param {
 799     my ($param, $key) = @_;
 800
 801     my $res = $param->{$key};
 802     delete $param->{$key};
 803
 804     return $res;
 805 }
 806
 807 # Note: we use this to wait until vncterm/spiceterm is ready
 808 sub wait_for_vnc_port {
 809     my ($port, $family, $timeout) = @_;
 810
 811     $timeout = 5 if !$timeout;
 812     my $sleeptime = 0;
 813     my $starttime = [gettimeofday];
 814     my $elapsed;
 815
 816     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 817     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 818
 819     my $found;
 820     while (($elapsed = tv_interval($starttime)) < $timeout) {
 821         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 822         run_command($cmd, outfunc => sub {
 823             my $line = shift;
 824             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 825                 $found = 1 if ($port == $1);
 826             }
 827         });
 828         return 1 if $found;
 829         $sleeptime += 100000 if  $sleeptime < 1000000;
 830         usleep($sleeptime);
 831     }
 832
 833     die "Timeout while waiting for port '$port' to get ready!\n";
 834 }
 835
 836 sub next_unused_port {
 837     my ($range_start, $range_end, $family, $address) = @_;
 838
 839     # We use a file to register allocated ports.
 840     # Those registrations expires after $expiretime.
 841     # We use this to avoid race conditions between
 842     # allocation and use of ports.
 843
 844     my $filename = "/var/tmp/pve-reserved-ports";
 845
 846     my $code = sub {
 847
 848         my $expiretime = 5;
 849         my $ctime = time();
 850
 851         my $ports = {};
 852
 853         if (my $fh = IO::File->new ($filename, "r")) {
 854             while (my $line = <$fh>) {
 855                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 856                     my ($port, $timestamp) = ($1, $2);
 857                     if (($timestamp + $expiretime) > $ctime) {
 858                         $ports->{$port} = $timestamp; # not expired
 859                     }
 860                 }
 861             }
 862         }
 863
 864         my $newport;
 865         my %sockargs = (Listen => 5,
 866                         ReuseAddr => 1,
 867                         Family    => $family,
 868                         Proto     => IPPROTO_TCP,
 869                         GetAddrInfoFlags => 0);
 870         $sockargs{LocalAddr} = $address if defined($address);
 871
 872         for (my $p = $range_start; $p < $range_end; $p++) {
 873             next if $ports->{$p}; # reserved
 874
 875             $sockargs{LocalPort} = $p;
 876             my $sock = IO::Socket::IP->new(%sockargs);
 877
 878             if ($sock) {
 879                 close($sock);
 880                 $newport = $p;
 881                 $ports->{$p} = $ctime;
 882                 last;
 883             }
 884         }
 885
 886         my $data = "";
 887         foreach my $p (keys %$ports) {
 888             $data .= "$p $ports->{$p}\n";
 889         }
 890
 891         file_set_contents($filename, $data);
 892
 893         return $newport;
 894     };
 895
 896     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 897     die $@ if $@;
 898
 899     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 900
 901     return $p;
 902 }
 903
 904 sub next_migrate_port {
 905     my ($family, $address) = @_;
 906     return next_unused_port(60000, 60050, $family, $address);
 907 }
 908
 909 sub next_vnc_port {
 910     my ($family, $address) = @_;
 911     return next_unused_port(5900, 6000, $family, $address);
 912 }
 913
 914 sub spice_port_range {
 915     return (61000, 61999);
 916 }
 917
 918 sub next_spice_port {
 919     my ($family, $address) = @_;
 920     return next_unused_port(spice_port_range(), $family, $address);
 921 }
 922
 923 sub must_stringify {
 924         my ($value) = @_;
 925         eval { $value = "$value" };
 926         return "error turning value into a string: $@" if $@;
 927         return $value;
 928 }
 929
 930 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 931 # the $sub has to return a single scalar
 932 sub run_fork_with_timeout {
 933     my ($timeout, $sub) = @_;
 934
 935     my $res;
 936     my $error;
 937     my $pipe_out = IO::Pipe->new();
 938
 939     # disable pending alarms, save their remaining time
 940     my $prev_alarm = alarm 0;
 941
 942     # avoid leaving a zombie if the parent gets interrupted
 943     my $sig_received;
 944
 945     my $child = fork();
 946     if (!defined($child)) {
 947         die "fork failed: $!\n";
 948         return $res;
 949     }
 950
 951     if (!$child) {
 952         $pipe_out->writer();
 953
 954         eval {
 955             $res = $sub->();
 956             print {$pipe_out} encode_json({ result => $res });
 957             $pipe_out->flush();
 958         };
 959         if (my $err = $@) {
 960             print {$pipe_out} encode_json({ error => must_stringify($err) });
 961             $pipe_out->flush();
 962             POSIX::_exit(1);
 963         }
 964         POSIX::_exit(0);
 965     }
 966
 967     local $SIG{INT} = sub { $sig_received++; };
 968     local $SIG{TERM} = sub {
 969         $error //= "interrupted by unexpected signal\n";
 970         kill('TERM', $child);
 971     };
 972
 973     $pipe_out->reader();
 974
 975     my $readvalues = sub {
 976         local $/ = undef;
 977         my $child_res = decode_json(readline_nointr($pipe_out));
 978         $res = $child_res->{result};
 979         $error = $child_res->{error};
 980     };
 981     eval {
 982         if (defined($timeout)) {
 983             run_with_timeout($timeout, $readvalues);
 984         } else {
 985             $readvalues->();
 986         }
 987     };
 988     warn $@ if $@;
 989     $pipe_out->close();
 990     kill('KILL', $child);
 991     waitpid($child, 0);
 992
 993     alarm $prev_alarm;
 994     die "interrupted by unexpected signal\n" if $sig_received;
 995
 996     die $error if $error;
 997     return $res;
 998 }
 999
1000 sub run_fork {
1001     my ($code) = @_;
1002     return run_fork_with_timeout(undef, $code);
1003 }
1004
1005 # NOTE: NFS syscall can't be interrupted, so alarm does
1006 # not work to provide timeouts.
1007 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1008 # So fork() before using Filesys::Df
1009 sub df {
1010     my ($path, $timeout) = @_;
1011
1012     my $df = sub { return Filesys::Df::df($path, 1) };
1013
1014     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1015     warn $@ if $@;
1016
1017     # untaint, but be flexible: PB usage can result in scientific notation
1018     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1019         $res->@{qw(blocks used bavail)};
1020
1021     return {
1022         total => $blocks,
1023         used => $used,
1024         avail => $bavail,
1025     };
1026 }
1027
1028 sub du {
1029     my ($path, $timeout) = @_;
1030
1031     my $size;
1032
1033     $timeout //= 10;
1034
1035     my $parser = sub {
1036         my $line = shift;
1037
1038         if ($line =~ m/^(\d+)\s+total$/) {
1039             $size = $1;
1040         }
1041     };
1042
1043     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1044
1045     return $size;
1046 }
1047
1048 # UPID helper
1049 # We use this to uniquely identify a process.
1050 # An 'Unique Process ID' has the following format:
1051 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1052
1053 sub upid_encode {
1054     my $d = shift;
1055
1056     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1057     # more that 8 characters for pstart
1058     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1059                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1060                    $d->{user});
1061 }
1062
1063 sub upid_decode {
1064     my ($upid, $noerr) = @_;
1065
1066     my $res;
1067     my $filename;
1068
1069     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1070     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1071     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1072         $res->{node} = $1;
1073         $res->{pid} = hex($3);
1074         $res->{pstart} = hex($4);
1075         $res->{starttime} = hex($5);
1076         $res->{type} = $6;
1077         $res->{id} = $7;
1078         $res->{user} = $8;
1079
1080         my $subdir = substr($5, 7, 8);
1081         $filename = "$pvetaskdir/$subdir/$upid";
1082
1083     } else {
1084         return undef if $noerr;
1085         die "unable to parse worker upid '$upid'\n";
1086     }
1087
1088     return wantarray ? ($res, $filename) : $res;
1089 }
1090
1091 sub upid_open {
1092     my ($upid) = @_;
1093
1094     my ($task, $filename) = upid_decode($upid);
1095
1096     my $dirname = dirname($filename);
1097     make_path($dirname);
1098
1099     my $wwwid = getpwnam('www-data') ||
1100         die "getpwnam failed";
1101
1102     my $perm = 0640;
1103
1104     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1105         die "unable to create output file '$filename' - $!\n";
1106     chown $wwwid, -1, $outfh;
1107
1108     return $outfh;
1109 };
1110
1111 sub upid_read_status {
1112     my ($upid) = @_;
1113
1114     my ($task, $filename) = upid_decode($upid);
1115     my $fh = IO::File->new($filename, "r");
1116     return "unable to open file - $!" if !$fh;
1117     my $maxlen = 4096;
1118     sysseek($fh, -$maxlen, 2);
1119     my $readbuf = '';
1120     my $br = sysread($fh, $readbuf, $maxlen);
1121     close($fh);
1122     if ($br) {
1123         return "unable to extract last line"
1124             if $readbuf !~ m/\n?(.+)$/;
1125         my $line = $1;
1126         if ($line =~ m/^TASK OK$/) {
1127             return 'OK';
1128         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1129             return $1;
1130         } else {
1131             return "unexpected status";
1132         }
1133     }
1134     return "unable to read tail (got $br bytes)";
1135 }
1136
1137 # useful functions to store comments in config files
1138 sub encode_text {
1139     my ($text) = @_;
1140
1141     # all control and hi-bit characters, and ':'
1142     my $unsafe = "^\x20-\x39\x3b-\x7e";
1143     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1144 }
1145
1146 sub decode_text {
1147     my ($data) = @_;
1148
1149     return Encode::decode("utf8", uri_unescape($data));
1150 }
1151
1152 # depreciated - do not use!
1153 # we now decode all parameters by default
1154 sub decode_utf8_parameters {
1155     my ($param) = @_;
1156
1157     foreach my $p (qw(comment description firstname lastname)) {
1158         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1159     }
1160
1161     return $param;
1162 }
1163
1164 sub random_ether_addr {
1165     my ($prefix) = @_;
1166
1167     my ($seconds, $microseconds) = gettimeofday;
1168
1169     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1170
1171     # clear multicast, set local id
1172     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1173
1174     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1175     if (defined($prefix)) {
1176         $addr = uc($prefix) . substr($addr, length($prefix));
1177     }
1178     return $addr;
1179 }
1180
1181 sub shellquote {
1182     my $str = shift;
1183
1184     return String::ShellQuote::shell_quote($str);
1185 }
1186
1187 sub cmd2string {
1188     my ($cmd) = @_;
1189
1190     die "no arguments" if !$cmd;
1191
1192     return $cmd if !ref($cmd);
1193
1194     my @qa = ();
1195     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1196
1197     return join (' ', @qa);
1198 }
1199
1200 # split an shell argument string into an array,
1201 sub split_args {
1202     my ($str) = @_;
1203
1204     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1205 }
1206
1207 sub dump_logfile {
1208     my ($filename, $start, $limit, $filter) = @_;
1209
1210     my $lines = [];
1211     my $count = 0;
1212
1213     my $fh = IO::File->new($filename, "r");
1214     if (!$fh) {
1215         $count++;
1216         push @$lines, { n => $count, t => "unable to open file - $!"};
1217         return ($count, $lines);
1218     }
1219
1220     $start = 0 if !$start;
1221     $limit = 50 if !$limit;
1222
1223     my $line;
1224
1225     if ($filter) {
1226         # duplicate code, so that we do not slow down normal path
1227         while (defined($line = <$fh>)) {
1228             next if $line !~ m/$filter/;
1229             next if $count++ < $start;
1230             next if $limit <= 0;
1231             chomp $line;
1232             push @$lines, { n => $count, t => $line};
1233             $limit--;
1234         }
1235     } else {
1236         while (defined($line = <$fh>)) {
1237             next if $count++ < $start;
1238             next if $limit <= 0;
1239             chomp $line;
1240             push @$lines, { n => $count, t => $line};
1241             $limit--;
1242         }
1243     }
1244
1245     close($fh);
1246
1247     # HACK: ExtJS store.guaranteeRange() does not like empty array
1248     # so we add a line
1249     if (!$count) {
1250         $count++;
1251         push @$lines, { n => $count, t => "no content"};
1252     }
1253
1254     return ($count, $lines);
1255 }
1256
1257 sub dump_journal {
1258     my ($start, $limit, $since, $until, $service) = @_;
1259
1260     my $lines = [];
1261     my $count = 0;
1262
1263     $start = 0 if !$start;
1264     $limit = 50 if !$limit;
1265
1266     my $parser = sub {
1267         my $line = shift;
1268
1269         return if $count++ < $start;
1270         return if $limit <= 0;
1271         push @$lines, { n => int($count), t => $line};
1272         $limit--;
1273     };
1274
1275     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1276
1277     push @$cmd, '--unit', $service if $service;
1278     push @$cmd, '--since', $since if $since;
1279     push @$cmd, '--until', $until if $until;
1280     run_command($cmd, outfunc => $parser);
1281
1282     # HACK: ExtJS store.guaranteeRange() does not like empty array
1283     # so we add a line
1284     if (!$count) {
1285         $count++;
1286         push @$lines, { n => $count, t => "no content"};
1287     }
1288
1289     return ($count, $lines);
1290 }
1291
1292 sub dir_glob_regex {
1293     my ($dir, $regex) = @_;
1294
1295     my $dh = IO::Dir->new ($dir);
1296     return wantarray ? () : undef if !$dh;
1297
1298     while (defined(my $tmp = $dh->read)) {
1299         if (my @res = $tmp =~ m/^($regex)$/) {
1300             $dh->close;
1301             return wantarray ? @res : $tmp;
1302         }
1303     }
1304     $dh->close;
1305
1306     return wantarray ? () : undef;
1307 }
1308
1309 sub dir_glob_foreach {
1310     my ($dir, $regex, $func) = @_;
1311
1312     my $dh = IO::Dir->new ($dir);
1313     if (defined $dh) {
1314         while (defined(my $tmp = $dh->read)) {
1315             if (my @res = $tmp =~ m/^($regex)$/) {
1316                 &$func (@res);
1317             }
1318         }
1319     }
1320 }
1321
1322 sub assert_if_modified {
1323     my ($digest1, $digest2) = @_;
1324
1325     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1326         die "detected modified configuration - file changed by other user? Try again.\n";
1327     }
1328 }
1329
1330 # Digest for short strings
1331 # like FNV32a, but we only return 31 bits (positive numbers)
1332 sub fnv31a {
1333     my ($string) = @_;
1334
1335     my $hval = 0x811c9dc5;
1336
1337     foreach my $c (unpack('C*', $string)) {
1338         $hval ^= $c;
1339         $hval += (
1340             (($hval << 1) ) +
1341             (($hval << 4) ) +
1342             (($hval << 7) ) +
1343             (($hval << 8) ) +
1344             (($hval << 24) ) );
1345         $hval = $hval & 0xffffffff;
1346     }
1347     return $hval & 0x7fffffff;
1348 }
1349
1350 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1351
1352 sub unpack_sockaddr_in46 {
1353     my ($sin) = @_;
1354     my $family = Socket::sockaddr_family($sin);
1355     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1356                                              : Socket::unpack_sockaddr_in($sin));
1357     return ($family, $port, $host);
1358 }
1359
1360 sub getaddrinfo_all {
1361     my ($hostname, @opts) = @_;
1362     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1363                   @opts );
1364     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1365     die "failed to get address info for: $hostname: $err\n" if $err;
1366     return @res;
1367 }
1368
1369 sub get_host_address_family {
1370     my ($hostname, $socktype) = @_;
1371     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1372     return $res[0]->{family};
1373 }
1374
1375 # get the fully qualified domain name of a host
1376 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1377 # given a nodename as a parameter
1378 sub get_fqdn {
1379     my ($nodename) = @_;
1380
1381     my $hints = {
1382         flags => AI_CANONNAME,
1383         socktype => SOCK_DGRAM
1384     };
1385
1386     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1387
1388     die "getaddrinfo: $err" if $err;
1389
1390     return $addrs[0]->{canonname};
1391 }
1392
1393 # Parses any sane kind of host, or host+port pair:
1394 # The port is always optional and thus may be undef.
1395 sub parse_host_and_port {
1396     my ($address) = @_;
1397     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1398         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1399         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1400     {
1401         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1402     }
1403     return; # nothing
1404 }
1405
1406 sub setresuid($$$) {
1407     my ($ruid, $euid, $suid) = @_;
1408     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1409 }
1410
1411 sub unshare($) {
1412     my ($flags) = @_;
1413     return 0 == syscall(PVE::Syscall::unshare, $flags);
1414 }
1415
1416 sub setns($$) {
1417     my ($fileno, $nstype) = @_;
1418     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1419 }
1420
1421 sub syncfs($) {
1422     my ($fileno) = @_;
1423     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1424 }
1425
1426 sub fsync($) {
1427     my ($fileno) = @_;
1428     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1429 }
1430
1431 sub sync_mountpoint {
1432     my ($path) = @_;
1433     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1434     my $result = syncfs(fileno($fd));
1435     close($fd);
1436     return $result;
1437 }
1438
1439 # support sending multi-part mail messages with a text and or a HTML part
1440 # mailto may be a single email string or an array of receivers
1441 sub sendmail {
1442     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1443     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1444
1445     $mailto = [ $mailto ] if !ref($mailto);
1446
1447     foreach (@$mailto) {
1448         die "illegal character in mailto address\n"
1449             if ($_ =~ $mail_re);
1450     }
1451
1452     my $rcvrtxt = join (', ', @$mailto);
1453
1454     $mailfrom = $mailfrom || "root";
1455     die "illegal character in mailfrom address\n"
1456         if $mailfrom =~ $mail_re;
1457
1458     $author = $author || 'Proxmox VE';
1459
1460     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, "--", @$mailto) ||
1461         die "unable to open 'sendmail' - $!";
1462
1463     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1464     my $boundary = "----_=_NextPart_001_".int(time).$$;
1465
1466     print MAIL "Content-Type: multipart/alternative;\n";
1467     print MAIL "\tboundary=\"$boundary\"\n";
1468     print MAIL "MIME-Version: 1.0\n";
1469
1470     print MAIL "FROM: $author <$mailfrom>\n";
1471     print MAIL "TO: $rcvrtxt\n";
1472     print MAIL "SUBJECT: $subject\n";
1473     print MAIL "\n";
1474     print MAIL "This is a multi-part message in MIME format.\n\n";
1475     print MAIL "--$boundary\n";
1476
1477     if (defined($text)) {
1478         print MAIL "Content-Type: text/plain;\n";
1479         print MAIL "\tcharset=\"UTF8\"\n";
1480         print MAIL "Content-Transfer-Encoding: 8bit\n";
1481         print MAIL "\n";
1482
1483         # avoid 'remove extra line breaks' issue (MS Outlook)
1484         my $fill = '  ';
1485         $text =~ s/^/$fill/gm;
1486
1487         print MAIL $text;
1488
1489         print MAIL "\n--$boundary\n";
1490     }
1491
1492     if (defined($html)) {
1493         print MAIL "Content-Type: text/html;\n";
1494         print MAIL "\tcharset=\"UTF8\"\n";
1495         print MAIL "Content-Transfer-Encoding: 8bit\n";
1496         print MAIL "\n";
1497
1498         print MAIL $html;
1499
1500         print MAIL "\n--$boundary--\n";
1501     }
1502
1503     close(MAIL);
1504 }
1505
1506 sub tempfile {
1507     my ($perm, %opts) = @_;
1508
1509     # default permissions are stricter than with file_set_contents
1510     $perm = 0600 if !defined($perm);
1511
1512     my $dir = $opts{dir} // '/run';
1513     my $mode = $opts{mode} // O_RDWR;
1514     $mode |= O_EXCL if !$opts{allow_links};
1515
1516     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1517     if (!$fh && $! == EOPNOTSUPP) {
1518         $dir = '/tmp' if !defined($opts{dir});
1519         $dir .= "/.tmpfile.$$";
1520         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1521         unlink($dir) if $fh;
1522     }
1523     die "failed to create tempfile: $!\n" if !$fh;
1524     return $fh;
1525 }
1526
1527 sub tempfile_contents {
1528     my ($data, $perm, %opts) = @_;
1529
1530     my $fh = tempfile($perm, %opts);
1531     eval {
1532         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1533         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1534     };
1535     if (my $err = $@) {
1536         close $fh;
1537         die $err;
1538     }
1539
1540     return ("/proc/$$/fd/".$fh->fileno, $fh);
1541 }
1542
1543 sub validate_ssh_public_keys {
1544     my ($raw) = @_;
1545     my @lines = split(/\n/, $raw);
1546
1547     foreach my $line (@lines) {
1548         next if $line =~ m/^\s*$/;
1549         eval {
1550             my ($filename, $handle) = tempfile_contents($line);
1551             run_command(["ssh-keygen", "-l", "-f", $filename],
1552                         outfunc => sub {}, errfunc => sub {});
1553         };
1554         die "SSH public key validation error\n" if $@;
1555     }
1556 }
1557
1558 sub openat($$$;$) {
1559     my ($dirfd, $pathname, $flags, $mode) = @_;
1560     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1561     return undef if $fd < 0;
1562     # sysopen() doesn't deal with numeric file descriptors apparently
1563     # so we need to convert to a mode string for IO::Handle->new_from_fd
1564     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1565     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1566     return $handle if $handle;
1567     my $err = $!; # save error before closing the raw fd
1568     syscall(PVE::Syscall::close, $fd); # close
1569     $! = $err;
1570     return undef;
1571 }
1572
1573 sub mkdirat($$$) {
1574     my ($dirfd, $name, $mode) = @_;
1575     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1576 }
1577
1578 sub fchownat($$$$$) {
1579     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1580     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1581 }
1582
1583 my $salt_starter = time();
1584
1585 sub encrypt_pw {
1586     my ($pw) = @_;
1587
1588     $salt_starter++;
1589     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1590
1591     # crypt does not want '+' in salt (see 'man crypt')
1592     $salt =~ s/\+/X/g;
1593
1594     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1595 }
1596
1597 # intended usage: convert_size($val, "kb" => "gb")
1598 # we round up to the next integer by default
1599 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1600 # use $no_round_up to switch this off, above example would then return 0
1601 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1602 # (0 if $no_round_up is true)
1603 # allowed formats for value:
1604 # 1234
1605 # 1234.
1606 # 1234.1234
1607 # .1234
1608 sub convert_size {
1609     my ($value, $from, $to, $no_round_up) = @_;
1610
1611     my $units = {
1612         b  => 0,
1613         kb => 1,
1614         mb => 2,
1615         gb => 3,
1616         tb => 4,
1617         pb => 5,
1618     };
1619
1620     die "no value given"
1621         if !defined($value) || $value eq "";
1622
1623     $from = lc($from // ''); $to = lc($to // '');
1624     die "unknown 'from' and/or 'to' units ($from => $to)"
1625         if !defined($units->{$from}) || !defined($units->{$to});
1626
1627     die "value '$value' is not a valid, positive number"
1628         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1629
1630     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1631
1632     $value *= 2**$shift_amount;
1633     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1634
1635     return int($value);
1636 }
1637
1638 # uninterruptible readline
1639 # retries on EINTR
1640 sub readline_nointr {
1641     my ($fh) = @_;
1642     my $line;
1643     while (1) {
1644         $line = <$fh>;
1645         last if defined($line) || ($! != EINTR);
1646     }
1647     return $line;
1648 }
1649
1650 my $host_arch;
1651 sub get_host_arch {
1652     $host_arch = (POSIX::uname())[4] if !$host_arch;
1653     return $host_arch;
1654 }
1655
1656 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1657 sub dev_t_major($) {
1658     my ($dev_t) = @_;
1659     return (int($dev_t) & 0xfff00) >> 8;
1660 }
1661
1662 sub dev_t_minor($) {
1663     my ($dev_t) = @_;
1664     $dev_t = int($dev_t);
1665     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1666 }
1667
1668 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1669 # Returns the intersection of elements as a single array [a b]
1670 sub array_intersect {
1671     my ($arrays) = @_;
1672
1673     if (!ref($arrays->[0])) {
1674         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1675     }
1676
1677     return [] if scalar(@$arrays) == 0;
1678     return $arrays->[0] if scalar(@$arrays) == 1;
1679
1680     my $array_unique = sub {
1681         my %seen = ();
1682         return grep { ! $seen{ $_ }++ } @_;
1683     };
1684
1685     # base idea is to get all unique members from the first array, then
1686     # check the common elements with the next (uniquely made) one, only keep
1687     # those. Repeat for every array and at the end we only have those left
1688     # which exist in all arrays
1689     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1690     for my $i (1 .. $#$arrays) {
1691         my %count = ();
1692         # $return_arr is already unique, explicit at before the loop, implicit below.
1693         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1694             $count{$element}++;
1695         }
1696         $return_arr = [];
1697         foreach my $element (keys %count) {
1698             push @$return_arr, $element if $count{$element} > 1;
1699         }
1700         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1701     }
1702
1703     return $return_arr;
1704 }
1705
1706 sub open_tree($$$) {
1707     my ($dfd, $pathname, $flags) = @_;
1708     return PVE::Syscall::file_handle_result(syscall(
1709         &PVE::Syscall::open_tree,
1710         $dfd,
1711         $pathname,
1712         $flags,
1713     ));
1714 }
1715
1716 sub move_mount($$$$$) {
1717     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1718     return 0 == syscall(
1719         &PVE::Syscall::move_mount,
1720         $from_dirfd,
1721         $from_pathname,
1722         $to_dirfd,
1723         $to_pathname,
1724         $flags,
1725     );
1726 }
1727
1728 sub fsopen($$) {
1729     my ($fsname, $flags) = @_;
1730     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
1731 }
1732
1733 sub fsmount($$$) {
1734     my ($fd, $flags, $mount_attrs) = @_;
1735     return PVE::Syscall::file_handle_result(syscall(
1736         &PVE::Syscall::fsmount,
1737         $fd,
1738         $flags,
1739         $mount_attrs,
1740     ));
1741 }
1742
1743 sub fspick($$$) {
1744     my ($dirfd, $pathname, $flags) = @_;
1745     return PVE::Syscall::file_handle_result(syscall(
1746         &PVE::Syscall::fspick,
1747         $dirfd,
1748         $pathname,
1749         $flags,
1750     ));
1751 }
1752
1753 sub fsconfig($$$$$) {
1754     my ($fd, $command, $key, $value, $aux) = @_;
1755     return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
1756 }
1757
1758 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1759 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1760 sub mount($$$$$) {
1761     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1762     return 0 == syscall(
1763         &PVE::Syscall::mount,
1764         $source,
1765         $target,
1766         $filesystemtype,
1767         $mountflags,
1768         $data,
1769     );
1770 }
1771
1772 sub safe_compare {
1773     my ($left, $right, $cmp) = @_;
1774
1775     return 0 if !defined($left) && !defined($right);
1776     return -1 if !defined($left);
1777     return 1 if !defined($right);
1778     return $cmp->($left, $right);
1779 }
1780
1781 1;