src/PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5 use Data::Dumper;
   6 use Digest::SHA;
   7 use PVE::INotify;
   8 use PVE::Cluster;
   9 use PVE::ProcFSTools;
  10 use PVE::Tools;
  11 use PVE::QemuServer;
  12 use PVE::OpenVZ; # dependeny problem?!
  13 use File::Basename;
  14 use File::Path;
  15 use IO::File;
  16 use Net::IP;
  17 use PVE::Tools qw(run_command lock_file);
  18
  19 use Data::Dumper;
  20
  21 # fixme: remove loglevel settings? NFLOG does not have --loglevel
  22
  23 my $nodename = PVE::INotify::nodename();
  24
  25 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
  26 my $pve_fw_status_filename = "/var/lib/pve-firewall/pvefw.status";
  27
  28 my $default_log_level = 'info';
  29
  30 my $log_level_hash = {
  31     debug => 7,
  32     info => 6,
  33     notice => 5,
  34     warning => 4,
  35     err => 3,
  36     crit => 2,
  37     alert => 1,
  38     emerg => 0,
  39 };
  40
  41 # imported/converted from: /usr/share/shorewall/macro.*
  42 my $pve_fw_macros = {
  43     'Amanda' => [
  44         { action => 'PARAM', proto => 'udp', dport => '10080' },
  45         { action => 'PARAM', proto => 'tcp', dport => '10080' },
  46     ],
  47     'Auth' => [
  48         { action => 'PARAM', proto => 'tcp', dport => '113' },
  49     ],
  50     'BGP' => [
  51         { action => 'PARAM', proto => 'tcp', dport => '179' },
  52     ],
  53     'BitTorrent' => [
  54         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
  55         { action => 'PARAM', proto => 'udp', dport => '6881' },
  56     ],
  57     'BitTorrent32' => [
  58         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
  59         { action => 'PARAM', proto => 'udp', dport => '6881' },
  60     ],
  61     'CVS' => [
  62         { action => 'PARAM', proto => 'tcp', dport => '2401' },
  63     ],
  64     'Citrix' => [
  65         { action => 'PARAM', proto => 'tcp', dport => '1494' },
  66         { action => 'PARAM', proto => 'udp', dport => '1604' },
  67         { action => 'PARAM', proto => 'tcp', dport => '2598' },
  68     ],
  69     'DAAP' => [
  70         { action => 'PARAM', proto => 'tcp', dport => '3689' },
  71         { action => 'PARAM', proto => 'udp', dport => '3689' },
  72     ],
  73     'DCC' => [
  74         { action => 'PARAM', proto => 'tcp', dport => '6277' },
  75     ],
  76     'DHCPfwd' => [
  77         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
  78         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '67:68', sport => '67:68' },
  79     ],
  80     'DNS' => [
  81         { action => 'PARAM', proto => 'udp', dport => '53' },
  82         { action => 'PARAM', proto => 'tcp', dport => '53' },
  83     ],
  84     'Distcc' => [
  85         { action => 'PARAM', proto => 'tcp', dport => '3632' },
  86     ],
  87     'Edonkey' => [
  88         { action => 'PARAM', proto => 'tcp', dport => '4662' },
  89         { action => 'PARAM', proto => 'udp', dport => '4665' },
  90     ],
  91     'FTP' => [
  92         { action => 'PARAM', proto => 'tcp', dport => '21' },
  93     ],
  94     'Finger' => [
  95         { action => 'PARAM', proto => 'tcp', dport => '79' },
  96     ],
  97     'GNUnet' => [
  98         { action => 'PARAM', proto => 'tcp', dport => '2086' },
  99         { action => 'PARAM', proto => 'udp', dport => '2086' },
 100         { action => 'PARAM', proto => 'tcp', dport => '1080' },
 101         { action => 'PARAM', proto => 'udp', dport => '1080' },
 102     ],
 103     'GRE' => [
 104         { action => 'PARAM', proto => '47' },
 105         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '47' },
 106     ],
 107     'Git' => [
 108         { action => 'PARAM', proto => 'tcp', dport => '9418' },
 109     ],
 110     'Gnutella' => [
 111         { action => 'PARAM', proto => 'tcp', dport => '6346' },
 112         { action => 'PARAM', proto => 'udp', dport => '6346' },
 113     ],
 114     'HKP' => [
 115         { action => 'PARAM', proto => 'tcp', dport => '11371' },
 116     ],
 117     'HTTP' => [
 118         { action => 'PARAM', proto => 'tcp', dport => '80' },
 119     ],
 120     'HTTPS' => [
 121         { action => 'PARAM', proto => 'tcp', dport => '443' },
 122     ],
 123     'ICPV2' => [
 124         { action => 'PARAM', proto => 'udp', dport => '3130' },
 125     ],
 126     'ICQ' => [
 127         { action => 'PARAM', proto => 'tcp', dport => '5190' },
 128     ],
 129     'IMAP' => [
 130         { action => 'PARAM', proto => 'tcp', dport => '143' },
 131     ],
 132     'IMAPS' => [
 133         { action => 'PARAM', proto => 'tcp', dport => '993' },
 134     ],
 135     'IPIP' => [
 136         { action => 'PARAM', proto => '94' },
 137         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '94' },
 138     ],
 139     'IPP' => [
 140         { action => 'PARAM', proto => 'tcp', dport => '631' },
 141     ],
 142     'IPPbrd' => [
 143         { action => 'PARAM', proto => 'udp', dport => '631' },
 144     ],
 145     'IPPserver' => [
 146         { action => 'PARAM', source => 'SOURCE', dest => 'DEST', proto => 'tcp', dport => '631' },
 147         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '631' },
 148     ],
 149     'IPsec' => [
 150         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 151         { action => 'PARAM', proto => '50' },
 152         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500', sport => '500' },
 153         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '50' },
 154     ],
 155     'IPsecah' => [
 156         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 157         { action => 'PARAM', proto => '51' },
 158         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500', sport => '500' },
 159         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '51' },
 160     ],
 161     'IPsecnat' => [
 162         { action => 'PARAM', proto => 'udp', dport => '500' },
 163         { action => 'PARAM', proto => 'udp', dport => '4500' },
 164         { action => 'PARAM', proto => '50' },
 165         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '500' },
 166         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '4500' },
 167         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '50' },
 168     ],
 169     'IRC' => [
 170         { action => 'PARAM', proto => 'tcp', dport => '6667' },
 171     ],
 172     'JabberPlain' => [
 173         { action => 'PARAM', proto => 'tcp', dport => '5222' },
 174     ],
 175     'JabberSecure' => [
 176         { action => 'PARAM', proto => 'tcp', dport => '5223' },
 177     ],
 178     'Jabberd' => [
 179         { action => 'PARAM', proto => 'tcp', dport => '5269' },
 180     ],
 181     'Jetdirect' => [
 182         { action => 'PARAM', proto => 'tcp', dport => '9100' },
 183     ],
 184     'L2TP' => [
 185         { action => 'PARAM', proto => 'udp', dport => '1701' },
 186         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '1701' },
 187     ],
 188     'LDAP' => [
 189         { action => 'PARAM', proto => 'tcp', dport => '389' },
 190     ],
 191     'LDAPS' => [
 192         { action => 'PARAM', proto => 'tcp', dport => '636' },
 193     ],
 194     'MSNP' => [
 195         { action => 'PARAM', proto => 'tcp', dport => '1863' },
 196     ],
 197     'MSSQL' => [
 198         { action => 'PARAM', proto => 'tcp', dport => '1433' },
 199     ],
 200     'Mail' => [
 201         { action => 'PARAM', proto => 'tcp', dport => '25' },
 202         { action => 'PARAM', proto => 'tcp', dport => '465' },
 203         { action => 'PARAM', proto => 'tcp', dport => '587' },
 204     ],
 205     'Munin' => [
 206         { action => 'PARAM', proto => 'tcp', dport => '4949' },
 207     ],
 208     'MySQL' => [
 209         { action => 'PARAM', proto => 'tcp', dport => '3306' },
 210     ],
 211     'NNTP' => [
 212         { action => 'PARAM', proto => 'tcp', dport => '119' },
 213     ],
 214     'NNTPS' => [
 215         { action => 'PARAM', proto => 'tcp', dport => '563' },
 216     ],
 217     'NTP' => [
 218         { action => 'PARAM', proto => 'udp', dport => '123' },
 219     ],
 220     'NTPbi' => [
 221         { action => 'PARAM', proto => 'udp', dport => '123' },
 222         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '123' },
 223     ],
 224     'NTPbrd' => [
 225         { action => 'PARAM', proto => 'udp', dport => '123' },
 226         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '123' },
 227     ],
 228     'OSPF' => [
 229         { action => 'PARAM', proto => '89' },
 230     ],
 231     'OpenVPN' => [
 232         { action => 'PARAM', proto => 'udp', dport => '1194' },
 233     ],
 234     'PCA' => [
 235         { action => 'PARAM', proto => 'udp', dport => '5632' },
 236         { action => 'PARAM', proto => 'tcp', dport => '5631' },
 237     ],
 238     'POP3' => [
 239         { action => 'PARAM', proto => 'tcp', dport => '110' },
 240     ],
 241     'POP3S' => [
 242         { action => 'PARAM', proto => 'tcp', dport => '995' },
 243     ],
 244     'PPtP' => [
 245         { action => 'PARAM', proto => '47' },
 246         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => '47' },
 247         { action => 'PARAM', proto => 'tcp', dport => '1723' },
 248     ],
 249     'Ping' => [
 250         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 251     ],
 252     'PostgreSQL' => [
 253         { action => 'PARAM', proto => 'tcp', dport => '5432' },
 254     ],
 255     'Printer' => [
 256         { action => 'PARAM', proto => 'tcp', dport => '515' },
 257     ],
 258     'RDP' => [
 259         { action => 'PARAM', proto => 'tcp', dport => '3389' },
 260     ],
 261     'RIPbi' => [
 262         { action => 'PARAM', proto => 'udp', dport => '520' },
 263         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '520' },
 264     ],
 265     'RNDC' => [
 266         { action => 'PARAM', proto => 'tcp', dport => '953' },
 267     ],
 268     'Razor' => [
 269         { action => 'ACCEPT', proto => 'tcp', dport => '2703' },
 270     ],
 271     'Rdate' => [
 272         { action => 'PARAM', proto => 'tcp', dport => '37' },
 273     ],
 274     'Rsync' => [
 275         { action => 'PARAM', proto => 'tcp', dport => '873' },
 276     ],
 277     'SANE' => [
 278         { action => 'PARAM', proto => 'tcp', dport => '6566' },
 279     ],
 280     'SMB' => [
 281         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 282         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 283         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 284         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 285     ],
 286     'SMBBI' => [
 287         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 288         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 289         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 290         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 291         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '135,445' },
 292         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '137:139' },
 293         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'udp', dport => '1024:65535', sport => '137' },
 294         { action => 'PARAM', source => 'DEST', dest => 'SOURCE', proto => 'tcp', dport => '135,139,445' },
 295     ],
 296     'SMBswat' => [
 297         { action => 'PARAM', proto => 'tcp', dport => '901' },
 298     ],
 299     'SMTP' => [
 300         { action => 'PARAM', proto => 'tcp', dport => '25' },
 301     ],
 302     'SMTPS' => [
 303         { action => 'PARAM', proto => 'tcp', dport => '465' },
 304     ],
 305     'SNMP' => [
 306         { action => 'PARAM', proto => 'udp', dport => '161:162' },
 307         { action => 'PARAM', proto => 'tcp', dport => '161' },
 308     ],
 309     'SPAMD' => [
 310         { action => 'PARAM', proto => 'tcp', dport => '783' },
 311     ],
 312     'SSH' => [
 313         { action => 'PARAM', proto => 'tcp', dport => '22' },
 314     ],
 315     'SVN' => [
 316         { action => 'PARAM', proto => 'tcp', dport => '3690' },
 317     ],
 318     'SixXS' => [
 319         { action => 'PARAM', proto => 'tcp', dport => '3874' },
 320         { action => 'PARAM', proto => 'udp', dport => '3740' },
 321         { action => 'PARAM', proto => '41' },
 322         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
 323     ],
 324     'Squid' => [
 325         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 326     ],
 327     'Submission' => [
 328         { action => 'PARAM', proto => 'tcp', dport => '587' },
 329     ],
 330     'Syslog' => [
 331         { action => 'PARAM', proto => 'udp', dport => '514' },
 332         { action => 'PARAM', proto => 'tcp', dport => '514' },
 333     ],
 334     'TFTP' => [
 335         { action => 'PARAM', proto => 'udp', dport => '69' },
 336     ],
 337     'Telnet' => [
 338         { action => 'PARAM', proto => 'tcp', dport => '23' },
 339     ],
 340     'Telnets' => [
 341         { action => 'PARAM', proto => 'tcp', dport => '992' },
 342     ],
 343     'Time' => [
 344         { action => 'PARAM', proto => 'tcp', dport => '37' },
 345     ],
 346     'Trcrt' => [
 347         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 348         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 349     ],
 350     'VNC' => [
 351         { action => 'PARAM', proto => 'tcp', dport => '5900:5909' },
 352     ],
 353     'VNCL' => [
 354         { action => 'PARAM', proto => 'tcp', dport => '5500' },
 355     ],
 356     'Web' => [
 357         { action => 'PARAM', proto => 'tcp', dport => '80' },
 358         { action => 'PARAM', proto => 'tcp', dport => '443' },
 359     ],
 360     'Webcache' => [
 361         { action => 'PARAM', proto => 'tcp', dport => '8080' },
 362     ],
 363     'Webmin' => [
 364         { action => 'PARAM', proto => 'tcp', dport => '10000' },
 365     ],
 366     'Whois' => [
 367         { action => 'PARAM', proto => 'tcp', dport => '43' },
 368     ],
 369 };
 370
 371 my $pve_fw_parsed_macros;
 372 my $pve_fw_preferred_macro_names = {};
 373
 374 my $pve_std_chains = {
 375     'PVEFW-SET-ACCEPT-MARK' => [
 376         "-j MARK --set-mark 1",
 377     ],
 378     'PVEFW-DropBroadcast' => [
 379         # same as shorewall 'Broadcast'
 380         # simply DROP BROADCAST/MULTICAST/ANYCAST
 381         # we can use this to reduce logging
 382         { action => 'DROP', dsttype => 'BROADCAST' },
 383         { action => 'DROP', dsttype => 'MULTICAST' },
 384         { action => 'DROP', dsttype => 'ANYCAST' },
 385         { action => 'DROP', dest => '224.0.0.0/4' },
 386     ],
 387     'PVEFW-reject' => [
 388         # same as shorewall 'reject'
 389         { action => 'DROP', dsttype => 'BROADCAST' },
 390         { action => 'DROP', source => '224.0.0.0/4' },
 391         { action => 'DROP', proto => 'icmp' },
 392         "-p tcp -j REJECT --reject-with tcp-reset",
 393         "-p udp -j REJECT --reject-with icmp-port-unreachable",
 394         "-p icmp -j REJECT --reject-with icmp-host-unreachable",
 395         "-j REJECT --reject-with icmp-host-prohibited",
 396     ],
 397     'PVEFW-Drop' => [
 398         # same as shorewall 'Drop', which is equal to DROP,
 399         # but REJECT/DROP some packages to reduce logging,
 400         # and ACCEPT critical ICMP types
 401         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 402         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 403         { action => 'PVEFW-DropBroadcast' },
 404         # ACCEPT critical ICMP types
 405         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 406         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 407         # Drop packets with INVALID state
 408         "-m conntrack --ctstate INVALID -j DROP",
 409         # Drop Microsoft SMB noise
 410         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
 411         { action => 'DROP', proto => 'udp', dport => '137:139'},
 412         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 413         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 414         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 415         # Drop new/NotSyn traffic so that it doesn't get logged
 416         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 417         # Drop DNS replies
 418         { action => 'DROP', proto => 'udp', sport => 53 },
 419     ],
 420     'PVEFW-Reject' => [
 421         # same as shorewall 'Reject', which is equal to Reject,
 422         # but REJECT/DROP some packages to reduce logging,
 423         # and ACCEPT critical ICMP types
 424         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 425         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 426         { action => 'PVEFW-DropBroadcast' },
 427         # ACCEPT critical ICMP types
 428         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 429         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 430         # Drop packets with INVALID state
 431         "-m conntrack --ctstate INVALID -j DROP",
 432         # Drop Microsoft SMB noise
 433         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
 434         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 435         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 436         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 437         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 438         # Drop new/NotSyn traffic so that it doesn't get logged
 439         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 440         # Drop DNS replies
 441         { action => 'DROP', proto => 'udp', sport => 53 },
 442     ],
 443     'PVEFW-tcpflags' => [
 444         # same as shorewall tcpflags action.
 445         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
 446         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
 447         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
 448         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
 449         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
 450         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
 451     ],
 452     'PVEFW-smurfs' => [
 453         # same as shorewall smurfs action
 454         # Filter packets for smurfs (packets with a broadcast address as the source).
 455         "-s 0.0.0.0/32 -j RETURN",
 456         "-m addrtype --src-type BROADCAST -g PVEFW-smurflog",
 457         "-s 224.0.0.0/4 -g PVEFW-smurflog",
 458     ],
 459 };
 460
 461 # iptables -p icmp -h
 462 my $icmp_type_names = {
 463     any => 1,
 464     'echo-reply' => 1,
 465     'destination-unreachable' => 1,
 466     'network-unreachable' => 1,
 467     'host-unreachable' => 1,
 468     'protocol-unreachable' => 1,
 469     'port-unreachable' => 1,
 470     'fragmentation-needed' => 1,
 471     'source-route-failed' => 1,
 472     'network-unknown' => 1,
 473     'host-unknown' => 1,
 474     'network-prohibited' => 1,
 475     'host-prohibited' => 1,
 476     'TOS-network-unreachable' => 1,
 477     'TOS-host-unreachable' => 1,
 478     'communication-prohibited' => 1,
 479     'host-precedence-violation' => 1,
 480     'precedence-cutoff' => 1,
 481     'source-quench' => 1,
 482     'redirect' => 1,
 483     'network-redirect' => 1,
 484     'host-redirect' => 1,
 485     'TOS-network-redirect' => 1,
 486     'TOS-host-redirect' => 1,
 487     'echo-request' => 1,
 488     'router-advertisement' => 1,
 489     'router-solicitation' => 1,
 490     'time-exceeded' => 1,
 491     'ttl-zero-during-transit' => 1,
 492     'ttl-zero-during-reassembly' => 1,
 493     'parameter-problem' => 1,
 494     'ip-header-bad' => 1,
 495     'required-option-missing' => 1,
 496     'timestamp-request' => 1,
 497     'timestamp-reply' => 1,
 498     'address-mask-request' => 1,
 499     'address-mask-reply' => 1,
 500 };
 501
 502 sub get_firewall_macros {
 503
 504     return $pve_fw_parsed_macros if $pve_fw_parsed_macros;
 505
 506     $pve_fw_parsed_macros = {};
 507
 508     foreach my $k (keys %$pve_fw_macros) {
 509         my $name = lc($k);
 510
 511         my $macro =  $pve_fw_macros->{$k};
 512         $pve_fw_preferred_macro_names->{$name} = $k;
 513         $pve_fw_parsed_macros->{$name} = $macro;
 514     }
 515
 516     return $pve_fw_parsed_macros;
 517 }
 518
 519 my $etc_services;
 520
 521 sub get_etc_services {
 522
 523     return $etc_services if $etc_services;
 524
 525     my $filename = "/etc/services";
 526
 527     my $fh = IO::File->new($filename, O_RDONLY);
 528     if (!$fh) {
 529         warn "unable to read '$filename' - $!\n";
 530         return {};
 531     }
 532
 533     my $services = {};
 534
 535     while (my $line = <$fh>) {
 536         chomp ($line);
 537         next if $line =~m/^#/;
 538         next if ($line =~m/^\s*$/);
 539
 540         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
 541             $services->{byid}->{$2}->{name} = $1;
 542             $services->{byid}->{$2}->{port} = $2;
 543             $services->{byid}->{$2}->{$3} = 1;
 544             $services->{byname}->{$1} = $services->{byid}->{$2};
 545         }
 546     }
 547
 548     close($fh);
 549
 550     $etc_services = $services;
 551
 552
 553     return $etc_services;
 554 }
 555
 556 my $etc_protocols;
 557
 558 sub get_etc_protocols {
 559     return $etc_protocols if $etc_protocols;
 560
 561     my $filename = "/etc/protocols";
 562
 563     my $fh = IO::File->new($filename, O_RDONLY);
 564     if (!$fh) {
 565         warn "unable to read '$filename' - $!\n";
 566         return {};
 567     }
 568
 569     my $protocols = {};
 570
 571     while (my $line = <$fh>) {
 572         chomp ($line);
 573         next if $line =~m/^#/;
 574         next if ($line =~m/^\s*$/);
 575
 576         if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
 577             $protocols->{byid}->{$2}->{name} = $1;
 578             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
 579         }
 580     }
 581
 582     close($fh);
 583
 584     $etc_protocols = $protocols;
 585
 586     return $etc_protocols;
 587 }
 588
 589 sub parse_address_list {
 590     my ($str) = @_;
 591
 592     my $nbaor = 0;
 593     foreach my $aor (split(/,/, $str)) {
 594         if (!Net::IP->new($aor)) {
 595             my $err = Net::IP::Error();
 596             die "invalid IP address: $err\n";
 597         }else{
 598             $nbaor++;
 599         }
 600     }
 601     return $nbaor;
 602 }
 603
 604 sub parse_port_name_number_or_range {
 605     my ($str) = @_;
 606
 607     my $services = PVE::Firewall::get_etc_services();
 608     my $nbports = 0;
 609     foreach my $item (split(/,/, $str)) {
 610         my $portlist = "";
 611         my $oldpon = undef;
 612         $nbports++;
 613         foreach my $pon (split(':', $item, 2)) {
 614             $pon = $services->{byname}->{$pon}->{port} if $services->{byname}->{$pon}->{port};
 615             if ($pon =~ m/^\d+$/){
 616                 die "invalid port '$pon'\n" if $pon < 0 && $pon > 65535;
 617                 die "port '$pon' must be bigger than port '$oldpon' \n" if $oldpon && ($pon < $oldpon);
 618                 $oldpon = $pon;
 619             }else{
 620                 die "invalid port $services->{byname}->{$pon}\n" if !$services->{byname}->{$pon};
 621             }
 622         }
 623     }
 624
 625     return ($nbports);
 626 }
 627
 628 my $bridge_firewall_enabled = 0;
 629
 630 sub enable_bridge_firewall {
 631
 632     return if $bridge_firewall_enabled; # only once
 633
 634     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
 635     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
 636
 637     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
 638     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
 639
 640     $bridge_firewall_enabled = 1;
 641 }
 642
 643 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
 644
 645 sub iptables {
 646     my ($cmd) = @_;
 647
 648     run_command("/sbin/iptables $cmd", outfunc => sub {}, errfunc => sub {});
 649 }
 650
 651 sub iptables_restore_cmdlist {
 652     my ($cmdlist) = @_;
 653
 654     run_command("/sbin/iptables-restore -n", input => $cmdlist);
 655 }
 656
 657 sub iptables_get_chains {
 658
 659     my $res = {};
 660
 661     # check what chains we want to track
 662     my $is_pvefw_chain = sub {
 663         my $name = shift;
 664
 665         return 1 if $name =~ m/^PVEFW-\S+$/;
 666
 667         return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
 668
 669         return 1 if $name =~ m/^veth\d+.\d+-(:?IN|OUT)$/; # fixme: dev name is configurable
 670
 671         return 1 if $name =~ m/^venet0-\d+-(:?IN|OUT)$/;
 672
 673         return 1 if $name =~ m/^vmbr\d+-(:?FW|IN|OUT)$/;
 674         return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
 675
 676         return undef;
 677     };
 678
 679     my $table = '';
 680
 681     my $parser = sub {
 682         my $line = shift;
 683
 684         return if $line =~ m/^#/;
 685         return if $line =~ m/^\s*$/;
 686
 687         if ($line =~ m/^\*(\S+)$/) {
 688             $table = $1;
 689             return;
 690         }
 691
 692         return if $table ne 'filter';
 693
 694         if ($line =~ m/^:(\S+)\s/) {
 695             my $chain = $1;
 696             return if !&$is_pvefw_chain($chain);
 697             $res->{$chain} = "unknown";
 698         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
 699             my ($chain, $sig) = ($1, $2);
 700             return if !&$is_pvefw_chain($chain);
 701             $res->{$chain} = $sig;
 702         } else {
 703             # simply ignore the rest
 704             return;
 705         }
 706     };
 707
 708     run_command("/sbin/iptables-save", outfunc => $parser);
 709
 710     return $res;
 711 }
 712
 713 sub iptables_chain_exist {
 714     my ($chain) = @_;
 715
 716     eval{
 717         iptables("-n --list $chain");
 718     };
 719     return undef if $@;
 720
 721     return 1;
 722 }
 723
 724 sub iptables_rule_exist {
 725     my ($rule) = @_;
 726
 727     eval{
 728         iptables("-C $rule");
 729     };
 730     return undef if $@;
 731
 732     return 1;
 733 }
 734
 735 sub ruleset_generate_cmdstr {
 736     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
 737
 738     return if $rule->{disable};
 739
 740     my @cmd = ();
 741
 742     push @cmd, "-i $rule->{iface_in}" if $rule->{iface_in};
 743     push @cmd, "-o $rule->{iface_out}" if $rule->{iface_out};
 744
 745     push @cmd, "-m iprange --src-range" if $rule->{nbsource} && $rule->{nbsource} > 1;
 746     push @cmd, "-s $rule->{source}" if $rule->{source};
 747     push @cmd, "-m iprange --dst-range" if $rule->{nbdest} && $rule->{nbdest} > 1;
 748     push @cmd, "-d $rule->{dest}" if $rule->{dest};
 749
 750     if ($rule->{proto}) {
 751         push @cmd, "-p $rule->{proto}";
 752
 753         my $multiport = 0;
 754         $multiport++ if $rule->{nbdport} && ($rule->{nbdport} > 1);
 755         $multiport++ if $rule->{nbsport} && ($rule->{nbsport} > 1);
 756
 757         push @cmd, "--match multiport" if $multiport;
 758
 759         die "multiport: option '--sports' cannot be used together with '--dports'\n"
 760             if ($multiport == 2) && ($rule->{dport} ne $rule->{sport});
 761
 762         if ($rule->{dport}) {
 763             if ($rule->{proto} && $rule->{proto} eq 'icmp') {
 764                 # Note: we use dport to store --icmp-type
 765                 die "unknown icmp-type '$rule->{dport}'\n" if !defined($icmp_type_names->{$rule->{dport}});
 766                 push @cmd, "-m icmp --icmp-type $rule->{dport}";
 767             } else {
 768                 if ($rule->{nbdport} && $rule->{nbdport} > 1) {
 769                     if ($multiport == 2) {
 770                         push @cmd,  "--ports $rule->{dport}";
 771                     } else {
 772                         push @cmd, "--dports $rule->{dport}";
 773                     }
 774                 } else {
 775                     push @cmd, "--dport $rule->{dport}";
 776                 }
 777             }
 778         }
 779
 780         if ($rule->{sport}) {
 781             if ($rule->{nbsport} && $rule->{nbsport} > 1) {
 782                 push @cmd, "--sports $rule->{sport}" if $multiport != 2;
 783             } else {
 784                 push @cmd, "--sport $rule->{sport}";
 785             }
 786         }
 787     } elsif ($rule->{dport} || $rule->{sport}) {
 788         warn "ignoring destination port '$rule->{dport}' - no protocol specified\n" if $rule->{dport};
 789         warn "ignoring source port '$rule->{sport}' - no protocol specified\n" if $rule->{sport};
 790     }
 791
 792     push @cmd, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
 793
 794     if (my $action = $rule->{action}) {
 795         $action = $actions->{$action} if defined($actions->{$action});
 796         $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
 797         push @cmd, $goto ? "-g $action" : "-j $action";
 798     }
 799
 800     return scalar(@cmd) ? join(' ', @cmd) : undef;
 801 }
 802
 803 sub ruleset_generate_rule {
 804     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
 805
 806     if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $rule, $actions, $goto)) {
 807         ruleset_addrule($ruleset, $chain, $cmdstr);
 808     }
 809 }
 810 sub ruleset_generate_rule_insert {
 811     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
 812
 813     if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $rule, $actions, $goto)) {
 814         ruleset_insertrule($ruleset, $chain, $cmdstr);
 815     }
 816 }
 817
 818 sub ruleset_create_chain {
 819     my ($ruleset, $chain) = @_;
 820
 821     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
 822     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
 823
 824     die "chain '$chain' already exists\n" if $ruleset->{$chain};
 825
 826     $ruleset->{$chain} = [];
 827 }
 828
 829 sub ruleset_chain_exist {
 830     my ($ruleset, $chain) = @_;
 831
 832     return $ruleset->{$chain} ? 1 : undef;
 833 }
 834
 835 sub ruleset_addrule {
 836    my ($ruleset, $chain, $rule) = @_;
 837
 838    die "no such chain '$chain'\n" if !$ruleset->{$chain};
 839
 840    push @{$ruleset->{$chain}}, "-A $chain $rule";
 841 }
 842
 843 sub ruleset_insertrule {
 844    my ($ruleset, $chain, $rule) = @_;
 845
 846    die "no such chain '$chain'\n" if !$ruleset->{$chain};
 847
 848    unshift @{$ruleset->{$chain}}, "-A $chain $rule";
 849 }
 850
 851 sub get_log_rule_base {
 852     my ($chain, $vmid, $msg, $loglevel) = @_;
 853
 854     die "internal error - no log level" if !defined($loglevel);
 855
 856     $vmid = 0 if !defined($vmid);
 857
 858     # Note: we use special format for prefix to pass further
 859     # info to log daemon (VMID, LOGVELEL and CHAIN)
 860
 861     return "-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
 862 }
 863
 864 sub ruleset_addlog {
 865     my ($ruleset, $chain, $vmid, $msg, $loglevel, $rule) = @_;
 866
 867     return if !defined($loglevel);
 868
 869     my $logrule = get_log_rule_base($chain, $vmid, $msg, $loglevel);
 870
 871     $logrule = "$rule $logrule" if defined($rule);
 872
 873     ruleset_addrule($ruleset, $chain, $logrule)
 874 }
 875
 876 sub generate_bridge_chains {
 877     my ($ruleset, $hostfw_conf, $bridge, $routing_table) = @_;
 878
 879     my $options = $hostfw_conf->{options} || {};
 880
 881     die "error: detected direct route to bridge '$bridge'\n"
 882         if !$options->{allow_bridge_route} && $routing_table->{$bridge};
 883
 884     if (!ruleset_chain_exist($ruleset, "$bridge-FW")) {
 885         ruleset_create_chain($ruleset, "$bridge-FW");
 886         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o $bridge -m physdev --physdev-is-out -j $bridge-FW");
 887         ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i $bridge -m physdev --physdev-is-in -j $bridge-FW");
 888     }
 889
 890     if (!ruleset_chain_exist($ruleset, "$bridge-OUT")) {
 891         ruleset_create_chain($ruleset, "$bridge-OUT");
 892         ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-in -j $bridge-OUT");
 893         ruleset_insertrule($ruleset, "PVEFW-INPUT", "-i $bridge -m physdev --physdev-is-in -j $bridge-OUT");
 894     }
 895
 896     if (!ruleset_chain_exist($ruleset, "$bridge-IN")) {
 897         ruleset_create_chain($ruleset, "$bridge-IN");
 898         ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-out -j $bridge-IN");
 899         ruleset_addrule($ruleset, "$bridge-FW", "-m mark --mark 1 -j ACCEPT");
 900         # accept traffic to unmanaged bridge ports
 901         ruleset_addrule($ruleset, "$bridge-FW", "-m physdev --physdev-is-out -j ACCEPT ");
 902     }
 903 }
 904
 905 sub ruleset_add_chain_policy {
 906     my ($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action) = @_;
 907
 908     if ($policy eq 'ACCEPT') {
 909
 910         ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT' },
 911                               { ACCEPT =>  $accept_action});
 912
 913     } elsif ($policy eq 'DROP') {
 914
 915         ruleset_addrule($ruleset, $chain, "-j PVEFW-Drop");
 916
 917         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
 918
 919         ruleset_addrule($ruleset, $chain, "-j DROP");
 920     } elsif ($policy eq 'REJECT') {
 921         ruleset_addrule($ruleset, $chain, "-j PVEFW-Reject");
 922
 923         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
 924
 925         ruleset_addrule($ruleset, $chain, "-g PVEFW-reject");
 926     } else {
 927         # should not happen
 928         die "internal error: unknown policy '$policy'";
 929     }
 930 }
 931
 932 sub ruleset_create_vm_chain {
 933     my ($ruleset, $chain, $options, $macaddr, $direction) = @_;
 934
 935     ruleset_create_chain($ruleset, $chain);
 936
 937     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
 938         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
 939     }
 940
 941     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
 942         ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 67:68 -j ACCEPT");
 943     }
 944
 945     if ($options->{tcpflags}) {
 946         ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
 947     }
 948
 949     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
 950     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
 951
 952     if ($direction eq 'OUT') {
 953         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
 954             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr -j DROP");
 955         }
 956         ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
 957     }
 958 }
 959
 960 sub ruleset_generate_vm_rules {
 961     my ($ruleset, $rules, $groups_conf, $chain, $netid, $direction) = @_;
 962
 963     my $lc_direction = lc($direction);
 964
 965     foreach my $rule (@$rules) {
 966         next if $rule->{iface} && $rule->{iface} ne $netid;
 967         next if $rule->{disable};
 968         if ($rule->{type} eq 'group') {
 969             my $group_chain = "GROUP-$rule->{action}-$direction";
 970             if(!ruleset_chain_exist($ruleset, $group_chain)){
 971                 generate_group_rules($ruleset, $groups_conf, $rule->{action});
 972             }
 973             ruleset_addrule($ruleset, $chain, "-j $group_chain");
 974             ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j RETURN")
 975                 if $direction eq 'OUT';
 976         } else {
 977             next if $rule->{type} ne $lc_direction;
 978             if ($direction eq 'OUT') {
 979                 ruleset_generate_rule($ruleset, $chain, $rule,
 980                                       { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
 981             } else {
 982                 ruleset_generate_rule($ruleset, $chain, $rule, { REJECT => "PVEFW-reject" });
 983             }
 984         }
 985     }
 986 }
 987
 988 sub generate_venet_rules_direction {
 989     my ($ruleset, $groups_conf, $vmfw_conf, $vmid, $ip, $direction) = @_;
 990
 991     parse_address_list($ip); # make sure we have a valid $ip list
 992
 993     my $lc_direction = lc($direction);
 994
 995     my $rules = $vmfw_conf->{rules};
 996
 997     my $options = $vmfw_conf->{options};
 998     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
 999
1000     my $chain = "venet0-$vmid-$direction";
1001
1002     ruleset_create_vm_chain($ruleset, $chain, $options, undef, $direction);
1003
1004     ruleset_generate_vm_rules($ruleset, $rules, $groups_conf, $chain, 'venet', $direction);
1005
1006     # implement policy
1007     my $policy;
1008
1009     if ($direction eq 'OUT') {
1010         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1011     } else {
1012         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1013     }
1014
1015     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : "ACCEPT";
1016     ruleset_add_chain_policy($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action);
1017
1018     # plug into FORWARD, INPUT and OUTPUT chain
1019     if ($direction eq 'OUT') {
1020         ruleset_generate_rule_insert($ruleset, "PVEFW-FORWARD", {
1021             action => $chain,
1022             source => $ip,
1023             iface_in => 'venet0'});
1024
1025         ruleset_generate_rule_insert($ruleset, "PVEFW-INPUT", {
1026             action => $chain,
1027             source => $ip,
1028             iface_in => 'venet0'});
1029     } else {
1030         ruleset_generate_rule($ruleset, "PVEFW-FORWARD", {
1031             action => $chain,
1032             dest => $ip,
1033             iface_out => 'venet0'});
1034
1035         ruleset_generate_rule($ruleset, "PVEFW-OUTPUT", {
1036             action => $chain,
1037             dest => $ip,
1038             iface_out => 'venet0'});
1039     }
1040 }
1041
1042 sub generate_tap_rules_direction {
1043     my ($ruleset, $groups_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $bridge, $direction) = @_;
1044
1045     my $lc_direction = lc($direction);
1046
1047     my $rules = $vmfw_conf->{rules};
1048
1049     my $options = $vmfw_conf->{options};
1050     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1051
1052     my $tapchain = "$iface-$direction";
1053
1054     ruleset_create_vm_chain($ruleset, $tapchain, $options, $macaddr, $direction);
1055
1056     ruleset_generate_vm_rules($ruleset, $rules, $groups_conf, $tapchain, $netid, $direction);
1057
1058     # implement policy
1059     my $policy;
1060
1061     if ($direction eq 'OUT') {
1062         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1063     } else {
1064         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1065     }
1066
1067     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : "ACCEPT";
1068     ruleset_add_chain_policy($ruleset, $tapchain, $vmid, $policy, $loglevel, $accept_action);
1069
1070     # plug the tap chain to bridge chain
1071     if ($direction eq 'IN') {
1072         ruleset_insertrule($ruleset, "$bridge-IN",
1073                            "-m physdev --physdev-is-bridged --physdev-out $iface -j $tapchain");
1074     } else {
1075         ruleset_insertrule($ruleset, "$bridge-OUT",
1076                            "-m physdev --physdev-in $iface -j $tapchain");
1077     }
1078 }
1079
1080 sub enable_host_firewall {
1081     my ($ruleset, $hostfw_conf, $groups_conf) = @_;
1082
1083     # fixme: allow security groups
1084
1085     my $options = $hostfw_conf->{options};
1086     my $rules = $hostfw_conf->{rules};
1087
1088     # host inbound firewall
1089     my $chain = "PVEFW-HOST-IN";
1090     ruleset_create_chain($ruleset, $chain);
1091
1092     my $loglevel = get_option_log_level($options, "log_level_in");
1093
1094     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1095     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1096     ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
1097     ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
1098     ruleset_addrule($ruleset, $chain, "-p udp -m conntrack --ctstate NEW --dport 5404:5405 -j ACCEPT");
1099     ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT");  #corosync
1100
1101     # we use RETURN because we need to check also tap rules
1102     my $accept_action = 'RETURN';
1103
1104     foreach my $rule (@$rules) {
1105         next if $rule->{type} ne 'in';
1106         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
1107     }
1108
1109     # implement input policy
1110     my $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1111     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1112
1113     # host outbound firewall
1114     $chain = "PVEFW-HOST-OUT";
1115     ruleset_create_chain($ruleset, $chain);
1116
1117     $loglevel = get_option_log_level($options, "log_level_out");
1118
1119     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1120     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1121     ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
1122     ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST -j ACCEPT");
1123     ruleset_addrule($ruleset, $chain, "-p udp -m conntrack --ctstate NEW --dport 5404:5405 -j ACCEPT");
1124     ruleset_addrule($ruleset, $chain, "-p udp -m udp --dport 9000 -j ACCEPT"); #corosync
1125
1126     # we use RETURN because we may want to check other thigs later
1127     $accept_action = 'RETURN';
1128
1129     foreach my $rule (@$rules) {
1130         next if $rule->{type} ne 'out';
1131         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
1132     }
1133
1134     # implement output policy
1135     $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1136     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
1137
1138     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
1139     ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
1140 }
1141
1142 sub generate_group_rules {
1143     my ($ruleset, $groups_conf, $group) = @_;
1144
1145     die "no such security group '$group'\n" if !$groups_conf->{$group};
1146
1147     my $rules = $groups_conf->{$group}->{rules};
1148
1149     my $chain = "GROUP-${group}-IN";
1150
1151     ruleset_create_chain($ruleset, $chain);
1152
1153     foreach my $rule (@$rules) {
1154         next if $rule->{type} ne 'in';
1155         ruleset_generate_rule($ruleset, $chain, $rule, { REJECT => "PVEFW-reject" });
1156     }
1157
1158     $chain = "GROUP-${group}-OUT";
1159
1160     ruleset_create_chain($ruleset, $chain);
1161     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1162
1163     foreach my $rule (@$rules) {
1164         next if $rule->{type} ne 'out';
1165         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
1166         # check also other tap rules later
1167         ruleset_generate_rule($ruleset, $chain, $rule,
1168                               { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" });
1169     }
1170 }
1171
1172 my $MAX_NETS = 32;
1173 my $valid_netdev_names = {};
1174 for (my $i = 0; $i < $MAX_NETS; $i++)  {
1175     $valid_netdev_names->{"net$i"} = 1;
1176 }
1177
1178 sub parse_fw_rule {
1179     my ($line, $need_iface, $allow_groups) = @_;
1180
1181     my $macros = get_firewall_macros();
1182     my $protocols = get_etc_protocols();
1183
1184     my ($type, $action, $iface, $source, $dest, $proto, $dport, $sport);
1185
1186     # we can add single line comments to the end of the rule
1187     my $comment = $1 if $line =~ s/#\s*(.*?)\s*$//;
1188
1189     # we can disable a rule when prefixed with '|'
1190     my $disable = 1 if  $line =~ s/^\|//;
1191
1192     my @data = split(/\s+/, $line);
1193     my $expected_elements = $need_iface ? 8 : 7;
1194
1195     die "wrong number of rule elements\n" if scalar(@data) > $expected_elements;
1196
1197     if ($need_iface) {
1198         ($type, $action, $iface, $source, $dest, $proto, $dport, $sport) = @data
1199     } else {
1200         ($type, $action, $source, $dest, $proto, $dport, $sport) =  @data;
1201     }
1202
1203     die "incomplete rule\n" if ! ($type && $action);
1204
1205     my $macro;
1206     my $macro_name;
1207
1208     $type = lc($type);
1209
1210     if ($type eq  'in' || $type eq 'out') {
1211         if ($action =~ m/^(ACCEPT|DROP|REJECT)$/) {
1212             # OK
1213         } elsif ($action =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
1214             ($macro_name, $action) = ($1, $2);
1215             my $lc_macro_name = lc($macro_name);
1216             my $preferred_name = $pve_fw_preferred_macro_names->{$lc_macro_name};
1217             $macro_name = $preferred_name if $preferred_name;
1218             $macro = $macros->{$lc_macro_name};
1219             die "unknown macro '$macro_name'\n" if !$macro;
1220         } else {
1221             die "unknown action '$action'\n";
1222         }
1223     } elsif ($type eq 'group') {
1224         die "wrong number of rule elements\n" if scalar(@data) != 3;
1225         die "groups disabled\n" if !$allow_groups;
1226
1227         die "invalid characters in group name\n" if $action !~ m/^[A-Za-z0-9_\-]+$/;
1228     } else {
1229         die "unknown rule type '$type'\n";
1230     }
1231
1232     if ($need_iface) {
1233         $iface = undef if $iface && $iface eq '-';
1234     }
1235
1236     $proto = undef if $proto && $proto eq '-';
1237     die "unknown protokol '$proto'\n" if $proto &&
1238         !(defined($protocols->{byname}->{$proto}) ||
1239           defined($protocols->{byid}->{$proto}));
1240
1241     $source = undef if $source && $source eq '-';
1242     $dest = undef if $dest && $dest eq '-';
1243
1244     $dport = undef if $dport && $dport eq '-';
1245     $sport = undef if $sport && $sport eq '-';
1246
1247     my $nbsource = undef;
1248     my $nbdest = undef;
1249
1250     $nbsource = parse_address_list($source) if $source;
1251     $nbdest = parse_address_list($dest) if $dest;
1252
1253     my $rules = [];
1254
1255     my $param = {
1256         type => $type,
1257         disable => $disable,
1258         comment => $comment,
1259         action => $action,
1260         iface => $iface,
1261         source => $source,
1262         dest => $dest,
1263         nbsource => $nbsource,
1264         nbdest => $nbdest,
1265         proto => $proto,
1266         dport => $dport,
1267         sport => $sport,
1268     };
1269
1270     if ($macro) {
1271         foreach my $templ (@$macro) {
1272             my $rule = {};
1273             my $param_used = {};
1274             foreach my $k (keys %$templ) {
1275                 my $v = $templ->{$k};
1276                 if ($v eq 'PARAM') {
1277                     $v = $param->{$k};
1278                     $param_used->{$k} = 1;
1279                 } elsif ($v eq 'DEST') {
1280                     $v = $param->{dest};
1281                     $param_used->{dest} = 1;
1282                 } elsif ($v eq 'SOURCE') {
1283                     $v = $param->{source};
1284                     $param_used->{source} = 1;
1285                 }
1286
1287                 die "missing parameter '$k' in macro '$macro_name'\n" if !defined($v);
1288                 $rule->{$k} = $v;
1289             }
1290             foreach my $k (keys %$param) {
1291                 next if !defined($param->{$k});
1292                 next if $param_used->{$k};
1293                 if (defined($rule->{$k})) {
1294                     die "parameter '$k' already define in macro (value = '$rule->{$k}')\n"
1295                         if $rule->{$k} ne $param->{$k};
1296                 } else {
1297                     $rule->{$k} = $param->{$k};
1298                 }
1299             }
1300             push @$rules, $rule;
1301         }
1302     } else {
1303         push @$rules, $param;
1304     }
1305
1306     foreach my $rule (@$rules) {
1307         $rule->{nbdport} = parse_port_name_number_or_range($rule->{dport})
1308             if defined($rule->{dport});
1309         $rule->{nbsport} = parse_port_name_number_or_range($rule->{sport})
1310             if defined($rule->{sport});
1311     }
1312
1313     return $rules;
1314 }
1315
1316 sub parse_vmfw_option {
1317     my ($line) = @_;
1318
1319     my ($opt, $value);
1320
1321     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
1322
1323     if ($line =~ m/^(enable|dhcp|macfilter|nosmurfs|tcpflags):\s*(0|1)\s*$/i) {
1324         $opt = lc($1);
1325         $value = int($2);
1326     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
1327         $opt = lc($1);
1328         $value = $2 ? lc($3) : '';
1329     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
1330         $opt = lc($1);
1331         $value = uc($3);
1332     } else {
1333         chomp $line;
1334         die "can't parse option '$line'\n"
1335     }
1336
1337     return ($opt, $value);
1338 }
1339
1340 sub parse_hostfw_option {
1341     my ($line) = @_;
1342
1343     my ($opt, $value);
1344
1345     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
1346
1347     if ($line =~ m/^(enable|dhcp|nosmurfs|tcpflags|allow_bridge_route):\s*(0|1)\s*$/i) {
1348         $opt = lc($1);
1349         $value = int($2);
1350     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
1351         $opt = lc($1);
1352         $value = $2 ? lc($3) : '';
1353     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
1354         $opt = lc($1);
1355         $value = uc($3);
1356     } elsif ($line =~ m/^(nf_conntrack_max):\s*(\d+)\s*$/i) {
1357         $opt = lc($1);
1358         $value = int($2);
1359     } else {
1360         chomp $line;
1361         die "can't parse option '$line'\n"
1362     }
1363
1364     return ($opt, $value);
1365 }
1366
1367 sub parse_vm_fw_rules {
1368     my ($filename, $fh) = @_;
1369
1370     my $res = { rules => [], options => {}};
1371
1372     my $section;
1373
1374     while (defined(my $line = <$fh>)) {
1375         next if $line =~ m/^#/;
1376         next if $line =~ m/^\s*$/;
1377
1378         my $linenr = $fh->input_line_number();
1379         my $prefix = "$filename (line $linenr)";
1380
1381         if ($line =~ m/^\[(\S+)\]\s*$/i) {
1382             $section = lc($1);
1383             warn "$prefix: ignore unknown section '$section'\n" if !$res->{$section};
1384             next;
1385         }
1386         if (!$section) {
1387             warn "$prefix: skip line - no section";
1388             next;
1389         }
1390
1391         next if !$res->{$section}; # skip undefined section
1392
1393         if ($section eq 'options') {
1394             eval {
1395                 my ($opt, $value) = parse_vmfw_option($line);
1396                 $res->{options}->{$opt} = $value;
1397             };
1398             warn "$prefix: $@" if $@;
1399             next;
1400         }
1401
1402         my $rules;
1403         eval { $rules = parse_fw_rule($line, 1, 1); };
1404         if (my $err = $@) {
1405             warn "$prefix: $err";
1406             next;
1407         }
1408
1409         push @{$res->{$section}}, @$rules;
1410     }
1411
1412     return $res;
1413 }
1414
1415 sub parse_host_fw_rules {
1416     my ($filename, $fh) = @_;
1417
1418     my $res = { rules => [], options => {}};
1419
1420     my $section;
1421
1422     while (defined(my $line = <$fh>)) {
1423         next if $line =~ m/^#/;
1424         next if $line =~ m/^\s*$/;
1425
1426         my $linenr = $fh->input_line_number();
1427         my $prefix = "$filename (line $linenr)";
1428
1429         if ($line =~ m/^\[(\S+)\]\s*$/i) {
1430             $section = lc($1);
1431             warn "$prefix: ignore unknown section '$section'\n" if !$res->{$section};
1432             next;
1433         }
1434         if (!$section) {
1435             warn "$prefix: skip line - no section";
1436             next;
1437         }
1438
1439         next if !$res->{$section}; # skip undefined section
1440
1441         if ($section eq 'options') {
1442             eval {
1443                 my ($opt, $value) = parse_hostfw_option($line);
1444                 $res->{options}->{$opt} = $value;
1445             };
1446             warn "$prefix: $@" if $@;
1447             next;
1448         }
1449
1450         my $rules;
1451         eval { $rules = parse_fw_rule($line, 1, 1); };
1452         if (my $err = $@) {
1453             warn "$prefix: $err";
1454             next;
1455         }
1456
1457         push @{$res->{$section}}, @$rules;
1458     }
1459
1460     return $res;
1461 }
1462
1463 sub parse_group_fw_rules {
1464     my ($filename, $fh) = @_;
1465
1466     my $section;
1467     my $group;
1468
1469     my $res = { rules => [] };
1470
1471     while (defined(my $line = <$fh>)) {
1472         next if $line =~ m/^#/;
1473         next if $line =~ m/^\s*$/;
1474
1475         my $linenr = $fh->input_line_number();
1476         my $prefix = "$filename (line $linenr)";
1477
1478         if ($line =~ m/^\[group\s+(\S+)\]\s*$/i) {
1479             $section = 'rules';
1480             $group = lc($1);
1481             next;
1482         }
1483         if (!$section || !$group) {
1484             warn "$prefix: skip line - no section";
1485             next;
1486         }
1487
1488         my $rules;
1489         eval { $rules = parse_fw_rule($line, 0, 0); };
1490         if (my $err = $@) {
1491             warn "$prefix: $err";
1492             next;
1493         }
1494
1495         push @{$res->{$group}->{$section}}, @$rules;
1496     }
1497
1498     return $res;
1499 }
1500
1501 sub run_locked {
1502     my ($code, @param) = @_;
1503
1504     my $timeout = 10;
1505
1506     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
1507
1508     die $@ if $@;
1509
1510     return $res;
1511 }
1512
1513 sub read_local_vm_config {
1514
1515     my $openvz = {};
1516     my $qemu = {};
1517
1518     my $vmdata = { openvz => $openvz, qemu => $qemu };
1519
1520     my $vmlist = PVE::Cluster::get_vmlist();
1521     return $vmdata if !$vmlist || !$vmlist->{ids};
1522     my $ids = $vmlist->{ids};
1523
1524     foreach my $vmid (keys %$ids) {
1525         next if !$vmid; # skip VE0
1526         my $d = $ids->{$vmid};
1527         next if !$d->{node} || $d->{node} ne $nodename;
1528         next if !$d->{type};
1529         if ($d->{type} eq 'openvz') {
1530             my $cfspath = PVE::OpenVZ::cfs_config_path($vmid);
1531             if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
1532                 $openvz->{$vmid} = $conf;
1533             }
1534         } elsif ($d->{type} eq 'qemu') {
1535             my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
1536             if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
1537                 $qemu->{$vmid} = $conf;
1538             }
1539         }
1540     }
1541
1542     return $vmdata;
1543 };
1544
1545 sub read_vm_firewall_configs {
1546     my ($vmdata) = @_;
1547     my $vmfw_configs = {};
1548
1549     foreach my $vmid (keys %{$vmdata->{qemu}}, keys %{$vmdata->{openvz}}) {
1550         my $filename = "/etc/pve/firewall/$vmid.fw";
1551         my $fh = IO::File->new($filename, O_RDONLY);
1552         next if !$fh;
1553
1554         $vmfw_configs->{$vmid} = parse_vm_fw_rules($filename, $fh);
1555     }
1556
1557     return $vmfw_configs;
1558 }
1559
1560 sub get_option_log_level {
1561     my ($options, $k) = @_;
1562
1563     my $v = $options->{$k};
1564     $v = $default_log_level if !defined($v);
1565
1566     return undef if $v eq '' || $v eq 'nolog';
1567
1568     $v = $log_level_hash->{$v} if defined($log_level_hash->{$v});
1569
1570     return $v if ($v >= 0) && ($v <= 7);
1571
1572     warn "unknown log level ($k = '$v')\n";
1573
1574     return undef;
1575 }
1576
1577 sub generate_std_chains {
1578     my ($ruleset, $options) = @_;
1579
1580     my $loglevel = get_option_log_level($options, 'smurf_log_level');
1581
1582     # same as shorewall smurflog.
1583     my $chain = 'PVEFW-smurflog';
1584
1585     push @{$pve_std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
1586     push @{$pve_std_chains->{$chain}}, "-j DROP";
1587
1588     # same as shorewall logflags action.
1589     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
1590     $chain = 'PVEFW-logflags';
1591     # fixme: is this correctly logged by pvewf-logger? (ther is no --log-ip-options for NFLOG)
1592     push @{$pve_std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
1593     push @{$pve_std_chains->{$chain}}, "-j DROP";
1594
1595     foreach my $chain (keys %$pve_std_chains) {
1596         ruleset_create_chain($ruleset, $chain);
1597         foreach my $rule (@{$pve_std_chains->{$chain}}) {
1598             if (ref($rule)) {
1599                 ruleset_generate_rule($ruleset, $chain, $rule);
1600             } else {
1601                 ruleset_addrule($ruleset, $chain, $rule);
1602             }
1603         }
1604     }
1605 }
1606
1607 sub save_pvefw_status {
1608     my ($status) = @_;
1609
1610     die "unknown status '$status' - internal error"
1611         if $status !~ m/^(stopped|active)$/;
1612
1613     mkdir dirname($pve_fw_status_filename);
1614     PVE::Tools::file_set_contents($pve_fw_status_filename, $status);
1615 }
1616
1617 sub read_pvefw_status {
1618
1619     my $status = 'unknown';
1620
1621     return 'stopped' if ! -f $pve_fw_status_filename;
1622
1623     eval {
1624         $status = PVE::Tools::file_get_contents($pve_fw_status_filename);
1625     };
1626     warn $@ if $@;
1627
1628     return $status;
1629 }
1630
1631 # fixme: move to pve-common PVE::ProcFSTools
1632 sub read_proc_net_route {
1633     my $filename = "/proc/net/route";
1634
1635     my $res = {};
1636
1637     my $fh = IO::File->new ($filename, "r");
1638     return $res if !$fh;
1639
1640     my $int_to_quad = sub {
1641         return join '.' => map { ($_[0] >> 8*(3-$_)) % 256 } (3, 2, 1, 0);
1642     };
1643
1644     while (defined(my $line = <$fh>)) {
1645         next if $line =~/^Iface\s+Destination/; # skip head
1646         my ($iface, $dest, $gateway, $metric, $mask, $mtu) = (split(/\s+/, $line))[0,1,2,6,7,8];
1647         push @{$res->{$iface}}, {
1648             dest => &$int_to_quad(hex($dest)),
1649             gateway => &$int_to_quad(hex($gateway)),
1650             mask => &$int_to_quad(hex($mask)),
1651             metric => $metric,
1652             mtu => $mtu,
1653         };
1654     }
1655
1656     return $res;
1657 }
1658
1659 sub compile {
1660     my $vmdata = read_local_vm_config();
1661     my $vmfw_configs = read_vm_firewall_configs($vmdata);
1662
1663     my $routing_table = read_proc_net_route();
1664
1665     my $groups_conf = {};
1666     my $filename = "/etc/pve/firewall/groups.fw";
1667     if (my $fh = IO::File->new($filename, O_RDONLY)) {
1668         $groups_conf = parse_group_fw_rules($filename, $fh);
1669     }
1670
1671     my $ruleset = {};
1672
1673     ruleset_create_chain($ruleset, "PVEFW-INPUT");
1674     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
1675
1676     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
1677
1678     my $hostfw_options = {};
1679     my $hostfw_conf = {};
1680
1681     $filename = "/etc/pve/local/host.fw";
1682     if (my $fh = IO::File->new($filename, O_RDONLY)) {
1683         $hostfw_conf = parse_host_fw_rules($filename, $fh);
1684         $hostfw_options = $hostfw_conf->{options};
1685     }
1686
1687     generate_std_chains($ruleset, $hostfw_options);
1688
1689     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
1690
1691     enable_host_firewall($ruleset, $hostfw_conf, $groups_conf) if $hostfw_enable;
1692
1693     # generate firewall rules for QEMU VMs
1694     foreach my $vmid (keys %{$vmdata->{qemu}}) {
1695         my $conf = $vmdata->{qemu}->{$vmid};
1696         my $vmfw_conf = $vmfw_configs->{$vmid};
1697         next if !$vmfw_conf;
1698         next if defined($vmfw_conf->{options}->{enable}) && ($vmfw_conf->{options}->{enable} == 0);
1699
1700         foreach my $netid (keys %$conf) {
1701             next if $netid !~ m/^net(\d+)$/;
1702             my $net = PVE::QemuServer::parse_net($conf->{$netid});
1703             next if !$net;
1704             my $iface = "tap${vmid}i$1";
1705
1706             my $bridge = $net->{bridge};
1707             next if !$bridge; # fixme: ?
1708
1709             $bridge .= "v$net->{tag}" if $net->{tag};
1710
1711             generate_bridge_chains($ruleset, $hostfw_conf, $bridge, $routing_table);
1712
1713             my $macaddr = $net->{macaddr};
1714             generate_tap_rules_direction($ruleset, $groups_conf, $iface, $netid, $macaddr,
1715                                          $vmfw_conf, $vmid, $bridge, 'IN');
1716             generate_tap_rules_direction($ruleset, $groups_conf, $iface, $netid, $macaddr,
1717                                          $vmfw_conf, $vmid, $bridge, 'OUT');
1718         }
1719     }
1720
1721     # generate firewall rules for OpenVZ containers
1722     foreach my $vmid (keys %{$vmdata->{openvz}}) {
1723         my $conf = $vmdata->{openvz}->{$vmid};
1724
1725         my $vmfw_conf = $vmfw_configs->{$vmid};
1726         next if !$vmfw_conf;
1727         next if defined($vmfw_conf->{options}->{enable}) && ($vmfw_conf->{options}->{enable} == 0);
1728
1729         if ($conf->{ip_address} && $conf->{ip_address}->{value}) {
1730             my $ip = $conf->{ip_address}->{value};
1731             generate_venet_rules_direction($ruleset, $groups_conf, $vmfw_conf, $vmid, $ip, 'IN');
1732             generate_venet_rules_direction($ruleset, $groups_conf, $vmfw_conf, $vmid, $ip, 'OUT');
1733         }
1734
1735         if ($conf->{netif} && $conf->{netif}->{value}) {
1736             my $netif = PVE::OpenVZ::parse_netif($conf->{netif}->{value});
1737             foreach my $netid (keys %$netif) {
1738                 my $d = $netif->{$netid};
1739                 my $bridge = $d->{bridge};
1740                 if (!$bridge) {
1741                     warn "no bridge device for CT $vmid iface '$netid'\n";
1742                     next; # fixme?
1743                 }
1744
1745                 generate_bridge_chains($ruleset, $hostfw_conf, $bridge, $routing_table);
1746
1747                 my $macaddr = $d->{mac};
1748                 my $iface = $d->{host_ifname};
1749                 generate_tap_rules_direction($ruleset, $groups_conf, $iface, $netid, $macaddr,
1750                                              $vmfw_conf, $vmid, $bridge, 'IN');
1751                 generate_tap_rules_direction($ruleset, $groups_conf, $iface, $netid, $macaddr,
1752                                              $vmfw_conf, $vmid, $bridge, 'OUT');
1753             }
1754         }
1755     }
1756
1757     # fixme: this is an optimization? if so, we should also drop INVALID packages?
1758     ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED -j ACCEPT");
1759
1760     # fixme: what log level should we use here?
1761     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
1762
1763     # fixme: should we really block inter-bridge traffic?
1764
1765     # always allow traffic from containers?
1766     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i venet0 -j RETURN");
1767
1768     # disable interbridge routing
1769     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o vmbr+ -j PVEFW-Drop");
1770     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i vmbr+ -j PVEFW-Drop");
1771     ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-o vmbr+");
1772     ruleset_addlog($ruleset, "PVEFW-FORWARD", 0, "DROP: ", $loglevel, "-i vmbr+");
1773     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o vmbr+ -j DROP");
1774     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i vmbr+ -j DROP");
1775
1776     return wantarray ? ($ruleset, $hostfw_conf) : $ruleset;
1777 }
1778
1779 sub get_ruleset_status {
1780     my ($ruleset, $verbose) = @_;
1781
1782     my $active_chains = iptables_get_chains();
1783
1784     my $statushash = {};
1785
1786     foreach my $chain (sort keys %$ruleset) {
1787         my $digest = Digest::SHA->new('sha1');
1788         foreach my $cmd (@{$ruleset->{$chain}}) {
1789              $digest->add("$cmd\n");
1790         }
1791         my $sig = $digest->b64digest;
1792         $statushash->{$chain}->{sig} = $sig;
1793
1794         my $oldsig = $active_chains->{$chain};
1795         if (!defined($oldsig)) {
1796             $statushash->{$chain}->{action} = 'create';
1797         } else {
1798             if ($oldsig eq $sig) {
1799                 $statushash->{$chain}->{action} = 'exists';
1800             } else {
1801                 $statushash->{$chain}->{action} = 'update';
1802             }
1803         }
1804         print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
1805         foreach my $cmd (@{$ruleset->{$chain}}) {
1806             print "\t$cmd\n" if $verbose;
1807         }
1808     }
1809
1810     foreach my $chain (sort keys %$active_chains) {
1811         if (!defined($ruleset->{$chain})) {
1812             my $sig = $active_chains->{$chain};
1813             $statushash->{$chain}->{action} = 'delete';
1814             $statushash->{$chain}->{sig} = $sig;
1815             print "delete $chain ($sig)\n" if $verbose;
1816         }
1817     }
1818
1819     return $statushash;
1820 }
1821
1822 sub print_ruleset {
1823     my ($ruleset) = @_;
1824
1825     get_ruleset_status($ruleset, 1);
1826 }
1827
1828 sub print_sig_rule {
1829     my ($chain, $sig) = @_;
1830
1831     # We just use this to store a SHA1 checksum used to detect changes
1832     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
1833 }
1834
1835 sub get_rulset_cmdlist {
1836     my ($ruleset, $verbose) = @_;
1837
1838     my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
1839
1840     my $statushash = get_ruleset_status($ruleset, $verbose);
1841
1842     # create missing chains first
1843     foreach my $chain (sort keys %$ruleset) {
1844         my $stat = $statushash->{$chain};
1845         die "internal error" if !$stat;
1846         next if $stat->{action} ne 'create';
1847
1848         $cmdlist .= ":$chain - [0:0]\n";
1849     }
1850
1851     my $rule = "INPUT -j PVEFW-INPUT";
1852     if (!PVE::Firewall::iptables_rule_exist($rule)) {
1853         $cmdlist .= "-A $rule\n";
1854     }
1855     $rule = "OUTPUT -j PVEFW-OUTPUT";
1856     if (!PVE::Firewall::iptables_rule_exist($rule)) {
1857         $cmdlist .= "-A $rule\n";
1858     }
1859
1860     $rule = "FORWARD -j PVEFW-FORWARD";
1861     if (!PVE::Firewall::iptables_rule_exist($rule)) {
1862         $cmdlist .= "-A $rule\n";
1863     }
1864
1865     foreach my $chain (sort keys %$ruleset) {
1866         my $stat = $statushash->{$chain};
1867         die "internal error" if !$stat;
1868
1869         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
1870             $cmdlist .= "-F $chain\n";
1871             foreach my $cmd (@{$ruleset->{$chain}}) {
1872                 $cmdlist .= "$cmd\n";
1873             }
1874             $cmdlist .= print_sig_rule($chain, $stat->{sig});
1875         } elsif ($stat->{action} eq 'delete') {
1876             die "internal error"; # this should not happen
1877         } elsif ($stat->{action} eq 'exists') {
1878             # do nothing
1879         } else {
1880             die "internal error - unknown status '$stat->{action}'";
1881         }
1882     }
1883
1884     foreach my $chain (keys %$statushash) {
1885         next if $statushash->{$chain}->{action} ne 'delete';
1886         $cmdlist .= "-F $chain\n";
1887     }
1888     foreach my $chain (keys %$statushash) {
1889         next if $statushash->{$chain}->{action} ne 'delete';
1890         next if $chain eq 'PVEFW-INPUT';
1891         next if $chain eq 'PVEFW-OUTPUT';
1892         next if $chain eq 'PVEFW-FORWARD';
1893         $cmdlist .= "-X $chain\n";
1894     }
1895
1896     $cmdlist .= "COMMIT\n";
1897
1898     return $cmdlist;
1899 }
1900
1901 sub apply_ruleset {
1902     my ($ruleset, $hostfw_conf, $verbose) = @_;
1903
1904     enable_bridge_firewall();
1905
1906     update_nf_conntrack_max($hostfw_conf);
1907
1908     my $cmdlist = get_rulset_cmdlist($ruleset, $verbose);
1909
1910     print $cmdlist if $verbose;
1911
1912     iptables_restore_cmdlist($cmdlist);
1913
1914     # test: re-read status and check if everything is up to date
1915     my $statushash = get_ruleset_status($ruleset);
1916
1917     my $errors;
1918     foreach my $chain (sort keys %$ruleset) {
1919         my $stat = $statushash->{$chain};
1920         if ($stat->{action} ne 'exists') {
1921             warn "unable to update chain '$chain'\n";
1922             $errors = 1;
1923         }
1924     }
1925
1926     die "unable to apply firewall changes\n" if $errors;
1927 }
1928
1929 sub update_nf_conntrack_max {
1930     my ($hostfw_conf) = @_;
1931
1932     my $max = 65536; # reasonable default
1933
1934     my $options = $hostfw_conf->{options} || {};
1935
1936     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
1937         $max = $options->{nf_conntrack_max};
1938         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
1939     }
1940
1941     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
1942     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
1943
1944     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
1945
1946     if ($current != $max) {
1947         my $hashsize = int($max/4);
1948         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
1949         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
1950     }
1951 }
1952
1953 sub update {
1954     my ($start, $verbose) = @_;
1955
1956     my $code = sub {
1957         my $status = read_pvefw_status();
1958
1959         my ($ruleset, $hostfw_conf) = PVE::Firewall::compile();
1960
1961         if ($start || $status eq 'active') {
1962
1963             save_pvefw_status('active') if ($status ne 'active');
1964
1965             apply_ruleset($ruleset, $hostfw_conf, $verbose);
1966         } else {
1967             print "Firewall not active (status = $status)\n" if $verbose;
1968         }
1969     };
1970
1971     run_locked($code);
1972 }
1973
1974
1975 1;