src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Scalar::Util 'weaken';
  28 use Date::Format qw(time2str);
  29
  30 use PVE::Syscall;
  31
  32 # avoid warning when parsing long hex values with hex()
  33 no warnings 'portable'; # Support for 64-bit ints required
  34
  35 our @EXPORT_OK = qw(
  36 $IPV6RE
  37 $IPV4RE
  38 lock_file
  39 lock_file_full
  40 run_command
  41 file_set_contents
  42 file_get_contents
  43 file_read_firstline
  44 dir_glob_regex
  45 dir_glob_foreach
  46 split_list
  47 template_replace
  48 safe_print
  49 trim
  50 extract_param
  51 extract_sensitive_params
  52 file_copy
  53 get_host_arch
  54 O_PATH
  55 O_TMPFILE
  56 AT_EMPTY_PATH
  57 AT_FDCWD
  58 CLONE_NEWNS
  59 CLONE_NEWUTS
  60 CLONE_NEWIPC
  61 CLONE_NEWUSER
  62 CLONE_NEWPID
  63 CLONE_NEWNET
  64 );
  65
  66 my $pvelogdir = "/var/log/pve";
  67 my $pvetaskdir = "$pvelogdir/tasks";
  68
  69 mkdir $pvelogdir;
  70 mkdir $pvetaskdir;
  71
  72 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  73 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  74 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  75 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  76
  77 our $IPV6RE = "(?:" .
  78     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  79     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  80     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  81     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  84     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  85     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  86     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  87
  88 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  89
  90 our $EMAIL_USER_RE = qr/[\w\+\-\~]+(\.[\w\+\-\~]+)*/;
  91 our $EMAIL_RE = qr/$EMAIL_USER_RE@[a-zA-Z0-9\-]+(\.[a-zA-Z0-9\-]+)*/;
  92
  93 use constant {CLONE_NEWNS   => 0x00020000,
  94               CLONE_NEWUTS  => 0x04000000,
  95               CLONE_NEWIPC  => 0x08000000,
  96               CLONE_NEWUSER => 0x10000000,
  97               CLONE_NEWPID  => 0x20000000,
  98               CLONE_NEWNET  => 0x40000000};
  99
 100 use constant {O_PATH    => 0x00200000,
 101               O_CLOEXEC => 0x00080000,
 102               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
 103
 104 use constant {AT_EMPTY_PATH => 0x1000,
 105               AT_FDCWD => -100};
 106
 107 sub run_with_timeout {
 108     my ($timeout, $code, @param) = @_;
 109
 110     die "got timeout\n" if $timeout <= 0;
 111
 112     my $prev_alarm = alarm 0; # suspend outer alarm early
 113
 114     my $sigcount = 0;
 115
 116     my $res;
 117
 118     eval {
 119         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 120         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 121         local $SIG{__DIE__};   # see SA bug 4631
 122
 123         alarm($timeout);
 124
 125         eval { $res = &$code(@param); };
 126
 127         alarm(0); # avoid race conditions
 128
 129         die $@ if $@;
 130     };
 131
 132     my $err = $@;
 133
 134     alarm $prev_alarm;
 135
 136     # this shouldn't happen anymore?
 137     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 138
 139     die $err if $err;
 140
 141     return $res;
 142 }
 143
 144 # flock: we use one file handle per process, so lock file
 145 # can be nested multiple times and succeeds for the same process.
 146 #
 147 # Since this is the only way we lock now and we don't have the old
 148 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 149 # count how deep we're nesting. Therefore this hash now stores a weak reference
 150 # to a boolean telling us whether we already have a lock.
 151
 152 my $lock_handles =  {};
 153
 154 sub lock_file_full {
 155     my ($filename, $timeout, $shared, $code, @param) = @_;
 156
 157     $timeout = 10 if !$timeout;
 158
 159     my $mode = $shared ? LOCK_SH : LOCK_EX;
 160
 161     my $lockhash = ($lock_handles->{$$} //= {});
 162
 163     # Returns a locked file handle.
 164     my $get_locked_file = sub {
 165         my $fh = IO::File->new(">>$filename")
 166             or die "can't open file - $!\n";
 167
 168         if (!flock($fh, $mode|LOCK_NB)) {
 169             print STDERR "trying to acquire lock...\n";
 170             my $success;
 171             while(1) {
 172                 $success = flock($fh, $mode);
 173                 # try again on EINTR (see bug #273)
 174                 if ($success || ($! != EINTR)) {
 175                     last;
 176                 }
 177             }
 178             if (!$success) {
 179                 print STDERR " failed\n";
 180                 die "can't acquire lock '$filename' - $!\n";
 181             }
 182             print STDERR " OK\n";
 183         }
 184
 185         return $fh;
 186     };
 187
 188     my $res;
 189     my $checkptr = $lockhash->{$filename};
 190     my $check = 0; # This must not go out of scope before running the code.
 191     my $local_fh; # This must stay local
 192     if (!$checkptr || !$$checkptr) {
 193         # We cannot create a weak reference in a single atomic step, so we first
 194         # create a false-value, then create a reference to it, then weaken it,
 195         # and after successfully locking the file we change the boolean value.
 196         #
 197         # The reason for this is that if an outer SIGALRM throws an exception
 198         # between creating the reference and weakening it, a subsequent call to
 199         # lock_file_full() will see a leftover full reference to a valid
 200         # variable. This variable must be 0 in order for said call to attempt to
 201         # lock the file anew.
 202         #
 203         # An externally triggered exception elsewhere in the code will cause the
 204         # weak reference to become 'undef', and since the file handle is only
 205         # stored in the local scope in $local_fh, the file will be closed by
 206         # perl's cleanup routines as well.
 207         #
 208         # This still assumes that an IO::File handle can properly deal with such
 209         # exceptions thrown during its own destruction, but that's up to perls
 210         # guts now.
 211         $lockhash->{$filename} = \$check;
 212         weaken $lockhash->{$filename};
 213         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 214         if ($@) {
 215             $@ = "can't lock file '$filename' - $@";
 216             return undef;
 217         }
 218         $check = 1;
 219     }
 220     $res = eval { &$code(@param); };
 221     return undef if $@;
 222     return $res;
 223 }
 224
 225
 226 sub lock_file {
 227     my ($filename, $timeout, $code, @param) = @_;
 228
 229     return lock_file_full($filename, $timeout, 0, $code, @param);
 230 }
 231
 232 sub file_set_contents {
 233     my ($filename, $data, $perm)  = @_;
 234
 235     $perm = 0644 if !defined($perm);
 236
 237     my $tmpname = "$filename.tmp.$$";
 238
 239     eval {
 240         my ($fh, $tries) = (undef, 0);
 241         while (!$fh && $tries++ < 3) {
 242             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 243             if (!$fh && $! == EEXIST) {
 244                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 245             }
 246         }
 247         die "unable to open file '$tmpname' - $!\n" if !$fh;
 248         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 249         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 250     };
 251     my $err = $@;
 252
 253     if ($err) {
 254         unlink $tmpname;
 255         die $err;
 256     }
 257
 258     if (!rename($tmpname, $filename)) {
 259         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 260         unlink $tmpname;
 261         die $msg;
 262     }
 263 }
 264
 265 sub file_get_contents {
 266     my ($filename, $max) = @_;
 267
 268     my $fh = IO::File->new($filename, "r") ||
 269         die "can't open '$filename' - $!\n";
 270
 271     my $content = safe_read_from($fh, $max, 0, $filename);
 272
 273     close $fh;
 274
 275     return $content;
 276 }
 277
 278 sub file_copy {
 279     my ($filename, $dst, $max, $perm) = @_;
 280
 281     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 282 }
 283
 284 sub file_read_firstline {
 285     my ($filename) = @_;
 286
 287     my $fh = IO::File->new ($filename, "r");
 288     return undef if !$fh;
 289     my $res = <$fh>;
 290     chomp $res if $res;
 291     $fh->close;
 292     return $res;
 293 }
 294
 295 sub safe_read_from {
 296     my ($fh, $max, $oneline, $filename) = @_;
 297
 298     # pmxcfs file size limit
 299     $max = 512*1024 if !$max;
 300
 301     my $subject = defined($filename) ? "file '$filename'" : 'input';
 302
 303     my $br = 0;
 304     my $input = '';
 305     my $count;
 306     while ($count = sysread($fh, $input, 8192, $br)) {
 307         $br += $count;
 308         die "$subject too long - aborting\n" if $br > $max;
 309         if ($oneline && $input =~ m/^(.*)\n/) {
 310             $input = $1;
 311             last;
 312         }
 313     }
 314     die "unable to read $subject - $!\n" if !defined($count);
 315
 316     return $input;
 317 }
 318
 319 # The $cmd parameter can be:
 320 #  -) a string
 321 #    This is generally executed by passing it to the shell with the -c option.
 322 #    However, it can be executed in one of two ways, depending on whether
 323 #    there's a pipe involved:
 324 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 325 #          set -o pipefail &&
 326 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 327 #      (Note that this may result in two different syntax requirements!)
 328 #      FIXME?
 329 #  -) an array of arguments (strings)
 330 #    Will be executed without interference from a shell. (Parameters are passed
 331 #    as is, no escape sequences of strings will be touched.)
 332 #  -) an array of arrays
 333 #    Each array represents a command, and each command's output is piped into
 334 #    the following command's standard input.
 335 #    For this a shell command string is created with pipe symbols between each
 336 #    command.
 337 #    Each command is a list of strings meant to end up in the final command
 338 #    unchanged. In order to achieve this, every argument is shell-quoted.
 339 #    Quoting can be disabled for a particular argument by turning it into a
 340 #    reference, this allows inserting arbitrary shell options.
 341 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 342 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 343 #    will literally print: hello >/dev/null
 344 sub run_command {
 345     my ($cmd, %param) = @_;
 346
 347     my $old_umask;
 348     my $cmdstr;
 349
 350     if (my $ref = ref($cmd)) {
 351         if (ref($cmd->[0])) {
 352             $cmdstr = 'set -o pipefail && ';
 353             my $pipe = '';
 354             foreach my $command (@$cmd) {
 355                 # concatenate quoted parameters
 356                 # strings which are passed by reference are NOT shell quoted
 357                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 358                 $pipe = ' | ';
 359             }
 360             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 361         } else {
 362             $cmdstr = cmd2string($cmd);
 363         }
 364     } else {
 365         $cmdstr = $cmd;
 366         if ($cmd =~ m/\|/) {
 367             # see 'man bash' for option pipefail
 368             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 369         } else {
 370             $cmd = [ $cmd ];
 371         }
 372     }
 373
 374     my $errmsg;
 375     my $laststderr;
 376     my $timeout;
 377     my $oldtimeout;
 378     my $pid;
 379     my $exitcode = -1;
 380
 381     my $outfunc;
 382     my $errfunc;
 383     my $logfunc;
 384     my $input;
 385     my $output;
 386     my $afterfork;
 387     my $noerr;
 388     my $keeplocale;
 389     my $quiet;
 390
 391     eval {
 392
 393         foreach my $p (keys %param) {
 394             if ($p eq 'timeout') {
 395                 $timeout = $param{$p};
 396             } elsif ($p eq 'umask') {
 397                 $old_umask = umask($param{$p});
 398             } elsif ($p eq 'errmsg') {
 399                 $errmsg = $param{$p};
 400             } elsif ($p eq 'input') {
 401                 $input = $param{$p};
 402             } elsif ($p eq 'output') {
 403                 $output = $param{$p};
 404             } elsif ($p eq 'outfunc') {
 405                 $outfunc = $param{$p};
 406             } elsif ($p eq 'errfunc') {
 407                 $errfunc = $param{$p};
 408             } elsif ($p eq 'logfunc') {
 409                 $logfunc = $param{$p};
 410             } elsif ($p eq 'afterfork') {
 411                 $afterfork = $param{$p};
 412             } elsif ($p eq 'noerr') {
 413                 $noerr = $param{$p};
 414             } elsif ($p eq 'keeplocale') {
 415                 $keeplocale = $param{$p};
 416             } elsif ($p eq 'quiet') {
 417                 $quiet = $param{$p};
 418             } else {
 419                 die "got unknown parameter '$p' for run_command\n";
 420             }
 421         }
 422
 423         if ($errmsg) {
 424             my $origerrfunc = $errfunc;
 425             $errfunc = sub {
 426                 if ($laststderr) {
 427                     if ($origerrfunc) {
 428                         &$origerrfunc("$laststderr\n");
 429                     } else {
 430                         print STDERR "$laststderr\n" if $laststderr;
 431                     }
 432                 }
 433                 $laststderr = shift;
 434             };
 435         }
 436
 437         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 438         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 439         my $error  = IO::File->new();
 440
 441         my $orig_pid = $$;
 442
 443         eval {
 444             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 445
 446             # suppress LVM warnings like: "File descriptor 3 left open";
 447             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 448
 449             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 450
 451             # if we pipe fron STDIN, open3 closes STDIN, so we we
 452             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 453             # as soon as we open a new file.
 454             # to avoid that we open /dev/null
 455             if (!ref($writer) && !defined(fileno(STDIN))) {
 456                 POSIX::close(0);
 457                 open(STDIN, "</dev/null");
 458             }
 459         };
 460
 461         my $err = $@;
 462
 463         # catch exec errors
 464         if ($orig_pid != $$) {
 465             warn "ERROR: $err";
 466             POSIX::_exit (1);
 467             kill ('KILL', $$);
 468         }
 469
 470         die $err if $err;
 471
 472         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 473         $oldtimeout = alarm($timeout) if $timeout;
 474
 475         &$afterfork() if $afterfork;
 476
 477         if (ref($writer)) {
 478             print $writer $input if defined $input;
 479             close $writer;
 480         }
 481
 482         my $select = new IO::Select;
 483         $select->add($reader) if ref($reader);
 484         $select->add($error);
 485
 486         my $outlog = '';
 487         my $errlog = '';
 488
 489         my $starttime = time();
 490
 491         while ($select->count) {
 492             my @handles = $select->can_read(1);
 493
 494             foreach my $h (@handles) {
 495                 my $buf = '';
 496                 my $count = sysread ($h, $buf, 4096);
 497                 if (!defined ($count)) {
 498                     my $err = $!;
 499                     kill (9, $pid);
 500                     waitpid ($pid, 0);
 501                     die $err;
 502                 }
 503                 $select->remove ($h) if !$count;
 504                 if ($h eq $reader) {
 505                     if ($outfunc || $logfunc) {
 506                         eval {
 507                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 508                                 my $line = $outlog . $1;
 509                                 $outlog = '';
 510                                 &$outfunc($line) if $outfunc;
 511                                 &$logfunc($line) if $logfunc;
 512                             }
 513                             $outlog .= $buf;
 514                         };
 515                         my $err = $@;
 516                         if ($err) {
 517                             kill (9, $pid);
 518                             waitpid ($pid, 0);
 519                             die $err;
 520                         }
 521                     } elsif (!$quiet) {
 522                         print $buf;
 523                         *STDOUT->flush();
 524                     }
 525                 } elsif ($h eq $error) {
 526                     if ($errfunc || $logfunc) {
 527                         eval {
 528                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 529                                 my $line = $errlog . $1;
 530                                 $errlog = '';
 531                                 &$errfunc($line) if $errfunc;
 532                                 &$logfunc($line) if $logfunc;
 533                             }
 534                             $errlog .= $buf;
 535                         };
 536                         my $err = $@;
 537                         if ($err) {
 538                             kill (9, $pid);
 539                             waitpid ($pid, 0);
 540                             die $err;
 541                         }
 542                     } elsif (!$quiet) {
 543                         print STDERR $buf;
 544                         *STDERR->flush();
 545                     }
 546                 }
 547             }
 548         }
 549
 550         &$outfunc($outlog) if $outfunc && $outlog;
 551         &$logfunc($outlog) if $logfunc && $outlog;
 552
 553         &$errfunc($errlog) if $errfunc && $errlog;
 554         &$logfunc($errlog) if $logfunc && $errlog;
 555
 556         waitpid ($pid, 0);
 557
 558         if ($? == -1) {
 559             die "failed to execute\n";
 560         } elsif (my $sig = ($? & 127)) {
 561             die "got signal $sig\n";
 562         } elsif ($exitcode = ($? >> 8)) {
 563             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 564                 if ($errmsg && $laststderr) {
 565                     my $lerr = $laststderr;
 566                     $laststderr = undef;
 567                     die "$lerr\n";
 568                 }
 569                 die "exit code $exitcode\n";
 570             }
 571         }
 572
 573         alarm(0);
 574     };
 575
 576     my $err = $@;
 577
 578     alarm(0);
 579
 580     if ($errmsg && $laststderr) {
 581         &$errfunc(undef); # flush laststderr
 582     }
 583
 584     umask ($old_umask) if defined($old_umask);
 585
 586     alarm($oldtimeout) if $oldtimeout;
 587
 588     if ($err) {
 589         if ($pid && ($err eq "got timeout\n")) {
 590             kill (9, $pid);
 591             waitpid ($pid, 0);
 592             die "command '$cmdstr' failed: $err";
 593         }
 594
 595         if ($errmsg) {
 596             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 597             die "$errmsg: $err";
 598         } elsif(!$noerr) {
 599             die "command '$cmdstr' failed: $err";
 600         }
 601     }
 602
 603     return $exitcode;
 604 }
 605
 606 # Run a command with a tcp socket as standard input.
 607 sub pipe_socket_to_command  {
 608     my ($cmd, $ip, $port) = @_;
 609
 610     my $params = {
 611         Listen => 1,
 612         ReuseAddr => 1,
 613         Proto => &Socket::IPPROTO_TCP,
 614         GetAddrInfoFlags => 0,
 615         LocalAddr => $ip,
 616         LocalPort => $port,
 617     };
 618     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 619
 620     print "$ip\n$port\n"; # tell remote where to connect
 621     *STDOUT->flush();
 622
 623     alarm 0;
 624     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 625     alarm 30;
 626     my $client = $socket->accept; # Wait for a client
 627     alarm 0;
 628     close($socket);
 629
 630     # We want that the command talks over the TCP socket and takes
 631     # ownership of it, so that when it closes it the connection is
 632     # terminated, so we need to be able to close the socket. So we
 633     # can't really use PVE::Tools::run_command().
 634     my $pid = fork() // die "fork failed: $!\n";
 635     if (!$pid) {
 636         POSIX::dup2(fileno($client), 0);
 637         POSIX::dup2(fileno($client), 1);
 638         close($client);
 639         exec {$cmd->[0]} @$cmd or do {
 640             warn "exec failed: $!\n";
 641             POSIX::_exit(1);
 642         };
 643     }
 644
 645     close($client);
 646     if (waitpid($pid, 0) != $pid) {
 647         kill(15 => $pid); # if we got interrupted terminate the child
 648         my $count = 0;
 649         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 650             usleep(100000);
 651             $count++;
 652             kill(9 => $pid), last if $count > 300; # 30 second timeout
 653         }
 654     }
 655     if (my $sig = ($? & 127)) {
 656         die "got signal $sig\n";
 657     } elsif (my $exitcode = ($? >> 8)) {
 658         die "exit code $exitcode\n";
 659     }
 660
 661     return undef;
 662 }
 663
 664 sub split_list {
 665     my $listtxt = shift // '';
 666
 667     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 668
 669     $listtxt =~ s/[,;]/ /g;
 670     $listtxt =~ s/^\s+//;
 671
 672     my @data = split (/\s+/, $listtxt);
 673
 674     return @data;
 675 }
 676
 677 sub trim {
 678     my $txt = shift;
 679
 680     return $txt if !defined($txt);
 681
 682     $txt =~ s/^\s+//;
 683     $txt =~ s/\s+$//;
 684
 685     return $txt;
 686 }
 687
 688 # simple uri templates like "/vms/{vmid}"
 689 sub template_replace {
 690     my ($tmpl, $data) = @_;
 691
 692     return $tmpl if !$tmpl;
 693
 694     my $res = '';
 695     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 696         $res .= $1 if $1;
 697         $res .= ($data->{$3} || '-') if $2;
 698     }
 699     return $res;
 700 }
 701
 702 sub safe_print {
 703     my ($filename, $fh, $data) = @_;
 704
 705     return if !$data;
 706
 707     my $res = print $fh $data;
 708
 709     die "write to '$filename' failed\n" if !$res;
 710 }
 711
 712 sub debmirrors {
 713
 714     return {
 715         'at' => 'ftp.at.debian.org',
 716         'au' => 'ftp.au.debian.org',
 717         'be' => 'ftp.be.debian.org',
 718         'bg' => 'ftp.bg.debian.org',
 719         'br' => 'ftp.br.debian.org',
 720         'ca' => 'ftp.ca.debian.org',
 721         'ch' => 'ftp.ch.debian.org',
 722         'cl' => 'ftp.cl.debian.org',
 723         'cz' => 'ftp.cz.debian.org',
 724         'de' => 'ftp.de.debian.org',
 725         'dk' => 'ftp.dk.debian.org',
 726         'ee' => 'ftp.ee.debian.org',
 727         'es' => 'ftp.es.debian.org',
 728         'fi' => 'ftp.fi.debian.org',
 729         'fr' => 'ftp.fr.debian.org',
 730         'gr' => 'ftp.gr.debian.org',
 731         'hk' => 'ftp.hk.debian.org',
 732         'hr' => 'ftp.hr.debian.org',
 733         'hu' => 'ftp.hu.debian.org',
 734         'ie' => 'ftp.ie.debian.org',
 735         'is' => 'ftp.is.debian.org',
 736         'it' => 'ftp.it.debian.org',
 737         'jp' => 'ftp.jp.debian.org',
 738         'kr' => 'ftp.kr.debian.org',
 739         'mx' => 'ftp.mx.debian.org',
 740         'nl' => 'ftp.nl.debian.org',
 741         'no' => 'ftp.no.debian.org',
 742         'nz' => 'ftp.nz.debian.org',
 743         'pl' => 'ftp.pl.debian.org',
 744         'pt' => 'ftp.pt.debian.org',
 745         'ro' => 'ftp.ro.debian.org',
 746         'ru' => 'ftp.ru.debian.org',
 747         'se' => 'ftp.se.debian.org',
 748         'si' => 'ftp.si.debian.org',
 749         'sk' => 'ftp.sk.debian.org',
 750         'tr' => 'ftp.tr.debian.org',
 751         'tw' => 'ftp.tw.debian.org',
 752         'gb' => 'ftp.uk.debian.org',
 753         'us' => 'ftp.us.debian.org',
 754     };
 755 }
 756
 757 my $keymaphash =  {
 758     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 759     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 760     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 761     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 762     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 763     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 764     #'et'     => [], # Ethopia or Estonia ??
 765     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 766     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 767     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 768     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 769     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 770     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 771     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 772     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 773     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 774     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 775     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 776     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 777     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 778     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 779     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 780     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 781     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 782     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 783     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 784     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 785     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 786     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 787     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 788     #'th'     => [],
 789     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 790 };
 791
 792 my $kvmkeymaparray = [];
 793 foreach my $lc (sort keys %$keymaphash) {
 794     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 795 }
 796
 797 sub kvmkeymaps {
 798     return $keymaphash;
 799 }
 800
 801 sub kvmkeymaplist {
 802     return $kvmkeymaparray;
 803 }
 804
 805 sub extract_param {
 806     my ($param, $key) = @_;
 807
 808     my $res = $param->{$key};
 809     delete $param->{$key};
 810
 811     return $res;
 812 }
 813
 814 # For extracting sensitive keys (e.g. password), to avoid writing them to www-data owned configs
 815 sub extract_sensitive_params :prototype($$$) {
 816     my ($param, $sensitive_list, $delete_list) = @_;
 817
 818     my %delete = map { $_ => 1 } ($delete_list || [])->@*;
 819
 820     my $sensitive = {};
 821     for my $opt (@$sensitive_list) {
 822         # handle deletions as explicitly setting `undef`, so subs which only have $param but not
 823         # $delete_list available can recognize them. Afterwards new values  may override.
 824         if (exists($delete{$opt})) {
 825             $sensitive->{$opt} = undef;
 826         }
 827
 828         if (defined(my $value = extract_param($param, $opt))) {
 829             $sensitive->{$opt} = $value;
 830         }
 831     }
 832
 833     return $sensitive;
 834 }
 835
 836 # Note: we use this to wait until vncterm/spiceterm is ready
 837 sub wait_for_vnc_port {
 838     my ($port, $family, $timeout) = @_;
 839
 840     $timeout = 5 if !$timeout;
 841     my $sleeptime = 0;
 842     my $starttime = [gettimeofday];
 843     my $elapsed;
 844
 845     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 846     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 847
 848     my $found;
 849     while (($elapsed = tv_interval($starttime)) < $timeout) {
 850         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 851         run_command($cmd, outfunc => sub {
 852             my $line = shift;
 853             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 854                 $found = 1 if ($port == $1);
 855             }
 856         });
 857         return 1 if $found;
 858         $sleeptime += 100000 if  $sleeptime < 1000000;
 859         usleep($sleeptime);
 860     }
 861
 862     die "Timeout while waiting for port '$port' to get ready!\n";
 863 }
 864
 865 sub next_unused_port {
 866     my ($range_start, $range_end, $family, $address) = @_;
 867
 868     # We use a file to register allocated ports.
 869     # Those registrations expires after $expiretime.
 870     # We use this to avoid race conditions between
 871     # allocation and use of ports.
 872
 873     my $filename = "/var/tmp/pve-reserved-ports";
 874
 875     my $code = sub {
 876
 877         my $expiretime = 5;
 878         my $ctime = time();
 879
 880         my $ports = {};
 881
 882         if (my $fh = IO::File->new ($filename, "r")) {
 883             while (my $line = <$fh>) {
 884                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 885                     my ($port, $timestamp) = ($1, $2);
 886                     if (($timestamp + $expiretime) > $ctime) {
 887                         $ports->{$port} = $timestamp; # not expired
 888                     }
 889                 }
 890             }
 891         }
 892
 893         my $newport;
 894         my %sockargs = (Listen => 5,
 895                         ReuseAddr => 1,
 896                         Family    => $family,
 897                         Proto     => IPPROTO_TCP,
 898                         GetAddrInfoFlags => 0);
 899         $sockargs{LocalAddr} = $address if defined($address);
 900
 901         for (my $p = $range_start; $p < $range_end; $p++) {
 902             next if $ports->{$p}; # reserved
 903
 904             $sockargs{LocalPort} = $p;
 905             my $sock = IO::Socket::IP->new(%sockargs);
 906
 907             if ($sock) {
 908                 close($sock);
 909                 $newport = $p;
 910                 $ports->{$p} = $ctime;
 911                 last;
 912             }
 913         }
 914
 915         my $data = "";
 916         foreach my $p (keys %$ports) {
 917             $data .= "$p $ports->{$p}\n";
 918         }
 919
 920         file_set_contents($filename, $data);
 921
 922         return $newport;
 923     };
 924
 925     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 926     die $@ if $@;
 927
 928     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 929
 930     return $p;
 931 }
 932
 933 sub next_migrate_port {
 934     my ($family, $address) = @_;
 935     return next_unused_port(60000, 60050, $family, $address);
 936 }
 937
 938 sub next_vnc_port {
 939     my ($family, $address) = @_;
 940     return next_unused_port(5900, 6000, $family, $address);
 941 }
 942
 943 sub spice_port_range {
 944     return (61000, 61999);
 945 }
 946
 947 sub next_spice_port {
 948     my ($family, $address) = @_;
 949     return next_unused_port(spice_port_range(), $family, $address);
 950 }
 951
 952 sub must_stringify {
 953         my ($value) = @_;
 954         eval { $value = "$value" };
 955         return "error turning value into a string: $@" if $@;
 956         return $value;
 957 }
 958
 959 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 960 # the $sub has to return a single scalar
 961 sub run_fork_with_timeout {
 962     my ($timeout, $sub) = @_;
 963
 964     my $res;
 965     my $error;
 966     my $pipe_out = IO::Pipe->new();
 967
 968     # disable pending alarms, save their remaining time
 969     my $prev_alarm = alarm 0;
 970
 971     # avoid leaving a zombie if the parent gets interrupted
 972     my $sig_received;
 973
 974     my $child = fork();
 975     if (!defined($child)) {
 976         die "fork failed: $!\n";
 977         return $res;
 978     }
 979
 980     if (!$child) {
 981         $pipe_out->writer();
 982
 983         eval {
 984             $res = $sub->();
 985             print {$pipe_out} encode_json({ result => $res });
 986             $pipe_out->flush();
 987         };
 988         if (my $err = $@) {
 989             print {$pipe_out} encode_json({ error => must_stringify($err) });
 990             $pipe_out->flush();
 991             POSIX::_exit(1);
 992         }
 993         POSIX::_exit(0);
 994     }
 995
 996     local $SIG{INT} = sub { $sig_received++; };
 997     local $SIG{TERM} = sub {
 998         $error //= "interrupted by unexpected signal\n";
 999         kill('TERM', $child);
1000     };
1001
1002     $pipe_out->reader();
1003
1004     my $readvalues = sub {
1005         local $/ = undef;
1006         my $child_res = decode_json(readline_nointr($pipe_out));
1007         $res = $child_res->{result};
1008         $error = $child_res->{error};
1009     };
1010     eval {
1011         if (defined($timeout)) {
1012             run_with_timeout($timeout, $readvalues);
1013         } else {
1014             $readvalues->();
1015         }
1016     };
1017     warn $@ if $@;
1018     $pipe_out->close();
1019     kill('KILL', $child);
1020     waitpid($child, 0);
1021
1022     alarm $prev_alarm;
1023     die "interrupted by unexpected signal\n" if $sig_received;
1024
1025     die $error if $error;
1026     return $res;
1027 }
1028
1029 sub run_fork {
1030     my ($code) = @_;
1031     return run_fork_with_timeout(undef, $code);
1032 }
1033
1034 # NOTE: NFS syscall can't be interrupted, so alarm does
1035 # not work to provide timeouts.
1036 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1037 # So fork() before using Filesys::Df
1038 sub df {
1039     my ($path, $timeout) = @_;
1040
1041     my $df = sub { return Filesys::Df::df($path, 1) };
1042
1043     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1044     warn $@ if $@;
1045
1046     # untaint, but be flexible: PB usage can result in scientific notation
1047     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1048         $res->@{qw(blocks used bavail)};
1049
1050     return {
1051         total => $blocks,
1052         used => $used,
1053         avail => $bavail,
1054     };
1055 }
1056
1057 sub du {
1058     my ($path, $timeout) = @_;
1059
1060     my $size;
1061
1062     $timeout //= 10;
1063
1064     my $parser = sub {
1065         my $line = shift;
1066
1067         if ($line =~ m/^(\d+)\s+total$/) {
1068             $size = $1;
1069         }
1070     };
1071
1072     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1073
1074     return $size;
1075 }
1076
1077 # UPID helper
1078 # We use this to uniquely identify a process.
1079 # An 'Unique Process ID' has the following format:
1080 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1081
1082 sub upid_encode {
1083     my $d = shift;
1084
1085     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1086     # more that 8 characters for pstart
1087     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1088                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1089                    $d->{user});
1090 }
1091
1092 sub upid_decode {
1093     my ($upid, $noerr) = @_;
1094
1095     my $res;
1096     my $filename;
1097
1098     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1099     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1100     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1101         $res->{node} = $1;
1102         $res->{pid} = hex($3);
1103         $res->{pstart} = hex($4);
1104         $res->{starttime} = hex($5);
1105         $res->{type} = $6;
1106         $res->{id} = $7;
1107         $res->{user} = $8;
1108
1109         my $subdir = substr($5, 7, 8);
1110         $filename = "$pvetaskdir/$subdir/$upid";
1111
1112     } else {
1113         return undef if $noerr;
1114         die "unable to parse worker upid '$upid'\n";
1115     }
1116
1117     return wantarray ? ($res, $filename) : $res;
1118 }
1119
1120 sub upid_open {
1121     my ($upid) = @_;
1122
1123     my ($task, $filename) = upid_decode($upid);
1124
1125     my $dirname = dirname($filename);
1126     make_path($dirname);
1127
1128     my $wwwid = getpwnam('www-data') ||
1129         die "getpwnam failed";
1130
1131     my $perm = 0640;
1132
1133     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1134         die "unable to create output file '$filename' - $!\n";
1135     chown $wwwid, -1, $outfh;
1136
1137     return $outfh;
1138 };
1139
1140 sub upid_read_status {
1141     my ($upid) = @_;
1142
1143     my ($task, $filename) = upid_decode($upid);
1144     my $fh = IO::File->new($filename, "r");
1145     return "unable to open file - $!" if !$fh;
1146     my $maxlen = 4096;
1147     sysseek($fh, -$maxlen, 2);
1148     my $readbuf = '';
1149     my $br = sysread($fh, $readbuf, $maxlen);
1150     close($fh);
1151     if ($br) {
1152         return "unable to extract last line"
1153             if $readbuf !~ m/\n?(.+)$/;
1154         my $line = $1;
1155         if ($line =~ m/^TASK OK$/) {
1156             return 'OK';
1157         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1158             return $1;
1159         } else {
1160             return "unexpected status";
1161         }
1162     }
1163     return "unable to read tail (got $br bytes)";
1164 }
1165
1166 # useful functions to store comments in config files
1167 sub encode_text {
1168     my ($text) = @_;
1169
1170     # all control and hi-bit characters, and ':'
1171     my $unsafe = "^\x20-\x39\x3b-\x7e";
1172     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1173 }
1174
1175 sub decode_text {
1176     my ($data) = @_;
1177
1178     return Encode::decode("utf8", uri_unescape($data));
1179 }
1180
1181 # depreciated - do not use!
1182 # we now decode all parameters by default
1183 sub decode_utf8_parameters {
1184     my ($param) = @_;
1185
1186     foreach my $p (qw(comment description firstname lastname)) {
1187         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1188     }
1189
1190     return $param;
1191 }
1192
1193 sub random_ether_addr {
1194     my ($prefix) = @_;
1195
1196     my ($seconds, $microseconds) = gettimeofday;
1197
1198     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1199
1200     # clear multicast, set local id
1201     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1202
1203     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1204     if (defined($prefix)) {
1205         $addr = uc($prefix) . substr($addr, length($prefix));
1206     }
1207     return $addr;
1208 }
1209
1210 sub shellquote {
1211     my $str = shift;
1212
1213     return String::ShellQuote::shell_quote($str);
1214 }
1215
1216 sub cmd2string {
1217     my ($cmd) = @_;
1218
1219     die "no arguments" if !$cmd;
1220
1221     return $cmd if !ref($cmd);
1222
1223     my @qa = ();
1224     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1225
1226     return join (' ', @qa);
1227 }
1228
1229 # split an shell argument string into an array,
1230 sub split_args {
1231     my ($str) = @_;
1232
1233     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1234 }
1235
1236 sub dump_logfile {
1237     my ($filename, $start, $limit, $filter) = @_;
1238
1239     my $lines = [];
1240     my $count = 0;
1241
1242     my $fh = IO::File->new($filename, "r");
1243     if (!$fh) {
1244         $count++;
1245         push @$lines, { n => $count, t => "unable to open file - $!"};
1246         return ($count, $lines);
1247     }
1248
1249     $start = 0 if !$start;
1250     $limit = 50 if !$limit;
1251
1252     my $line;
1253
1254     if ($filter) {
1255         # duplicate code, so that we do not slow down normal path
1256         while (defined($line = <$fh>)) {
1257             next if $line !~ m/$filter/;
1258             next if $count++ < $start;
1259             next if $limit <= 0;
1260             chomp $line;
1261             push @$lines, { n => $count, t => $line};
1262             $limit--;
1263         }
1264     } else {
1265         while (defined($line = <$fh>)) {
1266             next if $count++ < $start;
1267             next if $limit <= 0;
1268             chomp $line;
1269             push @$lines, { n => $count, t => $line};
1270             $limit--;
1271         }
1272     }
1273
1274     close($fh);
1275
1276     # HACK: ExtJS store.guaranteeRange() does not like empty array
1277     # so we add a line
1278     if (!$count) {
1279         $count++;
1280         push @$lines, { n => $count, t => "no content"};
1281     }
1282
1283     return ($count, $lines);
1284 }
1285
1286 sub dump_journal {
1287     my ($start, $limit, $since, $until, $service) = @_;
1288
1289     my $lines = [];
1290     my $count = 0;
1291
1292     $start = 0 if !$start;
1293     $limit = 50 if !$limit;
1294
1295     my $parser = sub {
1296         my $line = shift;
1297
1298         return if $count++ < $start;
1299         return if $limit <= 0;
1300         push @$lines, { n => int($count), t => $line};
1301         $limit--;
1302     };
1303
1304     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1305
1306     push @$cmd, '--unit', $service if $service;
1307     push @$cmd, '--since', $since if $since;
1308     push @$cmd, '--until', $until if $until;
1309     run_command($cmd, outfunc => $parser);
1310
1311     # HACK: ExtJS store.guaranteeRange() does not like empty array
1312     # so we add a line
1313     if (!$count) {
1314         $count++;
1315         push @$lines, { n => $count, t => "no content"};
1316     }
1317
1318     return ($count, $lines);
1319 }
1320
1321 sub dir_glob_regex {
1322     my ($dir, $regex) = @_;
1323
1324     my $dh = IO::Dir->new ($dir);
1325     return wantarray ? () : undef if !$dh;
1326
1327     while (defined(my $tmp = $dh->read)) {
1328         if (my @res = $tmp =~ m/^($regex)$/) {
1329             $dh->close;
1330             return wantarray ? @res : $tmp;
1331         }
1332     }
1333     $dh->close;
1334
1335     return wantarray ? () : undef;
1336 }
1337
1338 sub dir_glob_foreach {
1339     my ($dir, $regex, $func) = @_;
1340
1341     my $dh = IO::Dir->new ($dir);
1342     if (defined $dh) {
1343         while (defined(my $tmp = $dh->read)) {
1344             if (my @res = $tmp =~ m/^($regex)$/) {
1345                 &$func (@res);
1346             }
1347         }
1348     }
1349 }
1350
1351 sub assert_if_modified {
1352     my ($digest1, $digest2) = @_;
1353
1354     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1355         die "detected modified configuration - file changed by other user? Try again.\n";
1356     }
1357 }
1358
1359 # Digest for short strings
1360 # like FNV32a, but we only return 31 bits (positive numbers)
1361 sub fnv31a {
1362     my ($string) = @_;
1363
1364     my $hval = 0x811c9dc5;
1365
1366     foreach my $c (unpack('C*', $string)) {
1367         $hval ^= $c;
1368         $hval += (
1369             (($hval << 1) ) +
1370             (($hval << 4) ) +
1371             (($hval << 7) ) +
1372             (($hval << 8) ) +
1373             (($hval << 24) ) );
1374         $hval = $hval & 0xffffffff;
1375     }
1376     return $hval & 0x7fffffff;
1377 }
1378
1379 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1380
1381 sub unpack_sockaddr_in46 {
1382     my ($sin) = @_;
1383     my $family = Socket::sockaddr_family($sin);
1384     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1385                                              : Socket::unpack_sockaddr_in($sin));
1386     return ($family, $port, $host);
1387 }
1388
1389 sub getaddrinfo_all {
1390     my ($hostname, @opts) = @_;
1391     my %hints = (
1392         flags => AI_V4MAPPED | AI_ALL,
1393         @opts,
1394     );
1395     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1396     die "failed to get address info for: $hostname: $err\n" if $err;
1397     return @res;
1398 }
1399
1400 sub get_host_address_family {
1401     my ($hostname, $socktype) = @_;
1402     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1403     return $res[0]->{family};
1404 }
1405
1406 # get the fully qualified domain name of a host
1407 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1408 # given a nodename as a parameter
1409 sub get_fqdn {
1410     my ($nodename) = @_;
1411
1412     my $hints = {
1413         flags => AI_CANONNAME,
1414         socktype => SOCK_DGRAM
1415     };
1416
1417     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1418
1419     die "getaddrinfo: $err" if $err;
1420
1421     return $addrs[0]->{canonname};
1422 }
1423
1424 # Parses any sane kind of host, or host+port pair:
1425 # The port is always optional and thus may be undef.
1426 sub parse_host_and_port {
1427     my ($address) = @_;
1428     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1429         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1430         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1431     {
1432         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1433     }
1434     return; # nothing
1435 }
1436
1437 sub setresuid($$$) {
1438     my ($ruid, $euid, $suid) = @_;
1439     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1440 }
1441
1442 sub unshare($) {
1443     my ($flags) = @_;
1444     return 0 == syscall(PVE::Syscall::unshare, $flags);
1445 }
1446
1447 sub setns($$) {
1448     my ($fileno, $nstype) = @_;
1449     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1450 }
1451
1452 sub syncfs($) {
1453     my ($fileno) = @_;
1454     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1455 }
1456
1457 sub fsync($) {
1458     my ($fileno) = @_;
1459     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1460 }
1461
1462 sub sync_mountpoint {
1463     my ($path) = @_;
1464     sysopen my $fd, $path, O_RDONLY|O_CLOEXEC or die "failed to open $path: $!\n";
1465     my $syncfs_err;
1466     if (!syncfs(fileno($fd))) {
1467         $syncfs_err = "$!";
1468     }
1469     close($fd);
1470     die "syncfs '$path' failed - $syncfs_err\n" if defined $syncfs_err;
1471 }
1472
1473 # support sending multi-part mail messages with a text and or a HTML part
1474 # mailto may be a single email string or an array of receivers
1475 sub sendmail {
1476     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1477
1478     $mailto = [ $mailto ] if !ref($mailto);
1479
1480     my $mailto_quoted = [];
1481     for my $to (@$mailto) {
1482         die "mailto does not look like a valid email address or username\n"
1483             if $to !~ /^$EMAIL_RE$/ && $to !~ /^$EMAIL_USER_RE$/;
1484         push @$mailto_quoted, shellquote($to);
1485     }
1486
1487     my $rcvrtxt = join (', ', @$mailto);
1488
1489     $mailfrom = $mailfrom || "root";
1490     die "mailfrom does not look like a valid email address or username\n"
1491             if $mailfrom !~ /^$EMAIL_RE$/ && $mailfrom !~ /^$EMAIL_USER_RE$/;
1492     my $mailfrom_quoted = shellquote($mailfrom);
1493
1494     $author = $author // 'Proxmox VE';
1495
1496     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom_quoted,
1497         "--", @$mailto_quoted) || die "unable to open 'sendmail' - $!";
1498
1499     my $date = time2str('%a, %d %b %Y %H:%M:%S %z', time());
1500
1501     my $is_multipart = $text && $html;
1502
1503     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1504     my $boundary = "----_=_NextPart_001_".int(time).$$;
1505
1506     if ($subject =~ /[^[:ascii:]]/) {
1507         $subject = Encode::encode('MIME-Header', $subject);
1508     }
1509
1510     if ($subject =~ /[^[:ascii:]]/ || $is_multipart) {
1511         print MAIL "MIME-Version: 1.0\n";
1512     }
1513     print MAIL "From: $author <$mailfrom>\n";
1514     print MAIL "To: $rcvrtxt\n";
1515     print MAIL "Date: $date\n";
1516     print MAIL "Subject: $subject\n";
1517
1518     if ($is_multipart) {
1519         print MAIL "Content-Type: multipart/alternative;\n";
1520         print MAIL "\tboundary=\"$boundary\"\n";
1521         print MAIL "\n";
1522         print MAIL "This is a multi-part message in MIME format.\n\n";
1523         print MAIL "--$boundary\n";
1524     }
1525
1526     if (defined($text)) {
1527         print MAIL "Content-Type: text/plain;\n";
1528         print MAIL "\tcharset=\"UTF-8\"\n";
1529         print MAIL "Content-Transfer-Encoding: 8bit\n";
1530         print MAIL "\n";
1531
1532         # avoid 'remove extra line breaks' issue (MS Outlook)
1533         my $fill = '  ';
1534         $text =~ s/^/$fill/gm;
1535
1536         print MAIL $text;
1537
1538         print MAIL "\n--$boundary\n" if $is_multipart;
1539     }
1540
1541     if (defined($html)) {
1542         print MAIL "Content-Type: text/html;\n";
1543         print MAIL "\tcharset=\"UTF-8\"\n";
1544         print MAIL "Content-Transfer-Encoding: 8bit\n";
1545         print MAIL "\n";
1546
1547         print MAIL $html;
1548
1549         print MAIL "\n--$boundary--\n" if $is_multipart;
1550     }
1551
1552     close(MAIL);
1553 }
1554
1555 sub tempfile {
1556     my ($perm, %opts) = @_;
1557
1558     # default permissions are stricter than with file_set_contents
1559     $perm = 0600 if !defined($perm);
1560
1561     my $dir = $opts{dir} // '/run';
1562     my $mode = $opts{mode} // O_RDWR;
1563     $mode |= O_EXCL if !$opts{allow_links};
1564
1565     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1566     if (!$fh && $! == EOPNOTSUPP) {
1567         $dir = '/tmp' if !defined($opts{dir});
1568         $dir .= "/.tmpfile.$$";
1569         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1570         unlink($dir) if $fh;
1571     }
1572     die "failed to create tempfile: $!\n" if !$fh;
1573     return $fh;
1574 }
1575
1576 sub tempfile_contents {
1577     my ($data, $perm, %opts) = @_;
1578
1579     my $fh = tempfile($perm, %opts);
1580     eval {
1581         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1582         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1583     };
1584     if (my $err = $@) {
1585         close $fh;
1586         die $err;
1587     }
1588
1589     return ("/proc/$$/fd/".$fh->fileno, $fh);
1590 }
1591
1592 sub validate_ssh_public_keys {
1593     my ($raw) = @_;
1594     my @lines = split(/\n/, $raw);
1595
1596     foreach my $line (@lines) {
1597         next if $line =~ m/^\s*$/;
1598         eval {
1599             my ($filename, $handle) = tempfile_contents($line);
1600             run_command(["ssh-keygen", "-l", "-f", $filename],
1601                         outfunc => sub {}, errfunc => sub {});
1602         };
1603         die "SSH public key validation error\n" if $@;
1604     }
1605 }
1606
1607 sub openat($$$;$) {
1608     my ($dirfd, $pathname, $flags, $mode) = @_;
1609     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1610     return undef if $fd < 0;
1611     # sysopen() doesn't deal with numeric file descriptors apparently
1612     # so we need to convert to a mode string for IO::Handle->new_from_fd
1613     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1614     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1615     return $handle if $handle;
1616     my $err = $!; # save error before closing the raw fd
1617     syscall(PVE::Syscall::close, $fd); # close
1618     $! = $err;
1619     return undef;
1620 }
1621
1622 sub mkdirat($$$) {
1623     my ($dirfd, $name, $mode) = @_;
1624     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1625 }
1626
1627 sub fchownat($$$$$) {
1628     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1629     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1630 }
1631
1632 my $salt_starter = time();
1633
1634 sub encrypt_pw {
1635     my ($pw) = @_;
1636
1637     $salt_starter++;
1638     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1639
1640     # crypt does not want '+' in salt (see 'man crypt')
1641     $salt =~ s/\+/X/g;
1642
1643     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1644 }
1645
1646 # intended usage: convert_size($val, "kb" => "gb")
1647 # we round up to the next integer by default
1648 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1649 # use $no_round_up to switch this off, above example would then return 0
1650 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1651 # (0 if $no_round_up is true)
1652 # allowed formats for value:
1653 # 1234
1654 # 1234.
1655 # 1234.1234
1656 # .1234
1657 sub convert_size {
1658     my ($value, $from, $to, $no_round_up) = @_;
1659
1660     my $units = {
1661         b  => 0,
1662         kb => 1,
1663         mb => 2,
1664         gb => 3,
1665         tb => 4,
1666         pb => 5,
1667     };
1668
1669     die "no value given"
1670         if !defined($value) || $value eq "";
1671
1672     $from = lc($from // ''); $to = lc($to // '');
1673     die "unknown 'from' and/or 'to' units ($from => $to)"
1674         if !defined($units->{$from}) || !defined($units->{$to});
1675
1676     die "value '$value' is not a valid, positive number"
1677         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1678
1679     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1680
1681     $value *= 2**$shift_amount;
1682     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1683
1684     return int($value);
1685 }
1686
1687 # uninterruptible readline
1688 # retries on EINTR
1689 sub readline_nointr {
1690     my ($fh) = @_;
1691     my $line;
1692     while (1) {
1693         $line = <$fh>;
1694         last if defined($line) || ($! != EINTR);
1695     }
1696     return $line;
1697 }
1698
1699 my $host_arch;
1700 sub get_host_arch {
1701     $host_arch = (POSIX::uname())[4] if !$host_arch;
1702     return $host_arch;
1703 }
1704
1705 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1706 sub dev_t_major($) {
1707     my ($dev_t) = @_;
1708     return (int($dev_t) & 0xfff00) >> 8;
1709 }
1710
1711 sub dev_t_minor($) {
1712     my ($dev_t) = @_;
1713     $dev_t = int($dev_t);
1714     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1715 }
1716
1717 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1718 # Returns the intersection of elements as a single array [a b]
1719 sub array_intersect {
1720     my ($arrays) = @_;
1721
1722     if (!ref($arrays->[0])) {
1723         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1724     }
1725
1726     return [] if scalar(@$arrays) == 0;
1727     return $arrays->[0] if scalar(@$arrays) == 1;
1728
1729     my $array_unique = sub {
1730         my %seen = ();
1731         return grep { ! $seen{ $_ }++ } @_;
1732     };
1733
1734     # base idea is to get all unique members from the first array, then
1735     # check the common elements with the next (uniquely made) one, only keep
1736     # those. Repeat for every array and at the end we only have those left
1737     # which exist in all arrays
1738     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1739     for my $i (1 .. $#$arrays) {
1740         my %count = ();
1741         # $return_arr is already unique, explicit at before the loop, implicit below.
1742         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1743             $count{$element}++;
1744         }
1745         $return_arr = [];
1746         foreach my $element (keys %count) {
1747             push @$return_arr, $element if $count{$element} > 1;
1748         }
1749         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1750     }
1751
1752     return $return_arr;
1753 }
1754
1755 sub open_tree($$$) {
1756     my ($dfd, $pathname, $flags) = @_;
1757     return PVE::Syscall::file_handle_result(syscall(
1758         &PVE::Syscall::open_tree,
1759         $dfd,
1760         $pathname,
1761         $flags,
1762     ));
1763 }
1764
1765 sub move_mount($$$$$) {
1766     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1767     return 0 == syscall(
1768         &PVE::Syscall::move_mount,
1769         $from_dirfd,
1770         $from_pathname,
1771         $to_dirfd,
1772         $to_pathname,
1773         $flags,
1774     );
1775 }
1776
1777 sub fsopen($$) {
1778     my ($fsname, $flags) = @_;
1779     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
1780 }
1781
1782 sub fsmount($$$) {
1783     my ($fd, $flags, $mount_attrs) = @_;
1784     return PVE::Syscall::file_handle_result(syscall(
1785         &PVE::Syscall::fsmount,
1786         $fd,
1787         $flags,
1788         $mount_attrs,
1789     ));
1790 }
1791
1792 sub fspick($$$) {
1793     my ($dirfd, $pathname, $flags) = @_;
1794     return PVE::Syscall::file_handle_result(syscall(
1795         &PVE::Syscall::fspick,
1796         $dirfd,
1797         $pathname,
1798         $flags,
1799     ));
1800 }
1801
1802 sub fsconfig($$$$$) {
1803     my ($fd, $command, $key, $value, $aux) = @_;
1804     return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
1805 }
1806
1807 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1808 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1809 sub mount($$$$$) {
1810     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1811     return 0 == syscall(
1812         &PVE::Syscall::mount,
1813         $source,
1814         $target,
1815         $filesystemtype,
1816         $mountflags,
1817         $data,
1818     );
1819 }
1820
1821 sub safe_compare {
1822     my ($left, $right, $cmp) = @_;
1823
1824     return 0 if !defined($left) && !defined($right);
1825     return -1 if !defined($left);
1826     return 1 if !defined($right);
1827     return $cmp->($left, $right);
1828 }
1829
1830 1;