src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP EROFS);
  15
  16 use PVE::Exception qw(raise_perm_exc);
  17 use PVE::Storage;
  18 use PVE::SafeSyslog;
  19 use PVE::INotify;
  20 use PVE::Tools qw($IPV6RE $IPV4RE dir_glob_foreach lock_file lock_file_full O_PATH);
  21 use PVE::Network;
  22 use PVE::AccessControl;
  23 use PVE::ProcFSTools;
  24 use PVE::LXC::Config;
  25 use Time::HiRes qw (gettimeofday);
  26
  27 use Data::Dumper;
  28
  29 my $nodename = PVE::INotify::nodename();
  30
  31 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  32
  33 our $COMMON_TAR_FLAGS = [ '--sparse', '--numeric-owner', '--acls',
  34                           '--xattrs',
  35                           '--xattrs-include=user.*',
  36                           '--xattrs-include=security.capability',
  37                           '--warning=no-xattr-write' ];
  38
  39 sub config_list {
  40     my $vmlist = PVE::Cluster::get_vmlist();
  41     my $res = {};
  42     return $res if !$vmlist || !$vmlist->{ids};
  43     my $ids = $vmlist->{ids};
  44
  45     foreach my $vmid (keys %$ids) {
  46         next if !$vmid; # skip CT0
  47         my $d = $ids->{$vmid};
  48         next if !$d->{node} || $d->{node} ne $nodename;
  49         next if !$d->{type} || $d->{type} ne 'lxc';
  50         $res->{$vmid}->{type} = 'lxc';
  51     }
  52     return $res;
  53 }
  54
  55 sub destroy_config {
  56     my ($vmid) = @_;
  57
  58     unlink PVE::LXC::Config->config_file($vmid, $nodename);
  59 }
  60
  61 # container status helpers
  62
  63 sub list_active_containers {
  64
  65     my $filename = "/proc/net/unix";
  66
  67     # similar test is used by lcxcontainers.c: list_active_containers
  68     my $res = {};
  69
  70     my $fh = IO::File->new ($filename, "r");
  71     return $res if !$fh;
  72
  73     while (defined(my $line = <$fh>)) {
  74         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  75             my $path = $1;
  76             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  77                 $res->{$1} = 1;
  78             }
  79         }
  80     }
  81
  82     close($fh);
  83
  84     return $res;
  85 }
  86
  87 # warning: this is slow
  88 sub check_running {
  89     my ($vmid) = @_;
  90
  91     my $active_hash = list_active_containers();
  92
  93     return 1 if defined($active_hash->{$vmid});
  94
  95     return undef;
  96 }
  97
  98 sub get_container_disk_usage {
  99     my ($vmid, $pid) = @_;
 100
 101     return PVE::Tools::df("/proc/$pid/root/", 1);
 102 }
 103
 104 my $last_proc_vmid_stat;
 105
 106 my $parse_cpuacct_stat = sub {
 107     my ($vmid) = @_;
 108
 109     my $raw = read_cgroup_value('cpuacct', $vmid, 'cpuacct.stat', 1);
 110
 111     my $stat = {};
 112
 113     if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
 114
 115         $stat->{utime} = $1;
 116         $stat->{stime} = $2;
 117
 118     }
 119
 120     return $stat;
 121 };
 122
 123 sub vmstatus {
 124     my ($opt_vmid) = @_;
 125
 126     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc' }} : config_list();
 127
 128     my $active_hash = list_active_containers();
 129
 130     my $cpucount = $cpuinfo->{cpus} || 1;
 131
 132     my $cdtime = gettimeofday;
 133
 134     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 135
 136     foreach my $vmid (keys %$list) {
 137         my $d = $list->{$vmid};
 138
 139         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 140         warn $@ if $@; # ignore errors (consider them stopped)
 141
 142         $d->{status} = $d->{pid} ? 'running' : 'stopped';
 143
 144         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 145         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 146
 147         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 148         $d->{name} =~ s/[\s]//g;
 149
 150         $d->{cpus} = $conf->{cpulimit} || $cpucount;
 151
 152         $d->{lock} = $conf->{lock} || '';
 153
 154         if ($d->{pid}) {
 155             my $res = get_container_disk_usage($vmid, $d->{pid});
 156             $d->{disk} = $res->{used};
 157             $d->{maxdisk} = $res->{total};
 158         } else {
 159             $d->{disk} = 0;
 160             # use 4GB by default ??
 161             if (my $rootfs = $conf->{rootfs}) {
 162                 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
 163                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 164             } else {
 165                 $d->{maxdisk} = 4*1024*1024*1024;
 166             }
 167         }
 168
 169         $d->{mem} = 0;
 170         $d->{swap} = 0;
 171         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 172         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 173
 174         $d->{uptime} = 0;
 175         $d->{cpu} = 0;
 176
 177         $d->{netout} = 0;
 178         $d->{netin} = 0;
 179
 180         $d->{diskread} = 0;
 181         $d->{diskwrite} = 0;
 182
 183         $d->{template} = PVE::LXC::Config->is_template($conf);
 184     }
 185
 186     foreach my $vmid (keys %$list) {
 187         my $d = $list->{$vmid};
 188         my $pid = $d->{pid};
 189
 190         next if !$pid; # skip stopped CTs
 191
 192         my $ctime = (stat("/proc/$pid"))[10]; # 10 = ctime
 193         $d->{uptime} = time - $ctime; # the method lxcfs uses
 194
 195         $d->{mem} = read_cgroup_value('memory', $vmid, 'memory.usage_in_bytes');
 196         $d->{swap} = read_cgroup_value('memory', $vmid, 'memory.memsw.usage_in_bytes') - $d->{mem};
 197
 198         my $blkio_bytes = read_cgroup_value('blkio', $vmid, 'blkio.throttle.io_service_bytes', 1);
 199         my @bytes = split(/\n/, $blkio_bytes);
 200         foreach my $byte (@bytes) {
 201             if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 202                 $d->{diskread} = $2 if $key eq 'Read';
 203                 $d->{diskwrite} = $2 if $key eq 'Write';
 204             }
 205         }
 206
 207         my $pstat = &$parse_cpuacct_stat($vmid);
 208
 209         my $used = $pstat->{utime} + $pstat->{stime};
 210
 211         my $old = $last_proc_vmid_stat->{$vmid};
 212         if (!$old) {
 213             $last_proc_vmid_stat->{$vmid} = {
 214                 time => $cdtime,
 215                 used => $used,
 216                 cpu => 0,
 217             };
 218             next;
 219         }
 220
 221         my $dtime = ($cdtime -  $old->{time}) * $cpucount * $cpuinfo->{user_hz};
 222
 223         if ($dtime > 1000) {
 224             my $dutime = $used -  $old->{used};
 225
 226             $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
 227             $last_proc_vmid_stat->{$vmid} = {
 228                 time => $cdtime,
 229                 used => $used,
 230                 cpu => $d->{cpu},
 231             };
 232         } else {
 233             $d->{cpu} = $old->{cpu};
 234         }
 235     }
 236
 237     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 238
 239     foreach my $dev (keys %$netdev) {
 240         next if $dev !~ m/^veth([1-9]\d*)i/;
 241         my $vmid = $1;
 242         my $d = $list->{$vmid};
 243
 244         next if !$d;
 245
 246         $d->{netout} += $netdev->{$dev}->{receive};
 247         $d->{netin} += $netdev->{$dev}->{transmit};
 248
 249     }
 250
 251     return $list;
 252 }
 253
 254 sub read_cgroup_value {
 255     my ($group, $vmid, $name, $full) = @_;
 256
 257     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 258
 259     return PVE::Tools::file_get_contents($path) if $full;
 260
 261     return PVE::Tools::file_read_firstline($path);
 262 }
 263
 264 sub write_cgroup_value {
 265    my ($group, $vmid, $name, $value) = @_;
 266
 267    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 268    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 269
 270 }
 271
 272 sub find_lxc_console_pids {
 273
 274     my $res = {};
 275
 276     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 277         my ($pid) = @_;
 278
 279         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 280         return if !$cmdline;
 281
 282         my @args = split(/\0/, $cmdline);
 283
 284         # search for lxc-console -n <vmid>
 285         return if scalar(@args) != 3;
 286         return if $args[1] ne '-n';
 287         return if $args[2] !~ m/^\d+$/;
 288         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 289
 290         my $vmid = $args[2];
 291
 292         push @{$res->{$vmid}}, $pid;
 293     });
 294
 295     return $res;
 296 }
 297
 298 sub find_lxc_pid {
 299     my ($vmid) = @_;
 300
 301     my $pid = undef;
 302     my $parser = sub {
 303         my $line = shift;
 304         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 305     };
 306     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 307
 308     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 309
 310     return $pid;
 311 }
 312
 313 # Note: we cannot use Net:IP, because that only allows strict
 314 # CIDR networks
 315 sub parse_ipv4_cidr {
 316     my ($cidr, $noerr) = @_;
 317
 318     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 319         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 320     }
 321
 322     return undef if $noerr;
 323
 324     die "unable to parse ipv4 address/mask\n";
 325 }
 326
 327
 328 sub update_lxc_config {
 329     my ($storage_cfg, $vmid, $conf) = @_;
 330
 331     my $dir = "/var/lib/lxc/$vmid";
 332
 333     if ($conf->{template}) {
 334
 335         unlink "$dir/config";
 336
 337         return;
 338     }
 339
 340     my $raw = '';
 341
 342     die "missing 'arch' - internal error" if !$conf->{arch};
 343     $raw .= "lxc.arch = $conf->{arch}\n";
 344
 345     my $unprivileged = $conf->{unprivileged};
 346     my $custom_idmap = grep { $_->[0] eq 'lxc.id_map' } @{$conf->{lxc}};
 347
 348     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 349     if ($ostype =~ /^(?:debian | ubuntu | centos | fedora | opensuse | archlinux | alpine | gentoo | unmanaged)$/x) {
 350         my $inc ="/usr/share/lxc/config/$ostype.common.conf";
 351         $inc ="/usr/share/lxc/config/common.conf" if !-f $inc;
 352         $raw .= "lxc.include = $inc\n";
 353         if ($unprivileged || $custom_idmap) {
 354             $inc = "/usr/share/lxc/config/$ostype.userns.conf";
 355             $inc = "/usr/share/lxc/config/userns.conf" if !-f $inc;
 356             $raw .= "lxc.include = $inc\n"
 357         }
 358     } else {
 359         die "implement me (ostype $ostype)";
 360     }
 361
 362     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 363     # cannot be exposed to the container with r/w access (cgroup perms).
 364     # When this is enabled mounts will still remain in the monitor's namespace
 365     # after the container unmounted them and thus will not detach from their
 366     # files while the container is running!
 367     $raw .= "lxc.monitor.unshare = 1\n";
 368
 369     # Should we read them from /etc/subuid?
 370     if ($unprivileged && !$custom_idmap) {
 371         $raw .= "lxc.id_map = u 0 100000 65536\n";
 372         $raw .= "lxc.id_map = g 0 100000 65536\n";
 373     }
 374
 375     if (!PVE::LXC::Config->has_dev_console($conf)) {
 376         $raw .= "lxc.console = none\n";
 377         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 378     }
 379
 380     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 381     $raw .= "lxc.tty = $ttycount\n";
 382
 383     # some init scripts expect a linux terminal (turnkey).
 384     $raw .= "lxc.environment = TERM=linux\n";
 385
 386     my $utsname = $conf->{hostname} || "CT$vmid";
 387     $raw .= "lxc.utsname = $utsname\n";
 388
 389     my $memory = $conf->{memory} || 512;
 390     my $swap = $conf->{swap} // 0;
 391
 392     my $lxcmem = int($memory*1024*1024);
 393     $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 394
 395     my $lxcswap = int(($memory + $swap)*1024*1024);
 396     $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 397
 398     if (my $cpulimit = $conf->{cpulimit}) {
 399         $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 400         my $value = int(100000*$cpulimit);
 401         $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 402     }
 403
 404     my $shares = $conf->{cpuunits} || 1024;
 405     $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 406
 407     die "missing 'rootfs' configuration\n"
 408         if !defined($conf->{rootfs});
 409
 410     my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 411
 412     $raw .= "lxc.rootfs = $dir/rootfs\n";
 413
 414     my $netcount = 0;
 415     foreach my $k (keys %$conf) {
 416         next if $k !~ m/^net(\d+)$/;
 417         my $ind = $1;
 418         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 419         $netcount++;
 420         $raw .= "lxc.network.type = veth\n";
 421         $raw .= "lxc.network.veth.pair = veth${vmid}i${ind}\n";
 422         $raw .= "lxc.network.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 423         $raw .= "lxc.network.name = $d->{name}\n" if defined($d->{name});
 424         $raw .= "lxc.network.mtu = $d->{mtu}\n" if defined($d->{mtu});
 425     }
 426
 427     if (my $lxcconf = $conf->{lxc}) {
 428         foreach my $entry (@$lxcconf) {
 429             my ($k, $v) = @$entry;
 430             $netcount++ if $k eq 'lxc.network.type';
 431             $raw .= "$k = $v\n";
 432         }
 433     }
 434
 435     $raw .= "lxc.network.type = empty\n" if !$netcount;
 436
 437     File::Path::mkpath("$dir/rootfs");
 438
 439     PVE::Tools::file_set_contents("$dir/config", $raw);
 440 }
 441
 442 # verify and cleanup nameserver list (replace \0 with ' ')
 443 sub verify_nameserver_list {
 444     my ($nameserver_list) = @_;
 445
 446     my @list = ();
 447     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 448         PVE::JSONSchema::pve_verify_ip($server);
 449         push @list, $server;
 450     }
 451
 452     return join(' ', @list);
 453 }
 454
 455 sub verify_searchdomain_list {
 456     my ($searchdomain_list) = @_;
 457
 458     my @list = ();
 459     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 460         # todo: should we add checks for valid dns domains?
 461         push @list, $server;
 462     }
 463
 464     return join(' ', @list);
 465 }
 466
 467 sub get_console_command {
 468     my ($vmid, $conf) = @_;
 469
 470     my $cmode = PVE::LXC::Config->get_cmode($conf);
 471
 472     if ($cmode eq 'console') {
 473         return ['lxc-console', '-n',  $vmid, '-t', 0];
 474     } elsif ($cmode eq 'tty') {
 475         return ['lxc-console', '-n',  $vmid];
 476     } elsif ($cmode eq 'shell') {
 477         return ['lxc-attach', '--clear-env', '-n', $vmid];
 478     } else {
 479         die "internal error";
 480     }
 481 }
 482
 483 sub get_primary_ips {
 484     my ($conf) = @_;
 485
 486     # return data from net0
 487
 488     return undef if !defined($conf->{net0});
 489     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 490
 491     my $ipv4 = $net->{ip};
 492     if ($ipv4) {
 493         if ($ipv4 =~ /^(dhcp|manual)$/) {
 494             $ipv4 = undef
 495         } else {
 496             $ipv4 =~ s!/\d+$!!;
 497         }
 498     }
 499     my $ipv6 = $net->{ip6};
 500     if ($ipv6) {
 501         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 502             $ipv6 = undef;
 503         } else {
 504             $ipv6 =~ s!/\d+$!!;
 505         }
 506     }
 507
 508     return ($ipv4, $ipv6);
 509 }
 510
 511 sub delete_mountpoint_volume {
 512     my ($storage_cfg, $vmid, $volume) = @_;
 513
 514     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 515
 516     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 517     PVE::Storage::vdisk_free($storage_cfg, $volume) if $vmid == $owner;
 518 }
 519
 520 sub destroy_lxc_container {
 521     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 522
 523     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 524         my ($ms, $mountpoint) = @_;
 525         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 526     });
 527
 528     rmdir "/var/lib/lxc/$vmid/rootfs";
 529     unlink "/var/lib/lxc/$vmid/config";
 530     rmdir "/var/lib/lxc/$vmid";
 531     if (defined $replacement_conf) {
 532         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 533     } else {
 534         destroy_config($vmid);
 535     }
 536
 537     #my $cmd = ['lxc-destroy', '-n', $vmid ];
 538     #PVE::Tools::run_command($cmd);
 539 }
 540
 541 sub vm_stop_cleanup {
 542     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 543
 544     eval {
 545         if (!$keepActive) {
 546
 547             my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 548             PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 549         }
 550     };
 551     warn $@ if $@; # avoid errors - just warn
 552 }
 553
 554 my $safe_num_ne = sub {
 555     my ($a, $b) = @_;
 556
 557     return 0 if !defined($a) && !defined($b);
 558     return 1 if !defined($a);
 559     return 1 if !defined($b);
 560
 561     return $a != $b;
 562 };
 563
 564 my $safe_string_ne = sub {
 565     my ($a, $b) = @_;
 566
 567     return 0 if !defined($a) && !defined($b);
 568     return 1 if !defined($a);
 569     return 1 if !defined($b);
 570
 571     return $a ne $b;
 572 };
 573
 574 sub update_net {
 575     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 576
 577     if ($newnet->{type} ne 'veth') {
 578         # for when there are physical interfaces
 579         die "cannot update interface of type $newnet->{type}";
 580     }
 581
 582     my $veth = "veth${vmid}i${netid}";
 583     my $eth = $newnet->{name};
 584
 585     if (my $oldnetcfg = $conf->{$opt}) {
 586         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 587
 588         if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 589             &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
 590
 591             PVE::Network::veth_delete($veth);
 592             delete $conf->{$opt};
 593             PVE::LXC::Config->write_config($vmid, $conf);
 594
 595             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 596
 597         } else {
 598             if (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 599                 &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 600                 &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 601
 602                 if ($oldnet->{bridge}) {
 603                     PVE::Network::tap_unplug($veth);
 604                     foreach (qw(bridge tag firewall)) {
 605                         delete $oldnet->{$_};
 606                     }
 607                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 608                     PVE::LXC::Config->write_config($vmid, $conf);
 609                 }
 610
 611                 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 612                 # This includes the rate:
 613                 foreach (qw(bridge tag firewall rate)) {
 614                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 615                 }
 616             } elsif (&$safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 617                 # Rate can be applied on its own but any change above needs to
 618                 # include the rate in tap_plug since OVS resets everything.
 619                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 620                 $oldnet->{rate} = $newnet->{rate}
 621             }
 622             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 623             PVE::LXC::Config->write_config($vmid, $conf);
 624         }
 625     } else {
 626         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 627     }
 628
 629     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 630 }
 631
 632 sub hotplug_net {
 633     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 634
 635     my $veth = "veth${vmid}i${netid}";
 636     my $vethpeer = $veth . "p";
 637     my $eth = $newnet->{name};
 638
 639     PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 640     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 641
 642     # attach peer in container
 643     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 644     PVE::Tools::run_command($cmd);
 645
 646     # link up peer in container
 647     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 648     PVE::Tools::run_command($cmd);
 649
 650     my $done = { type => 'veth' };
 651     foreach (qw(bridge tag firewall hwaddr name)) {
 652         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 653     }
 654     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 655
 656     PVE::LXC::Config->write_config($vmid, $conf);
 657 }
 658
 659 sub update_ipconfig {
 660     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 661
 662     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 663
 664     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 665     my $deleted = [];
 666     my $added = [];
 667     my $nscmd = sub {
 668         my $cmdargs = shift;
 669         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 670     };
 671     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 672
 673     my $change_ip_config = sub {
 674         my ($ipversion) = @_;
 675
 676         my $family_opt = "-$ipversion";
 677         my $suffix = $ipversion == 4 ? '' : $ipversion;
 678         my $gw= "gw$suffix";
 679         my $ip= "ip$suffix";
 680
 681         my $newip = $newnet->{$ip};
 682         my $newgw = $newnet->{$gw};
 683         my $oldip = $optdata->{$ip};
 684
 685         my $change_ip = &$safe_string_ne($oldip, $newip);
 686         my $change_gw = &$safe_string_ne($optdata->{$gw}, $newgw);
 687
 688         return if !$change_ip && !$change_gw;
 689
 690         # step 1: add new IP, if this fails we cancel
 691         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 692         if ($change_ip && $is_real_ip) {
 693             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 694             if (my $err = $@) {
 695                 warn $err;
 696                 return;
 697             }
 698         }
 699
 700         # step 2: replace gateway
 701         #   If this fails we delete the added IP and cancel.
 702         #   If it succeeds we save the config and delete the old IP, ignoring
 703         #   errors. The config is then saved.
 704         # Note: 'ip route replace' can add
 705         if ($change_gw) {
 706             if ($newgw) {
 707                 eval {
 708                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
 709                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
 710                     }
 711                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
 712                 };
 713                 if (my $err = $@) {
 714                     warn $err;
 715                     # the route was not replaced, the old IP is still available
 716                     # rollback (delete new IP) and cancel
 717                     if ($change_ip) {
 718                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
 719                         warn $@ if $@; # no need to die here
 720                     }
 721                     return;
 722                 }
 723             } else {
 724                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
 725                 # if the route was not deleted, the guest might have deleted it manually
 726                 # warn and continue
 727                 warn $@ if $@;
 728             }
 729         }
 730
 731         # from this point on we save the configuration
 732         # step 3: delete old IP ignoring errors
 733         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
 734             # We need to enable promote_secondaries, otherwise our newly added
 735             # address will be removed along with the old one.
 736             my $promote = 0;
 737             eval {
 738                 if ($ipversion == 4) {
 739                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
 740                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
 741                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
 742                 }
 743                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
 744             };
 745             warn $@ if $@; # no need to die here
 746
 747             if ($ipversion == 4) {
 748                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
 749             }
 750         }
 751
 752         foreach my $property ($ip, $gw) {
 753             if ($newnet->{$property}) {
 754                 $optdata->{$property} = $newnet->{$property};
 755             } else {
 756                 delete $optdata->{$property};
 757             }
 758         }
 759         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
 760         PVE::LXC::Config->write_config($vmid, $conf);
 761         $lxc_setup->setup_network($conf);
 762     };
 763
 764     &$change_ip_config(4);
 765     &$change_ip_config(6);
 766
 767 }
 768
 769 my $enter_namespace = sub {
 770     my ($vmid, $pid, $which, $type) = @_;
 771     sysopen my $fd, "/proc/$pid/ns/$which", O_RDONLY
 772         or die "failed to open $which namespace of container $vmid: $!\n";
 773     PVE::Tools::setns(fileno($fd), $type)
 774         or die "failed to enter $which namespace of container $vmid: $!\n";
 775     close $fd;
 776 };
 777
 778 my $do_syncfs = sub {
 779     my ($vmid, $pid, $socket) = @_;
 780
 781     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
 782
 783     # Tell the parent process to start reading our /proc/mounts
 784     print {$socket} "go\n";
 785     $socket->flush();
 786
 787     # Receive /proc/self/mounts
 788     my $mountdata = do { local $/ = undef; <$socket> };
 789     close $socket;
 790
 791     # Now sync all mountpoints...
 792     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
 793     foreach my $mp (@$mounts) {
 794         my ($what, $dir, $fs) = @$mp;
 795         next if $fs eq 'fuse.lxcfs';
 796         eval { PVE::Tools::sync_mountpoint($dir); };
 797         warn $@ if $@;
 798     }
 799 };
 800
 801 sub sync_container_namespace {
 802     my ($vmid) = @_;
 803     my $pid = find_lxc_pid($vmid);
 804
 805     # SOCK_DGRAM is nicer for barriers but cannot be slurped
 806     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
 807         or die "failed to create socketpair: $!\n";
 808
 809     my $child = fork();
 810     die "fork failed: $!\n" if !defined($child);
 811
 812     if (!$child) {
 813         eval {
 814             close $pfd;
 815             &$do_syncfs($vmid, $pid, $cfd);
 816         };
 817         if (my $err = $@) {
 818             warn $err;
 819             POSIX::_exit(1);
 820         }
 821         POSIX::_exit(0);
 822     }
 823     close $cfd;
 824     my $go = <$pfd>;
 825     die "failed to enter container namespace\n" if $go ne "go\n";
 826
 827     open my $mounts, '<', "/proc/$child/mounts"
 828         or die "failed to open container's /proc/mounts: $!\n";
 829     my $mountdata = do { local $/ = undef; <$mounts> };
 830     close $mounts;
 831     print {$pfd} $mountdata;
 832     close $pfd;
 833
 834     while (waitpid($child, 0) != $child) {}
 835     die "failed to sync container namespace\n" if $? != 0;
 836 }
 837
 838 sub template_create {
 839     my ($vmid, $conf) = @_;
 840
 841     my $storecfg = PVE::Storage::config();
 842
 843     my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 844     my $volid = $rootinfo->{volume};
 845
 846     die "Template feature is not available for '$volid'\n"
 847         if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
 848
 849     PVE::Storage::activate_volumes($storecfg, [$volid]);
 850
 851     my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
 852     $rootinfo->{volume} = $template_volid;
 853     $conf->{rootfs} = PVE::LXC::Config->print_ct_mountpoint($rootinfo, 1);
 854
 855     PVE::LXC::Config->write_config($vmid, $conf);
 856 }
 857
 858 sub check_ct_modify_config_perm {
 859     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
 860
 861     return 1 if $authuser eq 'root@pam';
 862
 863     my $check = sub {
 864         my ($opt, $delete) = @_;
 865         if ($opt eq 'cpus' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
 866             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 867         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
 868             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 869             return if $delete;
 870             my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
 871                                         : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
 872             raise_perm_exc("mountpoint type $data->{type}") if $data->{type} ne 'volume';
 873         } elsif ($opt eq 'memory' || $opt eq 'swap') {
 874             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 875         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
 876                  $opt eq 'searchdomain' || $opt eq 'hostname') {
 877             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 878         } else {
 879             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 880         }
 881     };
 882
 883     foreach my $opt (keys %$newconf) {
 884         &$check($opt, 0);
 885     }
 886     foreach my $opt (@$delete) {
 887         &$check($opt, 1);
 888     }
 889
 890     return 1;
 891 }
 892
 893 sub umount_all {
 894     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
 895
 896     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
 897     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
 898
 899     PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
 900         my ($ms, $mountpoint) = @_;
 901
 902         my $volid = $mountpoint->{volume};
 903         my $mount = $mountpoint->{mp};
 904
 905         return if !$volid || !$mount;
 906
 907         my $mount_path = "$rootdir/$mount";
 908         $mount_path =~ s!/+!/!g;
 909
 910         return if !PVE::ProcFSTools::is_mounted($mount_path);
 911
 912         eval {
 913             PVE::Tools::run_command(['umount', '-d', $mount_path]);
 914         };
 915         if (my $err = $@) {
 916             if ($noerr) {
 917                 warn $err;
 918             } else {
 919                 die $err;
 920             }
 921         }
 922     });
 923 }
 924
 925 sub mount_all {
 926     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
 927
 928     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
 929     File::Path::make_path($rootdir);
 930
 931     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
 932     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
 933
 934     eval {
 935         PVE::LXC::Config->foreach_mountpoint($conf, sub {
 936             my ($ms, $mountpoint) = @_;
 937
 938             $mountpoint->{ro} = 0 if $ignore_ro;
 939
 940             mountpoint_mount($mountpoint, $rootdir, $storage_cfg);
 941         });
 942     };
 943     if (my $err = $@) {
 944         warn "mounting container failed\n";
 945         umount_all($vmid, $storage_cfg, $conf, 1);
 946         die $err;
 947     }
 948
 949     return $rootdir;
 950 }
 951
 952
 953 sub mountpoint_mount_path {
 954     my ($mountpoint, $storage_cfg, $snapname) = @_;
 955
 956     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
 957 }
 958
 959 sub query_loopdev {
 960     my ($path) = @_;
 961     my $found;
 962     my $parser = sub {
 963         my $line = shift;
 964         if ($line =~ m@^(/dev/loop\d+):@) {
 965             $found = $1;
 966         }
 967     };
 968     my $cmd = ['losetup', '--associated', $path];
 969     PVE::Tools::run_command($cmd, outfunc => $parser);
 970     return $found;
 971 }
 972
 973 # Run a function with a file attached to a loop device.
 974 # The loop device is always detached afterwards (or set to autoclear).
 975 # Returns the loop device.
 976 sub run_with_loopdev {
 977     my ($func, $file) = @_;
 978     my $device = query_loopdev($file);
 979     # Try to reuse an existing device
 980     if ($device) {
 981         # We assume that whoever setup the loop device is responsible for
 982         # detaching it.
 983         &$func($device);
 984         return $device;
 985     }
 986
 987     my $parser = sub {
 988         my $line = shift;
 989         if ($line =~ m@^(/dev/loop\d+)$@) {
 990             $device = $1;
 991         }
 992     };
 993     PVE::Tools::run_command(['losetup', '--show', '-f', $file], outfunc => $parser);
 994     die "failed to setup loop device for $file\n" if !$device;
 995     eval { &$func($device); };
 996     my $err = $@;
 997     PVE::Tools::run_command(['losetup', '-d', $device]);
 998     die $err if $err;
 999     return $device;
1000 }
1001
1002 # In scalar mode: returns a file handle to the deepest directory node.
1003 # In list context: returns a list of:
1004 #   * the deepest directory node
1005 #   * the 2nd deepest directory (parent of the above)
1006 #   * directory name of the last directory
1007 # So that the path $2/$3 should lead to $1 afterwards.
1008 sub walk_tree_nofollow($$$) {
1009     my ($start, $subdir, $mkdir) = @_;
1010
1011     # splitdir() returns '' for empty components including the leading /
1012     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1013
1014     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1015         or die "failed to open start directory $start: $!\n";
1016
1017     my $dir = $start;
1018     my $last_component = undef;
1019     my $second = $fd;
1020     foreach my $component (@comps) {
1021         $dir .= "/$component";
1022         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1023
1024         if (!$next) {
1025             # failed, check for symlinks and try to create the path
1026             die "symlink encountered at: $dir\n" if $! == ELOOP;
1027             die "cannot open directory $dir: $!\n" if !$mkdir;
1028
1029             # We don't check for errors on mkdirat() here and just try to
1030             # openat() again, since at least one error (EEXIST) is an
1031             # expected possibility if multiple containers start
1032             # simultaneously. If someone else injects a symlink now then
1033             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1034             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1035
1036             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1037             die "failed to create path: $dir: $!\n" if !$next;
1038         }
1039
1040         close $second if defined($last_component);
1041         $last_component = $component;
1042         $second = $fd;
1043         $fd = $next;
1044     }
1045
1046     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1047     close $second if defined($last_component);
1048     return $fd;
1049 }
1050
1051 # To guard against symlink attack races against other currently running
1052 # containers with shared recursive bind mount hierarchies we prepare a
1053 # directory handle for the directory we're mounting over to verify the
1054 # mountpoint afterwards.
1055 sub __bindmount_prepare {
1056     my ($hostroot, $dir) = @_;
1057     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1058     return $srcdh;
1059 }
1060
1061 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1062 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1063 # we intended to bind mount.
1064 sub __bindmount_verify {
1065     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1066     my $destdh;
1067     if ($parentfd) {
1068         # Open the mount point path coming from the parent directory since the
1069         # filehandle we would have gotten as first result of walk_tree_nofollow
1070         # earlier is still a handle to the underlying directory instead of the
1071         # mounted path.
1072         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1073         die "failed to open mount point: $!\n" if !$destdh;
1074         if ($ro) {
1075             my $dot = '.';
1076             # 269: faccessat()
1077             # no separate function because 99% of the time it's the wrong thing to use.
1078             if (syscall(269, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1079                 die "failed to mark bind mount read only\n";
1080             }
1081             die "read-only check failed: $!\n" if $! != EROFS;
1082         }
1083     } else {
1084         # For the rootfs we don't have a parentfd so we open the path directly.
1085         # Note that this means bindmounting any prefix of the host's
1086         # /var/lib/lxc/$vmid path into another container is considered a grave
1087         # security error.
1088         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1089         die "failed to open mount point: $!\n" if !$destdh;
1090     }
1091
1092     my ($srcdev, $srcinode) = stat($srcdh);
1093     my ($dstdev, $dstinode) = stat($destdh);
1094     close $srcdh;
1095     close $destdh;
1096
1097     return ($srcdev == $dstdev && $srcinode == $dstinode);
1098 }
1099
1100 # Perform the actual bind mounting:
1101 sub __bindmount_do {
1102     my ($dir, $dest, $ro, @extra_opts) = @_;
1103     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1104     if ($ro) {
1105         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1106         if (my $err = $@) {
1107             warn "bindmount error\n";
1108             # don't leave writable bind-mounts behind...
1109             PVE::Tools::run_command(['umount', $dest]);
1110             die $err;
1111         }
1112     }
1113 }
1114
1115 sub bindmount {
1116     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1117
1118     my $srcdh = __bindmount_prepare('/', $dir);
1119
1120     __bindmount_do($dir, $dest, $ro, @extra_opts);
1121
1122     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1123         PVE::Tools::run_command(['umount', $dest]);
1124         die "detected mount path change at: $dir\n";
1125     }
1126 }
1127
1128 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1129 # from $rootdir and $mount and walk the path from $rootdir to the final
1130 # directory to check for symlinks.
1131 sub __mount_prepare_rootdir {
1132     my ($rootdir, $mount) = @_;
1133     $rootdir =~ s!/+!/!g;
1134     $rootdir =~ s!/+$!!;
1135     my $mount_path = "$rootdir/$mount";
1136     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1);
1137     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1138 }
1139
1140 # use $rootdir = undef to just return the corresponding mount path
1141 sub mountpoint_mount {
1142     my ($mountpoint, $rootdir, $storage_cfg, $snapname) = @_;
1143
1144     my $volid = $mountpoint->{volume};
1145     my $mount = $mountpoint->{mp};
1146     my $type = $mountpoint->{type};
1147     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1148     my $mounted_dev;
1149
1150     return if !$volid || !$mount;
1151
1152     $mount =~ s!/+!/!g;
1153
1154     my $mount_path;
1155     my ($mpfd, $parentfd, $last_dir);
1156
1157     if (defined($rootdir)) {
1158         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1159             __mount_prepare_rootdir($rootdir, $mount);
1160     }
1161
1162     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1163
1164     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1165
1166     my $optstring = '';
1167     my $acl = $mountpoint->{acl};
1168     if (defined($acl)) {
1169         $optstring .= ($acl ? 'acl' : 'noacl');
1170     }
1171     my $readonly = $mountpoint->{ro};
1172
1173     my @extra_opts = ('-o', $optstring) if $optstring;
1174
1175     if ($storage) {
1176
1177         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1178
1179         # early sanity checks:
1180         # we otherwise call realpath on the rbd url
1181         die "containers on rbd storage without krbd are not supported\n"
1182             if $scfg->{type} eq 'rbd' && !$scfg->{krbd};
1183
1184         my $path = PVE::Storage::path($storage_cfg, $volid, $snapname);
1185
1186         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1187             PVE::Storage::parse_volname($storage_cfg, $volid);
1188
1189         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1190
1191         if ($format eq 'subvol') {
1192             if ($mount_path) {
1193                 if ($snapname) {
1194                     if ($scfg->{type} eq 'zfspool') {
1195                         my $path_arg = $path;
1196                         $path_arg =~ s!^/+!!;
1197                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', $path_arg, $mount_path]);
1198                     } else {
1199                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1200                     }
1201                 } else {
1202                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1203                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1204                         my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1205                         $name .= "\@$snapname" if defined($snapname);
1206                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1207                     }
1208                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1209                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1210                 }
1211             }
1212             return wantarray ? ($path, 0, undef) : $path;
1213         } elsif ($format eq 'raw' || $format eq 'iso') {
1214             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1215             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1216             # Our autodev hook expects the /dev/dm-* device currently
1217             # and will create the /dev/mapper symlink accordingly
1218             $path = Cwd::realpath($path);
1219             die "failed to get device path\n" if !$path;
1220             ($path) = ($path =~ /^(.*)$/s); #untaint
1221             my $domount = sub {
1222                 my ($path) = @_;
1223                 if ($mount_path) {
1224                     if ($format eq 'iso') {
1225                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1226                     } elsif ($isBase || defined($snapname)) {
1227                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1228                     } else {
1229                         if ($quota) {
1230                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1231                         }
1232                         push @extra_opts, '-o', 'ro' if $readonly;
1233                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1234                     }
1235                 }
1236             };
1237             my $use_loopdev = 0;
1238             if ($scfg->{path}) {
1239                 $mounted_dev = run_with_loopdev($domount, $path);
1240                 $use_loopdev = 1;
1241             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1242                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1243                 $mounted_dev = $path;
1244                 &$domount($path);
1245             } else {
1246                 die "unsupported storage type '$scfg->{type}'\n";
1247             }
1248             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1249         } else {
1250             die "unsupported image format '$format'\n";
1251         }
1252     } elsif ($type eq 'device') {
1253         push @extra_opts, '-o', 'ro' if $readonly;
1254         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1255         # See the NOTE above about devicemapper canonicalization
1256         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1257         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1258         return wantarray ? ($volid, 0, $devpath) : $volid;
1259     } elsif ($type eq 'bind') {
1260         die "directory '$volid' does not exist\n" if ! -d $volid;
1261         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1262         warn "cannot enable quota control for bind mounts\n" if $quota;
1263         return wantarray ? ($volid, 0, undef) : $volid;
1264     }
1265
1266     die "unsupported storage";
1267 }
1268
1269 sub mkfs {
1270     my ($dev, $rootuid, $rootgid) = @_;
1271
1272     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1273                              '-E', "root_owner=$rootuid:$rootgid",
1274                              $dev]);
1275 }
1276
1277 sub format_disk {
1278     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1279
1280     if ($volid =~ m!^/dev/.+!) {
1281         mkfs($volid);
1282         return;
1283     }
1284
1285     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1286
1287     die "cannot format volume '$volid' with no storage\n" if !$storage;
1288
1289     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1290
1291     my $path = PVE::Storage::path($storage_cfg, $volid);
1292
1293     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1294         PVE::Storage::parse_volname($storage_cfg, $volid);
1295
1296     die "cannot format volume '$volid' (format == $format)\n"
1297         if $format ne 'raw';
1298
1299     mkfs($path, $rootuid, $rootgid);
1300 }
1301
1302 sub destroy_disks {
1303     my ($storecfg, $vollist) = @_;
1304
1305     foreach my $volid (@$vollist) {
1306         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1307         warn $@ if $@;
1308     }
1309 }
1310
1311 sub create_disks {
1312     my ($storecfg, $vmid, $settings, $conf) = @_;
1313
1314     my $vollist = [];
1315
1316     eval {
1317         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1318         my $chown_vollist = [];
1319
1320         PVE::LXC::Config->foreach_mountpoint($settings, sub {
1321             my ($ms, $mountpoint) = @_;
1322
1323             my $volid = $mountpoint->{volume};
1324             my $mp = $mountpoint->{mp};
1325
1326             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1327
1328             if ($storage && ($volid =~ m/^([^:\s]+):(\d+(\.\d+)?)$/)) {
1329                 my ($storeid, $size_gb) = ($1, $2);
1330
1331                 my $size_kb = int(${size_gb}*1024) * 1024;
1332
1333                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1334                 # fixme: use better naming ct-$vmid-disk-X.raw?
1335
1336                 if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs') {
1337                     if ($size_kb > 0) {
1338                         $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1339                                                            undef, $size_kb);
1340                         format_disk($storecfg, $volid, $rootuid, $rootgid);
1341                     } else {
1342                         $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1343                                                            undef, 0);
1344                         push @$chown_vollist, $volid;
1345                     }
1346                 } elsif ($scfg->{type} eq 'zfspool') {
1347
1348                     $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1349                                                        undef, $size_kb);
1350                     push @$chown_vollist, $volid;
1351                 } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1352
1353                     $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1354                     format_disk($storecfg, $volid, $rootuid, $rootgid);
1355
1356                 } elsif ($scfg->{type} eq 'rbd') {
1357
1358                     die "krbd option must be enabled on storage type '$scfg->{type}'\n" if !$scfg->{krbd};
1359                     $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1360                     format_disk($storecfg, $volid, $rootuid, $rootgid);
1361                 } else {
1362                     die "unable to create containers on storage type '$scfg->{type}'\n";
1363                 }
1364                 push @$vollist, $volid;
1365                 $mountpoint->{volume} = $volid;
1366                 $mountpoint->{size} = $size_kb * 1024;
1367                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1368             } else {
1369                 # use specified/existing volid/dir/device
1370                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1371             }
1372         });
1373
1374         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1375         foreach my $volid (@$chown_vollist) {
1376             my $path = PVE::Storage::path($storecfg, $volid, undef);
1377             chown($rootuid, $rootgid, $path);
1378         }
1379         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1380     };
1381     # free allocated images on error
1382     if (my $err = $@) {
1383         destroy_disks($storecfg, $vollist);
1384         die $err;
1385     }
1386     return $vollist;
1387 }
1388
1389 # bash completion helper
1390
1391 sub complete_os_templates {
1392     my ($cmdname, $pname, $cvalue) = @_;
1393
1394     my $cfg = PVE::Storage::config();
1395
1396     my $storeid;
1397
1398     if ($cvalue =~ m/^([^:]+):/) {
1399         $storeid = $1;
1400     }
1401
1402     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
1403     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
1404
1405     my $res = [];
1406     foreach my $id (keys %$data) {
1407         foreach my $item (@{$data->{$id}}) {
1408             push @$res, $item->{volid} if defined($item->{volid});
1409         }
1410     }
1411
1412     return $res;
1413 }
1414
1415 my $complete_ctid_full = sub {
1416     my ($running) = @_;
1417
1418     my $idlist = vmstatus();
1419
1420     my $active_hash = list_active_containers();
1421
1422     my $res = [];
1423
1424     foreach my $id (keys %$idlist) {
1425         my $d = $idlist->{$id};
1426         if (defined($running)) {
1427             next if $d->{template};
1428             next if $running && !$active_hash->{$id};
1429             next if !$running && $active_hash->{$id};
1430         }
1431         push @$res, $id;
1432
1433     }
1434     return $res;
1435 };
1436
1437 sub complete_ctid {
1438     return &$complete_ctid_full();
1439 }
1440
1441 sub complete_ctid_stopped {
1442     return &$complete_ctid_full(0);
1443 }
1444
1445 sub complete_ctid_running {
1446     return &$complete_ctid_full(1);
1447 }
1448
1449 sub parse_id_maps {
1450     my ($conf) = @_;
1451
1452     my $id_map = [];
1453     my $rootuid = 0;
1454     my $rootgid = 0;
1455
1456     my $lxc = $conf->{lxc};
1457     foreach my $entry (@$lxc) {
1458         my ($key, $value) = @$entry;
1459         next if $key ne 'lxc.id_map';
1460         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
1461             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
1462             push @$id_map, [$type, $ct, $host, $length];
1463             if ($ct == 0) {
1464                 $rootuid = $host if $type eq 'u';
1465                 $rootgid = $host if $type eq 'g';
1466             }
1467         } else {
1468             die "failed to parse id_map: $value\n";
1469         }
1470     }
1471
1472     if (!@$id_map && $conf->{unprivileged}) {
1473         # Should we read them from /etc/subuid?
1474         $id_map = [ ['u', '0', '100000', '65536'],
1475                     ['g', '0', '100000', '65536'] ];
1476         $rootuid = $rootgid = 100000;
1477     }
1478
1479     return ($id_map, $rootuid, $rootgid);
1480 }
1481
1482 sub userns_command {
1483     my ($id_map) = @_;
1484     if (@$id_map) {
1485         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
1486     }
1487     return [];
1488 }
1489
1490
1491 1;