src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
   6 use IO::Socket::IP;
   7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
   8               IPPROTO_TCP);
   9 use IO::Select;
  10 use File::Basename;
  11 use File::Path qw(make_path);
  12 use Filesys::Df (); # don't overwrite our df()
  13 use IO::Pipe;
  14 use IO::File;
  15 use IO::Dir;
  16 use IO::Handle;
  17 use IPC::Open3;
  18 use Fcntl qw(:DEFAULT :flock);
  19 use base 'Exporter';
  20 use URI::Escape;
  21 use Encode;
  22 use Digest::SHA;
  23 use JSON;
  24 use Text::ParseWords;
  25 use String::ShellQuote;
  26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  27 use Scalar::Util 'weaken';
  28 use Date::Format qw(time2str);
  29
  30 use PVE::Syscall;
  31
  32 # avoid warning when parsing long hex values with hex()
  33 no warnings 'portable'; # Support for 64-bit ints required
  34
  35 our @EXPORT_OK = qw(
  36 $IPV6RE
  37 $IPV4RE
  38 lock_file
  39 lock_file_full
  40 run_command
  41 file_set_contents
  42 file_get_contents
  43 file_read_firstline
  44 dir_glob_regex
  45 dir_glob_foreach
  46 split_list
  47 template_replace
  48 safe_print
  49 trim
  50 extract_param
  51 file_copy
  52 get_host_arch
  53 O_PATH
  54 O_TMPFILE
  55 AT_EMPTY_PATH
  56 AT_FDCWD
  57 CLONE_NEWNS
  58 CLONE_NEWUTS
  59 CLONE_NEWIPC
  60 CLONE_NEWUSER
  61 CLONE_NEWPID
  62 CLONE_NEWNET
  63 );
  64
  65 my $pvelogdir = "/var/log/pve";
  66 my $pvetaskdir = "$pvelogdir/tasks";
  67
  68 mkdir $pvelogdir;
  69 mkdir $pvetaskdir;
  70
  71 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  72 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  73 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  74 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  75
  76 our $IPV6RE = "(?:" .
  77     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  78     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  79     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  80     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  81     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  84     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  85     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  86
  87 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  88
  89 use constant {CLONE_NEWNS   => 0x00020000,
  90               CLONE_NEWUTS  => 0x04000000,
  91               CLONE_NEWIPC  => 0x08000000,
  92               CLONE_NEWUSER => 0x10000000,
  93               CLONE_NEWPID  => 0x20000000,
  94               CLONE_NEWNET  => 0x40000000};
  95
  96 use constant {O_PATH    => 0x00200000,
  97               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
  98
  99 use constant {AT_EMPTY_PATH => 0x1000,
 100               AT_FDCWD => -100};
 101
 102 sub run_with_timeout {
 103     my ($timeout, $code, @param) = @_;
 104
 105     die "got timeout\n" if $timeout <= 0;
 106
 107     my $prev_alarm = alarm 0; # suspend outer alarm early
 108
 109     my $sigcount = 0;
 110
 111     my $res;
 112
 113     eval {
 114         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
 115         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 116         local $SIG{__DIE__};   # see SA bug 4631
 117
 118         alarm($timeout);
 119
 120         eval { $res = &$code(@param); };
 121
 122         alarm(0); # avoid race conditions
 123
 124         die $@ if $@;
 125     };
 126
 127     my $err = $@;
 128
 129     alarm $prev_alarm;
 130
 131     # this shouldn't happen anymore?
 132     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 133
 134     die $err if $err;
 135
 136     return $res;
 137 }
 138
 139 # flock: we use one file handle per process, so lock file
 140 # can be nested multiple times and succeeds for the same process.
 141 #
 142 # Since this is the only way we lock now and we don't have the old
 143 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 144 # count how deep we're nesting. Therefore this hash now stores a weak reference
 145 # to a boolean telling us whether we already have a lock.
 146
 147 my $lock_handles =  {};
 148
 149 sub lock_file_full {
 150     my ($filename, $timeout, $shared, $code, @param) = @_;
 151
 152     $timeout = 10 if !$timeout;
 153
 154     my $mode = $shared ? LOCK_SH : LOCK_EX;
 155
 156     my $lockhash = ($lock_handles->{$$} //= {});
 157
 158     # Returns a locked file handle.
 159     my $get_locked_file = sub {
 160         my $fh = IO::File->new(">>$filename")
 161             or die "can't open file - $!\n";
 162
 163         if (!flock($fh, $mode|LOCK_NB)) {
 164             print STDERR "trying to acquire lock...\n";
 165             my $success;
 166             while(1) {
 167                 $success = flock($fh, $mode);
 168                 # try again on EINTR (see bug #273)
 169                 if ($success || ($! != EINTR)) {
 170                     last;
 171                 }
 172             }
 173             if (!$success) {
 174                 print STDERR " failed\n";
 175                 die "can't acquire lock '$filename' - $!\n";
 176             }
 177             print STDERR " OK\n";
 178         }
 179
 180         return $fh;
 181     };
 182
 183     my $res;
 184     my $checkptr = $lockhash->{$filename};
 185     my $check = 0; # This must not go out of scope before running the code.
 186     my $local_fh; # This must stay local
 187     if (!$checkptr || !$$checkptr) {
 188         # We cannot create a weak reference in a single atomic step, so we first
 189         # create a false-value, then create a reference to it, then weaken it,
 190         # and after successfully locking the file we change the boolean value.
 191         #
 192         # The reason for this is that if an outer SIGALRM throws an exception
 193         # between creating the reference and weakening it, a subsequent call to
 194         # lock_file_full() will see a leftover full reference to a valid
 195         # variable. This variable must be 0 in order for said call to attempt to
 196         # lock the file anew.
 197         #
 198         # An externally triggered exception elsewhere in the code will cause the
 199         # weak reference to become 'undef', and since the file handle is only
 200         # stored in the local scope in $local_fh, the file will be closed by
 201         # perl's cleanup routines as well.
 202         #
 203         # This still assumes that an IO::File handle can properly deal with such
 204         # exceptions thrown during its own destruction, but that's up to perls
 205         # guts now.
 206         $lockhash->{$filename} = \$check;
 207         weaken $lockhash->{$filename};
 208         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 209         if ($@) {
 210             $@ = "can't lock file '$filename' - $@";
 211             return undef;
 212         }
 213         $check = 1;
 214     }
 215     $res = eval { &$code(@param); };
 216     return undef if $@;
 217     return $res;
 218 }
 219
 220
 221 sub lock_file {
 222     my ($filename, $timeout, $code, @param) = @_;
 223
 224     return lock_file_full($filename, $timeout, 0, $code, @param);
 225 }
 226
 227 sub file_set_contents {
 228     my ($filename, $data, $perm)  = @_;
 229
 230     $perm = 0644 if !defined($perm);
 231
 232     my $tmpname = "$filename.tmp.$$";
 233
 234     eval {
 235         my ($fh, $tries) = (undef, 0);
 236         while (!$fh && $tries++ < 3) {
 237             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 238             if (!$fh && $! == EEXIST) {
 239                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 240             }
 241         }
 242         die "unable to open file '$tmpname' - $!\n" if !$fh;
 243         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 244         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 245     };
 246     my $err = $@;
 247
 248     if ($err) {
 249         unlink $tmpname;
 250         die $err;
 251     }
 252
 253     if (!rename($tmpname, $filename)) {
 254         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 255         unlink $tmpname;
 256         die $msg;
 257     }
 258 }
 259
 260 sub file_get_contents {
 261     my ($filename, $max) = @_;
 262
 263     my $fh = IO::File->new($filename, "r") ||
 264         die "can't open '$filename' - $!\n";
 265
 266     my $content = safe_read_from($fh, $max, 0, $filename);
 267
 268     close $fh;
 269
 270     return $content;
 271 }
 272
 273 sub file_copy {
 274     my ($filename, $dst, $max, $perm) = @_;
 275
 276     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 277 }
 278
 279 sub file_read_firstline {
 280     my ($filename) = @_;
 281
 282     my $fh = IO::File->new ($filename, "r");
 283     return undef if !$fh;
 284     my $res = <$fh>;
 285     chomp $res if $res;
 286     $fh->close;
 287     return $res;
 288 }
 289
 290 sub safe_read_from {
 291     my ($fh, $max, $oneline, $filename) = @_;
 292
 293     # pmxcfs file size limit
 294     $max = 512*1024 if !$max;
 295
 296     my $subject = defined($filename) ? "file '$filename'" : 'input';
 297
 298     my $br = 0;
 299     my $input = '';
 300     my $count;
 301     while ($count = sysread($fh, $input, 8192, $br)) {
 302         $br += $count;
 303         die "$subject too long - aborting\n" if $br > $max;
 304         if ($oneline && $input =~ m/^(.*)\n/) {
 305             $input = $1;
 306             last;
 307         }
 308     }
 309     die "unable to read $subject - $!\n" if !defined($count);
 310
 311     return $input;
 312 }
 313
 314 # The $cmd parameter can be:
 315 #  -) a string
 316 #    This is generally executed by passing it to the shell with the -c option.
 317 #    However, it can be executed in one of two ways, depending on whether
 318 #    there's a pipe involved:
 319 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 320 #          set -o pipefail &&
 321 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 322 #      (Note that this may result in two different syntax requirements!)
 323 #      FIXME?
 324 #  -) an array of arguments (strings)
 325 #    Will be executed without interference from a shell. (Parameters are passed
 326 #    as is, no escape sequences of strings will be touched.)
 327 #  -) an array of arrays
 328 #    Each array represents a command, and each command's output is piped into
 329 #    the following command's standard input.
 330 #    For this a shell command string is created with pipe symbols between each
 331 #    command.
 332 #    Each command is a list of strings meant to end up in the final command
 333 #    unchanged. In order to achieve this, every argument is shell-quoted.
 334 #    Quoting can be disabled for a particular argument by turning it into a
 335 #    reference, this allows inserting arbitrary shell options.
 336 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 337 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 338 #    will literally print: hello >/dev/null
 339 sub run_command {
 340     my ($cmd, %param) = @_;
 341
 342     my $old_umask;
 343     my $cmdstr;
 344
 345     if (my $ref = ref($cmd)) {
 346         if (ref($cmd->[0])) {
 347             $cmdstr = 'set -o pipefail && ';
 348             my $pipe = '';
 349             foreach my $command (@$cmd) {
 350                 # concatenate quoted parameters
 351                 # strings which are passed by reference are NOT shell quoted
 352                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 353                 $pipe = ' | ';
 354             }
 355             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 356         } else {
 357             $cmdstr = cmd2string($cmd);
 358         }
 359     } else {
 360         $cmdstr = $cmd;
 361         if ($cmd =~ m/\|/) {
 362             # see 'man bash' for option pipefail
 363             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 364         } else {
 365             $cmd = [ $cmd ];
 366         }
 367     }
 368
 369     my $errmsg;
 370     my $laststderr;
 371     my $timeout;
 372     my $oldtimeout;
 373     my $pid;
 374     my $exitcode = -1;
 375
 376     my $outfunc;
 377     my $errfunc;
 378     my $logfunc;
 379     my $input;
 380     my $output;
 381     my $afterfork;
 382     my $noerr;
 383     my $keeplocale;
 384     my $quiet;
 385
 386     eval {
 387
 388         foreach my $p (keys %param) {
 389             if ($p eq 'timeout') {
 390                 $timeout = $param{$p};
 391             } elsif ($p eq 'umask') {
 392                 $old_umask = umask($param{$p});
 393             } elsif ($p eq 'errmsg') {
 394                 $errmsg = $param{$p};
 395             } elsif ($p eq 'input') {
 396                 $input = $param{$p};
 397             } elsif ($p eq 'output') {
 398                 $output = $param{$p};
 399             } elsif ($p eq 'outfunc') {
 400                 $outfunc = $param{$p};
 401             } elsif ($p eq 'errfunc') {
 402                 $errfunc = $param{$p};
 403             } elsif ($p eq 'logfunc') {
 404                 $logfunc = $param{$p};
 405             } elsif ($p eq 'afterfork') {
 406                 $afterfork = $param{$p};
 407             } elsif ($p eq 'noerr') {
 408                 $noerr = $param{$p};
 409             } elsif ($p eq 'keeplocale') {
 410                 $keeplocale = $param{$p};
 411             } elsif ($p eq 'quiet') {
 412                 $quiet = $param{$p};
 413             } else {
 414                 die "got unknown parameter '$p' for run_command\n";
 415             }
 416         }
 417
 418         if ($errmsg) {
 419             my $origerrfunc = $errfunc;
 420             $errfunc = sub {
 421                 if ($laststderr) {
 422                     if ($origerrfunc) {
 423                         &$origerrfunc("$laststderr\n");
 424                     } else {
 425                         print STDERR "$laststderr\n" if $laststderr;
 426                     }
 427                 }
 428                 $laststderr = shift;
 429             };
 430         }
 431
 432         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 433         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 434         my $error  = IO::File->new();
 435
 436         my $orig_pid = $$;
 437
 438         eval {
 439             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 440
 441             # suppress LVM warnings like: "File descriptor 3 left open";
 442             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 443
 444             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 445
 446             # if we pipe fron STDIN, open3 closes STDIN, so we we
 447             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
 448             # as soon as we open a new file.
 449             # to avoid that we open /dev/null
 450             if (!ref($writer) && !defined(fileno(STDIN))) {
 451                 POSIX::close(0);
 452                 open(STDIN, "</dev/null");
 453             }
 454         };
 455
 456         my $err = $@;
 457
 458         # catch exec errors
 459         if ($orig_pid != $$) {
 460             warn "ERROR: $err";
 461             POSIX::_exit (1);
 462             kill ('KILL', $$);
 463         }
 464
 465         die $err if $err;
 466
 467         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 468         $oldtimeout = alarm($timeout) if $timeout;
 469
 470         &$afterfork() if $afterfork;
 471
 472         if (ref($writer)) {
 473             print $writer $input if defined $input;
 474             close $writer;
 475         }
 476
 477         my $select = new IO::Select;
 478         $select->add($reader) if ref($reader);
 479         $select->add($error);
 480
 481         my $outlog = '';
 482         my $errlog = '';
 483
 484         my $starttime = time();
 485
 486         while ($select->count) {
 487             my @handles = $select->can_read(1);
 488
 489             foreach my $h (@handles) {
 490                 my $buf = '';
 491                 my $count = sysread ($h, $buf, 4096);
 492                 if (!defined ($count)) {
 493                     my $err = $!;
 494                     kill (9, $pid);
 495                     waitpid ($pid, 0);
 496                     die $err;
 497                 }
 498                 $select->remove ($h) if !$count;
 499                 if ($h eq $reader) {
 500                     if ($outfunc || $logfunc) {
 501                         eval {
 502                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 503                                 my $line = $outlog . $1;
 504                                 $outlog = '';
 505                                 &$outfunc($line) if $outfunc;
 506                                 &$logfunc($line) if $logfunc;
 507                             }
 508                             $outlog .= $buf;
 509                         };
 510                         my $err = $@;
 511                         if ($err) {
 512                             kill (9, $pid);
 513                             waitpid ($pid, 0);
 514                             die $err;
 515                         }
 516                     } elsif (!$quiet) {
 517                         print $buf;
 518                         *STDOUT->flush();
 519                     }
 520                 } elsif ($h eq $error) {
 521                     if ($errfunc || $logfunc) {
 522                         eval {
 523                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 524                                 my $line = $errlog . $1;
 525                                 $errlog = '';
 526                                 &$errfunc($line) if $errfunc;
 527                                 &$logfunc($line) if $logfunc;
 528                             }
 529                             $errlog .= $buf;
 530                         };
 531                         my $err = $@;
 532                         if ($err) {
 533                             kill (9, $pid);
 534                             waitpid ($pid, 0);
 535                             die $err;
 536                         }
 537                     } elsif (!$quiet) {
 538                         print STDERR $buf;
 539                         *STDERR->flush();
 540                     }
 541                 }
 542             }
 543         }
 544
 545         &$outfunc($outlog) if $outfunc && $outlog;
 546         &$logfunc($outlog) if $logfunc && $outlog;
 547
 548         &$errfunc($errlog) if $errfunc && $errlog;
 549         &$logfunc($errlog) if $logfunc && $errlog;
 550
 551         waitpid ($pid, 0);
 552
 553         if ($? == -1) {
 554             die "failed to execute\n";
 555         } elsif (my $sig = ($? & 127)) {
 556             die "got signal $sig\n";
 557         } elsif ($exitcode = ($? >> 8)) {
 558             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 559                 if ($errmsg && $laststderr) {
 560                     my $lerr = $laststderr;
 561                     $laststderr = undef;
 562                     die "$lerr\n";
 563                 }
 564                 die "exit code $exitcode\n";
 565             }
 566         }
 567
 568         alarm(0);
 569     };
 570
 571     my $err = $@;
 572
 573     alarm(0);
 574
 575     if ($errmsg && $laststderr) {
 576         &$errfunc(undef); # flush laststderr
 577     }
 578
 579     umask ($old_umask) if defined($old_umask);
 580
 581     alarm($oldtimeout) if $oldtimeout;
 582
 583     if ($err) {
 584         if ($pid && ($err eq "got timeout\n")) {
 585             kill (9, $pid);
 586             waitpid ($pid, 0);
 587             die "command '$cmdstr' failed: $err";
 588         }
 589
 590         if ($errmsg) {
 591             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 592             die "$errmsg: $err";
 593         } elsif(!$noerr) {
 594             die "command '$cmdstr' failed: $err";
 595         }
 596     }
 597
 598     return $exitcode;
 599 }
 600
 601 # Run a command with a tcp socket as standard input.
 602 sub pipe_socket_to_command  {
 603     my ($cmd, $ip, $port) = @_;
 604
 605     my $params = {
 606         Listen => 1,
 607         ReuseAddr => 1,
 608         Proto => &Socket::IPPROTO_TCP,
 609         GetAddrInfoFlags => 0,
 610         LocalAddr => $ip,
 611         LocalPort => $port,
 612     };
 613     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 614
 615     print "$ip\n$port\n"; # tell remote where to connect
 616     *STDOUT->flush();
 617
 618     alarm 0;
 619     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 620     alarm 30;
 621     my $client = $socket->accept; # Wait for a client
 622     alarm 0;
 623     close($socket);
 624
 625     # We want that the command talks over the TCP socket and takes
 626     # ownership of it, so that when it closes it the connection is
 627     # terminated, so we need to be able to close the socket. So we
 628     # can't really use PVE::Tools::run_command().
 629     my $pid = fork() // die "fork failed: $!\n";
 630     if (!$pid) {
 631         POSIX::dup2(fileno($client), 0);
 632         POSIX::dup2(fileno($client), 1);
 633         close($client);
 634         exec {$cmd->[0]} @$cmd or do {
 635             warn "exec failed: $!\n";
 636             POSIX::_exit(1);
 637         };
 638     }
 639
 640     close($client);
 641     if (waitpid($pid, 0) != $pid) {
 642         kill(15 => $pid); # if we got interrupted terminate the child
 643         my $count = 0;
 644         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 645             usleep(100000);
 646             $count++;
 647             kill(9 => $pid), last if $count > 300; # 30 second timeout
 648         }
 649     }
 650     if (my $sig = ($? & 127)) {
 651         die "got signal $sig\n";
 652     } elsif (my $exitcode = ($? >> 8)) {
 653         die "exit code $exitcode\n";
 654     }
 655
 656     return undef;
 657 }
 658
 659 sub split_list {
 660     my $listtxt = shift // '';
 661
 662     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 663
 664     $listtxt =~ s/[,;]/ /g;
 665     $listtxt =~ s/^\s+//;
 666
 667     my @data = split (/\s+/, $listtxt);
 668
 669     return @data;
 670 }
 671
 672 sub trim {
 673     my $txt = shift;
 674
 675     return $txt if !defined($txt);
 676
 677     $txt =~ s/^\s+//;
 678     $txt =~ s/\s+$//;
 679
 680     return $txt;
 681 }
 682
 683 # simple uri templates like "/vms/{vmid}"
 684 sub template_replace {
 685     my ($tmpl, $data) = @_;
 686
 687     return $tmpl if !$tmpl;
 688
 689     my $res = '';
 690     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 691         $res .= $1 if $1;
 692         $res .= ($data->{$3} || '-') if $2;
 693     }
 694     return $res;
 695 }
 696
 697 sub safe_print {
 698     my ($filename, $fh, $data) = @_;
 699
 700     return if !$data;
 701
 702     my $res = print $fh $data;
 703
 704     die "write to '$filename' failed\n" if !$res;
 705 }
 706
 707 sub debmirrors {
 708
 709     return {
 710         'at' => 'ftp.at.debian.org',
 711         'au' => 'ftp.au.debian.org',
 712         'be' => 'ftp.be.debian.org',
 713         'bg' => 'ftp.bg.debian.org',
 714         'br' => 'ftp.br.debian.org',
 715         'ca' => 'ftp.ca.debian.org',
 716         'ch' => 'ftp.ch.debian.org',
 717         'cl' => 'ftp.cl.debian.org',
 718         'cz' => 'ftp.cz.debian.org',
 719         'de' => 'ftp.de.debian.org',
 720         'dk' => 'ftp.dk.debian.org',
 721         'ee' => 'ftp.ee.debian.org',
 722         'es' => 'ftp.es.debian.org',
 723         'fi' => 'ftp.fi.debian.org',
 724         'fr' => 'ftp.fr.debian.org',
 725         'gr' => 'ftp.gr.debian.org',
 726         'hk' => 'ftp.hk.debian.org',
 727         'hr' => 'ftp.hr.debian.org',
 728         'hu' => 'ftp.hu.debian.org',
 729         'ie' => 'ftp.ie.debian.org',
 730         'is' => 'ftp.is.debian.org',
 731         'it' => 'ftp.it.debian.org',
 732         'jp' => 'ftp.jp.debian.org',
 733         'kr' => 'ftp.kr.debian.org',
 734         'mx' => 'ftp.mx.debian.org',
 735         'nl' => 'ftp.nl.debian.org',
 736         'no' => 'ftp.no.debian.org',
 737         'nz' => 'ftp.nz.debian.org',
 738         'pl' => 'ftp.pl.debian.org',
 739         'pt' => 'ftp.pt.debian.org',
 740         'ro' => 'ftp.ro.debian.org',
 741         'ru' => 'ftp.ru.debian.org',
 742         'se' => 'ftp.se.debian.org',
 743         'si' => 'ftp.si.debian.org',
 744         'sk' => 'ftp.sk.debian.org',
 745         'tr' => 'ftp.tr.debian.org',
 746         'tw' => 'ftp.tw.debian.org',
 747         'gb' => 'ftp.uk.debian.org',
 748         'us' => 'ftp.us.debian.org',
 749     };
 750 }
 751
 752 my $keymaphash =  {
 753     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 754     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 755     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 756     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 757     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 758     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 759     #'et'     => [], # Ethopia or Estonia ??
 760     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 761     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 762     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 763     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 764     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 765     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 766     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 767     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 768     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 769     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 770     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 771     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 772     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 773     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 774     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 775     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 776     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 777     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 778     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 779     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 780     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 781     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 782     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 783     #'th'     => [],
 784     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 785 };
 786
 787 my $kvmkeymaparray = [];
 788 foreach my $lc (sort keys %$keymaphash) {
 789     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 790 }
 791
 792 sub kvmkeymaps {
 793     return $keymaphash;
 794 }
 795
 796 sub kvmkeymaplist {
 797     return $kvmkeymaparray;
 798 }
 799
 800 sub extract_param {
 801     my ($param, $key) = @_;
 802
 803     my $res = $param->{$key};
 804     delete $param->{$key};
 805
 806     return $res;
 807 }
 808
 809 # Note: we use this to wait until vncterm/spiceterm is ready
 810 sub wait_for_vnc_port {
 811     my ($port, $family, $timeout) = @_;
 812
 813     $timeout = 5 if !$timeout;
 814     my $sleeptime = 0;
 815     my $starttime = [gettimeofday];
 816     my $elapsed;
 817
 818     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 819     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 820
 821     my $found;
 822     while (($elapsed = tv_interval($starttime)) < $timeout) {
 823         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 824         run_command($cmd, outfunc => sub {
 825             my $line = shift;
 826             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 827                 $found = 1 if ($port == $1);
 828             }
 829         });
 830         return 1 if $found;
 831         $sleeptime += 100000 if  $sleeptime < 1000000;
 832         usleep($sleeptime);
 833     }
 834
 835     die "Timeout while waiting for port '$port' to get ready!\n";
 836 }
 837
 838 sub next_unused_port {
 839     my ($range_start, $range_end, $family, $address) = @_;
 840
 841     # We use a file to register allocated ports.
 842     # Those registrations expires after $expiretime.
 843     # We use this to avoid race conditions between
 844     # allocation and use of ports.
 845
 846     my $filename = "/var/tmp/pve-reserved-ports";
 847
 848     my $code = sub {
 849
 850         my $expiretime = 5;
 851         my $ctime = time();
 852
 853         my $ports = {};
 854
 855         if (my $fh = IO::File->new ($filename, "r")) {
 856             while (my $line = <$fh>) {
 857                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 858                     my ($port, $timestamp) = ($1, $2);
 859                     if (($timestamp + $expiretime) > $ctime) {
 860                         $ports->{$port} = $timestamp; # not expired
 861                     }
 862                 }
 863             }
 864         }
 865
 866         my $newport;
 867         my %sockargs = (Listen => 5,
 868                         ReuseAddr => 1,
 869                         Family    => $family,
 870                         Proto     => IPPROTO_TCP,
 871                         GetAddrInfoFlags => 0);
 872         $sockargs{LocalAddr} = $address if defined($address);
 873
 874         for (my $p = $range_start; $p < $range_end; $p++) {
 875             next if $ports->{$p}; # reserved
 876
 877             $sockargs{LocalPort} = $p;
 878             my $sock = IO::Socket::IP->new(%sockargs);
 879
 880             if ($sock) {
 881                 close($sock);
 882                 $newport = $p;
 883                 $ports->{$p} = $ctime;
 884                 last;
 885             }
 886         }
 887
 888         my $data = "";
 889         foreach my $p (keys %$ports) {
 890             $data .= "$p $ports->{$p}\n";
 891         }
 892
 893         file_set_contents($filename, $data);
 894
 895         return $newport;
 896     };
 897
 898     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 899     die $@ if $@;
 900
 901     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 902
 903     return $p;
 904 }
 905
 906 sub next_migrate_port {
 907     my ($family, $address) = @_;
 908     return next_unused_port(60000, 60050, $family, $address);
 909 }
 910
 911 sub next_vnc_port {
 912     my ($family, $address) = @_;
 913     return next_unused_port(5900, 6000, $family, $address);
 914 }
 915
 916 sub spice_port_range {
 917     return (61000, 61999);
 918 }
 919
 920 sub next_spice_port {
 921     my ($family, $address) = @_;
 922     return next_unused_port(spice_port_range(), $family, $address);
 923 }
 924
 925 sub must_stringify {
 926         my ($value) = @_;
 927         eval { $value = "$value" };
 928         return "error turning value into a string: $@" if $@;
 929         return $value;
 930 }
 931
 932 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 933 # the $sub has to return a single scalar
 934 sub run_fork_with_timeout {
 935     my ($timeout, $sub) = @_;
 936
 937     my $res;
 938     my $error;
 939     my $pipe_out = IO::Pipe->new();
 940
 941     # disable pending alarms, save their remaining time
 942     my $prev_alarm = alarm 0;
 943
 944     # avoid leaving a zombie if the parent gets interrupted
 945     my $sig_received;
 946
 947     my $child = fork();
 948     if (!defined($child)) {
 949         die "fork failed: $!\n";
 950         return $res;
 951     }
 952
 953     if (!$child) {
 954         $pipe_out->writer();
 955
 956         eval {
 957             $res = $sub->();
 958             print {$pipe_out} encode_json({ result => $res });
 959             $pipe_out->flush();
 960         };
 961         if (my $err = $@) {
 962             print {$pipe_out} encode_json({ error => must_stringify($err) });
 963             $pipe_out->flush();
 964             POSIX::_exit(1);
 965         }
 966         POSIX::_exit(0);
 967     }
 968
 969     local $SIG{INT} = sub { $sig_received++; };
 970     local $SIG{TERM} = sub {
 971         $error //= "interrupted by unexpected signal\n";
 972         kill('TERM', $child);
 973     };
 974
 975     $pipe_out->reader();
 976
 977     my $readvalues = sub {
 978         local $/ = undef;
 979         my $child_res = decode_json(readline_nointr($pipe_out));
 980         $res = $child_res->{result};
 981         $error = $child_res->{error};
 982     };
 983     eval {
 984         if (defined($timeout)) {
 985             run_with_timeout($timeout, $readvalues);
 986         } else {
 987             $readvalues->();
 988         }
 989     };
 990     warn $@ if $@;
 991     $pipe_out->close();
 992     kill('KILL', $child);
 993     waitpid($child, 0);
 994
 995     alarm $prev_alarm;
 996     die "interrupted by unexpected signal\n" if $sig_received;
 997
 998     die $error if $error;
 999     return $res;
1000 }
1001
1002 sub run_fork {
1003     my ($code) = @_;
1004     return run_fork_with_timeout(undef, $code);
1005 }
1006
1007 # NOTE: NFS syscall can't be interrupted, so alarm does
1008 # not work to provide timeouts.
1009 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1010 # So fork() before using Filesys::Df
1011 sub df {
1012     my ($path, $timeout) = @_;
1013
1014     my $df = sub { return Filesys::Df::df($path, 1) };
1015
1016     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1017     warn $@ if $@;
1018
1019     # untaint, but be flexible: PB usage can result in scientific notation
1020     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1021         $res->@{qw(blocks used bavail)};
1022
1023     return {
1024         total => $blocks,
1025         used => $used,
1026         avail => $bavail,
1027     };
1028 }
1029
1030 sub du {
1031     my ($path, $timeout) = @_;
1032
1033     my $size;
1034
1035     $timeout //= 10;
1036
1037     my $parser = sub {
1038         my $line = shift;
1039
1040         if ($line =~ m/^(\d+)\s+total$/) {
1041             $size = $1;
1042         }
1043     };
1044
1045     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1046
1047     return $size;
1048 }
1049
1050 # UPID helper
1051 # We use this to uniquely identify a process.
1052 # An 'Unique Process ID' has the following format:
1053 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1054
1055 sub upid_encode {
1056     my $d = shift;
1057
1058     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1059     # more that 8 characters for pstart
1060     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1061                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1062                    $d->{user});
1063 }
1064
1065 sub upid_decode {
1066     my ($upid, $noerr) = @_;
1067
1068     my $res;
1069     my $filename;
1070
1071     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1072     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1073     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1074         $res->{node} = $1;
1075         $res->{pid} = hex($3);
1076         $res->{pstart} = hex($4);
1077         $res->{starttime} = hex($5);
1078         $res->{type} = $6;
1079         $res->{id} = $7;
1080         $res->{user} = $8;
1081
1082         my $subdir = substr($5, 7, 8);
1083         $filename = "$pvetaskdir/$subdir/$upid";
1084
1085     } else {
1086         return undef if $noerr;
1087         die "unable to parse worker upid '$upid'\n";
1088     }
1089
1090     return wantarray ? ($res, $filename) : $res;
1091 }
1092
1093 sub upid_open {
1094     my ($upid) = @_;
1095
1096     my ($task, $filename) = upid_decode($upid);
1097
1098     my $dirname = dirname($filename);
1099     make_path($dirname);
1100
1101     my $wwwid = getpwnam('www-data') ||
1102         die "getpwnam failed";
1103
1104     my $perm = 0640;
1105
1106     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1107         die "unable to create output file '$filename' - $!\n";
1108     chown $wwwid, -1, $outfh;
1109
1110     return $outfh;
1111 };
1112
1113 sub upid_read_status {
1114     my ($upid) = @_;
1115
1116     my ($task, $filename) = upid_decode($upid);
1117     my $fh = IO::File->new($filename, "r");
1118     return "unable to open file - $!" if !$fh;
1119     my $maxlen = 4096;
1120     sysseek($fh, -$maxlen, 2);
1121     my $readbuf = '';
1122     my $br = sysread($fh, $readbuf, $maxlen);
1123     close($fh);
1124     if ($br) {
1125         return "unable to extract last line"
1126             if $readbuf !~ m/\n?(.+)$/;
1127         my $line = $1;
1128         if ($line =~ m/^TASK OK$/) {
1129             return 'OK';
1130         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1131             return $1;
1132         } else {
1133             return "unexpected status";
1134         }
1135     }
1136     return "unable to read tail (got $br bytes)";
1137 }
1138
1139 # useful functions to store comments in config files
1140 sub encode_text {
1141     my ($text) = @_;
1142
1143     # all control and hi-bit characters, and ':'
1144     my $unsafe = "^\x20-\x39\x3b-\x7e";
1145     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1146 }
1147
1148 sub decode_text {
1149     my ($data) = @_;
1150
1151     return Encode::decode("utf8", uri_unescape($data));
1152 }
1153
1154 # depreciated - do not use!
1155 # we now decode all parameters by default
1156 sub decode_utf8_parameters {
1157     my ($param) = @_;
1158
1159     foreach my $p (qw(comment description firstname lastname)) {
1160         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1161     }
1162
1163     return $param;
1164 }
1165
1166 sub random_ether_addr {
1167     my ($prefix) = @_;
1168
1169     my ($seconds, $microseconds) = gettimeofday;
1170
1171     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1172
1173     # clear multicast, set local id
1174     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1175
1176     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1177     if (defined($prefix)) {
1178         $addr = uc($prefix) . substr($addr, length($prefix));
1179     }
1180     return $addr;
1181 }
1182
1183 sub shellquote {
1184     my $str = shift;
1185
1186     return String::ShellQuote::shell_quote($str);
1187 }
1188
1189 sub cmd2string {
1190     my ($cmd) = @_;
1191
1192     die "no arguments" if !$cmd;
1193
1194     return $cmd if !ref($cmd);
1195
1196     my @qa = ();
1197     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1198
1199     return join (' ', @qa);
1200 }
1201
1202 # split an shell argument string into an array,
1203 sub split_args {
1204     my ($str) = @_;
1205
1206     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1207 }
1208
1209 sub dump_logfile {
1210     my ($filename, $start, $limit, $filter) = @_;
1211
1212     my $lines = [];
1213     my $count = 0;
1214
1215     my $fh = IO::File->new($filename, "r");
1216     if (!$fh) {
1217         $count++;
1218         push @$lines, { n => $count, t => "unable to open file - $!"};
1219         return ($count, $lines);
1220     }
1221
1222     $start = 0 if !$start;
1223     $limit = 50 if !$limit;
1224
1225     my $line;
1226
1227     if ($filter) {
1228         # duplicate code, so that we do not slow down normal path
1229         while (defined($line = <$fh>)) {
1230             next if $line !~ m/$filter/;
1231             next if $count++ < $start;
1232             next if $limit <= 0;
1233             chomp $line;
1234             push @$lines, { n => $count, t => $line};
1235             $limit--;
1236         }
1237     } else {
1238         while (defined($line = <$fh>)) {
1239             next if $count++ < $start;
1240             next if $limit <= 0;
1241             chomp $line;
1242             push @$lines, { n => $count, t => $line};
1243             $limit--;
1244         }
1245     }
1246
1247     close($fh);
1248
1249     # HACK: ExtJS store.guaranteeRange() does not like empty array
1250     # so we add a line
1251     if (!$count) {
1252         $count++;
1253         push @$lines, { n => $count, t => "no content"};
1254     }
1255
1256     return ($count, $lines);
1257 }
1258
1259 sub dump_journal {
1260     my ($start, $limit, $since, $until, $service) = @_;
1261
1262     my $lines = [];
1263     my $count = 0;
1264
1265     $start = 0 if !$start;
1266     $limit = 50 if !$limit;
1267
1268     my $parser = sub {
1269         my $line = shift;
1270
1271         return if $count++ < $start;
1272         return if $limit <= 0;
1273         push @$lines, { n => int($count), t => $line};
1274         $limit--;
1275     };
1276
1277     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1278
1279     push @$cmd, '--unit', $service if $service;
1280     push @$cmd, '--since', $since if $since;
1281     push @$cmd, '--until', $until if $until;
1282     run_command($cmd, outfunc => $parser);
1283
1284     # HACK: ExtJS store.guaranteeRange() does not like empty array
1285     # so we add a line
1286     if (!$count) {
1287         $count++;
1288         push @$lines, { n => $count, t => "no content"};
1289     }
1290
1291     return ($count, $lines);
1292 }
1293
1294 sub dir_glob_regex {
1295     my ($dir, $regex) = @_;
1296
1297     my $dh = IO::Dir->new ($dir);
1298     return wantarray ? () : undef if !$dh;
1299
1300     while (defined(my $tmp = $dh->read)) {
1301         if (my @res = $tmp =~ m/^($regex)$/) {
1302             $dh->close;
1303             return wantarray ? @res : $tmp;
1304         }
1305     }
1306     $dh->close;
1307
1308     return wantarray ? () : undef;
1309 }
1310
1311 sub dir_glob_foreach {
1312     my ($dir, $regex, $func) = @_;
1313
1314     my $dh = IO::Dir->new ($dir);
1315     if (defined $dh) {
1316         while (defined(my $tmp = $dh->read)) {
1317             if (my @res = $tmp =~ m/^($regex)$/) {
1318                 &$func (@res);
1319             }
1320         }
1321     }
1322 }
1323
1324 sub assert_if_modified {
1325     my ($digest1, $digest2) = @_;
1326
1327     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1328         die "detected modified configuration - file changed by other user? Try again.\n";
1329     }
1330 }
1331
1332 # Digest for short strings
1333 # like FNV32a, but we only return 31 bits (positive numbers)
1334 sub fnv31a {
1335     my ($string) = @_;
1336
1337     my $hval = 0x811c9dc5;
1338
1339     foreach my $c (unpack('C*', $string)) {
1340         $hval ^= $c;
1341         $hval += (
1342             (($hval << 1) ) +
1343             (($hval << 4) ) +
1344             (($hval << 7) ) +
1345             (($hval << 8) ) +
1346             (($hval << 24) ) );
1347         $hval = $hval & 0xffffffff;
1348     }
1349     return $hval & 0x7fffffff;
1350 }
1351
1352 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1353
1354 sub unpack_sockaddr_in46 {
1355     my ($sin) = @_;
1356     my $family = Socket::sockaddr_family($sin);
1357     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1358                                              : Socket::unpack_sockaddr_in($sin));
1359     return ($family, $port, $host);
1360 }
1361
1362 sub getaddrinfo_all {
1363     my ($hostname, @opts) = @_;
1364     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1365                   @opts );
1366     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1367     die "failed to get address info for: $hostname: $err\n" if $err;
1368     return @res;
1369 }
1370
1371 sub get_host_address_family {
1372     my ($hostname, $socktype) = @_;
1373     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1374     return $res[0]->{family};
1375 }
1376
1377 # get the fully qualified domain name of a host
1378 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1379 # given a nodename as a parameter
1380 sub get_fqdn {
1381     my ($nodename) = @_;
1382
1383     my $hints = {
1384         flags => AI_CANONNAME,
1385         socktype => SOCK_DGRAM
1386     };
1387
1388     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1389
1390     die "getaddrinfo: $err" if $err;
1391
1392     return $addrs[0]->{canonname};
1393 }
1394
1395 # Parses any sane kind of host, or host+port pair:
1396 # The port is always optional and thus may be undef.
1397 sub parse_host_and_port {
1398     my ($address) = @_;
1399     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1400         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1401         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1402     {
1403         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1404     }
1405     return; # nothing
1406 }
1407
1408 sub setresuid($$$) {
1409     my ($ruid, $euid, $suid) = @_;
1410     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1411 }
1412
1413 sub unshare($) {
1414     my ($flags) = @_;
1415     return 0 == syscall(PVE::Syscall::unshare, $flags);
1416 }
1417
1418 sub setns($$) {
1419     my ($fileno, $nstype) = @_;
1420     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1421 }
1422
1423 sub syncfs($) {
1424     my ($fileno) = @_;
1425     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1426 }
1427
1428 sub fsync($) {
1429     my ($fileno) = @_;
1430     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1431 }
1432
1433 sub sync_mountpoint {
1434     my ($path) = @_;
1435     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1436     my $result = syncfs(fileno($fd));
1437     close($fd);
1438     return $result;
1439 }
1440
1441 # support sending multi-part mail messages with a text and or a HTML part
1442 # mailto may be a single email string or an array of receivers
1443 sub sendmail {
1444     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1445     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1446
1447     $mailto = [ $mailto ] if !ref($mailto);
1448
1449     foreach (@$mailto) {
1450         die "illegal character in mailto address\n"
1451             if ($_ =~ $mail_re);
1452     }
1453
1454     my $rcvrtxt = join (', ', @$mailto);
1455
1456     $mailfrom = $mailfrom || "root";
1457     die "illegal character in mailfrom address\n"
1458         if $mailfrom =~ $mail_re;
1459
1460     $author = $author || 'Proxmox VE';
1461
1462     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, "--", @$mailto) ||
1463         die "unable to open 'sendmail' - $!";
1464
1465     my $date = time2str('%a, %d %b %Y %H:%M:%S %z', time());
1466
1467     my $is_multipart = $text && $html;
1468
1469     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1470     my $boundary = "----_=_NextPart_001_".int(time).$$;
1471
1472     if ($subject =~ /[^[:ascii:]]/) {
1473         $subject = Encode::encode('MIME-Header', $subject);
1474     }
1475
1476     if ($subject =~ /[^[:ascii:]]/ || $is_multipart) {
1477         print MAIL "MIME-Version: 1.0\n";
1478     }
1479     print MAIL "From: $author <$mailfrom>\n";
1480     print MAIL "To: $rcvrtxt\n";
1481     print MAIL "Date: $date\n";
1482     print MAIL "Subject: $subject\n";
1483
1484     if ($is_multipart) {
1485         print MAIL "Content-Type: multipart/alternative;\n";
1486         print MAIL "\tboundary=\"$boundary\"\n";
1487         print MAIL "\n";
1488         print MAIL "This is a multi-part message in MIME format.\n\n";
1489         print MAIL "--$boundary\n";
1490     }
1491
1492     if (defined($text)) {
1493         print MAIL "Content-Type: text/plain;\n";
1494         print MAIL "\tcharset=\"UTF-8\"\n";
1495         print MAIL "Content-Transfer-Encoding: 8bit\n";
1496         print MAIL "\n";
1497
1498         # avoid 'remove extra line breaks' issue (MS Outlook)
1499         my $fill = '  ';
1500         $text =~ s/^/$fill/gm;
1501
1502         print MAIL $text;
1503
1504         print MAIL "\n--$boundary\n" if $is_multipart;
1505     }
1506
1507     if (defined($html)) {
1508         print MAIL "Content-Type: text/html;\n";
1509         print MAIL "\tcharset=\"UTF-8\"\n";
1510         print MAIL "Content-Transfer-Encoding: 8bit\n";
1511         print MAIL "\n";
1512
1513         print MAIL $html;
1514
1515         print MAIL "\n--$boundary--\n" if $is_multipart;
1516     }
1517
1518     close(MAIL);
1519 }
1520
1521 sub tempfile {
1522     my ($perm, %opts) = @_;
1523
1524     # default permissions are stricter than with file_set_contents
1525     $perm = 0600 if !defined($perm);
1526
1527     my $dir = $opts{dir} // '/run';
1528     my $mode = $opts{mode} // O_RDWR;
1529     $mode |= O_EXCL if !$opts{allow_links};
1530
1531     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1532     if (!$fh && $! == EOPNOTSUPP) {
1533         $dir = '/tmp' if !defined($opts{dir});
1534         $dir .= "/.tmpfile.$$";
1535         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1536         unlink($dir) if $fh;
1537     }
1538     die "failed to create tempfile: $!\n" if !$fh;
1539     return $fh;
1540 }
1541
1542 sub tempfile_contents {
1543     my ($data, $perm, %opts) = @_;
1544
1545     my $fh = tempfile($perm, %opts);
1546     eval {
1547         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1548         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1549     };
1550     if (my $err = $@) {
1551         close $fh;
1552         die $err;
1553     }
1554
1555     return ("/proc/$$/fd/".$fh->fileno, $fh);
1556 }
1557
1558 sub validate_ssh_public_keys {
1559     my ($raw) = @_;
1560     my @lines = split(/\n/, $raw);
1561
1562     foreach my $line (@lines) {
1563         next if $line =~ m/^\s*$/;
1564         eval {
1565             my ($filename, $handle) = tempfile_contents($line);
1566             run_command(["ssh-keygen", "-l", "-f", $filename],
1567                         outfunc => sub {}, errfunc => sub {});
1568         };
1569         die "SSH public key validation error\n" if $@;
1570     }
1571 }
1572
1573 sub openat($$$;$) {
1574     my ($dirfd, $pathname, $flags, $mode) = @_;
1575     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1576     return undef if $fd < 0;
1577     # sysopen() doesn't deal with numeric file descriptors apparently
1578     # so we need to convert to a mode string for IO::Handle->new_from_fd
1579     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1580     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1581     return $handle if $handle;
1582     my $err = $!; # save error before closing the raw fd
1583     syscall(PVE::Syscall::close, $fd); # close
1584     $! = $err;
1585     return undef;
1586 }
1587
1588 sub mkdirat($$$) {
1589     my ($dirfd, $name, $mode) = @_;
1590     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1591 }
1592
1593 sub fchownat($$$$$) {
1594     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1595     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1596 }
1597
1598 my $salt_starter = time();
1599
1600 sub encrypt_pw {
1601     my ($pw) = @_;
1602
1603     $salt_starter++;
1604     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1605
1606     # crypt does not want '+' in salt (see 'man crypt')
1607     $salt =~ s/\+/X/g;
1608
1609     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1610 }
1611
1612 # intended usage: convert_size($val, "kb" => "gb")
1613 # we round up to the next integer by default
1614 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1615 # use $no_round_up to switch this off, above example would then return 0
1616 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1617 # (0 if $no_round_up is true)
1618 # allowed formats for value:
1619 # 1234
1620 # 1234.
1621 # 1234.1234
1622 # .1234
1623 sub convert_size {
1624     my ($value, $from, $to, $no_round_up) = @_;
1625
1626     my $units = {
1627         b  => 0,
1628         kb => 1,
1629         mb => 2,
1630         gb => 3,
1631         tb => 4,
1632         pb => 5,
1633     };
1634
1635     die "no value given"
1636         if !defined($value) || $value eq "";
1637
1638     $from = lc($from // ''); $to = lc($to // '');
1639     die "unknown 'from' and/or 'to' units ($from => $to)"
1640         if !defined($units->{$from}) || !defined($units->{$to});
1641
1642     die "value '$value' is not a valid, positive number"
1643         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1644
1645     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1646
1647     $value *= 2**$shift_amount;
1648     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1649
1650     return int($value);
1651 }
1652
1653 # uninterruptible readline
1654 # retries on EINTR
1655 sub readline_nointr {
1656     my ($fh) = @_;
1657     my $line;
1658     while (1) {
1659         $line = <$fh>;
1660         last if defined($line) || ($! != EINTR);
1661     }
1662     return $line;
1663 }
1664
1665 my $host_arch;
1666 sub get_host_arch {
1667     $host_arch = (POSIX::uname())[4] if !$host_arch;
1668     return $host_arch;
1669 }
1670
1671 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1672 sub dev_t_major($) {
1673     my ($dev_t) = @_;
1674     return (int($dev_t) & 0xfff00) >> 8;
1675 }
1676
1677 sub dev_t_minor($) {
1678     my ($dev_t) = @_;
1679     $dev_t = int($dev_t);
1680     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1681 }
1682
1683 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1684 # Returns the intersection of elements as a single array [a b]
1685 sub array_intersect {
1686     my ($arrays) = @_;
1687
1688     if (!ref($arrays->[0])) {
1689         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1690     }
1691
1692     return [] if scalar(@$arrays) == 0;
1693     return $arrays->[0] if scalar(@$arrays) == 1;
1694
1695     my $array_unique = sub {
1696         my %seen = ();
1697         return grep { ! $seen{ $_ }++ } @_;
1698     };
1699
1700     # base idea is to get all unique members from the first array, then
1701     # check the common elements with the next (uniquely made) one, only keep
1702     # those. Repeat for every array and at the end we only have those left
1703     # which exist in all arrays
1704     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1705     for my $i (1 .. $#$arrays) {
1706         my %count = ();
1707         # $return_arr is already unique, explicit at before the loop, implicit below.
1708         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1709             $count{$element}++;
1710         }
1711         $return_arr = [];
1712         foreach my $element (keys %count) {
1713             push @$return_arr, $element if $count{$element} > 1;
1714         }
1715         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1716     }
1717
1718     return $return_arr;
1719 }
1720
1721 sub open_tree($$$) {
1722     my ($dfd, $pathname, $flags) = @_;
1723     return PVE::Syscall::file_handle_result(syscall(
1724         &PVE::Syscall::open_tree,
1725         $dfd,
1726         $pathname,
1727         $flags,
1728     ));
1729 }
1730
1731 sub move_mount($$$$$) {
1732     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1733     return 0 == syscall(
1734         &PVE::Syscall::move_mount,
1735         $from_dirfd,
1736         $from_pathname,
1737         $to_dirfd,
1738         $to_pathname,
1739         $flags,
1740     );
1741 }
1742
1743 sub fsopen($$) {
1744     my ($fsname, $flags) = @_;
1745     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
1746 }
1747
1748 sub fsmount($$$) {
1749     my ($fd, $flags, $mount_attrs) = @_;
1750     return PVE::Syscall::file_handle_result(syscall(
1751         &PVE::Syscall::fsmount,
1752         $fd,
1753         $flags,
1754         $mount_attrs,
1755     ));
1756 }
1757
1758 sub fspick($$$) {
1759     my ($dirfd, $pathname, $flags) = @_;
1760     return PVE::Syscall::file_handle_result(syscall(
1761         &PVE::Syscall::fspick,
1762         $dirfd,
1763         $pathname,
1764         $flags,
1765     ));
1766 }
1767
1768 sub fsconfig($$$$$) {
1769     my ($fd, $command, $key, $value, $aux) = @_;
1770     return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
1771 }
1772
1773 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1774 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1775 sub mount($$$$$) {
1776     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1777     return 0 == syscall(
1778         &PVE::Syscall::mount,
1779         $source,
1780         $target,
1781         $filesystemtype,
1782         $mountflags,
1783         $data,
1784     );
1785 }
1786
1787 sub safe_compare {
1788     my ($left, $right, $cmp) = @_;
1789
1790     return 0 if !defined($left) && !defined($right);
1791     return -1 if !defined($left);
1792     return 1 if !defined($right);
1793     return $cmp->($left, $right);
1794 }
1795
1796 1;