scan-adoc-refs

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use JSON;
   7
   8 use Data::Dumper;
   9
  10 my $environments = {
  11     default => 1,
  12     wiki => 1,
  13     manvolnum => 1,
  14     pvelogo => 0, # ignore
  15 };
  16
  17 my $fileinfo = {};
  18
  19 my $start_env = [];
  20 foreach my $e (keys %$environments) {
  21     push @$start_env, $e if $environments->{$e};
  22 }
  23
  24 my $env_stack = [$start_env];
  25 my $env_name_stack = [];
  26
  27 sub reset_environment_stack {
  28     $env_stack = [$start_env];
  29     $env_name_stack = [];
  30 }
  31
  32 sub push_environment {
  33     my ($env, $not) = @_;
  34
  35     die "undefined environment '$env'\n" if !defined($environments->{$env});
  36
  37     # FIXME: this seems wrong  (nested env?)?
  38     return if !$environments->{$env}; # do not track
  39
  40     if ($not) {
  41         my $new_env = [];
  42         foreach my $e (@{$env_stack->[-1]}) {
  43             if ($e ne $env) {
  44                 push @$new_env, $e;
  45             }
  46         }
  47         die "empty environment" if !scalar($new_env);
  48         push @$env_stack, $new_env;
  49     } else {
  50         push @$env_stack, [$env];
  51     }
  52
  53     push @$env_name_stack, $env;
  54 }
  55
  56 sub pop_environment {
  57     my ($env) = @_;
  58
  59     die "undefined environment '$env'\n" if !defined($environments->{$env});
  60
  61     return if !$environments->{$env}; # do not track
  62
  63     pop @$env_stack;
  64     my $res = pop @$env_name_stack;
  65
  66     die "environment missmatch ($res != $env)\n" if $res ne $env;
  67 }
  68
  69 sub register_include {
  70     my ($filename, $include_filename, $env_list) = @_;
  71
  72     return if $include_filename !~ m/\.adoc$/; # skip attributes.txt
  73
  74     foreach my $e (@$env_list) {
  75         $fileinfo->{include}->{$e}->{$filename}->{$include_filename} = 1;
  76     }
  77 }
  78
  79 sub register_blockid {
  80     my ($filename, $blockid, $reftext, $env_list) = @_;
  81
  82     foreach my $e (@$env_list) {
  83         my $fn = $fileinfo->{blockid}->{$e}->{$blockid};
  84         die "blockid '$blockid' already defined in $fn"
  85             if defined($fn);
  86         $fileinfo->{blockid}->{$e}->{$blockid} = $filename;
  87         $fileinfo->{reftext}->{$e}->{$blockid} = $reftext
  88             if defined($reftext);
  89     }
  90 }
  91
  92 sub register_title {
  93     my ($filename, $env, $doctype, $title) = @_;
  94
  95     # fixme: what about other macros?
  96     $title =~ s/\{pve\}/Proxmox VE/g;
  97     $title =~ s!http://\S+\[(.*?)\]!$1!g;
  98
  99     $fileinfo->{titles}->{$env}->{$filename} = $title;
 100     $fileinfo->{doctype}->{$env}->{$filename} = $doctype;
 101 }
 102
 103 sub scan_adoc_file {
 104     my ($filename) = @_;
 105
 106     reset_environment_stack();
 107
 108     # print "SCAN $filename\n";
 109
 110     my $fh = IO::File->new("$filename", "r") or
 111         die "unable to open file '$filename' - $!\n";
 112
 113     my $env_last_line = {};
 114
 115     while (defined (my $line = <$fh>)) {
 116         if ($line =~ m/^if(n?)def::(\S+)\[(.*)\]\s*$/) {
 117             my ($not, $env, $text) = ($1, $2, $3);
 118             die "unsuported ifdef usage - implement me" if $text;
 119             push_environment($env, $not);
 120             next;
 121         } elsif ($line =~ m/^endif::(\S+)\[(.*)\]\s*$/) {
 122             my ($env, $text) = ($1, $2);
 123             die "unsuported ifdef usage - implement me" if $text;
 124             pop_environment($env);
 125             next;
 126         } elsif ($line =~ m/^include::(\S+)\[.*\]\s*$/) {
 127             register_include($filename, $1, $env_stack->[-1]);
 128             next;
 129         }
 130
 131         # try to detect titles
 132         foreach my $e (@{$env_stack->[-1]}) {
 133             my $title = $fileinfo->{titles}->{$e}->{$filename};
 134             next if defined($title);
 135
 136             if ($line =~ m/^=====+$/) {
 137                 register_title($filename, $e, 0, $env_last_line->{$e});
 138             } elsif ($line =~ m/^-----+$/) {
 139                 register_title($filename, $e, 1, $env_last_line->{$e});
 140             } elsif ($line =~ m/^= +(\S.*?)( +=)?$/) {
 141                 register_title($filename, $e, 0, $1);
 142             } elsif ($line =~ m/^== +(\S.*?)( +==)?$/) {
 143                 register_title($filename, $e, 1, $1);
 144             }
 145
 146             $env_last_line->{$e} = $line;
 147             chomp $env_last_line->{$e};
 148         }
 149
 150         if ($line =~ m/^:(\S+?):\s*(.*\S)?\s*$/) {
 151             my ($key, $value) = ($1, $2);
 152             if ($key eq 'pve-toplevel') {
 153
 154                 foreach my $e (@{$env_stack->[-1]}) {
 155                     my $title = $fileinfo->{titles}->{$e}->{$filename};
 156                     die "not title for toplevel file '$filename' (env=$e)\n"
 157                         if !defined($title);
 158                     $fileinfo->{toplevel}->{$e}->{$filename} = 1;
 159                 }
 160             }
 161         }
 162
 163         if ($line =~ m/^\[\[(.*)\]\]\s*$/) {
 164             my $blockid = $1;
 165             die "implement me" if $blockid =~m/,/;
 166             my $reftext = '';
 167             register_blockid($filename, $blockid, $reftext, $env_stack->[-1]);
 168         }
 169         # fixme: "anchor:"
 170         # bibliography anchors
 171         if ($line =~ m/\[\[\[([^\]]*)\]\]\]/) {
 172             my $blockid = $1;
 173             die "implement me" if $blockid =~m/,/;
 174             register_blockid($filename, $blockid, "&#91;$blockid&#93;", $env_stack->[-1]);
 175         }
 176     }
 177 }
 178
 179 my $scanned_files = {};
 180 while (my $filename = shift) {
 181     next if $filename !~ m/\.adoc$/; # skip attributes.txt
 182     next if $scanned_files->{$filename};
 183
 184     scan_adoc_file($filename);
 185     $scanned_files->{$filename} = 1;
 186 }
 187
 188 sub resolve_link_target {
 189     my ($env, $filename) = @_;
 190
 191     my $include_hash = $fileinfo->{include}->{$env};
 192
 193     my $repeat = 1;
 194
 195     while ($repeat) {
 196         $repeat = 0;
 197         foreach my $fn (keys %$include_hash) {
 198             if ($include_hash->{$fn}->{$filename}) {
 199                 $filename = $fn;
 200                 $repeat = 1;
 201                 last;
 202             }
 203         }
 204     }
 205
 206     return $filename;
 207 }
 208
 209 # now resolve blockids
 210 foreach my $e (@$start_env) {
 211     my $blockid_hash = $fileinfo->{blockid}->{$e};
 212     foreach my $blockid (keys %$blockid_hash) {
 213         my $fn = resolve_link_target($e, $blockid_hash->{$blockid});
 214         if ($e eq 'wiki') {
 215             my $title = $fileinfo->{titles}->{$e}->{$fn};
 216             $title =~ s/\s/_/g;
 217             die "found not title for '$fn' in env '$e'" if !$title;
 218             $fileinfo->{blockid_target}->{$e}->{$blockid} = "link:/wiki/$title#$blockid";
 219         } else {
 220             $fileinfo->{blockid_target}->{$e}->{$blockid} = $fn;
 221         }
 222     }
 223 }
 224
 225
 226 print to_json($fileinfo, { pretty => 1 } );