src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP EROFS);
  15
  16 use PVE::Exception qw(raise_perm_exc);
  17 use PVE::Storage;
  18 use PVE::SafeSyslog;
  19 use PVE::INotify;
  20 use PVE::Tools qw($IPV6RE $IPV4RE dir_glob_foreach lock_file lock_file_full O_PATH);
  21 use PVE::Network;
  22 use PVE::AccessControl;
  23 use PVE::ProcFSTools;
  24 use PVE::LXC::Config;
  25 use Time::HiRes qw (gettimeofday);
  26
  27 use Data::Dumper;
  28
  29 my $nodename = PVE::INotify::nodename();
  30
  31 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  32
  33 our $COMMON_TAR_FLAGS = [ '--sparse', '--numeric-owner', '--acls',
  34                           '--xattrs',
  35                           '--xattrs-include=user.*',
  36                           '--xattrs-include=security.capability',
  37                           '--warning=no-xattr-write' ];
  38
  39 sub config_list {
  40     my $vmlist = PVE::Cluster::get_vmlist();
  41     my $res = {};
  42     return $res if !$vmlist || !$vmlist->{ids};
  43     my $ids = $vmlist->{ids};
  44
  45     foreach my $vmid (keys %$ids) {
  46         next if !$vmid; # skip CT0
  47         my $d = $ids->{$vmid};
  48         next if !$d->{node} || $d->{node} ne $nodename;
  49         next if !$d->{type} || $d->{type} ne 'lxc';
  50         $res->{$vmid}->{type} = 'lxc';
  51     }
  52     return $res;
  53 }
  54
  55 sub destroy_config {
  56     my ($vmid) = @_;
  57
  58     unlink PVE::LXC::Config->config_file($vmid, $nodename);
  59 }
  60
  61 # container status helpers
  62
  63 sub list_active_containers {
  64
  65     my $filename = "/proc/net/unix";
  66
  67     # similar test is used by lcxcontainers.c: list_active_containers
  68     my $res = {};
  69
  70     my $fh = IO::File->new ($filename, "r");
  71     return $res if !$fh;
  72
  73     while (defined(my $line = <$fh>)) {
  74         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  75             my $path = $1;
  76             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  77                 $res->{$1} = 1;
  78             }
  79         }
  80     }
  81
  82     close($fh);
  83
  84     return $res;
  85 }
  86
  87 # warning: this is slow
  88 sub check_running {
  89     my ($vmid) = @_;
  90
  91     my $active_hash = list_active_containers();
  92
  93     return 1 if defined($active_hash->{$vmid});
  94
  95     return undef;
  96 }
  97
  98 sub get_container_disk_usage {
  99     my ($vmid, $pid) = @_;
 100
 101     return PVE::Tools::df("/proc/$pid/root/", 1);
 102 }
 103
 104 my $last_proc_vmid_stat;
 105
 106 my $parse_cpuacct_stat = sub {
 107     my ($vmid) = @_;
 108
 109     my $raw = read_cgroup_value('cpuacct', $vmid, 'cpuacct.stat', 1);
 110
 111     my $stat = {};
 112
 113     if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
 114
 115         $stat->{utime} = $1;
 116         $stat->{stime} = $2;
 117
 118     }
 119
 120     return $stat;
 121 };
 122
 123 sub vmstatus {
 124     my ($opt_vmid) = @_;
 125
 126     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc' }} : config_list();
 127
 128     my $active_hash = list_active_containers();
 129
 130     my $cpucount = $cpuinfo->{cpus} || 1;
 131
 132     my $cdtime = gettimeofday;
 133
 134     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 135
 136     foreach my $vmid (keys %$list) {
 137         my $d = $list->{$vmid};
 138
 139         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 140         warn $@ if $@; # ignore errors (consider them stopped)
 141
 142         $d->{status} = $d->{pid} ? 'running' : 'stopped';
 143
 144         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 145         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 146
 147         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 148         $d->{name} =~ s/[\s]//g;
 149
 150         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 151         $d->{cpus} = $cpucount if !$d->{cpus};
 152
 153         $d->{lock} = $conf->{lock} || '';
 154
 155         if ($d->{pid}) {
 156             my $res = get_container_disk_usage($vmid, $d->{pid});
 157             $d->{disk} = $res->{used};
 158             $d->{maxdisk} = $res->{total};
 159         } else {
 160             $d->{disk} = 0;
 161             # use 4GB by default ??
 162             if (my $rootfs = $conf->{rootfs}) {
 163                 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
 164                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 165             } else {
 166                 $d->{maxdisk} = 4*1024*1024*1024;
 167             }
 168         }
 169
 170         $d->{mem} = 0;
 171         $d->{swap} = 0;
 172         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 173         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 174
 175         $d->{uptime} = 0;
 176         $d->{cpu} = 0;
 177
 178         $d->{netout} = 0;
 179         $d->{netin} = 0;
 180
 181         $d->{diskread} = 0;
 182         $d->{diskwrite} = 0;
 183
 184         $d->{template} = PVE::LXC::Config->is_template($conf);
 185     }
 186
 187     foreach my $vmid (keys %$list) {
 188         my $d = $list->{$vmid};
 189         my $pid = $d->{pid};
 190
 191         next if !$pid; # skip stopped CTs
 192
 193         my $ctime = (stat("/proc/$pid"))[10]; # 10 = ctime
 194         $d->{uptime} = time - $ctime; # the method lxcfs uses
 195
 196         my $memory_stat = read_cgroup_list('memory', $vmid, 'memory.stat');
 197         my $mem_usage_in_bytes = read_cgroup_value('memory', $vmid, 'memory.usage_in_bytes');
 198
 199         $d->{mem} = $mem_usage_in_bytes - $memory_stat->{cache};
 200         $d->{swap} = read_cgroup_value('memory', $vmid, 'memory.memsw.usage_in_bytes') - $mem_usage_in_bytes;
 201
 202         my $blkio_bytes = read_cgroup_value('blkio', $vmid, 'blkio.throttle.io_service_bytes', 1);
 203         my @bytes = split(/\n/, $blkio_bytes);
 204         foreach my $byte (@bytes) {
 205             if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 206                 $d->{diskread} = $2 if $key eq 'Read';
 207                 $d->{diskwrite} = $2 if $key eq 'Write';
 208             }
 209         }
 210
 211         my $pstat = &$parse_cpuacct_stat($vmid);
 212
 213         my $used = $pstat->{utime} + $pstat->{stime};
 214
 215         my $old = $last_proc_vmid_stat->{$vmid};
 216         if (!$old) {
 217             $last_proc_vmid_stat->{$vmid} = {
 218                 time => $cdtime,
 219                 used => $used,
 220                 cpu => 0,
 221             };
 222             next;
 223         }
 224
 225         my $dtime = ($cdtime -  $old->{time}) * $cpucount * $cpuinfo->{user_hz};
 226
 227         if ($dtime > 1000) {
 228             my $dutime = $used -  $old->{used};
 229
 230             $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
 231             $last_proc_vmid_stat->{$vmid} = {
 232                 time => $cdtime,
 233                 used => $used,
 234                 cpu => $d->{cpu},
 235             };
 236         } else {
 237             $d->{cpu} = $old->{cpu};
 238         }
 239     }
 240
 241     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 242
 243     foreach my $dev (keys %$netdev) {
 244         next if $dev !~ m/^veth([1-9]\d*)i/;
 245         my $vmid = $1;
 246         my $d = $list->{$vmid};
 247
 248         next if !$d;
 249
 250         $d->{netout} += $netdev->{$dev}->{receive};
 251         $d->{netin} += $netdev->{$dev}->{transmit};
 252
 253     }
 254
 255     return $list;
 256 }
 257
 258 sub read_cgroup_list {
 259     my ($group, $vmid, $name) = @_;
 260
 261     my $content = read_cgroup_value($group, $vmid, $name, 1);
 262
 263     return { split(/\s+/, $content) };
 264 }
 265
 266 sub read_cgroup_value {
 267     my ($group, $vmid, $name, $full) = @_;
 268
 269     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 270
 271     return PVE::Tools::file_get_contents($path) if $full;
 272
 273     return PVE::Tools::file_read_firstline($path);
 274 }
 275
 276 sub write_cgroup_value {
 277    my ($group, $vmid, $name, $value) = @_;
 278
 279    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 280    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 281
 282 }
 283
 284 sub find_lxc_console_pids {
 285
 286     my $res = {};
 287
 288     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 289         my ($pid) = @_;
 290
 291         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 292         return if !$cmdline;
 293
 294         my @args = split(/\0/, $cmdline);
 295
 296         # search for lxc-console -n <vmid>
 297         return if scalar(@args) != 3;
 298         return if $args[1] ne '-n';
 299         return if $args[2] !~ m/^\d+$/;
 300         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 301
 302         my $vmid = $args[2];
 303
 304         push @{$res->{$vmid}}, $pid;
 305     });
 306
 307     return $res;
 308 }
 309
 310 sub find_lxc_pid {
 311     my ($vmid) = @_;
 312
 313     my $pid = undef;
 314     my $parser = sub {
 315         my $line = shift;
 316         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 317     };
 318     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 319
 320     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 321
 322     return $pid;
 323 }
 324
 325 # Note: we cannot use Net:IP, because that only allows strict
 326 # CIDR networks
 327 sub parse_ipv4_cidr {
 328     my ($cidr, $noerr) = @_;
 329
 330     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 331         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 332     }
 333
 334     return undef if $noerr;
 335
 336     die "unable to parse ipv4 address/mask\n";
 337 }
 338
 339
 340 sub update_lxc_config {
 341     my ($vmid, $conf) = @_;
 342
 343     my $dir = "/var/lib/lxc/$vmid";
 344
 345     if ($conf->{template}) {
 346
 347         unlink "$dir/config";
 348
 349         return;
 350     }
 351
 352     my $raw = '';
 353
 354     die "missing 'arch' - internal error" if !$conf->{arch};
 355     $raw .= "lxc.arch = $conf->{arch}\n";
 356
 357     my $unprivileged = $conf->{unprivileged};
 358     my $custom_idmap = grep { $_->[0] eq 'lxc.id_map' } @{$conf->{lxc}};
 359
 360     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 361     if ($ostype =~ /^(?:debian | ubuntu | centos | fedora | opensuse | archlinux | alpine | gentoo | unmanaged)$/x) {
 362         my $inc ="/usr/share/lxc/config/$ostype.common.conf";
 363         $inc ="/usr/share/lxc/config/common.conf" if !-f $inc;
 364         $raw .= "lxc.include = $inc\n";
 365         if ($unprivileged || $custom_idmap) {
 366             $inc = "/usr/share/lxc/config/$ostype.userns.conf";
 367             $inc = "/usr/share/lxc/config/userns.conf" if !-f $inc;
 368             $raw .= "lxc.include = $inc\n"
 369         }
 370     } else {
 371         die "implement me (ostype $ostype)";
 372     }
 373
 374     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 375     # cannot be exposed to the container with r/w access (cgroup perms).
 376     # When this is enabled mounts will still remain in the monitor's namespace
 377     # after the container unmounted them and thus will not detach from their
 378     # files while the container is running!
 379     $raw .= "lxc.monitor.unshare = 1\n";
 380
 381     # Should we read them from /etc/subuid?
 382     if ($unprivileged && !$custom_idmap) {
 383         $raw .= "lxc.id_map = u 0 100000 65536\n";
 384         $raw .= "lxc.id_map = g 0 100000 65536\n";
 385     }
 386
 387     if (!PVE::LXC::Config->has_dev_console($conf)) {
 388         $raw .= "lxc.console = none\n";
 389         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 390     }
 391
 392     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 393     $raw .= "lxc.tty = $ttycount\n";
 394
 395     # some init scripts expect a linux terminal (turnkey).
 396     $raw .= "lxc.environment = TERM=linux\n";
 397
 398     my $utsname = $conf->{hostname} || "CT$vmid";
 399     $raw .= "lxc.utsname = $utsname\n";
 400
 401     my $memory = $conf->{memory} || 512;
 402     my $swap = $conf->{swap} // 0;
 403
 404     my $lxcmem = int($memory*1024*1024);
 405     $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 406
 407     my $lxcswap = int(($memory + $swap)*1024*1024);
 408     $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 409
 410     if (my $cpulimit = $conf->{cpulimit}) {
 411         $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 412         my $value = int(100000*$cpulimit);
 413         $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 414     }
 415
 416     my $shares = $conf->{cpuunits} || 1024;
 417     $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 418
 419     die "missing 'rootfs' configuration\n"
 420         if !defined($conf->{rootfs});
 421
 422     my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 423
 424     $raw .= "lxc.rootfs = $dir/rootfs\n";
 425
 426     my $netcount = 0;
 427     foreach my $k (sort keys %$conf) {
 428         next if $k !~ m/^net(\d+)$/;
 429         my $ind = $1;
 430         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 431         $netcount++;
 432         $raw .= "lxc.network.type = veth\n";
 433         $raw .= "lxc.network.veth.pair = veth${vmid}i${ind}\n";
 434         $raw .= "lxc.network.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 435         $raw .= "lxc.network.name = $d->{name}\n" if defined($d->{name});
 436         $raw .= "lxc.network.mtu = $d->{mtu}\n" if defined($d->{mtu});
 437     }
 438
 439     if (my $lxcconf = $conf->{lxc}) {
 440         foreach my $entry (@$lxcconf) {
 441             my ($k, $v) = @$entry;
 442             $netcount++ if $k eq 'lxc.network.type';
 443             $raw .= "$k = $v\n";
 444         }
 445     }
 446
 447     $raw .= "lxc.network.type = empty\n" if !$netcount;
 448
 449     File::Path::mkpath("$dir/rootfs");
 450
 451     PVE::Tools::file_set_contents("$dir/config", $raw);
 452 }
 453
 454 # verify and cleanup nameserver list (replace \0 with ' ')
 455 sub verify_nameserver_list {
 456     my ($nameserver_list) = @_;
 457
 458     my @list = ();
 459     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 460         PVE::JSONSchema::pve_verify_ip($server);
 461         push @list, $server;
 462     }
 463
 464     return join(' ', @list);
 465 }
 466
 467 sub verify_searchdomain_list {
 468     my ($searchdomain_list) = @_;
 469
 470     my @list = ();
 471     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 472         # todo: should we add checks for valid dns domains?
 473         push @list, $server;
 474     }
 475
 476     return join(' ', @list);
 477 }
 478
 479 sub get_console_command {
 480     my ($vmid, $conf) = @_;
 481
 482     my $cmode = PVE::LXC::Config->get_cmode($conf);
 483
 484     if ($cmode eq 'console') {
 485         return ['lxc-console', '-n',  $vmid, '-t', 0];
 486     } elsif ($cmode eq 'tty') {
 487         return ['lxc-console', '-n',  $vmid];
 488     } elsif ($cmode eq 'shell') {
 489         return ['lxc-attach', '--clear-env', '-n', $vmid];
 490     } else {
 491         die "internal error";
 492     }
 493 }
 494
 495 sub get_primary_ips {
 496     my ($conf) = @_;
 497
 498     # return data from net0
 499
 500     return undef if !defined($conf->{net0});
 501     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 502
 503     my $ipv4 = $net->{ip};
 504     if ($ipv4) {
 505         if ($ipv4 =~ /^(dhcp|manual)$/) {
 506             $ipv4 = undef
 507         } else {
 508             $ipv4 =~ s!/\d+$!!;
 509         }
 510     }
 511     my $ipv6 = $net->{ip6};
 512     if ($ipv6) {
 513         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 514             $ipv6 = undef;
 515         } else {
 516             $ipv6 =~ s!/\d+$!!;
 517         }
 518     }
 519
 520     return ($ipv4, $ipv6);
 521 }
 522
 523 sub delete_mountpoint_volume {
 524     my ($storage_cfg, $vmid, $volume) = @_;
 525
 526     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 527
 528     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 529     PVE::Storage::vdisk_free($storage_cfg, $volume) if $vmid == $owner;
 530 }
 531
 532 sub destroy_lxc_container {
 533     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 534
 535     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 536         my ($ms, $mountpoint) = @_;
 537         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 538     });
 539
 540     rmdir "/var/lib/lxc/$vmid/rootfs";
 541     unlink "/var/lib/lxc/$vmid/config";
 542     rmdir "/var/lib/lxc/$vmid";
 543     if (defined $replacement_conf) {
 544         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 545     } else {
 546         destroy_config($vmid);
 547     }
 548
 549     #my $cmd = ['lxc-destroy', '-n', $vmid ];
 550     #PVE::Tools::run_command($cmd);
 551 }
 552
 553 sub vm_stop_cleanup {
 554     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 555
 556     eval {
 557         if (!$keepActive) {
 558
 559             my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 560             PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 561         }
 562     };
 563     warn $@ if $@; # avoid errors - just warn
 564 }
 565
 566 my $safe_num_ne = sub {
 567     my ($a, $b) = @_;
 568
 569     return 0 if !defined($a) && !defined($b);
 570     return 1 if !defined($a);
 571     return 1 if !defined($b);
 572
 573     return $a != $b;
 574 };
 575
 576 my $safe_string_ne = sub {
 577     my ($a, $b) = @_;
 578
 579     return 0 if !defined($a) && !defined($b);
 580     return 1 if !defined($a);
 581     return 1 if !defined($b);
 582
 583     return $a ne $b;
 584 };
 585
 586 sub update_net {
 587     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 588
 589     if ($newnet->{type} ne 'veth') {
 590         # for when there are physical interfaces
 591         die "cannot update interface of type $newnet->{type}";
 592     }
 593
 594     my $veth = "veth${vmid}i${netid}";
 595     my $eth = $newnet->{name};
 596
 597     if (my $oldnetcfg = $conf->{$opt}) {
 598         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 599
 600         if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 601             &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
 602
 603             PVE::Network::veth_delete($veth);
 604             delete $conf->{$opt};
 605             PVE::LXC::Config->write_config($vmid, $conf);
 606
 607             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 608
 609         } else {
 610             if (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 611                 &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 612                 &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 613
 614                 if ($oldnet->{bridge}) {
 615                     PVE::Network::tap_unplug($veth);
 616                     foreach (qw(bridge tag firewall)) {
 617                         delete $oldnet->{$_};
 618                     }
 619                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 620                     PVE::LXC::Config->write_config($vmid, $conf);
 621                 }
 622
 623                 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 624                 # This includes the rate:
 625                 foreach (qw(bridge tag firewall rate)) {
 626                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 627                 }
 628             } elsif (&$safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 629                 # Rate can be applied on its own but any change above needs to
 630                 # include the rate in tap_plug since OVS resets everything.
 631                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 632                 $oldnet->{rate} = $newnet->{rate}
 633             }
 634             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 635             PVE::LXC::Config->write_config($vmid, $conf);
 636         }
 637     } else {
 638         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 639     }
 640
 641     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 642 }
 643
 644 sub hotplug_net {
 645     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 646
 647     my $veth = "veth${vmid}i${netid}";
 648     my $vethpeer = $veth . "p";
 649     my $eth = $newnet->{name};
 650
 651     PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 652     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 653
 654     # attach peer in container
 655     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 656     PVE::Tools::run_command($cmd);
 657
 658     # link up peer in container
 659     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 660     PVE::Tools::run_command($cmd);
 661
 662     my $done = { type => 'veth' };
 663     foreach (qw(bridge tag firewall hwaddr name)) {
 664         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 665     }
 666     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 667
 668     PVE::LXC::Config->write_config($vmid, $conf);
 669 }
 670
 671 sub update_ipconfig {
 672     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 673
 674     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 675
 676     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 677     my $deleted = [];
 678     my $added = [];
 679     my $nscmd = sub {
 680         my $cmdargs = shift;
 681         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 682     };
 683     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 684
 685     my $change_ip_config = sub {
 686         my ($ipversion) = @_;
 687
 688         my $family_opt = "-$ipversion";
 689         my $suffix = $ipversion == 4 ? '' : $ipversion;
 690         my $gw= "gw$suffix";
 691         my $ip= "ip$suffix";
 692
 693         my $newip = $newnet->{$ip};
 694         my $newgw = $newnet->{$gw};
 695         my $oldip = $optdata->{$ip};
 696
 697         my $change_ip = &$safe_string_ne($oldip, $newip);
 698         my $change_gw = &$safe_string_ne($optdata->{$gw}, $newgw);
 699
 700         return if !$change_ip && !$change_gw;
 701
 702         # step 1: add new IP, if this fails we cancel
 703         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 704         if ($change_ip && $is_real_ip) {
 705             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 706             if (my $err = $@) {
 707                 warn $err;
 708                 return;
 709             }
 710         }
 711
 712         # step 2: replace gateway
 713         #   If this fails we delete the added IP and cancel.
 714         #   If it succeeds we save the config and delete the old IP, ignoring
 715         #   errors. The config is then saved.
 716         # Note: 'ip route replace' can add
 717         if ($change_gw) {
 718             if ($newgw) {
 719                 eval {
 720                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
 721                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
 722                     }
 723                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
 724                 };
 725                 if (my $err = $@) {
 726                     warn $err;
 727                     # the route was not replaced, the old IP is still available
 728                     # rollback (delete new IP) and cancel
 729                     if ($change_ip) {
 730                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
 731                         warn $@ if $@; # no need to die here
 732                     }
 733                     return;
 734                 }
 735             } else {
 736                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
 737                 # if the route was not deleted, the guest might have deleted it manually
 738                 # warn and continue
 739                 warn $@ if $@;
 740             }
 741         }
 742
 743         # from this point on we save the configuration
 744         # step 3: delete old IP ignoring errors
 745         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
 746             # We need to enable promote_secondaries, otherwise our newly added
 747             # address will be removed along with the old one.
 748             my $promote = 0;
 749             eval {
 750                 if ($ipversion == 4) {
 751                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
 752                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
 753                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
 754                 }
 755                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
 756             };
 757             warn $@ if $@; # no need to die here
 758
 759             if ($ipversion == 4) {
 760                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
 761             }
 762         }
 763
 764         foreach my $property ($ip, $gw) {
 765             if ($newnet->{$property}) {
 766                 $optdata->{$property} = $newnet->{$property};
 767             } else {
 768                 delete $optdata->{$property};
 769             }
 770         }
 771         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
 772         PVE::LXC::Config->write_config($vmid, $conf);
 773         $lxc_setup->setup_network($conf);
 774     };
 775
 776     &$change_ip_config(4);
 777     &$change_ip_config(6);
 778
 779 }
 780
 781 my $enter_namespace = sub {
 782     my ($vmid, $pid, $which, $type) = @_;
 783     sysopen my $fd, "/proc/$pid/ns/$which", O_RDONLY
 784         or die "failed to open $which namespace of container $vmid: $!\n";
 785     PVE::Tools::setns(fileno($fd), $type)
 786         or die "failed to enter $which namespace of container $vmid: $!\n";
 787     close $fd;
 788 };
 789
 790 my $do_syncfs = sub {
 791     my ($vmid, $pid, $socket) = @_;
 792
 793     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
 794
 795     # Tell the parent process to start reading our /proc/mounts
 796     print {$socket} "go\n";
 797     $socket->flush();
 798
 799     # Receive /proc/self/mounts
 800     my $mountdata = do { local $/ = undef; <$socket> };
 801     close $socket;
 802
 803     # Now sync all mountpoints...
 804     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
 805     foreach my $mp (@$mounts) {
 806         my ($what, $dir, $fs) = @$mp;
 807         next if $fs eq 'fuse.lxcfs';
 808         eval { PVE::Tools::sync_mountpoint($dir); };
 809         warn $@ if $@;
 810     }
 811 };
 812
 813 sub sync_container_namespace {
 814     my ($vmid) = @_;
 815     my $pid = find_lxc_pid($vmid);
 816
 817     # SOCK_DGRAM is nicer for barriers but cannot be slurped
 818     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
 819         or die "failed to create socketpair: $!\n";
 820
 821     my $child = fork();
 822     die "fork failed: $!\n" if !defined($child);
 823
 824     if (!$child) {
 825         eval {
 826             close $pfd;
 827             &$do_syncfs($vmid, $pid, $cfd);
 828         };
 829         if (my $err = $@) {
 830             warn $err;
 831             POSIX::_exit(1);
 832         }
 833         POSIX::_exit(0);
 834     }
 835     close $cfd;
 836     my $go = <$pfd>;
 837     die "failed to enter container namespace\n" if $go ne "go\n";
 838
 839     open my $mounts, '<', "/proc/$child/mounts"
 840         or die "failed to open container's /proc/mounts: $!\n";
 841     my $mountdata = do { local $/ = undef; <$mounts> };
 842     close $mounts;
 843     print {$pfd} $mountdata;
 844     close $pfd;
 845
 846     while (waitpid($child, 0) != $child) {}
 847     die "failed to sync container namespace\n" if $? != 0;
 848 }
 849
 850 sub template_create {
 851     my ($vmid, $conf) = @_;
 852
 853     my $storecfg = PVE::Storage::config();
 854
 855     my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 856     my $volid = $rootinfo->{volume};
 857
 858     die "Template feature is not available for '$volid'\n"
 859         if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
 860
 861     PVE::Storage::activate_volumes($storecfg, [$volid]);
 862
 863     my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
 864     $rootinfo->{volume} = $template_volid;
 865     $conf->{rootfs} = PVE::LXC::Config->print_ct_mountpoint($rootinfo, 1);
 866
 867     PVE::LXC::Config->write_config($vmid, $conf);
 868 }
 869
 870 sub check_ct_modify_config_perm {
 871     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
 872
 873     return 1 if $authuser eq 'root@pam';
 874
 875     my $check = sub {
 876         my ($opt, $delete) = @_;
 877         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
 878             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 879         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
 880             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 881             return if $delete;
 882             my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
 883                                         : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
 884             raise_perm_exc("mount point type $data->{type}") if $data->{type} ne 'volume';
 885         } elsif ($opt eq 'memory' || $opt eq 'swap') {
 886             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 887         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
 888                  $opt eq 'searchdomain' || $opt eq 'hostname') {
 889             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 890         } else {
 891             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 892         }
 893     };
 894
 895     foreach my $opt (keys %$newconf) {
 896         &$check($opt, 0);
 897     }
 898     foreach my $opt (@$delete) {
 899         &$check($opt, 1);
 900     }
 901
 902     return 1;
 903 }
 904
 905 sub umount_all {
 906     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
 907
 908     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
 909     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
 910
 911     PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
 912         my ($ms, $mountpoint) = @_;
 913
 914         my $volid = $mountpoint->{volume};
 915         my $mount = $mountpoint->{mp};
 916
 917         return if !$volid || !$mount;
 918
 919         my $mount_path = "$rootdir/$mount";
 920         $mount_path =~ s!/+!/!g;
 921
 922         return if !PVE::ProcFSTools::is_mounted($mount_path);
 923
 924         eval {
 925             PVE::Tools::run_command(['umount', '-d', $mount_path]);
 926         };
 927         if (my $err = $@) {
 928             if ($noerr) {
 929                 warn $err;
 930             } else {
 931                 die $err;
 932             }
 933         }
 934     });
 935 }
 936
 937 sub mount_all {
 938     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
 939
 940     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
 941     File::Path::make_path($rootdir);
 942
 943     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
 944     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
 945
 946     eval {
 947         PVE::LXC::Config->foreach_mountpoint($conf, sub {
 948             my ($ms, $mountpoint) = @_;
 949
 950             $mountpoint->{ro} = 0 if $ignore_ro;
 951
 952             mountpoint_mount($mountpoint, $rootdir, $storage_cfg);
 953         });
 954     };
 955     if (my $err = $@) {
 956         warn "mounting container failed\n";
 957         umount_all($vmid, $storage_cfg, $conf, 1);
 958         die $err;
 959     }
 960
 961     return $rootdir;
 962 }
 963
 964
 965 sub mountpoint_mount_path {
 966     my ($mountpoint, $storage_cfg, $snapname) = @_;
 967
 968     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
 969 }
 970
 971 sub query_loopdev {
 972     my ($path) = @_;
 973     my $found;
 974     my $parser = sub {
 975         my $line = shift;
 976         if ($line =~ m@^(/dev/loop\d+):@) {
 977             $found = $1;
 978         }
 979     };
 980     my $cmd = ['losetup', '--associated', $path];
 981     PVE::Tools::run_command($cmd, outfunc => $parser);
 982     return $found;
 983 }
 984
 985 # Run a function with a file attached to a loop device.
 986 # The loop device is always detached afterwards (or set to autoclear).
 987 # Returns the loop device.
 988 sub run_with_loopdev {
 989     my ($func, $file) = @_;
 990     my $device = query_loopdev($file);
 991     # Try to reuse an existing device
 992     if ($device) {
 993         # We assume that whoever setup the loop device is responsible for
 994         # detaching it.
 995         &$func($device);
 996         return $device;
 997     }
 998
 999     my $parser = sub {
1000         my $line = shift;
1001         if ($line =~ m@^(/dev/loop\d+)$@) {
1002             $device = $1;
1003         }
1004     };
1005     PVE::Tools::run_command(['losetup', '--show', '-f', $file], outfunc => $parser);
1006     die "failed to setup loop device for $file\n" if !$device;
1007     eval { &$func($device); };
1008     my $err = $@;
1009     PVE::Tools::run_command(['losetup', '-d', $device]);
1010     die $err if $err;
1011     return $device;
1012 }
1013
1014 # In scalar mode: returns a file handle to the deepest directory node.
1015 # In list context: returns a list of:
1016 #   * the deepest directory node
1017 #   * the 2nd deepest directory (parent of the above)
1018 #   * directory name of the last directory
1019 # So that the path $2/$3 should lead to $1 afterwards.
1020 sub walk_tree_nofollow($$$) {
1021     my ($start, $subdir, $mkdir) = @_;
1022
1023     # splitdir() returns '' for empty components including the leading /
1024     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1025
1026     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1027         or die "failed to open start directory $start: $!\n";
1028
1029     my $dir = $start;
1030     my $last_component = undef;
1031     my $second = $fd;
1032     foreach my $component (@comps) {
1033         $dir .= "/$component";
1034         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1035
1036         if (!$next) {
1037             # failed, check for symlinks and try to create the path
1038             die "symlink encountered at: $dir\n" if $! == ELOOP;
1039             die "cannot open directory $dir: $!\n" if !$mkdir;
1040
1041             # We don't check for errors on mkdirat() here and just try to
1042             # openat() again, since at least one error (EEXIST) is an
1043             # expected possibility if multiple containers start
1044             # simultaneously. If someone else injects a symlink now then
1045             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1046             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1047
1048             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1049             die "failed to create path: $dir: $!\n" if !$next;
1050         }
1051
1052         close $second if defined($last_component);
1053         $last_component = $component;
1054         $second = $fd;
1055         $fd = $next;
1056     }
1057
1058     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1059     close $second if defined($last_component);
1060     return $fd;
1061 }
1062
1063 # To guard against symlink attack races against other currently running
1064 # containers with shared recursive bind mount hierarchies we prepare a
1065 # directory handle for the directory we're mounting over to verify the
1066 # mountpoint afterwards.
1067 sub __bindmount_prepare {
1068     my ($hostroot, $dir) = @_;
1069     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1070     return $srcdh;
1071 }
1072
1073 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1074 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1075 # we intended to bind mount.
1076 sub __bindmount_verify {
1077     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1078     my $destdh;
1079     if ($parentfd) {
1080         # Open the mount point path coming from the parent directory since the
1081         # filehandle we would have gotten as first result of walk_tree_nofollow
1082         # earlier is still a handle to the underlying directory instead of the
1083         # mounted path.
1084         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1085         die "failed to open mount point: $!\n" if !$destdh;
1086         if ($ro) {
1087             my $dot = '.';
1088             # 269: faccessat()
1089             # no separate function because 99% of the time it's the wrong thing to use.
1090             if (syscall(269, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1091                 die "failed to mark bind mount read only\n";
1092             }
1093             die "read-only check failed: $!\n" if $! != EROFS;
1094         }
1095     } else {
1096         # For the rootfs we don't have a parentfd so we open the path directly.
1097         # Note that this means bindmounting any prefix of the host's
1098         # /var/lib/lxc/$vmid path into another container is considered a grave
1099         # security error.
1100         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1101         die "failed to open mount point: $!\n" if !$destdh;
1102     }
1103
1104     my ($srcdev, $srcinode) = stat($srcdh);
1105     my ($dstdev, $dstinode) = stat($destdh);
1106     close $srcdh;
1107     close $destdh;
1108
1109     return ($srcdev == $dstdev && $srcinode == $dstinode);
1110 }
1111
1112 # Perform the actual bind mounting:
1113 sub __bindmount_do {
1114     my ($dir, $dest, $ro, @extra_opts) = @_;
1115     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1116     if ($ro) {
1117         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1118         if (my $err = $@) {
1119             warn "bindmount error\n";
1120             # don't leave writable bind-mounts behind...
1121             PVE::Tools::run_command(['umount', $dest]);
1122             die $err;
1123         }
1124     }
1125 }
1126
1127 sub bindmount {
1128     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1129
1130     my $srcdh = __bindmount_prepare('/', $dir);
1131
1132     __bindmount_do($dir, $dest, $ro, @extra_opts);
1133
1134     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1135         PVE::Tools::run_command(['umount', $dest]);
1136         die "detected mount path change at: $dir\n";
1137     }
1138 }
1139
1140 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1141 # from $rootdir and $mount and walk the path from $rootdir to the final
1142 # directory to check for symlinks.
1143 sub __mount_prepare_rootdir {
1144     my ($rootdir, $mount) = @_;
1145     $rootdir =~ s!/+!/!g;
1146     $rootdir =~ s!/+$!!;
1147     my $mount_path = "$rootdir/$mount";
1148     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1);
1149     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1150 }
1151
1152 # use $rootdir = undef to just return the corresponding mount path
1153 sub mountpoint_mount {
1154     my ($mountpoint, $rootdir, $storage_cfg, $snapname) = @_;
1155
1156     my $volid = $mountpoint->{volume};
1157     my $mount = $mountpoint->{mp};
1158     my $type = $mountpoint->{type};
1159     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1160     my $mounted_dev;
1161
1162     return if !$volid || !$mount;
1163
1164     $mount =~ s!/+!/!g;
1165
1166     my $mount_path;
1167     my ($mpfd, $parentfd, $last_dir);
1168
1169     if (defined($rootdir)) {
1170         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1171             __mount_prepare_rootdir($rootdir, $mount);
1172     }
1173
1174     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1175
1176     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1177
1178     my $optstring = '';
1179     my $acl = $mountpoint->{acl};
1180     if (defined($acl)) {
1181         $optstring .= ($acl ? 'acl' : 'noacl');
1182     }
1183     my $readonly = $mountpoint->{ro};
1184
1185     my @extra_opts = ('-o', $optstring) if $optstring;
1186
1187     if ($storage) {
1188
1189         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1190
1191         # early sanity checks:
1192         # we otherwise call realpath on the rbd url
1193         die "containers on rbd storage without krbd are not supported\n"
1194             if $scfg->{type} eq 'rbd' && !$scfg->{krbd};
1195
1196         my $path = PVE::Storage::path($storage_cfg, $volid, $snapname);
1197
1198         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1199             PVE::Storage::parse_volname($storage_cfg, $volid);
1200
1201         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1202
1203         if ($format eq 'subvol') {
1204             if ($mount_path) {
1205                 if ($snapname) {
1206                     if ($scfg->{type} eq 'zfspool') {
1207                         my $path_arg = $path;
1208                         $path_arg =~ s!^/+!!;
1209                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', $path_arg, $mount_path]);
1210                     } else {
1211                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1212                     }
1213                 } else {
1214                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1215                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1216                         my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1217                         $name .= "\@$snapname" if defined($snapname);
1218                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1219                     }
1220                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1221                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1222                 }
1223             }
1224             return wantarray ? ($path, 0, undef) : $path;
1225         } elsif ($format eq 'raw' || $format eq 'iso') {
1226             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1227             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1228             # Our autodev hook expects the /dev/dm-* device currently
1229             # and will create the /dev/mapper symlink accordingly
1230             $path = Cwd::realpath($path);
1231             die "failed to get device path\n" if !$path;
1232             ($path) = ($path =~ /^(.*)$/s); #untaint
1233             my $domount = sub {
1234                 my ($path) = @_;
1235                 if ($mount_path) {
1236                     if ($format eq 'iso') {
1237                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1238                     } elsif ($isBase || defined($snapname)) {
1239                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1240                     } else {
1241                         if ($quota) {
1242                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1243                         }
1244                         push @extra_opts, '-o', 'ro' if $readonly;
1245                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1246                     }
1247                 }
1248             };
1249             my $use_loopdev = 0;
1250             if ($scfg->{path}) {
1251                 $mounted_dev = run_with_loopdev($domount, $path);
1252                 $use_loopdev = 1;
1253             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1254                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1255                 $mounted_dev = $path;
1256                 &$domount($path);
1257             } else {
1258                 die "unsupported storage type '$scfg->{type}'\n";
1259             }
1260             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1261         } else {
1262             die "unsupported image format '$format'\n";
1263         }
1264     } elsif ($type eq 'device') {
1265         push @extra_opts, '-o', 'ro' if $readonly;
1266         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1267         # See the NOTE above about devicemapper canonicalization
1268         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1269         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1270         return wantarray ? ($volid, 0, $devpath) : $volid;
1271     } elsif ($type eq 'bind') {
1272         die "directory '$volid' does not exist\n" if ! -d $volid;
1273         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1274         warn "cannot enable quota control for bind mounts\n" if $quota;
1275         return wantarray ? ($volid, 0, undef) : $volid;
1276     }
1277
1278     die "unsupported storage";
1279 }
1280
1281 sub mkfs {
1282     my ($dev, $rootuid, $rootgid) = @_;
1283
1284     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1285                              '-E', "root_owner=$rootuid:$rootgid",
1286                              $dev]);
1287 }
1288
1289 sub format_disk {
1290     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1291
1292     if ($volid =~ m!^/dev/.+!) {
1293         mkfs($volid);
1294         return;
1295     }
1296
1297     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1298
1299     die "cannot format volume '$volid' with no storage\n" if !$storage;
1300
1301     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1302
1303     my $path = PVE::Storage::path($storage_cfg, $volid);
1304
1305     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1306         PVE::Storage::parse_volname($storage_cfg, $volid);
1307
1308     die "cannot format volume '$volid' (format == $format)\n"
1309         if $format ne 'raw';
1310
1311     mkfs($path, $rootuid, $rootgid);
1312 }
1313
1314 sub destroy_disks {
1315     my ($storecfg, $vollist) = @_;
1316
1317     foreach my $volid (@$vollist) {
1318         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1319         warn $@ if $@;
1320     }
1321 }
1322
1323 sub create_disks {
1324     my ($storecfg, $vmid, $settings, $conf) = @_;
1325
1326     my $vollist = [];
1327
1328     eval {
1329         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1330         my $chown_vollist = [];
1331
1332         PVE::LXC::Config->foreach_mountpoint($settings, sub {
1333             my ($ms, $mountpoint) = @_;
1334
1335             my $volid = $mountpoint->{volume};
1336             my $mp = $mountpoint->{mp};
1337
1338             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1339
1340             if ($storage && ($volid =~ m/^([^:\s]+):(\d+(\.\d+)?)$/)) {
1341                 my ($storeid, $size_gb) = ($1, $2);
1342
1343                 my $size_kb = int(${size_gb}*1024) * 1024;
1344
1345                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1346                 # fixme: use better naming ct-$vmid-disk-X.raw?
1347
1348                 if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs') {
1349                     if ($size_kb > 0) {
1350                         $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1351                                                            undef, $size_kb);
1352                         format_disk($storecfg, $volid, $rootuid, $rootgid);
1353                     } else {
1354                         $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1355                                                            undef, 0);
1356                         push @$chown_vollist, $volid;
1357                     }
1358                 } elsif ($scfg->{type} eq 'zfspool') {
1359
1360                     $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1361                                                        undef, $size_kb);
1362                     push @$chown_vollist, $volid;
1363                 } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1364
1365                     $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1366                     format_disk($storecfg, $volid, $rootuid, $rootgid);
1367
1368                 } elsif ($scfg->{type} eq 'rbd') {
1369
1370                     die "krbd option must be enabled on storage type '$scfg->{type}'\n" if !$scfg->{krbd};
1371                     $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1372                     format_disk($storecfg, $volid, $rootuid, $rootgid);
1373                 } else {
1374                     die "unable to create containers on storage type '$scfg->{type}'\n";
1375                 }
1376                 push @$vollist, $volid;
1377                 $mountpoint->{volume} = $volid;
1378                 $mountpoint->{size} = $size_kb * 1024;
1379                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1380             } else {
1381                 # use specified/existing volid/dir/device
1382                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1383             }
1384         });
1385
1386         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1387         foreach my $volid (@$chown_vollist) {
1388             my $path = PVE::Storage::path($storecfg, $volid, undef);
1389             chown($rootuid, $rootgid, $path);
1390         }
1391         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1392     };
1393     # free allocated images on error
1394     if (my $err = $@) {
1395         destroy_disks($storecfg, $vollist);
1396         die $err;
1397     }
1398     return $vollist;
1399 }
1400
1401 # bash completion helper
1402
1403 sub complete_os_templates {
1404     my ($cmdname, $pname, $cvalue) = @_;
1405
1406     my $cfg = PVE::Storage::config();
1407
1408     my $storeid;
1409
1410     if ($cvalue =~ m/^([^:]+):/) {
1411         $storeid = $1;
1412     }
1413
1414     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
1415     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
1416
1417     my $res = [];
1418     foreach my $id (keys %$data) {
1419         foreach my $item (@{$data->{$id}}) {
1420             push @$res, $item->{volid} if defined($item->{volid});
1421         }
1422     }
1423
1424     return $res;
1425 }
1426
1427 my $complete_ctid_full = sub {
1428     my ($running) = @_;
1429
1430     my $idlist = vmstatus();
1431
1432     my $active_hash = list_active_containers();
1433
1434     my $res = [];
1435
1436     foreach my $id (keys %$idlist) {
1437         my $d = $idlist->{$id};
1438         if (defined($running)) {
1439             next if $d->{template};
1440             next if $running && !$active_hash->{$id};
1441             next if !$running && $active_hash->{$id};
1442         }
1443         push @$res, $id;
1444
1445     }
1446     return $res;
1447 };
1448
1449 sub complete_ctid {
1450     return &$complete_ctid_full();
1451 }
1452
1453 sub complete_ctid_stopped {
1454     return &$complete_ctid_full(0);
1455 }
1456
1457 sub complete_ctid_running {
1458     return &$complete_ctid_full(1);
1459 }
1460
1461 sub parse_id_maps {
1462     my ($conf) = @_;
1463
1464     my $id_map = [];
1465     my $rootuid = 0;
1466     my $rootgid = 0;
1467
1468     my $lxc = $conf->{lxc};
1469     foreach my $entry (@$lxc) {
1470         my ($key, $value) = @$entry;
1471         next if $key ne 'lxc.id_map';
1472         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
1473             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
1474             push @$id_map, [$type, $ct, $host, $length];
1475             if ($ct == 0) {
1476                 $rootuid = $host if $type eq 'u';
1477                 $rootgid = $host if $type eq 'g';
1478             }
1479         } else {
1480             die "failed to parse id_map: $value\n";
1481         }
1482     }
1483
1484     if (!@$id_map && $conf->{unprivileged}) {
1485         # Should we read them from /etc/subuid?
1486         $id_map = [ ['u', '0', '100000', '65536'],
1487                     ['g', '0', '100000', '65536'] ];
1488         $rootuid = $rootgid = 100000;
1489     }
1490
1491     return ($id_map, $rootuid, $rootgid);
1492 }
1493
1494 sub userns_command {
1495     my ($id_map) = @_;
1496     if (@$id_map) {
1497         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
1498     }
1499     return [];
1500 }
1501
1502
1503 1;