PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5 use Data::Dumper;
   6 use Digest::SHA;
   7 use PVE::Tools;
   8 use PVE::QemuServer;
   9 use File::Path;
  10 use IO::File;
  11 use Net::IP;
  12 use PVE::Tools qw(run_command lock_file);
  13
  14 use Data::Dumper;
  15
  16 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
  17
  18 my $macros;
  19
  20 # todo: implement some kind of MACROS, like shorewall /usr/share/shorewall/macro.*
  21 sub get_firewall_macros {
  22
  23     return $macros if $macros;
  24
  25     #foreach my $path (</usr/share/shorewall/macro.*>) {
  26     #  if ($path =~ m|/macro\.(\S+)$|) {
  27     #    $macros->{$1} = 1;
  28     #  }
  29     #}
  30
  31     $macros = {}; # fixme: implemet me
  32
  33     return $macros;
  34 }
  35
  36 my $etc_services;
  37
  38 sub get_etc_services {
  39
  40     return $etc_services if $etc_services;
  41
  42     my $filename = "/etc/services";
  43
  44     my $fh = IO::File->new($filename, O_RDONLY);
  45     if (!$fh) {
  46         warn "unable to read '$filename' - $!\n";
  47         return {};
  48     }
  49
  50     my $services = {};
  51
  52     while (my $line = <$fh>) {
  53         chomp ($line);
  54         next if $line =~m/^#/;
  55         next if ($line =~m/^\s*$/);
  56
  57         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
  58             $services->{byid}->{$2}->{name} = $1;
  59             $services->{byid}->{$2}->{$3} = 1;
  60             $services->{byname}->{$1} = $services->{byid}->{$2};
  61         }
  62     }
  63
  64     close($fh);
  65
  66     $etc_services = $services;
  67
  68
  69     return $etc_services;
  70 }
  71
  72 my $etc_protocols;
  73
  74 sub get_etc_protocols {
  75     return $etc_protocols if $etc_protocols;
  76
  77     my $filename = "/etc/protocols";
  78
  79     my $fh = IO::File->new($filename, O_RDONLY);
  80     if (!$fh) {
  81         warn "unable to read '$filename' - $!\n";
  82         return {};
  83     }
  84
  85     my $protocols = {};
  86
  87     while (my $line = <$fh>) {
  88         chomp ($line);
  89         next if $line =~m/^#/;
  90         next if ($line =~m/^\s*$/);
  91
  92         if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
  93             $protocols->{byid}->{$2}->{name} = $1;
  94             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
  95         }
  96     }
  97
  98     close($fh);
  99
 100     $etc_protocols = $protocols;
 101
 102     return $etc_protocols;
 103 }
 104
 105 sub parse_address_list {
 106     my ($str) = @_;
 107
 108     my $nbaor = 0;
 109     foreach my $aor (split(/,/, $str)) {
 110         if (!Net::IP->new($aor)) {
 111             my $err = Net::IP::Error();
 112             die "invalid IP address: $err\n";
 113         }else{
 114             $nbaor++;
 115         }
 116     }
 117     return $nbaor;
 118 }
 119
 120 sub parse_port_name_number_or_range {
 121     my ($str) = @_;
 122
 123     my $services = PVE::Firewall::get_etc_services();
 124     my $nbports = 0;
 125     foreach my $item (split(/,/, $str)) {
 126         my $portlist = "";
 127         foreach my $pon (split(':', $item, 2)) {
 128             if ($pon =~ m/^\d+$/){
 129                 die "invalid port '$pon'\n" if $pon < 0 && $pon > 65536;
 130             }else{
 131                 die "invalid port $services->{byname}->{$pon}\n" if !$services->{byname}->{$pon};
 132             }
 133             $nbports++;
 134         }
 135     }
 136
 137     return ($nbports);
 138 }
 139
 140 my $bridge_firewall_enabled = 0;
 141
 142 sub enable_bridge_firewall {
 143
 144     return if $bridge_firewall_enabled; # only once
 145
 146     system("echo 1 > /proc/sys/net/bridge/bridge-nf-call-iptables");
 147     system("echo 1 > /proc/sys/net/bridge/bridge-nf-call-ip6tables");
 148
 149     $bridge_firewall_enabled = 1;
 150 }
 151
 152 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
 153
 154 sub iptables {
 155     my ($cmd) = @_;
 156
 157     run_command("/sbin/iptables $cmd", outfunc => sub {}, errfunc => sub {});
 158 }
 159
 160 sub iptables_restore_cmdlist {
 161     my ($cmdlist) = @_;
 162
 163     run_command("/sbin/iptables-restore -n", input => $cmdlist);
 164 }
 165
 166 sub iptables_get_chains {
 167
 168     my $res = {};
 169
 170     # check what chains we want to track
 171     my $is_pvefw_chain = sub {
 172         my $name = shift;
 173
 174         return 1 if $name =~ m/^PVEFW-\S+$/;
 175
 176         return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
 177         return 1 if $name =~ m/^vmbr\d+-(:?IN|OUT)$/;
 178         return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
 179
 180         return undef;
 181     };
 182
 183     my $table = '';
 184
 185     my $parser = sub {
 186         my $line = shift;
 187
 188         return if $line =~ m/^#/;
 189         return if $line =~ m/^\s*$/;
 190
 191         if ($line =~ m/^\*(\S+)$/) {
 192             $table = $1;
 193             return;
 194         }
 195
 196         return if $table ne 'filter';
 197
 198         if ($line =~ m/^:(\S+)\s/) {
 199             my $chain = $1;
 200             return if !&$is_pvefw_chain($chain);
 201             $res->{$chain} = "unknown";
 202         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
 203             my ($chain, $sig) = ($1, $2);
 204             return if !&$is_pvefw_chain($chain);
 205             $res->{$chain} = $sig;
 206         } else {
 207             # simply ignore the rest
 208             return;
 209         }
 210     };
 211
 212     run_command("/sbin/iptables-save", outfunc => $parser);
 213
 214     return $res;
 215 }
 216
 217 sub iptables_chain_exist {
 218     my ($chain) = @_;
 219
 220     eval{
 221         iptables("-n --list $chain");
 222     };
 223     return undef if $@;
 224
 225     return 1;
 226 }
 227
 228 sub iptables_rule_exist {
 229     my ($rule) = @_;
 230
 231     eval{
 232         iptables("-C $rule");
 233     };
 234     return undef if $@;
 235
 236     return 1;
 237 }
 238
 239 sub ruleset_generate_rule {
 240     my ($ruleset, $chain, $rule, $goto) = @_;
 241
 242     my $cmd = '';
 243
 244     $cmd .= " -m iprange --src-range" if $rule->{nbsource} && $rule->{nbsource} > 1;
 245     $cmd .= " -s $rule->{source}" if $rule->{source};
 246     $cmd .= " -m iprange --dst-range" if $rule->{nbdest} && $rule->{nbdest} > 1;
 247     $cmd .= " -d $rule->{dest}" if $rule->{destination};
 248     $cmd .= " -p $rule->{proto}" if $rule->{proto};
 249     $cmd .= "  --match multiport" if $rule->{nbdport} && $rule->{nbdport} > 1;
 250     $cmd .= " --dport $rule->{dport}" if $rule->{dport};
 251     $cmd .= "  --match multiport" if $rule->{nbsport} && $rule->{nbsport} > 1;
 252     $cmd .= " --sport $rule->{sport}" if $rule->{sport};
 253
 254     if (my $action = $rule->{action}) {
 255         $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
 256         $cmd .= $goto ? " -g $action" : " -j $action";
 257     };
 258
 259     ruleset_addrule($ruleset, $chain, $cmd) if $cmd;
 260 }
 261
 262 sub ruleset_create_chain {
 263     my ($ruleset, $chain) = @_;
 264
 265     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
 266
 267     die "chain '$chain' already exists\n" if $ruleset->{$chain};
 268
 269     $ruleset->{$chain} = [];
 270 }
 271
 272 sub ruleset_chain_exist {
 273     my ($ruleset, $chain) = @_;
 274
 275     return $ruleset->{$chain} ? 1 : undef;
 276 }
 277
 278 sub ruleset_addrule {
 279    my ($ruleset, $chain, $rule) = @_;
 280
 281    die "no such chain '$chain'\n" if !$ruleset->{$chain};
 282
 283    push @{$ruleset->{$chain}}, "-A $chain $rule";
 284 }
 285
 286 sub ruleset_insertrule {
 287    my ($ruleset, $chain, $rule) = @_;
 288
 289    die "no such chain '$chain'\n" if !$ruleset->{$chain};
 290
 291    unshift @{$ruleset->{$chain}}, "-A $chain $rule";
 292 }
 293
 294 sub generate_bridge_chains {
 295     my ($ruleset, $bridge) = @_;
 296
 297     if (!ruleset_chain_exist($ruleset, "PVEFW-BRIDGE-IN")){
 298         ruleset_create_chain($ruleset, "PVEFW-BRIDGE-IN");
 299     }
 300
 301     if (!ruleset_chain_exist($ruleset, "PVEFW-BRIDGE-OUT")){
 302         ruleset_create_chain($ruleset, "PVEFW-BRIDGE-OUT");
 303     }
 304
 305     if (!ruleset_chain_exist($ruleset, "PVEFW-FORWARD")){
 306         ruleset_create_chain($ruleset, "PVEFW-FORWARD");
 307
 308         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m state --state RELATED,ESTABLISHED -j ACCEPT");
 309         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-in --physdev-is-bridged -j PVEFW-BRIDGE-OUT");
 310         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-out --physdev-is-bridged -j PVEFW-BRIDGE-IN");
 311     }
 312
 313     if (!ruleset_chain_exist($ruleset, "$bridge-IN")) {
 314         ruleset_create_chain($ruleset, "$bridge-IN");
 315         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i $bridge -j DROP");  # disable interbridge routing
 316         ruleset_addrule($ruleset, "PVEFW-BRIDGE-IN", "-j $bridge-IN");
 317         ruleset_addrule($ruleset, "$bridge-IN", "-j ACCEPT");
 318     }
 319
 320     if (!ruleset_chain_exist($ruleset, "$bridge-OUT")) {
 321         ruleset_create_chain($ruleset, "$bridge-OUT");
 322         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o $bridge -j DROP"); # disable interbridge routing
 323         ruleset_addrule($ruleset, "PVEFW-BRIDGE-OUT", "-j $bridge-OUT");
 324     }
 325 }
 326
 327 sub generate_tap_rules_direction {
 328     my ($ruleset, $iface, $netid, $macaddr, $rules, $bridge, $direction) = @_;
 329
 330     my $tapchain = "$iface-$direction";
 331
 332     ruleset_create_chain($ruleset, $tapchain);
 333
 334     ruleset_addrule($ruleset, $tapchain, "-m state --state INVALID -j DROP");
 335     ruleset_addrule($ruleset, $tapchain, "-m state --state RELATED,ESTABLISHED -j ACCEPT");
 336
 337     if ($direction eq 'OUT' && defined($macaddr)) {
 338         ruleset_addrule($ruleset, $tapchain, "-m mac ! --mac-source $macaddr -j DROP");
 339     }
 340
 341     if ($rules) {
 342         foreach my $rule (@$rules) {
 343             next if $rule->{iface} && $rule->{iface} ne $netid;
 344             if($rule->{action}  =~ m/^(GROUP-(\S+))$/){
 345                 $rule->{action} .= "-$direction";
 346                 # generate empty group rule if don't exist
 347                 if(!ruleset_chain_exist($ruleset, $rule->{action})){
 348                     generate_group_rules($ruleset, $2);
 349                 }
 350                 ruleset_generate_rule($ruleset, $tapchain, $rule);
 351                 ruleset_addrule($ruleset, $tapchain, "-m mark --mark 1 -g $bridge-IN");
 352             } else {
 353                 # we go to vmbr-IN if accept in out rules
 354                 $rule->{action} = "$bridge-IN" if $rule->{action} eq 'ACCEPT' && $direction eq 'OUT';
 355                 ruleset_generate_rule($ruleset, $tapchain, $rule);
 356             }
 357         }
 358     }
 359
 360     ruleset_addrule($ruleset, $tapchain, "-j LOG --log-prefix \"$tapchain-dropped: \" --log-level 4");
 361     ruleset_addrule($ruleset, $tapchain, "-j DROP");
 362
 363     # plug the tap chain to bridge chain
 364     my $physdevdirection = $direction eq 'IN' ? "out" : "in";
 365     my $rule = "-m physdev --physdev-$physdevdirection $iface --physdev-is-bridged -j $tapchain";
 366     ruleset_insertrule($ruleset, "$bridge-$direction", $rule);
 367
 368     if ($direction eq 'OUT'){
 369         # add tap->host rules
 370         my $rule = "-m physdev --physdev-$physdevdirection $iface -j $tapchain";
 371         ruleset_addrule($ruleset, "PVEFW-INPUT", $rule);
 372     }
 373 }
 374
 375 sub enablehostfw {
 376     my ($ruleset) = @_;
 377
 378     my $filename = "/etc/pve/local/host.fw";
 379     my $fh = IO::File->new($filename, O_RDONLY);
 380     return if !$fh;
 381
 382     my $rules = parse_fw_rules($filename, $fh);
 383
 384     # host inbound firewall
 385     my $chain = "PVEFW-HOST-IN";
 386     ruleset_create_chain($ruleset, $chain);
 387
 388     ruleset_addrule($ruleset, $chain, "-m state --state INVALID -j DROP");
 389     ruleset_addrule($ruleset, $chain, "-m state --state RELATED,ESTABLISHED -j ACCEPT");
 390     ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
 391     ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
 392     ruleset_addrule($ruleset, $chain, "-p udp -m state --state NEW -m multiport --dports 5404,5405 -j ACCEPT");
 393     ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT");  #corosync
 394
 395     if ($rules->{in}) {
 396         foreach my $rule (@{$rules->{in}}) {
 397             # we use RETURN because we need to check also tap rules
 398             $rule->{action} = 'RETURN' if $rule->{action} eq 'ACCEPT';
 399             ruleset_generate_rule($ruleset, $chain, $rule);
 400         }
 401     }
 402
 403     ruleset_addrule($ruleset, $chain, "-j LOG --log-prefix \"kvmhost-IN dropped: \" --log-level 4");
 404     ruleset_addrule($ruleset, $chain, "-j DROP");
 405
 406     # host outbound firewall
 407     $chain = "PVEFW-HOST-OUT";
 408     ruleset_create_chain($ruleset, $chain);
 409
 410     ruleset_addrule($ruleset, $chain, "-m state --state INVALID -j DROP");
 411     ruleset_addrule($ruleset, $chain, "-m state --state RELATED,ESTABLISHED -j ACCEPT");
 412     ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
 413     ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
 414     ruleset_addrule($ruleset, $chain, "-p udp -m state --state NEW -m multiport --dports 5404,5405 -j ACCEPT");
 415     ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT"); #corosync
 416
 417     if ($rules->{out}) {
 418         foreach my $rule (@{$rules->{out}}) {
 419             # we use RETURN because we need to check also tap rules
 420             $rule->{action} = 'RETURN' if $rule->{action} eq 'ACCEPT';
 421             ruleset_generate_rule($ruleset, $chain, $rule);
 422         }
 423     }
 424
 425     ruleset_addrule($ruleset, $chain, "-j LOG --log-prefix \"kvmhost-OUT dropped: \" --log-level 4");
 426     ruleset_addrule($ruleset, $chain, "-j DROP");
 427
 428     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
 429     ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
 430 }
 431
 432 sub generate_group_rules {
 433     my ($ruleset, $group) = @_;
 434
 435     my $filename = "/etc/pve/firewall/groups.fw";
 436     my $fh = IO::File->new($filename, O_RDONLY);
 437     return if !$fh;
 438
 439     my $rules = parse_fw_rules($filename, $fh, $group);
 440
 441     my $chain = "GROUP-${group}-IN";
 442
 443     ruleset_create_chain($ruleset, $chain);
 444
 445     if ($rules->{in}) {
 446         foreach my $rule (@{$rules->{in}}) {
 447             ruleset_generate_rule($ruleset, $chain, $rule);
 448         }
 449     }
 450
 451     $chain = "GROUP-${group}-OUT";
 452
 453     ruleset_create_chain($ruleset, $chain);
 454     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
 455
 456     if ($rules->{out}) {
 457         foreach my $rule (@{$rules->{out}}) {
 458             # we go the PVEFW-SET-ACCEPT-MARK Instead of ACCEPT) because we need to
 459             # check also other tap rules (and group rules can be set on any bridge,
 460             # so we can't go to VMBRXX-IN)
 461             $rule->{action} = 'PVEFW-SET-ACCEPT-MARK' if $rule->{action} eq 'ACCEPT';
 462             ruleset_generate_rule($ruleset, $chain, $rule);
 463         }
 464     }
 465 }
 466
 467 sub parse_fw_rules {
 468     my ($filename, $fh, $group) = @_;
 469
 470     my $section;
 471     my $securitygroup;
 472     my $securitygroupexist;
 473
 474     my $res = { in => [], out => [] };
 475
 476     my $macros = get_firewall_macros();
 477     my $protocols = get_etc_protocols();
 478
 479     while (defined(my $line = <$fh>)) {
 480         next if $line =~ m/^#/;
 481         next if $line =~ m/^\s*$/;
 482
 483         if ($line =~ m/^\[(in|out)(:(\S+))?\]\s*$/i) {
 484             $section = lc($1);
 485             $securitygroup = lc($3) if $3;
 486             $securitygroupexist = 1 if $securitygroup &&  $securitygroup eq $group;
 487             next;
 488         }
 489         next if !$section;
 490         next if $group && $securitygroup ne $group;
 491
 492         my ($action, $iface, $source, $dest, $proto, $dport, $sport) =
 493             split(/\s+/, $line);
 494
 495         if (!$action) {
 496             warn "skip incomplete line\n";
 497             next;
 498         }
 499
 500         my $service;
 501         if ($action =~ m/^(ACCEPT|DROP|REJECT|GROUP-(\S+))$/) {
 502             # OK
 503         } elsif ($action =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
 504             ($service, $action) = ($1, $2);
 505             if (!$macros->{$service}) {
 506                 warn "unknown service '$service'\n";
 507                 next;
 508             }
 509         } else {
 510             warn "unknown action '$action'\n";
 511             next;
 512         }
 513
 514         $iface = undef if $iface && $iface eq '-';
 515         if ($iface && $iface !~ m/^(net0|net1|net2|net3|net4|net5)$/) {
 516             warn "unknown interface '$iface'\n";
 517             next;
 518         }
 519
 520         $proto = undef if $proto && $proto eq '-';
 521         if ($proto && !(defined($protocols->{byname}->{$proto}) ||
 522                         defined($protocols->{byid}->{$proto}))) {
 523             warn "unknown protokol '$proto'\n";
 524             next;
 525         }
 526
 527         $source = undef if $source && $source eq '-';
 528         $dest = undef if $dest && $dest eq '-';
 529
 530         $dport = undef if $dport && $dport eq '-';
 531         $sport = undef if $sport && $sport eq '-';
 532         my $nbdport = undef;
 533         my $nbsport = undef;
 534         my $nbsource = undef;
 535         my $nbdest = undef;
 536
 537         eval {
 538             $nbsource = parse_address_list($source) if $source;
 539             $nbdest = parse_address_list($dest) if $dest;
 540             $nbdport = parse_port_name_number_or_range($dport) if $dport;
 541             $nbsport = parse_port_name_number_or_range($sport) if $sport;
 542         };
 543         if (my $err = $@) {
 544             warn $err;
 545             next;
 546
 547         }
 548
 549
 550         my $rule = {
 551             action => $action,
 552             service => $service,
 553             iface => $iface,
 554             source => $source,
 555             dest => $dest,
 556             nbsource => $nbsource,
 557             nbdest => $nbdest,
 558             proto => $proto,
 559             dport => $dport,
 560             sport => $sport,
 561             nbdport => $nbdport,
 562             nbsport => $nbsport,
 563
 564         };
 565
 566         push @{$res->{$section}}, $rule;
 567     }
 568
 569     die "security group $group don't exist" if $group && !$securitygroupexist;
 570     return $res;
 571 }
 572
 573 sub run_locked {
 574     my ($code, @param) = @_;
 575
 576     my $timeout = 10;
 577
 578     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
 579
 580     die $@ if $@;
 581
 582     return $res;
 583 }
 584
 585 sub read_local_vm_config {
 586
 587     my $openvz = {};
 588
 589     my $qemu = {};
 590
 591     my $list = PVE::QemuServer::config_list();
 592
 593     foreach my $vmid (keys %$list) {
 594         my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
 595         if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
 596             $qemu->{$vmid} = $conf;
 597         }
 598     }
 599
 600     my $vmdata = { openvz => $openvz, qemu => $qemu };
 601
 602     return $vmdata;
 603 };
 604
 605 sub read_vm_firewall_rules {
 606     my ($vmdata) = @_;
 607     my $rules = {};
 608     foreach my $vmid (keys %{$vmdata->{qemu}}, keys %{$vmdata->{openvz}}) {
 609         my $filename = "/etc/pve/firewall/$vmid.fw";
 610         my $fh = IO::File->new($filename, O_RDONLY);
 611         next if !$fh;
 612
 613         $rules->{$vmid} = parse_fw_rules($filename, $fh);
 614     }
 615
 616     return $rules;
 617 }
 618
 619 sub compile {
 620     my $vmdata = read_local_vm_config();
 621     my $rules = read_vm_firewall_rules($vmdata);
 622
 623     #print Dumper($rules);
 624
 625     my $ruleset = {};
 626
 627     # setup host firewall rules
 628     ruleset_create_chain($ruleset, "PVEFW-INPUT");
 629     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
 630
 631     ruleset_create_chain($ruleset, "PVEFW-SET-ACCEPT-MARK");
 632     ruleset_addrule($ruleset, "PVEFW-SET-ACCEPT-MARK", "-j MARK --set-mark 1");
 633
 634     enablehostfw($ruleset);
 635
 636     # generate firewall rules for QEMU VMs
 637     foreach my $vmid (keys %{$vmdata->{qemu}}) {
 638         my $conf = $vmdata->{qemu}->{$vmid};
 639         next if !$rules->{$vmid};
 640
 641         foreach my $netid (keys %$conf) {
 642             next if $netid !~ m/^net(\d+)$/;
 643             my $net = PVE::QemuServer::parse_net($conf->{$netid});
 644             next if !$net;
 645             my $iface = "tap${vmid}i$1";
 646
 647             my $bridge = $net->{bridge};
 648             next if !$bridge; # fixme: ?
 649
 650             $bridge .= "v$net->{tag}" if $net->{tag};
 651
 652             generate_bridge_chains($ruleset, $bridge);
 653
 654             my $macaddr = $net->{macaddr};
 655             generate_tap_rules_direction($ruleset, $iface, $netid, $macaddr, $rules->{$vmid}->{in}, $bridge, 'IN');
 656             generate_tap_rules_direction($ruleset, $iface, $netid, $macaddr, $rules->{$vmid}->{out}, $bridge, 'OUT');
 657         }
 658     }
 659     return $ruleset;
 660 }
 661
 662 sub get_ruleset_status {
 663     my ($ruleset, $verbose) = @_;
 664
 665     my $active_chains = iptables_get_chains();
 666
 667     my $statushash = {};
 668
 669     foreach my $chain (sort keys %$ruleset) {
 670         my $digest = Digest::SHA->new('sha1');
 671         foreach my $cmd (@{$ruleset->{$chain}}) {
 672              $digest->add("$cmd\n");
 673         }
 674         my $sig = $digest->b64digest;
 675         $statushash->{$chain}->{sig} = $sig;
 676
 677         my $oldsig = $active_chains->{$chain};
 678         if (!defined($oldsig)) {
 679             $statushash->{$chain}->{action} = 'create';
 680         } else {
 681             if ($oldsig eq $sig) {
 682                 $statushash->{$chain}->{action} = 'exists';
 683             } else {
 684                 $statushash->{$chain}->{action} = 'update';
 685             }
 686         }
 687         print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
 688         foreach my $cmd (@{$ruleset->{$chain}}) {
 689             print "\t$cmd\n" if $verbose;
 690         }
 691     }
 692
 693     foreach my $chain (sort keys %$active_chains) {
 694         if (!defined($ruleset->{$chain})) {
 695             my $sig = $active_chains->{$chain};
 696             $statushash->{$chain}->{action} = 'delete';
 697             $statushash->{$chain}->{sig} = $sig;
 698             print "delete $chain ($sig)\n" if $verbose;
 699         }
 700     }
 701
 702     return $statushash;
 703 }
 704
 705 sub print_ruleset {
 706     my ($ruleset) = @_;
 707
 708     get_ruleset_status($ruleset, 1);
 709 }
 710
 711 sub print_sig_rule {
 712     my ($chain, $sig) = @_;
 713
 714     # We just use this to store a SHA1 checksum used to detect changes
 715     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
 716 }
 717
 718 sub apply_ruleset {
 719     my ($ruleset, $verbose) = @_;
 720
 721     enable_bridge_firewall();
 722
 723     my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
 724
 725     my $statushash = get_ruleset_status($ruleset, $verbose);
 726
 727     # create missing chains first
 728     foreach my $chain (sort keys %$ruleset) {
 729         my $stat = $statushash->{$chain};
 730         die "internal error" if !$stat;
 731         next if $stat->{action} ne 'create';
 732
 733         $cmdlist .= ":$chain - [0:0]\n";
 734     }
 735
 736     my $rule = "INPUT -j PVEFW-INPUT";
 737     if (!PVE::Firewall::iptables_rule_exist($rule)) {
 738         $cmdlist .= "-A $rule\n";
 739     }
 740     $rule = "OUTPUT -j PVEFW-OUTPUT";
 741     if (!PVE::Firewall::iptables_rule_exist($rule)) {
 742         $cmdlist .= "-A $rule\n";
 743     }
 744
 745     $rule = "FORWARD -j PVEFW-FORWARD";
 746     if (!PVE::Firewall::iptables_rule_exist($rule)) {
 747         $cmdlist .= "-A $rule\n";
 748     }
 749
 750     foreach my $chain (sort keys %$ruleset) {
 751         my $stat = $statushash->{$chain};
 752         die "internal error" if !$stat;
 753
 754         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
 755             $cmdlist .= "-F $chain\n";
 756             foreach my $cmd (@{$ruleset->{$chain}}) {
 757                 $cmdlist .= "$cmd\n";
 758             }
 759             $cmdlist .= print_sig_rule($chain, $stat->{sig});
 760         } elsif ($stat->{action} eq 'delete') {
 761             die "internal error"; # this should not happen
 762         } elsif ($stat->{action} eq 'exists') {
 763             # do nothing
 764         } else {
 765             die "internal error - unknown status '$stat->{action}'";
 766         }
 767     }
 768
 769     foreach my $chain (keys %$statushash) {
 770         next if $statushash->{$chain}->{action} ne 'delete';
 771         $cmdlist .= "-F $chain\n";
 772     }
 773     foreach my $chain (keys %$statushash) {
 774         next if $statushash->{$chain}->{action} ne 'delete';
 775         $cmdlist .= "-X $chain\n";
 776     }
 777
 778     $cmdlist .= "COMMIT\n";
 779
 780     print $cmdlist if $verbose;
 781
 782     iptables_restore_cmdlist($cmdlist);
 783
 784     # test: re-read status and check if everything is up to date
 785     $statushash = get_ruleset_status($ruleset);
 786
 787     my $errors;
 788     foreach my $chain (sort keys %$ruleset) {
 789         my $stat = $statushash->{$chain};
 790         if ($stat->{action} ne 'exists') {
 791             warn "unable to update chain '$chain'\n";
 792             $errors = 1;
 793         }
 794     }
 795
 796     die "unable to apply firewall changes\n" if $errors;
 797 }
 798
 799 1;