enable hostfw for ipv4 only
[pve-firewall.git] / src / PVE / Firewall.pm
1 package PVE::Firewall;
2
3 use warnings;
4 use strict;
5 use POSIX;
6 use Data::Dumper;
7 use Digest::SHA;
8 use PVE::INotify;
9 use PVE::Exception qw(raise raise_param_exc);
10 use PVE::JSONSchema qw(register_standard_option get_standard_option);
11 use PVE::Cluster;
12 use PVE::ProcFSTools;
13 use PVE::Tools qw($IPV4RE);
14 use File::Basename;
15 use File::Path;
16 use IO::File;
17 use Net::IP;
18 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
19 use Encode;
20
21 my $hostfw_conf_filename = "/etc/pve/local/host.fw";
22 my $pvefw_conf_dir = "/etc/pve/firewall";
23 my $clusterfw_conf_filename = "$pvefw_conf_dir/cluster.fw";
24
25 # dynamically include PVE::QemuServer and PVE::OpenVZ
26 # to avoid dependency problems
27 my $have_qemu_server;
28 eval {
29     require PVE::QemuServer;
30     $have_qemu_server = 1;
31 };
32
33 my $have_pve_manager;
34 eval {
35     require PVE::OpenVZ;
36     $have_pve_manager = 1;
37 };
38
39 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
40 my $ipset_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
41 my $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
42
43 my $max_alias_name_length = 64;
44 my $max_ipset_name_length = 64;
45 my $max_group_name_length = 20;
46
47 PVE::JSONSchema::register_format('IPv4orCIDR', \&pve_verify_ipv4_or_cidr);
48 sub pve_verify_ipv4_or_cidr {
49     my ($cidr, $noerr) = @_;
50
51     if ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
52         return $cidr if Net::IP->new($cidr);
53         return undef if $noerr;
54         die Net::IP::Error() . "\n";
55     }
56     return undef if $noerr;
57     die "value does not look like a valid IP address or CIDR network\n";
58 }
59
60 PVE::JSONSchema::register_format('IPv4orCIDRorAlias', \&pve_verify_ipv4_or_cidr_or_alias);
61 sub pve_verify_ipv4_or_cidr_or_alias {
62     my ($cidr, $noerr) = @_;
63
64     return if $cidr =~ m/^(?:$ip_alias_pattern)$/;
65
66     if ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
67         return $cidr if Net::IP->new($cidr);
68         return undef if $noerr;
69         die Net::IP::Error() . "\n";
70     }
71     return undef if $noerr;
72     die "value does not look like a valid IP address or CIDR network\n";
73 }
74
75 PVE::JSONSchema::register_standard_option('ipset-name', {
76     description => "IP set name.",
77     type => 'string',
78     pattern => $ipset_name_pattern,
79     minLength => 2,
80     maxLength => $max_ipset_name_length,
81 });
82
83 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
84     description => "Alias name.",
85     type => 'string',
86     pattern => $ip_alias_pattern,
87     minLength => 2,
88     maxLength => $max_alias_name_length,
89 });
90
91 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
92     description => "Log level.",
93     type => 'string',
94     enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
95     optional => 1,
96 });
97
98 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
99     description => "Security Group name.",
100     type => 'string',
101     pattern => $security_group_name_pattern,
102     minLength => 2,
103     maxLength => $max_group_name_length,
104 });
105
106 my $feature_ipset_nomatch = 0;
107 eval  {
108     my (undef, undef, $release) = POSIX::uname();
109     if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
110         my ($major, $minor) = ($1, $2);
111         $feature_ipset_nomatch = 1 if ($major > 3) ||
112             ($major == 3 && $minor >= 7);
113     }
114
115 };
116
117 use Data::Dumper;
118
119 my $nodename = PVE::INotify::nodename();
120
121 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
122
123 my $default_log_level = 'nolog'; # avoid logs by default
124
125 my $log_level_hash = {
126     debug => 7,
127     info => 6,
128     notice => 5,
129     warning => 4,
130     err => 3,
131     crit => 2,
132     alert => 1,
133     emerg => 0,
134 };
135
136 # imported/converted from: /usr/share/shorewall/macro.*
137 my $pve_fw_macros = {
138     'Amanda' => [
139         "Amanda Backup",
140         { action => 'PARAM', proto => 'udp', dport => '10080' },
141         { action => 'PARAM', proto => 'tcp', dport => '10080' },
142     ],
143     'Auth' => [
144         "Auth (identd) traffic",
145         { action => 'PARAM', proto => 'tcp', dport => '113' },
146     ],
147     'BGP' => [
148         "Border Gateway Protocol traffic",
149         { action => 'PARAM', proto => 'tcp', dport => '179' },
150     ],
151     'BitTorrent' => [
152         "BitTorrent traffic for BitTorrent 3.1 and earlier",
153         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
154         { action => 'PARAM', proto => 'udp', dport => '6881' },
155     ],
156     'BitTorrent32' => [
157         "BitTorrent traffic for BitTorrent 3.2 and later",
158         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
159         { action => 'PARAM', proto => 'udp', dport => '6881' },
160     ],
161     'CVS' => [
162         "Concurrent Versions System pserver traffic",
163         { action => 'PARAM', proto => 'tcp', dport => '2401' },
164     ],
165     'Citrix' => [
166         "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
167         { action => 'PARAM', proto => 'tcp', dport => '1494' },
168         { action => 'PARAM', proto => 'udp', dport => '1604' },
169         { action => 'PARAM', proto => 'tcp', dport => '2598' },
170     ],
171     'DAAP' => [
172         "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
173         { action => 'PARAM', proto => 'tcp', dport => '3689' },
174         { action => 'PARAM', proto => 'udp', dport => '3689' },
175     ],
176     'DCC' => [
177         "Distributed Checksum Clearinghouse spam filtering mechanism",
178         { action => 'PARAM', proto => 'tcp', dport => '6277' },
179     ],
180     'DHCPfwd' => [
181         "Forwarded DHCP traffic",
182         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
183     ],
184     'DNS' => [
185         "Domain Name System traffic (upd and tcp)",
186         { action => 'PARAM', proto => 'udp', dport => '53' },
187         { action => 'PARAM', proto => 'tcp', dport => '53' },
188     ],
189     'Distcc' => [
190         "Distributed Compiler service",
191         { action => 'PARAM', proto => 'tcp', dport => '3632' },
192     ],
193     'FTP' => [
194         "File Transfer Protocol",
195         { action => 'PARAM', proto => 'tcp', dport => '21' },
196     ],
197     'Finger' => [
198         "Finger protocol (RFC 742)",
199         { action => 'PARAM', proto => 'tcp', dport => '79' },
200     ],
201     'GNUnet' => [
202         "GNUnet secure peer-to-peer networking traffic",
203         { action => 'PARAM', proto => 'tcp', dport => '2086' },
204         { action => 'PARAM', proto => 'udp', dport => '2086' },
205         { action => 'PARAM', proto => 'tcp', dport => '1080' },
206         { action => 'PARAM', proto => 'udp', dport => '1080' },
207     ],
208     'GRE' => [
209         "Generic Routing Encapsulation tunneling protocol",
210         { action => 'PARAM', proto => '47' },
211     ],
212     'Git' => [
213         "Git distributed revision control traffic",
214         { action => 'PARAM', proto => 'tcp', dport => '9418' },
215     ],
216     'HKP' => [
217         "OpenPGP HTTP keyserver protocol traffic",
218         { action => 'PARAM', proto => 'tcp', dport => '11371' },
219     ],
220     'HTTP' => [
221         "Hypertext Transfer Protocol (WWW)",
222         { action => 'PARAM', proto => 'tcp', dport => '80' },
223     ],
224     'HTTPS' => [
225         "Hypertext Transfer Protocol (WWW) over SSL",
226         { action => 'PARAM', proto => 'tcp', dport => '443' },
227     ],
228     'ICPV2' => [
229         "Internet Cache Protocol V2 (Squid) traffic",
230         { action => 'PARAM', proto => 'udp', dport => '3130' },
231     ],
232     'ICQ' => [
233         "AOL Instant Messenger traffic",
234         { action => 'PARAM', proto => 'tcp', dport => '5190' },
235     ],
236     'IMAP' => [
237         "Internet Message Access Protocol",
238         { action => 'PARAM', proto => 'tcp', dport => '143' },
239     ],
240     'IMAPS' => [
241         "Internet Message Access Protocol over SSL",
242         { action => 'PARAM', proto => 'tcp', dport => '993' },
243     ],
244     'IPIP' => [
245         "IPIP capsulation traffic",
246         { action => 'PARAM', proto => '94' },
247     ],
248     'IPsec' => [
249         "IPsec traffic",
250         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
251         { action => 'PARAM', proto => '50' },
252     ],
253     'IPsecah' => [
254         "IPsec authentication (AH) traffic",
255         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
256         { action => 'PARAM', proto => '51' },
257     ],
258     'IPsecnat' => [
259         "IPsec traffic and Nat-Traversal",
260         { action => 'PARAM', proto => 'udp', dport => '500' },
261         { action => 'PARAM', proto => 'udp', dport => '4500' },
262         { action => 'PARAM', proto => '50' },
263     ],
264     'IRC' => [
265         "Internet Relay Chat traffic",
266         { action => 'PARAM', proto => 'tcp', dport => '6667' },
267     ],
268     'Jetdirect' => [
269         "HP Jetdirect printing",
270         { action => 'PARAM', proto => 'tcp', dport => '9100' },
271     ],
272     'L2TP' => [
273         "Layer 2 Tunneling Protocol traffic",
274         { action => 'PARAM', proto => 'udp', dport => '1701' },
275     ],
276     'LDAP' => [
277         "Lightweight Directory Access Protocol traffic",
278         { action => 'PARAM', proto => 'tcp', dport => '389' },
279     ],
280     'LDAPS' => [
281         "Secure Lightweight Directory Access Protocol traffic",
282         { action => 'PARAM', proto => 'tcp', dport => '636' },
283     ],
284     'MSNP' => [
285         "Microsoft Notification Protocol",
286         { action => 'PARAM', proto => 'tcp', dport => '1863' },
287     ],
288     'MSSQL' => [
289         "Microsoft SQL Server",
290         { action => 'PARAM', proto => 'tcp', dport => '1433' },
291     ],
292     'Mail' => [
293         "Mail traffic (SMTP, SMTPS, Submission)",
294         { action => 'PARAM', proto => 'tcp', dport => '25' },
295         { action => 'PARAM', proto => 'tcp', dport => '465' },
296         { action => 'PARAM', proto => 'tcp', dport => '587' },
297     ],
298     'Munin' => [
299         "Munin networked resource monitoring traffic",
300         { action => 'PARAM', proto => 'tcp', dport => '4949' },
301     ],
302     'MySQL' => [
303         "MySQL server",
304         { action => 'PARAM', proto => 'tcp', dport => '3306' },
305     ],
306     'NNTP' => [
307         "NNTP traffic (Usenet).",
308         { action => 'PARAM', proto => 'tcp', dport => '119' },
309     ],
310     'NNTPS' => [
311         "Encrypted NNTP traffic (Usenet)",
312         { action => 'PARAM', proto => 'tcp', dport => '563' },
313     ],
314     'NTP' => [
315         "Network Time Protocol (ntpd)",
316         { action => 'PARAM', proto => 'udp', dport => '123' },
317     ],
318     'OSPF' => [
319         "OSPF multicast traffic",
320         { action => 'PARAM', proto => '89' },
321     ],
322     'OpenVPN' => [
323         "OpenVPN traffic",
324         { action => 'PARAM', proto => 'udp', dport => '1194' },
325     ],
326     'PCA' => [
327         "Symantec PCAnywere (tm)",
328         { action => 'PARAM', proto => 'udp', dport => '5632' },
329         { action => 'PARAM', proto => 'tcp', dport => '5631' },
330     ],
331     'POP3' => [
332         "POP3 traffic",
333         { action => 'PARAM', proto => 'tcp', dport => '110' },
334     ],
335     'POP3S' => [
336         "Encrypted POP3 traffic",
337         { action => 'PARAM', proto => 'tcp', dport => '995' },
338     ],
339     'PPtP' => [
340         "Point-to-Point Tunneling Protocol",
341         { action => 'PARAM', proto => '47' },
342         { action => 'PARAM', proto => 'tcp', dport => '1723' },
343     ],
344     'Ping' => [
345         "ICMP echo request",
346         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
347     ],
348     'PostgreSQL' => [
349         "PostgreSQL server",
350         { action => 'PARAM', proto => 'tcp', dport => '5432' },
351     ],
352     'Printer' => [
353         "Line Printer protocol printing",
354         { action => 'PARAM', proto => 'tcp', dport => '515' },
355     ],
356     'RDP' => [
357         "Microsoft Remote Desktop Protocol traffic",
358         { action => 'PARAM', proto => 'tcp', dport => '3389' },
359     ],
360     'RIP' => [
361         "Routing Information Protocol (bidirectional)",
362         { action => 'PARAM', proto => 'udp', dport => '520' },
363     ],
364     'RNDC' => [
365         "BIND remote management protocol",
366         { action => 'PARAM', proto => 'tcp', dport => '953' },
367     ],
368     'Razor' => [
369         "Razor Antispam System",
370         { action => 'ACCEPT', proto => 'tcp', dport => '2703' },
371     ],
372     'Rdate' => [
373         "Remote time retrieval (rdate)",
374         { action => 'PARAM', proto => 'tcp', dport => '37' },
375     ],
376     'Rsync' => [
377         "Rsync server",
378         { action => 'PARAM', proto => 'tcp', dport => '873' },
379     ],
380     'SANE' => [
381         "SANE network scanning",
382         { action => 'PARAM', proto => 'tcp', dport => '6566' },
383     ],
384     'SMB' => [
385         "Microsoft SMB traffic",
386         { action => 'PARAM', proto => 'udp', dport => '135,445' },
387         { action => 'PARAM', proto => 'udp', dport => '137:139' },
388         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
389         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
390     ],
391     'SMBswat' => [
392         "Samba Web Administration Tool",
393         { action => 'PARAM', proto => 'tcp', dport => '901' },
394     ],
395     'SMTP' => [
396         "Simple Mail Transfer Protocol",
397         { action => 'PARAM', proto => 'tcp', dport => '25' },
398     ],
399     'SMTPS' => [
400         "Encrypted Simple Mail Transfer Protocol",
401         { action => 'PARAM', proto => 'tcp', dport => '465' },
402     ],
403     'SNMP' => [
404         "Simple Network Management Protocol",
405         { action => 'PARAM', proto => 'udp', dport => '161:162' },
406         { action => 'PARAM', proto => 'tcp', dport => '161' },
407     ],
408     'SPAMD' => [
409         "Spam Assassin SPAMD traffic",
410         { action => 'PARAM', proto => 'tcp', dport => '783' },
411     ],
412     'SSH' => [
413         "Secure shell traffic",
414         { action => 'PARAM', proto => 'tcp', dport => '22' },
415     ],
416     'SVN' => [
417         "Subversion server (svnserve)",
418         { action => 'PARAM', proto => 'tcp', dport => '3690' },
419     ],
420     'SixXS' => [
421         "SixXS IPv6 Deployment and Tunnel Broker",
422         { action => 'PARAM', proto => 'tcp', dport => '3874' },
423         { action => 'PARAM', proto => 'udp', dport => '3740' },
424         { action => 'PARAM', proto => '41' },
425         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
426     ],
427     'Squid' => [
428         "Squid web proxy traffic",
429         { action => 'PARAM', proto => 'tcp', dport => '3128' },
430     ],
431     'Submission' => [
432         "Mail message submission traffic",
433         { action => 'PARAM', proto => 'tcp', dport => '587' },
434     ],
435     'Syslog' => [
436         "Syslog protocol (RFC 5424) traffic",
437         { action => 'PARAM', proto => 'udp', dport => '514' },
438         { action => 'PARAM', proto => 'tcp', dport => '514' },
439     ],
440     'TFTP' => [
441         "Trivial File Transfer Protocol traffic",
442         { action => 'PARAM', proto => 'udp', dport => '69' },
443     ],
444     'Telnet' => [
445         "Telnet traffic",
446         { action => 'PARAM', proto => 'tcp', dport => '23' },
447     ],
448     'Telnets' => [
449         "Telnet over SSL",
450         { action => 'PARAM', proto => 'tcp', dport => '992' },
451     ],
452     'Time' => [
453         "RFC 868 Time protocol",
454         { action => 'PARAM', proto => 'tcp', dport => '37' },
455     ],
456     'Trcrt' => [
457         "Traceroute (for up to 30 hops) traffic",
458         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
459         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
460     ],
461     'VNC' => [
462         "VNC traffic for VNC display's 0 - 99",
463         { action => 'PARAM', proto => 'tcp', dport => '5900:5999' },
464     ],
465     'VNCL' => [
466         "VNC traffic from Vncservers to Vncviewers in listen mode",
467         { action => 'PARAM', proto => 'tcp', dport => '5500' },
468     ],
469     'Web' => [
470         "WWW traffic (HTTP and HTTPS)",
471         { action => 'PARAM', proto => 'tcp', dport => '80' },
472         { action => 'PARAM', proto => 'tcp', dport => '443' },
473     ],
474     'Webcache' => [
475         "Web Cache/Proxy traffic (port 8080)",
476         { action => 'PARAM', proto => 'tcp', dport => '8080' },
477     ],
478     'Webmin' => [
479         "Webmin traffic",
480         { action => 'PARAM', proto => 'tcp', dport => '10000' },
481     ],
482     'Whois' => [
483         "Whois (nicname, RFC 3912) traffic",
484         { action => 'PARAM', proto => 'tcp', dport => '43' },
485     ],
486 };
487
488 my $pve_fw_parsed_macros;
489 my $pve_fw_macro_descr;
490 my $pve_fw_preferred_macro_names = {};
491
492 my $pve_std_chains = {};
493 $pve_std_chains->{4} = {
494     'PVEFW-SET-ACCEPT-MARK' => [
495         "-j MARK --set-mark 1",
496     ],
497     'PVEFW-DropBroadcast' => [
498         # same as shorewall 'Broadcast'
499         # simply DROP BROADCAST/MULTICAST/ANYCAST
500         # we can use this to reduce logging
501         { action => 'DROP', dsttype => 'BROADCAST' },
502         { action => 'DROP', dsttype => 'MULTICAST' },
503         { action => 'DROP', dsttype => 'ANYCAST' },
504         { action => 'DROP', dest => '224.0.0.0/4' },
505     ],
506     'PVEFW-reject' => [
507         # same as shorewall 'reject'
508         { action => 'DROP', dsttype => 'BROADCAST' },
509         { action => 'DROP', source => '224.0.0.0/4' },
510         { action => 'DROP', proto => 'icmp' },
511         "-p tcp -j REJECT --reject-with tcp-reset",
512         "-p udp -j REJECT --reject-with icmp-port-unreachable",
513         "-p icmp -j REJECT --reject-with icmp-host-unreachable",
514         "-j REJECT --reject-with icmp-host-prohibited",
515     ],
516     'PVEFW-Drop' => [
517         # same as shorewall 'Drop', which is equal to DROP,
518         # but REJECT/DROP some packages to reduce logging,
519         # and ACCEPT critical ICMP types
520         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
521         # we are not interested in BROADCAST/MULTICAST/ANYCAST
522         { action => 'PVEFW-DropBroadcast' },
523         # ACCEPT critical ICMP types
524         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
525         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
526         # Drop packets with INVALID state
527         "-m conntrack --ctstate INVALID -j DROP",
528         # Drop Microsoft SMB noise
529         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
530         { action => 'DROP', proto => 'udp', dport => '137:139'},
531         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
532         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
533         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
534         # Drop new/NotSyn traffic so that it doesn't get logged
535         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
536         # Drop DNS replies
537         { action => 'DROP', proto => 'udp', sport => 53 },
538     ],
539     'PVEFW-Reject' => [
540         # same as shorewall 'Reject', which is equal to Reject,
541         # but REJECT/DROP some packages to reduce logging,
542         # and ACCEPT critical ICMP types
543         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
544         # we are not interested in BROADCAST/MULTICAST/ANYCAST
545         { action => 'PVEFW-DropBroadcast' },
546         # ACCEPT critical ICMP types
547         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
548         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
549         # Drop packets with INVALID state
550         "-m conntrack --ctstate INVALID -j DROP",
551         # Drop Microsoft SMB noise
552         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
553         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
554         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
555         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
556         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
557         # Drop new/NotSyn traffic so that it doesn't get logged
558         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
559         # Drop DNS replies
560         { action => 'DROP', proto => 'udp', sport => 53 },
561     ],
562     'PVEFW-tcpflags' => [
563         # same as shorewall tcpflags action.
564         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
565         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
566         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
567         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
568         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
569         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
570     ],
571     'PVEFW-smurfs' => [
572         # same as shorewall smurfs action
573         # Filter packets for smurfs (packets with a broadcast address as the source).
574         "-s 0.0.0.0/32 -j RETURN",
575         "-m addrtype --src-type BROADCAST -g PVEFW-smurflog",
576         "-s 224.0.0.0/4 -g PVEFW-smurflog",
577     ],
578 };
579
580 # iptables -p icmp -h
581 my $icmp_type_names = {
582     any => 1,
583     'echo-reply' => 1,
584     'destination-unreachable' => 1,
585     'network-unreachable' => 1,
586     'host-unreachable' => 1,
587     'protocol-unreachable' => 1,
588     'port-unreachable' => 1,
589     'fragmentation-needed' => 1,
590     'source-route-failed' => 1,
591     'network-unknown' => 1,
592     'host-unknown' => 1,
593     'network-prohibited' => 1,
594     'host-prohibited' => 1,
595     'TOS-network-unreachable' => 1,
596     'TOS-host-unreachable' => 1,
597     'communication-prohibited' => 1,
598     'host-precedence-violation' => 1,
599     'precedence-cutoff' => 1,
600     'source-quench' => 1,
601     'redirect' => 1,
602     'network-redirect' => 1,
603     'host-redirect' => 1,
604     'TOS-network-redirect' => 1,
605     'TOS-host-redirect' => 1,
606     'echo-request' => 1,
607     'router-advertisement' => 1,
608     'router-solicitation' => 1,
609     'time-exceeded' => 1,
610     'ttl-zero-during-transit' => 1,
611     'ttl-zero-during-reassembly' => 1,
612     'parameter-problem' => 1,
613     'ip-header-bad' => 1,
614     'required-option-missing' => 1,
615     'timestamp-request' => 1,
616     'timestamp-reply' => 1,
617     'address-mask-request' => 1,
618     'address-mask-reply' => 1,
619 };
620
621 sub init_firewall_macros {
622
623     $pve_fw_parsed_macros = {};
624
625     foreach my $k (keys %$pve_fw_macros) {
626         my $lc_name = lc($k);
627         my $macro = $pve_fw_macros->{$k};
628         if (!ref($macro->[0])) {
629             $pve_fw_macro_descr->{$k} = shift @$macro;
630         }
631         $pve_fw_preferred_macro_names->{$lc_name} = $k;
632         $pve_fw_parsed_macros->{$k} = $macro;
633     }
634 }
635
636 init_firewall_macros();
637
638 sub get_macros {
639     return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
640 }
641
642 my $etc_services;
643
644 sub get_etc_services {
645
646     return $etc_services if $etc_services;
647
648     my $filename = "/etc/services";
649
650     my $fh = IO::File->new($filename, O_RDONLY);
651     if (!$fh) {
652         warn "unable to read '$filename' - $!\n";
653         return {};
654     }
655
656     my $services = {};
657
658     while (my $line = <$fh>) {
659         chomp ($line);
660         next if $line =~m/^#/;
661         next if ($line =~m/^\s*$/);
662
663         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
664             $services->{byid}->{$2}->{name} = $1;
665             $services->{byid}->{$2}->{port} = $2;
666             $services->{byid}->{$2}->{$3} = 1;
667             $services->{byname}->{$1} = $services->{byid}->{$2};
668         }
669     }
670
671     close($fh);
672
673     $etc_services = $services;
674
675
676     return $etc_services;
677 }
678
679 my $etc_protocols;
680
681 sub get_etc_protocols {
682     return $etc_protocols if $etc_protocols;
683
684     my $filename = "/etc/protocols";
685
686     my $fh = IO::File->new($filename, O_RDONLY);
687     if (!$fh) {
688         warn "unable to read '$filename' - $!\n";
689         return {};
690     }
691
692     my $protocols = {};
693
694     while (my $line = <$fh>) {
695         chomp ($line);
696         next if $line =~m/^#/;
697         next if ($line =~m/^\s*$/);
698
699         if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
700             $protocols->{byid}->{$2}->{name} = $1;
701             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
702         }
703     }
704
705     close($fh);
706
707     $etc_protocols = $protocols;
708
709     return $etc_protocols;
710 }
711
712 my $ipv4_mask_hash_localnet = {
713     '255.255.0.0' => 16,
714     '255.255.128.0' => 17,
715     '255.255.192.0' => 18,
716     '255.255.224.0' => 19,
717     '255.255.240.0' => 20,
718     '255.255.248.0' => 21,
719     '255.255.252.0' => 22,
720     '255.255.254.0' => 23,
721     '255.255.255.0' => 24,
722     '255.255.255.128' => 25,
723     '255.255.255.192' => 26,
724     '255.255.255.224' => 27,
725     '255.255.255.240' => 28,
726     '255.255.255.248' => 29,
727     '255.255.255.252' => 30,
728 };
729
730 my $__local_network;
731
732 sub local_network {
733     my ($new_value) = @_;
734
735     $__local_network = $new_value if defined($new_value);
736
737     return $__local_network if defined($__local_network);
738
739     eval {
740         my $nodename = PVE::INotify::nodename();
741
742         my $ip = PVE::Cluster::remote_node_ip($nodename);
743
744         my $testip = Net::IP->new($ip);
745
746         my $routes = PVE::ProcFSTools::read_proc_net_route();
747         foreach my $entry (@$routes) {
748             my $mask = $ipv4_mask_hash_localnet->{$entry->{mask}};
749             next if !defined($mask);
750             return if $mask eq '0.0.0.0';
751             my $cidr = "$entry->{dest}/$mask";
752             my $testnet = Net::IP->new($cidr);
753             if ($testnet->overlaps($testip)) {
754                 $__local_network = $cidr;
755                 return;
756             }
757         }
758     };
759     warn $@ if $@;
760
761     return $__local_network;
762 }
763
764 # ipset names are limited to 31 characters, and we use '_swap' 
765 # suffix for atomic update, for example PVEFW-${VMID}-${ipset_name}_swap
766
767 my $max_iptables_ipset_name_length = 31 - length("_swap");
768
769 sub compute_ipset_chain_name {
770     my ($vmid, $ipset_name) = @_;
771
772     $vmid = 0 if !defined($vmid);
773
774     my $id = "$vmid-${ipset_name}";
775
776    
777     if ((length($id) + 6) > $max_iptables_ipset_name_length) {
778         $id = PVE::Tools::fnv31a_hex($id);
779     }
780
781     return "PVEFW-$id";
782 }
783
784 sub compute_ipfilter_ipset_name {
785     my ($iface) = @_;
786
787     return "ipfilter-$iface";
788 }
789
790 sub parse_address_list {
791     my ($str) = @_;
792
793     if ($str =~ m/^(\+)(\S+)$/) { # ipset ref
794         die "ipset name too long\n" if length($str) > ($max_ipset_name_length + 1);
795         return;
796     }
797
798     if ($str =~ m/^${ip_alias_pattern}$/) {
799         die "alias name too long\n" if length($str) > $max_alias_name_length;
800         return;
801     }
802
803     my $count = 0;
804     my $iprange = 0;
805     my $ipversion;
806
807     foreach my $elem (split(/,/, $str)) {
808         $count++;
809         my $ip = Net::IP->new($elem);
810         if (!$ip) {
811             my $err = Net::IP::Error();
812             die "invalid IP address: $err\n";
813         }
814         $iprange = 1 if $elem =~ m/-/;
815
816         my $new_ipversion = Net::IP::ip_is_ipv6($ip->ip()) ? 6 : 4;
817
818         die "detected mixed ipv4/ipv6 addresses in address list '$str'\n"
819             if $ipversion && ($new_ipversion != $ipversion);
820
821         $ipversion = $new_ipversion;
822     }
823
824     die "you can't use a range in a list\n" if $iprange && $count > 1;
825
826     return $ipversion;
827 }
828
829 sub parse_port_name_number_or_range {
830     my ($str) = @_;
831
832     my $services = PVE::Firewall::get_etc_services();
833     my $count = 0;
834     my $icmp_port = 0;
835
836     foreach my $item (split(/,/, $str)) {
837         $count++;
838         if ($item =~ m/^(\d+):(\d+)$/) {
839             my ($port1, $port2) = ($1, $2);
840             die "invalid port '$port1'\n" if $port1 > 65535;
841             die "invalid port '$port2'\n" if $port2 > 65535;
842         } elsif ($item =~ m/^(\d+)$/) {
843             my $port = $1;
844             die "invalid port '$port'\n" if $port > 65535;
845         } else {
846             if ($icmp_type_names->{$item}) {
847                 $icmp_port = 1;
848             } else {
849                 die "invalid port '$item'\n" if !$services->{byname}->{$item};
850             }
851         }
852     }
853
854     die "ICPM ports not allowed in port range\n" if $icmp_port && $count > 1;
855
856     return $count;
857 }
858
859 PVE::JSONSchema::register_format('pve-fw-port-spec', \&pve_fw_verify_port_spec);
860 sub pve_fw_verify_port_spec {
861    my ($portstr) = @_;
862
863    parse_port_name_number_or_range($portstr);
864
865    return $portstr;
866 }
867
868 PVE::JSONSchema::register_format('pve-fw-addr-spec', \&pve_fw_verify_addr_spec);
869 sub pve_fw_verify_addr_spec {
870    my ($list) = @_;
871
872    parse_address_list($list);
873
874    return $list;
875 }
876
877 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
878 sub pve_fw_verify_protocol_spec {
879    my ($proto) = @_;
880
881    my $protocols = get_etc_protocols();
882
883    die "unknown protocol '$proto'\n" if $proto &&
884        !(defined($protocols->{byname}->{$proto}) ||
885          defined($protocols->{byid}->{$proto}));
886
887    return $proto;
888 }
889
890
891 # helper function for API
892
893 sub copy_opject_with_digest {
894     my ($object) = @_;
895
896     my $sha = Digest::SHA->new('sha1');
897
898     my $res = {};
899     foreach my $k (sort keys %$object) {
900         my $v = $object->{$k};
901         next if !defined($v);
902         $res->{$k} = $v;
903         $sha->add($k, ':', $v, "\n");
904     }
905
906     my $digest = $sha->hexdigest;
907
908     $res->{digest} = $digest;
909
910     return wantarray ? ($res, $digest) : $res;
911 }
912
913 sub copy_list_with_digest {
914     my ($list) = @_;
915
916     my $sha = Digest::SHA->new('sha1');
917
918     my $res = [];
919     foreach my $entry (@$list) {
920         my $data = {};
921         foreach my $k (sort keys %$entry) {
922             my $v = $entry->{$k};
923             next if !defined($v);
924             $data->{$k} = $v;
925             # Note: digest ignores refs ($rule->{errors})
926             $sha->add($k, ':', $v, "\n") if !ref($v); ;
927         }
928         push @$res, $data;
929     }
930
931     my $digest = $sha->hexdigest;
932
933     foreach my $entry (@$res) {
934         $entry->{digest} = $digest;
935     }
936
937     return wantarray ? ($res, $digest) : $res;
938 }
939
940 my $rule_properties = {
941     pos => {
942         description => "Update rule at position <pos>.",
943         type => 'integer',
944         minimum => 0,
945         optional => 1,
946     },
947     digest => get_standard_option('pve-config-digest'),
948     type => {
949         type => 'string',
950         optional => 1,
951         enum => ['in', 'out', 'group'],
952     },
953     action => {
954         description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
955         type => 'string',
956         optional => 1,
957         pattern => $security_group_name_pattern,
958         maxLength => 20,
959         minLength => 2,
960     },
961     macro => {
962         type => 'string',
963         optional => 1,
964         maxLength => 128,
965     },
966     iface => get_standard_option('pve-iface', { optional => 1 }),
967     source => {
968         type => 'string', format => 'pve-fw-addr-spec',
969         optional => 1,
970     },
971     dest => {
972         type => 'string', format => 'pve-fw-addr-spec',
973         optional => 1,
974     },
975     proto => {
976         type => 'string', format => 'pve-fw-protocol-spec',
977         optional => 1,
978     },
979     enable => {
980         type => 'boolean',
981         optional => 1,
982     },
983     sport => {
984         type => 'string', format => 'pve-fw-port-spec',
985         optional => 1,
986     },
987     dport => {
988         type => 'string', format => 'pve-fw-port-spec',
989         optional => 1,
990     },
991     comment => {
992         type => 'string',
993         optional => 1,
994     },
995 };
996
997 sub add_rule_properties {
998     my ($properties) = @_;
999
1000     foreach my $k (keys %$rule_properties) {
1001         my $h = $rule_properties->{$k};
1002         # copy data, so that we can modify later without side effects
1003         foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
1004     }
1005
1006     return $properties;
1007 }
1008
1009 sub delete_rule_properties {
1010     my ($rule, $delete_str) = @_;
1011
1012     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1013         raise_param_exc({ 'delete' => "no such property ('$opt')"})
1014             if !defined($rule_properties->{$opt});
1015         raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
1016             if $opt eq 'type' || $opt eq 'action';
1017         delete $rule->{$opt};
1018     }
1019
1020     return $rule;
1021 }
1022
1023 my $apply_macro = sub {
1024     my ($macro_name, $param, $verify) = @_;
1025
1026     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1027     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1028
1029     my $rules = [];
1030
1031     foreach my $templ (@$macro_rules) {
1032         my $rule = {};
1033         my $param_used = {};
1034         foreach my $k (keys %$templ) {
1035             my $v = $templ->{$k};
1036             if ($v eq 'PARAM') {
1037                 $v = $param->{$k};
1038                 $param_used->{$k} = 1;
1039             } elsif ($v eq 'DEST') {
1040                 $v = $param->{dest};
1041                 $param_used->{dest} = 1;
1042             } elsif ($v eq 'SOURCE') {
1043                 $v = $param->{source};
1044                 $param_used->{source} = 1;
1045             }
1046
1047             if (!defined($v)) {
1048                 my $msg = "missing parameter '$k' in macro '$macro_name'";
1049                 raise_param_exc({ macro => $msg }) if $verify;
1050                 die "$msg\n";
1051             }
1052             $rule->{$k} = $v;
1053         }
1054         foreach my $k (keys %$param) {
1055             next if $k eq 'macro';
1056             next if !defined($param->{$k});
1057             next if $param_used->{$k};
1058             if (defined($rule->{$k})) {
1059                 if ($rule->{$k} ne $param->{$k}) {
1060                     my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
1061                     raise_param_exc({ $k => $msg }) if $verify;
1062                     die "$msg\n";
1063                 }
1064             } else {
1065                 $rule->{$k} = $param->{$k};
1066             }
1067         }
1068         push @$rules, $rule;
1069     }
1070
1071     return $rules;
1072 };
1073
1074 my $rule_env_iface_lookup = {
1075     'ct' => 1,
1076     'vm' => 1,
1077     'group' => 0,
1078     'cluster' => 1,
1079     'host' => 1,
1080 };
1081
1082 sub verify_rule {
1083     my ($rule, $cluster_conf, $fw_conf, $rule_env, $noerr) = @_;
1084
1085     my $allow_groups = $rule_env eq 'group' ? 0 : 1;
1086
1087     my $allow_iface = $rule_env_iface_lookup->{$rule_env};
1088     die "unknown rule_env '$rule_env'\n" if !defined($allow_iface); # should not happen
1089
1090     my $errors = $rule->{errors} || {};
1091
1092     my $error_count = 0;
1093
1094     my $add_error = sub {
1095         my ($param, $msg)  = @_;
1096         chomp $msg;
1097         raise_param_exc({ $param => $msg }) if !$noerr;
1098         $error_count++;
1099         $errors->{$param} = $msg if !$errors->{$param};
1100     };
1101
1102     my $check_ipset_or_alias_property = sub {
1103         my ($name) = @_;
1104
1105         if (my $value = $rule->{$name}) {
1106             if ($value =~ m/^\+/) {
1107                 if ($value =~ m/^\+(${ipset_name_pattern})$/) {
1108                     &$add_error($name, "no such ipset '$1'")
1109                         if !($cluster_conf->{ipset}->{$1} || ($fw_conf && $fw_conf->{ipset}->{$1}));
1110
1111                 } else {
1112                     &$add_error($name, "invalid ipset name '$value'");
1113                 }
1114             } elsif ($value =~ m/^${ip_alias_pattern}$/){
1115                 my $alias = lc($value);
1116                 &$add_error($name, "no such alias '$value'")
1117                     if !($cluster_conf->{aliases}->{$alias} || ($fw_conf && $fw_conf->{aliases}->{$alias}))
1118             }
1119         }
1120     };
1121
1122     my $type = $rule->{type};
1123     my $action = $rule->{action};
1124
1125     &$add_error('type', "missing property") if !$type;
1126     &$add_error('action', "missing property") if !$action;
1127
1128     if ($type) {
1129         if ($type eq  'in' || $type eq 'out') {
1130             &$add_error('action', "unknown action '$action'")
1131                 if $action && ($action !~ m/^(ACCEPT|DROP|REJECT)$/);
1132         } elsif ($type eq 'group') {
1133             &$add_error('type', "security groups not allowed")
1134                 if !$allow_groups;
1135             &$add_error('action', "invalid characters in security group name")
1136                 if $action && ($action !~ m/^${security_group_name_pattern}$/);
1137         } else {
1138             &$add_error('type', "unknown rule type '$type'");
1139         }
1140     }
1141
1142     if ($rule->{iface}) {
1143         &$add_error('type', "parameter -i not allowed for this rule type")
1144             if !$allow_iface;
1145         eval { PVE::JSONSchema::pve_verify_iface($rule->{iface}); };
1146         &$add_error('iface', $@) if $@;
1147         if ($rule_env eq 'vm') {
1148             &$add_error('iface', "value does not match the regex pattern 'net\\d+'")
1149                 if $rule->{iface} !~  m/^net(\d+)$/;
1150         } elsif ($rule_env eq 'ct') {
1151             &$add_error('iface', "value does not match the regex pattern '(venet|eth\\d+)'")
1152                 if $rule->{iface} !~  m/^(venet|eth(\d+))$/;
1153         }
1154     }
1155
1156     if ($rule->{macro}) {
1157         if (my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})}) {
1158             $rule->{macro} = $preferred_name;
1159         } else {
1160             &$add_error('macro', "unknown macro '$rule->{macro}'");
1161         }
1162     }
1163
1164     if ($rule->{proto}) {
1165         eval { pve_fw_verify_protocol_spec($rule->{proto}); };
1166         &$add_error('proto', $@) if $@;
1167     }
1168
1169     if ($rule->{dport}) {
1170         eval { parse_port_name_number_or_range($rule->{dport}); };
1171         &$add_error('dport', $@) if $@;
1172         &$add_error('proto', "missing property - 'dport' requires this property")
1173             if !$rule->{proto};
1174     }
1175
1176     if ($rule->{sport}) {
1177         eval { parse_port_name_number_or_range($rule->{sport}); };
1178         &$add_error('sport', $@) if $@;
1179         &$add_error('proto', "missing property - 'sport' requires this property")
1180             if !$rule->{proto};
1181     }
1182
1183     my $ipversion;
1184
1185     if ($rule->{source}) {
1186         eval { $ipversion = parse_address_list($rule->{source}); };
1187         &$add_error('source', $@) if $@;
1188         &$check_ipset_or_alias_property('source');
1189     }
1190
1191     if ($rule->{dest}) {
1192         eval { 
1193             my $dest_ipversion = parse_address_list($rule->{dest}); 
1194             die "detected mixed ipv4/ipv6 adresses in rule\n"
1195                 if defined($ipversion) && ($dest_ipversion != $ipversion);
1196             $ipversion = $dest_ipversion;
1197         };
1198         &$add_error('dest', $@) if $@;
1199         &$check_ipset_or_alias_property('dest');
1200     }
1201
1202     if ($rule->{macro} && !$error_count) {
1203         eval { &$apply_macro($rule->{macro}, $rule, 1); };
1204         if (my $err = $@) {
1205             if (ref($err) eq "PVE::Exception" && $err->{errors}) {
1206                 my $eh = $err->{errors};
1207                 foreach my $p (keys %$eh) {
1208                     &$add_error($p, $eh->{$p});
1209                 }
1210             } else {
1211                 &$add_error('macro', "$err");
1212             }
1213         }
1214     }
1215
1216     $rule->{errors} = $errors if $error_count;
1217     $rule->{ipversion} = $ipversion if $ipversion;
1218
1219     return $rule;
1220 }
1221
1222 sub copy_rule_data {
1223     my ($rule, $param) = @_;
1224
1225     foreach my $k (keys %$rule_properties) {
1226         if (defined(my $v = $param->{$k})) {
1227             if ($v eq '' || $v eq '-') {
1228                 delete $rule->{$k};
1229             } else {
1230                 $rule->{$k} = $v;
1231             }
1232         }
1233     }
1234
1235     return $rule;
1236 }
1237
1238 sub rules_modify_permissions {
1239     my ($rule_env) = @_;
1240
1241     if ($rule_env eq 'host') {
1242         return {
1243             check => ['perm', '/nodes/{node}', [ 'Sys.Modify' ]],
1244         };
1245     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1246         return {
1247             check => ['perm', '/', [ 'Sys.Modify' ]],
1248         };
1249     } elsif ($rule_env eq 'vm' ||   $rule_env eq 'ct') {
1250         return {
1251             check => ['perm', '/vms/{vmid}', [ 'VM.Config.Network' ]],
1252         }
1253     }
1254
1255     return undef;
1256 }
1257
1258 sub rules_audit_permissions {
1259     my ($rule_env) = @_;
1260
1261     if ($rule_env eq 'host') {
1262         return {
1263             check => ['perm', '/nodes/{node}', [ 'Sys.Audit' ]],
1264         };
1265     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1266         return {
1267             check => ['perm', '/', [ 'Sys.Audit' ]],
1268         };
1269     } elsif ($rule_env eq 'vm' ||   $rule_env eq 'ct') {
1270         return {
1271             check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1272         }
1273     }
1274
1275     return undef;
1276 }
1277
1278 # core functions
1279 my $bridge_firewall_enabled = 0;
1280
1281 sub enable_bridge_firewall {
1282
1283     return if $bridge_firewall_enabled; # only once
1284
1285     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1286     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1287
1288     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1289     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1290
1291     $bridge_firewall_enabled = 1;
1292 }
1293
1294 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
1295
1296 sub iptables_restore_cmdlist {
1297     my ($cmdlist) = @_;
1298
1299     run_command("/sbin/iptables-restore -n", input => $cmdlist);
1300 }
1301
1302 sub ipset_restore_cmdlist {
1303     my ($cmdlist) = @_;
1304
1305     run_command("/usr/sbin/ipset restore", input => $cmdlist);
1306 }
1307
1308 sub iptables_get_chains {
1309
1310     my $res = {};
1311
1312     # check what chains we want to track
1313     my $is_pvefw_chain = sub {
1314         my $name = shift;
1315
1316         return 1 if $name =~ m/^PVEFW-\S+$/;
1317
1318         return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
1319
1320         return 1 if $name =~ m/^veth\d+.\d+-(:?IN|OUT)$/; # fixme: dev name is configurable
1321
1322         return 1 if $name =~ m/^venet0-\d+-(:?IN|OUT)$/;
1323
1324         return 1 if $name =~ m/^fwbr\d+(v\d+)?-(:?FW|IN|OUT|IPS)$/;
1325         return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
1326
1327         return undef;
1328     };
1329
1330     my $table = '';
1331
1332     my $hooks = {};
1333
1334     my $parser = sub {
1335         my $line = shift;
1336
1337         return if $line =~ m/^#/;
1338         return if $line =~ m/^\s*$/;
1339
1340         if ($line =~ m/^\*(\S+)$/) {
1341             $table = $1;
1342             return;
1343         }
1344
1345         return if $table ne 'filter';
1346
1347         if ($line =~ m/^:(\S+)\s/) {
1348             my $chain = $1;
1349             return if !&$is_pvefw_chain($chain);
1350             $res->{$chain} = "unknown";
1351         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1352             my ($chain, $sig) = ($1, $2);
1353             return if !&$is_pvefw_chain($chain);
1354             $res->{$chain} = $sig;
1355         } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD)\s+-j\s+PVEFW-\1$/) {
1356             $hooks->{$1} = 1;
1357         } else {
1358             # simply ignore the rest
1359             return;
1360         }
1361     };
1362
1363     run_command("/sbin/iptables-save", outfunc => $parser);
1364
1365     return wantarray ? ($res, $hooks) : $res;
1366 }
1367
1368 sub iptables_chain_digest {
1369     my ($rules) = @_;
1370     my $digest = Digest::SHA->new('sha1');
1371     foreach my $rule (@$rules) { # order is important
1372         $digest->add($rule);
1373     }
1374     return $digest->b64digest;
1375 }
1376
1377 sub ipset_chain_digest {
1378     my ($rules) = @_;
1379
1380     my $digest = Digest::SHA->new('sha1');
1381     foreach my $rule (sort @$rules) { # note: sorted
1382         $digest->add($rule);
1383     }
1384     return $digest->b64digest;
1385 }
1386
1387 sub ipset_get_chains {
1388
1389     my $res = {};
1390     my $chains = {};
1391
1392     my $parser = sub {
1393         my $line = shift;
1394
1395         return if $line =~ m/^#/;
1396         return if $line =~ m/^\s*$/;
1397         if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
1398             my $chain = $1;
1399             $line =~ s/\s+$//; # delete trailing white space
1400             push @{$chains->{$chain}}, $line;
1401         } else {
1402             # simply ignore the rest
1403             return;
1404         }
1405     };
1406
1407     run_command("/usr/sbin/ipset save", outfunc => $parser);
1408
1409     # compute digest for each chain
1410     foreach my $chain (keys %$chains) {
1411         $res->{$chain} = ipset_chain_digest($chains->{$chain});
1412     }
1413
1414     return $res;
1415 }
1416
1417 sub ruleset_generate_cmdstr {
1418     my ($ruleset, $chain, $rule, $actions, $goto, $cluster_conf, $fw_conf) = @_;
1419
1420     return if defined($rule->{enable}) && !$rule->{enable};
1421     return if $rule->{errors};
1422
1423     die "unable to emit macro - internal error" if $rule->{macro}; # should not happen
1424
1425     my $nbdport = defined($rule->{dport}) ? parse_port_name_number_or_range($rule->{dport}) : 0;
1426     my $nbsport = defined($rule->{sport}) ? parse_port_name_number_or_range($rule->{sport}) : 0;
1427
1428     my @cmd = ();
1429
1430     push @cmd, "-i $rule->{iface_in}" if $rule->{iface_in};
1431     push @cmd, "-o $rule->{iface_out}" if $rule->{iface_out};
1432
1433     my $source = $rule->{source};
1434     my $dest = $rule->{dest};
1435
1436     if ($source) {
1437         if ($source =~ m/^\+/) {
1438             if ($source =~ m/^\+(${ipset_name_pattern})$/) {
1439                 my $name = $1;
1440                 if ($fw_conf && $fw_conf->{ipset}->{$name}) {
1441                     my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name);
1442                     push @cmd, "-m set --match-set ${ipset_chain} src";
1443                 } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
1444                     my $ipset_chain = compute_ipset_chain_name(0, $name);
1445                     push @cmd, "-m set --match-set ${ipset_chain} src";
1446                 } else {
1447                     die "no such ipset '$name'\n";
1448                 }
1449             } else {
1450                 die "invalid security group name '$source'\n";
1451             }
1452         } elsif ($source =~ m/^${ip_alias_pattern}$/){
1453             my $alias = lc($source);
1454             my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
1455             $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1456             die "no such alias '$source'\n" if !$e;
1457             push @cmd, "-s $e->{cidr}";
1458         } elsif ($source =~ m/\-/){
1459             push @cmd, "-m iprange --src-range $source";
1460         } else {
1461             push @cmd, "-s $source";
1462         }
1463     }
1464
1465     if ($dest) {
1466         if ($dest =~ m/^\+/) {
1467             if ($dest =~ m/^\+(${ipset_name_pattern})$/) {
1468                 my $name = $1;
1469                 if ($fw_conf && $fw_conf->{ipset}->{$name}) {
1470                     my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name);
1471                     push @cmd, "-m set --match-set ${ipset_chain} dst";
1472                 } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
1473                     my $ipset_chain = compute_ipset_chain_name(0, $name);
1474                     push @cmd, "-m set --match-set ${ipset_chain} dst";
1475                 } else {
1476                     die "no such ipset '$name'\n";
1477                 }
1478             } else {
1479                 die "invalid security group name '$dest'\n";
1480             }
1481         } elsif ($dest =~ m/^${ip_alias_pattern}$/){
1482             my $alias = lc($dest);
1483             my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
1484             $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1485             die "no such alias '$dest'\n" if !$e;
1486             push @cmd, "-d $e->{cidr}";
1487         } elsif ($dest =~ m/^(\d+)\.(\d+).(\d+).(\d+)\-(\d+)\.(\d+).(\d+).(\d+)$/){
1488             push @cmd, "-m iprange --dst-range $dest";
1489         } else {
1490             push @cmd, "-d $dest";
1491         }
1492     }
1493
1494     if ($rule->{proto}) {
1495         push @cmd, "-p $rule->{proto}";
1496
1497         my $multiport = 0;
1498         $multiport++ if $nbdport > 1;
1499         $multiport++ if $nbsport > 1;
1500
1501         push @cmd, "--match multiport" if $multiport;
1502
1503         die "multiport: option '--sports' cannot be used together with '--dports'\n"
1504             if ($multiport == 2) && ($rule->{dport} ne $rule->{sport});
1505
1506         if ($rule->{dport}) {
1507             if ($rule->{proto} && $rule->{proto} eq 'icmp') {
1508                 # Note: we use dport to store --icmp-type
1509                 die "unknown icmp-type '$rule->{dport}'\n" if !defined($icmp_type_names->{$rule->{dport}});
1510                 push @cmd, "-m icmp --icmp-type $rule->{dport}";
1511             } else {
1512                 if ($nbdport > 1) {
1513                     if ($multiport == 2) {
1514                         push @cmd,  "--ports $rule->{dport}";
1515                     } else {
1516                         push @cmd, "--dports $rule->{dport}";
1517                     }
1518                 } else {
1519                     push @cmd, "--dport $rule->{dport}";
1520                 }
1521             }
1522         }
1523
1524         if ($rule->{sport}) {
1525             if ($nbsport > 1) {
1526                 push @cmd, "--sports $rule->{sport}" if $multiport != 2;
1527             } else {
1528                 push @cmd, "--sport $rule->{sport}";
1529             }
1530         }
1531     } elsif ($rule->{dport} || $rule->{sport}) {
1532         die "destination port '$rule->{dport}', but no protocol specified\n" if $rule->{dport};
1533         die "source port '$rule->{sport}', but no protocol specified\n" if $rule->{sport};
1534     }
1535
1536     push @cmd, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
1537
1538     if (my $action = $rule->{action}) {
1539         $action = $actions->{$action} if defined($actions->{$action});
1540         $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
1541         push @cmd, $goto ? "-g $action" : "-j $action";
1542     }
1543
1544     return scalar(@cmd) ? join(' ', @cmd) : undef;
1545 }
1546
1547 sub ruleset_generate_rule {
1548     my ($ruleset, $chain, $rule, $actions, $goto, $cluster_conf, $fw_conf) = @_;
1549
1550     my $rules;
1551
1552     if ($rule->{macro}) {
1553         $rules = &$apply_macro($rule->{macro}, $rule);
1554     } else {
1555         $rules = [ $rule ];
1556     }
1557
1558     # update all or nothing
1559
1560     my @cmds = ();
1561     foreach my $tmp (@$rules) {
1562         if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $tmp, $actions, $goto, $cluster_conf, $fw_conf)) {
1563             push @cmds, $cmdstr;
1564         }
1565     }
1566
1567     foreach my $cmdstr (@cmds) {
1568         ruleset_addrule($ruleset, $chain, $cmdstr);
1569     }
1570 }
1571
1572 sub ruleset_generate_rule_insert {
1573     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
1574
1575     die "implement me" if $rule->{macro}; # not implemented, because not needed so far
1576
1577     if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $rule, $actions, $goto)) {
1578         ruleset_insertrule($ruleset, $chain, $cmdstr);
1579     }
1580 }
1581
1582 sub ruleset_create_chain {
1583     my ($ruleset, $chain) = @_;
1584
1585     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
1586     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
1587
1588     die "chain '$chain' already exists\n" if $ruleset->{$chain};
1589
1590     $ruleset->{$chain} = [];
1591 }
1592
1593 sub ruleset_chain_exist {
1594     my ($ruleset, $chain) = @_;
1595
1596     return $ruleset->{$chain} ? 1 : undef;
1597 }
1598
1599 sub ruleset_addrule {
1600    my ($ruleset, $chain, $rule) = @_;
1601
1602    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1603
1604    push @{$ruleset->{$chain}}, "-A $chain $rule";
1605 }
1606
1607 sub ruleset_insertrule {
1608    my ($ruleset, $chain, $rule) = @_;
1609
1610    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1611
1612    unshift @{$ruleset->{$chain}}, "-A $chain $rule";
1613 }
1614
1615 sub get_log_rule_base {
1616     my ($chain, $vmid, $msg, $loglevel) = @_;
1617
1618     die "internal error - no log level" if !defined($loglevel);
1619
1620     $vmid = 0 if !defined($vmid);
1621
1622     # Note: we use special format for prefix to pass further
1623     # info to log daemon (VMID, LOGVELEL and CHAIN)
1624
1625     return "-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
1626 }
1627
1628 sub ruleset_addlog {
1629     my ($ruleset, $chain, $vmid, $msg, $loglevel, $rule) = @_;
1630
1631     return if !defined($loglevel);
1632
1633     my $logrule = get_log_rule_base($chain, $vmid, $msg, $loglevel);
1634
1635     $logrule = "$rule $logrule" if defined($rule);
1636
1637     ruleset_addrule($ruleset, $chain, $logrule);
1638 }
1639
1640 sub ruleset_add_chain_policy {
1641     my ($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action) = @_;
1642
1643     if ($policy eq 'ACCEPT') {
1644
1645         ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT' },
1646                               { ACCEPT =>  $accept_action});
1647
1648     } elsif ($policy eq 'DROP') {
1649
1650         ruleset_addrule($ruleset, $chain, "-j PVEFW-Drop");
1651
1652         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1653
1654         ruleset_addrule($ruleset, $chain, "-j DROP");
1655     } elsif ($policy eq 'REJECT') {
1656         ruleset_addrule($ruleset, $chain, "-j PVEFW-Reject");
1657
1658         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1659
1660         ruleset_addrule($ruleset, $chain, "-g PVEFW-reject");
1661     } else {
1662         # should not happen
1663         die "internal error: unknown policy '$policy'";
1664     }
1665 }
1666
1667 sub ruleset_chain_add_conn_filters {
1668     my ($ruleset, $chain, $accept) = @_;
1669
1670     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1671     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
1672 }
1673
1674 sub ruleset_chain_add_input_filters {
1675     my ($ruleset, $chain, $options, $cluster_conf, $loglevel) = @_;
1676
1677     if ($cluster_conf->{ipset}->{blacklist}){
1678         if (!ruleset_chain_exist($ruleset, "PVEFW-blacklist")) {
1679             ruleset_create_chain($ruleset, "PVEFW-blacklist");
1680             ruleset_addlog($ruleset, "PVEFW-blacklist", 0, "DROP: ", $loglevel) if $loglevel;
1681             ruleset_addrule($ruleset, "PVEFW-blacklist", "-j DROP");
1682         }
1683         my $ipset_chain = compute_ipset_chain_name(0, 'blacklist');
1684         ruleset_addrule($ruleset, $chain, "-m set --match-set ${ipset_chain} src -j PVEFW-blacklist");
1685     }
1686
1687     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
1688         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1689     }
1690
1691     if ($options->{tcpflags}) {
1692         ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1693     }
1694 }
1695
1696 sub ruleset_create_vm_chain {
1697     my ($ruleset, $chain, $options, $macaddr, $ipfilter_ipset, $direction) = @_;
1698
1699     ruleset_create_chain($ruleset, $chain);
1700     my $accept = generate_nfqueue($options);
1701
1702     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
1703         if ($direction eq 'OUT') {
1704             ruleset_generate_rule($ruleset, $chain, { action => 'PVEFW-SET-ACCEPT-MARK',
1705                                                       proto => 'udp', sport => 68, dport => 67 });
1706         } else {
1707             ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT',
1708                                                       proto => 'udp', sport => 67, dport => 68 });
1709         }
1710     }
1711
1712     if ($direction eq 'OUT') {
1713         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
1714             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr -j DROP");
1715         }
1716         if ($ipfilter_ipset) {
1717             ruleset_addrule($ruleset, $chain, "-m set ! --match-set $ipfilter_ipset src -j DROP");
1718         }
1719         ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1720     }
1721 }
1722
1723 sub ruleset_add_group_rule {
1724     my ($ruleset, $cluster_conf, $chain, $rule, $direction, $action) = @_;
1725
1726     my $group = $rule->{action};
1727     my $group_chain = "GROUP-$group-$direction";
1728     if(!ruleset_chain_exist($ruleset, $group_chain)){
1729         generate_group_rules($ruleset, $cluster_conf, $group);
1730     }
1731
1732     if ($direction eq 'OUT' && $rule->{iface_out}) {
1733         ruleset_addrule($ruleset, $chain, "-o $rule->{iface_out} -j $group_chain");
1734     } elsif ($direction eq 'IN' && $rule->{iface_in}) {
1735         ruleset_addrule($ruleset, $chain, "-i $rule->{iface_in} -j $group_chain");
1736     } else {
1737         ruleset_addrule($ruleset, $chain, "-j $group_chain");
1738     }
1739
1740     ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j $action");
1741 }
1742
1743 sub ruleset_generate_vm_rules {
1744     my ($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, $netid, $direction, $options, $ipversion) = @_;
1745
1746     my $lc_direction = lc($direction);
1747
1748     my $in_accept = generate_nfqueue($options);
1749
1750     foreach my $rule (@$rules) {
1751         next if $rule->{iface} && $rule->{iface} ne $netid;
1752         next if !$rule->{enable} || $rule->{errors};
1753         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
1754
1755         if ($rule->{type} eq 'group') {
1756             ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, $direction,
1757                                    $direction eq 'OUT' ? 'RETURN' : $in_accept);
1758         } else {
1759             next if $rule->{type} ne $lc_direction;
1760             eval {
1761                 if ($direction eq 'OUT') {
1762                     ruleset_generate_rule($ruleset, $chain, $rule,
1763                                           { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" },
1764                                           undef, $cluster_conf, $vmfw_conf);
1765                 } else {
1766                     ruleset_generate_rule($ruleset, $chain, $rule,
1767                                           { ACCEPT => $in_accept , REJECT => "PVEFW-reject" },
1768                                           undef, $cluster_conf, $vmfw_conf);
1769                 }
1770             };
1771             warn $@ if $@;
1772         }
1773     }
1774 }
1775
1776 sub generate_nfqueue {
1777     my ($options) = @_;
1778
1779     if ($options->{ips}) {
1780         my $action = "NFQUEUE";
1781         if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
1782             if (defined($3) && defined($1)) {
1783                 $action .= " --queue-balance $1:$3";
1784             } elsif (defined($1)) {
1785                 $action .= " --queue-num $1";
1786             }
1787         }
1788         $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
1789         return $action;
1790     } else {
1791         return "ACCEPT";
1792     }
1793 }
1794
1795 sub ruleset_generate_vm_ipsrules {
1796     my ($ruleset, $options, $direction, $iface) = @_;
1797
1798     if ($options->{ips} && $direction eq 'IN') {
1799         my $nfqueue = generate_nfqueue($options);
1800
1801         if (!ruleset_chain_exist($ruleset, "PVEFW-IPS")) {
1802             ruleset_create_chain($ruleset, "PVEFW-IPS");
1803         }
1804
1805         ruleset_addrule($ruleset, "PVEFW-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged -j $nfqueue");
1806     }
1807 }
1808
1809 sub generate_venet_rules_direction {
1810     my ($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip, $direction, $ipversion) = @_;
1811
1812     my $lc_direction = lc($direction);
1813
1814     my $rules = $vmfw_conf->{rules};
1815
1816     my $options = $vmfw_conf->{options};
1817     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1818
1819     my $chain = "venet0-$vmid-$direction";
1820
1821     ruleset_create_vm_chain($ruleset, $chain, $options, undef, undef, $direction);
1822
1823     ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, 'venet', $direction, undef, $ipversion);
1824
1825     # implement policy
1826     my $policy;
1827
1828     if ($direction eq 'OUT') {
1829         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1830     } else {
1831         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1832     }
1833
1834     my $accept = generate_nfqueue($options);
1835     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1836     ruleset_add_chain_policy($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action);
1837
1838     if ($direction eq 'OUT') {
1839         ruleset_generate_rule_insert($ruleset, "PVEFW-VENET-OUT", {
1840             action => $chain,
1841             source => $ip,
1842             iface_in => 'venet0'});
1843     } else {
1844         ruleset_generate_rule($ruleset, "PVEFW-VENET-IN", {
1845             action => $chain,
1846             dest => $ip,
1847             iface_out => 'venet0'});
1848     }
1849 }
1850
1851 sub generate_tap_rules_direction {
1852     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $direction, $ipversion) = @_;
1853
1854     my $lc_direction = lc($direction);
1855
1856     my $rules = $vmfw_conf->{rules};
1857
1858     my $options = $vmfw_conf->{options};
1859     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1860
1861     my $tapchain = "$iface-$direction";
1862
1863     my $ipfilter_name = compute_ipfilter_ipset_name($netid);
1864     my $ipfilter_ipset = compute_ipset_chain_name($vmid, $ipfilter_name)
1865         if $vmfw_conf->{ipset}->{$ipfilter_name};       
1866
1867     # create chain with mac and ip filter
1868     ruleset_create_vm_chain($ruleset, $tapchain, $options, $macaddr, $ipfilter_ipset, $direction);
1869
1870     if ($options->{enable}) {
1871         ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $tapchain, $netid, $direction, $options, $ipversion);
1872
1873         ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface);
1874
1875         # implement policy
1876         my $policy;
1877
1878         if ($direction eq 'OUT') {
1879             $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1880         } else {
1881         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1882         }
1883
1884         my $accept = generate_nfqueue($options);
1885         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1886         ruleset_add_chain_policy($ruleset, $tapchain, $vmid, $policy, $loglevel, $accept_action);
1887     } else {
1888         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : 'ACCEPT';
1889         ruleset_add_chain_policy($ruleset, $tapchain, $vmid, 'ACCEPT', $loglevel, $accept_action);
1890     }
1891
1892     # plug the tap chain to bridge chain
1893     if ($direction eq 'IN') {
1894         ruleset_addrule($ruleset, "PVEFW-FWBR-IN",
1895                         "-m physdev --physdev-is-bridged --physdev-out $iface -j $tapchain");
1896     } else {
1897         ruleset_addrule($ruleset, "PVEFW-FWBR-OUT",
1898                         "-m physdev --physdev-is-bridged --physdev-in $iface -j $tapchain");
1899     }
1900 }
1901
1902 sub enable_host_firewall {
1903     my ($ruleset, $hostfw_conf, $cluster_conf) = @_;
1904
1905     my $options = $hostfw_conf->{options};
1906     my $cluster_options = $cluster_conf->{options};
1907     my $rules = $hostfw_conf->{rules};
1908     my $cluster_rules = $cluster_conf->{rules};
1909
1910     # host inbound firewall
1911     my $chain = "PVEFW-HOST-IN";
1912     ruleset_create_chain($ruleset, $chain);
1913
1914     my $loglevel = get_option_log_level($options, "log_level_in");
1915
1916     ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
1917
1918     ruleset_chain_add_conn_filters($ruleset, $chain, 'ACCEPT');
1919     ruleset_chain_add_input_filters($ruleset, $chain, $options, $cluster_conf, $loglevel);
1920
1921     # we use RETURN because we need to check also tap rules
1922     my $accept_action = 'RETURN';
1923
1924     ruleset_addrule($ruleset, $chain, "-p igmp -j $accept_action"); # important for multicast
1925
1926     # add host rules first, so that cluster wide rules can be overwritten
1927     foreach my $rule (@$rules, @$cluster_rules) {
1928         next if !$rule->{enable} || $rule->{errors};
1929
1930         $rule->{iface_in} = $rule->{iface} if $rule->{iface};
1931
1932         eval {
1933             if ($rule->{type} eq 'group') {
1934                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'IN', $accept_action);
1935             } elsif ($rule->{type} eq 'in') {
1936                 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" },
1937                                       undef, $cluster_conf, $hostfw_conf);
1938             }
1939         };
1940         warn $@ if $@;
1941         delete $rule->{iface_in};
1942     }
1943
1944     # allow standard traffic for management ipset (includes cluster network)
1945     my $mngmnt_ipset_chain = compute_ipset_chain_name(0, "management");
1946     my $mngmntsrc = "-m set --match-set ${mngmnt_ipset_chain} src";
1947     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 8006 -j $accept_action");  # PVE API
1948     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 5900:5999 -j $accept_action");  # PVE VNC Console
1949     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 3128 -j $accept_action");  # SPICE Proxy
1950     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 22 -j $accept_action");  # SSH
1951
1952     my $localnet = local_network();
1953
1954     # corosync
1955     if ($localnet) {
1956         my $corosync_rule = "-p udp --dport 5404:5405 -j $accept_action";
1957         ruleset_addrule($ruleset, $chain, "-s $localnet -d $localnet $corosync_rule");
1958         ruleset_addrule($ruleset, $chain, "-s $localnet -m addrtype --dst-type MULTICAST $corosync_rule");
1959     }
1960
1961     # implement input policy
1962     my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
1963     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1964
1965     # host outbound firewall
1966     $chain = "PVEFW-HOST-OUT";
1967     ruleset_create_chain($ruleset, $chain);
1968
1969     $loglevel = get_option_log_level($options, "log_level_out");
1970
1971     ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
1972
1973     ruleset_chain_add_conn_filters($ruleset, $chain, 'ACCEPT');
1974
1975     # we use RETURN because we may want to check other thigs later
1976     $accept_action = 'RETURN';
1977
1978     ruleset_addrule($ruleset, $chain, "-p igmp -j $accept_action"); # important for multicast
1979
1980     # add host rules first, so that cluster wide rules can be overwritten
1981     foreach my $rule (@$rules, @$cluster_rules) {
1982         next if !$rule->{enable} || $rule->{errors};
1983
1984         $rule->{iface_out} = $rule->{iface} if $rule->{iface};
1985         eval {
1986             if ($rule->{type} eq 'group') {
1987                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'OUT', $accept_action);
1988             } elsif ($rule->{type} eq 'out') {
1989                 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" },
1990                                       undef, $cluster_conf, $hostfw_conf);
1991             }
1992         };
1993         warn $@ if $@;
1994         delete $rule->{iface_out};
1995     }
1996
1997     # allow standard traffic on cluster network
1998     if ($localnet) {
1999         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 8006 -j $accept_action");  # PVE API
2000         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 22 -j $accept_action");  # SSH
2001         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 5900:5999 -j $accept_action");  # PVE VNC Console
2002         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 3128 -j $accept_action");  # SPICE Proxy
2003
2004         my $corosync_rule = "-p udp --dport 5404:5405 -j $accept_action";
2005         ruleset_addrule($ruleset, $chain, "-d $localnet $corosync_rule");
2006         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule");
2007     }
2008
2009     # implement output policy
2010     $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
2011     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
2012
2013     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
2014     ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
2015 }
2016
2017 sub generate_group_rules {
2018     my ($ruleset, $cluster_conf, $group) = @_;
2019
2020     my $rules = $cluster_conf->{groups}->{$group};
2021
2022     if (!$rules) {
2023         warn "no such security group '$group'\n";
2024         $rules = []; # create empty chain
2025     }
2026
2027     my $chain = "GROUP-${group}-IN";
2028
2029     ruleset_create_chain($ruleset, $chain);
2030     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
2031
2032     foreach my $rule (@$rules) {
2033         next if $rule->{type} ne 'in';
2034         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" }, undef, $cluster_conf);
2035     }
2036
2037     $chain = "GROUP-${group}-OUT";
2038
2039     ruleset_create_chain($ruleset, $chain);
2040     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
2041
2042     foreach my $rule (@$rules) {
2043         next if $rule->{type} ne 'out';
2044         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
2045         # check also other tap rules later
2046         ruleset_generate_rule($ruleset, $chain, $rule,
2047                               { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" }, undef, $cluster_conf);
2048     }
2049 }
2050
2051 my $MAX_NETS = 32;
2052 my $valid_netdev_names = {};
2053 for (my $i = 0; $i < $MAX_NETS; $i++)  {
2054     $valid_netdev_names->{"net$i"} = 1;
2055 }
2056
2057 sub parse_fw_rule {
2058     my ($prefix, $line, $cluster_conf, $fw_conf, $rule_env, $verbose) = @_;
2059
2060     my $orig_line = $line;
2061
2062     my $rule = {};
2063
2064     # we can add single line comments to the end of the rule
2065     if ($line =~ s/#\s*(.*?)\s*$//) {
2066         $rule->{comment} = decode('utf8', $1);
2067     }
2068
2069     # we can disable a rule when prefixed with '|'
2070
2071     $rule->{enable} = $line =~ s/^\|// ? 0 : 1;
2072
2073     $line =~ s/^(\S+)\s+(\S+)\s*// ||
2074         die "unable to parse rule: $line\n";
2075
2076     $rule->{type} = lc($1);
2077     $rule->{action} = $2;
2078
2079     if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2080         if ($rule->{action} =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
2081             $rule->{macro} = $1;
2082             $rule->{action} = $2;
2083         }
2084     }
2085
2086     while (length($line)) {
2087         if ($line =~ s/^-i (\S+)\s*//) {
2088             $rule->{iface} = $1;
2089             next;
2090         }
2091
2092         last if $rule->{type} eq 'group';
2093
2094         if ($line =~ s/^-p (\S+)\s*//) {
2095             $rule->{proto} = $1;
2096             next;
2097         }
2098
2099         if ($line =~ s/^-dport (\S+)\s*//) {
2100             $rule->{dport} = $1;
2101             next;
2102         }
2103
2104         if ($line =~ s/^-sport (\S+)\s*//) {
2105             $rule->{sport} = $1;
2106             next;
2107         }
2108         if ($line =~ s/^-source (\S+)\s*//) {
2109             $rule->{source} = $1;
2110             next;
2111         }
2112         if ($line =~ s/^-dest (\S+)\s*//) {
2113             $rule->{dest} = $1;
2114             next;
2115         }
2116
2117         last;
2118     }
2119
2120     die "unable to parse rule parameters: $line\n" if length($line);
2121
2122     $rule = verify_rule($rule, $cluster_conf, $fw_conf, $rule_env, 1);
2123     if ($verbose && $rule->{errors}) {
2124         warn "$prefix - errors in rule parameters: $orig_line\n";
2125         foreach my $p (keys %{$rule->{errors}}) {
2126             warn "  $p: $rule->{errors}->{$p}\n";
2127         }
2128     }
2129
2130     return $rule;
2131 }
2132
2133 sub parse_vmfw_option {
2134     my ($line) = @_;
2135
2136     my ($opt, $value);
2137
2138     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2139
2140     if ($line =~ m/^(enable|dhcp|macfilter|ips):\s*(0|1)\s*$/i) {
2141         $opt = lc($1);
2142         $value = int($2);
2143     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
2144         $opt = lc($1);
2145         $value = $2 ? lc($3) : '';
2146     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2147         $opt = lc($1);
2148         $value = uc($3);
2149     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
2150         $opt = lc($1);
2151         $value = $2;
2152     } else {
2153         die "can't parse option '$line'\n"
2154     }
2155
2156     return ($opt, $value);
2157 }
2158
2159 sub parse_hostfw_option {
2160     my ($line) = @_;
2161
2162     my ($opt, $value);
2163
2164     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2165
2166     if ($line =~ m/^(enable|nosmurfs|tcpflags):\s*(0|1)\s*$/i) {
2167         $opt = lc($1);
2168         $value = int($2);
2169     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
2170         $opt = lc($1);
2171         $value = $2 ? lc($3) : '';
2172     } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established):\s*(\d+)\s*$/i) {
2173         $opt = lc($1);
2174         $value = int($2);
2175     } else {
2176         die "can't parse option '$line'\n"
2177     }
2178
2179     return ($opt, $value);
2180 }
2181
2182 sub parse_clusterfw_option {
2183     my ($line) = @_;
2184
2185     my ($opt, $value);
2186
2187     if ($line =~ m/^(enable):\s*(0|1)\s*$/i) {
2188         $opt = lc($1);
2189         $value = int($2);
2190     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2191         $opt = lc($1);
2192         $value = uc($3);
2193     } else {
2194         die "can't parse option '$line'\n"
2195     }
2196
2197     return ($opt, $value);
2198 }
2199
2200 sub resolve_alias {
2201     my ($clusterfw_conf, $fw_conf, $cidr) = @_;
2202
2203     if ($cidr !~ m/^\d/) {
2204         my $alias = lc($cidr);
2205         my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
2206         $e = $clusterfw_conf->{aliases}->{$alias} if !$e && $clusterfw_conf;
2207         return $e->{cidr} if $e;
2208         
2209         die "no such alias '$cidr'\n";
2210     }
2211
2212     return $cidr;
2213 }
2214
2215 sub parse_alias {
2216     my ($line) = @_;
2217
2218     # we can add single line comments to the end of the line
2219     my $comment = decode('utf8', $1) if $line =~ s/\s*#\s*(.*?)\s*$//;
2220
2221     if ($line =~ m/^(\S+)\s(\S+)$/) {
2222         my ($name, $cidr) = ($1, $2);
2223         $cidr =~ s|/32$||;
2224         pve_verify_ipv4_or_cidr($cidr);
2225         my $data = {
2226             name => $name,
2227             cidr => $cidr,
2228         };
2229         $data->{comment} = $comment  if $comment;
2230         return $data;
2231     }
2232
2233     return undef;
2234 }
2235
2236 sub generic_fw_config_parser {
2237     my ($filename, $fh, $verbose, $cluster_conf, $empty_conf, $rule_env) = @_;
2238
2239     my $section;
2240     my $group;
2241
2242     my $res = $empty_conf;
2243
2244     while (defined(my $line = <$fh>)) {
2245         next if $line =~ m/^#/;
2246         next if $line =~ m/^\s*$/;
2247
2248         chomp $line;
2249
2250         my $linenr = $fh->input_line_number();
2251         my $prefix = "$filename (line $linenr)";
2252
2253         if ($empty_conf->{options} && ($line =~ m/^\[options\]$/i)) {
2254             $section = 'options';
2255             next;
2256         }
2257
2258         if ($empty_conf->{aliases} && ($line =~ m/^\[aliases\]$/i)) {
2259             $section = 'aliases';
2260             next;
2261         }
2262
2263         if ($empty_conf->{groups} && ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2264             $section = 'groups';
2265             $group = lc($1);
2266             my $comment = $2;
2267             eval {
2268                 die "security group name too long\n" if length($group) > $max_group_name_length;
2269                 die "invalid security group name '$group'\n" if $group !~ m/^${security_group_name_pattern}$/;
2270             };
2271             if (my $err = $@) {
2272                 ($section, $group, $comment) = undef;
2273                 warn "$prefix: $err";
2274                 next;
2275             }
2276             
2277             $res->{$section}->{$group} = [];
2278             $res->{group_comments}->{$group} =  decode('utf8', $comment)
2279                 if $comment;
2280             next;
2281         }
2282
2283         if ($empty_conf->{rules} && ($line =~ m/^\[rules\]$/i)) {
2284             $section = 'rules';
2285             next;
2286         }
2287
2288         if ($empty_conf->{ipset} && ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2289             $section = 'ipset';
2290             $group = lc($1);
2291             my $comment = $2;
2292             eval {      
2293                 die "ipset name too long\n" if length($group) > $max_ipset_name_length;
2294                 die "invalid ipset name '$group'\n" if $group !~ m/^${ipset_name_pattern}$/;
2295             };
2296             if (my $err = $@) {
2297                 ($section, $group, $comment) = undef;
2298                 warn "$prefix: $err";
2299                 next;
2300             }
2301
2302             $res->{$section}->{$group} = [];
2303             $res->{ipset_comments}->{$group} = decode('utf8', $comment)
2304                 if $comment;
2305             next;
2306         }
2307
2308         if (!$section) {
2309             warn "$prefix: skip line - no section\n";
2310             next;
2311         }
2312
2313         if ($section eq 'options') {
2314             eval {
2315                 my ($opt, $value);
2316                 if ($rule_env eq 'cluster') {
2317                     ($opt, $value) = parse_clusterfw_option($line);
2318                 } elsif ($rule_env eq 'host') {
2319                     ($opt, $value) = parse_hostfw_option($line);
2320                 } else {
2321                     ($opt, $value) = parse_vmfw_option($line);
2322                 }
2323                 $res->{options}->{$opt} = $value;
2324             };
2325             warn "$prefix: $@" if $@;
2326         } elsif ($section eq 'aliases') {
2327             eval {
2328                 my $data = parse_alias($line);
2329                 $res->{aliases}->{lc($data->{name})} = $data;
2330             };
2331             warn "$prefix: $@" if $@;
2332         } elsif ($section eq 'rules') {
2333             my $rule;
2334             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, $res, $rule_env, $verbose); };
2335             if (my $err = $@) {
2336                 warn "$prefix: $err";
2337                 next;
2338             }
2339             push @{$res->{$section}}, $rule;
2340         } elsif ($section eq 'groups') {
2341             my $rule;
2342             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, undef, 'group', $verbose); };
2343             if (my $err = $@) {
2344                 warn "$prefix: $err";
2345                 next;
2346             }
2347             push @{$res->{$section}->{$group}}, $rule;
2348         } elsif ($section eq 'ipset') {
2349             # we can add single line comments to the end of the rule
2350             my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
2351
2352             $line =~ m/^(\!)?\s*(\S+)\s*$/;
2353             my $nomatch = $1;
2354             my $cidr = $2;
2355             my $errors;
2356
2357             if ($nomatch && !$feature_ipset_nomatch) {
2358                 $errors->{nomatch} = "nomatch not supported by kernel";
2359             }
2360
2361             eval { 
2362                 if ($cidr =~ m/^${ip_alias_pattern}$/) {
2363                     resolve_alias($cluster_conf, $res, $cidr); # make sure alias exists
2364                 } else {
2365                     $cidr =~ s|/32$||;
2366                     pve_verify_ipv4_or_cidr_or_alias($cidr);
2367                 }
2368             };
2369             if (my $err = $@) {
2370                 chomp $err;
2371                 $errors->{cidr} = $err;
2372             }
2373
2374             my $entry = { cidr => $cidr };
2375             $entry->{nomatch} = 1 if $nomatch;
2376             $entry->{comment} = $comment if $comment;
2377             $entry->{errors} =  $errors if $errors;
2378
2379             if ($verbose && $errors) {
2380                 warn "$prefix - errors in ipset '$group': $line\n";
2381                 foreach my $p (keys %{$errors}) {
2382                     warn "  $p: $errors->{$p}\n";
2383                 }
2384             }
2385
2386             push @{$res->{$section}->{$group}}, $entry;
2387         } else {
2388             warn "$prefix: skip line - unknown section\n";
2389             next;
2390         }
2391     }
2392
2393     return $res;
2394 }
2395
2396 sub parse_hostfw_config {
2397     my ($filename, $fh, $cluster_conf, $verbose) = @_;
2398
2399     my $empty_conf = { rules => [], options => {}};
2400
2401     return generic_fw_config_parser($filename, $fh, $verbose, $cluster_conf, $empty_conf, 'host');
2402 }
2403
2404 sub parse_vmfw_config {
2405     my ($filename, $fh, $cluster_conf, $rule_env, $verbose) = @_;
2406
2407     my $empty_conf = {
2408         rules => [],
2409         options => {},
2410         aliases => {},
2411         ipset => {} ,
2412         ipset_comments => {},
2413     };
2414
2415     return generic_fw_config_parser($filename, $fh, $verbose, $cluster_conf, $empty_conf, $rule_env);
2416 }
2417
2418 sub parse_clusterfw_config {
2419     my ($filename, $fh, $verbose) = @_;
2420
2421     my $section;
2422     my $group;
2423
2424     my $empty_conf = {
2425         rules => [],
2426         options => {},
2427         aliases => {},
2428         groups => {},
2429         group_comments => {},
2430         ipset => {} ,
2431         ipset_comments => {},
2432     };
2433
2434     return generic_fw_config_parser($filename, $fh, $verbose, $empty_conf, $empty_conf, 'cluster');
2435 }
2436
2437 sub run_locked {
2438     my ($code, @param) = @_;
2439
2440     my $timeout = 10;
2441
2442     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
2443
2444     die $@ if $@;
2445
2446     return $res;
2447 }
2448
2449 sub read_local_vm_config {
2450
2451     my $openvz = {};
2452     my $qemu = {};
2453
2454     my $vmdata = { openvz => $openvz, qemu => $qemu };
2455
2456     my $vmlist = PVE::Cluster::get_vmlist();
2457     return $vmdata if !$vmlist || !$vmlist->{ids};
2458     my $ids = $vmlist->{ids};
2459
2460     foreach my $vmid (keys %$ids) {
2461         next if !$vmid; # skip VE0
2462         my $d = $ids->{$vmid};
2463         next if !$d->{node} || $d->{node} ne $nodename;
2464         next if !$d->{type};
2465         if ($d->{type} eq 'openvz') {
2466             if ($have_pve_manager) {
2467                 my $cfspath = PVE::OpenVZ::cfs_config_path($vmid);
2468                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2469                     $openvz->{$vmid} = $conf;
2470                 }
2471             }
2472         } elsif ($d->{type} eq 'qemu') {
2473             if ($have_qemu_server) {
2474                 my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
2475                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2476                     $qemu->{$vmid} = $conf;
2477                 }
2478             }
2479         }
2480     }
2481
2482     return $vmdata;
2483 };
2484
2485 sub load_vmfw_conf {
2486     my ($cluster_conf, $rule_env, $vmid, $dir, $verbose) = @_;
2487
2488     my $vmfw_conf = {};
2489
2490     $dir = $pvefw_conf_dir if !defined($dir);
2491
2492     my $filename = "$dir/$vmid.fw";
2493     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2494         $vmfw_conf = parse_vmfw_config($filename, $fh, $cluster_conf, $rule_env, $verbose);
2495         $vmfw_conf->{vmid} = $vmid;
2496     }
2497
2498     return $vmfw_conf;
2499 }
2500
2501 my $format_rules = sub {
2502     my ($rules, $allow_iface) = @_;
2503
2504     my $raw = '';
2505
2506     foreach my $rule (@$rules) {
2507         if ($rule->{type} eq  'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
2508             $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
2509             $raw .= uc($rule->{type});
2510             if ($rule->{macro}) {
2511                 $raw .= " $rule->{macro}($rule->{action})";
2512             } else {
2513                 $raw .= " " . $rule->{action};
2514             }
2515             if ($allow_iface && $rule->{iface}) {
2516                 $raw .= " -i $rule->{iface}";
2517             }
2518
2519             if ($rule->{type} ne  'group')  {
2520                 $raw .= " -source $rule->{source}" if $rule->{source};
2521                 $raw .= " -dest $rule->{dest}" if $rule->{dest};
2522                 $raw .= " -p $rule->{proto}" if $rule->{proto};
2523                 $raw .= " -dport $rule->{dport}" if $rule->{dport};
2524                 $raw .= " -sport $rule->{sport}" if $rule->{sport};
2525             }
2526
2527             $raw .= " # " . encode('utf8', $rule->{comment})
2528                 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
2529             $raw .= "\n";
2530         } else {
2531             die "unknown rule type '$rule->{type}'";
2532         }
2533     }
2534
2535     return $raw;
2536 };
2537
2538 my $format_options = sub {
2539     my ($options) = @_;
2540
2541     my $raw = '';
2542
2543     $raw .= "[OPTIONS]\n\n";
2544     foreach my $opt (keys %$options) {
2545         $raw .= "$opt: $options->{$opt}\n";
2546     }
2547     $raw .= "\n";
2548
2549     return $raw;
2550 };
2551
2552 my $format_aliases = sub {
2553     my ($aliases) = @_;
2554
2555     my $raw = '';
2556
2557     $raw .= "[ALIASES]\n\n";
2558     foreach my $k (keys %$aliases) {
2559         my $e = $aliases->{$k};
2560         $raw .= "$e->{name} $e->{cidr}";
2561         $raw .= " # " . encode('utf8', $e->{comment})
2562             if $e->{comment} && $e->{comment} !~ m/^\s*$/;
2563         $raw .= "\n";
2564     }
2565     $raw .= "\n";
2566
2567     return $raw;
2568 };
2569
2570 my $format_ipsets = sub {
2571     my ($fw_conf) = @_;
2572     
2573     my $raw = '';
2574
2575     foreach my $ipset (sort keys %{$fw_conf->{ipset}}) {
2576         if (my $comment = $fw_conf->{ipset_comments}->{$ipset}) {
2577             my $utf8comment = encode('utf8', $comment);
2578             $raw .= "[IPSET $ipset] # $utf8comment\n\n";
2579         } else {
2580             $raw .= "[IPSET $ipset]\n\n";
2581         }
2582         my $options = $fw_conf->{ipset}->{$ipset};
2583
2584         my $nethash = {};
2585         foreach my $entry (@$options) {
2586             $nethash->{$entry->{cidr}} = $entry;
2587         }
2588
2589         foreach my $cidr (sort keys %$nethash) {
2590             my $entry = $nethash->{$cidr};
2591             my $line = $entry->{nomatch} ? '!' : '';
2592             $line .= $entry->{cidr};
2593             $line .= " # " . encode('utf8', $entry->{comment})
2594                 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
2595             $raw .= "$line\n";
2596         }
2597
2598         $raw .= "\n";
2599     }
2600
2601     return $raw;
2602 };
2603
2604 sub save_vmfw_conf {
2605     my ($vmid, $vmfw_conf) = @_;
2606
2607     my $raw = '';
2608
2609     my $options = $vmfw_conf->{options};
2610     $raw .= &$format_options($options) if $options && scalar(keys %$options);
2611
2612     my $aliases = $vmfw_conf->{aliases};
2613     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
2614
2615     $raw .= &$format_ipsets($vmfw_conf) if $vmfw_conf->{ipset};
2616
2617     my $rules = $vmfw_conf->{rules} || [];
2618     if ($rules && scalar(@$rules)) {
2619         $raw .= "[RULES]\n\n";
2620         $raw .= &$format_rules($rules, 1);
2621         $raw .= "\n";
2622     }
2623
2624     mkdir $pvefw_conf_dir;
2625
2626     my $filename = "$pvefw_conf_dir/$vmid.fw";
2627     PVE::Tools::file_set_contents($filename, $raw);
2628 }
2629
2630 sub read_vm_firewall_configs {
2631     my ($cluster_conf, $vmdata, $dir, $verbose) = @_;
2632
2633     my $vmfw_configs = {};
2634
2635     foreach my $vmid (keys %{$vmdata->{qemu}}) {
2636         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'vm', $vmid, $dir, $verbose);
2637         next if !$vmfw_conf->{options}; # skip if file does not exists
2638         $vmfw_configs->{$vmid} = $vmfw_conf;
2639     }
2640     foreach my $vmid (keys %{$vmdata->{openvz}}) {
2641         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'ct', $vmid, $dir, $verbose);
2642         next if !$vmfw_conf->{options}; # skip if file does not exists
2643         $vmfw_configs->{$vmid} = $vmfw_conf;
2644     }
2645
2646     return $vmfw_configs;
2647 }
2648
2649 sub get_option_log_level {
2650     my ($options, $k) = @_;
2651
2652     my $v = $options->{$k};
2653     $v = $default_log_level if !defined($v);
2654
2655     return undef if $v eq '' || $v eq 'nolog';
2656
2657     $v = $log_level_hash->{$v} if defined($log_level_hash->{$v});
2658
2659     return $v if ($v >= 0) && ($v <= 7);
2660
2661     warn "unknown log level ($k = '$v')\n";
2662
2663     return undef;
2664 }
2665
2666 sub generate_std_chains {
2667     my ($ruleset, $options, $ipversion) = @_;
2668
2669     my $std_chains = $pve_std_chains->{$ipversion} || die "internal error";
2670
2671     my $loglevel = get_option_log_level($options, 'smurf_log_level');
2672
2673     my $chain;
2674
2675     if ($ipversion == 4) {
2676         # same as shorewall smurflog.
2677         $chain = 'PVEFW-smurflog';
2678         $std_chains->{$chain} = [];
2679         
2680         push @{$std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2681         push @{$std_chains->{$chain}}, "-j DROP";
2682     }
2683
2684     # same as shorewall logflags action.
2685     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
2686     $chain = 'PVEFW-logflags';
2687     $std_chains->{$chain} = [];
2688
2689     # fixme: is this correctly logged by pvewf-logger? (ther is no --log-ip-options for NFLOG)
2690     push @{$std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2691     push @{$std_chains->{$chain}}, "-j DROP";
2692
2693     foreach my $chain (keys %$std_chains) {
2694         ruleset_create_chain($ruleset, $chain);
2695         foreach my $rule (@{$std_chains->{$chain}}) {
2696             if (ref($rule)) {
2697                 ruleset_generate_rule($ruleset, $chain, $rule);
2698             } else {
2699                 ruleset_addrule($ruleset, $chain, $rule);
2700             }
2701         }
2702     }
2703 }
2704
2705 sub generate_ipset_chains {
2706     my ($ipset_ruleset, $clusterfw_conf, $fw_conf) = @_;
2707
2708     foreach my $ipset (keys %{$fw_conf->{ipset}}) {
2709         my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $ipset);
2710         generate_ipset($ipset_ruleset, $ipset_chain, $fw_conf->{ipset}->{$ipset}, $clusterfw_conf, $fw_conf);
2711     }
2712 }
2713
2714 sub generate_ipset {
2715     my ($ipset_ruleset, $name, $options, $clusterfw_conf, $fw_conf) = @_;
2716
2717     die "duplicate ipset chain '$name'\n" if defined($ipset_ruleset->{$name});
2718
2719     my $hashsize = scalar(@$options);
2720     if ($hashsize <= 64) {
2721         $hashsize = 64;
2722     } else {
2723         $hashsize = round_powerof2($hashsize);
2724     }
2725
2726     $ipset_ruleset->{$name} = ["create $name hash:net family inet hashsize $hashsize maxelem $hashsize"];
2727
2728     # remove duplicates
2729     my $nethash = {};
2730     foreach my $entry (@$options) {
2731         next if $entry->{errors}; # skip entries with errors
2732         eval {
2733             my $cidr = resolve_alias($clusterfw_conf, $fw_conf, $entry->{cidr});
2734             $nethash->{$cidr} = { cidr => $cidr, nomatch => $entry->{nomatch} };
2735         };
2736         warn $@ if $@;
2737     }
2738
2739     foreach my $cidr (sort keys %$nethash) {
2740         my $entry = $nethash->{$cidr};
2741
2742         my $cmd = "add $name $cidr";
2743         if ($entry->{nomatch}) {
2744             if ($feature_ipset_nomatch) {
2745                 push @{$ipset_ruleset->{$name}}, "$cmd nomatch";
2746             } else {
2747                 warn "ignore !$cidr - nomatch not supported by kernel\n";
2748             }
2749         } else {
2750             push @{$ipset_ruleset->{$name}}, $cmd;
2751         }
2752     }
2753 }
2754
2755 sub round_powerof2 {
2756     my ($int) = @_;
2757
2758     $int--;
2759     $int |= $int >> $_ foreach (1,2,4,8,16);
2760     return ++$int;
2761 }
2762
2763 sub load_clusterfw_conf {
2764     my ($filename, $verbose) = @_;
2765
2766     $filename = $clusterfw_conf_filename if !defined($filename);
2767
2768     my $cluster_conf = {};
2769     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2770         $cluster_conf = parse_clusterfw_config($filename, $fh, $verbose);
2771     }
2772
2773     return $cluster_conf;
2774 }
2775
2776 sub save_clusterfw_conf {
2777     my ($cluster_conf) = @_;
2778
2779     my $raw = '';
2780
2781     my $options = $cluster_conf->{options};
2782     $raw .= &$format_options($options) if $options && scalar(keys %$options);
2783
2784     my $aliases = $cluster_conf->{aliases};
2785     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
2786
2787     $raw .= &$format_ipsets($cluster_conf) if $cluster_conf->{ipset};
2788  
2789     my $rules = $cluster_conf->{rules};
2790     if ($rules && scalar(@$rules)) {
2791         $raw .= "[RULES]\n\n";
2792         $raw .= &$format_rules($rules, 1);
2793         $raw .= "\n";
2794     }
2795
2796     if ($cluster_conf->{groups}) {
2797         foreach my $group (sort keys %{$cluster_conf->{groups}}) {
2798             my $rules = $cluster_conf->{groups}->{$group};
2799             if (my $comment = $cluster_conf->{group_comments}->{$group}) {
2800                 my $utf8comment = encode('utf8', $comment);
2801                 $raw .= "[group $group] # $utf8comment\n\n";
2802             } else {
2803                 $raw .= "[group $group]\n\n";
2804             }
2805
2806             $raw .= &$format_rules($rules, 0);
2807             $raw .= "\n";
2808         }
2809     }
2810
2811     mkdir $pvefw_conf_dir;
2812     PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
2813 }
2814
2815 sub load_hostfw_conf {
2816     my ($cluster_conf, $filename, $verbose) = @_;
2817
2818     $filename = $hostfw_conf_filename if !defined($filename);
2819
2820     my $hostfw_conf = {};
2821     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2822         $hostfw_conf = parse_hostfw_config($filename, $fh, $cluster_conf, $verbose);
2823     }
2824     return $hostfw_conf;
2825 }
2826
2827 sub save_hostfw_conf {
2828     my ($hostfw_conf) = @_;
2829
2830     my $raw = '';
2831
2832     my $options = $hostfw_conf->{options};
2833     $raw .= &$format_options($options) if $options && scalar(keys %$options);
2834
2835     my $rules = $hostfw_conf->{rules};
2836     if ($rules && scalar(@$rules)) {
2837         $raw .= "[RULES]\n\n";
2838         $raw .= &$format_rules($rules, 1);
2839         $raw .= "\n";
2840     }
2841
2842     PVE::Tools::file_set_contents($hostfw_conf_filename, $raw);
2843 }
2844
2845 sub compile {
2846     my ($cluster_conf, $hostfw_conf, $vmdata, $verbose) = @_;
2847
2848     my $vmfw_configs;
2849
2850     if ($vmdata) { # test mode
2851         my $testdir = $vmdata->{testdir} || die "no test directory specified";
2852         my $filename = "$testdir/cluster.fw";
2853         $cluster_conf = load_clusterfw_conf($filename, $verbose);
2854
2855         $filename = "$testdir/host.fw";
2856         $hostfw_conf = load_hostfw_conf($cluster_conf, $filename, $verbose);
2857
2858         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, $testdir, $verbose);
2859     } else { # normal operation
2860         $cluster_conf = load_clusterfw_conf(undef, $verbose) if !$cluster_conf;
2861
2862         $hostfw_conf = load_hostfw_conf($cluster_conf, undef, $verbose) if !$hostfw_conf;
2863
2864         $vmdata = read_local_vm_config();
2865         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, undef, $verbose);
2866     }
2867
2868     my ($ruleset, $ipset_ruleset) = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, 4, $verbose);
2869     return ($ruleset, $ipset_ruleset);
2870 }
2871
2872 sub compile_iptables_filter {
2873     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $ipversion, $verbose) = @_;
2874
2875     $cluster_conf->{ipset}->{venet0} = [];
2876     my $venet0_ipset_chain = compute_ipset_chain_name(0, 'venet0');
2877
2878     my $localnet;
2879     if ($cluster_conf->{aliases}->{local_network}) {
2880         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
2881     } else {
2882         $localnet = local_network() || '127.0.0.0/8';
2883         $cluster_conf->{aliases}->{local_network} = { cidr => $localnet };
2884     }
2885
2886     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
2887
2888     return ({}, {}) if !$cluster_conf->{options}->{enable};
2889
2890     my $ruleset = {};
2891
2892     ruleset_create_chain($ruleset, "PVEFW-INPUT");
2893     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
2894
2895     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
2896
2897     my $hostfw_options = $hostfw_conf->{options} || {};
2898
2899     # fixme: what log level should we use here?
2900     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
2901
2902     ruleset_chain_add_conn_filters($ruleset, "PVEFW-FORWARD", "ACCEPT");
2903
2904
2905     ruleset_create_chain($ruleset, "PVEFW-VENET-OUT");
2906     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i venet0 -m set --match-set ${venet0_ipset_chain} src -j PVEFW-VENET-OUT");
2907     ruleset_addrule($ruleset, "PVEFW-INPUT", "-i venet0 -m set --match-set ${venet0_ipset_chain} src -j PVEFW-VENET-OUT");
2908
2909     ruleset_create_chain($ruleset, "PVEFW-FWBR-IN");
2910     ruleset_chain_add_input_filters($ruleset, "PVEFW-FWBR-IN", $hostfw_options, $cluster_conf, $loglevel);
2911
2912     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-in fwln+ -j PVEFW-FWBR-IN");
2913
2914     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
2915     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-out fwln+ -j PVEFW-FWBR-OUT");
2916
2917     ruleset_create_chain($ruleset, "PVEFW-VENET-IN");
2918     ruleset_chain_add_input_filters($ruleset, "PVEFW-VENET-IN", $hostfw_options, $cluster_conf, $loglevel);
2919
2920     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o venet0 -m set --match-set ${venet0_ipset_chain} dst -j PVEFW-VENET-IN");
2921
2922     generate_std_chains($ruleset, $hostfw_options, $ipversion);
2923
2924     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
2925
2926     my $ipset_ruleset = {};
2927
2928     if ($hostfw_enable && $ipversion eq 4) {
2929         eval { enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf); };
2930         warn $@ if $@; # just to be sure - should not happen
2931     }
2932
2933     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-o venet0 -m set --match-set ${venet0_ipset_chain} dst -j PVEFW-VENET-IN");
2934
2935     # generate firewall rules for QEMU VMs
2936     foreach my $vmid (keys %{$vmdata->{qemu}}) {
2937         eval {
2938             my $conf = $vmdata->{qemu}->{$vmid};
2939             my $vmfw_conf = $vmfw_configs->{$vmid};
2940             return if !$vmfw_conf;
2941
2942             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf);
2943
2944             foreach my $netid (keys %$conf) {
2945                 next if $netid !~ m/^net(\d+)$/;
2946                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
2947                 next if !$net->{firewall};
2948                 my $iface = "tap${vmid}i$1";
2949
2950                 my $macaddr = $net->{macaddr};
2951                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
2952                                              $vmfw_conf, $vmid, 'IN', $ipversion);
2953                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
2954                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
2955             }
2956         };
2957         warn $@ if $@; # just to be sure - should not happen
2958     }
2959
2960     # generate firewall rules for OpenVZ containers
2961     foreach my $vmid (keys %{$vmdata->{openvz}}) {
2962         eval {
2963             my $conf = $vmdata->{openvz}->{$vmid};
2964
2965             my $vmfw_conf = $vmfw_configs->{$vmid};
2966             return if !$vmfw_conf;
2967
2968             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf);
2969
2970             if ($vmfw_conf->{options}->{enable}) {
2971                 if ($conf->{ip_address} && $conf->{ip_address}->{value}) {
2972                     my $ip = $conf->{ip_address}->{value};
2973                     $ip =~ s/\s+/,/g;
2974
2975                     my @ips = ();
2976
2977                     foreach my $singleip (split(',', $ip)) {
2978                         my $singleip_ver = parse_address_list($singleip); # make sure we have a valid $ip list
2979                         push @{$cluster_conf->{ipset}->{venet0}}, { cidr => $singleip };
2980                         push @ips, $singleip if $singleip_ver == $ipversion;
2981                     }
2982
2983                     if (scalar(@ips)) {
2984                         my $ip_list = join(',', @ips);
2985                         generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip_list, 'IN', $ipversion);
2986                         generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip_list, 'OUT', $ipversion);
2987                     }
2988                 }
2989             }
2990
2991             if ($conf->{netif} && $conf->{netif}->{value}) {
2992                 my $netif = PVE::OpenVZ::parse_netif($conf->{netif}->{value});
2993                 foreach my $netid (keys %$netif) {
2994                     my $d = $netif->{$netid};
2995                     my $bridge = $d->{bridge};
2996                     next if !$bridge || $bridge !~ m/^vmbr\d+(v(\d+))?f$/; # firewall enabled ?
2997                     my $macaddr = $d->{mac};
2998                     my $iface = $d->{host_ifname};
2999                     generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3000                                                  $vmfw_conf, $vmid, 'IN', $ipversion);
3001                     generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3002                                                  $vmfw_conf, $vmid, 'OUT', $ipversion);
3003                 }
3004             }
3005         };
3006         warn $@ if $@; # just to be sure - should not happen
3007     }
3008
3009     if(ruleset_chain_exist($ruleset, "PVEFW-IPS")){
3010         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED -j PVEFW-IPS");
3011     }
3012
3013     generate_ipset_chains($ipset_ruleset, undef, $cluster_conf);
3014
3015     return ($ruleset, $ipset_ruleset);
3016 }
3017
3018 sub get_ruleset_status {
3019     my ($ruleset, $active_chains, $digest_fn, $verbose) = @_;
3020
3021     my $statushash = {};
3022
3023     foreach my $chain (sort keys %$ruleset) {
3024         my $sig = &$digest_fn($ruleset->{$chain});
3025
3026         $statushash->{$chain}->{sig} = $sig;
3027
3028         my $oldsig = $active_chains->{$chain};
3029         if (!defined($oldsig)) {
3030             $statushash->{$chain}->{action} = 'create';
3031         } else {
3032             if ($oldsig eq $sig) {
3033                 $statushash->{$chain}->{action} = 'exists';
3034             } else {
3035                 $statushash->{$chain}->{action} = 'update';
3036             }
3037         }
3038         print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
3039         foreach my $cmd (@{$ruleset->{$chain}}) {
3040             print "\t$cmd\n" if $verbose;
3041         }
3042     }
3043
3044     foreach my $chain (sort keys %$active_chains) {
3045         if (!defined($ruleset->{$chain})) {
3046             my $sig = $active_chains->{$chain};
3047             $statushash->{$chain}->{action} = 'delete';
3048             $statushash->{$chain}->{sig} = $sig;
3049             print "delete $chain ($sig)\n" if $verbose;
3050         }
3051     }
3052
3053     return $statushash;
3054 }
3055
3056 sub print_sig_rule {
3057     my ($chain, $sig) = @_;
3058
3059     # We just use this to store a SHA1 checksum used to detect changes
3060     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
3061 }
3062
3063 sub get_ruleset_cmdlist {
3064     my ($ruleset, $verbose) = @_;
3065
3066     my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
3067
3068     my ($active_chains, $hooks) = iptables_get_chains();
3069     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, $verbose);
3070
3071     # create missing chains first
3072     foreach my $chain (sort keys %$ruleset) {
3073         my $stat = $statushash->{$chain};
3074         die "internal error" if !$stat;
3075         next if $stat->{action} ne 'create';
3076
3077         $cmdlist .= ":$chain - [0:0]\n";
3078     }
3079
3080     foreach my $h (qw(INPUT OUTPUT FORWARD)) {
3081         my $chain = "PVEFW-$h";
3082         if ($ruleset->{$chain} && !$hooks->{$h}) {
3083             $cmdlist .= "-A $h -j $chain\n";
3084         }
3085     }
3086
3087     foreach my $chain (sort keys %$ruleset) {
3088         my $stat = $statushash->{$chain};
3089         die "internal error" if !$stat;
3090
3091         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
3092             $cmdlist .= "-F $chain\n";
3093             foreach my $cmd (@{$ruleset->{$chain}}) {
3094                 $cmdlist .= "$cmd\n";
3095             }
3096             $cmdlist .= print_sig_rule($chain, $stat->{sig});
3097         } elsif ($stat->{action} eq 'delete') {
3098             die "internal error"; # this should not happen
3099         } elsif ($stat->{action} eq 'exists') {
3100             # do nothing
3101         } else {
3102             die "internal error - unknown status '$stat->{action}'";
3103         }
3104     }
3105
3106     foreach my $chain (keys %$statushash) {
3107         next if $statushash->{$chain}->{action} ne 'delete';
3108         $cmdlist .= "-F $chain\n";
3109     }
3110     foreach my $chain (keys %$statushash) {
3111         next if $statushash->{$chain}->{action} ne 'delete';
3112         next if $chain eq 'PVEFW-INPUT';
3113         next if $chain eq 'PVEFW-OUTPUT';
3114         next if $chain eq 'PVEFW-FORWARD';
3115         $cmdlist .= "-X $chain\n";
3116     }
3117
3118     my $changes = $cmdlist ne "*filter\n" ? 1 : 0;
3119
3120     $cmdlist .= "COMMIT\n";
3121
3122     return wantarray ? ($cmdlist, $changes) : $cmdlist;
3123 }
3124
3125 sub get_ipset_cmdlist {
3126     my ($ruleset, $verbose) = @_;
3127
3128     my $cmdlist = "";
3129
3130     my $delete_cmdlist = "";
3131
3132     my $active_chains = ipset_get_chains();
3133     my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest, $verbose);
3134
3135     # remove stale _swap chains
3136     foreach my $chain (keys %$active_chains) {
3137         if ($chain =~ m/^PVEFW-\S+_swap$/) {
3138             $cmdlist .= "destroy $chain\n";
3139         }
3140     }
3141
3142     foreach my $chain (sort keys %$ruleset) {
3143         my $stat = $statushash->{$chain};
3144         die "internal error" if !$stat;
3145
3146         if ($stat->{action} eq 'create') {
3147             foreach my $cmd (@{$ruleset->{$chain}}) {
3148                 $cmdlist .= "$cmd\n";
3149             }
3150         }
3151
3152         if ($stat->{action} eq 'update') {
3153             my $chain_swap = $chain."_swap";
3154
3155             foreach my $cmd (@{$ruleset->{$chain}}) {
3156                 $cmd =~ s/$chain/$chain_swap/;
3157                 $cmdlist .= "$cmd\n";
3158             }
3159             $cmdlist .= "swap $chain_swap $chain\n";
3160             $cmdlist .= "flush $chain_swap\n";
3161             $cmdlist .= "destroy $chain_swap\n";
3162         }
3163
3164     }
3165
3166     foreach my $chain (keys %$statushash) {
3167         next if $statushash->{$chain}->{action} ne 'delete';
3168
3169         $delete_cmdlist .= "flush $chain\n";
3170         $delete_cmdlist .= "destroy $chain\n";
3171     }
3172
3173     my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
3174
3175     return ($cmdlist, $delete_cmdlist, $changes);
3176 }
3177
3178 sub apply_ruleset {
3179     my ($ruleset, $hostfw_conf, $ipset_ruleset, $verbose) = @_;
3180
3181     enable_bridge_firewall();
3182
3183     my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
3184         get_ipset_cmdlist($ipset_ruleset, undef, $verbose);
3185
3186     my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset, $verbose);
3187
3188     if ($verbose) {
3189         if ($ipset_changes) {
3190             print "ipset changes:\n";
3191             print $ipset_create_cmdlist if $ipset_create_cmdlist;
3192             print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
3193         }
3194
3195         if ($changes) {
3196             print "iptables changes:\n";
3197             print $cmdlist;
3198         }
3199     }
3200
3201     ipset_restore_cmdlist($ipset_create_cmdlist);
3202
3203     iptables_restore_cmdlist($cmdlist);
3204
3205     ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
3206
3207     # test: re-read status and check if everything is up to date
3208     my $active_chains = iptables_get_chains();
3209     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, 0);
3210
3211     my $errors;
3212     foreach my $chain (sort keys %$ruleset) {
3213         my $stat = $statushash->{$chain};
3214         if ($stat->{action} ne 'exists') {
3215             warn "unable to update chain '$chain'\n";
3216             $errors = 1;
3217         }
3218     }
3219
3220     die "unable to apply firewall changes\n" if $errors;
3221
3222     update_nf_conntrack_max($hostfw_conf);
3223
3224     update_nf_conntrack_tcp_timeout_established($hostfw_conf);
3225
3226 }
3227
3228 sub update_nf_conntrack_max {
3229     my ($hostfw_conf) = @_;
3230
3231     my $max = 65536; # reasonable default
3232
3233     my $options = $hostfw_conf->{options} || {};
3234
3235     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
3236         $max = $options->{nf_conntrack_max};
3237         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
3238     }
3239
3240     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
3241     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
3242
3243     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
3244
3245     if ($current != $max) {
3246         my $hashsize = int($max/4);
3247         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
3248         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
3249     }
3250 }
3251
3252 sub update_nf_conntrack_tcp_timeout_established {
3253     my ($hostfw_conf) = @_;
3254
3255     my $options = $hostfw_conf->{options} || {};
3256
3257     my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
3258
3259     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
3260 }
3261
3262 sub remove_pvefw_chains {
3263
3264     my ($chash, $hooks) = iptables_get_chains();
3265     my $cmdlist = "*filter\n";
3266
3267     foreach my $h (qw(INPUT OUTPUT FORWARD)) {
3268         if ($hooks->{$h}) {
3269             $cmdlist .= "-D $h -j PVEFW-$h\n";
3270         }
3271     }
3272
3273     foreach my $chain (keys %$chash) {
3274         $cmdlist .= "-F $chain\n";
3275     }
3276
3277     foreach my $chain (keys %$chash) {
3278         $cmdlist .= "-X $chain\n";
3279     }
3280     $cmdlist .= "COMMIT\n";
3281
3282     iptables_restore_cmdlist($cmdlist);
3283
3284     my $ipset_chains = ipset_get_chains();
3285
3286     $cmdlist = "";
3287  
3288     foreach my $chain (keys %$ipset_chains) {
3289        $cmdlist .= "flush $chain\n";
3290        $cmdlist .= "destroy $chain\n";
3291     }
3292
3293     ipset_restore_cmdlist($cmdlist) if $cmdlist; 
3294 }
3295
3296 sub init {
3297     my $cluster_conf = load_clusterfw_conf();
3298     my $cluster_options = $cluster_conf->{options};
3299     my $enable = $cluster_options->{enable};
3300
3301     return if !$enable;
3302
3303     # load required modules here
3304 }
3305
3306 sub update {
3307     my $code = sub {
3308
3309         my $cluster_conf = load_clusterfw_conf();
3310         my $cluster_options = $cluster_conf->{options};
3311
3312         if (!$cluster_options->{enable}) {
3313             PVE::Firewall::remove_pvefw_chains();
3314             return;
3315         }
3316
3317         my $hostfw_conf = load_hostfw_conf();
3318
3319         my ($ruleset, $ipset_ruleset) = compile($cluster_conf, $hostfw_conf);
3320
3321         apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset);
3322     };
3323
3324     run_locked($code);
3325 }
3326
3327 1;