da7da5d36146a51a5d95276faaa822284ecaf91d
[pve-common.git] / src / PVE / Tools.pm
1 package PVE::Tools;
2
3 use strict;
4 use warnings;
5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
6 use IO::Socket::IP;
7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
8               IPPROTO_TCP);
9 use IO::Select;
10 use File::Basename;
11 use File::Path qw(make_path);
12 use Filesys::Df (); # don't overwrite our df()
13 use IO::Pipe;
14 use IO::File;
15 use IO::Dir;
16 use IO::Handle;
17 use IPC::Open3;
18 use Fcntl qw(:DEFAULT :flock);
19 use base 'Exporter';
20 use URI::Escape;
21 use Encode;
22 use Digest::SHA;
23 use Text::ParseWords;
24 use String::ShellQuote;
25 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
26 use Net::DBus qw(dbus_uint32 dbus_uint64);
27 use Net::DBus::Callback;
28 use Net::DBus::Reactor;
29 use Scalar::Util 'weaken';
30 use PVE::Syscall;
31
32 # avoid warning when parsing long hex values with hex()
33 no warnings 'portable'; # Support for 64-bit ints required
34
35 our @EXPORT_OK = qw(
36 $IPV6RE
37 $IPV4RE
38 lock_file
39 lock_file_full
40 run_command
41 file_set_contents
42 file_get_contents
43 file_read_firstline
44 dir_glob_regex
45 dir_glob_foreach
46 split_list
47 template_replace
48 safe_print
49 trim
50 extract_param
51 file_copy
52 O_PATH
53 O_TMPFILE
54 );
55
56 my $pvelogdir = "/var/log/pve";
57 my $pvetaskdir = "$pvelogdir/tasks";
58
59 mkdir $pvelogdir;
60 mkdir $pvetaskdir;
61
62 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
63 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
64 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
65 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
66
67 our $IPV6RE = "(?:" .
68     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
69     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
70     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
71     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
72     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
73     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
74     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
75     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
76     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
77
78 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
79
80 use constant {CLONE_NEWNS   => 0x00020000,
81               CLONE_NEWUTS  => 0x04000000,
82               CLONE_NEWIPC  => 0x08000000,
83               CLONE_NEWUSER => 0x10000000,
84               CLONE_NEWPID  => 0x20000000,
85               CLONE_NEWNET  => 0x40000000};
86
87 use constant {O_PATH    => 0x00200000,
88               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
89
90 sub run_with_timeout {
91     my ($timeout, $code, @param) = @_;
92
93     die "got timeout\n" if $timeout <= 0;
94
95     my $prev_alarm = alarm 0; # suspend outer alarm early
96
97     my $sigcount = 0;
98
99     my $res;
100
101     eval {
102         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
103         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
104         local $SIG{__DIE__};   # see SA bug 4631
105
106         alarm($timeout);
107
108         eval { $res = &$code(@param); };
109
110         alarm(0); # avoid race conditions
111
112         die $@ if $@;
113     };
114
115     my $err = $@;
116
117     alarm $prev_alarm;
118
119     # this shouldn't happen anymore?
120     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
121
122     die $err if $err;
123
124     return $res;
125 }
126
127 # flock: we use one file handle per process, so lock file
128 # can be nested multiple times and succeeds for the same process.
129 #
130 # Since this is the only way we lock now and we don't have the old
131 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
132 # count how deep we're nesting. Therefore this hash now stores a weak reference
133 # to a boolean telling us whether we already have a lock.
134
135 my $lock_handles =  {};
136
137 sub lock_file_full {
138     my ($filename, $timeout, $shared, $code, @param) = @_;
139
140     $timeout = 10 if !$timeout;
141
142     my $mode = $shared ? LOCK_SH : LOCK_EX;
143
144     my $lockhash = ($lock_handles->{$$} //= {});
145
146     # Returns a locked file handle.
147     my $get_locked_file = sub {
148         my $fh = IO::File->new(">>$filename")
149             or die "can't open file - $!\n";
150
151         if (!flock($fh, $mode|LOCK_NB)) {
152             print STDERR "trying to acquire lock...";
153             my $success;
154             while(1) {
155                 $success = flock($fh, $mode);
156                 # try again on EINTR (see bug #273)
157                 if ($success || ($! != EINTR)) {
158                     last;
159                 }
160             }
161             if (!$success) {
162                 print STDERR " failed\n";
163                 die "can't acquire lock '$filename' - $!\n";
164             }
165             print STDERR " OK\n";
166         }
167
168         return $fh;
169     };
170
171     my $res;
172     my $checkptr = $lockhash->{$filename};
173     my $check = 0; # This must not go out of scope before running the code.
174     my $local_fh; # This must stay local
175     if (!$checkptr || !$$checkptr) {
176         # We cannot create a weak reference in a single atomic step, so we first
177         # create a false-value, then create a reference to it, then weaken it,
178         # and after successfully locking the file we change the boolean value.
179         #
180         # The reason for this is that if an outer SIGALRM throws an exception
181         # between creating the reference and weakening it, a subsequent call to
182         # lock_file_full() will see a leftover full reference to a valid
183         # variable. This variable must be 0 in order for said call to attempt to
184         # lock the file anew.
185         #
186         # An externally triggered exception elsewhere in the code will cause the
187         # weak reference to become 'undef', and since the file handle is only
188         # stored in the local scope in $local_fh, the file will be closed by
189         # perl's cleanup routines as well.
190         #
191         # This still assumes that an IO::File handle can properly deal with such
192         # exceptions thrown during its own destruction, but that's up to perls
193         # guts now.
194         $lockhash->{$filename} = \$check;
195         weaken $lockhash->{$filename};
196         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
197         if ($@) {
198             $@ = "can't lock file '$filename' - $@";
199             return undef;
200         }
201         $check = 1;
202     }
203     $res = eval { &$code(@param); };
204     return undef if $@;
205     return $res;
206 }
207
208
209 sub lock_file {
210     my ($filename, $timeout, $code, @param) = @_;
211
212     return lock_file_full($filename, $timeout, 0, $code, @param);
213 }
214
215 sub file_set_contents {
216     my ($filename, $data, $perm)  = @_;
217
218     $perm = 0644 if !defined($perm);
219
220     my $tmpname = "$filename.tmp.$$";
221
222     eval {
223         my ($fh, $tries) = (undef, 0);
224         while (!$fh && $tries++ < 3) {
225             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
226             if (!$fh && $! == EEXIST) {
227                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
228             }
229         }
230         die "unable to open file '$tmpname' - $!\n" if !$fh;
231         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
232         die "closing file '$tmpname' failed - $!\n" unless close $fh;
233     };
234     my $err = $@;
235
236     if ($err) {
237         unlink $tmpname;
238         die $err;
239     }
240
241     if (!rename($tmpname, $filename)) {
242         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
243         unlink $tmpname;
244         die $msg;
245     }
246 }
247
248 sub file_get_contents {
249     my ($filename, $max) = @_;
250
251     my $fh = IO::File->new($filename, "r") ||
252         die "can't open '$filename' - $!\n";
253
254     my $content = safe_read_from($fh, $max, 0, $filename);
255
256     close $fh;
257
258     return $content;
259 }
260
261 sub file_copy {
262     my ($filename, $dst, $max, $perm) = @_;
263
264     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
265 }
266
267 sub file_read_firstline {
268     my ($filename) = @_;
269
270     my $fh = IO::File->new ($filename, "r");
271     return undef if !$fh;
272     my $res = <$fh>;
273     chomp $res if $res;
274     $fh->close;
275     return $res;
276 }
277
278 sub safe_read_from {
279     my ($fh, $max, $oneline, $filename) = @_;
280
281     $max = 32768 if !$max;
282
283     my $subject = defined($filename) ? "file '$filename'" : 'input';
284
285     my $br = 0;
286     my $input = '';
287     my $count;
288     while ($count = sysread($fh, $input, 8192, $br)) {
289         $br += $count;
290         die "$subject too long - aborting\n" if $br > $max;
291         if ($oneline && $input =~ m/^(.*)\n/) {
292             $input = $1;
293             last;
294         }
295     }
296     die "unable to read $subject - $!\n" if !defined($count);
297
298     return $input;
299 }
300
301 # The $cmd parameter can be:
302 #  -) a string
303 #    This is generally executed by passing it to the shell with the -c option.
304 #    However, it can be executed in one of two ways, depending on whether
305 #    there's a pipe involved:
306 #      *) with pipe: passed explicitly to bash -c, prefixed with:
307 #          set -o pipefail &&
308 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
309 #      (Note that this may result in two different syntax requirements!)
310 #      FIXME?
311 #  -) an array of arguments (strings)
312 #    Will be executed without interference from a shell. (Parameters are passed
313 #    as is, no escape sequences of strings will be touched.)
314 #  -) an array of arrays
315 #    Each array represents a command, and each command's output is piped into
316 #    the following command's standard input.
317 #    For this a shell command string is created with pipe symbols between each
318 #    command.
319 #    Each command is a list of strings meant to end up in the final command
320 #    unchanged. In order to achieve this, every argument is shell-quoted.
321 #    Quoting can be disabled for a particular argument by turning it into a
322 #    reference, this allows inserting arbitrary shell options.
323 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
324 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
325 #    will literally print: hello >/dev/null
326 sub run_command {
327     my ($cmd, %param) = @_;
328
329     my $old_umask;
330     my $cmdstr;
331
332     if (my $ref = ref($cmd)) {
333         if (ref($cmd->[0])) {
334             $cmdstr = 'set -o pipefail && ';
335             my $pipe = '';
336             foreach my $command (@$cmd) {
337                 # concatenate quoted parameters
338                 # strings which are passed by reference are NOT shell quoted
339                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
340                 $pipe = ' | ';
341             }
342             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
343         } else {
344             $cmdstr = cmd2string($cmd);
345         }
346     } else {
347         $cmdstr = $cmd;
348         if ($cmd =~ m/\|/) {
349             # see 'man bash' for option pipefail
350             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
351         } else {
352             $cmd = [ $cmd ];
353         }
354     }
355
356     my $errmsg;
357     my $laststderr;
358     my $timeout;
359     my $oldtimeout;
360     my $pid;
361     my $exitcode = -1;
362
363     my $outfunc;
364     my $errfunc;
365     my $logfunc;
366     my $input;
367     my $output;
368     my $afterfork;
369     my $noerr;
370     my $keeplocale;
371
372     eval {
373
374         foreach my $p (keys %param) {
375             if ($p eq 'timeout') {
376                 $timeout = $param{$p};
377             } elsif ($p eq 'umask') {
378                 $old_umask = umask($param{$p});
379             } elsif ($p eq 'errmsg') {
380                 $errmsg = $param{$p};
381             } elsif ($p eq 'input') {
382                 $input = $param{$p};
383             } elsif ($p eq 'output') {
384                 $output = $param{$p};
385             } elsif ($p eq 'outfunc') {
386                 $outfunc = $param{$p};
387             } elsif ($p eq 'errfunc') {
388                 $errfunc = $param{$p};
389             } elsif ($p eq 'logfunc') {
390                 $logfunc = $param{$p};
391             } elsif ($p eq 'afterfork') {
392                 $afterfork = $param{$p};
393             } elsif ($p eq 'noerr') {
394                 $noerr = $param{$p};
395             } elsif ($p eq 'keeplocale') {
396                 $keeplocale = $param{$p};
397             } else {
398                 die "got unknown parameter '$p' for run_command\n";
399             }
400         }
401
402         if ($errmsg) {
403             my $origerrfunc = $errfunc;
404             $errfunc = sub {
405                 if ($laststderr) {
406                     if ($origerrfunc) {
407                         &$origerrfunc("$laststderr\n");
408                     } else {
409                         print STDERR "$laststderr\n" if $laststderr;
410                     }
411                 }
412                 $laststderr = shift;
413             };
414         }
415
416         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
417         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
418         my $error  = IO::File->new();
419
420         my $orig_pid = $$;
421
422         eval {
423             local $ENV{LC_ALL} = 'C' if !$keeplocale;
424
425             # suppress LVM warnings like: "File descriptor 3 left open";
426             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
427
428             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
429
430             # if we pipe fron STDIN, open3 closes STDIN, so we we
431             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
432             # as soon as we open a new file.
433             # to avoid that we open /dev/null
434             if (!ref($writer) && !defined(fileno(STDIN))) {
435                 POSIX::close(0);
436                 open(STDIN, "</dev/null");
437             }
438         };
439
440         my $err = $@;
441
442         # catch exec errors
443         if ($orig_pid != $$) {
444             warn "ERROR: $err";
445             POSIX::_exit (1);
446             kill ('KILL', $$);
447         }
448
449         die $err if $err;
450
451         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
452         $oldtimeout = alarm($timeout) if $timeout;
453
454         &$afterfork() if $afterfork;
455
456         if (ref($writer)) {
457             print $writer $input if defined $input;
458             close $writer;
459         }
460
461         my $select = new IO::Select;
462         $select->add($reader) if ref($reader);
463         $select->add($error);
464
465         my $outlog = '';
466         my $errlog = '';
467
468         my $starttime = time();
469
470         while ($select->count) {
471             my @handles = $select->can_read(1);
472
473             foreach my $h (@handles) {
474                 my $buf = '';
475                 my $count = sysread ($h, $buf, 4096);
476                 if (!defined ($count)) {
477                     my $err = $!;
478                     kill (9, $pid);
479                     waitpid ($pid, 0);
480                     die $err;
481                 }
482                 $select->remove ($h) if !$count;
483                 if ($h eq $reader) {
484                     if ($outfunc || $logfunc) {
485                         eval {
486                             $outlog .= $buf;
487                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
488                                 my $line = $1;
489                                 &$outfunc($line) if $outfunc;
490                                 &$logfunc($line) if $logfunc;
491                             }
492                         };
493                         my $err = $@;
494                         if ($err) {
495                             kill (9, $pid);
496                             waitpid ($pid, 0);
497                             die $err;
498                         }
499                     } else {
500                         print $buf;
501                         *STDOUT->flush();
502                     }
503                 } elsif ($h eq $error) {
504                     if ($errfunc || $logfunc) {
505                         eval {
506                             $errlog .= $buf;
507                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
508                                 my $line = $1;
509                                 &$errfunc($line) if $errfunc;
510                                 &$logfunc($line) if $logfunc;
511                             }
512                         };
513                         my $err = $@;
514                         if ($err) {
515                             kill (9, $pid);
516                             waitpid ($pid, 0);
517                             die $err;
518                         }
519                     } else {
520                         print STDERR $buf;
521                         *STDERR->flush();
522                     }
523                 }
524             }
525         }
526
527         &$outfunc($outlog) if $outfunc && $outlog;
528         &$logfunc($outlog) if $logfunc && $outlog;
529
530         &$errfunc($errlog) if $errfunc && $errlog;
531         &$logfunc($errlog) if $logfunc && $errlog;
532
533         waitpid ($pid, 0);
534
535         if ($? == -1) {
536             die "failed to execute\n";
537         } elsif (my $sig = ($? & 127)) {
538             die "got signal $sig\n";
539         } elsif ($exitcode = ($? >> 8)) {
540             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
541                 if ($errmsg && $laststderr) {
542                     my $lerr = $laststderr;
543                     $laststderr = undef;
544                     die "$lerr\n";
545                 }
546                 die "exit code $exitcode\n";
547             }
548         }
549
550         alarm(0);
551     };
552
553     my $err = $@;
554
555     alarm(0);
556
557     if ($errmsg && $laststderr) {
558         &$errfunc(undef); # flush laststderr
559     }
560
561     umask ($old_umask) if defined($old_umask);
562
563     alarm($oldtimeout) if $oldtimeout;
564
565     if ($err) {
566         if ($pid && ($err eq "got timeout\n")) {
567             kill (9, $pid);
568             waitpid ($pid, 0);
569             die "command '$cmdstr' failed: $err";
570         }
571
572         if ($errmsg) {
573             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
574             die "$errmsg: $err";
575         } elsif(!$noerr) {
576             die "command '$cmdstr' failed: $err";
577         }
578     }
579
580     return $exitcode;
581 }
582
583 sub split_list {
584     my $listtxt = shift || '';
585
586     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
587
588     $listtxt =~ s/[,;]/ /g;
589     $listtxt =~ s/^\s+//;
590
591     my @data = split (/\s+/, $listtxt);
592
593     return @data;
594 }
595
596 sub trim {
597     my $txt = shift;
598
599     return $txt if !defined($txt);
600
601     $txt =~ s/^\s+//;
602     $txt =~ s/\s+$//;
603
604     return $txt;
605 }
606
607 # simple uri templates like "/vms/{vmid}"
608 sub template_replace {
609     my ($tmpl, $data) = @_;
610
611     return $tmpl if !$tmpl;
612
613     my $res = '';
614     while ($tmpl =~ m/([^{]+)?({([^}]+)})?/g) {
615         $res .= $1 if $1;
616         $res .= ($data->{$3} || '-') if $2;
617     }
618     return $res;
619 }
620
621 sub safe_print {
622     my ($filename, $fh, $data) = @_;
623
624     return if !$data;
625
626     my $res = print $fh $data;
627
628     die "write to '$filename' failed\n" if !$res;
629 }
630
631 sub debmirrors {
632
633     return {
634         'at' => 'ftp.at.debian.org',
635         'au' => 'ftp.au.debian.org',
636         'be' => 'ftp.be.debian.org',
637         'bg' => 'ftp.bg.debian.org',
638         'br' => 'ftp.br.debian.org',
639         'ca' => 'ftp.ca.debian.org',
640         'ch' => 'ftp.ch.debian.org',
641         'cl' => 'ftp.cl.debian.org',
642         'cz' => 'ftp.cz.debian.org',
643         'de' => 'ftp.de.debian.org',
644         'dk' => 'ftp.dk.debian.org',
645         'ee' => 'ftp.ee.debian.org',
646         'es' => 'ftp.es.debian.org',
647         'fi' => 'ftp.fi.debian.org',
648         'fr' => 'ftp.fr.debian.org',
649         'gr' => 'ftp.gr.debian.org',
650         'hk' => 'ftp.hk.debian.org',
651         'hr' => 'ftp.hr.debian.org',
652         'hu' => 'ftp.hu.debian.org',
653         'ie' => 'ftp.ie.debian.org',
654         'is' => 'ftp.is.debian.org',
655         'it' => 'ftp.it.debian.org',
656         'jp' => 'ftp.jp.debian.org',
657         'kr' => 'ftp.kr.debian.org',
658         'mx' => 'ftp.mx.debian.org',
659         'nl' => 'ftp.nl.debian.org',
660         'no' => 'ftp.no.debian.org',
661         'nz' => 'ftp.nz.debian.org',
662         'pl' => 'ftp.pl.debian.org',
663         'pt' => 'ftp.pt.debian.org',
664         'ro' => 'ftp.ro.debian.org',
665         'ru' => 'ftp.ru.debian.org',
666         'se' => 'ftp.se.debian.org',
667         'si' => 'ftp.si.debian.org',
668         'sk' => 'ftp.sk.debian.org',
669         'tr' => 'ftp.tr.debian.org',
670         'tw' => 'ftp.tw.debian.org',
671         'gb' => 'ftp.uk.debian.org',
672         'us' => 'ftp.us.debian.org',
673     };
674 }
675
676 my $keymaphash =  {
677     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
678     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
679     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
680     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
681     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
682     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
683     #'et'     => [], # Ethopia or Estonia ??
684     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
685     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
686     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
687     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
688     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
689     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
690     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
691     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
692     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
693     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
694     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
695     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
696     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
697     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
698     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
699     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
700     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
701     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
702     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
703     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
704     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # dont know?
705     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
706     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
707     #'th'     => [],
708     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
709 };
710
711 my $kvmkeymaparray = [];
712 foreach my $lc (sort keys %$keymaphash) {
713     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
714 }
715
716 sub kvmkeymaps {
717     return $keymaphash;
718 }
719
720 sub kvmkeymaplist {
721     return $kvmkeymaparray;
722 }
723
724 sub extract_param {
725     my ($param, $key) = @_;
726
727     my $res = $param->{$key};
728     delete $param->{$key};
729
730     return $res;
731 }
732
733 # Note: we use this to wait until vncterm/spiceterm is ready
734 sub wait_for_vnc_port {
735     my ($port, $timeout) = @_;
736
737     $timeout = 5 if !$timeout;
738     my $sleeptime = 0;
739     my $starttime = [gettimeofday];
740     my $elapsed;
741
742     while (($elapsed = tv_interval($starttime)) < $timeout) {
743         if (my $fh = IO::File->new ("/proc/net/tcp", "r")) {
744             while (defined (my $line = <$fh>)) {
745                 if ($line =~ m/^\s*\d+:\s+([0-9A-Fa-f]{8}):([0-9A-Fa-f]{4})\s/) {
746                     if ($port == hex($2)) {
747                         close($fh);
748                         return 1;
749                     }
750                 }
751             }
752             close($fh);
753         }
754         $sleeptime += 100000 if  $sleeptime < 1000000;
755         usleep($sleeptime);
756     }
757
758     return undef;
759 }
760
761 sub next_unused_port {
762     my ($range_start, $range_end, $family, $address) = @_;
763
764     # We use a file to register allocated ports.
765     # Those registrations expires after $expiretime.
766     # We use this to avoid race conditions between
767     # allocation and use of ports.
768
769     my $filename = "/var/tmp/pve-reserved-ports";
770
771     my $code = sub {
772
773         my $expiretime = 5;
774         my $ctime = time();
775
776         my $ports = {};
777
778         if (my $fh = IO::File->new ($filename, "r")) {
779             while (my $line = <$fh>) {
780                 if ($line =~ m/^(\d+)\s(\d+)$/) {
781                     my ($port, $timestamp) = ($1, $2);
782                     if (($timestamp + $expiretime) > $ctime) {
783                         $ports->{$port} = $timestamp; # not expired
784                     }
785                 }
786             }
787         }
788
789         my $newport;
790         my %sockargs = (Listen => 5,
791                         ReuseAddr => 1,
792                         Family    => $family,
793                         Proto     => IPPROTO_TCP,
794                         GetAddrInfoFlags => 0);
795         $sockargs{LocalAddr} = $address if defined($address);
796
797         for (my $p = $range_start; $p < $range_end; $p++) {
798             next if $ports->{$p}; # reserved
799
800             $sockargs{LocalPort} = $p;
801             my $sock = IO::Socket::IP->new(%sockargs);
802
803             if ($sock) {
804                 close($sock);
805                 $newport = $p;
806                 $ports->{$p} = $ctime;
807                 last;
808             }
809         }
810
811         my $data = "";
812         foreach my $p (keys %$ports) {
813             $data .= "$p $ports->{$p}\n";
814         }
815
816         file_set_contents($filename, $data);
817
818         return $newport;
819     };
820
821     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
822     die $@ if $@;
823
824     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
825
826     return $p;
827 }
828
829 sub next_migrate_port {
830     my ($family, $address) = @_;
831     return next_unused_port(60000, 60050, $family, $address);
832 }
833
834 sub next_vnc_port {
835     my ($family, $address) = @_;
836     return next_unused_port(5900, 6000, $family, $address);
837 }
838
839 sub next_spice_port {
840     my ($family, $address) = @_;
841     return next_unused_port(61000, 61099, $family, $address);
842 }
843
844 # NOTE: NFS syscall can't be interrupted, so alarm does
845 # not work to provide timeouts.
846 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
847 # So fork() before using Filesys::Df
848 sub df {
849     my ($path, $timeout) = @_;
850
851     my $res = {
852         total => 0,
853         used => 0,
854         avail => 0,
855     };
856
857     my $pipe = IO::Pipe->new();
858     my $child = fork();
859     if (!defined($child)) {
860         warn "fork failed: $!\n";
861         return $res;
862     }
863
864     if (!$child) {
865         $pipe->writer();
866         eval {
867             my $df = Filesys::Df::df($path, 1);
868             print {$pipe} "$df->{blocks}\n$df->{used}\n$df->{bavail}\n";
869             $pipe->close();
870         };
871         if (my $err = $@) {
872             warn $err;
873             POSIX::_exit(1);
874         }
875         POSIX::_exit(0);
876     }
877
878     $pipe->reader();
879
880     my $readvalues = sub {
881         $res->{total} = int((<$pipe> =~ /^(\d*)$/)[0]);
882         $res->{used}  = int((<$pipe> =~ /^(\d*)$/)[0]);
883         $res->{avail} = int((<$pipe> =~ /^(\d*)$/)[0]);
884     };
885     eval {
886         run_with_timeout($timeout, $readvalues);
887     };
888     warn $@ if $@;
889     $pipe->close();
890     kill('KILL', $child);
891     waitpid($child, 0);
892     return $res;
893 }
894
895 # UPID helper
896 # We use this to uniquely identify a process.
897 # An 'Unique Process ID' has the following format:
898 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
899
900 sub upid_encode {
901     my $d = shift;
902
903     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
904     # more that 8 characters for pstart
905     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
906                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
907                    $d->{user});
908 }
909
910 sub upid_decode {
911     my ($upid, $noerr) = @_;
912
913     my $res;
914     my $filename;
915
916     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
917     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
918     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
919         $res->{node} = $1;
920         $res->{pid} = hex($3);
921         $res->{pstart} = hex($4);
922         $res->{starttime} = hex($5);
923         $res->{type} = $6;
924         $res->{id} = $7;
925         $res->{user} = $8;
926
927         my $subdir = substr($5, 7, 8);
928         $filename = "$pvetaskdir/$subdir/$upid";
929
930     } else {
931         return undef if $noerr;
932         die "unable to parse worker upid '$upid'\n";
933     }
934
935     return wantarray ? ($res, $filename) : $res;
936 }
937
938 sub upid_open {
939     my ($upid) = @_;
940
941     my ($task, $filename) = upid_decode($upid);
942
943     my $dirname = dirname($filename);
944     make_path($dirname);
945
946     my $wwwid = getpwnam('www-data') ||
947         die "getpwnam failed";
948
949     my $perm = 0640;
950
951     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
952         die "unable to create output file '$filename' - $!\n";
953     chown $wwwid, -1, $outfh;
954
955     return $outfh;
956 };
957
958 sub upid_read_status {
959     my ($upid) = @_;
960
961     my ($task, $filename) = upid_decode($upid);
962     my $fh = IO::File->new($filename, "r");
963     return "unable to open file - $!" if !$fh;
964     my $maxlen = 4096;
965     sysseek($fh, -$maxlen, 2);
966     my $readbuf = '';
967     my $br = sysread($fh, $readbuf, $maxlen);
968     close($fh);
969     if ($br) {
970         return "unable to extract last line"
971             if $readbuf !~ m/\n?(.+)$/;
972         my $line = $1;
973         if ($line =~ m/^TASK OK$/) {
974             return 'OK';
975         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
976             return $1;
977         } else {
978             return "unexpected status";
979         }
980     }
981     return "unable to read tail (got $br bytes)";
982 }
983
984 # useful functions to store comments in config files
985 sub encode_text {
986     my ($text) = @_;
987
988     # all control and hi-bit characters, and ':'
989     my $unsafe = "^\x20-\x39\x3b-\x7e";
990     return uri_escape(Encode::encode("utf8", $text), $unsafe);
991 }
992
993 sub decode_text {
994     my ($data) = @_;
995
996     return Encode::decode("utf8", uri_unescape($data));
997 }
998
999 # depreciated - do not use!
1000 # we now decode all parameters by default
1001 sub decode_utf8_parameters {
1002     my ($param) = @_;
1003
1004     foreach my $p (qw(comment description firstname lastname)) {
1005         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1006     }
1007
1008     return $param;
1009 }
1010
1011 sub random_ether_addr {
1012     my ($prefix) = @_;
1013
1014     my ($seconds, $microseconds) = gettimeofday;
1015
1016     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1017
1018     # clear multicast, set local id
1019     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1020
1021     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1022     if (defined($prefix)) {
1023         $addr = uc($prefix) . substr($addr, length($prefix));
1024     }
1025     return $addr;
1026 }
1027
1028 sub shellquote {
1029     my $str = shift;
1030
1031     return String::ShellQuote::shell_quote($str);
1032 }
1033
1034 sub cmd2string {
1035     my ($cmd) = @_;
1036
1037     die "no arguments" if !$cmd;
1038
1039     return $cmd if !ref($cmd);
1040
1041     my @qa = ();
1042     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1043
1044     return join (' ', @qa);
1045 }
1046
1047 # split an shell argument string into an array,
1048 sub split_args {
1049     my ($str) = @_;
1050
1051     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1052 }
1053
1054 sub dump_logfile {
1055     my ($filename, $start, $limit, $filter) = @_;
1056
1057     my $lines = [];
1058     my $count = 0;
1059
1060     my $fh = IO::File->new($filename, "r");
1061     if (!$fh) {
1062         $count++;
1063         push @$lines, { n => $count, t => "unable to open file - $!"};
1064         return ($count, $lines);
1065     }
1066
1067     $start = 0 if !$start;
1068     $limit = 50 if !$limit;
1069
1070     my $line;
1071
1072     if ($filter) {
1073         # duplicate code, so that we do not slow down normal path
1074         while (defined($line = <$fh>)) {
1075             next if $line !~ m/$filter/;
1076             next if $count++ < $start;
1077             next if $limit <= 0;
1078             chomp $line;
1079             push @$lines, { n => $count, t => $line};
1080             $limit--;
1081         }
1082     } else {
1083         while (defined($line = <$fh>)) {
1084             next if $count++ < $start;
1085             next if $limit <= 0;
1086             chomp $line;
1087             push @$lines, { n => $count, t => $line};
1088             $limit--;
1089         }
1090     }
1091
1092     close($fh);
1093
1094     # HACK: ExtJS store.guaranteeRange() does not like empty array
1095     # so we add a line
1096     if (!$count) {
1097         $count++;
1098         push @$lines, { n => $count, t => "no content"};
1099     }
1100
1101     return ($count, $lines);
1102 }
1103
1104 sub dump_journal {
1105     my ($start, $limit, $since, $until, $service) = @_;
1106
1107     my $lines = [];
1108     my $count = 0;
1109
1110     $start = 0 if !$start;
1111     $limit = 50 if !$limit;
1112
1113     my $parser = sub {
1114         my $line = shift;
1115
1116         return if $count++ < $start;
1117         return if $limit <= 0;
1118         push @$lines, { n => int($count), t => $line};
1119         $limit--;
1120     };
1121
1122     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1123
1124     push @$cmd, '--unit', $service if $service;
1125     push @$cmd, '--since', $since if $since;
1126     push @$cmd, '--until', $until if $until;
1127     run_command($cmd, outfunc => $parser);
1128
1129     # HACK: ExtJS store.guaranteeRange() does not like empty array
1130     # so we add a line
1131     if (!$count) {
1132         $count++;
1133         push @$lines, { n => $count, t => "no content"};
1134     }
1135
1136     return ($count, $lines);
1137 }
1138
1139 sub dir_glob_regex {
1140     my ($dir, $regex) = @_;
1141
1142     my $dh = IO::Dir->new ($dir);
1143     return wantarray ? () : undef if !$dh;
1144
1145     while (defined(my $tmp = $dh->read)) {
1146         if (my @res = $tmp =~ m/^($regex)$/) {
1147             $dh->close;
1148             return wantarray ? @res : $tmp;
1149         }
1150     }
1151     $dh->close;
1152
1153     return wantarray ? () : undef;
1154 }
1155
1156 sub dir_glob_foreach {
1157     my ($dir, $regex, $func) = @_;
1158
1159     my $dh = IO::Dir->new ($dir);
1160     if (defined $dh) {
1161         while (defined(my $tmp = $dh->read)) {
1162             if (my @res = $tmp =~ m/^($regex)$/) {
1163                 &$func (@res);
1164             }
1165         }
1166     }
1167 }
1168
1169 sub assert_if_modified {
1170     my ($digest1, $digest2) = @_;
1171
1172     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1173         die "detected modified configuration - file changed by other user? Try again.\n";
1174     }
1175 }
1176
1177 # Digest for short strings
1178 # like FNV32a, but we only return 31 bits (positive numbers)
1179 sub fnv31a {
1180     my ($string) = @_;
1181
1182     my $hval = 0x811c9dc5;
1183
1184     foreach my $c (unpack('C*', $string)) {
1185         $hval ^= $c;
1186         $hval += (
1187             (($hval << 1) ) +
1188             (($hval << 4) ) +
1189             (($hval << 7) ) +
1190             (($hval << 8) ) +
1191             (($hval << 24) ) );
1192         $hval = $hval & 0xffffffff;
1193     }
1194     return $hval & 0x7fffffff;
1195 }
1196
1197 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1198
1199 sub unpack_sockaddr_in46 {
1200     my ($sin) = @_;
1201     my $family = Socket::sockaddr_family($sin);
1202     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1203                                              : Socket::unpack_sockaddr_in($sin));
1204     return ($family, $port, $host);
1205 }
1206
1207 sub getaddrinfo_all {
1208     my ($hostname, @opts) = @_;
1209     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1210                   @opts );
1211     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1212     die "failed to get address info for: $hostname: $err\n" if $err;
1213     return @res;
1214 }
1215
1216 sub get_host_address_family {
1217     my ($hostname, $socktype) = @_;
1218     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1219     return $res[0]->{family};
1220 }
1221
1222 # get the fully qualified domain name of a host
1223 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1224 # given a nodename as a parameter
1225 sub get_fqdn {
1226     my ($nodename) = @_;
1227
1228     my $hints = {
1229         flags => AI_CANONNAME,
1230         socktype => SOCK_DGRAM
1231     };
1232
1233     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1234
1235     die "getaddrinfo: $err" if $err;
1236
1237     return $addrs[0]->{canonname};
1238 }
1239
1240 # Parses any sane kind of host, or host+port pair:
1241 # The port is always optional and thus may be undef.
1242 sub parse_host_and_port {
1243     my ($address) = @_;
1244     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1245         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1246         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1247     {
1248         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1249     }
1250     return; # nothing
1251 }
1252
1253 sub unshare($) {
1254     my ($flags) = @_;
1255     return 0 == syscall(PVE::Syscall::unshare, $flags);
1256 }
1257
1258 sub setns($$) {
1259     my ($fileno, $nstype) = @_;
1260     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1261 }
1262
1263 sub syncfs($) {
1264     my ($fileno) = @_;
1265     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1266 }
1267
1268 sub sync_mountpoint {
1269     my ($path) = @_;
1270     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1271     my $result = syncfs(fileno($fd));
1272     close($fd);
1273     return $result;
1274 }
1275
1276 # support sending multi-part mail messages with a text and or a HTML part
1277 # mailto may be a single email string or an array of receivers
1278 sub sendmail {
1279     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1280     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1281
1282     $mailto = [ $mailto ] if !ref($mailto);
1283
1284     foreach (@$mailto) {
1285         die "illegal character in mailto address\n"
1286             if ($_ =~ $mail_re);
1287     }
1288
1289     my $rcvrtxt = join (', ', @$mailto);
1290
1291     $mailfrom = $mailfrom || "root";
1292     die "illegal character in mailfrom address\n"
1293         if $mailfrom =~ $mail_re;
1294
1295     $author = $author || 'Proxmox VE';
1296
1297     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1298         die "unable to open 'sendmail' - $!";
1299
1300     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1301     my $boundary = "----_=_NextPart_001_".int(time).$$;
1302
1303     print MAIL "Content-Type: multipart/alternative;\n";
1304     print MAIL "\tboundary=\"$boundary\"\n";
1305     print MAIL "MIME-Version: 1.0\n";
1306
1307     print MAIL "FROM: $author <$mailfrom>\n";
1308     print MAIL "TO: $rcvrtxt\n";
1309     print MAIL "SUBJECT: $subject\n";
1310     print MAIL "\n";
1311     print MAIL "This is a multi-part message in MIME format.\n\n";
1312     print MAIL "--$boundary\n";
1313
1314     if (defined($text)) {
1315         print MAIL "Content-Type: text/plain;\n";
1316         print MAIL "\tcharset=\"UTF8\"\n";
1317         print MAIL "Content-Transfer-Encoding: 8bit\n";
1318         print MAIL "\n";
1319
1320         # avoid 'remove extra line breaks' issue (MS Outlook)
1321         my $fill = '  ';
1322         $text =~ s/^/$fill/gm;
1323
1324         print MAIL $text;
1325
1326         print MAIL "\n--$boundary\n";
1327     }
1328
1329     if (defined($html)) {
1330         print MAIL "Content-Type: text/html;\n";
1331         print MAIL "\tcharset=\"UTF8\"\n";
1332         print MAIL "Content-Transfer-Encoding: 8bit\n";
1333         print MAIL "\n";
1334
1335         print MAIL $html;
1336
1337         print MAIL "\n--$boundary--\n";
1338     }
1339
1340     close(MAIL);
1341 }
1342
1343 sub tempfile {
1344     my ($perm, %opts) = @_;
1345
1346     # default permissions are stricter than with file_set_contents
1347     $perm = 0600 if !defined($perm);
1348
1349     my $dir = $opts{dir} // '/run';
1350     my $mode = $opts{mode} // O_RDWR;
1351     $mode |= O_EXCL if !$opts{allow_links};
1352
1353     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1354     if (!$fh && $! == EOPNOTSUPP) {
1355         $dir = '/tmp' if !defined($opts{dir});
1356         $dir .= "/.tmpfile.$$";
1357         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1358         unlink($dir) if $fh;
1359     }
1360     die "failed to create tempfile: $!\n" if !$fh;
1361     return $fh;
1362 }
1363
1364 sub tempfile_contents {
1365     my ($data, $perm, %opts) = @_;
1366
1367     my $fh = tempfile($perm, %opts);
1368     eval {
1369         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1370         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1371     };
1372     if (my $err = $@) {
1373         close $fh;
1374         die $err;
1375     }
1376
1377     return ("/proc/$$/fd/".$fh->fileno, $fh);
1378 }
1379
1380 sub validate_ssh_public_keys {
1381     my ($raw) = @_;
1382     my @lines = split(/\n/, $raw);
1383
1384     foreach my $line (@lines) {
1385         next if $line =~ m/^\s*$/;
1386         eval {
1387             my ($filename, $handle) = tempfile_contents($line);
1388             run_command(["ssh-keygen", "-l", "-f", $filename],
1389                         outfunc => sub {}, errfunc => sub {});
1390         };
1391         die "SSH public key validation error\n" if $@;
1392     }
1393 }
1394
1395 sub openat($$$;$) {
1396     my ($dirfd, $pathname, $flags, $mode) = @_;
1397     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1398     return undef if $fd < 0;
1399     # sysopen() doesn't deal with numeric file descriptors apparently
1400     # so we need to convert to a mode string for IO::Handle->new_from_fd
1401     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1402     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1403     return $handle if $handle;
1404     my $err = $!; # save error before closing the raw fd
1405     syscall(PVE::Syscall::close, $fd); # close
1406     $! = $err;
1407     return undef;
1408 }
1409
1410 sub mkdirat($$$) {
1411     my ($dirfd, $name, $mode) = @_;
1412     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1413 }
1414
1415 # NOTE: This calls the dbus main loop and must not be used when another dbus
1416 # main loop is being used as we need to wait for the JobRemoved signal.
1417 # Polling the job status instead doesn't work because this doesn't give us the
1418 # distinction between success and failure.
1419 #
1420 # Note that the description is mandatory for security reasons.
1421 sub enter_systemd_scope {
1422     my ($unit, $description, %extra) = @_;
1423     die "missing description\n" if !defined($description);
1424
1425     my $timeout = delete $extra{timeout};
1426
1427     $unit .= '.scope';
1428     my $properties = [ [PIDs => [dbus_uint32($$)]] ];
1429
1430     foreach my $key (keys %extra) {
1431         if ($key eq 'Slice' || $key eq 'KillMode') {
1432             push @$properties, [$key, $extra{$key}];
1433         } elsif ($key eq 'CPUShares') {
1434             push @$properties, [$key, dbus_uint64($extra{$key})];
1435         } elsif ($key eq 'CPUQuota') {
1436             push @$properties, ['CPUQuotaPerSecUSec',
1437                                 dbus_uint64($extra{$key} * 10000)];
1438         } else {
1439             die "Don't know how to encode $key for systemd scope\n";
1440         }
1441     }
1442
1443     my $job;
1444     my $done = 0;
1445
1446     my $bus = Net::DBus->system();
1447     my $reactor = Net::DBus::Reactor->main();
1448
1449     my $service = $bus->get_service('org.freedesktop.systemd1');
1450     my $if = $service->get_object('/org/freedesktop/systemd1', 'org.freedesktop.systemd1.Manager');
1451     # Connect to the JobRemoved signal since we want to wait for it to finish
1452     my $sigid;
1453     my $timer;
1454     my $cleanup = sub {
1455         my ($no_shutdown) = @_;
1456         $if->disconnect_from_signal('JobRemoved', $sigid) if defined($if);
1457         $if = undef;
1458         $sigid = undef;
1459         $reactor->remove_timeout($timer) if defined($timer);
1460         $timer = undef;
1461         return if $no_shutdown;
1462         $reactor->shutdown();
1463     };
1464
1465     $sigid = $if->connect_to_signal('JobRemoved', sub {
1466         my ($id, $removed_job, $signaled_unit, $result) = @_;
1467         return if $signaled_unit ne $unit || $removed_job ne $job;
1468         $cleanup->(0);
1469         die "systemd job failed\n" if $result ne 'done';
1470         $done = 1;
1471     });
1472
1473     my $on_timeout = sub {
1474         $cleanup->(0);
1475         die "systemd job timed out\n";
1476     };
1477
1478     $timer = $reactor->add_timeout($timeout * 1000, Net::DBus::Callback->new(method => $on_timeout))
1479         if defined($timeout);
1480     $job = $if->StartTransientUnit($unit, 'fail', $properties, []);
1481     $reactor->run();
1482     $cleanup->(1);
1483     die "systemd job never completed\n" if !$done;
1484 }
1485
1486 my $salt_starter = time();
1487
1488 sub encrypt_pw {
1489     my ($pw) = @_;
1490
1491     $salt_starter++;
1492     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1493
1494     # crypt does not want '+' in salt (see 'man crypt')
1495     $salt =~ s/\+/X/g;
1496
1497     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1498 }
1499
1500 1;