buildsys: don't use rm -r on so many globs
[pve-docs.git] / asciidoc-pve.in
1 #!/usr/bin/perl
2
3 use strict;
4 use warnings;
5 use Getopt::Long;
6 use File::Path;
7 use File::Basename;
8 use IO::File;
9 use Cwd;
10
11 use JSON;
12
13 my $verbose;
14 my $keep_artifacts;
15
16 my $release = '@RELEASE@';
17
18 my $clicmd = shift or
19 die "no command specified\n";
20
21 my $data_str = "";
22 while (<main::DATA>) { $data_str .= $_; }
23
24 my $fileinfo = decode_json($data_str);
25
26 my $tmpprefix = ".asciidoc-pve-tmp_";
27
28 my $adoc_source_dir = "/usr/share/pve-doc-generator";
29
30 # inside pve-docs source dir?
31 if (-f "asciidoc-pve.in" && -f "pve-admin-guide.adoc") {
32 $adoc_source_dir = getcwd();
33 }
34
35 my $prepared_files = {};
36
37 my $man_target = 'man';
38 my $env_stack = [];
39 my $env_skip = 0;
40
41 my $online_help_links = {
42 'pve_service_daemons' => {
43 link => '/pve-docs/index.html#_service_daemons',
44 title => 'Service Daemons',
45 },
46 'pve_documentation_index' => {
47 link => '/pve-docs/index.html',
48 title => 'Proxmox VE Documentation Index',
49 },
50 'pve_admin_guide' => {
51 link => '/pve-docs/pve-admin-guide.html',
52 title => 'Proxmox VE Administration Guide',
53 },
54 };
55
56 sub debug {
57 my $msg = shift;
58
59 return if !$verbose;
60
61 print STDERR "asciidoc-pve: $msg\n";
62 }
63
64 sub push_environment {
65 my ($env, $skip) = @_;
66
67 $skip = 1 if $env_skip;
68 $skip = 0 if !defined($skip);
69
70 push @$env_stack, [$env, $skip];
71
72 $env_skip = $skip;
73 }
74
75 sub pop_environment {
76 my ($env) = @_;
77
78 my $last_stack_entry = pop @$env_stack;
79 die "unable to pop env '$env'" if !defined($last_stack_entry);
80
81 my ($last_env, $skip) = @$last_stack_entry;
82 die "environment missmatch (${last_env} != $env)\n" if $last_env ne $env;
83
84 if (!scalar(@$env_stack)) {
85 $env_skip = 0;
86 } else {
87 my (undef, $skip) = @{$env_stack->[-1]};
88 $env_skip = $skip;
89 }
90 }
91
92 my $files_for_cleanup = [];
93
94 sub cleanup {
95
96 return if $keep_artifacts;
97
98 foreach my $file (@$files_for_cleanup) {
99 unlink $file;
100 }
101 }
102
103 sub replace_wiki_xref {
104 my ($blockid, $text) = @_;
105
106 my $link = $fileinfo->{blockid_target}->{wiki}->{$blockid};
107 my $reftext = $fileinfo->{reftext}->{wiki}->{$blockid};
108
109 die "unable to resolve wiki link (xref:$blockid)\n"
110 if !defined($link);
111
112 $text = $reftext if !length($text);
113
114 die "xref: no text for wiki link '$blockid'\n" if !$text;
115
116 return "$link\[$text\]";
117 }
118
119 sub replace_default_xref {
120 my ($blockid, $text) = @_;
121
122 my $link = $fileinfo->{blockid_target}->{default}->{$blockid};
123 my $reftext = $fileinfo->{reftext}->{default}->{$blockid};
124
125 die "unable to resolve chapter link (xref:$blockid)\n"
126 if !defined($link);
127
128 $text = $reftext if !length($text);
129
130 die "xref: no text for chapter link '$blockid'\n" if !$text;
131
132 return "$link\[$text\]";
133 }
134
135 sub replace_man_xref {
136 my ($blockid, $text) = @_;
137
138 my $link = $fileinfo->{blockid_target}->{manvolnum}->{$blockid};
139 my $reftext = $fileinfo->{reftext}->{manvolnum}->{$blockid};
140
141 die "unable to resolve man page link (xref:$blockid)\n"
142 if !defined($link);
143
144 $text = $reftext if !length($text);
145
146 die "xref: no text for man page link '$blockid'\n" if !$text;
147
148 my $section = $fileinfo->{mansection}->{manvolnum}->{$link};
149 die "link target is not a manual page" if !defined($section);
150
151
152 if ($man_target eq 'html') {
153 my $target = $link;
154 $target =~ s/\.adoc//;
155 $target .= ".$section";
156 return "link:${target}.html#${blockid}\[$text\]";
157 } elsif ($man_target eq 'man') {
158 my $command = $link;
159 $command =~ s/\.adoc//;
160 return "\*${text}\* (man \*${command}\*($section))";
161 } else {
162 die "internal error"
163 }
164 }
165
166 sub replace_xref {
167 my ($env, $blockid, $text) = @_;
168
169 if ($env eq 'wiki') {
170 return replace_wiki_xref($blockid, $text);
171 } elsif ($env eq 'manvolnum') {
172 if (($man_target eq 'man') || ($man_target eq 'html')) {
173 return replace_man_xref($blockid, $text);
174 } elsif ($man_target eq 'wiki') {
175 return replace_wiki_xref($blockid, $text);
176 } else {
177 die "internal error"
178 }
179 } elsif ($env eq 'default') {
180 return replace_default_xref($blockid, $text);
181 } else {
182 die "internal error";
183 }
184 }
185
186 sub prepare_adoc_file {
187 my ($target_env, $filename, $attributes) = @_;
188
189 return $prepared_files->{$filename} if defined($prepared_files->{$filename});
190
191 debug("prepare $filename");
192
193 my $dirname = dirname($filename);
194 my $basename = basename($filename);
195
196 my $outfilename = "$dirname/${tmpprefix}$basename";
197
198 $prepared_files->{$filename} = $outfilename;
199
200 my $fh = IO::File->new("$filename", "r") or
201 die "unable to open file '$filename' - $!\n";
202
203 my $outfh = IO::File->new("$outfilename", "w") or
204 die "unable to open temporary file '$outfilename'\n";
205
206 push @$files_for_cleanup, $outfilename;
207
208 while (defined (my $line = <$fh>)) {
209 chomp $line;
210 if ($line =~ m/^if(n?)def::(\S+)\[(.*)\]\s*$/) {
211 my ($not, $env, $text) = ($1, $2, $3);
212 die "unsuported ifdef usage - implement me" if $text;
213
214 my $skip = !exists($attributes->{$env}) ? 1 : 0;
215 $skip = ($skip ? 0 : 1 ) if $not;
216
217 push_environment($env, $skip);
218 next;
219 } elsif ($line =~ m/^endif::(\S+)\[(.*)\]\s*$/) {
220 my ($env, $text) = ($1, $2);
221 die "unsuported ifdef usage - implement me" if $text;
222 pop_environment($env);
223 next;
224 }
225
226 next if $env_skip;
227
228 if ($line =~ m/^include::(\S+)(\[.*\]\s*)$/) {
229 my ($fn, $rest) = ($1, $2);
230 debug("include $fn");
231 my $new_fn = prepare_adoc_file($target_env, $fn, $attributes);
232
233 print $outfh "include::${new_fn}$rest\n";
234 next;
235 }
236
237 if ($line =~ m/xref:\S+?\[[^\]]*$/) {
238 die "possible xref spanning multiple lines in '$filename':\n(line $.): $line\n";
239 }
240 if ($line =~ m/<<((?!\>\>).)*$/) {
241 die "possible xref spanning multiple lines in '$filename':\n(line $.): $line\n";
242 }
243 # fix xrefs
244 $line =~ s/xref:([^\s\[\]]+)\[([^\]]*)\]/replace_xref(${target_env},$1,$2)/ge;
245
246 $line =~ s/<<([^\s,\[\]]+)(?:,(.*?))?>>/replace_xref(${target_env},$1,$2)/ge;
247
248 print $outfh $line . "\n";
249 }
250
251 return $outfilename;
252 }
253
254 sub compile_asciidoc {
255 my ($env) = @_;
256
257 my $outfile;
258
259 GetOptions ("outfile=s" => \$outfile,
260 "keep-artifacts" => \$keep_artifacts,
261 "verbose" => \$verbose) or
262 die("Error in command line arguments\n");
263
264 my $infile = shift(@ARGV) or
265 die "no input file specified\n";
266
267 scalar(@ARGV) == 0 or
268 die "too many arguments...\n";
269
270 my $outfilemap = $fileinfo->{outfile}->{$env}->{$infile} ||
271 die "no output file mapping for '$infile' ($env)";
272
273 if ($man_target eq 'html') {
274 $outfilemap .= '.html';
275 } elsif ($man_target eq 'wiki') {
276 $outfilemap .= '-plain.html';
277 }
278
279 if (defined($outfile)) {
280 die "wrong output file name '$outfile != $outfilemap' ($env)"
281 if $outfile ne $outfilemap;
282 } else {
283 $outfile = $outfilemap;
284 }
285
286 defined($fileinfo->{titles}->{$env}) ||
287 die "unknown environment '$env'";
288
289 my $title = $fileinfo->{titles}->{$env}->{$infile} or
290 die "unable to get title for '$infile'$env\n";
291
292 debug("compile $title");
293
294 my $leveloffset = 0;
295
296 my $doctype = $fileinfo->{doctype}->{$env}->{$infile};
297
298 die "unable to get document type for '$infile'\n"
299 if !defined($doctype);
300
301 $leveloffset = - $doctype;
302
303 my $date = `date`;
304 chomp $date;
305
306 my $attributes = {
307 $env => undef,
308 leveloffset => $leveloffset,
309 revnumber => $release,
310 revdate => $date,
311 };
312
313 my $mansection = $fileinfo->{mansection}->{$env}->{$infile};
314
315 if ($env eq 'wiki') {
316 } elsif ($env eq 'manvolnum') {
317 die "undefined man section" if !defined($mansection);
318 $attributes->{manvolnum} = $mansection;
319 } elsif ($env eq 'default') {
320 die "$infile: wrong doctype\n" if $doctype != 0;
321 $attributes->{toc} = undef;
322 }
323
324 if (!defined($outfile)) {
325 $outfile = $infile;
326 $outfile =~ s/\.adoc$//;
327 if ($env eq 'manvolnum') {
328 if (($man_target eq 'html') || ($man_target eq 'wiki')) {
329 $outfile .= ".$mansection.html";
330 } else {
331 $outfile .= ".$mansection";
332 }
333 } else {
334 $outfile .= ".html";
335 }
336 }
337
338 if (($env eq 'manvolnum') && ($man_target eq 'man')) {
339
340 # asciidoc /etc/asciidoc/docbook-xsl/manpage.xsl skip REFERENCES
341 # section like footnotes, so we cannot use a2x.
342 # We use xmlto instead.
343
344 my $cmd = ['asciidoc', '-dmanpage', '-bdocbook',
345 '-f', "$adoc_source_dir/asciidoc/asciidoc-pve.conf",
346 '-a', 'docinfo1'];
347
348 foreach my $key (keys %$attributes) {
349 my $value = $attributes->{$key};
350 if (defined($value)) {
351 push @$cmd, '-a', "$key=$value";
352 } else {
353 push @$cmd, '-a', $key;
354 }
355 }
356
357 push @$cmd, '--verbose' if $verbose;
358
359 my $tmpxmlfile = "${outfile}.xml.tmp";
360
361 push @$cmd, '--out-file', $tmpxmlfile;
362
363 push @$files_for_cleanup, $tmpxmlfile;
364
365 my $new_infile = prepare_adoc_file($env, $infile, $attributes);
366
367 push @$cmd, $new_infile;
368
369 debug("run " . join(' ', @$cmd));
370
371 system(@$cmd) == 0 or
372 die "aciidoc error";
373
374 $cmd = ['xmlto', 'man', $tmpxmlfile];
375
376 push @$cmd, '-v' if $verbose;
377
378 debug("run " . join(' ', @$cmd));
379
380 system(@$cmd) == 0 or
381 die "xmlto error";
382
383 } else {
384
385 $attributes->{icons} = undef;
386 $attributes->{'data-uri'} = undef;
387
388 my $cmd = ['asciidoc',
389 '-f', "$adoc_source_dir/asciidoc/asciidoc-pve.conf",
390 ];
391
392 if (($env eq 'wiki') ||
393 (($env eq 'manvolnum') && ($man_target eq 'wiki'))) {
394
395 push @$cmd, '-b', "$adoc_source_dir/asciidoc/mediawiki";
396 } else {
397 push @$cmd, '-b', "$adoc_source_dir/asciidoc/pve-html";
398 }
399
400 foreach my $key (keys %$attributes) {
401 my $value = $attributes->{$key};
402 if (defined($value)) {
403 push @$cmd, '-a', "$key=$value";
404 } else {
405 push @$cmd, '-a', $key;
406 }
407 }
408
409 push @$cmd, '--verbose' if $verbose;
410
411 push @$cmd, '--out-file', $outfile;
412
413 my $new_infile = prepare_adoc_file($env, $infile, $attributes);
414
415 push @$cmd, $new_infile;
416
417 debug("run " . join(' ', @$cmd));
418
419 system(@$cmd) == 0 or
420 die "aciidoc error";
421 }
422 }
423
424 sub get_links {
425
426 my $data = {};
427
428 foreach my $blockid (sort keys %{$fileinfo->{blockid_target}->{default}}) {
429 my $link = $fileinfo->{blockid_target}->{default}->{$blockid};
430 my $reftitle = $fileinfo->{reftitle}->{default}->{$blockid};
431 my $reftext = $fileinfo->{reftext}->{default}->{$blockid};
432 die "internal error" if $link !~ m/^link:/;
433 $link =~ s/^link://;
434
435 my $file = $fileinfo->{blockid}->{default}->{$blockid};
436 die "internal error - no filename" if ! defined($file);
437 my $title = $fileinfo->{titles}->{default}->{$file} ||
438 die "internal error - no title";
439
440 $data->{$blockid}->{title} = $title;
441 $data->{$blockid}->{link} = $link;
442 my $subtitle = $reftitle || $reftext;
443 $data->{$blockid}->{subtitle} = $subtitle
444 if $subtitle && ($title ne $subtitle);
445 }
446
447 return $data;
448 }
449
450 sub scan_extjs_file {
451 my ($filename, $res_data) = @_;
452
453 my $fh = IO::File->new($filename, "r") ||
454 die "unable to open '$filename' - $!\n";
455
456 debug("scan-extjs $filename");
457
458 while(defined(my $line = <$fh>)) {
459 if ($line =~ m/\s+onlineHelp:\s*[\'\"](.*?)[\'\"]/) {
460 my $blockid = $1;
461 my $link = $fileinfo->{blockid_target}->{default}->{$blockid};
462 die "undefined blockid '$blockid' ($filename, line $.)\n"
463 if !(defined($link) || defined($online_help_links->{$blockid}));
464
465 $res_data->{$blockid} = 1;
466 }
467 }
468 }
469
470 if ($clicmd eq 'compile-wiki') {
471
472 eval { compile_asciidoc('wiki'); };
473 my $err = $@;
474
475 cleanup();
476
477 die $err if $err;
478
479 } elsif ($clicmd eq 'compile-chapter') {
480
481 eval { compile_asciidoc('default'); };
482 my $err = $@;
483
484 cleanup();
485
486 die $err if $err;
487
488 } elsif ($clicmd eq 'compile-man-html') {
489
490 $man_target = 'html';
491
492 eval { compile_asciidoc('manvolnum'); };
493 my $err = $@;
494
495 cleanup();
496
497 die $err if $err;
498
499 } elsif ($clicmd eq 'compile-man-wiki') {
500
501 $man_target = 'wiki';
502
503 eval { compile_asciidoc('manvolnum'); };
504 my $err = $@;
505
506 cleanup();
507
508 die $err if $err;
509
510 } elsif ($clicmd eq 'compile-man') {
511
512 eval { compile_asciidoc('manvolnum'); };
513 my $err = $@;
514
515 cleanup();
516
517 die $err if $err;
518
519 } elsif ($clicmd eq 'print-links') {
520
521 my $outfile;
522
523 GetOptions("outfile=s" => \$outfile,
524 "verbose" => \$verbose) or
525 die("Error in command line arguments\n");
526
527 scalar(@ARGV) == 0 or
528 die "too many arguments...\n";
529
530 my $data = get_links();
531
532 my $res = to_json($data, { pretty => 1, canonical => 1 } );
533
534 if (defined($outfile)) {
535 my $outfh = IO::File->new("$outfile", "w") or
536 die "unable to open temporary file '$outfile'\n";
537
538 print $outfh $res;
539
540 } else {
541
542 print $res;
543 }
544
545 } elsif ($clicmd eq 'scan-extjs') {
546
547 GetOptions("verbose" => \$verbose) or
548 die("Error in command line arguments\n");
549
550 my $link_hash = {};
551 my $scanned_files = {};
552 while (my $filename = shift) {
553 die "got strange file name '$filename'\n"
554 if $filename !~ m/\.js$/;
555 next if $scanned_files->{$filename};
556
557 scan_extjs_file($filename, $link_hash);
558 $scanned_files->{$filename} = 1;
559 }
560
561 my $data = get_links();
562
563 my $res_data = {};
564
565 foreach my $blockid (keys %$link_hash) {
566 $res_data->{$blockid} = $data->{$blockid} || $online_help_links->{$blockid} ||
567 die "internal error - no data for '$blockid'";
568 }
569
570 my $data_str = to_json($res_data, { pretty => 1, canonical => 1 });
571 chomp $data_str;
572
573 print "var pveOnlineHelpInfo = ${data_str};\n";
574
575 } elsif ($clicmd eq 'chapter-table') {
576
577 print '[width="100%",options="header"]' . "\n";
578 print "|====\n";
579 print "|Title|Link\n";
580
581 my $filelist = $fileinfo->{outfile}->{default};
582 foreach my $sourcefile (sort keys %$filelist) {
583 my $target = $filelist->{$sourcefile};
584 next if $target eq 'pve-admin-guide.html';
585 my $title = $fileinfo->{titles}->{default}->{$sourcefile} ||
586 die "not title for '$sourcefile'";
587 print "|$title|link:$target\[\]\n";
588 }
589
590 print "|====\n";
591
592 } elsif ($clicmd =~ m/^man([158])page-table$/) {
593
594 my $section = $1;
595 print '[width="100%",cols="5*d",options="header"]' . "\n";
596 print "|====\n";
597 print "|Name 3+|Title|Link\n";
598
599 my $filelist = $fileinfo->{outfile}->{manvolnum};
600 foreach my $manpage (sort keys %$filelist) {
601 next if $section ne $fileinfo->{mansection}->{manvolnum}->{$manpage};
602 my $mantitle = $fileinfo->{titles}->{manvolnum}->{$manpage} ||
603 die "not manual title for '$manpage'";
604 my $title = $fileinfo->{titles}->{default}->{$manpage} ||
605 die "not title for '$manpage'";
606
607 # hack - remove command name prefix from titles
608 $title =~ s/^[a-z]+\s*-\s*//;
609
610 my $target = $filelist->{$manpage};
611 print "|$mantitle 3+|$title|link:$target.html\[$target\]\n";
612 }
613
614 print "|====\n";
615
616 } else {
617
618 die "unknown command '$clicmd'\n";
619
620 }
621
622
623 exit 0;
624
625 __END__