]> git.proxmox.com Git - pve-firewall.git/blob - src/PVE/Firewall.pm
projects / pve-firewall.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
avoid error about undefined array
[pve-firewall.git] / src / PVE / Firewall.pm
1 package PVE::Firewall;
2
3 use warnings;
4 use strict;
5 use POSIX;
6 use Data::Dumper;
7 use Digest::SHA;
8 use PVE::INotify;
9 use PVE::Exception qw(raise raise_param_exc);
10 use PVE::JSONSchema qw(register_standard_option get_standard_option);
11 use PVE::Cluster;
12 use PVE::ProcFSTools;
13 use PVE::Tools qw($IPV4RE);
14 use File::Basename;
15 use File::Path;
16 use IO::File;
17 use Net::IP;
18 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
19 use Encode;
20
21 my $hostfw_conf_filename = "/etc/pve/local/host.fw";
22 my $clusterfw_conf_filename = "/etc/pve/firewall/cluster.fw";
23
24 # dynamically include PVE::QemuServer and PVE::OpenVZ
25 # to avoid dependency problems
26 my $have_qemu_server;
27 eval {
28 require PVE::QemuServer;
29 $have_qemu_server = 1;
30 };
31
32 my $have_pve_manager;
33 eval {
34 require PVE::OpenVZ;
35 $have_pve_manager = 1;
36 };
37
38 PVE::JSONSchema::register_format('IPv4orCIDR', \&pve_verify_ipv4_or_cidr);
39 sub pve_verify_ipv4_or_cidr {
40 my ($cidr, $noerr) = @_;
41
42 if ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
43 return $cidr if Net::IP->new($cidr);
44 return undef if $noerr;
45 die Net::IP::Error() . "\n";
46 }
47 return undef if $noerr;
48 die "value does not look like a valid IP address or CIDR network\n";
49 }
50
51 PVE::JSONSchema::register_standard_option('ipset-name', {
52 description => "IP set name.",
53 type => 'string',
54 pattern => '[A-Za-z][A-Za-z0-9\-\_]+',
55 minLength => 2,
56 maxLength => 20,
57 });
58
59 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
60 description => "Alias name.",
61 type => 'string',
62 pattern => '[A-Za-z][A-Za-z0-9\-\_]+',
63 minLength => 2,
64 maxLength => 20,
65 });
66
67 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
68 description => "Log level.",
69 type => 'string',
70 enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
71 optional => 1,
72 });
73
74 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
75 my $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
76
77 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
78 description => "Security Group name.",
79 type => 'string',
80 pattern => $security_group_name_pattern,
81 minLength => 2,
82 maxLength => 20,
83 });
84
85 my $feature_ipset_nomatch = 0;
86 eval {
87 my (undef, undef, $release) = POSIX::uname();
88 if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
89 my ($major, $minor) = ($1, $2);
90 $feature_ipset_nomatch = 1 if ($major > 3) ||
91 ($major == 3 && $minor >= 7);
92 }
93
94 };
95
96 use Data::Dumper;
97
98 my $nodename = PVE::INotify::nodename();
99
100 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
101 my $pve_fw_status_filename = "/var/lib/pve-firewall/pvefw.status";
102
103 my $default_log_level = 'info';
104
105 my $log_level_hash = {
106 debug => 7,
107 info => 6,
108 notice => 5,
109 warning => 4,
110 err => 3,
111 crit => 2,
112 alert => 1,
113 emerg => 0,
114 };
115
116 # imported/converted from: /usr/share/shorewall/macro.*
117 my $pve_fw_macros = {
118 'Amanda' => [
119 "Amanda Backup",
120 { action => 'PARAM', proto => 'udp', dport => '10080' },
121 { action => 'PARAM', proto => 'tcp', dport => '10080' },
122 ],
123 'Auth' => [
124 "Auth (identd) traffic",
125 { action => 'PARAM', proto => 'tcp', dport => '113' },
126 ],
127 'BGP' => [
128 "Border Gateway Protocol traffic",
129 { action => 'PARAM', proto => 'tcp', dport => '179' },
130 ],
131 'BitTorrent' => [
132 "BitTorrent traffic for BitTorrent 3.1 and earlier",
133 { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
134 { action => 'PARAM', proto => 'udp', dport => '6881' },
135 ],
136 'BitTorrent32' => [
137 "BitTorrent traffic for BitTorrent 3.2 and later",
138 { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
139 { action => 'PARAM', proto => 'udp', dport => '6881' },
140 ],
141 'CVS' => [
142 "Concurrent Versions System pserver traffic",
143 { action => 'PARAM', proto => 'tcp', dport => '2401' },
144 ],
145 'Citrix' => [
146 "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
147 { action => 'PARAM', proto => 'tcp', dport => '1494' },
148 { action => 'PARAM', proto => 'udp', dport => '1604' },
149 { action => 'PARAM', proto => 'tcp', dport => '2598' },
150 ],
151 'DAAP' => [
152 "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
153 { action => 'PARAM', proto => 'tcp', dport => '3689' },
154 { action => 'PARAM', proto => 'udp', dport => '3689' },
155 ],
156 'DCC' => [
157 "Distributed Checksum Clearinghouse spam filtering mechanism",
158 { action => 'PARAM', proto => 'tcp', dport => '6277' },
159 ],
160 'DHCPfwd' => [
161 "Forwarded DHCP traffic (bidirectional)",
162 { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
163 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '67:68', sport => '67:68' },
164 ],
165 'DNS' => [
166 "Domain Name System traffic (upd and tcp)",
167 { action => 'PARAM', proto => 'udp', dport => '53' },
168 { action => 'PARAM', proto => 'tcp', dport => '53' },
169 ],
170 'Distcc' => [
171 "Distributed Compiler service",
172 { action => 'PARAM', proto => 'tcp', dport => '3632' },
173 ],
174 'FTP' => [
175 "File Transfer Protocol",
176 { action => 'PARAM', proto => 'tcp', dport => '21' },
177 ],
178 'Finger' => [
179 "Finger protocol (RFC 742)",
180 { action => 'PARAM', proto => 'tcp', dport => '79' },
181 ],
182 'GNUnet' => [
183 "GNUnet secure peer-to-peer networking traffic",
184 { action => 'PARAM', proto => 'tcp', dport => '2086' },
185 { action => 'PARAM', proto => 'udp', dport => '2086' },
186 { action => 'PARAM', proto => 'tcp', dport => '1080' },
187 { action => 'PARAM', proto => 'udp', dport => '1080' },
188 ],
189 'GRE' => [
190 "Generic Routing Encapsulation tunneling protocol (bidirectional)",
191 { action => 'PARAM', proto => '47' },
192 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '47' },
193 ],
194 'Git' => [
195 "Git distributed revision control traffic",
196 { action => 'PARAM', proto => 'tcp', dport => '9418' },
197 ],
198 'HKP' => [
199 "OpenPGP HTTP keyserver protocol traffic",
200 { action => 'PARAM', proto => 'tcp', dport => '11371' },
201 ],
202 'HTTP' => [
203 "Hypertext Transfer Protocol (WWW)",
204 { action => 'PARAM', proto => 'tcp', dport => '80' },
205 ],
206 'HTTPS' => [
207 "Hypertext Transfer Protocol (WWW) over SSL",
208 { action => 'PARAM', proto => 'tcp', dport => '443' },
209 ],
210 'ICPV2' => [
211 "Internet Cache Protocol V2 (Squid) traffic",
212 { action => 'PARAM', proto => 'udp', dport => '3130' },
213 ],
214 'ICQ' => [
215 "AOL Instant Messenger traffic",
216 { action => 'PARAM', proto => 'tcp', dport => '5190' },
217 ],
218 'IMAP' => [
219 "Internet Message Access Protocol",
220 { action => 'PARAM', proto => 'tcp', dport => '143' },
221 ],
222 'IMAPS' => [
223 "Internet Message Access Protocol over SSL",
224 { action => 'PARAM', proto => 'tcp', dport => '993' },
225 ],
226 'IPIP' => [
227 "IPIP capsulation traffic (bidirectional)",
228 { action => 'PARAM', proto => '94' },
229 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '94' },
230 ],
231 'IPsec' => [
232 "IPsec traffic (bidirectional)",
233 { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
234 { action => 'PARAM', proto => '50' },
235 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500', sport => '500' },
236 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '50' },
237 ],
238 'IPsecah' => [
239 "IPsec authentication (AH) traffic (bidirectional)",
240 { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
241 { action => 'PARAM', proto => '51' },
242 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500', sport => '500' },
243 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '51' },
244 ],
245 'IPsecnat' => [
246 "IPsec traffic and Nat-Traversal (bidirectional)",
247 { action => 'PARAM', proto => 'udp', dport => '500' },
248 { action => 'PARAM', proto => 'udp', dport => '4500' },
249 { action => 'PARAM', proto => '50' },
250 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500' },
251 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '4500' },
252 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '50' },
253 ],
254 'IRC' => [
255 "Internet Relay Chat traffic",
256 { action => 'PARAM', proto => 'tcp', dport => '6667' },
257 ],
258 'Jetdirect' => [
259 "HP Jetdirect printing",
260 { action => 'PARAM', proto => 'tcp', dport => '9100' },
261 ],
262 'L2TP' => [
263 "Layer 2 Tunneling Protocol traffic",
264 { action => 'PARAM', proto => 'udp', dport => '1701' },
265 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '1701' },
266 ],
267 'LDAP' => [
268 "Lightweight Directory Access Protocol traffic",
269 { action => 'PARAM', proto => 'tcp', dport => '389' },
270 ],
271 'LDAPS' => [
272 "Secure Lightweight Directory Access Protocol traffic",
273 { action => 'PARAM', proto => 'tcp', dport => '636' },
274 ],
275 'MSNP' => [
276 "Microsoft Notification Protocol",
277 { action => 'PARAM', proto => 'tcp', dport => '1863' },
278 ],
279 'MSSQL' => [
280 "Microsoft SQL Server",
281 { action => 'PARAM', proto => 'tcp', dport => '1433' },
282 ],
283 'Mail' => [
284 "Mail traffic (SMTP, SMTPS, Submission)",
285 { action => 'PARAM', proto => 'tcp', dport => '25' },
286 { action => 'PARAM', proto => 'tcp', dport => '465' },
287 { action => 'PARAM', proto => 'tcp', dport => '587' },
288 ],
289 'Munin' => [
290 "Munin networked resource monitoring traffic",
291 { action => 'PARAM', proto => 'tcp', dport => '4949' },
292 ],
293 'MySQL' => [
294 "MySQL server",
295 { action => 'PARAM', proto => 'tcp', dport => '3306' },
296 ],
297 'NNTP' => [
298 "NNTP traffic (Usenet).",
299 { action => 'PARAM', proto => 'tcp', dport => '119' },
300 ],
301 'NNTPS' => [
302 "Encrypted NNTP traffic (Usenet)",
303 { action => 'PARAM', proto => 'tcp', dport => '563' },
304 ],
305 'NTP' => [
306 "Network Time Protocol (ntpd)",
307 { action => 'PARAM', proto => 'udp', dport => '123' },
308 ],
309 'NTPbi' => [
310 "Bi-directional NTP (for NTP peers)",
311 { action => 'PARAM', proto => 'udp', dport => '123' },
312 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '123' },
313 ],
314 'OSPF' => [
315 "OSPF multicast traffic",
316 { action => 'PARAM', proto => '89' },
317 ],
318 'OpenVPN' => [
319 "OpenVPN traffic",
320 { action => 'PARAM', proto => 'udp', dport => '1194' },
321 ],
322 'PCA' => [
323 "Symantec PCAnywere (tm)",
324 { action => 'PARAM', proto => 'udp', dport => '5632' },
325 { action => 'PARAM', proto => 'tcp', dport => '5631' },
326 ],
327 'POP3' => [
328 "POP3 traffic",
329 { action => 'PARAM', proto => 'tcp', dport => '110' },
330 ],
331 'POP3S' => [
332 "Encrypted POP3 traffic",
333 { action => 'PARAM', proto => 'tcp', dport => '995' },
334 ],
335 'PPtP' => [
336 "Point-to-Point Tunneling Protocol",
337 { action => 'PARAM', proto => '47' },
338 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '47' },
339 { action => 'PARAM', proto => 'tcp', dport => '1723' },
340 ],
341 'Ping' => [
342 "ICMP echo request",
343 { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
344 ],
345 'PostgreSQL' => [
346 "PostgreSQL server",
347 { action => 'PARAM', proto => 'tcp', dport => '5432' },
348 ],
349 'Printer' => [
350 "Line Printer protocol printing",
351 { action => 'PARAM', proto => 'tcp', dport => '515' },
352 ],
353 'RDP' => [
354 "Microsoft Remote Desktop Protocol traffic",
355 { action => 'PARAM', proto => 'tcp', dport => '3389' },
356 ],
357 'RIPbi' => [
358 "Routing Information Protocol (bidirectional)",
359 { action => 'PARAM', proto => 'udp', dport => '520' },
360 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '520' },
361 ],
362 'RNDC' => [
363 "BIND remote management protocol",
364 { action => 'PARAM', proto => 'tcp', dport => '953' },
365 ],
366 'Razor' => [
367 "Razor Antispam System",
368 { action => 'ACCEPT', proto => 'tcp', dport => '2703' },
369 ],
370 'Rdate' => [
371 "Remote time retrieval (rdate)",
372 { action => 'PARAM', proto => 'tcp', dport => '37' },
373 ],
374 'Rsync' => [
375 "Rsync server",
376 { action => 'PARAM', proto => 'tcp', dport => '873' },
377 ],
378 'SANE' => [
379 "SANE network scanning",
380 { action => 'PARAM', proto => 'tcp', dport => '6566' },
381 ],
382 'SMB' => [
383 "Microsoft SMB traffic",
384 { action => 'PARAM', proto => 'udp', dport => '135,445' },
385 { action => 'PARAM', proto => 'udp', dport => '137:139' },
386 { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
387 { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
388 ],
389 'SMBBI' => [
390 "Microsoft SMB traffic (bidirectional)",
391 { action => 'PARAM', proto => 'udp', dport => '135,445' },
392 { action => 'PARAM', proto => 'udp', dport => '137:139' },
393 { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
394 { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
395 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '135,445' },
396 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '137:139' },
397 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '1024:65535', sport => '137' },
398 { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'tcp', dport => '135,139,445' },
399 ],
400 'SMBswat' => [
401 "Samba Web Administration Tool",
402 { action => 'PARAM', proto => 'tcp', dport => '901' },
403 ],
404 'SMTP' => [
405 "Simple Mail Transfer Protocol",
406 { action => 'PARAM', proto => 'tcp', dport => '25' },
407 ],
408 'SMTPS' => [
409 "Encrypted Simple Mail Transfer Protocol",
410 { action => 'PARAM', proto => 'tcp', dport => '465' },
411 ],
412 'SNMP' => [
413 "Simple Network Management Protocol",
414 { action => 'PARAM', proto => 'udp', dport => '161:162' },
415 { action => 'PARAM', proto => 'tcp', dport => '161' },
416 ],
417 'SPAMD' => [
418 "Spam Assassin SPAMD traffic",
419 { action => 'PARAM', proto => 'tcp', dport => '783' },
420 ],
421 'SSH' => [
422 "Secure shell traffic",
423 { action => 'PARAM', proto => 'tcp', dport => '22' },
424 ],
425 'SVN' => [
426 "Subversion server (svnserve)",
427 { action => 'PARAM', proto => 'tcp', dport => '3690' },
428 ],
429 'SixXS' => [
430 "SixXS IPv6 Deployment and Tunnel Broker",
431 { action => 'PARAM', proto => 'tcp', dport => '3874' },
432 { action => 'PARAM', proto => 'udp', dport => '3740' },
433 { action => 'PARAM', proto => '41' },
434 { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
435 ],
436 'Squid' => [
437 "Squid web proxy traffic",
438 { action => 'PARAM', proto => 'tcp', dport => '3128' },
439 ],
440 'Submission' => [
441 "Mail message submission traffic",
442 { action => 'PARAM', proto => 'tcp', dport => '587' },
443 ],
444 'Syslog' => [
445 "Syslog protocol (RFC 5424) traffic",
446 { action => 'PARAM', proto => 'udp', dport => '514' },
447 { action => 'PARAM', proto => 'tcp', dport => '514' },
448 ],
449 'TFTP' => [
450 "Trivial File Transfer Protocol traffic",
451 { action => 'PARAM', proto => 'udp', dport => '69' },
452 ],
453 'Telnet' => [
454 "Telnet traffic",
455 { action => 'PARAM', proto => 'tcp', dport => '23' },
456 ],
457 'Telnets' => [
458 "Telnet over SSL",
459 { action => 'PARAM', proto => 'tcp', dport => '992' },
460 ],
461 'Time' => [
462 "RFC 868 Time protocol",
463 { action => 'PARAM', proto => 'tcp', dport => '37' },
464 ],
465 'Trcrt' => [
466 "Traceroute (for up to 30 hops) traffic",
467 { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
468 { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
469 ],
470 'VNC' => [
471 "VNC traffic for VNC display's 0 - 9",
472 { action => 'PARAM', proto => 'tcp', dport => '5900:5909' },
473 ],
474 'VNCL' => [
475 "VNC traffic from Vncservers to Vncviewers in listen mode",
476 { action => 'PARAM', proto => 'tcp', dport => '5500' },
477 ],
478 'Web' => [
479 "WWW traffic (HTTP and HTTPS)",
480 { action => 'PARAM', proto => 'tcp', dport => '80' },
481 { action => 'PARAM', proto => 'tcp', dport => '443' },
482 ],
483 'Webcache' => [
484 "Web Cache/Proxy traffic (port 8080)",
485 { action => 'PARAM', proto => 'tcp', dport => '8080' },
486 ],
487 'Webmin' => [
488 "Webmin traffic",
489 { action => 'PARAM', proto => 'tcp', dport => '10000' },
490 ],
491 'Whois' => [
492 "Whois (nicname, RFC 3912) traffic",
493 { action => 'PARAM', proto => 'tcp', dport => '43' },
494 ],
495 };
496
497 my $pve_fw_parsed_macros;
498 my $pve_fw_macro_descr;
499 my $pve_fw_preferred_macro_names = {};
500
501 my $pve_std_chains = {
502 'PVEFW-SET-ACCEPT-MARK' => [
503 "-j MARK --set-mark 1",
504 ],
505 'PVEFW-DropBroadcast' => [
506 # same as shorewall 'Broadcast'
507 # simply DROP BROADCAST/MULTICAST/ANYCAST
508 # we can use this to reduce logging
509 { action => 'DROP', dsttype => 'BROADCAST' },
510 { action => 'DROP', dsttype => 'MULTICAST' },
511 { action => 'DROP', dsttype => 'ANYCAST' },
512 { action => 'DROP', dest => '224.0.0.0/4' },
513 ],
514 'PVEFW-reject' => [
515 # same as shorewall 'reject'
516 { action => 'DROP', dsttype => 'BROADCAST' },
517 { action => 'DROP', source => '224.0.0.0/4' },
518 { action => 'DROP', proto => 'icmp' },
519 "-p tcp -j REJECT --reject-with tcp-reset",
520 "-p udp -j REJECT --reject-with icmp-port-unreachable",
521 "-p icmp -j REJECT --reject-with icmp-host-unreachable",
522 "-j REJECT --reject-with icmp-host-prohibited",
523 ],
524 'PVEFW-Drop' => [
525 # same as shorewall 'Drop', which is equal to DROP,
526 # but REJECT/DROP some packages to reduce logging,
527 # and ACCEPT critical ICMP types
528 { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
529 # we are not interested in BROADCAST/MULTICAST/ANYCAST
530 { action => 'PVEFW-DropBroadcast' },
531 # ACCEPT critical ICMP types
532 { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
533 { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
534 # Drop packets with INVALID state
535 "-m conntrack --ctstate INVALID -j DROP",
536 # Drop Microsoft SMB noise
537 { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
538 { action => 'DROP', proto => 'udp', dport => '137:139'},
539 { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
540 { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
541 { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
542 # Drop new/NotSyn traffic so that it doesn't get logged
543 "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
544 # Drop DNS replies
545 { action => 'DROP', proto => 'udp', sport => 53 },
546 ],
547 'PVEFW-Reject' => [
548 # same as shorewall 'Reject', which is equal to Reject,
549 # but REJECT/DROP some packages to reduce logging,
550 # and ACCEPT critical ICMP types
551 { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
552 # we are not interested in BROADCAST/MULTICAST/ANYCAST
553 { action => 'PVEFW-DropBroadcast' },
554 # ACCEPT critical ICMP types
555 { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
556 { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
557 # Drop packets with INVALID state
558 "-m conntrack --ctstate INVALID -j DROP",
559 # Drop Microsoft SMB noise
560 { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
561 { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
562 { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
563 { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
564 { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
565 # Drop new/NotSyn traffic so that it doesn't get logged
566 "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
567 # Drop DNS replies
568 { action => 'DROP', proto => 'udp', sport => 53 },
569 ],
570 'PVEFW-tcpflags' => [
571 # same as shorewall tcpflags action.
572 # Packets arriving on this interface are checked for som illegal combinations of TCP flags
573 "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
574 "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
575 "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
576 "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
577 "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
578 ],
579 'PVEFW-smurfs' => [
580 # same as shorewall smurfs action
581 # Filter packets for smurfs (packets with a broadcast address as the source).
582 "-s 0.0.0.0/32 -j RETURN",
583 "-m addrtype --src-type BROADCAST -g PVEFW-smurflog",
584 "-s 224.0.0.0/4 -g PVEFW-smurflog",
585 ],
586 };
587
588 # iptables -p icmp -h
589 my $icmp_type_names = {
590 any => 1,
591 'echo-reply' => 1,
592 'destination-unreachable' => 1,
593 'network-unreachable' => 1,
594 'host-unreachable' => 1,
595 'protocol-unreachable' => 1,
596 'port-unreachable' => 1,
597 'fragmentation-needed' => 1,
598 'source-route-failed' => 1,
599 'network-unknown' => 1,
600 'host-unknown' => 1,
601 'network-prohibited' => 1,
602 'host-prohibited' => 1,
603 'TOS-network-unreachable' => 1,
604 'TOS-host-unreachable' => 1,
605 'communication-prohibited' => 1,
606 'host-precedence-violation' => 1,
607 'precedence-cutoff' => 1,
608 'source-quench' => 1,
609 'redirect' => 1,
610 'network-redirect' => 1,
611 'host-redirect' => 1,
612 'TOS-network-redirect' => 1,
613 'TOS-host-redirect' => 1,
614 'echo-request' => 1,
615 'router-advertisement' => 1,
616 'router-solicitation' => 1,
617 'time-exceeded' => 1,
618 'ttl-zero-during-transit' => 1,
619 'ttl-zero-during-reassembly' => 1,
620 'parameter-problem' => 1,
621 'ip-header-bad' => 1,
622 'required-option-missing' => 1,
623 'timestamp-request' => 1,
624 'timestamp-reply' => 1,
625 'address-mask-request' => 1,
626 'address-mask-reply' => 1,
627 };
628
629 sub init_firewall_macros {
630
631 $pve_fw_parsed_macros = {};
632
633 foreach my $k (keys %$pve_fw_macros) {
634 my $lc_name = lc($k);
635 my $macro = $pve_fw_macros->{$k};
636 if (!ref($macro->[0])) {
637 $pve_fw_macro_descr->{$k} = shift @$macro;
638 }
639 $pve_fw_preferred_macro_names->{$lc_name} = $k;
640 $pve_fw_parsed_macros->{$k} = $macro;
641 }
642 }
643
644 init_firewall_macros();
645
646 sub get_macros {
647 return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
648 }
649
650 my $etc_services;
651
652 sub get_etc_services {
653
654 return $etc_services if $etc_services;
655
656 my $filename = "/etc/services";
657
658 my $fh = IO::File->new($filename, O_RDONLY);
659 if (!$fh) {
660 warn "unable to read '$filename' - $!\n";
661 return {};
662 }
663
664 my $services = {};
665
666 while (my $line = <$fh>) {
667 chomp ($line);
668 next if $line =~m/^#/;
669 next if ($line =~m/^\s*$/);
670
671 if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
672 $services->{byid}->{$2}->{name} = $1;
673 $services->{byid}->{$2}->{port} = $2;
674 $services->{byid}->{$2}->{$3} = 1;
675 $services->{byname}->{$1} = $services->{byid}->{$2};
676 }
677 }
678
679 close($fh);
680
681 $etc_services = $services;
682
683
684 return $etc_services;
685 }
686
687 my $etc_protocols;
688
689 sub get_etc_protocols {
690 return $etc_protocols if $etc_protocols;
691
692 my $filename = "/etc/protocols";
693
694 my $fh = IO::File->new($filename, O_RDONLY);
695 if (!$fh) {
696 warn "unable to read '$filename' - $!\n";
697 return {};
698 }
699
700 my $protocols = {};
701
702 while (my $line = <$fh>) {
703 chomp ($line);
704 next if $line =~m/^#/;
705 next if ($line =~m/^\s*$/);
706
707 if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
708 $protocols->{byid}->{$2}->{name} = $1;
709 $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
710 }
711 }
712
713 close($fh);
714
715 $etc_protocols = $protocols;
716
717 return $etc_protocols;
718 }
719
720 sub parse_address_list {
721 my ($str) = @_;
722
723 return if $str =~ m/^(\+)(\S+)$/; # ipset ref
724 return if $str =~ m/^${ip_alias_pattern}$/;
725
726 my $count = 0;
727 my $iprange = 0;
728 foreach my $elem (split(/,/, $str)) {
729 $count++;
730 if (!Net::IP->new($elem)) {
731 my $err = Net::IP::Error();
732 die "invalid IP address: $err\n";
733 }
734 $iprange = 1 if $elem =~ m/-/;
735 }
736
737 die "you can use a range in a list\n" if $iprange && $count > 1;
738 }
739
740 sub parse_port_name_number_or_range {
741 my ($str) = @_;
742
743 my $services = PVE::Firewall::get_etc_services();
744 my $count = 0;
745 my $icmp_port = 0;
746
747 foreach my $item (split(/,/, $str)) {
748 $count++;
749 if ($item =~ m/^(\d+):(\d+)$/) {
750 my ($port1, $port2) = ($1, $2);
751 die "invalid port '$port1'\n" if $port1 > 65535;
752 die "invalid port '$port2'\n" if $port2 > 65535;
753 } elsif ($item =~ m/^(\d+)$/) {
754 my $port = $1;
755 die "invalid port '$port'\n" if $port > 65535;
756 } else {
757 if ($icmp_type_names->{$item}) {
758 $icmp_port = 1;
759 } else {
760 die "invalid port '$item'\n" if !$services->{byname}->{$item};
761 }
762 }
763 }
764
765 die "ICPM ports not allowed in port range\n" if $icmp_port && $count > 1;
766
767 return $count;
768 }
769
770 PVE::JSONSchema::register_format('pve-fw-port-spec', \&pve_fw_verify_port_spec);
771 sub pve_fw_verify_port_spec {
772 my ($portstr) = @_;
773
774 parse_port_name_number_or_range($portstr);
775
776 return $portstr;
777 }
778
779 PVE::JSONSchema::register_format('pve-fw-v4addr-spec', \&pve_fw_verify_v4addr_spec);
780 sub pve_fw_verify_v4addr_spec {
781 my ($list) = @_;
782
783 parse_address_list($list);
784
785 return $list;
786 }
787
788 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
789 sub pve_fw_verify_protocol_spec {
790 my ($proto) = @_;
791
792 my $protocols = get_etc_protocols();
793
794 die "unknown protocol '$proto'\n" if $proto &&
795 !(defined($protocols->{byname}->{$proto}) ||
796 defined($protocols->{byid}->{$proto}));
797
798 return $proto;
799 }
800
801
802 # helper function for API
803
804 sub copy_opject_with_digest {
805 my ($object) = @_;
806
807 my $sha = Digest::SHA->new('sha1');
808
809 my $res = {};
810 foreach my $k (sort keys %$object) {
811 my $v = $object->{$k};
812 next if !defined($v);
813 $res->{$k} = $v;
814 $sha->add($k, ':', $v, "\n");
815 }
816
817 my $digest = $sha->b64digest;
818
819 $res->{digest} = $digest;
820
821 return wantarray ? ($res, $digest) : $res;
822 }
823
824 sub copy_list_with_digest {
825 my ($list) = @_;
826
827 my $sha = Digest::SHA->new('sha1');
828
829 my $res = [];
830 foreach my $entry (@$list) {
831 my $data = {};
832 foreach my $k (sort keys %$entry) {
833 my $v = $entry->{$k};
834 next if !defined($v);
835 $data->{$k} = $v;
836 $sha->add($k, ':', $v, "\n");
837 }
838 push @$res, $data;
839 }
840
841 my $digest = $sha->b64digest;
842
843 foreach my $entry (@$res) {
844 $entry->{digest} = $digest;
845 }
846
847 return wantarray ? ($res, $digest) : $res;
848 }
849
850 my $rule_properties = {
851 pos => {
852 description => "Update rule at position <pos>.",
853 type => 'integer',
854 minimum => 0,
855 optional => 1,
856 },
857 digest => get_standard_option('pve-config-digest'),
858 type => {
859 type => 'string',
860 optional => 1,
861 enum => ['in', 'out', 'group'],
862 },
863 action => {
864 description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
865 type => 'string',
866 optional => 1,
867 pattern => $security_group_name_pattern,
868 maxLength => 20,
869 minLength => 2,
870 },
871 macro => {
872 type => 'string',
873 optional => 1,
874 maxLength => 128,
875 },
876 iface => get_standard_option('pve-iface', { optional => 1 }),
877 source => {
878 type => 'string', format => 'pve-fw-v4addr-spec',
879 optional => 1,
880 },
881 dest => {
882 type => 'string', format => 'pve-fw-v4addr-spec',
883 optional => 1,
884 },
885 proto => {
886 type => 'string', format => 'pve-fw-protocol-spec',
887 optional => 1,
888 },
889 enable => {
890 type => 'boolean',
891 optional => 1,
892 },
893 sport => {
894 type => 'string', format => 'pve-fw-port-spec',
895 optional => 1,
896 },
897 dport => {
898 type => 'string', format => 'pve-fw-port-spec',
899 optional => 1,
900 },
901 comment => {
902 type => 'string',
903 optional => 1,
904 },
905 };
906
907 sub add_rule_properties {
908 my ($properties) = @_;
909
910 foreach my $k (keys %$rule_properties) {
911 my $h = $rule_properties->{$k};
912 # copy data, so that we can modify later without side effects
913 foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
914 }
915
916 return $properties;
917 }
918
919 sub delete_rule_properties {
920 my ($rule, $delete_str) = @_;
921
922 foreach my $opt (PVE::Tools::split_list($delete_str)) {
923 raise_param_exc({ 'delete' => "no such property ('$opt')"})
924 if !defined($rule_properties->{$opt});
925 raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
926 if $opt eq 'type' || $opt eq 'action';
927 delete $rule->{$opt};
928 }
929
930 return $rule;
931 }
932
933 my $apply_macro = sub {
934 my ($macro_name, $param, $verify) = @_;
935
936 my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
937 die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
938
939 my $rules = [];
940
941 foreach my $templ (@$macro_rules) {
942 my $rule = {};
943 my $param_used = {};
944 foreach my $k (keys %$templ) {
945 my $v = $templ->{$k};
946 if ($v eq 'PARAM') {
947 $v = $param->{$k};
948 $param_used->{$k} = 1;
949 } elsif ($v eq 'DEST') {
950 $v = $param->{dest};
951 $param_used->{dest} = 1;
952 } elsif ($v eq 'SOURCE') {
953 $v = $param->{source};
954 $param_used->{source} = 1;
955 }
956
957 if (!defined($v)) {
958 my $msg = "missing parameter '$k' in macro '$macro_name'";
959 raise_param_exc({ macro => $msg }) if $verify;
960 die "$msg\n";
961 }
962 $rule->{$k} = $v;
963 }
964 foreach my $k (keys %$param) {
965 next if $k eq 'macro';
966 next if !defined($param->{$k});
967 next if $param_used->{$k};
968 if (defined($rule->{$k})) {
969 if ($rule->{$k} ne $param->{$k}) {
970 my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
971 raise_param_exc({ $k => $msg }) if $verify;
972 die "$msg\n";
973 }
974 } else {
975 $rule->{$k} = $param->{$k};
976 }
977 }
978 push @$rules, $rule;
979 }
980
981 return $rules;
982 };
983
984 sub verify_rule {
985 my ($rule, $allow_groups) = @_;
986
987 my $type = $rule->{type};
988
989 raise_param_exc({ type => "missing property"}) if !$type;
990 raise_param_exc({ action => "missing property"}) if !$rule->{action};
991
992 if ($type eq 'in' || $type eq 'out') {
993 raise_param_exc({ action => "unknown action '$rule->{action}'"})
994 if $rule->{action} !~ m/^(ACCEPT|DROP|REJECT)$/;
995 } elsif ($type eq 'group') {
996 raise_param_exc({ type => "security groups not allowed"})
997 if !$allow_groups;
998 raise_param_exc({ action => "invalid characters in security group name"})
999 if $rule->{action} !~ m/^${security_group_name_pattern}$/;
1000 } else {
1001 raise_param_exc({ type => "unknown rule type '$type'"});
1002 }
1003
1004 # fixme: verify $rule->{iface}?
1005
1006 if ($rule->{macro}) {
1007 my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})};
1008 raise_param_exc({ macro => "unknown macro '$rule->{macro}'"}) if !$preferred_name;
1009 $rule->{macro} = $preferred_name;
1010 }
1011
1012 if ($rule->{dport}) {
1013 eval { parse_port_name_number_or_range($rule->{dport}); };
1014 raise_param_exc({ dport => $@ }) if $@;
1015 }
1016
1017 if ($rule->{sport}) {
1018 eval { parse_port_name_number_or_range($rule->{sport}); };
1019 raise_param_exc({ sport => $@ }) if $@;
1020 }
1021
1022 if ($rule->{source}) {
1023 eval { parse_address_list($rule->{source}); };
1024 raise_param_exc({ source => $@ }) if $@;
1025 }
1026
1027 if ($rule->{dest}) {
1028 eval { parse_address_list($rule->{dest}); };
1029 raise_param_exc({ dest => $@ }) if $@;
1030 }
1031
1032 if ($rule->{macro}) {
1033 &$apply_macro($rule->{macro}, $rule, 1);
1034 }
1035
1036 return $rule;
1037 }
1038
1039 sub copy_rule_data {
1040 my ($rule, $param) = @_;
1041
1042 foreach my $k (keys %$rule_properties) {
1043 if (defined(my $v = $param->{$k})) {
1044 if ($v eq '' || $v eq '-') {
1045 delete $rule->{$k};
1046 } else {
1047 $rule->{$k} = $v;
1048 }
1049 } else {
1050 delete $rule->{$k};
1051 }
1052 }
1053
1054 # verify rule now
1055
1056 return $rule;
1057 }
1058
1059 # core functions
1060 my $bridge_firewall_enabled = 0;
1061
1062 sub enable_bridge_firewall {
1063
1064 return if $bridge_firewall_enabled; # only once
1065
1066 PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1067 PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1068
1069 # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1070 PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1071
1072 $bridge_firewall_enabled = 1;
1073 }
1074
1075 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
1076
1077 sub iptables_restore_cmdlist {
1078 my ($cmdlist) = @_;
1079
1080 run_command("/sbin/iptables-restore -n", input => $cmdlist);
1081 }
1082
1083 sub ipset_restore_cmdlist {
1084 my ($cmdlist) = @_;
1085
1086 run_command("/usr/sbin/ipset restore", input => $cmdlist);
1087 }
1088
1089 sub iptables_get_chains {
1090
1091 my $res = {};
1092
1093 # check what chains we want to track
1094 my $is_pvefw_chain = sub {
1095 my $name = shift;
1096
1097 return 1 if $name =~ m/^PVEFW-\S+$/;
1098
1099 return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
1100
1101 return 1 if $name =~ m/^veth\d+.\d+-(:?IN|OUT)$/; # fixme: dev name is configurable
1102
1103 return 1 if $name =~ m/^venet0-\d+-(:?IN|OUT)$/;
1104
1105 return 1 if $name =~ m/^vmbr\d+(v\d+)?-(:?FW|IN|OUT|IPS)$/;
1106 return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
1107
1108 return undef;
1109 };
1110
1111 my $table = '';
1112
1113 my $hooks = {};
1114
1115 my $parser = sub {
1116 my $line = shift;
1117
1118 return if $line =~ m/^#/;
1119 return if $line =~ m/^\s*$/;
1120
1121 if ($line =~ m/^\*(\S+)$/) {
1122 $table = $1;
1123 return;
1124 }
1125
1126 return if $table ne 'filter';
1127
1128 if ($line =~ m/^:(\S+)\s/) {
1129 my $chain = $1;
1130 return if !&$is_pvefw_chain($chain);
1131 $res->{$chain} = "unknown";
1132 } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1133 my ($chain, $sig) = ($1, $2);
1134 return if !&$is_pvefw_chain($chain);
1135 $res->{$chain} = $sig;
1136 } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD)\s+-j\s+PVEFW-\1$/) {
1137 $hooks->{$1} = 1;
1138 } else {
1139 # simply ignore the rest
1140 return;
1141 }
1142 };
1143
1144 run_command("/sbin/iptables-save", outfunc => $parser);
1145
1146 return wantarray ? ($res, $hooks) : $res;
1147 }
1148
1149 sub iptables_chain_digest {
1150 my ($rules) = @_;
1151 my $digest = Digest::SHA->new('sha1');
1152 foreach my $rule (@$rules) { # order is important
1153 $digest->add($rule);
1154 }
1155 return $digest->b64digest;
1156 }
1157
1158 sub ipset_chain_digest {
1159 my ($rules) = @_;
1160
1161 my $digest = Digest::SHA->new('sha1');
1162 foreach my $rule (sort @$rules) { # note: sorted
1163 $digest->add($rule);
1164 }
1165 return $digest->b64digest;
1166 }
1167
1168 sub ipset_get_chains {
1169
1170 my $res = {};
1171 my $chains = {};
1172
1173 my $parser = sub {
1174 my $line = shift;
1175
1176 return if $line =~ m/^#/;
1177 return if $line =~ m/^\s*$/;
1178 if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
1179 my $chain = $1;
1180 $line =~ s/\s+$//; # delete trailing white space
1181 push @{$chains->{$chain}}, $line;
1182 } else {
1183 # simply ignore the rest
1184 return;
1185 }
1186 };
1187
1188 run_command("/usr/sbin/ipset save", outfunc => $parser);
1189
1190 # compute digest for each chain
1191 foreach my $chain (keys %$chains) {
1192 $res->{$chain} = ipset_chain_digest($chains->{$chain});
1193 }
1194
1195 return $res;
1196 }
1197
1198 sub ruleset_generate_cmdstr {
1199 my ($ruleset, $chain, $rule, $actions, $goto, $cluster_conf) = @_;
1200
1201 return if defined($rule->{enable}) && !$rule->{enable};
1202
1203 die "unable to emit macro - internal error" if $rule->{macro}; # should not happen
1204
1205 my $nbdport = defined($rule->{dport}) ? parse_port_name_number_or_range($rule->{dport}) : 0;
1206 my $nbsport = defined($rule->{sport}) ? parse_port_name_number_or_range($rule->{sport}) : 0;
1207
1208 my @cmd = ();
1209
1210 push @cmd, "-i $rule->{iface_in}" if $rule->{iface_in};
1211 push @cmd, "-o $rule->{iface_out}" if $rule->{iface_out};
1212
1213 my $source = $rule->{source};
1214 my $dest = $rule->{dest};
1215
1216 if ($source) {
1217 if ($source =~ m/^\+/) {
1218 if ($source =~ m/^\+(${security_group_name_pattern})$/) {
1219 die "no such ipset '$1'\n" if !$cluster_conf->{ipset}->{$1};
1220 push @cmd, "-m set --match-set PVEFW-$1 src";
1221 } else {
1222 die "invalid security group name '$source'\n";
1223 }
1224 } elsif ($source =~ m/^${ip_alias_pattern}$/){
1225 my $alias = lc($source);
1226 my $e = $cluster_conf->{aliases}->{$alias};
1227 die "no such alias $source\n" if !$e;
1228 push @cmd, "-s $e->{cidr}";
1229 } elsif ($source =~ m/\-/){
1230 push @cmd, "-m iprange --src-range $source";
1231
1232 } else {
1233 push @cmd, "-s $source";
1234 }
1235 }
1236
1237 if ($dest) {
1238 if ($dest =~ m/^\+/) {
1239 if ($dest =~ m/^\+(${security_group_name_pattern})$/) {
1240 die "no such ipset '$1'\n" if !$cluster_conf->{ipset}->{$1};
1241 push @cmd, "-m set --match-set PVEFW-$1 dst";
1242 } else {
1243 die "invalid security group name '$dest'\n";
1244 }
1245 } elsif ($dest =~ m/^${ip_alias_pattern}$/){
1246 my $alias = lc($source);
1247 my $e = $cluster_conf->{aliases}->{$alias};
1248 die "no such alias $dest" if !$e;
1249 push @cmd, "-d $e->{cidr}";
1250 } elsif ($dest =~ m/^(\d+)\.(\d+).(\d+).(\d+)\-(\d+)\.(\d+).(\d+).(\d+)$/){
1251 push @cmd, "-m iprange --dst-range $dest";
1252
1253 } else {
1254 push @cmd, "-d $dest";
1255 }
1256 }
1257
1258 if ($rule->{proto}) {
1259 push @cmd, "-p $rule->{proto}";
1260
1261 my $multiport = 0;
1262 $multiport++ if $nbdport > 1;
1263 $multiport++ if $nbsport > 1;
1264
1265 push @cmd, "--match multiport" if $multiport;
1266
1267 die "multiport: option '--sports' cannot be used together with '--dports'\n"
1268 if ($multiport == 2) && ($rule->{dport} ne $rule->{sport});
1269
1270 if ($rule->{dport}) {
1271 if ($rule->{proto} && $rule->{proto} eq 'icmp') {
1272 # Note: we use dport to store --icmp-type
1273 die "unknown icmp-type '$rule->{dport}'\n" if !defined($icmp_type_names->{$rule->{dport}});
1274 push @cmd, "-m icmp --icmp-type $rule->{dport}";
1275 } else {
1276 if ($nbdport > 1) {
1277 if ($multiport == 2) {
1278 push @cmd, "--ports $rule->{dport}";
1279 } else {
1280 push @cmd, "--dports $rule->{dport}";
1281 }
1282 } else {
1283 push @cmd, "--dport $rule->{dport}";
1284 }
1285 }
1286 }
1287
1288 if ($rule->{sport}) {
1289 if ($nbsport > 1) {
1290 push @cmd, "--sports $rule->{sport}" if $multiport != 2;
1291 } else {
1292 push @cmd, "--sport $rule->{sport}";
1293 }
1294 }
1295 } elsif ($rule->{dport} || $rule->{sport}) {
1296 warn "ignoring destination port '$rule->{dport}' - no protocol specified\n" if $rule->{dport};
1297 warn "ignoring source port '$rule->{sport}' - no protocol specified\n" if $rule->{sport};
1298 }
1299
1300 push @cmd, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
1301
1302 if (my $action = $rule->{action}) {
1303 $action = $actions->{$action} if defined($actions->{$action});
1304 $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
1305 push @cmd, $goto ? "-g $action" : "-j $action";
1306 }
1307
1308 return scalar(@cmd) ? join(' ', @cmd) : undef;
1309 }
1310
1311 sub ruleset_generate_rule {
1312 my ($ruleset, $chain, $rule, $actions, $goto, $cluster_conf) = @_;
1313
1314 my $rules;
1315
1316 if ($rule->{macro}) {
1317 $rules = &$apply_macro($rule->{macro}, $rule);
1318 } else {
1319 $rules = [ $rule ];
1320 }
1321
1322 # update all or nothing
1323
1324 my @cmds = ();
1325 foreach my $tmp (@$rules) {
1326 if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $tmp, $actions, $goto, $cluster_conf)) {
1327 push @cmds, $cmdstr;
1328 }
1329 }
1330
1331 foreach my $cmdstr (@cmds) {
1332 ruleset_addrule($ruleset, $chain, $cmdstr);
1333 }
1334 }
1335
1336 sub ruleset_generate_rule_insert {
1337 my ($ruleset, $chain, $rule, $actions, $goto) = @_;
1338
1339 die "implement me" if $rule->{macro}; # not implemented, because not needed so far
1340
1341 if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $rule, $actions, $goto)) {
1342 ruleset_insertrule($ruleset, $chain, $cmdstr);
1343 }
1344 }
1345
1346 sub ruleset_create_chain {
1347 my ($ruleset, $chain) = @_;
1348
1349 die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
1350 die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
1351
1352 die "chain '$chain' already exists\n" if $ruleset->{$chain};
1353
1354 $ruleset->{$chain} = [];
1355 }
1356
1357 sub ruleset_chain_exist {
1358 my ($ruleset, $chain) = @_;
1359
1360 return $ruleset->{$chain} ? 1 : undef;
1361 }
1362
1363 sub ruleset_addrule {
1364 my ($ruleset, $chain, $rule) = @_;
1365
1366 die "no such chain '$chain'\n" if !$ruleset->{$chain};
1367
1368 push @{$ruleset->{$chain}}, "-A $chain $rule";
1369 }
1370
1371 sub ruleset_insertrule {
1372 my ($ruleset, $chain, $rule) = @_;
1373
1374 die "no such chain '$chain'\n" if !$ruleset->{$chain};
1375
1376 unshift @{$ruleset->{$chain}}, "-A $chain $rule";
1377 }
1378
1379 sub get_log_rule_base {
1380 my ($chain, $vmid, $msg, $loglevel) = @_;
1381
1382 die "internal error - no log level" if !defined($loglevel);
1383
1384 $vmid = 0 if !defined($vmid);
1385
1386 # Note: we use special format for prefix to pass further
1387 # info to log daemon (VMID, LOGVELEL and CHAIN)
1388
1389 return "-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
1390 }
1391
1392 sub ruleset_addlog {
1393 my ($ruleset, $chain, $vmid, $msg, $loglevel, $rule) = @_;
1394
1395 return if !defined($loglevel);
1396
1397 my $logrule = get_log_rule_base($chain, $vmid, $msg, $loglevel);
1398
1399 $logrule = "$rule $logrule" if defined($rule);
1400
1401 ruleset_addrule($ruleset, $chain, $logrule);
1402 }
1403
1404 sub generate_bridge_chains {
1405 my ($ruleset, $hostfw_conf, $bridge, $bridges_config) = @_;
1406
1407 my $options = $hostfw_conf->{options} || {};
1408
1409 if (!ruleset_chain_exist($ruleset, "$bridge-FW")) {
1410 ruleset_create_chain($ruleset, "$bridge-FW");
1411 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o $bridge -m physdev --physdev-is-out -j $bridge-FW");
1412 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i $bridge -m physdev --physdev-is-in -j $bridge-FW");
1413 }
1414
1415 if (!ruleset_chain_exist($ruleset, "$bridge-OUT")) {
1416 ruleset_create_chain($ruleset, "$bridge-OUT");
1417
1418 if($options->{optimize}){
1419 foreach my $interface (@{$bridges_config->{$bridge}}) {
1420 ruleset_addrule($ruleset, "$bridge-OUT", "-m physdev --physdev-is-bridged --physdev-in $interface -g PVEFW-SET-ACCEPT-MARK");
1421 }
1422 }
1423
1424 ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-in -j $bridge-OUT");
1425 ruleset_insertrule($ruleset, "PVEFW-INPUT", "-i $bridge -m physdev --physdev-is-in -j $bridge-OUT");
1426 }
1427
1428 if (!ruleset_chain_exist($ruleset, "$bridge-IN")) {
1429 ruleset_create_chain($ruleset, "$bridge-IN");
1430
1431 if($options->{optimize}){
1432 foreach my $interface (@{$bridges_config->{$bridge}}) {
1433 ruleset_addrule($ruleset, "$bridge-IN", "-m physdev --physdev-is-bridged --physdev-out $interface -j ACCEPT");
1434 }
1435 }
1436
1437 ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-out -j $bridge-IN");
1438 ruleset_addrule($ruleset, "$bridge-FW", "-m mark --mark 1 -j ACCEPT");
1439 # accept traffic to unmanaged bridge ports
1440 ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-out -j ACCEPT ");
1441 }
1442 }
1443
1444 sub ruleset_add_chain_policy {
1445 my ($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action) = @_;
1446
1447 if ($policy eq 'ACCEPT') {
1448
1449 ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT' },
1450 { ACCEPT => $accept_action});
1451
1452 } elsif ($policy eq 'DROP') {
1453
1454 ruleset_addrule($ruleset, $chain, "-j PVEFW-Drop");
1455
1456 ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1457
1458 ruleset_addrule($ruleset, $chain, "-j DROP");
1459 } elsif ($policy eq 'REJECT') {
1460 ruleset_addrule($ruleset, $chain, "-j PVEFW-Reject");
1461
1462 ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1463
1464 ruleset_addrule($ruleset, $chain, "-g PVEFW-reject");
1465 } else {
1466 # should not happen
1467 die "internal error: unknown policy '$policy'";
1468 }
1469 }
1470
1471 sub ruleset_create_vm_chain {
1472 my ($ruleset, $chain, $options, $host_options, $macaddr, $direction) = @_;
1473
1474 ruleset_create_chain($ruleset, $chain);
1475 my $accept = generate_nfqueue($options);
1476
1477 if (!(defined($host_options->{nosmurfs}) && $host_options->{nosmurfs} == 0)) {
1478 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1479 }
1480
1481 if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
1482 if ($direction eq 'OUT') {
1483 ruleset_generate_rule($ruleset, $chain, { action => 'PVEFW-SET-ACCEPT-MARK',
1484 proto => 'udp', sport => 68, dport => 67 });
1485 } else {
1486 ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT',
1487 proto => 'udp', sport => 67, dport => 68 });
1488 }
1489 }
1490
1491 if ($host_options->{tcpflags}) {
1492 ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1493 }
1494
1495 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1496 if ($direction eq 'OUT') {
1497 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -g PVEFW-SET-ACCEPT-MARK");
1498 } else {
1499 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
1500 }
1501
1502 if ($direction eq 'OUT') {
1503 if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
1504 ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr -j DROP");
1505 }
1506 ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1507 }
1508 }
1509
1510 sub ruleset_generate_vm_rules {
1511 my ($ruleset, $rules, $cluster_conf, $chain, $netid, $direction, $options) = @_;
1512
1513 my $lc_direction = lc($direction);
1514
1515 my $in_accept = generate_nfqueue($options);
1516
1517 foreach my $rule (@$rules) {
1518 next if $rule->{iface} && $rule->{iface} ne $netid;
1519 next if !$rule->{enable};
1520 if ($rule->{type} eq 'group') {
1521 my $group_chain = "GROUP-$rule->{action}-$direction";
1522 if(!ruleset_chain_exist($ruleset, $group_chain)){
1523 generate_group_rules($ruleset, $cluster_conf, $rule->{action});
1524 }
1525 ruleset_addrule($ruleset, $chain, "-j $group_chain");
1526 if ($direction eq 'OUT'){
1527 ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j RETURN");
1528 }else{
1529 my $accept = generate_nfqueue($options);
1530 ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j $accept");
1531 }
1532
1533 } else {
1534 next if $rule->{type} ne $lc_direction;
1535 eval {
1536 if ($direction eq 'OUT') {
1537 ruleset_generate_rule($ruleset, $chain, $rule,
1538 { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" },
1539 undef, $cluster_conf);
1540 } else {
1541 ruleset_generate_rule($ruleset, $chain, $rule,
1542 { ACCEPT => $in_accept , REJECT => "PVEFW-reject" },
1543 undef, $cluster_conf);
1544 }
1545 };
1546 warn $@ if $@;
1547 }
1548 }
1549 }
1550
1551 sub generate_nfqueue {
1552 my ($options) = @_;
1553
1554 if ($options->{ips}) {
1555 my $action = "NFQUEUE";
1556 if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
1557 if (defined($3) && defined($1)) {
1558 $action .= " --queue-balance $1:$3";
1559 } elsif (defined($1)) {
1560 $action .= " --queue-num $1";
1561 }
1562 }
1563 $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
1564 return $action;
1565 } else {
1566 return "ACCEPT";
1567 }
1568 }
1569
1570 sub ruleset_generate_vm_ipsrules {
1571 my ($ruleset, $options, $direction, $iface, $bridge) = @_;
1572
1573 if ($options->{ips} && $direction eq 'IN') {
1574 my $nfqueue = generate_nfqueue($options);
1575
1576 if (!ruleset_chain_exist($ruleset, "$bridge-IPS")) {
1577 ruleset_create_chain($ruleset, "PVEFW-IPS");
1578 }
1579
1580 if (!ruleset_chain_exist($ruleset, "$bridge-IPS")) {
1581 ruleset_create_chain($ruleset, "$bridge-IPS");
1582 ruleset_insertrule($ruleset, "PVEFW-IPS", "-o $bridge -m physdev --physdev-is-out -j $bridge-IPS");
1583 }
1584
1585 ruleset_addrule($ruleset, "$bridge-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged -j $nfqueue");
1586 }
1587 }
1588
1589 sub generate_venet_rules_direction {
1590 my ($ruleset, $cluster_conf, $hostfw_conf, $vmfw_conf, $vmid, $ip, $direction) = @_;
1591
1592 parse_address_list($ip); # make sure we have a valid $ip list
1593
1594 my $lc_direction = lc($direction);
1595
1596 my $rules = $vmfw_conf->{rules};
1597
1598 my $options = $vmfw_conf->{options};
1599 my $hostfw_options = $vmfw_conf->{options};
1600 my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1601
1602 my $chain = "venet0-$vmid-$direction";
1603
1604 ruleset_create_vm_chain($ruleset, $chain, $options, $hostfw_options, undef, $direction);
1605
1606 ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $chain, 'venet', $direction);
1607
1608 # implement policy
1609 my $policy;
1610
1611 if ($direction eq 'OUT') {
1612 $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1613 } else {
1614 $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1615 }
1616
1617 my $accept = generate_nfqueue($options);
1618 my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1619 ruleset_add_chain_policy($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action);
1620
1621 # plug into FORWARD, INPUT and OUTPUT chain
1622 if ($direction eq 'OUT') {
1623 ruleset_generate_rule_insert($ruleset, "PVEFW-FORWARD", {
1624 action => $chain,
1625 source => $ip,
1626 iface_in => 'venet0'});
1627
1628 ruleset_generate_rule_insert($ruleset, "PVEFW-INPUT", {
1629 action => $chain,
1630 source => $ip,
1631 iface_in => 'venet0'});
1632 } else {
1633 ruleset_generate_rule($ruleset, "PVEFW-FORWARD", {
1634 action => $chain,
1635 dest => $ip,
1636 iface_out => 'venet0'});
1637
1638 ruleset_generate_rule($ruleset, "PVEFW-OUTPUT", {
1639 action => $chain,
1640 dest => $ip,
1641 iface_out => 'venet0'});
1642 }
1643 }
1644
1645 sub generate_tap_rules_direction {
1646 my ($ruleset, $cluster_conf, $hostfw_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $bridge, $direction) = @_;
1647
1648 my $lc_direction = lc($direction);
1649
1650 my $rules = $vmfw_conf->{rules};
1651
1652 my $options = $vmfw_conf->{options};
1653 my $hostfw_options = $hostfw_conf->{options};
1654 my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1655
1656 my $tapchain = "$iface-$direction";
1657
1658 ruleset_create_vm_chain($ruleset, $tapchain, $options, $hostfw_options, $macaddr, $direction);
1659
1660 ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $tapchain, $netid, $direction, $options);
1661
1662 ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface, $bridge);
1663
1664 # implement policy
1665 my $policy;
1666
1667 if ($direction eq 'OUT') {
1668 $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1669 } else {
1670 $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1671 }
1672
1673 my $accept = generate_nfqueue($options);
1674 my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1675 ruleset_add_chain_policy($ruleset, $tapchain, $vmid, $policy, $loglevel, $accept_action);
1676
1677 # plug the tap chain to bridge chain
1678 if ($direction eq 'IN') {
1679 ruleset_addrule($ruleset, "$bridge-IN",
1680 "-m physdev --physdev-is-bridged --physdev-out $iface -j $tapchain");
1681 } else {
1682 ruleset_addrule($ruleset, "$bridge-OUT",
1683 "-m physdev --physdev-in $iface -j $tapchain");
1684 }
1685 }
1686
1687 sub enable_host_firewall {
1688 my ($ruleset, $hostfw_conf, $cluster_conf) = @_;
1689
1690 my $options = $hostfw_conf->{options};
1691 my $cluster_options = $cluster_conf->{options};
1692 my $rules = $hostfw_conf->{rules};
1693 my $cluster_rules = $cluster_conf->{rules};
1694
1695 # host inbound firewall
1696 my $chain = "PVEFW-HOST-IN";
1697 ruleset_create_chain($ruleset, $chain);
1698
1699 my $loglevel = get_option_log_level($options, "log_level_in");
1700
1701 if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
1702 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1703 }
1704
1705 if ($options->{tcpflags}) {
1706 ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1707 }
1708
1709 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1710 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1711 ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
1712 ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
1713 ruleset_addrule($ruleset, $chain, "-p udp -m conntrack --ctstate NEW --dport 5404:5405 -j ACCEPT");
1714 ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT"); #corosync
1715
1716 # we use RETURN because we need to check also tap rules
1717 my $accept_action = 'RETURN';
1718
1719 # add host rules first, so that cluster wide rules can be overwritten
1720 foreach my $rule (@$rules, @$cluster_rules) {
1721 next if $rule->{type} ne 'in';
1722 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" }, undef, $cluster_conf);
1723 }
1724
1725 # implement input policy
1726 my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
1727 ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1728
1729 # host outbound firewall
1730 $chain = "PVEFW-HOST-OUT";
1731 ruleset_create_chain($ruleset, $chain);
1732
1733 $loglevel = get_option_log_level($options, "log_level_out");
1734
1735 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1736 ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1737 ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
1738 ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
1739 ruleset_addrule($ruleset, $chain, "-p udp -m conntrack --ctstate NEW --dport 5404:5405 -j ACCEPT");
1740 ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT"); #corosync
1741
1742 # we use RETURN because we may want to check other thigs later
1743 $accept_action = 'RETURN';
1744
1745 # add host rules first, so that cluster wide rules can be overwritten
1746 foreach my $rule (@$rules, @$cluster_rules) {
1747 next if $rule->{type} ne 'out';
1748 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" }, undef, $cluster_conf);
1749 }
1750
1751 # implement output policy
1752 $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
1753 ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1754
1755 ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
1756 ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
1757 }
1758
1759 sub generate_group_rules {
1760 my ($ruleset, $cluster_conf, $group) = @_;
1761 die "no such security group '$group'\n" if !$cluster_conf->{groups}->{$group};
1762
1763 my $rules = $cluster_conf->{groups}->{$group};
1764
1765 my $chain = "GROUP-${group}-IN";
1766
1767 ruleset_create_chain($ruleset, $chain);
1768 ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1769
1770 foreach my $rule (@$rules) {
1771 next if $rule->{type} ne 'in';
1772 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" }, undef, $cluster_conf);
1773 }
1774
1775 $chain = "GROUP-${group}-OUT";
1776
1777 ruleset_create_chain($ruleset, $chain);
1778 ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1779
1780 foreach my $rule (@$rules) {
1781 next if $rule->{type} ne 'out';
1782 # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
1783 # check also other tap rules later
1784 ruleset_generate_rule($ruleset, $chain, $rule,
1785 { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" }, undef, $cluster_conf);
1786 }
1787 }
1788
1789 my $MAX_NETS = 32;
1790 my $valid_netdev_names = {};
1791 for (my $i = 0; $i < $MAX_NETS; $i++) {
1792 $valid_netdev_names->{"net$i"} = 1;
1793 }
1794
1795 sub parse_fw_rule {
1796 my ($line, $need_iface, $allow_groups) = @_;
1797
1798 my ($type, $action, $iface, $source, $dest, $proto, $dport, $sport);
1799
1800 # we can add single line comments to the end of the rule
1801 my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
1802
1803 # we can disable a rule when prefixed with '|'
1804 my $enable = 1;
1805
1806 $enable = 0 if $line =~ s/^\|//;
1807
1808 my @data = split(/\s+/, $line);
1809 my $expected_elements = $need_iface ? 8 : 7;
1810
1811 die "wrong number of rule elements\n" if scalar(@data) > $expected_elements;
1812
1813 if ($need_iface) {
1814 ($type, $action, $iface, $source, $dest, $proto, $dport, $sport) = @data
1815 } else {
1816 ($type, $action, $source, $dest, $proto, $dport, $sport) = @data;
1817 }
1818
1819 die "incomplete rule\n" if ! ($type && $action);
1820
1821 my $macro;
1822
1823 $type = lc($type);
1824
1825 if ($type eq 'in' || $type eq 'out') {
1826 if ($action =~ m/^(ACCEPT|DROP|REJECT)$/) {
1827 # OK
1828 } elsif ($action =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
1829 $action = $2;
1830 my $preferred_name = $pve_fw_preferred_macro_names->{lc($1)};
1831 die "unknown macro '$1'\n" if !$preferred_name;
1832 $macro = $preferred_name;
1833 } else {
1834 die "unknown action '$action'\n";
1835 }
1836 } elsif ($type eq 'group') {
1837 die "wrong number of rule elements\n" if scalar(@data) != 3;
1838 die "groups disabled\n" if !$allow_groups;
1839
1840 die "invalid characters in group name\n" if $action !~ m/^${security_group_name_pattern}$/;
1841 } else {
1842 die "unknown rule type '$type'\n";
1843 }
1844
1845 if ($need_iface) {
1846 $iface = undef if $iface && $iface eq '-';
1847 }
1848
1849 $proto = undef if $proto && $proto eq '-';
1850 pve_fw_verify_protocol_spec($proto) if $proto;
1851
1852 $source = undef if $source && $source eq '-';
1853 $dest = undef if $dest && $dest eq '-';
1854
1855 $dport = undef if $dport && $dport eq '-';
1856 $sport = undef if $sport && $sport eq '-';
1857
1858 parse_port_name_number_or_range($dport) if defined($dport);
1859 parse_port_name_number_or_range($sport) if defined($sport);
1860
1861 parse_address_list($source) if $source;
1862 parse_address_list($dest) if $dest;
1863
1864 return {
1865 type => $type,
1866 enable => $enable,
1867 comment => $comment,
1868 action => $action,
1869 macro => $macro,
1870 iface => $iface,
1871 source => $source,
1872 dest => $dest,
1873 proto => $proto,
1874 dport => $dport,
1875 sport => $sport,
1876 };
1877 }
1878
1879 sub parse_vmfw_option {
1880 my ($line) = @_;
1881
1882 my ($opt, $value);
1883
1884 my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
1885
1886 if ($line =~ m/^(enable|dhcp|macfilter|ips):\s*(0|1)\s*$/i) {
1887 $opt = lc($1);
1888 $value = int($2);
1889 } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
1890 $opt = lc($1);
1891 $value = $2 ? lc($3) : '';
1892 } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
1893 $opt = lc($1);
1894 $value = uc($3);
1895 } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
1896 $opt = lc($1);
1897 $value = $2;
1898 } else {
1899 chomp $line;
1900 die "can't parse option '$line'\n"
1901 }
1902
1903 return ($opt, $value);
1904 }
1905
1906 sub parse_hostfw_option {
1907 my ($line) = @_;
1908
1909 my ($opt, $value);
1910
1911 my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
1912
1913 if ($line =~ m/^(enable|nosmurfs|tcpflags|optimize):\s*(0|1)\s*$/i) {
1914 $opt = lc($1);
1915 $value = int($2);
1916 } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
1917 $opt = lc($1);
1918 $value = $2 ? lc($3) : '';
1919 } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established):\s*(\d+)\s*$/i) {
1920 $opt = lc($1);
1921 $value = int($2);
1922 } else {
1923 chomp $line;
1924 die "can't parse option '$line'\n"
1925 }
1926
1927 return ($opt, $value);
1928 }
1929
1930 sub parse_clusterfw_option {
1931 my ($line) = @_;
1932
1933 my ($opt, $value);
1934
1935 if ($line =~ m/^(enable):\s*(0|1)\s*$/i) {
1936 $opt = lc($1);
1937 $value = int($2);
1938 } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
1939 $opt = lc($1);
1940 $value = uc($3);
1941 } else {
1942 chomp $line;
1943 die "can't parse option '$line'\n"
1944 }
1945
1946 return ($opt, $value);
1947 }
1948
1949 sub parse_clusterfw_alias {
1950 my ($line) = @_;
1951
1952 # we can add single line comments to the end of the line
1953 my $comment = decode('utf8', $1) if $line =~ s/\s*#\s*(.*?)\s*$//;
1954
1955 if ($line =~ m/^(\S+)\s(\S+)$/) {
1956 my ($name, $cidr) = ($1, $2);
1957 $cidr =~ s|/32$||;
1958 pve_verify_ipv4_or_cidr($cidr);
1959 my $data = {
1960 name => $name,
1961 cidr => $cidr,
1962 };
1963 $data->{comment} = $comment if $comment;
1964 return $data;
1965 }
1966
1967 return undef;
1968 }
1969
1970 sub parse_vm_fw_rules {
1971 my ($filename, $fh) = @_;
1972
1973 my $res = { rules => [], options => {}};
1974
1975 my $section;
1976
1977 while (defined(my $line = <$fh>)) {
1978 next if $line =~ m/^#/;
1979 next if $line =~ m/^\s*$/;
1980
1981 my $linenr = $fh->input_line_number();
1982 my $prefix = "$filename (line $linenr)";
1983
1984 if ($line =~ m/^\[(\S+)\]\s*$/i) {
1985 $section = lc($1);
1986 warn "$prefix: ignore unknown section '$section'\n" if !$res->{$section};
1987 next;
1988 }
1989 if (!$section) {
1990 warn "$prefix: skip line - no section";
1991 next;
1992 }
1993
1994 next if !$res->{$section}; # skip undefined section
1995
1996 if ($section eq 'options') {
1997 eval {
1998 my ($opt, $value) = parse_vmfw_option($line);
1999 $res->{options}->{$opt} = $value;
2000 };
2001 warn "$prefix: $@" if $@;
2002 next;
2003 }
2004
2005 my $rule;
2006 eval { $rule = parse_fw_rule($line, 1, 1); };
2007 if (my $err = $@) {
2008 warn "$prefix: $err";
2009 next;
2010 }
2011
2012 push @{$res->{$section}}, $rule;
2013 }
2014
2015 return $res;
2016 }
2017
2018 sub parse_host_fw_rules {
2019 my ($filename, $fh) = @_;
2020
2021 my $res = { rules => [], options => {}};
2022
2023 my $section;
2024
2025 while (defined(my $line = <$fh>)) {
2026 next if $line =~ m/^#/;
2027 next if $line =~ m/^\s*$/;
2028
2029 my $linenr = $fh->input_line_number();
2030 my $prefix = "$filename (line $linenr)";
2031
2032 if ($line =~ m/^\[(\S+)\]\s*$/i) {
2033 $section = lc($1);
2034 warn "$prefix: ignore unknown section '$section'\n" if !$res->{$section};
2035 next;
2036 }
2037 if (!$section) {
2038 warn "$prefix: skip line - no section";
2039 next;
2040 }
2041
2042 next if !$res->{$section}; # skip undefined section
2043
2044 if ($section eq 'options') {
2045 eval {
2046 my ($opt, $value) = parse_hostfw_option($line);
2047 $res->{options}->{$opt} = $value;
2048 };
2049 warn "$prefix: $@" if $@;
2050 next;
2051 }
2052
2053 my $rule;
2054 eval { $rule = parse_fw_rule($line, 1, 1); };
2055 if (my $err = $@) {
2056 warn "$prefix: $err";
2057 next;
2058 }
2059
2060 push @{$res->{$section}}, $rule;
2061 }
2062
2063 return $res;
2064 }
2065
2066 sub parse_cluster_fw_rules {
2067 my ($filename, $fh) = @_;
2068
2069 my $section;
2070 my $group;
2071
2072 my $res = {
2073 rules => [],
2074 options => {},
2075 aliases => {},
2076 groups => {},
2077 group_comments => {},
2078 ipset => {} ,
2079 ipset_comments => {},
2080 };
2081
2082 while (defined(my $line = <$fh>)) {
2083 next if $line =~ m/^#/;
2084 next if $line =~ m/^\s*$/;
2085
2086 my $linenr = $fh->input_line_number();
2087 my $prefix = "$filename (line $linenr)";
2088
2089 if ($line =~ m/^\[options\]$/i) {
2090 $section = 'options';
2091 next;
2092 }
2093
2094 if ($line =~ m/^\[aliases\]$/i) {
2095 $section = 'aliases';
2096 next;
2097 }
2098
2099 if ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i) {
2100 $section = 'groups';
2101 $group = lc($1);
2102 my $comment = $2;
2103 $res->{$section}->{$group} = [];
2104 $res->{group_comments}->{$group} = decode('utf8', $comment)
2105 if $comment;
2106 next;
2107 }
2108
2109 if ($line =~ m/^\[rules\]$/i) {
2110 $section = 'rules';
2111 next;
2112 }
2113
2114 if ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i) {
2115 $section = 'ipset';
2116 $group = lc($1);
2117 my $comment = $2;
2118 $res->{$section}->{$group} = [];
2119 $res->{ipset_comments}->{$group} = decode('utf8', $comment)
2120 if $comment;
2121 next;
2122 }
2123
2124 if (!$section) {
2125 warn "$prefix: skip line - no section\n";
2126 next;
2127 }
2128
2129 if ($section eq 'options') {
2130 eval {
2131 my ($opt, $value) = parse_clusterfw_option($line);
2132 $res->{options}->{$opt} = $value;
2133 };
2134 warn "$prefix: $@" if $@;
2135 } elsif ($section eq 'aliases') {
2136 eval {
2137 my $data = parse_clusterfw_alias($line);
2138 $res->{aliases}->{lc($data->{name})} = $data;
2139 };
2140 warn "$prefix: $@" if $@;
2141 } elsif ($section eq 'rules') {
2142 my $rule;
2143 eval { $rule = parse_fw_rule($line, 1, 1); };
2144 if (my $err = $@) {
2145 warn "$prefix: $err";
2146 next;
2147 }
2148 push @{$res->{$section}}, $rule;
2149 } elsif ($section eq 'groups') {
2150 my $rule;
2151 eval { $rule = parse_fw_rule($line, 0, 0); };
2152 if (my $err = $@) {
2153 warn "$prefix: $err";
2154 next;
2155 }
2156 push @{$res->{$section}->{$group}}, $rule;
2157 } elsif ($section eq 'ipset') {
2158 # we can add single line comments to the end of the rule
2159 my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
2160
2161 $line =~ m/^(\!)?\s*(\S+)\s*$/;
2162 my $nomatch = $1;
2163 my $cidr = $2;
2164
2165 if($cidr !~ m/^${ip_alias_pattern}$/) {
2166 $cidr =~ s|/32$||;
2167
2168 eval { pve_verify_ipv4_or_cidr($cidr); };
2169 if (my $err = $@) {
2170 warn "$prefix: $cidr - $err";
2171 next;
2172 }
2173 }
2174
2175 my $entry = { cidr => $cidr };
2176 $entry->{nomatch} = 1 if $nomatch;
2177 $entry->{comment} = $comment if $comment;
2178
2179 push @{$res->{$section}->{$group}}, $entry;
2180 }
2181 }
2182
2183 return $res;
2184 }
2185
2186 sub run_locked {
2187 my ($code, @param) = @_;
2188
2189 my $timeout = 10;
2190
2191 my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
2192
2193 die $@ if $@;
2194
2195 return $res;
2196 }
2197
2198 sub read_local_vm_config {
2199
2200 my $openvz = {};
2201 my $qemu = {};
2202
2203 my $vmdata = { openvz => $openvz, qemu => $qemu };
2204
2205 my $vmlist = PVE::Cluster::get_vmlist();
2206 return $vmdata if !$vmlist || !$vmlist->{ids};
2207 my $ids = $vmlist->{ids};
2208
2209 foreach my $vmid (keys %$ids) {
2210 next if !$vmid; # skip VE0
2211 my $d = $ids->{$vmid};
2212 next if !$d->{node} || $d->{node} ne $nodename;
2213 next if !$d->{type};
2214 if ($d->{type} eq 'openvz') {
2215 if ($have_pve_manager) {
2216 my $cfspath = PVE::OpenVZ::cfs_config_path($vmid);
2217 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2218 $openvz->{$vmid} = $conf;
2219 }
2220 }
2221 } elsif ($d->{type} eq 'qemu') {
2222 if ($have_qemu_server) {
2223 my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
2224 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2225 $qemu->{$vmid} = $conf;
2226 }
2227 }
2228 }
2229 }
2230
2231 return $vmdata;
2232 };
2233
2234 sub read_bridges_config {
2235
2236 my $bridgehash = {};
2237
2238 dir_glob_foreach('/sys/class/net', 'vmbr(\d+)', sub {
2239 my ($bridge) = @_;
2240
2241 dir_glob_foreach("/sys/class/net/$bridge/brif", '((eth|bond)(\d+)(\.(\d+))?)', sub {
2242 my ($interface) = @_;
2243 push @{$bridgehash->{$bridge}}, $interface;
2244 });
2245 });
2246
2247 return $bridgehash;
2248 };
2249
2250 sub load_vmfw_conf {
2251 my ($vmid) = @_;
2252
2253 my $vmfw_conf = {};
2254
2255 my $filename = "/etc/pve/firewall/$vmid.fw";
2256 if (my $fh = IO::File->new($filename, O_RDONLY)) {
2257 $vmfw_conf = parse_vm_fw_rules($filename, $fh);
2258 }
2259
2260 return $vmfw_conf;
2261 }
2262
2263 my $format_rules = sub {
2264 my ($rules, $need_iface) = @_;
2265
2266 my $raw = '';
2267
2268 foreach my $rule (@$rules) {
2269 if ($rule->{type} eq 'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
2270 $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
2271 $raw .= uc($rule->{type});
2272 if ($rule->{macro}) {
2273 $raw .= " $rule->{macro}($rule->{action})";
2274 } else {
2275 $raw .= " " . $rule->{action};
2276 }
2277 $raw .= " " . ($rule->{iface} || '-') if $need_iface;
2278
2279 if ($rule->{type} ne 'group') {
2280 $raw .= " " . ($rule->{source} || '-');
2281 $raw .= " " . ($rule->{dest} || '-');
2282 $raw .= " " . ($rule->{proto} || '-');
2283 $raw .= " " . ($rule->{dport} || '-');
2284 $raw .= " " . ($rule->{sport} || '-');
2285 }
2286
2287 $raw .= " # " . encode('utf8', $rule->{comment})
2288 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
2289 $raw .= "\n";
2290 } else {
2291 die "unknown rule type '$rule->{type}'";
2292 }
2293 }
2294
2295 return $raw;
2296 };
2297
2298 my $format_options = sub {
2299 my ($options) = @_;
2300
2301 my $raw = '';
2302
2303 $raw .= "[OPTIONS]\n\n";
2304 foreach my $opt (keys %$options) {
2305 $raw .= "$opt: $options->{$opt}\n";
2306 }
2307 $raw .= "\n";
2308
2309 return $raw;
2310 };
2311
2312 my $format_aliases = sub {
2313 my ($aliases) = @_;
2314
2315 my $raw = '';
2316
2317 $raw .= "[ALIASES]\n\n";
2318 foreach my $k (keys %$aliases) {
2319 my $e = $aliases->{$k};
2320 $raw .= "$e->{name} $e->{cidr}";
2321 $raw .= " # " . encode('utf8', $e->{comment})
2322 if $e->{comment} && $e->{comment} !~ m/^\s*$/;
2323 $raw .= "\n";
2324 }
2325 $raw .= "\n";
2326
2327 return $raw;
2328 };
2329
2330 my $format_ipset = sub {
2331 my ($options) = @_;
2332
2333 my $raw = '';
2334
2335 my $nethash = {};
2336 foreach my $entry (@$options) {
2337 $nethash->{$entry->{cidr}} = $entry;
2338 }
2339
2340 foreach my $cidr (sort keys %$nethash) {
2341 my $entry = $nethash->{$cidr};
2342 my $line = $entry->{nomatch} ? '!' : '';
2343 $line .= $entry->{cidr};
2344 $line .= " # " . encode('utf8', $entry->{comment})
2345 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
2346 $raw .= "$line\n";
2347 }
2348
2349 return $raw;
2350 };
2351
2352 sub save_vmfw_conf {
2353 my ($vmid, $vmfw_conf) = @_;
2354
2355 my $raw = '';
2356
2357 my $options = $vmfw_conf->{options};
2358 $raw .= &$format_options($options) if scalar(keys %$options);
2359
2360 my $rules = $vmfw_conf->{rules} || [];
2361 if (scalar(@$rules)) {
2362 $raw .= "[RULES]\n\n";
2363 $raw .= &$format_rules($rules, 1);
2364 $raw .= "\n";
2365 }
2366
2367 my $filename = "/etc/pve/firewall/$vmid.fw";
2368 PVE::Tools::file_set_contents($filename, $raw);
2369 }
2370
2371 sub read_vm_firewall_configs {
2372 my ($vmdata) = @_;
2373 my $vmfw_configs = {};
2374
2375 foreach my $vmid (keys %{$vmdata->{qemu}}, keys %{$vmdata->{openvz}}) {
2376 my $vmfw_conf = load_vmfw_conf($vmid);
2377 next if !$vmfw_conf->{options}; # skip if file does not exists
2378 $vmfw_configs->{$vmid} = $vmfw_conf;
2379 }
2380
2381 return $vmfw_configs;
2382 }
2383
2384 sub get_option_log_level {
2385 my ($options, $k) = @_;
2386
2387 my $v = $options->{$k};
2388 $v = $default_log_level if !defined($v);
2389
2390 return undef if $v eq '' || $v eq 'nolog';
2391
2392 $v = $log_level_hash->{$v} if defined($log_level_hash->{$v});
2393
2394 return $v if ($v >= 0) && ($v <= 7);
2395
2396 warn "unknown log level ($k = '$v')\n";
2397
2398 return undef;
2399 }
2400
2401 sub generate_std_chains {
2402 my ($ruleset, $options) = @_;
2403
2404 my $loglevel = get_option_log_level($options, 'smurf_log_level');
2405
2406 # same as shorewall smurflog.
2407 my $chain = 'PVEFW-smurflog';
2408 $pve_std_chains->{$chain} = [];
2409
2410 push @{$pve_std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2411 push @{$pve_std_chains->{$chain}}, "-j DROP";
2412
2413 # same as shorewall logflags action.
2414 $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
2415 $chain = 'PVEFW-logflags';
2416 $pve_std_chains->{$chain} = [];
2417
2418 # fixme: is this correctly logged by pvewf-logger? (ther is no --log-ip-options for NFLOG)
2419 push @{$pve_std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2420 push @{$pve_std_chains->{$chain}}, "-j DROP";
2421
2422 foreach my $chain (keys %$pve_std_chains) {
2423 ruleset_create_chain($ruleset, $chain);
2424 foreach my $rule (@{$pve_std_chains->{$chain}}) {
2425 if (ref($rule)) {
2426 ruleset_generate_rule($ruleset, $chain, $rule);
2427 } else {
2428 ruleset_addrule($ruleset, $chain, $rule);
2429 }
2430 }
2431 }
2432 }
2433
2434 sub generate_ipset_chains {
2435 my ($ipset_ruleset, $fw_conf) = @_;
2436
2437 foreach my $ipset (keys %{$fw_conf->{ipset}}) {
2438 generate_ipset($ipset_ruleset, "PVEFW-$ipset", $fw_conf->{ipset}->{$ipset}, $fw_conf->{aliases});
2439 }
2440 }
2441
2442 sub generate_ipset {
2443 my ($ipset_ruleset, $name, $options, $aliases) = @_;
2444
2445 my $hashsize = scalar(@$options);
2446 if ($hashsize <= 64) {
2447 $hashsize = 64;
2448 } else {
2449 $hashsize = round_powerof2($hashsize);
2450 }
2451
2452 push @{$ipset_ruleset->{$name}}, "create $name hash:net family inet hashsize $hashsize maxelem $hashsize";
2453
2454 # remove duplicates
2455 my $nethash = {};
2456 foreach my $entry (@$options) {
2457 my $cidr = $entry->{cidr};
2458 if ($cidr =~ m/^${ip_alias_pattern}$/) {
2459 my $alias = lc($cidr);
2460 if ($aliases->{$alias}) {
2461 $entry->{cidr} = $aliases->{$alias}->{cidr};
2462 $nethash->{$entry->{cidr}} = $entry;
2463 } else {
2464 warn "no such alias '$cidr'\n" if !$aliases->{$alias};
2465 }
2466 } else {
2467 $nethash->{$entry->{cidr}} = $entry;
2468 }
2469 }
2470
2471 foreach my $cidr (sort keys %$nethash) {
2472 my $entry = $nethash->{$cidr};
2473
2474 my $cmd = "add $name $cidr";
2475 if ($entry->{nomatch}) {
2476 if ($feature_ipset_nomatch) {
2477 push @{$ipset_ruleset->{$name}}, "$cmd nomatch";
2478 } else {
2479 warn "ignore !$cidr - nomatch not supported by kernel\n";
2480 }
2481 } else {
2482 push @{$ipset_ruleset->{$name}}, $cmd;
2483 }
2484 }
2485 }
2486
2487 sub round_powerof2 {
2488 my ($int) = @_;
2489
2490 $int--;
2491 $int |= $int >> $_ foreach (1,2,4,8,16);
2492 return ++$int;
2493 }
2494
2495 sub save_pvefw_status {
2496 my ($status) = @_;
2497
2498 die "unknown status '$status' - internal error"
2499 if $status !~ m/^(stopped|active)$/;
2500
2501 mkdir dirname($pve_fw_status_filename);
2502 PVE::Tools::file_set_contents($pve_fw_status_filename, $status);
2503 }
2504
2505 sub read_pvefw_status {
2506
2507 my $status = 'unknown';
2508
2509 return 'stopped' if ! -f $pve_fw_status_filename;
2510
2511 eval {
2512 $status = PVE::Tools::file_get_contents($pve_fw_status_filename);
2513 };
2514 warn $@ if $@;
2515
2516 return $status;
2517 }
2518
2519 sub load_clusterfw_conf {
2520
2521 my $cluster_conf = {};
2522 if (my $fh = IO::File->new($clusterfw_conf_filename, O_RDONLY)) {
2523 $cluster_conf = parse_cluster_fw_rules($clusterfw_conf_filename, $fh);
2524 }
2525
2526 return $cluster_conf;
2527 }
2528
2529 sub save_clusterfw_conf {
2530 my ($cluster_conf) = @_;
2531
2532 my $raw = '';
2533
2534 my $options = $cluster_conf->{options};
2535 $raw .= &$format_options($options) if scalar(keys %$options);
2536
2537 my $aliases = $cluster_conf->{aliases};
2538 $raw .= &$format_aliases($aliases) if scalar(keys %$aliases);
2539
2540 foreach my $ipset (sort keys %{$cluster_conf->{ipset}}) {
2541 if (my $comment = $cluster_conf->{ipset_comments}->{$ipset}) {
2542 my $utf8comment = encode('utf8', $comment);
2543 $raw .= "[IPSET $ipset] # $utf8comment\n\n";
2544 } else {
2545 $raw .= "[IPSET $ipset]\n\n";
2546 }
2547 my $options = $cluster_conf->{ipset}->{$ipset};
2548 $raw .= &$format_ipset($options);
2549 $raw .= "\n";
2550 }
2551
2552 my $rules = $cluster_conf->{rules};
2553 if (scalar(@$rules)) {
2554 $raw .= "[RULES]\n\n";
2555 $raw .= &$format_rules($rules, 1);
2556 $raw .= "\n";
2557 }
2558
2559 foreach my $group (sort keys %{$cluster_conf->{groups}}) {
2560 my $rules = $cluster_conf->{groups}->{$group};
2561 if (my $comment = $cluster_conf->{group_comments}->{$group}) {
2562 my $utf8comment = encode('utf8', $comment);
2563 $raw .= "[group $group] # $utf8comment\n\n";
2564 } else {
2565 $raw .= "[group $group]\n\n";
2566 }
2567
2568 $raw .= &$format_rules($rules, 0);
2569 $raw .= "\n";
2570 }
2571
2572 PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
2573 }
2574
2575 sub load_hostfw_conf {
2576
2577 my $hostfw_conf = {};
2578 if (my $fh = IO::File->new($hostfw_conf_filename, O_RDONLY)) {
2579 $hostfw_conf = parse_host_fw_rules($hostfw_conf_filename, $fh);
2580 }
2581 return $hostfw_conf;
2582 }
2583
2584 sub save_hostfw_conf {
2585 my ($hostfw_conf) = @_;
2586
2587 my $raw = '';
2588
2589 my $options = $hostfw_conf->{options};
2590 $raw .= &$format_options($options) if scalar(keys %$options);
2591
2592 my $rules = $hostfw_conf->{rules};
2593 if (scalar(@$rules)) {
2594 $raw .= "[RULES]\n\n";
2595 $raw .= &$format_rules($rules, 1);
2596 $raw .= "\n";
2597 }
2598
2599 PVE::Tools::file_set_contents($hostfw_conf_filename, $raw);
2600 }
2601
2602 sub compile {
2603 my ($cluster_conf, $hostfw_conf) = @_;
2604
2605 $cluster_conf = load_clusterfw_conf() if !$cluster_conf;
2606 $hostfw_conf = load_hostfw_conf() if !$hostfw_conf;
2607
2608 my $vmdata = read_local_vm_config();
2609 my $vmfw_configs = read_vm_firewall_configs($vmdata);
2610
2611 my $bridges_config = read_bridges_config();
2612
2613 my $ipset_ruleset = {};
2614 generate_ipset_chains($ipset_ruleset, $cluster_conf);
2615
2616 my $ruleset = {};
2617
2618 ruleset_create_chain($ruleset, "PVEFW-INPUT");
2619 ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
2620
2621 ruleset_create_chain($ruleset, "PVEFW-FORWARD");
2622
2623 my $hostfw_options = $hostfw_conf->{options} || {};
2624
2625 # fixme: what log level should we use here?
2626 my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
2627
2628 if($hostfw_options->{optimize}){
2629
2630 my $accept = ruleset_chain_exist($ruleset, "PVEFW-IPS") ? "PVEFW-IPS" : "ACCEPT";
2631 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate INVALID -j DROP");
2632 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
2633 }
2634
2635 if ($cluster_conf->{ipset}->{blacklist}){
2636 ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-m set --match-set PVEFW-blacklist src");
2637 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m set --match-set PVEFW-blacklist src -j DROP");
2638 }
2639
2640 generate_std_chains($ruleset, $hostfw_options);
2641
2642 my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
2643
2644 enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf) if $hostfw_enable;
2645
2646 # generate firewall rules for QEMU VMs
2647 foreach my $vmid (keys %{$vmdata->{qemu}}) {
2648 my $conf = $vmdata->{qemu}->{$vmid};
2649 my $vmfw_conf = $vmfw_configs->{$vmid};
2650 next if !$vmfw_conf;
2651 next if defined($vmfw_conf->{options}->{enable}) && ($vmfw_conf->{options}->{enable} == 0);
2652
2653 foreach my $netid (keys %$conf) {
2654 next if $netid !~ m/^net(\d+)$/;
2655 my $net = PVE::QemuServer::parse_net($conf->{$netid});
2656 next if !$net;
2657 my $iface = "tap${vmid}i$1";
2658
2659 my $bridge = $net->{bridge};
2660 next if !$bridge; # fixme: ?
2661
2662 $bridge .= "v$net->{tag}" if $net->{tag};
2663
2664 generate_bridge_chains($ruleset, $hostfw_conf, $bridge, $bridges_config);
2665
2666 my $macaddr = $net->{macaddr};
2667 generate_tap_rules_direction($ruleset, $cluster_conf, $hostfw_conf, $iface, $netid, $macaddr,
2668 $vmfw_conf, $vmid, $bridge, 'IN');
2669 generate_tap_rules_direction($ruleset, $cluster_conf, $hostfw_conf, $iface, $netid, $macaddr,
2670 $vmfw_conf, $vmid, $bridge, 'OUT');
2671 }
2672 }
2673
2674 # generate firewall rules for OpenVZ containers
2675 foreach my $vmid (keys %{$vmdata->{openvz}}) {
2676 my $conf = $vmdata->{openvz}->{$vmid};
2677
2678 my $vmfw_conf = $vmfw_configs->{$vmid};
2679 next if !$vmfw_conf;
2680 next if defined($vmfw_conf->{options}->{enable}) && ($vmfw_conf->{options}->{enable} == 0);
2681
2682 if ($conf->{ip_address} && $conf->{ip_address}->{value}) {
2683 my $ip = $conf->{ip_address}->{value};
2684 generate_venet_rules_direction($ruleset, $cluster_conf, $hostfw_conf, $vmfw_conf, $vmid, $ip, 'IN');
2685 generate_venet_rules_direction($ruleset, $cluster_conf, $hostfw_conf, $vmfw_conf, $vmid, $ip, 'OUT');
2686 }
2687
2688 if ($conf->{netif} && $conf->{netif}->{value}) {
2689 my $netif = PVE::OpenVZ::parse_netif($conf->{netif}->{value});
2690 foreach my $netid (keys %$netif) {
2691 my $d = $netif->{$netid};
2692 my $bridge = $d->{bridge};
2693 if (!$bridge) {
2694 warn "no bridge device for CT $vmid iface '$netid'\n";
2695 next; # fixme?
2696 }
2697
2698 generate_bridge_chains($ruleset, $hostfw_conf, $bridge, $bridges_config);
2699
2700 my $macaddr = $d->{mac};
2701 my $iface = $d->{host_ifname};
2702 generate_tap_rules_direction($ruleset, $cluster_conf, $hostfw_conf, $iface, $netid, $macaddr,
2703 $vmfw_conf, $vmid, $bridge, 'IN');
2704 generate_tap_rules_direction($ruleset, $cluster_conf, $hostfw_conf, $iface, $netid, $macaddr,
2705 $vmfw_conf, $vmid, $bridge, 'OUT');
2706 }
2707 }
2708 }
2709
2710 # fixme: should we really block inter-bridge traffic?
2711
2712 # always allow traffic from containers?
2713 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i venet0 -j RETURN");
2714
2715 # disable interbridge routing
2716 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o vmbr+ -j PVEFW-Drop");
2717 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i vmbr+ -j PVEFW-Drop");
2718 ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-o vmbr+");
2719 ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-i vmbr+");
2720 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o vmbr+ -j DROP");
2721 ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i vmbr+ -j DROP");
2722
2723 return ($ruleset, $ipset_ruleset);
2724 }
2725
2726 sub get_ruleset_status {
2727 my ($ruleset, $active_chains, $digest_fn, $verbose) = @_;
2728
2729 my $statushash = {};
2730
2731 foreach my $chain (sort keys %$ruleset) {
2732 my $sig = &$digest_fn($ruleset->{$chain});
2733
2734 $statushash->{$chain}->{sig} = $sig;
2735
2736 my $oldsig = $active_chains->{$chain};
2737 if (!defined($oldsig)) {
2738 $statushash->{$chain}->{action} = 'create';
2739 } else {
2740 if ($oldsig eq $sig) {
2741 $statushash->{$chain}->{action} = 'exists';
2742 } else {
2743 $statushash->{$chain}->{action} = 'update';
2744 }
2745 }
2746 print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
2747 foreach my $cmd (@{$ruleset->{$chain}}) {
2748 print "\t$cmd\n" if $verbose;
2749 }
2750 }
2751
2752 foreach my $chain (sort keys %$active_chains) {
2753 if (!defined($ruleset->{$chain})) {
2754 my $sig = $active_chains->{$chain};
2755 $statushash->{$chain}->{action} = 'delete';
2756 $statushash->{$chain}->{sig} = $sig;
2757 print "delete $chain ($sig)\n" if $verbose;
2758 }
2759 }
2760
2761 return $statushash;
2762 }
2763
2764 sub print_sig_rule {
2765 my ($chain, $sig) = @_;
2766
2767 # We just use this to store a SHA1 checksum used to detect changes
2768 return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
2769 }
2770
2771 sub get_ruleset_cmdlist {
2772 my ($ruleset, $verbose) = @_;
2773
2774 my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
2775
2776 my ($active_chains, $hooks) = iptables_get_chains();
2777 my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, $verbose);
2778
2779 # create missing chains first
2780 foreach my $chain (sort keys %$ruleset) {
2781 my $stat = $statushash->{$chain};
2782 die "internal error" if !$stat;
2783 next if $stat->{action} ne 'create';
2784
2785 $cmdlist .= ":$chain - [0:0]\n";
2786 }
2787
2788 foreach my $h (qw(INPUT OUTPUT FORWARD)) {
2789 if (!$hooks->{$h}) {
2790 $cmdlist .= "-A $h -j PVEFW-$h\n";
2791 }
2792 }
2793
2794 foreach my $chain (sort keys %$ruleset) {
2795 my $stat = $statushash->{$chain};
2796 die "internal error" if !$stat;
2797
2798 if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
2799 $cmdlist .= "-F $chain\n";
2800 foreach my $cmd (@{$ruleset->{$chain}}) {
2801 $cmdlist .= "$cmd\n";
2802 }
2803 $cmdlist .= print_sig_rule($chain, $stat->{sig});
2804 } elsif ($stat->{action} eq 'delete') {
2805 die "internal error"; # this should not happen
2806 } elsif ($stat->{action} eq 'exists') {
2807 # do nothing
2808 } else {
2809 die "internal error - unknown status '$stat->{action}'";
2810 }
2811 }
2812
2813 foreach my $chain (keys %$statushash) {
2814 next if $statushash->{$chain}->{action} ne 'delete';
2815 $cmdlist .= "-F $chain\n";
2816 }
2817 foreach my $chain (keys %$statushash) {
2818 next if $statushash->{$chain}->{action} ne 'delete';
2819 next if $chain eq 'PVEFW-INPUT';
2820 next if $chain eq 'PVEFW-OUTPUT';
2821 next if $chain eq 'PVEFW-FORWARD';
2822 $cmdlist .= "-X $chain\n";
2823 }
2824
2825 my $changes = $cmdlist ne "*filter\n" ? 1 : 0;
2826
2827 $cmdlist .= "COMMIT\n";
2828
2829 return wantarray ? ($cmdlist, $changes) : $cmdlist;
2830 }
2831
2832 sub get_ipset_cmdlist {
2833 my ($ruleset, $verbose) = @_;
2834
2835 my $cmdlist = "";
2836
2837 my $delete_cmdlist = "";
2838
2839 my $active_chains = ipset_get_chains();
2840 my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest, $verbose);
2841
2842 # remove stale _swap chains
2843 foreach my $chain (keys %$active_chains) {
2844 if ($chain =~ m/^PVEFW-\S+_swap$/) {
2845 $cmdlist .= "destroy $chain\n";
2846 }
2847 }
2848
2849 foreach my $chain (sort keys %$ruleset) {
2850 my $stat = $statushash->{$chain};
2851 die "internal error" if !$stat;
2852
2853 if ($stat->{action} eq 'create') {
2854 foreach my $cmd (@{$ruleset->{$chain}}) {
2855 $cmdlist .= "$cmd\n";
2856 }
2857 }
2858
2859 if ($stat->{action} eq 'update') {
2860 my $chain_swap = $chain."_swap";
2861
2862 foreach my $cmd (@{$ruleset->{$chain}}) {
2863 $cmd =~ s/$chain/$chain_swap/;
2864 $cmdlist .= "$cmd\n";
2865 }
2866 $cmdlist .= "swap $chain_swap $chain\n";
2867 $cmdlist .= "flush $chain_swap\n";
2868 $cmdlist .= "destroy $chain_swap\n";
2869 }
2870
2871 }
2872
2873 foreach my $chain (keys %$statushash) {
2874 next if $statushash->{$chain}->{action} ne 'delete';
2875
2876 $delete_cmdlist .= "flush $chain\n";
2877 $delete_cmdlist .= "destroy $chain\n";
2878 }
2879
2880 my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
2881
2882 return ($cmdlist, $delete_cmdlist, $changes);
2883 }
2884
2885 sub apply_ruleset {
2886 my ($ruleset, $hostfw_conf, $ipset_ruleset, $verbose) = @_;
2887
2888 enable_bridge_firewall();
2889
2890 my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
2891 get_ipset_cmdlist($ipset_ruleset, undef, $verbose);
2892
2893 my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset, $verbose);
2894
2895 if ($verbose) {
2896 if ($ipset_changes) {
2897 print "ipset changes:\n";
2898 print $ipset_create_cmdlist if $ipset_create_cmdlist;
2899 print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
2900 }
2901
2902 if ($changes) {
2903 print "iptables changes:\n";
2904 print $cmdlist;
2905 }
2906 }
2907
2908 ipset_restore_cmdlist($ipset_create_cmdlist);
2909
2910 iptables_restore_cmdlist($cmdlist);
2911
2912 ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
2913
2914 # test: re-read status and check if everything is up to date
2915 my $active_chains = iptables_get_chains();
2916 my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, 0);
2917
2918 my $errors;
2919 foreach my $chain (sort keys %$ruleset) {
2920 my $stat = $statushash->{$chain};
2921 if ($stat->{action} ne 'exists') {
2922 warn "unable to update chain '$chain'\n";
2923 $errors = 1;
2924 }
2925 }
2926
2927 die "unable to apply firewall changes\n" if $errors;
2928
2929 update_nf_conntrack_max($hostfw_conf);
2930
2931 update_nf_conntrack_tcp_timeout_established($hostfw_conf);
2932
2933 }
2934
2935 sub update_nf_conntrack_max {
2936 my ($hostfw_conf) = @_;
2937
2938 my $max = 65536; # reasonable default
2939
2940 my $options = $hostfw_conf->{options} || {};
2941
2942 if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
2943 $max = $options->{nf_conntrack_max};
2944 $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
2945 }
2946
2947 my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
2948 my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
2949
2950 my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
2951
2952 if ($current != $max) {
2953 my $hashsize = int($max/4);
2954 PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
2955 PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
2956 }
2957 }
2958
2959 sub update_nf_conntrack_tcp_timeout_established {
2960 my ($hostfw_conf) = @_;
2961
2962 my $options = $hostfw_conf->{options} || {};
2963
2964 my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
2965
2966 PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
2967 }
2968
2969 sub remove_pvefw_chains {
2970
2971 my ($chash, $hooks) = iptables_get_chains();
2972 my $cmdlist = "*filter\n";
2973
2974 foreach my $h (qw(INPUT OUTPUT FORWARD)) {
2975 if ($hooks->{$h}) {
2976 $cmdlist .= "-D $h -j PVEFW-$h\n";
2977 }
2978 }
2979
2980 foreach my $chain (keys %$chash) {
2981 $cmdlist .= "-F $chain\n";
2982 }
2983
2984 foreach my $chain (keys %$chash) {
2985 $cmdlist .= "-X $chain\n";
2986 }
2987 $cmdlist .= "COMMIT\n";
2988
2989 iptables_restore_cmdlist($cmdlist);
2990 }
2991
2992 sub update {
2993 my ($start, $verbose) = @_;
2994
2995 my $code = sub {
2996
2997 my $cluster_conf = load_clusterfw_conf();
2998 my $cluster_options = $cluster_conf->{options};
2999
3000 my $enable = $cluster_options->{enable};
3001
3002 my $status = read_pvefw_status();
3003
3004 die "Firewall is disabled - cannot start\n" if !$enable && $start;
3005
3006 if (!$enable) {
3007 PVE::Firewall::remove_pvefw_chains();
3008 print "Firewall disabled\n" if $verbose;
3009 return;
3010 }
3011
3012 my $hostfw_conf = load_hostfw_conf();
3013
3014 my ($ruleset, $ipset_ruleset) = compile($cluster_conf, $hostfw_conf);
3015
3016 if ($start || $status eq 'active') {
3017
3018 save_pvefw_status('active') if ($status ne 'active');
3019
3020 apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $verbose);
3021 } else {
3022 print "Firewall not active (status = $status)\n" if $verbose;
3023 }
3024 };
3025
3026 run_locked($code);
3027 }
3028
3029
3030 1;
Firewall test scripts