bump version to 4.1-1
[pve-container.git] / src / PVE / LXC.pm
1 package PVE::LXC;
2
3 use strict;
4 use warnings;
5
6 use POSIX qw(EINTR);
7
8 use Socket;
9
10 use File::Path;
11 use File::Spec;
12 use Cwd qw();
13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
15 use IO::Socket::UNIX;
16
17 use PVE::Exception qw(raise_perm_exc);
18 use PVE::Storage;
19 use PVE::SafeSyslog;
20 use PVE::INotify;
21 use PVE::JSONSchema qw(get_standard_option);
22 use PVE::Tools qw(
23 run_command
24 dir_glob_foreach
25 file_get_contents
26 file_set_contents
27 AT_FDCWD
28 O_PATH
29 $IPV4RE
30 $IPV6RE
31 );
32 use PVE::CpuSet;
33 use PVE::Network;
34 use PVE::AccessControl;
35 use PVE::ProcFSTools;
36 use PVE::Syscall qw(:fsmount);
37 use PVE::LXC::Config;
38 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
39 use PVE::LXC::Tools;
40 use PVE::LXC::CGroup;
41 use PVE::LXC::Monitor;
42 use PVE::CGroup;
43
44 use Time::HiRes qw (gettimeofday);
45 my $have_sdn;
46 eval {
47 require PVE::Network::SDN::Zones;
48 $have_sdn = 1;
49 };
50
51 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
52
53 my $nodename = PVE::INotify::nodename();
54
55 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
56
57 sub config_list {
58 my $vmlist = PVE::Cluster::get_vmlist();
59 my $res = {};
60 return $res if !$vmlist || !$vmlist->{ids};
61 my $ids = $vmlist->{ids};
62
63 foreach my $vmid (keys %$ids) {
64 next if !$vmid; # skip CT0
65 my $d = $ids->{$vmid};
66 next if !$d->{node} || $d->{node} ne $nodename;
67 next if !$d->{type} || $d->{type} ne 'lxc';
68 $res->{$vmid} = { type => 'lxc', vmid => $vmid };
69 }
70 return $res;
71 }
72
73 # container status helpers
74
75 sub list_active_containers {
76
77 my $filename = "/proc/net/unix";
78
79 # similar test is used by lcxcontainers.c: list_active_containers
80 my $res = {};
81
82 my $fh = IO::File->new ($filename, "r");
83 return $res if !$fh;
84
85 while (defined(my $line = <$fh>)) {
86 if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
87 my $path = $1;
88 if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
89 $res->{$1} = 1;
90 }
91 }
92 }
93
94 close($fh);
95
96 return $res;
97 }
98
99 # warning: this is slow
100 sub check_running {
101 my ($vmid) = @_;
102
103 my $active_hash = list_active_containers();
104
105 return 1 if defined($active_hash->{$vmid});
106
107 return undef;
108 }
109
110 sub get_container_disk_usage {
111 my ($vmid, $pid) = @_;
112
113 return PVE::Tools::df("/proc/$pid/root/", 1);
114 }
115
116 my $last_proc_vmid_stat;
117
118 our $vmstatus_return_properties = {
119 vmid => get_standard_option('pve-vmid'),
120 status => {
121 description => "LXC Container status.",
122 type => 'string',
123 enum => ['stopped', 'running'],
124 },
125 maxmem => {
126 description => "Maximum memory in bytes.",
127 type => 'integer',
128 optional => 1,
129 renderer => 'bytes',
130 },
131 maxswap => {
132 description => "Maximum SWAP memory in bytes.",
133 type => 'integer',
134 optional => 1,
135 renderer => 'bytes',
136 },
137 maxdisk => {
138 description => "Root disk size in bytes.",
139 type => 'integer',
140 optional => 1,
141 renderer => 'bytes',
142 },
143 name => {
144 description => "Container name.",
145 type => 'string',
146 optional => 1,
147 },
148 uptime => {
149 description => "Uptime.",
150 type => 'integer',
151 optional => 1,
152 renderer => 'duration',
153 },
154 cpus => {
155 description => "Maximum usable CPUs.",
156 type => 'number',
157 optional => 1,
158 },
159 lock => {
160 description => "The current config lock, if any.",
161 type => 'string',
162 optional => 1,
163 },
164 tags => {
165 description => "The current configured tags, if any.",
166 type => 'string',
167 optional => 1,
168 }
169 };
170
171 sub vmstatus {
172 my ($opt_vmid) = @_;
173
174 my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
175
176 my $active_hash = list_active_containers();
177
178 my $cpucount = $cpuinfo->{cpus} || 1;
179
180 my $cdtime = gettimeofday;
181
182 my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
183 my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
184
185 my $unprivileged = {};
186
187 foreach my $vmid (keys %$list) {
188 my $d = $list->{$vmid};
189
190 eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
191 warn $@ if $@; # ignore errors (consider them stopped)
192
193 $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
194
195 my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
196 my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
197
198 $unprivileged->{$vmid} = $conf->{unprivileged};
199
200 $d->{name} = $conf->{'hostname'} || "CT$vmid";
201 $d->{name} =~ s/[\s]//g;
202
203 $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
204 $d->{cpus} = $cpucount if !$d->{cpus};
205
206 $d->{tags} = $conf->{tags} if defined($conf->{tags});
207
208 if ($d->{pid}) {
209 my $res = get_container_disk_usage($vmid, $d->{pid});
210 $d->{disk} = $res->{used};
211 $d->{maxdisk} = $res->{total};
212 } else {
213 $d->{disk} = 0;
214 # use 4GB by default ??
215 if (my $rootfs = $conf->{rootfs}) {
216 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
217 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
218 } else {
219 $d->{maxdisk} = 4*1024*1024*1024;
220 }
221 }
222
223 $d->{mem} = 0;
224 $d->{swap} = 0;
225 $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
226 $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
227
228 $d->{uptime} = 0;
229 $d->{cpu} = 0;
230
231 $d->{netout} = 0;
232 $d->{netin} = 0;
233
234 $d->{diskread} = 0;
235 $d->{diskwrite} = 0;
236
237 $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
238 $d->{lock} = $conf->{lock} if $conf->{lock};
239 }
240
241 foreach my $vmid (keys %$list) {
242 my $d = $list->{$vmid};
243 my $pid = $d->{pid};
244
245 next if !$pid; # skip stopped CTs
246
247 my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
248 $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
249
250 my $unpriv = $unprivileged->{$vmid};
251
252 my $cgroups = PVE::LXC::CGroup->new($vmid);
253
254 if (defined(my $mem = $cgroups->get_memory_stat())) {
255 $d->{mem} = $mem->{mem};
256 $d->{swap} = $mem->{swap};
257 } else {
258 $d->{mem} = 0;
259 $d->{swap} = 0;
260 }
261
262 if (defined(my $blkio = $cgroups->get_io_stats())) {
263 $d->{diskread} = $blkio->{diskread};
264 $d->{diskwrite} = $blkio->{diskwrite};
265 } else {
266 $d->{diskread} = 0;
267 $d->{diskwrite} = 0;
268 }
269
270 if (defined(my $cpu = $cgroups->get_cpu_stat())) {
271 # Total time (in milliseconds) used up by the cpu.
272 my $used_ms = $cpu->{utime} + $cpu->{stime};
273
274 my $old = $last_proc_vmid_stat->{$vmid};
275 if (!$old) {
276 $last_proc_vmid_stat->{$vmid} = {
277 time => $cdtime,
278 used => $used_ms,
279 cpu => 0,
280 };
281 next;
282 }
283
284 my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
285 if ($delta_ms > 1000.0) {
286 my $delta_used_ms = $used_ms - $old->{used};
287 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
288 $last_proc_vmid_stat->{$vmid} = {
289 time => $cdtime,
290 used => $used_ms,
291 cpu => $d->{cpu},
292 };
293 } else {
294 $d->{cpu} = $old->{cpu};
295 }
296 } else {
297 $d->{cpu} = 0;
298 }
299 }
300
301 my $netdev = PVE::ProcFSTools::read_proc_net_dev();
302
303 foreach my $dev (keys %$netdev) {
304 next if $dev !~ m/^veth([1-9]\d*)i/;
305 my $vmid = $1;
306 my $d = $list->{$vmid};
307
308 next if !$d;
309
310 $d->{netout} += $netdev->{$dev}->{receive};
311 $d->{netin} += $netdev->{$dev}->{transmit};
312
313 }
314
315 return $list;
316 }
317
318 sub find_lxc_console_pids {
319
320 my $res = {};
321
322 PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
323 my ($pid) = @_;
324
325 my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
326 return if !$cmdline;
327
328 my @args = split(/\0/, $cmdline);
329
330 # search for lxc-console -n <vmid>
331 return if scalar(@args) != 3;
332 return if $args[1] ne '-n';
333 return if $args[2] !~ m/^\d+$/;
334 return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
335
336 my $vmid = $args[2];
337
338 push @{$res->{$vmid}}, $pid;
339 });
340
341 return $res;
342 }
343
344 sub find_lxc_pid {
345 my ($vmid) = @_;
346
347 my $pid = undef;
348 my $parser = sub {
349 my $line = shift;
350 $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
351 };
352 PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
353
354 die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
355
356 return $pid;
357 }
358
359 sub open_pid_fd($) {
360 my ($pid) = @_;
361 sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
362 or die "failed to open /proc/$pid pid fd\n";
363 return $fd;
364 }
365
366 sub open_lxc_pid {
367 my ($vmid) = @_;
368
369 # Find the pid and open:
370 my $pid = find_lxc_pid($vmid);
371 my $fd = open_pid_fd($pid);
372
373 # Verify:
374 my $pid2 = find_lxc_pid($vmid);
375
376 return () if $pid != $pid2;
377 return ($pid, $fd);
378 }
379
380 sub open_ppid {
381 my ($pid) = @_;
382
383 # Find the parent pid via proc and open it:
384 my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
385 my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
386
387 my $fd = open_pid_fd($ppid);
388
389 # Verify:
390 $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
391 my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
392
393 return () if $ppid != $ppid2;
394 return ($ppid, $fd);
395 }
396
397 # Note: we cannot use Net:IP, because that only allows strict
398 # CIDR networks
399 sub parse_ipv4_cidr {
400 my ($cidr, $noerr) = @_;
401
402 if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) && ($2 <= 32)) {
403 return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
404 }
405
406 return undef if $noerr;
407
408 die "unable to parse ipv4 address/mask\n";
409 }
410
411 # Deprecated. Use `PVE::CGroup::get_cgroup_controllers()` instead.
412 sub get_cgroup_subsystems {
413 PVE::CGroup::get_v1_controllers();
414 }
415
416 # With seccomp trap to userspace we now have the ability to optionally forward
417 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
418 #
419 # This means that there are cases where we need to create an extra seccomp
420 # profile for the container to load.
421 #
422 # This returns a configuration snippet added to the raw lxc config.
423 sub make_seccomp_config {
424 my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
425 # User-configured profile has precedence, note that the user's entry would
426 # be written 'after' this line anyway...
427 if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
428 # Warn the user if this conflicts with a feature:
429 my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
430 warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
431 if length($warn) > 0;
432 return '';
433 }
434
435 # Privileged containers keep using the default (which is already part of
436 # the files included via lxc.include, so we don't need to write it out,
437 # that way it stays admin-configurable via /usr/share/lxc/config/... as
438 # well)
439 return '' if !$unprivileged;
440
441 my $rules = {
442 keyctl => ['errno 38'],
443 };
444
445 my $raw_conf = '';
446
447 # Unprivileged containers will get keyctl() disabled by default as a
448 # workaround for systemd-networkd behavior. But we have an option to
449 # explicitly enable it:
450 if ($features->{keyctl}) {
451 delete $rules->{keyctl};
452 }
453
454 # By default, unprivileged containers cannot use `mknod` at all.
455 # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
456 # but for now this is experimental, so it has to be enabled via a feature
457 # flag.
458 # Note that we only handle block and char devices (like lxd), the rest we
459 # leave up to the kernel. We may in the future remove this if seccomp gets
460 # a way to tell the kernel to "continue" a syscall.
461 if ($features->{mknod}) {
462 my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
463 if (!$ok) {
464 die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
465 }
466
467 $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
468 $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
469
470 $rules->{mknod} = [
471 # condition: (mode & S_IFMT) == S_IFCHR
472 'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
473 # condition: (mode & S_IFMT) == S_IFBLK
474 'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
475 ];
476 $rules->{mknodat} = [
477 # condition: (mode & S_IFMT) == S_IFCHR
478 'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
479 # condition: (mode & S_IFMT) == S_IFBLK
480 'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
481 ];
482 }
483
484 # Now build the custom seccomp rule text...
485 my $extra_rules = join("\n", map {
486 my $syscall = $_;
487 map { "$syscall $_" } $rules->{$syscall}->@*
488 } sort keys %$rules) . "\n";
489
490 return $raw_conf if $extra_rules eq "\n";
491
492 # We still have the "most common" config readily available, so don't write
493 # out that one:
494 if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
495 # we have no extra $raw_conf and use the same we had in pve 6.1:
496 return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
497 }
498
499 # Write the rule file to the container's config path:
500 my $rule_file = "$conf_dir/rules.seccomp";
501 my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
502 . $extra_rules;
503 file_set_contents($rule_file, $rule_data);
504 $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
505
506 return $raw_conf;
507 }
508
509 # Since lxc-3.0.2 we can have lxc generate a profile for the container
510 # automatically. The default should be equivalent to the old
511 # `lxc-container-default-cgns` profile.
512 #
513 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
514 # additional lines into the profile. We can use that to allow mounting specific
515 # file systems.
516 sub make_apparmor_config {
517 my ($conf, $unprivileged, $features) = @_;
518
519 # user-configured profile has precedence, but first we go through our own
520 # code to figure out whether we should warn the user:
521
522 my $raw = "lxc.apparmor.profile = generated\n";
523 my @profile_uses;
524
525 if ($features->{fuse}) {
526 # For the informational warning:
527 push @profile_uses, 'features:fuse';
528 }
529
530 # There's lxc.apparmor.allow_nesting now, which will add the necessary
531 # apparmor lines, create an apparmor namespace for the container, but also
532 # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
533 # lxcfs mounted over them, because that would prevent the container from
534 # mounting new instances of them for nested containers.
535 if ($features->{nesting}) {
536 push @profile_uses, 'features:nesting';
537 $raw .= "lxc.apparmor.allow_nesting = 1\n"
538 } else {
539 # In the default profile in /etc/apparmor.d we patch this in because
540 # otherwise a container can for example run `chown` on /sys, breaking
541 # access to it for non-CAP_DAC_OVERRIDE tools on the host:
542 $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
543 $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
544 # Preferably we could use the 'remount' flag but this does not sit well
545 # with apparmor_parser currently:
546 # mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
547 }
548
549 if (my $mount = $features->{mount}) {
550 push @profile_uses, 'features:mount';
551 foreach my $fs (PVE::Tools::split_list($mount)) {
552 $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
553 }
554 }
555
556 # More to come?
557
558 if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
559 if (length(my $used = join(', ', @profile_uses))) {
560 warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
561 }
562 return '';
563 }
564
565 return $raw;
566 }
567
568 sub update_lxc_config {
569 my ($vmid, $conf) = @_;
570
571 my $dir = "/var/lib/lxc/$vmid";
572
573 if ($conf->{template}) {
574
575 unlink "$dir/config";
576
577 return;
578 }
579
580 my ($lxc_major, $lxc_minor) = get_lxc_version();
581
582 my $raw = '';
583
584 if ($lxc_major >= 4) {
585 # Explicitly don't use relative directories, which is the default, but
586 # note that we do this mostly because they are only applied for *some*
587 # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
588 # so we also don't need to worry about the new monitor cgroup to
589 # confuse systemd.
590 $raw .= "lxc.cgroup.relative = 0\n";
591
592 # To make things easier, let's keep our previous cgroup layout and
593 # simply move the monitor outside:
594 $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
595 # cgroup namespace separation for stronger limits:
596 $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
597 $raw .= "lxc.cgroup.dir.container.inner = ns\n";
598 }
599
600 die "missing 'arch' - internal error" if !$conf->{arch};
601 $raw .= "lxc.arch = $conf->{arch}\n";
602
603 my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
604 my $unprivileged = $conf->{unprivileged} || $custom_idmap;
605
606 my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
607
608 my $cfgpath = '/usr/share/lxc/config';
609 my $inc = "$cfgpath/$ostype.common.conf";
610 $inc ="$cfgpath/common.conf" if !-f $inc;
611 $raw .= "lxc.include = $inc\n";
612 if ($unprivileged) {
613 $inc = "$cfgpath/$ostype.userns.conf";
614 $inc = "$cfgpath/userns.conf" if !-f $inc;
615 $raw .= "lxc.include = $inc\n";
616 }
617
618 my $features = PVE::LXC::Config->parse_features($conf->{features});
619
620 $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
621 $raw .= make_apparmor_config($conf, $unprivileged, $features);
622 if ($features->{fuse}) {
623 $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
624 $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
625 }
626
627 if ($unprivileged && !$features->{force_rw_sys}) {
628 # unpriv. CT default to sys:rw, but that doesn't always plays well with
629 # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
630 $raw .= "lxc.mount.auto = sys:mixed\n";
631 }
632
633 # WARNING: DO NOT REMOVE this without making sure that loop device nodes
634 # cannot be exposed to the container with r/w access (cgroup perms).
635 # When this is enabled mounts will still remain in the monitor's namespace
636 # after the container unmounted them and thus will not detach from their
637 # files while the container is running!
638 $raw .= "lxc.monitor.unshare = 1\n";
639
640 my $cgv1 = get_cgroup_subsystems();
641
642 # Should we read them from /etc/subuid?
643 if ($unprivileged && !$custom_idmap) {
644 $raw .= "lxc.idmap = u 0 100000 65536\n";
645 $raw .= "lxc.idmap = g 0 100000 65536\n";
646 }
647
648 if (!PVE::LXC::Config->has_dev_console($conf)) {
649 $raw .= "lxc.console.path = none\n";
650 $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
651 }
652
653 my $ttycount = PVE::LXC::Config->get_tty_count($conf);
654 $raw .= "lxc.tty.max = $ttycount\n";
655
656 # some init scripts expect a linux terminal (turnkey).
657 $raw .= "lxc.environment = TERM=linux\n";
658
659 my $utsname = $conf->{hostname} || "CT$vmid";
660 $raw .= "lxc.uts.name = $utsname\n";
661
662 if ($cgv1->{memory}) {
663 my $memory = $conf->{memory} || 512;
664 my $swap = $conf->{swap} // 0;
665
666 my $lxcmem = int($memory*1024*1024);
667 $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
668
669 my $lxcswap = int(($memory + $swap)*1024*1024);
670 $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
671 }
672
673 if ($cgv1->{cpu}) {
674 if (my $cpulimit = $conf->{cpulimit}) {
675 $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
676 my $value = int(100000*$cpulimit);
677 $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
678 }
679
680 my $shares = $conf->{cpuunits} || 1024;
681 $raw .= "lxc.cgroup.cpu.shares = $shares\n";
682 }
683
684 die "missing 'rootfs' configuration\n"
685 if !defined($conf->{rootfs});
686
687 my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
688
689 $raw .= "lxc.rootfs.path = $dir/rootfs\n";
690
691 foreach my $k (sort keys %$conf) {
692 next if $k !~ m/^net(\d+)$/;
693 my $ind = $1;
694 my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
695 $raw .= "lxc.net.$ind.type = veth\n";
696 $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
697 $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
698 $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
699 $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
700
701 # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
702 if ($lxc_major >= 4) {
703 $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
704 }
705 }
706
707 my $had_cpuset = 0;
708 if (my $lxcconf = $conf->{lxc}) {
709 foreach my $entry (@$lxcconf) {
710 my ($k, $v) = @$entry;
711 $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
712 $raw .= "$k = $v\n";
713 }
714 }
715
716 my $cpuset;
717 my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
718 if (defined($cpuset_cgroup)) {
719 $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
720 || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
721 }
722 my $cores = $conf->{cores};
723 if (!$had_cpuset && $cores && $cpuset) {
724 my @members = $cpuset->members();
725 while (scalar(@members) > $cores) {
726 my $randidx = int(rand(scalar(@members)));
727 $cpuset->delete($members[$randidx]);
728 splice(@members, $randidx, 1); # keep track of the changes
729 }
730 my $ver = $cpuset_version == 1 ? '' : '2';
731 $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
732 }
733
734 File::Path::mkpath("$dir/rootfs");
735
736 PVE::Tools::file_set_contents("$dir/config", $raw);
737 }
738
739 # verify and cleanup nameserver list (replace \0 with ' ')
740 sub verify_nameserver_list {
741 my ($nameserver_list) = @_;
742
743 my @list = ();
744 foreach my $server (PVE::Tools::split_list($nameserver_list)) {
745 PVE::LXC::Config::verify_ip_with_ll_iface($server);
746 push @list, $server;
747 }
748
749 return join(' ', @list);
750 }
751
752 sub verify_searchdomain_list {
753 my ($searchdomain_list) = @_;
754
755 my @list = ();
756 foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
757 # todo: should we add checks for valid dns domains?
758 push @list, $server;
759 }
760
761 return join(' ', @list);
762 }
763
764 sub get_console_command {
765 my ($vmid, $conf, $escapechar) = @_;
766
767 # '-1' as $escapechar disables keyboard escape sequence
768 # any other passed char (a-z) will result in <Ctrl+$escapechar q>
769
770 my $cmode = PVE::LXC::Config->get_cmode($conf);
771
772 my $cmd = [];
773 if ($cmode eq 'console') {
774 push @$cmd, 'lxc-console', '-n', $vmid, '-t', 0;
775 push @$cmd, '-e', $escapechar if $escapechar;
776 } elsif ($cmode eq 'tty') {
777 push @$cmd, 'lxc-console', '-n', $vmid;
778 push @$cmd, '-e', $escapechar if $escapechar;
779 } elsif ($cmode eq 'shell') {
780 push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
781 } else {
782 die "internal error";
783 }
784
785 return $cmd;
786 }
787
788 sub get_primary_ips {
789 my ($conf) = @_;
790
791 # return data from net0
792
793 return undef if !defined($conf->{net0});
794 my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
795
796 my $ipv4 = $net->{ip};
797 if ($ipv4) {
798 if ($ipv4 =~ /^(dhcp|manual)$/) {
799 $ipv4 = undef
800 } else {
801 $ipv4 =~ s!/\d+$!!;
802 }
803 }
804 my $ipv6 = $net->{ip6};
805 if ($ipv6) {
806 if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
807 $ipv6 = undef;
808 } else {
809 $ipv6 =~ s!/\d+$!!;
810 }
811 }
812
813 return ($ipv4, $ipv6);
814 }
815
816 sub delete_mountpoint_volume {
817 my ($storage_cfg, $vmid, $volume) = @_;
818
819 return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
820
821 my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
822
823 if ($vmid == $owner) {
824 PVE::Storage::vdisk_free($storage_cfg, $volume);
825 } else {
826 warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
827 }
828 }
829
830 sub destroy_lxc_container {
831 my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
832
833 PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, sub {
834 my ($ms, $mountpoint) = @_;
835 delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
836 });
837
838 if ($purge_unreferenced) { # also remove unreferenced disk
839 my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
840 PVE::Storage::foreach_volid($vmdisks, sub {
841 my ($volid, $sid, $volname, $d) = @_;
842 eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
843 warn $@ if $@;
844 });
845 }
846
847 rmdir "/var/lib/lxc/$vmid/rootfs";
848 unlink "/var/lib/lxc/$vmid/config";
849 rmdir "/var/lib/lxc/$vmid";
850 if (defined $replacement_conf) {
851 PVE::LXC::Config->write_config($vmid, $replacement_conf);
852 } else {
853 PVE::LXC::Config->destroy_config($vmid);
854 }
855 }
856
857 sub vm_stop_cleanup {
858 my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
859
860 return if $keepActive;
861
862 eval {
863 my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
864 PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
865 };
866 warn $@ if $@; # avoid errors - just warn
867 }
868
869 sub update_net {
870 my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
871
872 if ($newnet->{type} ne 'veth') {
873 # for when there are physical interfaces
874 die "cannot update interface of type $newnet->{type}";
875 }
876
877 my $veth = "veth${vmid}i${netid}";
878 my $eth = $newnet->{name};
879
880 if (my $oldnetcfg = $conf->{$opt}) {
881 my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
882
883 if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
884 safe_string_ne($oldnet->{name}, $newnet->{name})) {
885
886 PVE::Network::veth_delete($veth);
887 delete $conf->{$opt};
888 PVE::LXC::Config->write_config($vmid, $conf);
889
890 hotplug_net($vmid, $conf, $opt, $newnet, $netid);
891
892 } else {
893 if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
894 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
895 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
896
897 if ($oldnet->{bridge}) {
898 PVE::Network::tap_unplug($veth);
899 foreach (qw(bridge tag firewall)) {
900 delete $oldnet->{$_};
901 }
902 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
903 PVE::LXC::Config->write_config($vmid, $conf);
904 }
905
906 if ($have_sdn) {
907 PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
908 } else {
909 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
910 }
911
912 # This includes the rate:
913 foreach (qw(bridge tag firewall rate)) {
914 $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
915 }
916 } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
917 # Rate can be applied on its own but any change above needs to
918 # include the rate in tap_plug since OVS resets everything.
919 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
920 $oldnet->{rate} = $newnet->{rate}
921 }
922 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
923 PVE::LXC::Config->write_config($vmid, $conf);
924 }
925 } else {
926 hotplug_net($vmid, $conf, $opt, $newnet, $netid);
927 }
928
929 update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
930 }
931
932 sub hotplug_net {
933 my ($vmid, $conf, $opt, $newnet, $netid) = @_;
934
935 my $veth = "veth${vmid}i${netid}";
936 my $vethpeer = $veth . "p";
937 my $eth = $newnet->{name};
938
939 if ($have_sdn) {
940 PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
941 PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
942 } else {
943 PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
944 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
945 }
946
947 # attach peer in container
948 my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
949 PVE::Tools::run_command($cmd);
950
951 # link up peer in container
952 $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up' ];
953 PVE::Tools::run_command($cmd);
954
955 my $done = { type => 'veth' };
956 foreach (qw(bridge tag firewall hwaddr name)) {
957 $done->{$_} = $newnet->{$_} if $newnet->{$_};
958 }
959 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
960
961 PVE::LXC::Config->write_config($vmid, $conf);
962 }
963
964 sub update_ipconfig {
965 my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
966
967 my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
968
969 my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
970 my $deleted = [];
971 my $added = [];
972 my $nscmd = sub {
973 my $cmdargs = shift;
974 PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
975 };
976 my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
977
978 my $change_ip_config = sub {
979 my ($ipversion) = @_;
980
981 my $family_opt = "-$ipversion";
982 my $suffix = $ipversion == 4 ? '' : $ipversion;
983 my $gw= "gw$suffix";
984 my $ip= "ip$suffix";
985
986 my $newip = $newnet->{$ip};
987 my $newgw = $newnet->{$gw};
988 my $oldip = $optdata->{$ip};
989 my $oldgw = $optdata->{$gw};
990
991 my $change_ip = safe_string_ne($oldip, $newip);
992 my $change_gw = safe_string_ne($oldgw, $newgw);
993
994 return if !$change_ip && !$change_gw;
995
996 # step 1: add new IP, if this fails we cancel
997 my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
998 if ($change_ip && $is_real_ip) {
999 eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1000 if (my $err = $@) {
1001 warn $err;
1002 return;
1003 }
1004 }
1005
1006 # step 2: replace gateway
1007 # If this fails we delete the added IP and cancel.
1008 # If it succeeds we save the config and delete the old IP, ignoring
1009 # errors. The config is then saved.
1010 # Note: 'ip route replace' can add
1011 if ($change_gw) {
1012 if ($newgw) {
1013 eval {
1014 if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1015 &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1016 }
1017 &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1018 };
1019 if (my $err = $@) {
1020 warn $err;
1021 # the route was not replaced, the old IP is still available
1022 # rollback (delete new IP) and cancel
1023 if ($change_ip) {
1024 eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1025 warn $@ if $@; # no need to die here
1026 }
1027 return;
1028 }
1029 } else {
1030 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1031 # if the route was not deleted, the guest might have deleted it manually
1032 # warn and continue
1033 warn $@ if $@;
1034 }
1035 if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1036 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1037 # warn if the route was deleted manually
1038 warn $@ if $@;
1039 }
1040 }
1041
1042 # from this point on we save the configuration
1043 # step 3: delete old IP ignoring errors
1044 if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1045 # We need to enable promote_secondaries, otherwise our newly added
1046 # address will be removed along with the old one.
1047 my $promote = 0;
1048 eval {
1049 if ($ipversion == 4) {
1050 &$nscmd({ outfunc => sub { $promote = int(shift) } },
1051 'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1052 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1053 }
1054 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1055 };
1056 warn $@ if $@; # no need to die here
1057
1058 if ($ipversion == 4) {
1059 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1060 }
1061 }
1062
1063 foreach my $property ($ip, $gw) {
1064 if ($newnet->{$property}) {
1065 $optdata->{$property} = $newnet->{$property};
1066 } else {
1067 delete $optdata->{$property};
1068 }
1069 }
1070 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1071 PVE::LXC::Config->write_config($vmid, $conf);
1072 $lxc_setup->setup_network($conf);
1073 };
1074
1075 &$change_ip_config(4);
1076 &$change_ip_config(6);
1077
1078 }
1079
1080 my $open_namespace = sub {
1081 my ($vmid, $pid, $kind) = @_;
1082 sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1083 or die "failed to open $kind namespace of container $vmid: $!\n";
1084 return $fd;
1085 };
1086
1087 my $enter_namespace = sub {
1088 my ($vmid, $pid, $kind, $type) = @_;
1089 my $fd = $open_namespace->($vmid, $pid, $kind);
1090 PVE::Tools::setns(fileno($fd), $type)
1091 or die "failed to enter $kind namespace of container $vmid: $!\n";
1092 close $fd;
1093 };
1094
1095 my $get_container_namespace = sub {
1096 my ($vmid, $pid, $kind) = @_;
1097
1098 my $pidfd;
1099 if (!defined($pid)) {
1100 # Pin the pid while we're grabbing its stuff from /proc
1101 ($pid, $pidfd) = open_lxc_pid($vmid)
1102 or die "failed to open pidfd of container $vmid\'s init process\n";
1103 }
1104
1105 return $open_namespace->($vmid, $pid, $kind);
1106 };
1107
1108 my $do_syncfs = sub {
1109 my ($vmid, $pid, $socket) = @_;
1110
1111 &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1112
1113 # Tell the parent process to start reading our /proc/mounts
1114 print {$socket} "go\n";
1115 $socket->flush();
1116
1117 # Receive /proc/self/mounts
1118 my $mountdata = do { local $/ = undef; <$socket> };
1119 close $socket;
1120
1121 my %nosyncfs = (
1122 cgroup => 1,
1123 cgroup2 => 1,
1124 devtmpfs => 1,
1125 devpts => 1,
1126 'fuse.lxcfs' => 1,
1127 fusectl => 1,
1128 mqueue => 1,
1129 proc => 1,
1130 sysfs => 1,
1131 tmpfs => 1,
1132 );
1133
1134 # Now sync all mountpoints...
1135 my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1136 foreach my $mp (@$mounts) {
1137 my ($what, $dir, $fs) = @$mp;
1138 next if $nosyncfs{$fs};
1139 eval { PVE::Tools::sync_mountpoint($dir); };
1140 warn $@ if $@;
1141 }
1142 };
1143
1144 sub sync_container_namespace {
1145 my ($vmid) = @_;
1146 my $pid = find_lxc_pid($vmid);
1147
1148 # SOCK_DGRAM is nicer for barriers but cannot be slurped
1149 socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1150 or die "failed to create socketpair: $!\n";
1151
1152 my $child = fork();
1153 die "fork failed: $!\n" if !defined($child);
1154
1155 if (!$child) {
1156 eval {
1157 close $pfd;
1158 &$do_syncfs($vmid, $pid, $cfd);
1159 };
1160 if (my $err = $@) {
1161 warn $err;
1162 POSIX::_exit(1);
1163 }
1164 POSIX::_exit(0);
1165 }
1166 close $cfd;
1167 my $go = <$pfd>;
1168 die "failed to enter container namespace\n" if $go ne "go\n";
1169
1170 open my $mounts, '<', "/proc/$child/mounts"
1171 or die "failed to open container's /proc/mounts: $!\n";
1172 my $mountdata = do { local $/ = undef; <$mounts> };
1173 close $mounts;
1174 print {$pfd} $mountdata;
1175 close $pfd;
1176
1177 while (waitpid($child, 0) != $child) {}
1178 die "failed to sync container namespace\n" if $? != 0;
1179 }
1180
1181 sub template_create {
1182 my ($vmid, $conf) = @_;
1183
1184 my $storecfg = PVE::Storage::config();
1185
1186 PVE::LXC::Config->foreach_volume($conf, sub {
1187 my ($ms, $mountpoint) = @_;
1188
1189 my $volid = $mountpoint->{volume};
1190
1191 die "Template feature is not available for '$volid'\n"
1192 if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1193 });
1194
1195 PVE::LXC::Config->foreach_volume($conf, sub {
1196 my ($ms, $mountpoint) = @_;
1197
1198 my $volid = $mountpoint->{volume};
1199
1200 PVE::Storage::activate_volumes($storecfg, [$volid]);
1201
1202 my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1203 $mountpoint->{volume} = $template_volid;
1204 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1205 });
1206
1207 PVE::LXC::Config->write_config($vmid, $conf);
1208 }
1209
1210 sub check_ct_modify_config_perm {
1211 my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1212
1213 return 1 if $authuser eq 'root@pam';
1214
1215 my $check = sub {
1216 my ($opt, $delete) = @_;
1217 if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1218 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1219 } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1220 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1221 return if $delete;
1222 my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1223 raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1224 if $data->{type} ne 'volume';
1225 } elsif ($opt eq 'memory' || $opt eq 'swap') {
1226 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1227 } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1228 $opt eq 'searchdomain' || $opt eq 'hostname') {
1229 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1230 } elsif ($opt eq 'features') {
1231 # For now this is restricted to root@pam
1232 raise_perm_exc("changing feature flags is only allowed for root\@pam");
1233 } elsif ($opt eq 'hookscript') {
1234 # For now this is restricted to root@pam
1235 raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1236 } else {
1237 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1238 }
1239 };
1240
1241 foreach my $opt (keys %$newconf) {
1242 &$check($opt, 0);
1243 }
1244 foreach my $opt (@$delete) {
1245 &$check($opt, 1);
1246 }
1247
1248 return 1;
1249 }
1250
1251 sub umount_all {
1252 my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1253
1254 my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1255 my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1256
1257 my $res = 1;
1258
1259 PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1260 my ($ms, $mountpoint) = @_;
1261
1262 my $volid = $mountpoint->{volume};
1263 my $mount = $mountpoint->{mp};
1264
1265 return if !$volid || !$mount;
1266
1267 my $mount_path = "$rootdir/$mount";
1268 $mount_path =~ s!/+!/!g;
1269
1270 return if !PVE::ProcFSTools::is_mounted($mount_path);
1271
1272 eval {
1273 PVE::Tools::run_command(['umount', '-d', $mount_path]);
1274 };
1275 if (my $err = $@) {
1276 if ($noerr) {
1277 $res = 0;
1278 warn $err;
1279 } else {
1280 die $err;
1281 }
1282 }
1283 });
1284
1285 return $res; # tell caller if (some) umounts failed for the noerr case
1286 }
1287
1288 sub mount_all {
1289 my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1290
1291 my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1292 File::Path::make_path($rootdir);
1293
1294 my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1295 PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1296
1297 my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1298
1299 eval {
1300 PVE::LXC::Config->foreach_volume($conf, sub {
1301 my ($ms, $mountpoint) = @_;
1302
1303 $mountpoint->{ro} = 0 if $ignore_ro;
1304
1305 mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1306 });
1307 };
1308 if (my $err = $@) {
1309 warn "mounting container failed\n";
1310 umount_all($vmid, $storage_cfg, $conf, 1);
1311 die $err;
1312 }
1313
1314 return $rootdir;
1315 }
1316
1317
1318 sub mountpoint_mount_path {
1319 my ($mountpoint, $storage_cfg, $snapname) = @_;
1320
1321 return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1322 }
1323
1324 sub query_loopdev {
1325 my ($path) = @_;
1326 my $found;
1327 my $parser = sub {
1328 my $line = shift;
1329 if ($line =~ m@^(/dev/loop\d+):@) {
1330 $found = $1;
1331 }
1332 };
1333 my $cmd = ['losetup', '--associated', $path];
1334 PVE::Tools::run_command($cmd, outfunc => $parser);
1335 return $found;
1336 }
1337
1338 # Run a function with a file attached to a loop device.
1339 # The loop device is always detached afterwards (or set to autoclear).
1340 # Returns the loop device.
1341 sub run_with_loopdev {
1342 my ($func, $file, $readonly) = @_;
1343 my $device = query_loopdev($file);
1344 # Try to reuse an existing device
1345 if ($device) {
1346 # We assume that whoever setup the loop device is responsible for
1347 # detaching it.
1348 &$func($device);
1349 return $device;
1350 }
1351
1352 my $parser = sub {
1353 my $line = shift;
1354 if ($line =~ m@^(/dev/loop\d+)$@) {
1355 $device = $1;
1356 }
1357 };
1358 my $losetup_cmd = [
1359 'losetup',
1360 '--show',
1361 '-f',
1362 $file,
1363 ];
1364 push @$losetup_cmd, '-r' if $readonly;
1365 PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1366 die "failed to setup loop device for $file\n" if !$device;
1367 eval { &$func($device); };
1368 my $err = $@;
1369 PVE::Tools::run_command(['losetup', '-d', $device]);
1370 die $err if $err;
1371 return $device;
1372 }
1373
1374 # In scalar mode: returns a file handle to the deepest directory node.
1375 # In list context: returns a list of:
1376 # * the deepest directory node
1377 # * the 2nd deepest directory (parent of the above)
1378 # * directory name of the last directory
1379 # So that the path $2/$3 should lead to $1 afterwards.
1380 sub walk_tree_nofollow($$$;$$) {
1381 my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1382
1383 sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1384 or die "failed to open start directory $start: $!\n";
1385
1386 return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1387 }
1388
1389
1390 sub walk_tree_nofollow_fd($$$$;$$) {
1391 my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1392
1393 # splitdir() returns '' for empty components including the leading /
1394 my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1395
1396 my $fd = $start_fd;
1397 my $dir = $start_dirname;
1398 my $last_component = undef;
1399 my $second = $fd;
1400 foreach my $component (@comps) {
1401 $dir .= "/$component";
1402 my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1403
1404 if (!$next) {
1405 # failed, check for symlinks and try to create the path
1406 die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1407 die "cannot open directory $dir: $!\n" if !$mkdir;
1408
1409 # We don't check for errors on mkdirat() here and just try to
1410 # openat() again, since at least one error (EEXIST) is an
1411 # expected possibility if multiple containers start
1412 # simultaneously. If someone else injects a symlink now then
1413 # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1414 PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1415
1416 $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1417 die "failed to create path: $dir: $!\n" if !$next;
1418
1419 PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1420 if defined($rootuid) && defined($rootgid);
1421 }
1422
1423 close $second if defined($last_component) && $second != $start_fd;
1424 $last_component = $component;
1425 $second = $fd;
1426 $fd = $next;
1427 }
1428
1429 return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1430 close $second if defined($last_component) && $second != $start_fd;
1431 return $fd;
1432 }
1433
1434 # To guard against symlink attack races against other currently running
1435 # containers with shared recursive bind mount hierarchies we prepare a
1436 # directory handle for the directory we're mounting over to verify the
1437 # mountpoint afterwards.
1438 sub __bindmount_prepare {
1439 my ($hostroot, $dir) = @_;
1440 my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1441 return $srcdh;
1442 }
1443
1444 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1445 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1446 # we intended to bind mount.
1447 sub __bindmount_verify {
1448 my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1449 my $destdh;
1450 if ($parentfd) {
1451 # Open the mount point path coming from the parent directory since the
1452 # filehandle we would have gotten as first result of walk_tree_nofollow
1453 # earlier is still a handle to the underlying directory instead of the
1454 # mounted path.
1455 $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1456 die "failed to open mount point: $!\n" if !$destdh;
1457 if ($ro) {
1458 my $dot = '.';
1459 # no separate function because 99% of the time it's the wrong thing to use.
1460 if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1461 die "failed to mark bind mount read only\n";
1462 }
1463 die "read-only check failed: $!\n" if $! != EROFS;
1464 }
1465 } else {
1466 # For the rootfs we don't have a parentfd so we open the path directly.
1467 # Note that this means bindmounting any prefix of the host's
1468 # /var/lib/lxc/$vmid path into another container is considered a grave
1469 # security error.
1470 sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1471 die "failed to open mount point: $!\n" if !$destdh;
1472 }
1473
1474 my ($srcdev, $srcinode) = stat($srcdh);
1475 my ($dstdev, $dstinode) = stat($destdh);
1476 close $srcdh;
1477 close $destdh;
1478
1479 return ($srcdev == $dstdev && $srcinode == $dstinode);
1480 }
1481
1482 # Perform the actual bind mounting:
1483 sub __bindmount_do {
1484 my ($dir, $dest, $ro, @extra_opts) = @_;
1485 PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1486 if ($ro) {
1487 eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1488 if (my $err = $@) {
1489 warn "bindmount error\n";
1490 # don't leave writable bind-mounts behind...
1491 PVE::Tools::run_command(['umount', $dest]);
1492 die $err;
1493 }
1494 }
1495 }
1496
1497 sub bindmount {
1498 my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1499
1500 my $srcdh = __bindmount_prepare('/', $dir);
1501
1502 __bindmount_do($dir, $dest, $ro, @extra_opts);
1503
1504 if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1505 PVE::Tools::run_command(['umount', $dest]);
1506 die "detected mount path change at: $dir\n";
1507 }
1508 }
1509
1510 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1511 # from $rootdir and $mount and walk the path from $rootdir to the final
1512 # directory to check for symlinks.
1513 sub __mount_prepare_rootdir {
1514 my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1515 $rootdir =~ s!/+!/!g;
1516 $rootdir =~ s!/+$!!;
1517 my $mount_path = "$rootdir/$mount";
1518 my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1519 return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1520 }
1521
1522 # use $rootdir = undef to just return the corresponding mount path
1523 sub mountpoint_mount {
1524 my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1525 return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1526 }
1527
1528 sub mountpoint_stage {
1529 my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1530 my ($path, $loop, $dev) =
1531 __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1532
1533 if (!defined($path)) {
1534 return undef if $! == ENOSYS;
1535 die "failed to mount subvolume: $!\n";
1536 }
1537
1538 # We clone the mount point and leave it there in order to keep them connected to eg. loop
1539 # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1540 # point).
1541 my $err;
1542 my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1543 or die "open_tree() on mount point failed: $!\n";
1544
1545 return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1546 }
1547
1548 sub mountpoint_insert_staged {
1549 my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1550
1551 if (!defined($rootdir_fd)) {
1552 sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1553 or die "failed to open '.': $!\n";
1554 }
1555
1556 my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1557
1558 PVE::Tools::move_mount(
1559 fileno($mount_fd),
1560 '',
1561 fileno($dest_fd),
1562 '',
1563 &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1564 ) or die "failed to move '$opt' into container hierarchy: $!\n";
1565 }
1566
1567 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1568 # can then open a file descriptor to it which can be used with the `move_mount` syscall.
1569 # Note that if the kernel does not support the new mount API, this will not perform any action
1570 # and return `undef` with $! = ENOSYS.
1571 sub __mountpoint_mount {
1572 my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1573
1574 if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1575 $! = ENOSYS;
1576 return undef;
1577 }
1578
1579 # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1580 # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1581 # which we use in __bindmount_verify()!
1582 my $mount = $stage_mount ? '/': $mountpoint->{mp};
1583
1584 my $volid = $mountpoint->{volume};
1585 my $type = $mountpoint->{type};
1586 my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1587 my $mounted_dev;
1588
1589 return if !$volid || !$mount;
1590
1591 $mount =~ s!/+!/!g;
1592
1593 my $mount_path;
1594 my ($mpfd, $parentfd, $last_dir);
1595
1596 if (defined($rootdir)) {
1597 ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1598 __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1599 }
1600
1601 if (defined($stage_mount)) {
1602 $mount_path = $rootdir;
1603 }
1604
1605 my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1606
1607 die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1608
1609 my $optlist = [];
1610
1611 if (my $mountopts = $mountpoint->{mountoptions}) {
1612 my @opts = split(/;/, $mountpoint->{mountoptions});
1613 push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1614 }
1615
1616 my $acl = $mountpoint->{acl};
1617 if (defined($acl)) {
1618 push @$optlist, ($acl ? 'acl' : 'noacl');
1619 }
1620
1621 my $optstring = join(',', @$optlist);
1622 my $readonly = $mountpoint->{ro};
1623
1624 my @extra_opts;
1625 @extra_opts = ('-o', $optstring) if $optstring;
1626
1627 if ($storage) {
1628
1629 my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1630
1631 my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1632
1633 $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1634
1635 my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1636 PVE::Storage::parse_volname($storage_cfg, $volid);
1637
1638 $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1639
1640 if ($format eq 'subvol') {
1641 if ($mount_path) {
1642 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1643 if (defined($snapname)) {
1644 $name .= "\@$snapname";
1645 if ($scfg->{type} eq 'zfspool') {
1646 PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1647 } else {
1648 die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1649 }
1650 } else {
1651 if (defined($acl) && $scfg->{type} eq 'zfspool') {
1652 my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1653 PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1654 }
1655 bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1656 warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1657 }
1658 }
1659 return wantarray ? ($path, 0, undef) : $path;
1660 } elsif ($format eq 'raw' || $format eq 'iso') {
1661 # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1662 # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1663 # Our autodev hook expects the /dev/dm-* device currently
1664 # and will create the /dev/mapper symlink accordingly
1665 $path = Cwd::realpath($path);
1666 die "failed to get device path\n" if !$path;
1667 ($path) = ($path =~ /^(.*)$/s); #untaint
1668 my $domount = sub {
1669 my ($path) = @_;
1670 if ($mount_path) {
1671 if ($format eq 'iso') {
1672 PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1673 } elsif ($isBase || defined($snapname)) {
1674 PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1675 } else {
1676 if ($quota) {
1677 push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1678 }
1679 push @extra_opts, '-o', 'ro' if $readonly;
1680 PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1681 }
1682 }
1683 };
1684 my $use_loopdev = 0;
1685 if ($scfg->{path}) {
1686 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1687 $use_loopdev = 1;
1688 } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1689 $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1690 $mounted_dev = $path;
1691 &$domount($path);
1692 } else {
1693 die "unsupported storage type '$scfg->{type}'\n";
1694 }
1695 return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1696 } else {
1697 die "unsupported image format '$format'\n";
1698 }
1699 } elsif ($type eq 'device') {
1700 push @extra_opts, '-o', 'ro' if $readonly;
1701 push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1702 # See the NOTE above about devicemapper canonicalization
1703 my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1704 PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1705 return wantarray ? ($volid, 0, $devpath) : $volid;
1706 } elsif ($type eq 'bind') {
1707 die "directory '$volid' does not exist\n" if ! -d $volid;
1708 bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1709 warn "cannot enable quota control for bind mounts\n" if $quota;
1710 return wantarray ? ($volid, 0, undef) : $volid;
1711 }
1712
1713 die "unsupported storage";
1714 }
1715
1716 sub mountpoint_hotplug($$$) {
1717 my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1718
1719 my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1720
1721 # We do the rest in a fork with an unshared mount namespace, because:
1722 # -) change our papparmor profile to that of /usr/bin/lxc-start
1723 # -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1724 # container's namespace, then mount it.
1725
1726 PVE::Tools::run_fork(sub {
1727 # Pin the container pid longer, we also need to get its monitor/parent:
1728 my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1729 or die "failed to open pidfd of container $vmid\'s init process\n";
1730
1731 my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1732 or die "failed to open pidfd of container $vmid\'s monitor process\n";
1733
1734 my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1735 my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1736
1737 # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1738 # profile to lower our privileges to the same level we have in the start hook:
1739 sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1740 or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1741 # But switch namespaces first, to make sure the namespace switches aren't blocked by
1742 # apparmor.
1743
1744 # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1745 # namespace for it to remain active there since the container will be able to unmount
1746 # hotplugged mount points and thereby potentially free up loop devices, which is a security
1747 # concern.
1748 PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1749 chdir('/')
1750 or die "failed to change root directory within the monitor's mount namespace: $!\n";
1751
1752 my $dir = get_staging_mount_path($opt);
1753
1754 # Now switch our apparmor profile before mounting:
1755 my $data = 'changeprofile /usr/bin/lxc-start';
1756 if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1757 die "failed to change apparmor profile: $!\n";
1758 }
1759 # Check errors on close as well:
1760 close($aa_fd)
1761 or die "failed to change apparmor profile (close() failed): $!\n";
1762
1763 my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1764
1765 PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1766 chdir('/')
1767 or die "failed to change root directory within the container's mount namespace: $!\n";
1768
1769 mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1770 });
1771 }
1772
1773 # Create a directory in the mountpoint staging tempfs.
1774 sub get_staging_mount_path($) {
1775 my ($opt) = @_;
1776
1777 my $target = get_staging_tempfs() . "/$opt";
1778 if (!mkdir($target) && $! != EEXIST) {
1779 die "failed to create directory $target: $!\n";
1780 }
1781
1782 return $target;
1783 }
1784
1785 # Mount /run/pve/mountpoints as tmpfs
1786 sub get_staging_tempfs() {
1787 # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1788 # mounts to that.
1789 my $target = '/var/lib/lxc/.pve-staged-mounts';
1790 if (!mkdir($target)) {
1791 return $target if $! == EEXIST;
1792 die "failed to create directory $target: $!\n";
1793 }
1794
1795 PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1796 or die "failed to mount $target as tmpfs: $!\n";
1797
1798 return $target;
1799 }
1800
1801 sub mkfs {
1802 my ($dev, $rootuid, $rootgid) = @_;
1803
1804 run_command(
1805 [
1806 'mkfs.ext4',
1807 '-O',
1808 'mmp',
1809 '-E',
1810 "root_owner=$rootuid:$rootgid",
1811 $dev,
1812 ],
1813 outfunc => sub {
1814 my $line = shift;
1815 # a hack to print only the relevant stuff, i.e., the one which could help on repair
1816 if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1817 print "$line\n";
1818 }
1819 },
1820 errfunc => sub {
1821 my $line = shift;
1822 print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1823 }
1824 );
1825 }
1826
1827 sub format_disk {
1828 my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1829
1830 if ($volid =~ m!^/dev/.+!) {
1831 mkfs($volid);
1832 return;
1833 }
1834
1835 my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1836
1837 die "cannot format volume '$volid' with no storage\n" if !$storage;
1838
1839 PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1840
1841 my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1842
1843 $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1844
1845 my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1846 PVE::Storage::parse_volname($storage_cfg, $volid);
1847
1848 die "cannot format volume '$volid' (format == $format)\n"
1849 if $format ne 'raw';
1850
1851 mkfs($path, $rootuid, $rootgid);
1852 }
1853
1854 sub destroy_disks {
1855 my ($storecfg, $vollist) = @_;
1856
1857 foreach my $volid (@$vollist) {
1858 eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1859 warn $@ if $@;
1860 }
1861 }
1862
1863 sub alloc_disk {
1864 my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1865
1866 my $needs_chown = 0;
1867 my $volid;
1868
1869 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1870 # fixme: use better naming ct-$vmid-disk-X.raw?
1871
1872 eval {
1873 my $do_format = 0;
1874 if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1875 if ($size_kb > 0) {
1876 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1877 undef, $size_kb);
1878 $do_format = 1;
1879 } else {
1880 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1881 undef, 0);
1882 $needs_chown = 1;
1883 }
1884 } elsif ($scfg->{type} eq 'zfspool') {
1885
1886 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1887 undef, $size_kb);
1888 $needs_chown = 1;
1889 } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1890
1891 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1892 $do_format = 1;
1893
1894 } elsif ($scfg->{type} eq 'rbd') {
1895
1896 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1897 $do_format = 1;
1898 } else {
1899 die "unable to create containers on storage type '$scfg->{type}'\n";
1900 }
1901 format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1902 };
1903 if (my $err = $@) {
1904 # in case formatting got interrupted:
1905 if (defined($volid)) {
1906 eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1907 warn $@ if $@;
1908 }
1909 die $err;
1910 }
1911
1912 return ($volid, $needs_chown);
1913 }
1914
1915 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1916 sub create_disks {
1917 my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1918
1919 my $vollist = [];
1920
1921 eval {
1922 my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1923 my $chown_vollist = [];
1924
1925 PVE::LXC::Config->foreach_volume($settings, sub {
1926 my ($ms, $mountpoint) = @_;
1927
1928 my $volid = $mountpoint->{volume};
1929 my $mp = $mountpoint->{mp};
1930
1931 my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1932
1933 if ($storage && ($volid =~ $NEW_DISK_RE)) {
1934 my ($storeid, $size_gb) = ($1, $2);
1935
1936 my $size_kb = int(${size_gb}*1024) * 1024;
1937
1938 my $needs_chown = 0;
1939 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1940 push @$chown_vollist, $volid if $needs_chown;
1941 push @$vollist, $volid;
1942 $mountpoint->{volume} = $volid;
1943 $mountpoint->{size} = $size_kb * 1024;
1944 if ($pending) {
1945 $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1946 } else {
1947 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1948 }
1949 } else {
1950 # use specified/existing volid/dir/device
1951 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1952 }
1953 });
1954
1955 PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1956 foreach my $volid (@$chown_vollist) {
1957 my $path = PVE::Storage::path($storecfg, $volid, undef);
1958 chown($rootuid, $rootgid, $path);
1959 }
1960 PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1961 };
1962 # free allocated images on error
1963 if (my $err = $@) {
1964 destroy_disks($storecfg, $vollist);
1965 die $err;
1966 }
1967 return $vollist;
1968 }
1969
1970 sub update_disksize {
1971 my ($vmid, $conf, $all_volumes) = @_;
1972
1973 my $changes;
1974 my $prefix = "CT $vmid:";
1975
1976 my $update_mp = sub {
1977 my ($key, $mp, @param) = @_;
1978 my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1979
1980 if (!defined($mp->{size}) || $size != $mp->{size}) {
1981 $changes = 1;
1982 print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1983 $mp->{size} = $size;
1984 my $nomp = 1 if ($key eq 'rootfs');
1985 $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1986 }
1987 };
1988
1989 PVE::LXC::Config->foreach_volume($conf, $update_mp);
1990
1991 return $changes;
1992 }
1993
1994 sub update_unused {
1995 my ($vmid, $conf, $all_volumes) = @_;
1996
1997 my $changes;
1998 my $prefix = "CT $vmid:";
1999
2000 # Note: it is allowed to define multiple storage entries with the same path
2001 # (alias), so we need to check both 'volid' and real 'path' (two different
2002 # volid can point to the same path).
2003
2004 # used and unused disks
2005 my $refpath = {};
2006 my $orphans = {};
2007
2008 foreach my $opt (keys %$conf) {
2009 next if ($opt !~ m/^unused\d+$/);
2010 my $vol = $all_volumes->{$conf->{$opt}};
2011 $refpath->{$vol->{path}} = $vol->{volid};
2012 }
2013
2014 foreach my $key (keys %$all_volumes) {
2015 my $vol = $all_volumes->{$key};
2016 my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2017 my $path = $vol->{path};
2018
2019 if ($in_use) {
2020 $refpath->{$path} = $key;
2021 delete $orphans->{$path};
2022 } else {
2023 if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2024 $orphans->{$path} = $key;
2025 }
2026 }
2027 }
2028
2029 for my $key (keys %$orphans) {
2030 my $disk = $orphans->{$key};
2031 my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2032
2033 if ($unused) {
2034 $changes = 1;
2035 print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2036 }
2037 }
2038
2039 return $changes;
2040 }
2041
2042 sub scan_volids {
2043 my ($cfg, $vmid) = @_;
2044
2045 my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2046
2047 my $all_volumes = {};
2048 foreach my $storeid (keys %$info) {
2049 foreach my $item (@{$info->{$storeid}}) {
2050 my $volid = $item->{volid};
2051 next if !($volid && $item->{size});
2052 $item->{path} = PVE::Storage::path($cfg, $volid);
2053 $all_volumes->{$volid} = $item;
2054 }
2055 }
2056
2057 return $all_volumes;
2058 }
2059
2060 sub rescan {
2061 my ($vmid, $nolock, $dryrun) = @_;
2062
2063 my $cfg = PVE::Storage::config();
2064
2065 print "rescan volumes...\n";
2066 my $all_volumes = scan_volids($cfg, $vmid);
2067
2068 my $updatefn = sub {
2069 my ($vmid) = @_;
2070
2071 my $changes;
2072 my $conf = PVE::LXC::Config->load_config($vmid);
2073
2074 PVE::LXC::Config->check_lock($conf);
2075
2076 my $vm_volids = {};
2077 foreach my $volid (keys %$all_volumes) {
2078 my $info = $all_volumes->{$volid};
2079 $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2080 }
2081
2082 my $upu = update_unused($vmid, $conf, $vm_volids);
2083 my $upd = update_disksize($vmid, $conf, $vm_volids);
2084 $changes = $upu || $upd;
2085
2086 PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2087 };
2088
2089 if (defined($vmid)) {
2090 if ($nolock) {
2091 &$updatefn($vmid);
2092 } else {
2093 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2094 }
2095 } else {
2096 my $vmlist = config_list();
2097 foreach my $vmid (keys %$vmlist) {
2098 if ($nolock) {
2099 &$updatefn($vmid);
2100 } else {
2101 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2102 }
2103 }
2104 }
2105 }
2106
2107
2108 # bash completion helper
2109
2110 sub complete_os_templates {
2111 my ($cmdname, $pname, $cvalue) = @_;
2112
2113 my $cfg = PVE::Storage::config();
2114
2115 my $storeid;
2116
2117 if ($cvalue =~ m/^([^:]+):/) {
2118 $storeid = $1;
2119 }
2120
2121 my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2122 my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2123
2124 my $res = [];
2125 foreach my $id (keys %$data) {
2126 foreach my $item (@{$data->{$id}}) {
2127 push @$res, $item->{volid} if defined($item->{volid});
2128 }
2129 }
2130
2131 return $res;
2132 }
2133
2134 my $complete_ctid_full = sub {
2135 my ($running) = @_;
2136
2137 my $idlist = vmstatus();
2138
2139 my $active_hash = list_active_containers();
2140
2141 my $res = [];
2142
2143 foreach my $id (keys %$idlist) {
2144 my $d = $idlist->{$id};
2145 if (defined($running)) {
2146 next if $d->{template};
2147 next if $running && !$active_hash->{$id};
2148 next if !$running && $active_hash->{$id};
2149 }
2150 push @$res, $id;
2151
2152 }
2153 return $res;
2154 };
2155
2156 sub complete_ctid {
2157 return &$complete_ctid_full();
2158 }
2159
2160 sub complete_ctid_stopped {
2161 return &$complete_ctid_full(0);
2162 }
2163
2164 sub complete_ctid_running {
2165 return &$complete_ctid_full(1);
2166 }
2167
2168 sub parse_id_maps {
2169 my ($conf) = @_;
2170
2171 my $id_map = [];
2172 my $rootuid = 0;
2173 my $rootgid = 0;
2174
2175 my $lxc = $conf->{lxc};
2176 foreach my $entry (@$lxc) {
2177 my ($key, $value) = @$entry;
2178 # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2179 next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2180 if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2181 my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2182 push @$id_map, [$type, $ct, $host, $length];
2183 if ($ct == 0) {
2184 $rootuid = $host if $type eq 'u';
2185 $rootgid = $host if $type eq 'g';
2186 }
2187 } else {
2188 die "failed to parse idmap: $value\n";
2189 }
2190 }
2191
2192 if (!@$id_map && $conf->{unprivileged}) {
2193 # Should we read them from /etc/subuid?
2194 $id_map = [ ['u', '0', '100000', '65536'],
2195 ['g', '0', '100000', '65536'] ];
2196 $rootuid = $rootgid = 100000;
2197 }
2198
2199 return ($id_map, $rootuid, $rootgid);
2200 }
2201
2202 sub userns_command {
2203 my ($id_map) = @_;
2204 if (@$id_map) {
2205 return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2206 }
2207 return [];
2208 }
2209
2210 my sub print_ct_stderr_log {
2211 my ($vmid) = @_;
2212 my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2213 return if !$log;
2214
2215 while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2216 my $line = $2;
2217 print STDERR "$line\n";
2218 }
2219 }
2220
2221 my sub monitor_state_change($$) {
2222 my ($monitor_socket, $vmid) = @_;
2223 die "no monitor socket\n" if !defined($monitor_socket);
2224
2225 while (1) {
2226 my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2227
2228 die "monitor socket: got EOF\n" if !defined($type);
2229
2230 next if $name ne "$vmid" || $type ne 'STATE';
2231
2232 if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2233 alarm(0); # don't timeout after seeing the starting state
2234 } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2235 $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2236 $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2237 return 0;
2238 } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2239 return 1;
2240 } else {
2241 warn "unexpected message from monitor socket - " .
2242 "type: '$type' - value: '$value'\n";
2243 }
2244 }
2245 }
2246 my sub monitor_start($$) {
2247 my ($monitor_socket, $vmid) = @_;
2248
2249 my $success = eval {
2250 PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2251 };
2252 if (my $err = $@) {
2253 warn "problem with monitor socket, but continuing anyway: $err\n";
2254 } elsif (!$success) {
2255 print_ct_stderr_log($vmid);
2256 die "startup for container '$vmid' failed\n";
2257 }
2258 }
2259
2260 sub vm_start {
2261 my ($vmid, $conf, $skiplock, $debug) = @_;
2262
2263 # apply pending changes while starting
2264 if (scalar(keys %{$conf->{pending}})) {
2265 my $storecfg = PVE::Storage::config();
2266 PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2267 PVE::LXC::Config->write_config($vmid, $conf);
2268 $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2269 }
2270
2271 update_lxc_config($vmid, $conf);
2272
2273 my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2274
2275 if ($skiplock) {
2276 open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2277 close($fh);
2278 }
2279
2280 my $storage_cfg = PVE::Storage::config();
2281 my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2282
2283 PVE::Storage::activate_volumes($storage_cfg, $vollist);
2284
2285 my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2286 warn $@ if $@;
2287
2288 unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2289
2290 my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2291 my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2292
2293 my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2294
2295 PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2296 eval {
2297 run_command($cmd);
2298
2299 monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2300
2301 # if debug is requested, print the log it also when the start succeeded
2302 print_ct_stderr_log($vmid) if $is_debug;
2303 };
2304 if (my $err = $@) {
2305 unlink $skiplock_flag_fn;
2306 die $err;
2307 }
2308 PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2309
2310 return;
2311 }
2312
2313 # Helper to stop a container completely and make sure it has stopped completely.
2314 # This is necessary because we want the post-stop hook to have completed its
2315 # unmount-all step, but post-stop happens after lxc puts the container into the
2316 # STOPPED state.
2317 # $kill - if true it will always do an immediate hard-stop
2318 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2319 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2320 sub vm_stop {
2321 my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2322
2323 # Open the container's command socket.
2324 my $path = "\0/var/lib/lxc/$vmid/command";
2325 my $sock = IO::Socket::UNIX->new(
2326 Type => SOCK_STREAM(),
2327 Peer => $path,
2328 );
2329 if (!$sock) {
2330 return if $! == ECONNREFUSED; # The container is not running
2331 die "failed to open container ${vmid}'s command socket: $!\n";
2332 }
2333
2334 my $conf = PVE::LXC::Config->load_config($vmid);
2335 PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2336
2337 # Stop the container:
2338
2339 my $cmd = ['lxc-stop', '-n', $vmid];
2340
2341 if ($kill) {
2342 push @$cmd, '--kill'; # doesn't allow timeouts
2343 } else {
2344 # lxc-stop uses a default timeout
2345 push @$cmd, '--nokill' if !$kill_after_timeout;
2346
2347 if (defined($shutdown_timeout)) {
2348 push @$cmd, '--timeout', $shutdown_timeout;
2349 # Give run_command 5 extra seconds
2350 $shutdown_timeout += 5;
2351 }
2352 }
2353
2354 eval { run_command($cmd, timeout => $shutdown_timeout) };
2355 if (my $err = $@) {
2356 warn $@ if $@;
2357 }
2358
2359 my $result = <$sock>;
2360
2361 return if !defined $result; # monitor is gone and the ct has stopped.
2362 die "container did not stop\n";
2363 }
2364
2365 sub vm_reboot {
2366 my ($vmid, $timeout, $skiplock) = @_;
2367
2368 PVE::LXC::Config->lock_config($vmid, sub {
2369 return if !check_running($vmid);
2370
2371 vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2372
2373 my $conf = PVE::LXC::Config->load_config($vmid);
2374 vm_start($vmid, $conf);
2375 });
2376 }
2377
2378 sub run_unshared {
2379 my ($code) = @_;
2380
2381 return PVE::Tools::run_fork(sub {
2382 # Unshare the mount namespace
2383 die "failed to unshare mount namespace: $!\n"
2384 if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2385 run_command(['mount', '--make-rslave', '/']);
2386 return $code->();
2387 });
2388 }
2389
2390 my $copy_volume = sub {
2391 my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid) = @_;
2392
2393 my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2394 $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2395
2396 my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2397 $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2398
2399 my @mounted;
2400 eval {
2401 # mount and copy
2402 mkdir $src;
2403 mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2404 push @mounted, $src;
2405 mkdir $dest;
2406 mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2407 push @mounted, $dest;
2408
2409 $bwlimit //= 0;
2410
2411 run_command([
2412 'rsync',
2413 '--stats',
2414 '-X',
2415 '-A',
2416 '--numeric-ids',
2417 '-aH',
2418 '--whole-file',
2419 '--sparse',
2420 '--one-file-system',
2421 "--bwlimit=$bwlimit",
2422 "$src/",
2423 $dest
2424 ]);
2425 };
2426 my $err = $@;
2427
2428 # Wait for rsync's children to release dest so that
2429 # consequent file operations (umount, remove) are possible
2430 while ((system {"fuser"} "fuser", "-s", $dest) == 0) {sleep 1};
2431
2432 foreach my $mount (reverse @mounted) {
2433 eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2434 warn "Can't umount $mount\n" if $@;
2435 }
2436
2437 # If this fails they're used as mount points in a concurrent operation
2438 # (which should not happen but there's also no real need to get rid of them).
2439 rmdir $dest;
2440 rmdir $src;
2441
2442 die $err if $err;
2443 };
2444
2445 # Should not be called after unsharing the mount namespace!
2446 sub copy_volume {
2447 my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2448
2449 die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2450 File::Path::make_path("/var/lib/lxc/$vmid");
2451 my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2452 my $src = "/var/lib/lxc/$vmid/.copy-volume-2";
2453
2454 # get id's for unprivileged container
2455 my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2456
2457 # Allocate the disk before unsharing in order to make sure zfs subvolumes
2458 # are visible in this namespace, otherwise the host only sees the empty
2459 # (not-mounted) directory.
2460 my $new_volid;
2461 eval {
2462 # Make sure $mp contains a correct size.
2463 $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2464 my $needs_chown;
2465 ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2466 if ($needs_chown) {
2467 PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2468 my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2469 chown($rootuid, $rootgid, $path);
2470 }
2471
2472 run_unshared(sub {
2473 $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2474 });
2475 };
2476 if (my $err = $@) {
2477 PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2478 if defined($new_volid);
2479 die $err;
2480 }
2481
2482 return $new_volid;
2483 }
2484
2485 sub get_lxc_version() {
2486 my $version;
2487 run_command([qw(lxc-start --version)], outfunc => sub {
2488 my ($line) = @_;
2489 # We only parse out major & minor version numbers.
2490 if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2491 $version = [$1, $2];
2492 }
2493 });
2494
2495 die "failed to get lxc version\n" if !defined($version);
2496
2497 # return as a list:
2498 return $version->@*;
2499 }
2500
2501 sub freeze($) {
2502 my ($vmid) = @_;
2503 if (PVE::CGroup::cgroup_mode() == 2) {
2504 PVE::LXC::Command::freeze($vmid, 30);
2505 } else {
2506 PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2507 }
2508 }
2509
2510 sub thaw($) {
2511 my ($vmid) = @_;
2512 if (PVE::CGroup::cgroup_mode() == 2) {
2513 PVE::LXC::Command::unfreeze($vmid, 30);
2514 } else {
2515 PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2516 }
2517 }
2518
2519 1;