src/PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5 use Data::Dumper;
   6 use Digest::SHA;
   7 use PVE::INotify;
   8 use PVE::JSONSchema qw(get_standard_option);
   9 use PVE::Cluster;
  10 use PVE::ProcFSTools;
  11 use PVE::Tools;
  12 use File::Basename;
  13 use File::Path;
  14 use IO::File;
  15 use Net::IP;
  16 use PVE::Tools qw(run_command lock_file);
  17 use Encode;
  18
  19 my $clusterfw_conf_filename = "/etc/pve/firewall/cluster.fw";
  20
  21 # dynamically include PVE::QemuServer and PVE::OpenVZ
  22 # to avoid dependency problems
  23 my $have_qemu_server;
  24 eval {
  25     require PVE::QemuServer;
  26     $have_qemu_server = 1;
  27 };
  28
  29 my $have_pve_manager;
  30 eval {
  31     require PVE::OpenVZ;
  32     $have_pve_manager = 1;
  33 };
  34
  35 use Data::Dumper;
  36
  37 my $nodename = PVE::INotify::nodename();
  38
  39 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
  40 my $pve_fw_status_filename = "/var/lib/pve-firewall/pvefw.status";
  41
  42 my $default_log_level = 'info';
  43
  44 my $log_level_hash = {
  45     debug => 7,
  46     info => 6,
  47     notice => 5,
  48     warning => 4,
  49     err => 3,
  50     crit => 2,
  51     alert => 1,
  52     emerg => 0,
  53 };
  54
  55 # imported/converted from: /usr/share/shorewall/macro.*
  56 my $pve_fw_macros = {
  57     'Amanda' => [
  58         { action => 'PARAM', proto => 'udp', dport => '10080' },
  59         { action => 'PARAM', proto => 'tcp', dport => '10080' },
  60     ],
  61     'Auth' => [
  62         { action => 'PARAM', proto => 'tcp', dport => '113' },
  63     ],
  64     'BGP' => [
  65         { action => 'PARAM', proto => 'tcp', dport => '179' },
  66     ],
  67     'BitTorrent' => [
  68         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
  69         { action => 'PARAM', proto => 'udp', dport => '6881' },
  70     ],
  71     'BitTorrent32' => [
  72         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
  73         { action => 'PARAM', proto => 'udp', dport => '6881' },
  74     ],
  75     'CVS' => [
  76         { action => 'PARAM', proto => 'tcp', dport => '2401' },
  77     ],
  78     'Citrix' => [
  79         { action => 'PARAM', proto => 'tcp', dport => '1494' },
  80         { action => 'PARAM', proto => 'udp', dport => '1604' },
  81         { action => 'PARAM', proto => 'tcp', dport => '2598' },
  82     ],
  83     'DAAP' => [
  84         { action => 'PARAM', proto => 'tcp', dport => '3689' },
  85         { action => 'PARAM', proto => 'udp', dport => '3689' },
  86     ],
  87     'DCC' => [
  88         { action => 'PARAM', proto => 'tcp', dport => '6277' },
  89     ],
  90     'DHCPfwd' => [
  91         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
  92         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '67:68', sport => '67:68' },
  93     ],
  94     'DNS' => [
  95         { action => 'PARAM', proto => 'udp', dport => '53' },
  96         { action => 'PARAM', proto => 'tcp', dport => '53' },
  97     ],
  98     'Distcc' => [
  99         { action => 'PARAM', proto => 'tcp', dport => '3632' },
 100     ],
 101     'Edonkey' => [
 102         { action => 'PARAM', proto => 'tcp', dport => '4662' },
 103         { action => 'PARAM', proto => 'udp', dport => '4665' },
 104     ],
 105     'FTP' => [
 106         { action => 'PARAM', proto => 'tcp', dport => '21' },
 107     ],
 108     'Finger' => [
 109         { action => 'PARAM', proto => 'tcp', dport => '79' },
 110     ],
 111     'GNUnet' => [
 112         { action => 'PARAM', proto => 'tcp', dport => '2086' },
 113         { action => 'PARAM', proto => 'udp', dport => '2086' },
 114         { action => 'PARAM', proto => 'tcp', dport => '1080' },
 115         { action => 'PARAM', proto => 'udp', dport => '1080' },
 116     ],
 117     'GRE' => [
 118         { action => 'PARAM', proto => '47' },
 119         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '47' },
 120     ],
 121     'Git' => [
 122         { action => 'PARAM', proto => 'tcp', dport => '9418' },
 123     ],
 124     'Gnutella' => [
 125         { action => 'PARAM', proto => 'tcp', dport => '6346' },
 126         { action => 'PARAM', proto => 'udp', dport => '6346' },
 127     ],
 128     'HKP' => [
 129         { action => 'PARAM', proto => 'tcp', dport => '11371' },
 130     ],
 131     'HTTP' => [
 132         { action => 'PARAM', proto => 'tcp', dport => '80' },
 133     ],
 134     'HTTPS' => [
 135         { action => 'PARAM', proto => 'tcp', dport => '443' },
 136     ],
 137     'ICPV2' => [
 138         { action => 'PARAM', proto => 'udp', dport => '3130' },
 139     ],
 140     'ICQ' => [
 141         { action => 'PARAM', proto => 'tcp', dport => '5190' },
 142     ],
 143     'IMAP' => [
 144         { action => 'PARAM', proto => 'tcp', dport => '143' },
 145     ],
 146     'IMAPS' => [
 147         { action => 'PARAM', proto => 'tcp', dport => '993' },
 148     ],
 149     'IPIP' => [
 150         { action => 'PARAM', proto => '94' },
 151         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '94' },
 152     ],
 153     'IPP' => [
 154         { action => 'PARAM', proto => 'tcp', dport => '631' },
 155     ],
 156     'IPPbrd' => [
 157         { action => 'PARAM', proto => 'udp', dport => '631' },
 158     ],
 159     'IPPserver' => [
 160         { action => 'PARAM', source => 'SOURCE', dest => 'DEST', proto => 'tcp', dport => '631' },
 161         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '631' },
 162     ],
 163     'IPsec' => [
 164         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 165         { action => 'PARAM', proto => '50' },
 166         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500', sport => '500' },
 167         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '50' },
 168     ],
 169     'IPsecah' => [
 170         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 171         { action => 'PARAM', proto => '51' },
 172         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500', sport => '500' },
 173         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '51' },
 174     ],
 175     'IPsecnat' => [
 176         { action => 'PARAM', proto => 'udp', dport => '500' },
 177         { action => 'PARAM', proto => 'udp', dport => '4500' },
 178         { action => 'PARAM', proto => '50' },
 179         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500' },
 180         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '4500' },
 181         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '50' },
 182     ],
 183     'IRC' => [
 184         { action => 'PARAM', proto => 'tcp', dport => '6667' },
 185     ],
 186     'JabberPlain' => [
 187         { action => 'PARAM', proto => 'tcp', dport => '5222' },
 188     ],
 189     'JabberSecure' => [
 190         { action => 'PARAM', proto => 'tcp', dport => '5223' },
 191     ],
 192     'Jabberd' => [
 193         { action => 'PARAM', proto => 'tcp', dport => '5269' },
 194     ],
 195     'Jetdirect' => [
 196         { action => 'PARAM', proto => 'tcp', dport => '9100' },
 197     ],
 198     'L2TP' => [
 199         { action => 'PARAM', proto => 'udp', dport => '1701' },
 200         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '1701' },
 201     ],
 202     'LDAP' => [
 203         { action => 'PARAM', proto => 'tcp', dport => '389' },
 204     ],
 205     'LDAPS' => [
 206         { action => 'PARAM', proto => 'tcp', dport => '636' },
 207     ],
 208     'MSNP' => [
 209         { action => 'PARAM', proto => 'tcp', dport => '1863' },
 210     ],
 211     'MSSQL' => [
 212         { action => 'PARAM', proto => 'tcp', dport => '1433' },
 213     ],
 214     'Mail' => [
 215         { action => 'PARAM', proto => 'tcp', dport => '25' },
 216         { action => 'PARAM', proto => 'tcp', dport => '465' },
 217         { action => 'PARAM', proto => 'tcp', dport => '587' },
 218     ],
 219     'Munin' => [
 220         { action => 'PARAM', proto => 'tcp', dport => '4949' },
 221     ],
 222     'MySQL' => [
 223         { action => 'PARAM', proto => 'tcp', dport => '3306' },
 224     ],
 225     'NNTP' => [
 226         { action => 'PARAM', proto => 'tcp', dport => '119' },
 227     ],
 228     'NNTPS' => [
 229         { action => 'PARAM', proto => 'tcp', dport => '563' },
 230     ],
 231     'NTP' => [
 232         { action => 'PARAM', proto => 'udp', dport => '123' },
 233     ],
 234     'NTPbi' => [
 235         { action => 'PARAM', proto => 'udp', dport => '123' },
 236         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '123' },
 237     ],
 238     'NTPbrd' => [
 239         { action => 'PARAM', proto => 'udp', dport => '123' },
 240         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '123' },
 241     ],
 242     'OSPF' => [
 243         { action => 'PARAM', proto => '89' },
 244     ],
 245     'OpenVPN' => [
 246         { action => 'PARAM', proto => 'udp', dport => '1194' },
 247     ],
 248     'PCA' => [
 249         { action => 'PARAM', proto => 'udp', dport => '5632' },
 250         { action => 'PARAM', proto => 'tcp', dport => '5631' },
 251     ],
 252     'POP3' => [
 253         { action => 'PARAM', proto => 'tcp', dport => '110' },
 254     ],
 255     'POP3S' => [
 256         { action => 'PARAM', proto => 'tcp', dport => '995' },
 257     ],
 258     'PPtP' => [
 259         { action => 'PARAM', proto => '47' },
 260         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '47' },
 261         { action => 'PARAM', proto => 'tcp', dport => '1723' },
 262     ],
 263     'Ping' => [
 264         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 265     ],
 266     'PostgreSQL' => [
 267         { action => 'PARAM', proto => 'tcp', dport => '5432' },
 268     ],
 269     'Printer' => [
 270         { action => 'PARAM', proto => 'tcp', dport => '515' },
 271     ],
 272     'RDP' => [
 273         { action => 'PARAM', proto => 'tcp', dport => '3389' },
 274     ],
 275     'RIPbi' => [
 276         { action => 'PARAM', proto => 'udp', dport => '520' },
 277         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '520' },
 278     ],
 279     'RNDC' => [
 280         { action => 'PARAM', proto => 'tcp', dport => '953' },
 281     ],
 282     'Razor' => [
 283         { action => 'ACCEPT', proto => 'tcp', dport => '2703' },
 284     ],
 285     'Rdate' => [
 286         { action => 'PARAM', proto => 'tcp', dport => '37' },
 287     ],
 288     'Rsync' => [
 289         { action => 'PARAM', proto => 'tcp', dport => '873' },
 290     ],
 291     'SANE' => [
 292         { action => 'PARAM', proto => 'tcp', dport => '6566' },
 293     ],
 294     'SMB' => [
 295         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 296         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 297         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 298         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 299     ],
 300     'SMBBI' => [
 301         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 302         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 303         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 304         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 305         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '135,445' },
 306         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '137:139' },
 307         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '1024:65535', sport => '137' },
 308         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'tcp', dport => '135,139,445' },
 309     ],
 310     'SMBswat' => [
 311         { action => 'PARAM', proto => 'tcp', dport => '901' },
 312     ],
 313     'SMTP' => [
 314         { action => 'PARAM', proto => 'tcp', dport => '25' },
 315     ],
 316     'SMTPS' => [
 317         { action => 'PARAM', proto => 'tcp', dport => '465' },
 318     ],
 319     'SNMP' => [
 320         { action => 'PARAM', proto => 'udp', dport => '161:162' },
 321         { action => 'PARAM', proto => 'tcp', dport => '161' },
 322     ],
 323     'SPAMD' => [
 324         { action => 'PARAM', proto => 'tcp', dport => '783' },
 325     ],
 326     'SSH' => [
 327         { action => 'PARAM', proto => 'tcp', dport => '22' },
 328     ],
 329     'SVN' => [
 330         { action => 'PARAM', proto => 'tcp', dport => '3690' },
 331     ],
 332     'SixXS' => [
 333         { action => 'PARAM', proto => 'tcp', dport => '3874' },
 334         { action => 'PARAM', proto => 'udp', dport => '3740' },
 335         { action => 'PARAM', proto => '41' },
 336         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
 337     ],
 338     'Squid' => [
 339         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 340     ],
 341     'Submission' => [
 342         { action => 'PARAM', proto => 'tcp', dport => '587' },
 343     ],
 344     'Syslog' => [
 345         { action => 'PARAM', proto => 'udp', dport => '514' },
 346         { action => 'PARAM', proto => 'tcp', dport => '514' },
 347     ],
 348     'TFTP' => [
 349         { action => 'PARAM', proto => 'udp', dport => '69' },
 350     ],
 351     'Telnet' => [
 352         { action => 'PARAM', proto => 'tcp', dport => '23' },
 353     ],
 354     'Telnets' => [
 355         { action => 'PARAM', proto => 'tcp', dport => '992' },
 356     ],
 357     'Time' => [
 358         { action => 'PARAM', proto => 'tcp', dport => '37' },
 359     ],
 360     'Trcrt' => [
 361         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 362         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 363     ],
 364     'VNC' => [
 365         { action => 'PARAM', proto => 'tcp', dport => '5900:5909' },
 366     ],
 367     'VNCL' => [
 368         { action => 'PARAM', proto => 'tcp', dport => '5500' },
 369     ],
 370     'Web' => [
 371         { action => 'PARAM', proto => 'tcp', dport => '80' },
 372         { action => 'PARAM', proto => 'tcp', dport => '443' },
 373     ],
 374     'Webcache' => [
 375         { action => 'PARAM', proto => 'tcp', dport => '8080' },
 376     ],
 377     'Webmin' => [
 378         { action => 'PARAM', proto => 'tcp', dport => '10000' },
 379     ],
 380     'Whois' => [
 381         { action => 'PARAM', proto => 'tcp', dport => '43' },
 382     ],
 383 };
 384
 385 my $pve_fw_parsed_macros;
 386 my $pve_fw_preferred_macro_names = {};
 387
 388 my $pve_std_chains = {
 389     'PVEFW-SET-ACCEPT-MARK' => [
 390         "-j MARK --set-mark 1",
 391     ],
 392     'PVEFW-DropBroadcast' => [
 393         # same as shorewall 'Broadcast'
 394         # simply DROP BROADCAST/MULTICAST/ANYCAST
 395         # we can use this to reduce logging
 396         { action => 'DROP', dsttype => 'BROADCAST' },
 397         { action => 'DROP', dsttype => 'MULTICAST' },
 398         { action => 'DROP', dsttype => 'ANYCAST' },
 399         { action => 'DROP', dest => '224.0.0.0/4' },
 400     ],
 401     'PVEFW-reject' => [
 402         # same as shorewall 'reject'
 403         { action => 'DROP', dsttype => 'BROADCAST' },
 404         { action => 'DROP', source => '224.0.0.0/4' },
 405         { action => 'DROP', proto => 'icmp' },
 406         "-p tcp -j REJECT --reject-with tcp-reset",
 407         "-p udp -j REJECT --reject-with icmp-port-unreachable",
 408         "-p icmp -j REJECT --reject-with icmp-host-unreachable",
 409         "-j REJECT --reject-with icmp-host-prohibited",
 410     ],
 411     'PVEFW-Drop' => [
 412         # same as shorewall 'Drop', which is equal to DROP,
 413         # but REJECT/DROP some packages to reduce logging,
 414         # and ACCEPT critical ICMP types
 415         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 416         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 417         { action => 'PVEFW-DropBroadcast' },
 418         # ACCEPT critical ICMP types
 419         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 420         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 421         # Drop packets with INVALID state
 422         "-m conntrack --ctstate INVALID -j DROP",
 423         # Drop Microsoft SMB noise
 424         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
 425         { action => 'DROP', proto => 'udp', dport => '137:139'},
 426         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 427         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 428         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 429         # Drop new/NotSyn traffic so that it doesn't get logged
 430         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 431         # Drop DNS replies
 432         { action => 'DROP', proto => 'udp', sport => 53 },
 433     ],
 434     'PVEFW-Reject' => [
 435         # same as shorewall 'Reject', which is equal to Reject,
 436         # but REJECT/DROP some packages to reduce logging,
 437         # and ACCEPT critical ICMP types
 438         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 439         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 440         { action => 'PVEFW-DropBroadcast' },
 441         # ACCEPT critical ICMP types
 442         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 443         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 444         # Drop packets with INVALID state
 445         "-m conntrack --ctstate INVALID -j DROP",
 446         # Drop Microsoft SMB noise
 447         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
 448         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 449         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 450         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 451         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 452         # Drop new/NotSyn traffic so that it doesn't get logged
 453         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 454         # Drop DNS replies
 455         { action => 'DROP', proto => 'udp', sport => 53 },
 456     ],
 457     'PVEFW-tcpflags' => [
 458         # same as shorewall tcpflags action.
 459         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
 460         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
 461         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
 462         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
 463         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
 464         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
 465     ],
 466     'PVEFW-smurfs' => [
 467         # same as shorewall smurfs action
 468         # Filter packets for smurfs (packets with a broadcast address as the source).
 469         "-s 0.0.0.0/32 -j RETURN",
 470         "-m addrtype --src-type BROADCAST -g PVEFW-smurflog",
 471         "-s 224.0.0.0/4 -g PVEFW-smurflog",
 472     ],
 473 };
 474
 475 # iptables -p icmp -h
 476 my $icmp_type_names = {
 477     any => 1,
 478     'echo-reply' => 1,
 479     'destination-unreachable' => 1,
 480     'network-unreachable' => 1,
 481     'host-unreachable' => 1,
 482     'protocol-unreachable' => 1,
 483     'port-unreachable' => 1,
 484     'fragmentation-needed' => 1,
 485     'source-route-failed' => 1,
 486     'network-unknown' => 1,
 487     'host-unknown' => 1,
 488     'network-prohibited' => 1,
 489     'host-prohibited' => 1,
 490     'TOS-network-unreachable' => 1,
 491     'TOS-host-unreachable' => 1,
 492     'communication-prohibited' => 1,
 493     'host-precedence-violation' => 1,
 494     'precedence-cutoff' => 1,
 495     'source-quench' => 1,
 496     'redirect' => 1,
 497     'network-redirect' => 1,
 498     'host-redirect' => 1,
 499     'TOS-network-redirect' => 1,
 500     'TOS-host-redirect' => 1,
 501     'echo-request' => 1,
 502     'router-advertisement' => 1,
 503     'router-solicitation' => 1,
 504     'time-exceeded' => 1,
 505     'ttl-zero-during-transit' => 1,
 506     'ttl-zero-during-reassembly' => 1,
 507     'parameter-problem' => 1,
 508     'ip-header-bad' => 1,
 509     'required-option-missing' => 1,
 510     'timestamp-request' => 1,
 511     'timestamp-reply' => 1,
 512     'address-mask-request' => 1,
 513     'address-mask-reply' => 1,
 514 };
 515
 516 sub init_firewall_macros {
 517
 518     $pve_fw_parsed_macros = {};
 519
 520     foreach my $k (keys %$pve_fw_macros) {
 521         my $lc_name = lc($k);
 522         my $macro = $pve_fw_macros->{$k};
 523         $pve_fw_preferred_macro_names->{$lc_name} = $k;
 524         $pve_fw_parsed_macros->{$k} = $macro;
 525     }
 526 }
 527
 528 init_firewall_macros();
 529
 530 my $etc_services;
 531
 532 sub get_etc_services {
 533
 534     return $etc_services if $etc_services;
 535
 536     my $filename = "/etc/services";
 537
 538     my $fh = IO::File->new($filename, O_RDONLY);
 539     if (!$fh) {
 540         warn "unable to read '$filename' - $!\n";
 541         return {};
 542     }
 543
 544     my $services = {};
 545
 546     while (my $line = <$fh>) {
 547         chomp ($line);
 548         next if $line =~m/^#/;
 549         next if ($line =~m/^\s*$/);
 550
 551         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
 552             $services->{byid}->{$2}->{name} = $1;
 553             $services->{byid}->{$2}->{port} = $2;
 554             $services->{byid}->{$2}->{$3} = 1;
 555             $services->{byname}->{$1} = $services->{byid}->{$2};
 556         }
 557     }
 558
 559     close($fh);
 560
 561     $etc_services = $services;
 562
 563
 564     return $etc_services;
 565 }
 566
 567 my $etc_protocols;
 568
 569 sub get_etc_protocols {
 570     return $etc_protocols if $etc_protocols;
 571
 572     my $filename = "/etc/protocols";
 573
 574     my $fh = IO::File->new($filename, O_RDONLY);
 575     if (!$fh) {
 576         warn "unable to read '$filename' - $!\n";
 577         return {};
 578     }
 579
 580     my $protocols = {};
 581
 582     while (my $line = <$fh>) {
 583         chomp ($line);
 584         next if $line =~m/^#/;
 585         next if ($line =~m/^\s*$/);
 586
 587         if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
 588             $protocols->{byid}->{$2}->{name} = $1;
 589             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
 590         }
 591     }
 592
 593     close($fh);
 594
 595     $etc_protocols = $protocols;
 596
 597     return $etc_protocols;
 598 }
 599
 600 sub parse_address_list {
 601     my ($str) = @_;
 602
 603     my $nbaor = 0;
 604     foreach my $aor (split(/,/, $str)) {
 605         if (!Net::IP->new($aor)) {
 606             my $err = Net::IP::Error();
 607             die "invalid IP address: $err\n";
 608         }else{
 609             $nbaor++;
 610         }
 611     }
 612     return $nbaor;
 613 }
 614
 615 sub parse_port_name_number_or_range {
 616     my ($str) = @_;
 617
 618     my $services = PVE::Firewall::get_etc_services();
 619     my $nbports = 0;
 620     foreach my $item (split(/,/, $str)) {
 621         my $portlist = "";
 622         my $oldpon = undef;
 623         $nbports++;
 624         foreach my $pon (split(':', $item, 2)) {
 625             $pon = $services->{byname}->{$pon}->{port} if $services->{byname}->{$pon}->{port};
 626             if ($pon =~ m/^\d+$/){
 627                 die "invalid port '$pon'\n" if $pon < 0 && $pon > 65535;
 628                 die "port '$pon' must be bigger than port '$oldpon' \n" if $oldpon && ($pon < $oldpon);
 629                 $oldpon = $pon;
 630             }else{
 631                 die "invalid port $services->{byname}->{$pon}\n" if !$services->{byname}->{$pon};
 632             }
 633         }
 634     }
 635
 636     return ($nbports);
 637 }
 638
 639 PVE::JSONSchema::register_format('pve-fw-port-spec', \&pve_fw_verify_port_spec);
 640 sub pve_fw_verify_port_spec {
 641    my ($portstr) = @_;
 642
 643     parse_port_name_number_or_range($portstr);
 644
 645    return $portstr;
 646 }
 647
 648 PVE::JSONSchema::register_format('pve-fw-v4addr-spec', \&pve_fw_verify_v4addr_spec);
 649 sub pve_fw_verify_v4addr_spec {
 650    my ($list) = @_;
 651
 652    parse_address_list($list);
 653
 654    return $list;
 655 }
 656
 657 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
 658 sub pve_fw_verify_protocol_spec {
 659    my ($proto) = @_;
 660
 661    my $protocols = get_etc_protocols();
 662
 663    die "unknown protocol '$proto'\n" if $proto &&
 664        !(defined($protocols->{byname}->{$proto}) ||
 665          defined($protocols->{byid}->{$proto}));
 666
 667    return $proto;
 668 }
 669
 670
 671 # helper function for API
 672
 673 my $rule_properties = {
 674     pos => {
 675         description => "Update rule at position <pos>.",
 676         type => 'integer',
 677         minimum => 0,
 678         optional => 1,
 679     },
 680     digest => {
 681         type => 'string',
 682         optional => 1,
 683         maxLength => 27,
 684         minLength => 27,
 685     },
 686     type => {
 687         type => 'string',
 688         optional => 1,
 689         enum => ['in', 'out', 'group'],
 690     },
 691     action => {
 692         type => 'string',
 693         optional => 1,
 694         enum => ['ACCEPT', 'DROP', 'REJECT'],
 695     },
 696     macro => {
 697         type => 'string',
 698         optional => 1,
 699         maxLength => 128,
 700     },
 701     iface => get_standard_option('pve-iface', { optional => 1 }),
 702     source => {
 703         type => 'string', format => 'pve-fw-v4addr-spec',
 704         optional => 1,
 705     },
 706     dest => {
 707         type => 'string', format => 'pve-fw-v4addr-spec',
 708         optional => 1,
 709     },
 710     proto => {
 711         type => 'string', format => 'pve-fw-protocol-spec',
 712         optional => 1,
 713     },
 714     enable => {
 715         type => 'boolean',
 716         optional => 1,
 717     },
 718     sport => {
 719         type => 'string', format => 'pve-fw-port-spec',
 720         optional => 1,
 721     },
 722     dport => {
 723         type => 'string', format => 'pve-fw-port-spec',
 724         optional => 1,
 725     },
 726     comment => {
 727         type => 'string',
 728         optional => 1,
 729     },
 730 };
 731
 732 sub cleanup_fw_rule {
 733     my ($rule, $digest, $pos) = @_;
 734
 735     my $r = {};
 736
 737     foreach my $k (keys %$rule) {
 738         next if !$rule_properties->{$k};
 739         my $v = $rule->{$k};
 740         next if !defined($v);
 741         $r->{$k} = $v;
 742         $r->{digest} = $digest;
 743         $r->{pos} = $pos;
 744     }
 745
 746     return $r;
 747 }
 748
 749 sub add_rule_properties {
 750     my ($properties) = @_;
 751
 752     foreach my $k (keys %$rule_properties) {
 753         $properties->{$k} = $rule_properties->{$k};
 754     }
 755
 756     return $properties;
 757 }
 758
 759 sub copy_rule_data {
 760     my ($rule, $param) = @_;
 761
 762     foreach my $k (keys %$rule_properties) {
 763         if (defined(my $v = $param->{$k})) {
 764             if ($v eq '' || $v eq '-') {
 765                 delete $rule->{$k};
 766             } else {
 767                 $rule->{$k} = $v;
 768             }
 769         } else {
 770             delete $rule->{$k};
 771         }
 772     }
 773     return $rule;
 774 }
 775
 776 # core functions
 777 my $bridge_firewall_enabled = 0;
 778
 779 sub enable_bridge_firewall {
 780
 781     return if $bridge_firewall_enabled; # only once
 782
 783     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
 784     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
 785
 786     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
 787     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
 788
 789     $bridge_firewall_enabled = 1;
 790 }
 791
 792 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
 793
 794 sub iptables {
 795     my ($cmd) = @_;
 796
 797     run_command("/sbin/iptables $cmd", outfunc => sub {}, errfunc => sub {});
 798 }
 799
 800 sub iptables_restore_cmdlist {
 801     my ($cmdlist) = @_;
 802
 803     run_command("/sbin/iptables-restore -n", input => $cmdlist);
 804 }
 805
 806 sub ipset_restore_cmdlist {
 807     my ($cmdlist) = @_;
 808
 809     run_command(" /usr/sbin/ipset restore", input => $cmdlist);
 810 }
 811
 812 sub iptables_get_chains {
 813
 814     my $res = {};
 815
 816     # check what chains we want to track
 817     my $is_pvefw_chain = sub {
 818         my $name = shift;
 819
 820         return 1 if $name =~ m/^PVEFW-\S+$/;
 821
 822         return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
 823
 824         return 1 if $name =~ m/^veth\d+.\d+-(:?IN|OUT)$/; # fixme: dev name is configurable
 825
 826         return 1 if $name =~ m/^venet0-\d+-(:?IN|OUT)$/;
 827
 828         return 1 if $name =~ m/^vmbr\d+-(:?FW|IN|OUT|IPS)$/;
 829         return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
 830
 831         return undef;
 832     };
 833
 834     my $table = '';
 835
 836     my $parser = sub {
 837         my $line = shift;
 838
 839         return if $line =~ m/^#/;
 840         return if $line =~ m/^\s*$/;
 841
 842         if ($line =~ m/^\*(\S+)$/) {
 843             $table = $1;
 844             return;
 845         }
 846
 847         return if $table ne 'filter';
 848
 849         if ($line =~ m/^:(\S+)\s/) {
 850             my $chain = $1;
 851             return if !&$is_pvefw_chain($chain);
 852             $res->{$chain} = "unknown";
 853         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
 854             my ($chain, $sig) = ($1, $2);
 855             return if !&$is_pvefw_chain($chain);
 856             $res->{$chain} = $sig;
 857         } else {
 858             # simply ignore the rest
 859             return;
 860         }
 861     };
 862
 863     run_command("/sbin/iptables-save", outfunc => $parser);
 864
 865     return $res;
 866 }
 867
 868 sub ipset_chain_digest {
 869     my ($rules) = @_;
 870     my $digest = Digest::SHA->new('sha1');
 871     foreach my $rule (sort @$rules) { # note: sorted
 872         $digest->add($rule);
 873     }
 874     return $digest->b64digest;
 875 }
 876
 877 sub ipset_get_chains {
 878
 879     my $res = {};
 880     my $chains = {};
 881
 882     my $parser = sub {
 883         my $line = shift;
 884
 885         return if $line =~ m/^#/;
 886         return if $line =~ m/^\s*$/;
 887         if ($line =~ m/^(\S+)\s(\S+)\s(\S+)/) {
 888             push @{$chains->{$2}}, $line;
 889         } else {
 890             # simply ignore the rest
 891             return;
 892         }
 893     };
 894
 895     run_command("/usr/sbin/ipset save", outfunc => $parser);
 896
 897     # compute digest for each chain
 898     foreach my $chain (keys %$chains) {
 899         $res->{$chain} = ipset_chain_digest($chains->{$chain});
 900     }
 901
 902     return $res;
 903 }
 904
 905 sub iptables_chain_exist {
 906     my ($chain) = @_;
 907
 908     eval{
 909         iptables("-n --list $chain");
 910     };
 911     return undef if $@;
 912
 913     return 1;
 914 }
 915
 916 sub iptables_rule_exist {
 917     my ($rule) = @_;
 918
 919     eval{
 920         iptables("-C $rule");
 921     };
 922     return undef if $@;
 923
 924     return 1;
 925 }
 926
 927 sub ruleset_generate_cmdstr {
 928     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
 929
 930     return if defined($rule->{enable}) && !$rule->{enable};
 931
 932     die "unable to emit macro - internal error" if $rule->{macro}; # should not happen
 933
 934     my $nbdport = defined($rule->{dport}) ? parse_port_name_number_or_range($rule->{dport}) : 0;
 935     my $nbsport = defined($rule->{sport}) ? parse_port_name_number_or_range($rule->{sport}) : 0;
 936     my $nbsource = $rule->{source} ? parse_address_list( $rule->{source}) : 0;
 937     my $nbdest = $rule->{dest} ? parse_address_list($rule->{dest}) : 0;
 938
 939     my @cmd = ();
 940
 941     push @cmd, "-i $rule->{iface_in}" if $rule->{iface_in};
 942     push @cmd, "-o $rule->{iface_out}" if $rule->{iface_out};
 943
 944     push @cmd, "-m iprange --src-range" if $nbsource > 1;
 945     push @cmd, "-s $rule->{source}" if $rule->{source};
 946     push @cmd, "-m iprange --dst-range" if $nbdest > 1;
 947     push @cmd, "-d $rule->{dest}" if $rule->{dest};
 948
 949     if ($rule->{proto}) {
 950         push @cmd, "-p $rule->{proto}";
 951
 952         my $multiport = 0;
 953         $multiport++ if $nbdport > 1;
 954         $multiport++ if $nbsport > 1;
 955
 956         push @cmd, "--match multiport" if $multiport;
 957
 958         die "multiport: option '--sports' cannot be used together with '--dports'\n"
 959             if ($multiport == 2) && ($rule->{dport} ne $rule->{sport});
 960
 961         if ($rule->{dport}) {
 962             if ($rule->{proto} && $rule->{proto} eq 'icmp') {
 963                 # Note: we use dport to store --icmp-type
 964                 die "unknown icmp-type '$rule->{dport}'\n" if !defined($icmp_type_names->{$rule->{dport}});
 965                 push @cmd, "-m icmp --icmp-type $rule->{dport}";
 966             } else {
 967                 if ($nbdport > 1) {
 968                     if ($multiport == 2) {
 969                         push @cmd,  "--ports $rule->{dport}";
 970                     } else {
 971                         push @cmd, "--dports $rule->{dport}";
 972                     }
 973                 } else {
 974                     push @cmd, "--dport $rule->{dport}";
 975                 }
 976             }
 977         }
 978
 979         if ($rule->{sport}) {
 980             if ($nbsport > 1) {
 981                 push @cmd, "--sports $rule->{sport}" if $multiport != 2;
 982             } else {
 983                 push @cmd, "--sport $rule->{sport}";
 984             }
 985         }
 986     } elsif ($rule->{dport} || $rule->{sport}) {
 987         warn "ignoring destination port '$rule->{dport}' - no protocol specified\n" if $rule->{dport};
 988         warn "ignoring source port '$rule->{sport}' - no protocol specified\n" if $rule->{sport};
 989     }
 990
 991     push @cmd, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
 992
 993     if (my $action = $rule->{action}) {
 994         $action = $actions->{$action} if defined($actions->{$action});
 995         $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
 996         push @cmd, $goto ? "-g $action" : "-j $action";
 997     }
 998
 999     return scalar(@cmd) ? join(' ', @cmd) : undef;
1000 }
1001
1002 my $apply_macro = sub {
1003     my ($macro_name, $param) = @_;
1004
1005     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1006     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1007
1008     my $rules = [];
1009
1010     foreach my $templ (@$macro_rules) {
1011         my $rule = {};
1012         my $param_used = {};
1013         foreach my $k (keys %$templ) {
1014             my $v = $templ->{$k};
1015             if ($v eq 'PARAM') {
1016                 $v = $param->{$k};
1017                 $param_used->{$k} = 1;
1018             } elsif ($v eq 'DEST') {
1019                 $v = $param->{dest};
1020                 $param_used->{dest} = 1;
1021             } elsif ($v eq 'SOURCE') {
1022                 $v = $param->{source};
1023                 $param_used->{source} = 1;
1024             }
1025
1026             die "missing parameter '$k' in macro '$macro_name'\n" if !defined($v);
1027             $rule->{$k} = $v;
1028         }
1029         foreach my $k (keys %$param) {
1030             next if $k eq 'macro';
1031             next if !defined($param->{$k});
1032             next if $param_used->{$k};
1033             if (defined($rule->{$k})) {
1034                 die "parameter '$k' already define in macro (value = '$rule->{$k}')\n"
1035                     if $rule->{$k} ne $param->{$k};
1036             } else {
1037                 $rule->{$k} = $param->{$k};
1038             }
1039         }
1040         push @$rules, $rule;
1041     }
1042
1043     return $rules;
1044 };
1045
1046 sub ruleset_generate_rule {
1047     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
1048
1049     my $rules;
1050
1051     if ($rule->{macro}) {
1052         $rules = &$apply_macro($rule->{macro}, $rule);
1053     } else {
1054         $rules = [ $rule ];
1055     }
1056
1057     foreach my $tmp (@$rules) {
1058         if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $tmp, $actions, $goto)) {
1059             ruleset_addrule($ruleset, $chain, $cmdstr);
1060         }
1061     }
1062 }
1063
1064 sub ruleset_generate_rule_insert {
1065     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
1066
1067     die "implement me" if $rule->{macro}; # not implemented, because not needed so far
1068
1069     if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $rule, $actions, $goto)) {
1070         ruleset_insertrule($ruleset, $chain, $cmdstr);
1071     }
1072 }
1073
1074 sub ruleset_create_chain {
1075     my ($ruleset, $chain) = @_;
1076
1077     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
1078     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
1079
1080     die "chain '$chain' already exists\n" if $ruleset->{$chain};
1081
1082     $ruleset->{$chain} = [];
1083 }
1084
1085 sub ruleset_chain_exist {
1086     my ($ruleset, $chain) = @_;
1087
1088     return $ruleset->{$chain} ? 1 : undef;
1089 }
1090
1091 sub ruleset_addrule {
1092    my ($ruleset, $chain, $rule) = @_;
1093
1094    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1095
1096    push @{$ruleset->{$chain}}, "-A $chain $rule";
1097 }
1098
1099 sub ruleset_insertrule {
1100    my ($ruleset, $chain, $rule) = @_;
1101
1102    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1103
1104    unshift @{$ruleset->{$chain}}, "-A $chain $rule";
1105 }
1106
1107 sub get_log_rule_base {
1108     my ($chain, $vmid, $msg, $loglevel) = @_;
1109
1110     die "internal error - no log level" if !defined($loglevel);
1111
1112     $vmid = 0 if !defined($vmid);
1113
1114     # Note: we use special format for prefix to pass further
1115     # info to log daemon (VMID, LOGVELEL and CHAIN)
1116
1117     return "-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
1118 }
1119
1120 sub ruleset_addlog {
1121     my ($ruleset, $chain, $vmid, $msg, $loglevel, $rule) = @_;
1122
1123     return if !defined($loglevel);
1124
1125     my $logrule = get_log_rule_base($chain, $vmid, $msg, $loglevel);
1126
1127     $logrule = "$rule $logrule" if defined($rule);
1128
1129     ruleset_addrule($ruleset, $chain, $logrule)
1130 }
1131
1132 sub generate_bridge_chains {
1133     my ($ruleset, $hostfw_conf, $bridge, $routing_table) = @_;
1134
1135     my $options = $hostfw_conf->{options} || {};
1136
1137     die "error: detected direct route to bridge '$bridge'\n"
1138         if !$options->{allow_bridge_route} && $routing_table->{$bridge};
1139
1140     if (!ruleset_chain_exist($ruleset, "$bridge-FW")) {
1141         ruleset_create_chain($ruleset, "$bridge-FW");
1142         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o $bridge -m physdev --physdev-is-out -j $bridge-FW");
1143         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i $bridge -m physdev --physdev-is-in -j $bridge-FW");
1144     }
1145
1146     if (!ruleset_chain_exist($ruleset, "$bridge-OUT")) {
1147         ruleset_create_chain($ruleset, "$bridge-OUT");
1148         ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-in -j $bridge-OUT");
1149         ruleset_insertrule($ruleset, "PVEFW-INPUT", "-i $bridge -m physdev --physdev-is-in -j $bridge-OUT");
1150     }
1151
1152     if (!ruleset_chain_exist($ruleset, "$bridge-IN")) {
1153         ruleset_create_chain($ruleset, "$bridge-IN");
1154         ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-out -j $bridge-IN");
1155         ruleset_addrule($ruleset, "$bridge-FW", "-m mark --mark 1 -j ACCEPT");
1156         # accept traffic to unmanaged bridge ports
1157         ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-out -j ACCEPT ");
1158     }
1159 }
1160
1161 sub ruleset_add_chain_policy {
1162     my ($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action) = @_;
1163
1164     if ($policy eq 'ACCEPT') {
1165
1166         ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT' },
1167                               { ACCEPT =>  $accept_action});
1168
1169     } elsif ($policy eq 'DROP') {
1170
1171         ruleset_addrule($ruleset, $chain, "-j PVEFW-Drop");
1172
1173         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1174
1175         ruleset_addrule($ruleset, $chain, "-j DROP");
1176     } elsif ($policy eq 'REJECT') {
1177         ruleset_addrule($ruleset, $chain, "-j PVEFW-Reject");
1178
1179         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1180
1181         ruleset_addrule($ruleset, $chain, "-g PVEFW-reject");
1182     } else {
1183         # should not happen
1184         die "internal error: unknown policy '$policy'";
1185     }
1186 }
1187
1188 sub ruleset_create_vm_chain {
1189     my ($ruleset, $chain, $options, $macaddr, $direction) = @_;
1190
1191     ruleset_create_chain($ruleset, $chain);
1192     my $accept = generate_nfqueue($options);
1193
1194     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
1195         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1196     }
1197
1198     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
1199         if ($direction eq 'OUT') {
1200             ruleset_generate_rule($ruleset, $chain, { action => 'PVEFW-SET-ACCEPT-MARK',
1201                                                       proto => 'udp', sport => 68, dport => 67 });
1202         } else {
1203             ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT',
1204                                                       proto => 'udp', sport => 67, dport => 68 });
1205         }
1206     }
1207
1208     if ($options->{tcpflags}) {
1209         ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1210     }
1211
1212     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1213     if($direction eq 'OUT'){
1214         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -g PVEFW-SET-ACCEPT-MARK");
1215
1216     }else{
1217         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
1218     }
1219     if ($direction eq 'OUT') {
1220         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
1221             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr -j DROP");
1222         }
1223         ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1224     }
1225
1226
1227 }
1228
1229 sub ruleset_generate_vm_rules {
1230     my ($ruleset, $rules, $cluster_conf, $chain, $netid, $direction, $options) = @_;
1231
1232     my $lc_direction = lc($direction);
1233
1234     foreach my $rule (@$rules) {
1235         next if $rule->{iface} && $rule->{iface} ne $netid;
1236         next if !$rule->{enable};
1237         if ($rule->{type} eq 'group') {
1238             my $group_chain = "GROUP-$rule->{action}-$direction";
1239             if(!ruleset_chain_exist($ruleset, $group_chain)){
1240                 generate_group_rules($ruleset, $cluster_conf, $rule->{action});
1241             }
1242             ruleset_addrule($ruleset, $chain, "-j $group_chain");
1243             if ($direction eq 'OUT'){
1244                 ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j RETURN");
1245             }else{
1246                 my $accept = generate_nfqueue($options);
1247                 ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j $accept");
1248             }
1249
1250         } else {
1251             next if $rule->{type} ne $lc_direction;
1252             if ($direction eq 'OUT') {
1253                 ruleset_generate_rule($ruleset, $chain, $rule,
1254                                       { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
1255             } else {
1256                 my $accept = generate_nfqueue($options);
1257                 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept , REJECT => "PVEFW-reject" });
1258             }
1259         }
1260     }
1261 }
1262
1263 sub generate_nfqueue {
1264     my ($options) = @_;
1265
1266     my $action = "";
1267     if($options->{ips}){
1268         $action = "NFQUEUE";
1269         if($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
1270             if(defined($3) && defined($1)) {
1271                 $action .= " --queue-balance $1:$3";
1272             }elsif (defined($1)) {
1273                 $action .= " --queue-num $1";
1274             }
1275         }
1276         $action .= " --queue-bypass";
1277     }else{
1278         $action = "ACCEPT";
1279     }
1280
1281     return $action;
1282 }
1283
1284 sub ruleset_generate_vm_ipsrules {
1285     my ($ruleset, $options, $direction, $iface, $bridge) = @_;
1286
1287     if ($options->{ips} && $direction eq 'IN') {
1288         my $nfqueue = generate_nfqueue($options);
1289
1290         if (!ruleset_chain_exist($ruleset, "$bridge-IPS")) {
1291             ruleset_create_chain($ruleset, "PVEFW-IPS");
1292         }
1293
1294         if (!ruleset_chain_exist($ruleset, "$bridge-IPS")) {
1295             ruleset_create_chain($ruleset, "$bridge-IPS");
1296             ruleset_insertrule($ruleset, "PVEFW-IPS", "-o $bridge -m physdev --physdev-is-out -j $bridge-IPS");
1297         }
1298
1299         ruleset_addrule($ruleset, "$bridge-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged -j $nfqueue");
1300     }
1301 }
1302
1303 sub generate_venet_rules_direction {
1304     my ($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip, $direction) = @_;
1305
1306     parse_address_list($ip); # make sure we have a valid $ip list
1307
1308     my $lc_direction = lc($direction);
1309
1310     my $rules = $vmfw_conf->{rules};
1311
1312     my $options = $vmfw_conf->{options};
1313     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1314
1315     my $chain = "venet0-$vmid-$direction";
1316
1317     ruleset_create_vm_chain($ruleset, $chain, $options, undef, $direction);
1318
1319     ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $chain, 'venet', $direction);
1320
1321     # implement policy
1322     my $policy;
1323
1324     if ($direction eq 'OUT') {
1325         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1326     } else {
1327         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1328     }
1329
1330     my $accept = generate_nfqueue($options);
1331     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1332     ruleset_add_chain_policy($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action);
1333
1334     # plug into FORWARD, INPUT and OUTPUT chain
1335     if ($direction eq 'OUT') {
1336         ruleset_generate_rule_insert($ruleset, "PVEFW-FORWARD", {
1337             action => $chain,
1338             source => $ip,
1339             iface_in => 'venet0'});
1340
1341         ruleset_generate_rule_insert($ruleset, "PVEFW-INPUT", {
1342             action => $chain,
1343             source => $ip,
1344             iface_in => 'venet0'});
1345     } else {
1346         ruleset_generate_rule($ruleset, "PVEFW-FORWARD", {
1347             action => $chain,
1348             dest => $ip,
1349             iface_out => 'venet0'});
1350
1351         ruleset_generate_rule($ruleset, "PVEFW-OUTPUT", {
1352             action => $chain,
1353             dest => $ip,
1354             iface_out => 'venet0'});
1355     }
1356 }
1357
1358 sub generate_tap_rules_direction {
1359     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $bridge, $direction) = @_;
1360
1361     my $lc_direction = lc($direction);
1362
1363     my $rules = $vmfw_conf->{rules};
1364
1365     my $options = $vmfw_conf->{options};
1366     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1367
1368     my $tapchain = "$iface-$direction";
1369
1370     ruleset_create_vm_chain($ruleset, $tapchain, $options, $macaddr, $direction);
1371
1372     ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $tapchain, $netid, $direction, $options);
1373
1374     ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface, $bridge);
1375
1376     # implement policy
1377     my $policy;
1378
1379     if ($direction eq 'OUT') {
1380         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1381     } else {
1382         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1383     }
1384
1385     my $accept = generate_nfqueue($options);
1386     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1387     ruleset_add_chain_policy($ruleset, $tapchain, $vmid, $policy, $loglevel, $accept_action);
1388
1389     # plug the tap chain to bridge chain
1390     if ($direction eq 'IN') {
1391         ruleset_insertrule($ruleset, "$bridge-IN",
1392                            "-m physdev --physdev-is-bridged --physdev-out $iface -j $tapchain");
1393     } else {
1394         ruleset_insertrule($ruleset, "$bridge-OUT",
1395                            "-m physdev --physdev-in $iface -j $tapchain");
1396     }
1397 }
1398
1399 sub enable_host_firewall {
1400     my ($ruleset, $hostfw_conf, $cluster_conf) = @_;
1401
1402     # fixme: allow security groups
1403
1404     my $options = $hostfw_conf->{options};
1405     my $rules = $hostfw_conf->{rules};
1406
1407     # host inbound firewall
1408     my $chain = "PVEFW-HOST-IN";
1409     ruleset_create_chain($ruleset, $chain);
1410
1411     my $loglevel = get_option_log_level($options, "log_level_in");
1412
1413     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
1414         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1415     }
1416
1417     if ($options->{tcpflags}) {
1418         ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1419     }
1420
1421     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1422     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1423     ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
1424     ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
1425     ruleset_addrule($ruleset, $chain, "-p udp -m conntrack --ctstate NEW --dport 5404:5405 -j ACCEPT");
1426     ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT");  #corosync
1427
1428     # we use RETURN because we need to check also tap rules
1429     my $accept_action = 'RETURN';
1430
1431     foreach my $rule (@$rules) {
1432         next if $rule->{type} ne 'in';
1433         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
1434     }
1435
1436     # implement input policy
1437     my $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1438     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1439
1440     # host outbound firewall
1441     $chain = "PVEFW-HOST-OUT";
1442     ruleset_create_chain($ruleset, $chain);
1443
1444     $loglevel = get_option_log_level($options, "log_level_out");
1445
1446     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1447     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1448     ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
1449     ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
1450     ruleset_addrule($ruleset, $chain, "-p udp -m conntrack --ctstate NEW --dport 5404:5405 -j ACCEPT");
1451     ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT"); #corosync
1452
1453     # we use RETURN because we may want to check other thigs later
1454     $accept_action = 'RETURN';
1455
1456     foreach my $rule (@$rules) {
1457         next if $rule->{type} ne 'out';
1458         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
1459     }
1460
1461     # implement output policy
1462     $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1463     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1464
1465     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
1466     ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
1467 }
1468
1469 sub generate_group_rules {
1470     my ($ruleset, $cluster_conf, $group) = @_;
1471     die "no such security group '$group'\n" if !$cluster_conf->{rules}->{$group};
1472
1473     my $rules = $cluster_conf->{rules}->{$group};
1474
1475     my $chain = "GROUP-${group}-IN";
1476
1477     ruleset_create_chain($ruleset, $chain);
1478     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1479
1480     foreach my $rule (@$rules) {
1481         next if $rule->{type} ne 'in';
1482         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
1483     }
1484
1485     $chain = "GROUP-${group}-OUT";
1486
1487     ruleset_create_chain($ruleset, $chain);
1488     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1489
1490     foreach my $rule (@$rules) {
1491         next if $rule->{type} ne 'out';
1492         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
1493         # check also other tap rules later
1494         ruleset_generate_rule($ruleset, $chain, $rule,
1495                               { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" });
1496     }
1497 }
1498
1499 my $MAX_NETS = 32;
1500 my $valid_netdev_names = {};
1501 for (my $i = 0; $i < $MAX_NETS; $i++)  {
1502     $valid_netdev_names->{"net$i"} = 1;
1503 }
1504
1505 sub parse_fw_rule {
1506     my ($line, $need_iface, $allow_groups) = @_;
1507
1508     my ($type, $action, $iface, $source, $dest, $proto, $dport, $sport);
1509
1510     # we can add single line comments to the end of the rule
1511     my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
1512
1513     # we can disable a rule when prefixed with '|'
1514     my $enable = 1;
1515
1516     $enable = 0 if $line =~ s/^\|//;
1517
1518     my @data = split(/\s+/, $line);
1519     my $expected_elements = $need_iface ? 8 : 7;
1520
1521     die "wrong number of rule elements\n" if scalar(@data) > $expected_elements;
1522
1523     if ($need_iface) {
1524         ($type, $action, $iface, $source, $dest, $proto, $dport, $sport) = @data
1525     } else {
1526         ($type, $action, $source, $dest, $proto, $dport, $sport) =  @data;
1527     }
1528
1529     die "incomplete rule\n" if ! ($type && $action);
1530
1531     my $macro;
1532
1533     $type = lc($type);
1534
1535     if ($type eq  'in' || $type eq 'out') {
1536         if ($action =~ m/^(ACCEPT|DROP|REJECT)$/) {
1537             # OK
1538         } elsif ($action =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
1539             $action = $2;
1540             my $preferred_name = $pve_fw_preferred_macro_names->{lc($1)};
1541             die "unknown macro '$1'\n" if !$preferred_name;
1542             $macro = $preferred_name;
1543         } else {
1544             die "unknown action '$action'\n";
1545         }
1546     } elsif ($type eq 'group') {
1547         die "wrong number of rule elements\n" if scalar(@data) != 3;
1548         die "groups disabled\n" if !$allow_groups;
1549
1550         die "invalid characters in group name\n" if $action !~ m/^[A-Za-z0-9_\-]+$/;
1551     } else {
1552         die "unknown rule type '$type'\n";
1553     }
1554
1555     if ($need_iface) {
1556         $iface = undef if $iface && $iface eq '-';
1557     }
1558
1559     $proto = undef if $proto && $proto eq '-';
1560     pve_fw_verify_protocol_spec($proto) if $proto;
1561
1562     $source = undef if $source && $source eq '-';
1563     $dest = undef if $dest && $dest eq '-';
1564
1565     $dport = undef if $dport && $dport eq '-';
1566     $sport = undef if $sport && $sport eq '-';
1567
1568     parse_port_name_number_or_range($dport) if defined($dport);
1569     parse_port_name_number_or_range($sport) if defined($sport);
1570
1571     parse_address_list($source) if $source;
1572     parse_address_list($dest) if $dest;
1573
1574     return {
1575         type => $type,
1576         enable => $enable,
1577         comment => $comment,
1578         action => $action,
1579         macro => $macro,
1580         iface => $iface,
1581         source => $source,
1582         dest => $dest,
1583         proto => $proto,
1584         dport => $dport,
1585         sport => $sport,
1586     };
1587 }
1588
1589 sub parse_vmfw_option {
1590     my ($line) = @_;
1591
1592     my ($opt, $value);
1593
1594     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
1595
1596     if ($line =~ m/^(enable|dhcp|macfilter|nosmurfs|tcpflags|ips):\s*(0|1)\s*$/i) {
1597         $opt = lc($1);
1598         $value = int($2);
1599     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
1600         $opt = lc($1);
1601         $value = $2 ? lc($3) : '';
1602     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
1603         $opt = lc($1);
1604         $value = uc($3);
1605     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
1606         $opt = lc($1);
1607         $value = $2;
1608     } else {
1609         chomp $line;
1610         die "can't parse option '$line'\n"
1611     }
1612
1613     return ($opt, $value);
1614 }
1615
1616 sub parse_hostfw_option {
1617     my ($line) = @_;
1618
1619     my ($opt, $value);
1620
1621     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
1622
1623     if ($line =~ m/^(enable|dhcp|nosmurfs|tcpflags|allow_bridge_route|optimize):\s*(0|1)\s*$/i) {
1624         $opt = lc($1);
1625         $value = int($2);
1626     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
1627         $opt = lc($1);
1628         $value = $2 ? lc($3) : '';
1629     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
1630         $opt = lc($1);
1631         $value = uc($3);
1632     } elsif ($line =~ m/^(nf_conntrack_max):\s*(\d+)\s*$/i) {
1633         $opt = lc($1);
1634         $value = int($2);
1635     } else {
1636         chomp $line;
1637         die "can't parse option '$line'\n"
1638     }
1639
1640     return ($opt, $value);
1641 }
1642
1643 sub parse_vm_fw_rules {
1644     my ($filename, $fh) = @_;
1645
1646     my $res = { rules => [], options => {}};
1647
1648     my $section;
1649
1650     my $digest = Digest::SHA->new('sha1');
1651
1652     while (defined(my $line = <$fh>)) {
1653         $digest->add($line);
1654
1655         next if $line =~ m/^#/;
1656         next if $line =~ m/^\s*$/;
1657
1658         my $linenr = $fh->input_line_number();
1659         my $prefix = "$filename (line $linenr)";
1660
1661         if ($line =~ m/^\[(\S+)\]\s*$/i) {
1662             $section = lc($1);
1663             warn "$prefix: ignore unknown section '$section'\n" if !$res->{$section};
1664             next;
1665         }
1666         if (!$section) {
1667             warn "$prefix: skip line - no section";
1668             next;
1669         }
1670
1671         next if !$res->{$section}; # skip undefined section
1672
1673         if ($section eq 'options') {
1674             eval {
1675                 my ($opt, $value) = parse_vmfw_option($line);
1676                 $res->{options}->{$opt} = $value;
1677             };
1678             warn "$prefix: $@" if $@;
1679             next;
1680         }
1681
1682         my $rule;
1683         eval { $rule = parse_fw_rule($line, 1, 1); };
1684         if (my $err = $@) {
1685             warn "$prefix: $err";
1686             next;
1687         }
1688
1689         push @{$res->{$section}}, $rule;
1690     }
1691
1692     $res->{digest} = $digest->b64digest;
1693
1694     return $res;
1695 }
1696
1697 sub parse_host_fw_rules {
1698     my ($filename, $fh) = @_;
1699
1700     my $res = { rules => [], options => {}};
1701
1702     my $section;
1703
1704     my $digest = Digest::SHA->new('sha1');
1705
1706     while (defined(my $line = <$fh>)) {
1707         $digest->add($line);
1708
1709         next if $line =~ m/^#/;
1710         next if $line =~ m/^\s*$/;
1711
1712         my $linenr = $fh->input_line_number();
1713         my $prefix = "$filename (line $linenr)";
1714
1715         if ($line =~ m/^\[(\S+)\]\s*$/i) {
1716             $section = lc($1);
1717             warn "$prefix: ignore unknown section '$section'\n" if !$res->{$section};
1718             next;
1719         }
1720         if (!$section) {
1721             warn "$prefix: skip line - no section";
1722             next;
1723         }
1724
1725         next if !$res->{$section}; # skip undefined section
1726
1727         if ($section eq 'options') {
1728             eval {
1729                 my ($opt, $value) = parse_hostfw_option($line);
1730                 $res->{options}->{$opt} = $value;
1731             };
1732             warn "$prefix: $@" if $@;
1733             next;
1734         }
1735
1736         my $rule;
1737         eval { $rule = parse_fw_rule($line, 1, 1); };
1738         if (my $err = $@) {
1739             warn "$prefix: $err";
1740             next;
1741         }
1742
1743         push @{$res->{$section}}, $rule;
1744     }
1745
1746     $res->{digest} = $digest->b64digest;
1747
1748     return $res;
1749 }
1750
1751 sub parse_group_fw_rules {
1752     my ($filename, $fh) = @_;
1753
1754     my $section;
1755     my $group;
1756
1757     my $res = { rules => {}, ipset => {} };
1758
1759     my $digest = Digest::SHA->new('sha1');
1760
1761     while (defined(my $line = <$fh>)) {
1762         $digest->add($line);
1763
1764         next if $line =~ m/^#/;
1765         next if $line =~ m/^\s*$/;
1766
1767         my $linenr = $fh->input_line_number();
1768         my $prefix = "$filename (line $linenr)";
1769
1770         if ($line =~ m/^\[group\s+(\S+)\]\s*$/i) {
1771             $section = 'rules';
1772             $group = lc($1);
1773             next;
1774         }
1775
1776         if ($line =~ m/^\[ipgroup\s+(\S+)\]\s*$/i) {
1777             $section = 'ipset';
1778             $group = lc($1);
1779             $res->{$section}->{$group}->{type} = 'hash:ip family inet hashsize 1024 maxelem 65536 ';
1780
1781             next;
1782         }
1783         if ($line =~ m/^\[netgroup\s+(\S+)\]\s*$/i) {
1784             $section = 'ipset';
1785             $group = lc($1);
1786             $res->{$section}->{$group}->{type} = 'hash:net family inet hashsize 1024 maxelem 65536 ';
1787
1788             next;
1789         }
1790
1791         if (!$section || !$group) {
1792             warn "$prefix: skip line - no section";
1793             next;
1794         }
1795
1796         if ($section eq 'rules') {
1797             my $rule;
1798             eval { $rule = parse_fw_rule($line, 0, 0); };
1799             if (my $err = $@) {
1800                 warn "$prefix: $err";
1801                 next;
1802             }
1803             push @{$res->{$section}->{$group}}, $rule;
1804
1805         } elsif ($section eq 'ipset') {
1806             chomp $line;
1807             my $ip;
1808             if (!Net::IP->new($line)) {
1809                 warn "$prefix: $line is not an valid ip address";
1810                 next;
1811             }
1812             push @{$res->{$section}->{$group}->{ip}}, $line;
1813         }
1814
1815
1816     }
1817
1818     $res->{digest} = $digest->b64digest;
1819
1820     return $res;
1821 }
1822
1823 sub run_locked {
1824     my ($code, @param) = @_;
1825
1826     my $timeout = 10;
1827
1828     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
1829
1830     die $@ if $@;
1831
1832     return $res;
1833 }
1834
1835 sub read_local_vm_config {
1836
1837     my $openvz = {};
1838     my $qemu = {};
1839
1840     my $vmdata = { openvz => $openvz, qemu => $qemu };
1841
1842     my $vmlist = PVE::Cluster::get_vmlist();
1843     return $vmdata if !$vmlist || !$vmlist->{ids};
1844     my $ids = $vmlist->{ids};
1845
1846     foreach my $vmid (keys %$ids) {
1847         next if !$vmid; # skip VE0
1848         my $d = $ids->{$vmid};
1849         next if !$d->{node} || $d->{node} ne $nodename;
1850         next if !$d->{type};
1851         if ($d->{type} eq 'openvz') {
1852             if ($have_pve_manager) {
1853                 my $cfspath = PVE::OpenVZ::cfs_config_path($vmid);
1854                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
1855                     $openvz->{$vmid} = $conf;
1856                 }
1857             }
1858         } elsif ($d->{type} eq 'qemu') {
1859             if ($have_qemu_server) {
1860                 my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
1861                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
1862                     $qemu->{$vmid} = $conf;
1863                 }
1864             }
1865         }
1866     }
1867
1868     return $vmdata;
1869 };
1870
1871 sub load_vmfw_conf {
1872     my ($vmid) = @_;
1873
1874     my $vmfw_conf = {};
1875
1876     my $filename = "/etc/pve/firewall/$vmid.fw";
1877     if (my $fh = IO::File->new($filename, O_RDONLY)) {
1878         $vmfw_conf = parse_vm_fw_rules($filename, $fh);
1879     }
1880
1881     return $vmfw_conf;
1882 }
1883
1884 sub read_vm_firewall_configs {
1885     my ($vmdata) = @_;
1886     my $vmfw_configs = {};
1887
1888     foreach my $vmid (keys %{$vmdata->{qemu}}, keys %{$vmdata->{openvz}}) {
1889         my $vmfw_conf = load_vmfw_conf($vmid);
1890         next if !$vmfw_conf->{options}; # skip if file does not exists
1891         $vmfw_configs->{$vmid} = $vmfw_conf;
1892     }
1893
1894     return $vmfw_configs;
1895 }
1896
1897 sub get_option_log_level {
1898     my ($options, $k) = @_;
1899
1900     my $v = $options->{$k};
1901     $v = $default_log_level if !defined($v);
1902
1903     return undef if $v eq '' || $v eq 'nolog';
1904
1905     $v = $log_level_hash->{$v} if defined($log_level_hash->{$v});
1906
1907     return $v if ($v >= 0) && ($v <= 7);
1908
1909     warn "unknown log level ($k = '$v')\n";
1910
1911     return undef;
1912 }
1913
1914 sub generate_std_chains {
1915     my ($ruleset, $options) = @_;
1916
1917     my $loglevel = get_option_log_level($options, 'smurf_log_level');
1918
1919     # same as shorewall smurflog.
1920     my $chain = 'PVEFW-smurflog';
1921
1922     push @{$pve_std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
1923     push @{$pve_std_chains->{$chain}}, "-j DROP";
1924
1925     # same as shorewall logflags action.
1926     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
1927     $chain = 'PVEFW-logflags';
1928     # fixme: is this correctly logged by pvewf-logger? (ther is no --log-ip-options for NFLOG)
1929     push @{$pve_std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
1930     push @{$pve_std_chains->{$chain}}, "-j DROP";
1931
1932     foreach my $chain (keys %$pve_std_chains) {
1933         ruleset_create_chain($ruleset, $chain);
1934         foreach my $rule (@{$pve_std_chains->{$chain}}) {
1935             if (ref($rule)) {
1936                 ruleset_generate_rule($ruleset, $chain, $rule);
1937             } else {
1938                 ruleset_addrule($ruleset, $chain, $rule);
1939             }
1940         }
1941     }
1942 }
1943
1944 sub generate_ipset_chains {
1945     my ($ipset_ruleset, $options) = @_;
1946
1947     foreach my $ipset (keys %{$options->{ipset}}) {
1948         generate_ipset($ipset_ruleset, $ipset, $options->{ipset}->{$ipset});
1949     }
1950 }
1951
1952 sub generate_ipset {
1953     my ($ipset_ruleset, $name, $options) = @_;
1954
1955     push @{$ipset_ruleset->{$name}}, "create $name $options->{type}";
1956
1957     foreach my $ip (@{$options->{ip}}) {
1958         push @{$ipset_ruleset->{$name}}, "add $name $ip";
1959     }
1960 }
1961
1962 sub save_pvefw_status {
1963     my ($status) = @_;
1964
1965     die "unknown status '$status' - internal error"
1966         if $status !~ m/^(stopped|active)$/;
1967
1968     mkdir dirname($pve_fw_status_filename);
1969     PVE::Tools::file_set_contents($pve_fw_status_filename, $status);
1970 }
1971
1972 sub read_pvefw_status {
1973
1974     my $status = 'unknown';
1975
1976     return 'stopped' if ! -f $pve_fw_status_filename;
1977
1978     eval {
1979         $status = PVE::Tools::file_get_contents($pve_fw_status_filename);
1980     };
1981     warn $@ if $@;
1982
1983     return $status;
1984 }
1985
1986 # fixme: move to pve-common PVE::ProcFSTools
1987 sub read_proc_net_route {
1988     my $filename = "/proc/net/route";
1989
1990     my $res = {};
1991
1992     my $fh = IO::File->new ($filename, "r");
1993     return $res if !$fh;
1994
1995     my $int_to_quad = sub {
1996         return join '.' => map { ($_[0] >> 8*(3-$_)) % 256 } (3, 2, 1, 0);
1997     };
1998
1999     while (defined(my $line = <$fh>)) {
2000         next if $line =~/^Iface\s+Destination/; # skip head
2001         my ($iface, $dest, $gateway, $metric, $mask, $mtu) = (split(/\s+/, $line))[0,1,2,6,7,8];
2002         push @{$res->{$iface}}, {
2003             dest => &$int_to_quad(hex($dest)),
2004             gateway => &$int_to_quad(hex($gateway)),
2005             mask => &$int_to_quad(hex($mask)),
2006             metric => $metric,
2007             mtu => $mtu,
2008         };
2009     }
2010
2011     return $res;
2012 }
2013
2014 sub load_clusterfw_conf {
2015
2016     my $cluster_conf = {};
2017      if (my $fh = IO::File->new($clusterfw_conf_filename, O_RDONLY)) {
2018         $cluster_conf = parse_group_fw_rules($clusterfw_conf_filename, $fh);
2019     }
2020
2021     return $cluster_conf;
2022 }
2023
2024 sub save_clusterfw_conf {
2025     my ($cluster_conf) = @_;
2026
2027     my $raw = '';
2028
2029     foreach my $group (sort keys %{$cluster_conf->{rules}}) {
2030         my $rules = $cluster_conf->{rules}->{$group};
2031         $raw .= "[group $group]\n\n";
2032
2033         foreach my $rule (@$rules) {
2034             if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2035                 $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
2036                 $raw .= uc($rule->{type});
2037                 $raw .= " " . $rule->{action};
2038                 $raw .= " " . ($rule->{source} || '-');
2039                 $raw .= " " . ($rule->{dest} || '-');
2040                 $raw .= " " . ($rule->{proto} || '-');
2041                 $raw .= " " . ($rule->{dport} || '-');
2042                 $raw .= " " . ($rule->{sport} || '-');
2043                 $raw .= " # " . encode('utf8', $rule->{comment})
2044                     if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
2045                 $raw .= "\n";
2046             } else {
2047                 die "implement me '$rule->{type}'";
2048             }
2049         }
2050
2051         $raw .= "\n";
2052     }
2053
2054     PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
2055 }
2056
2057 sub load_hostfw_conf {
2058
2059     my $hostfw_conf = {};
2060     my $filename = "/etc/pve/local/host.fw";
2061     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2062         $hostfw_conf = parse_host_fw_rules($filename, $fh);
2063     }
2064     return $hostfw_conf;
2065 }
2066
2067 sub compile {
2068     my $vmdata = read_local_vm_config();
2069     my $vmfw_configs = read_vm_firewall_configs($vmdata);
2070
2071     my $routing_table = read_proc_net_route();
2072
2073     my $cluster_conf = load_clusterfw_conf();
2074
2075     my $ipset_ruleset = {};
2076     generate_ipset_chains($ipset_ruleset, $cluster_conf);
2077
2078     my $ruleset = {};
2079
2080     ruleset_create_chain($ruleset, "PVEFW-INPUT");
2081     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
2082
2083     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
2084
2085     my $hostfw_conf = load_hostfw_conf();
2086     my $hostfw_options = $hostfw_conf->{options} || {};
2087
2088     generate_std_chains($ruleset, $hostfw_options);
2089
2090     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
2091
2092     enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf) if $hostfw_enable;
2093
2094     # generate firewall rules for QEMU VMs
2095     foreach my $vmid (keys %{$vmdata->{qemu}}) {
2096         my $conf = $vmdata->{qemu}->{$vmid};
2097         my $vmfw_conf = $vmfw_configs->{$vmid};
2098         next if !$vmfw_conf;
2099         next if defined($vmfw_conf->{options}->{enable}) && ($vmfw_conf->{options}->{enable} == 0);
2100
2101         foreach my $netid (keys %$conf) {
2102             next if $netid !~ m/^net(\d+)$/;
2103             my $net = PVE::QemuServer::parse_net($conf->{$netid});
2104             next if !$net;
2105             my $iface = "tap${vmid}i$1";
2106
2107             my $bridge = $net->{bridge};
2108             next if !$bridge; # fixme: ?
2109
2110             $bridge .= "v$net->{tag}" if $net->{tag};
2111
2112             generate_bridge_chains($ruleset, $hostfw_conf, $bridge, $routing_table);
2113
2114             my $macaddr = $net->{macaddr};
2115             generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
2116                                          $vmfw_conf, $vmid, $bridge, 'IN');
2117             generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
2118                                          $vmfw_conf, $vmid, $bridge, 'OUT');
2119         }
2120     }
2121
2122     # generate firewall rules for OpenVZ containers
2123     foreach my $vmid (keys %{$vmdata->{openvz}}) {
2124         my $conf = $vmdata->{openvz}->{$vmid};
2125
2126         my $vmfw_conf = $vmfw_configs->{$vmid};
2127         next if !$vmfw_conf;
2128         next if defined($vmfw_conf->{options}->{enable}) && ($vmfw_conf->{options}->{enable} == 0);
2129
2130         if ($conf->{ip_address} && $conf->{ip_address}->{value}) {
2131             my $ip = $conf->{ip_address}->{value};
2132             generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip, 'IN');
2133             generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip, 'OUT');
2134         }
2135
2136         if ($conf->{netif} && $conf->{netif}->{value}) {
2137             my $netif = PVE::OpenVZ::parse_netif($conf->{netif}->{value});
2138             foreach my $netid (keys %$netif) {
2139                 my $d = $netif->{$netid};
2140                 my $bridge = $d->{bridge};
2141                 if (!$bridge) {
2142                     warn "no bridge device for CT $vmid iface '$netid'\n";
2143                     next; # fixme?
2144                 }
2145
2146                 generate_bridge_chains($ruleset, $hostfw_conf, $bridge, $routing_table);
2147
2148                 my $macaddr = $d->{mac};
2149                 my $iface = $d->{host_ifname};
2150                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
2151                                              $vmfw_conf, $vmid, $bridge, 'IN');
2152                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
2153                                              $vmfw_conf, $vmid, $bridge, 'OUT');
2154             }
2155         }
2156     }
2157
2158     if($hostfw_options->{optimize}){
2159
2160         my $accept = ruleset_chain_exist($ruleset, "PVEFW-IPS") ? "PVEFW-IPS" : "ACCEPT";
2161         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
2162         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate INVALID -j DROP");
2163     }
2164
2165     # fixme: what log level should we use here?
2166     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
2167
2168     # fixme: should we really block inter-bridge traffic?
2169
2170     # always allow traffic from containers?
2171     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i venet0 -j RETURN");
2172
2173     # disable interbridge routing
2174     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o vmbr+ -j PVEFW-Drop");
2175     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i vmbr+ -j PVEFW-Drop");
2176     ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-o vmbr+");
2177     ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-i vmbr+");
2178     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o vmbr+ -j DROP");
2179     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i vmbr+ -j DROP");
2180
2181     return wantarray ? ($ruleset, $hostfw_conf, $ipset_ruleset) : $ruleset;
2182 }
2183
2184 sub get_ruleset_status {
2185     my ($ruleset, $verbose, $ipset) = @_;
2186
2187     my $active_chains = undef;
2188     if($ipset){
2189         $active_chains = ipset_get_chains();
2190     }else{
2191         $active_chains = iptables_get_chains();
2192     }
2193
2194     my $statushash = {};
2195
2196     foreach my $chain (sort keys %$ruleset) {
2197         my $sig = ipset_chain_digest($ruleset->{$chain});
2198         $statushash->{$chain}->{sig} = $sig;
2199
2200         my $oldsig = $active_chains->{$chain};
2201         if (!defined($oldsig)) {
2202             $statushash->{$chain}->{action} = 'create';
2203         } else {
2204             if ($oldsig eq $sig) {
2205                 $statushash->{$chain}->{action} = 'exists';
2206             } else {
2207                 $statushash->{$chain}->{action} = 'update';
2208             }
2209         }
2210         print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
2211         foreach my $cmd (@{$ruleset->{$chain}}) {
2212             print "\t$cmd\n" if $verbose;
2213         }
2214     }
2215
2216     foreach my $chain (sort keys %$active_chains) {
2217         if (!defined($ruleset->{$chain})) {
2218             my $sig = $active_chains->{$chain};
2219             $statushash->{$chain}->{action} = 'delete';
2220             $statushash->{$chain}->{sig} = $sig;
2221             print "delete $chain ($sig)\n" if $verbose;
2222         }
2223     }
2224
2225     return $statushash;
2226 }
2227
2228 sub print_sig_rule {
2229     my ($chain, $sig) = @_;
2230
2231     # We just use this to store a SHA1 checksum used to detect changes
2232     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
2233 }
2234
2235 sub get_rulset_cmdlist {
2236     my ($ruleset, $verbose) = @_;
2237
2238     my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
2239
2240     my $statushash = get_ruleset_status($ruleset, $verbose);
2241
2242     # create missing chains first
2243     foreach my $chain (sort keys %$ruleset) {
2244         my $stat = $statushash->{$chain};
2245         die "internal error" if !$stat;
2246         next if $stat->{action} ne 'create';
2247
2248         $cmdlist .= ":$chain - [0:0]\n";
2249     }
2250
2251     my $rule = "INPUT -j PVEFW-INPUT";
2252     if (!PVE::Firewall::iptables_rule_exist($rule)) {
2253         $cmdlist .= "-A $rule\n";
2254     }
2255     $rule = "OUTPUT -j PVEFW-OUTPUT";
2256     if (!PVE::Firewall::iptables_rule_exist($rule)) {
2257         $cmdlist .= "-A $rule\n";
2258     }
2259
2260     $rule = "FORWARD -j PVEFW-FORWARD";
2261     if (!PVE::Firewall::iptables_rule_exist($rule)) {
2262         $cmdlist .= "-A $rule\n";
2263     }
2264
2265     foreach my $chain (sort keys %$ruleset) {
2266         my $stat = $statushash->{$chain};
2267         die "internal error" if !$stat;
2268
2269         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
2270             $cmdlist .= "-F $chain\n";
2271             foreach my $cmd (@{$ruleset->{$chain}}) {
2272                 $cmdlist .= "$cmd\n";
2273             }
2274             $cmdlist .= print_sig_rule($chain, $stat->{sig});
2275         } elsif ($stat->{action} eq 'delete') {
2276             die "internal error"; # this should not happen
2277         } elsif ($stat->{action} eq 'exists') {
2278             # do nothing
2279         } else {
2280             die "internal error - unknown status '$stat->{action}'";
2281         }
2282     }
2283
2284     foreach my $chain (keys %$statushash) {
2285         next if $statushash->{$chain}->{action} ne 'delete';
2286         $cmdlist .= "-F $chain\n";
2287     }
2288     foreach my $chain (keys %$statushash) {
2289         next if $statushash->{$chain}->{action} ne 'delete';
2290         next if $chain eq 'PVEFW-INPUT';
2291         next if $chain eq 'PVEFW-OUTPUT';
2292         next if $chain eq 'PVEFW-FORWARD';
2293         $cmdlist .= "-X $chain\n";
2294     }
2295
2296     my $changes = $cmdlist ne "*filter\n" ? 1 : 0;
2297
2298     $cmdlist .= "COMMIT\n";
2299
2300     return wantarray ? ($cmdlist, $changes) : $cmdlist;
2301 }
2302
2303 sub get_ipset_cmdlist {
2304     my ($ruleset, $verbose) = @_;
2305
2306     my $cmdlist = "";
2307
2308     my $statushash = get_ruleset_status($ruleset, $verbose, 1);
2309
2310     foreach my $chain (sort keys %$ruleset) {
2311         my $stat = $statushash->{$chain};
2312         die "internal error" if !$stat;
2313
2314         if ($stat->{action} eq 'create') {
2315             foreach my $cmd (@{$ruleset->{$chain}}) {
2316                 $cmdlist .= "$cmd\n";
2317             }
2318         }
2319
2320         if ($stat->{action} eq 'update') {
2321             my $chain_swap = $chain."_swap";
2322
2323             foreach my $cmd (@{$ruleset->{$chain}}) {
2324                 $cmd =~ s/$chain/$chain_swap/;
2325                 $cmdlist .= "$cmd\n";
2326
2327             }
2328             $cmdlist .= "swap $chain_swap $chain\n";
2329             $cmdlist .= "flush $chain_swap\n";
2330             $cmdlist .= "destroy $chain_swap\n";
2331         }
2332
2333     }
2334
2335     foreach my $chain (keys %$statushash) {
2336         next if $statushash->{$chain}->{action} ne 'delete';
2337
2338         $cmdlist .= "flush $chain\n";
2339         $cmdlist .= "destroy $chain\n";
2340     }
2341
2342     my $changes = $cmdlist ? 1 : 0;
2343
2344     return wantarray ? ($cmdlist, $changes) : $cmdlist;
2345 }
2346
2347 sub apply_ruleset {
2348     my ($ruleset, $hostfw_conf, $ipset_ruleset, $verbose) = @_;
2349
2350     enable_bridge_firewall();
2351
2352     update_nf_conntrack_max($hostfw_conf);
2353
2354     my $ipsetcmdlist = get_ipset_cmdlist($ipset_ruleset, $verbose);
2355
2356     my $cmdlist = get_rulset_cmdlist($ruleset, $verbose);
2357
2358     print $ipsetcmdlist if $verbose;
2359
2360     print $cmdlist if $verbose;
2361
2362     ipset_restore_cmdlist($ipsetcmdlist);
2363
2364     iptables_restore_cmdlist($cmdlist);
2365
2366     # test: re-read status and check if everything is up to date
2367     my $statushash = get_ruleset_status($ruleset);
2368
2369     my $errors;
2370     foreach my $chain (sort keys %$ruleset) {
2371         my $stat = $statushash->{$chain};
2372         if ($stat->{action} ne 'exists') {
2373             warn "unable to update chain '$chain'\n";
2374             $errors = 1;
2375         }
2376     }
2377
2378     die "unable to apply firewall changes\n" if $errors;
2379 }
2380
2381 sub update_nf_conntrack_max {
2382     my ($hostfw_conf) = @_;
2383
2384     my $max = 65536; # reasonable default
2385
2386     my $options = $hostfw_conf->{options} || {};
2387
2388     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
2389         $max = $options->{nf_conntrack_max};
2390         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
2391     }
2392
2393     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
2394     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
2395
2396     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
2397
2398     if ($current != $max) {
2399         my $hashsize = int($max/4);
2400         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
2401         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
2402     }
2403 }
2404
2405 sub update {
2406     my ($start, $verbose) = @_;
2407
2408     my $code = sub {
2409         my $status = read_pvefw_status();
2410
2411         my ($ruleset, $hostfw_conf, $ipset_ruleset) = compile();
2412
2413         if ($start || $status eq 'active') {
2414
2415             save_pvefw_status('active') if ($status ne 'active');
2416
2417             apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $verbose);
2418         } else {
2419             print "Firewall not active (status = $status)\n" if $verbose;
2420         }
2421     };
2422
2423     run_locked($code);
2424 }
2425
2426
2427 1;