PVE/VZDump.pm

   1 package PVE::VZDump;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Clone;
   7 use Fcntl ':flock';
   8 use File::Basename;
   9 use File::Path;
  10 use IO::File;
  11 use IO::Select;
  12 use IPC::Open3;
  13 use POSIX qw(strftime);
  14 use Time::Local;
  15
  16 use PVE::Cluster qw(cfs_read_file);
  17 use PVE::DataCenterConfig;
  18 use PVE::Exception qw(raise_param_exc);
  19 use PVE::HA::Config;
  20 use PVE::HA::Env::PVE2;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::RPCEnvironment;
  23 use PVE::Storage;
  24 use PVE::VZDump::Common;
  25 use PVE::VZDump::Plugin;
  26 use PVE::Tools qw(extract_param split_list);
  27 use PVE::API2Tools;
  28
  29 my @posix_filesystems = qw(ext3 ext4 nfs nfs4 reiserfs xfs);
  30
  31 my $lockfile = '/var/run/vzdump.lock';
  32 my $pidfile = '/var/run/vzdump.pid';
  33 my $logdir = '/var/log/vzdump';
  34
  35 my @plugins = qw();
  36
  37 my $confdesc = PVE::VZDump::Common::get_confdesc();
  38
  39 my $confdesc_for_defaults = Clone::clone($confdesc);
  40 delete $confdesc_for_defaults->{$_}->{requires} for qw(notes-template protected);
  41
  42 # Load available plugins
  43 my @pve_vzdump_classes = qw(PVE::VZDump::QemuServer PVE::VZDump::LXC);
  44 foreach my $plug (@pve_vzdump_classes) {
  45     my $filename = "/usr/share/perl5/$plug.pm";
  46     $filename =~ s!::!/!g;
  47     if (-f $filename) {
  48         eval { require $filename; };
  49         if (!$@) {
  50             $plug->import ();
  51             push @plugins, $plug;
  52         } else {
  53             die $@;
  54         }
  55     }
  56 }
  57
  58 # helper functions
  59
  60 sub debugmsg {
  61     my ($mtype, $msg, $logfd, $syslog) = @_;
  62
  63     PVE::VZDump::Plugin::debugmsg(@_);
  64 }
  65
  66 sub run_command {
  67     my ($logfd, $cmdstr, %param) = @_;
  68
  69     my $logfunc = sub {
  70         my $line = shift;
  71         debugmsg ('info', $line, $logfd);
  72     };
  73
  74     PVE::Tools::run_command($cmdstr, %param, logfunc => $logfunc);
  75 }
  76
  77 my $verify_notes_template = sub {
  78     my ($template) = @_;
  79
  80     die "contains a line feed\n" if $template =~ /\n/;
  81
  82     my @problematic = ();
  83     while ($template =~ /\\(.)/g) {
  84         my $char = $1;
  85         push @problematic, "escape sequence '\\$char' at char " . (pos($template) - 2)
  86             if $char !~ /^[n\\]$/;
  87     }
  88
  89     while ($template =~ /\{\{([^\s{}]+)\}\}/g) {
  90         my $var = $1;
  91         push @problematic, "variable '$var' at char " . (pos($template) - length($var))
  92             if $var !~ /^(cluster|guestname|node|vmid)$/;
  93     }
  94
  95     die "found unknown: " . join(', ', @problematic) . "\n" if scalar(@problematic);
  96 };
  97
  98 my $generate_notes = sub {
  99     my ($notes_template, $task) = @_;
 100
 101     $verify_notes_template->($notes_template);
 102
 103     my $info = {
 104         cluster => PVE::Cluster::get_clinfo()->{cluster}->{name} // 'standalone node',
 105         guestname => $task->{hostname} // "VM $task->{vmid}", # is always set for CTs
 106         node => PVE::INotify::nodename(),
 107         vmid => $task->{vmid},
 108     };
 109
 110     my $unescape = sub {
 111         my ($char) = @_;
 112         return '\\' if $char eq '\\';
 113         return "\n" if $char eq 'n';
 114         die "unexpected escape character '$char'\n";
 115     };
 116
 117     $notes_template =~ s/\\(.)/$unescape->($1)/eg;
 118
 119     my $vars = join('|', keys $info->%*);
 120     $notes_template =~ s/\{\{($vars)\}\}/$info->{$1}/g;
 121
 122     return $notes_template;
 123 };
 124
 125 my sub parse_performance {
 126     my ($param) = @_;
 127
 128     if (defined(my $perf = $param->{performance})) {
 129         return if ref($perf) eq 'HASH'; # already parsed
 130         $param->{performance} = PVE::JSONSchema::parse_property_string('backup-performance', $perf);
 131     }
 132 }
 133
 134 my $parse_prune_backups_maxfiles = sub {
 135     my ($param, $kind) = @_;
 136
 137     my $maxfiles = delete $param->{maxfiles};
 138     my $prune_backups = $param->{'prune-backups'};
 139
 140     debugmsg('warn', "both 'maxfiles' and 'prune-backups' defined as ${kind} - ignoring 'maxfiles'")
 141         if defined($maxfiles) && defined($prune_backups);
 142
 143     if (defined($prune_backups)) {
 144         return if ref($prune_backups) eq 'HASH'; # already parsed
 145         $param->{'prune-backups'} = PVE::JSONSchema::parse_property_string(
 146             'prune-backups',
 147             $prune_backups
 148         );
 149     } elsif (defined($maxfiles)) {
 150         if ($maxfiles) {
 151             $param->{'prune-backups'} = { 'keep-last' => $maxfiles };
 152         } else {
 153             $param->{'prune-backups'} = { 'keep-all' => 1 };
 154         }
 155     }
 156 };
 157
 158 sub storage_info {
 159     my $storage = shift;
 160
 161     my $cfg = PVE::Storage::config();
 162     my $scfg = PVE::Storage::storage_config($cfg, $storage);
 163     my $type = $scfg->{type};
 164
 165     die "can't use storage '$storage' for backups - wrong content type\n"
 166         if (!$scfg->{content}->{backup});
 167
 168     my $info = {
 169         scfg => $scfg,
 170     };
 171
 172     $info->{'prune-backups'} = PVE::JSONSchema::parse_property_string('prune-backups', $scfg->{'prune-backups'})
 173         if defined($scfg->{'prune-backups'});
 174
 175     if ($type eq 'pbs') {
 176         $info->{pbs} = 1;
 177     } else {
 178         $info->{dumpdir} = PVE::Storage::get_backup_dir($cfg, $storage);
 179     }
 180
 181     return $info;
 182 }
 183
 184 sub format_size {
 185     my $size = shift;
 186
 187     my $kb = $size / 1024;
 188
 189     if ($kb < 1024) {
 190         return int ($kb) . "KB";
 191     }
 192
 193     my $mb = $size / (1024*1024);
 194     if ($mb < 1024) {
 195         return int ($mb) . "MB";
 196     }
 197     my $gb = $mb / 1024;
 198     if ($gb < 1024) {
 199         return sprintf ("%.2fGB", $gb);
 200     }
 201     my $tb = $gb / 1024;
 202     return sprintf ("%.2fTB", $tb);
 203 }
 204
 205 sub format_time {
 206     my $seconds = shift;
 207
 208     my $hours = int ($seconds/3600);
 209     $seconds = $seconds - $hours*3600;
 210     my $min = int ($seconds/60);
 211     $seconds = $seconds - $min*60;
 212
 213     return sprintf ("%02d:%02d:%02d", $hours, $min, $seconds);
 214 }
 215
 216 sub encode8bit {
 217     my ($str) = @_;
 218
 219     $str =~ s/^(.{990})/$1\n/mg; # reduce line length
 220
 221     return $str;
 222 }
 223
 224 sub escape_html {
 225     my ($str) = @_;
 226
 227     $str =~ s/&/&amp;/g;
 228     $str =~ s/</&lt;/g;
 229     $str =~ s/>/&gt;/g;
 230
 231     return $str;
 232 }
 233
 234 sub check_bin {
 235     my ($bin)  = @_;
 236
 237     foreach my $p (split (/:/, $ENV{PATH})) {
 238         my $fn = "$p/$bin";
 239         if (-x $fn) {
 240             return $fn;
 241         }
 242     }
 243
 244     die "unable to find command '$bin'\n";
 245 }
 246
 247 sub check_vmids {
 248     my (@vmids) = @_;
 249
 250     my $res = [];
 251     for my $vmid (sort {$a <=> $b} @vmids) {
 252         die "ERROR: strange VM ID '${vmid}'\n" if $vmid !~ m/^\d+$/;
 253         $vmid = int ($vmid); # remove leading zeros
 254         next if !$vmid;
 255         push @$res, $vmid;
 256     }
 257
 258     return $res;
 259 }
 260
 261
 262 sub read_vzdump_defaults {
 263
 264     my $fn = "/etc/vzdump.conf";
 265
 266     my $defaults = {
 267         map {
 268             my $default = $confdesc->{$_}->{default};
 269              defined($default) ? ($_ => $default) : ()
 270         } keys %$confdesc_for_defaults
 271     };
 272     $parse_prune_backups_maxfiles->($defaults, "defaults in VZDump schema");
 273     parse_performance($defaults);
 274
 275     my $raw;
 276     eval { $raw = PVE::Tools::file_get_contents($fn); };
 277     return $defaults if $@;
 278
 279     my $conf_schema = { type => 'object', properties => $confdesc_for_defaults };
 280     my $res = PVE::JSONSchema::parse_config($conf_schema, $fn, $raw);
 281     if (my $excludes = $res->{'exclude-path'}) {
 282         $res->{'exclude-path'} = PVE::Tools::split_args($excludes);
 283     }
 284     if (defined($res->{mailto})) {
 285         my @mailto = split_list($res->{mailto});
 286         $res->{mailto} = [ @mailto ];
 287     }
 288     $parse_prune_backups_maxfiles->($res, "options in '$fn'");
 289     parse_performance($res);
 290
 291     foreach my $key (keys %$defaults) {
 292         $res->{$key} = $defaults->{$key} if !defined($res->{$key});
 293     }
 294
 295     if (defined($res->{storage}) && defined($res->{dumpdir})) {
 296         debugmsg('warn', "both 'storage' and 'dumpdir' defined in '$fn' - ignoring 'dumpdir'");
 297         delete $res->{dumpdir};
 298     }
 299
 300     return $res;
 301 }
 302
 303 use constant MAX_MAIL_SIZE => 1024*1024;
 304 sub sendmail {
 305     my ($self, $tasklist, $totaltime, $err, $detail_pre, $detail_post) = @_;
 306
 307     my $opts = $self->{opts};
 308
 309     my $mailto = $opts->{mailto};
 310
 311     return if !($mailto && scalar(@$mailto));
 312
 313     my $cmdline = $self->{cmdline};
 314
 315     my $ecount = 0;
 316     foreach my $task (@$tasklist) {
 317         $ecount++ if $task->{state} ne 'ok';
 318         chomp $task->{msg} if $task->{msg};
 319         $task->{backuptime} = 0 if !$task->{backuptime};
 320         $task->{size} = 0 if !$task->{size};
 321         $task->{target} = 'unknown' if !$task->{target};
 322         $task->{hostname} = "VM $task->{vmid}" if !$task->{hostname};
 323
 324         if ($task->{state} eq 'todo') {
 325             $task->{msg} = 'aborted';
 326         }
 327     }
 328
 329     my $notify = $opts->{mailnotification} || 'always';
 330     return if (!$ecount && !$err && ($notify eq 'failure'));
 331
 332     my $stat = ($ecount || $err) ? 'backup failed' : 'backup successful';
 333     if ($err) {
 334         if ($err =~ /\n/) {
 335             $stat .= ": multiple problems";
 336         } else {
 337             $stat .= ": $err";
 338             $err = undef;
 339         }
 340     }
 341
 342     my $hostname = `hostname -f` || PVE::INotify::nodename();
 343     chomp $hostname;
 344
 345     # text part
 346     my $text = $err ? "$err\n\n" : '';
 347     my $namelength = 20;
 348     $text .= sprintf (
 349         "%-10s %-${namelength}s %-6s %10s %10s  %s\n",
 350         qw(VMID NAME STATUS TIME SIZE FILENAME)
 351     );
 352     foreach my $task (@$tasklist) {
 353         my $name = substr($task->{hostname}, 0, $namelength);
 354         my $successful = $task->{state} eq 'ok';
 355         my $size = $successful ? format_size ($task->{size}) : 0;
 356         my $filename = $successful ? $task->{target} : '-';
 357         my $size_fmt = $successful ? "%10s": "%8.2fMB";
 358         $text .= sprintf(
 359             "%-10s %-${namelength}s %-6s %10s $size_fmt  %s\n",
 360             $task->{vmid},
 361             $name,
 362             $task->{state},
 363             format_time($task->{backuptime}),
 364             $size,
 365             $filename,
 366         );
 367     }
 368
 369     my $text_log_part;
 370     $text_log_part .= "\nDetailed backup logs:\n\n";
 371     $text_log_part .= "$cmdline\n\n";
 372
 373     $text_log_part .= $detail_pre . "\n" if defined($detail_pre);
 374     foreach my $task (@$tasklist) {
 375         my $vmid = $task->{vmid};
 376         my $log = $task->{tmplog};
 377         if (!$log) {
 378             $text_log_part .= "$vmid: no log available\n\n";
 379             next;
 380         }
 381         if (open (my $TMP, '<', "$log")) {
 382             while (my $line = <$TMP>) {
 383                 next if $line =~ /^status: \d+/; # not useful in mails
 384                 $text_log_part .= encode8bit ("$vmid: $line");
 385             }
 386             close ($TMP);
 387         } else {
 388             $text_log_part .= "$vmid: Could not open log file\n\n";
 389         }
 390         $text_log_part .= "\n";
 391     }
 392     $text_log_part .= $detail_post if defined($detail_post);
 393
 394     # html part
 395     my $html = "<html><body>\n";
 396     $html .= "<p>" . (escape_html($err) =~ s/\n/<br>/gr) . "</p>\n" if $err;
 397     $html .= "<table border=1 cellpadding=3>\n";
 398     $html .= "<tr><td>VMID<td>NAME<td>STATUS<td>TIME<td>SIZE<td>FILENAME</tr>\n";
 399
 400     my $ssize = 0;
 401     foreach my $task (@$tasklist) {
 402         my $vmid = $task->{vmid};
 403         my $name = $task->{hostname};
 404
 405         if  ($task->{state} eq 'ok') {
 406             $ssize += $task->{size};
 407
 408             $html .= sprintf (
 409                 "<tr><td>%s<td>%s<td>OK<td>%s<td align=right>%s<td>%s</tr>\n",
 410                 $vmid,
 411                 $name,
 412                 format_time($task->{backuptime}),
 413                 format_size ($task->{size}),
 414                 escape_html ($task->{target}),
 415             );
 416         } else {
 417             $html .= sprintf (
 418                 "<tr><td>%s<td>%s<td><font color=red>FAILED<td>%s<td colspan=2>%s</tr>\n",
 419                 $vmid,
 420                 $name,
 421                 format_time($task->{backuptime}),
 422                 escape_html ($task->{msg}),
 423             );
 424         }
 425     }
 426
 427     $html .= sprintf ("<tr><td align=left colspan=3>TOTAL<td>%s<td>%s<td></tr>",
 428  format_time ($totaltime), format_size ($ssize));
 429
 430     $html .= "\n</table><br><br>\n";
 431     my $html_log_part;
 432     $html_log_part .= "Detailed backup logs:<br /><br />\n";
 433     $html_log_part .= "<pre>\n";
 434     $html_log_part .= escape_html($cmdline) . "\n\n";
 435
 436     $html_log_part .= escape_html($detail_pre) . "\n" if defined($detail_pre);
 437     foreach my $task (@$tasklist) {
 438         my $vmid = $task->{vmid};
 439         my $log = $task->{tmplog};
 440         if (!$log) {
 441             $html_log_part .= "$vmid: no log available\n\n";
 442             next;
 443         }
 444         if (open (my $TMP, '<', "$log")) {
 445             while (my $line = <$TMP>) {
 446                 next if $line =~ /^status: \d+/; # not useful in mails
 447                 if ($line =~ m/^\S+\s\d+\s+\d+:\d+:\d+\s+(ERROR|WARN):/) {
 448                     $html_log_part .= encode8bit ("$vmid: <font color=red>".
 449                         escape_html ($line) . "</font>");
 450                 } else {
 451                     $html_log_part .= encode8bit ("$vmid: " . escape_html ($line));
 452                 }
 453             }
 454             close ($TMP);
 455         } else {
 456             $html_log_part .= "$vmid: Could not open log file\n\n";
 457         }
 458         $html_log_part .= "\n";
 459     }
 460     $html_log_part .= escape_html($detail_post) if defined($detail_post);
 461     $html_log_part .= "</pre>";
 462     my $html_end = "\n</body></html>\n";
 463     # end html part
 464
 465     if (length($text) + length($text_log_part) +
 466         length($html) + length($html_log_part) +
 467         length($html_end) < MAX_MAIL_SIZE)
 468     {
 469         $html .= $html_log_part;
 470         $html .= $html_end;
 471         $text .= $text_log_part;
 472     } else {
 473         my $msg = "Log output was too long to be sent by mail. ".
 474             "See Task History for details!\n";
 475         $text .= $msg;
 476         $html .= "<p>$msg</p>";
 477         $html .= $html_end;
 478     }
 479
 480     my $subject = "vzdump backup status ($hostname) : $stat";
 481
 482     my $dcconf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 483     my $mailfrom = $dcconf->{email_from} || "root";
 484
 485     PVE::Tools::sendmail($mailto, $subject, $text, $html, $mailfrom, "vzdump backup tool");
 486 };
 487
 488 sub new {
 489     my ($class, $cmdline, $opts, $skiplist) = @_;
 490
 491     mkpath $logdir;
 492
 493     check_bin ('cp');
 494     check_bin ('df');
 495     check_bin ('sendmail');
 496     check_bin ('rsync');
 497     check_bin ('tar');
 498     check_bin ('mount');
 499     check_bin ('umount');
 500     check_bin ('cstream');
 501     check_bin ('ionice');
 502
 503     if ($opts->{mode} && $opts->{mode} eq 'snapshot') {
 504         check_bin ('lvcreate');
 505         check_bin ('lvs');
 506         check_bin ('lvremove');
 507     }
 508
 509     my $defaults = read_vzdump_defaults();
 510
 511     foreach my $k (keys %$defaults) {
 512         next if $k eq 'exclude-path' || $k eq 'prune-backups'; # dealt with separately
 513         if ($k eq 'dumpdir' || $k eq 'storage') {
 514             $opts->{$k} = $defaults->{$k} if !defined ($opts->{dumpdir}) &&
 515                 !defined ($opts->{storage});
 516         } else {
 517             $opts->{$k} = $defaults->{$k} if !defined ($opts->{$k});
 518         }
 519     }
 520
 521     $opts->{dumpdir} =~ s|/+$|| if ($opts->{dumpdir});
 522     $opts->{tmpdir} =~ s|/+$|| if ($opts->{tmpdir});
 523
 524     $skiplist = [] if !$skiplist;
 525     my $self = bless {
 526         cmdline => $cmdline,
 527         opts => $opts,
 528         skiplist => $skiplist,
 529     }, $class;
 530
 531     my $findexcl = $self->{findexcl} = [];
 532     if ($defaults->{'exclude-path'}) {
 533         push @$findexcl, @{$defaults->{'exclude-path'}};
 534     }
 535
 536     if ($opts->{'exclude-path'}) {
 537         push @$findexcl, @{$opts->{'exclude-path'}};
 538     }
 539
 540     if ($opts->{stdexcludes}) {
 541         push @$findexcl,
 542             '/tmp/?*',
 543             '/var/tmp/?*',
 544             '/var/run/?*.pid',
 545             ;
 546     }
 547
 548     foreach my $p (@plugins) {
 549         my $pd = $p->new($self);
 550
 551         push @{$self->{plugins}}, $pd;
 552     }
 553
 554     if (defined($opts->{storage}) && $opts->{stdout}) {
 555         die "cannot use options 'storage' and 'stdout' at the same time\n";
 556     } elsif (defined($opts->{storage}) && defined($opts->{dumpdir})) {
 557         die "cannot use options 'storage' and 'dumpdir' at the same time\n";
 558     }
 559
 560     if (!$opts->{dumpdir} && !$opts->{storage}) {
 561         $opts->{storage} = 'local';
 562     }
 563
 564     # Enforced by the API too, but these options might come in via defaults. Drop them if necessary.
 565     if (!$opts->{storage}) {
 566         delete $opts->{$_} for qw(notes-template protected);
 567     }
 568
 569     my $errors = '';
 570     my $add_error = sub {
 571         my ($error) = @_;
 572         $errors .= "\n" if $errors;
 573         chomp($error);
 574         $errors .= $error;
 575     };
 576
 577     eval {
 578         $self->{job_init_log} = '';
 579         open my $job_init_fd, '>', \$self->{job_init_log};
 580         $self->run_hook_script('job-init', undef, $job_init_fd);
 581         close $job_init_fd;
 582
 583         PVE::Cluster::cfs_update(); # Pick up possible changes made by the hook script.
 584     };
 585     $add_error->($@) if $@;
 586
 587     if ($opts->{storage}) {
 588         my $storage_cfg = PVE::Storage::config();
 589         eval { PVE::Storage::activate_storage($storage_cfg, $opts->{storage}) };
 590         $add_error->("could not activate storage '$opts->{storage}': $@") if $@;
 591
 592         my $info = eval { storage_info ($opts->{storage}) };
 593         if (my $err = $@) {
 594             $add_error->("could not get storage information for '$opts->{storage}': $err");
 595         } else {
 596             $opts->{dumpdir} = $info->{dumpdir};
 597             $opts->{scfg} = $info->{scfg};
 598             $opts->{pbs} = $info->{pbs};
 599             $opts->{'prune-backups'} //= $info->{'prune-backups'};
 600         }
 601     } elsif ($opts->{dumpdir}) {
 602         $add_error->("dumpdir '$opts->{dumpdir}' does not exist")
 603             if ! -d $opts->{dumpdir};
 604     } else {
 605         die "internal error";
 606     }
 607
 608     $opts->{'prune-backups'} //= $defaults->{'prune-backups'};
 609
 610     # avoid triggering any remove code path if keep-all is set
 611     $opts->{remove} = 0 if $opts->{'prune-backups'}->{'keep-all'};
 612
 613     if ($opts->{tmpdir} && ! -d $opts->{tmpdir}) {
 614         $add_error->("tmpdir '$opts->{tmpdir}' does not exist");
 615     }
 616
 617     if ($errors) {
 618         eval { $self->sendmail([], 0, $errors); };
 619         debugmsg ('err', $@) if $@;
 620         die "$errors\n";
 621     }
 622
 623     return $self;
 624 }
 625
 626 sub get_mount_info {
 627     my ($dir) = @_;
 628
 629     # Note: df 'available' can be negative, and percentage set to '-'
 630
 631     my $cmd = [ 'df', '-P', '-T', '-B', '1', $dir];
 632
 633     my $res;
 634
 635     my $parser = sub {
 636         my $line = shift;
 637         if (my ($fsid, $fstype, undef, $mp) = $line =~
 638             m!(\S+.*)\s+(\S+)\s+\d+\s+\-?\d+\s+\d+\s+(\d+%|-)\s+(/.*)$!) {
 639             $res = {
 640                 device => $fsid,
 641                 fstype => $fstype,
 642                 mountpoint => $mp,
 643             };
 644         }
 645     };
 646
 647     eval { PVE::Tools::run_command($cmd, errfunc => sub {}, outfunc => $parser); };
 648     warn $@ if $@;
 649
 650     return $res;
 651 }
 652
 653 sub getlock {
 654     my ($self, $upid) = @_;
 655
 656     my $fh;
 657
 658     my $maxwait = $self->{opts}->{lockwait} || $self->{lockwait};
 659
 660     die "missing UPID" if !$upid; # should not happen
 661
 662     my $SERVER_FLCK;
 663     if (!open ($SERVER_FLCK, '>>', "$lockfile")) {
 664         debugmsg ('err', "can't open lock on file '$lockfile' - $!", undef, 1);
 665         die "can't open lock on file '$lockfile' - $!";
 666     }
 667
 668     if (!flock ($SERVER_FLCK, LOCK_EX|LOCK_NB)) {
 669         if (!$maxwait) {
 670             debugmsg ('err', "can't acquire lock '$lockfile' (wait = 0)", undef, 1);
 671             die "can't acquire lock '$lockfile' (wait = 0)";
 672         }
 673
 674         debugmsg('info', "trying to get global lock - waiting...", undef, 1);
 675         eval {
 676             alarm ($maxwait * 60);
 677
 678             local $SIG{ALRM} = sub { alarm (0); die "got timeout\n"; };
 679
 680             if (!flock ($SERVER_FLCK, LOCK_EX)) {
 681                 my $err = $!;
 682                 close ($SERVER_FLCK);
 683                 alarm (0);
 684                 die "$err\n";
 685             }
 686             alarm (0);
 687         };
 688         alarm (0);
 689
 690         my $err = $@;
 691
 692         if ($err) {
 693             debugmsg ('err', "can't acquire lock '$lockfile' - $err", undef, 1);
 694             die "can't acquire lock '$lockfile' - $err";
 695         }
 696
 697         debugmsg('info', "got global lock", undef, 1);
 698     }
 699
 700     PVE::Tools::file_set_contents($pidfile, $upid);
 701
 702     return $SERVER_FLCK;
 703 }
 704
 705 sub run_hook_script {
 706     my ($self, $phase, $task, $logfd) = @_;
 707
 708     my $opts = $self->{opts};
 709
 710     my $script = $opts->{script};
 711     return if !$script;
 712
 713     die "Error: The hook script '$script' does not exist.\n" if ! -f $script;
 714     die "Error: The hook script '$script' is not executable.\n" if ! -x $script;
 715
 716     my $cmd = [$script, $phase];
 717
 718     if ($task) {
 719         push @$cmd, $task->{mode};
 720         push @$cmd, $task->{vmid};
 721     }
 722
 723     local %ENV;
 724     # set immutable opts directly (so they are available in all phases)
 725     $ENV{STOREID} = $opts->{storage} if $opts->{storage};
 726     $ENV{DUMPDIR} = $opts->{dumpdir} if $opts->{dumpdir};
 727
 728     foreach my $ek (qw(vmtype hostname target logfile)) {
 729         $ENV{uc($ek)} = $task->{$ek} if $task->{$ek};
 730     }
 731
 732     run_command ($logfd, $cmd);
 733 }
 734
 735 sub compressor_info {
 736     my ($opts) = @_;
 737     my $opt_compress = $opts->{compress};
 738
 739     if (!$opt_compress || $opt_compress eq '0') {
 740         return undef;
 741     } elsif ($opt_compress eq '1' || $opt_compress eq 'lzo') {
 742         return ('lzop', 'lzo');
 743     } elsif ($opt_compress eq 'gzip') {
 744         if ($opts->{pigz} > 0) {
 745             my $pigz_threads = $opts->{pigz};
 746             if ($pigz_threads == 1) {
 747                 my $cpuinfo = PVE::ProcFSTools::read_cpuinfo();
 748                 $pigz_threads = int(($cpuinfo->{cpus} + 1)/2);
 749             }
 750             return ("pigz -p ${pigz_threads} --rsyncable", 'gz');
 751         } else {
 752             return ('gzip --rsyncable', 'gz');
 753         }
 754     } elsif ($opt_compress eq 'zstd') {
 755         my $zstd_threads = $opts->{zstd} // 1;
 756         if ($zstd_threads == 0) {
 757             my $cpuinfo = PVE::ProcFSTools::read_cpuinfo();
 758             $zstd_threads = int(($cpuinfo->{cpus} + 1)/2);
 759         }
 760         return ("zstd --rsyncable --threads=${zstd_threads}", 'zst');
 761     } else {
 762         die "internal error - unknown compression option '$opt_compress'";
 763     }
 764 }
 765
 766 sub get_backup_file_list {
 767     my ($dir, $bkname) = @_;
 768
 769     my $bklist = [];
 770     foreach my $fn (<$dir/${bkname}-*>) {
 771         my $archive_info = eval { PVE::Storage::archive_info($fn) } // {};
 772         if ($archive_info->{is_std_name}) {
 773             my $path = "$dir/$archive_info->{filename}";
 774             my $backup = {
 775                 'path' => $path,
 776                 'ctime' => $archive_info->{ctime},
 777             };
 778             $backup->{mark} = "protected"
 779                 if -e PVE::Storage::protection_file_path($path);
 780             push @{$bklist}, $backup;
 781         }
 782     }
 783
 784     return $bklist;
 785 }
 786
 787 sub exec_backup_task {
 788     my ($self, $task) = @_;
 789
 790     my $opts = $self->{opts};
 791
 792     my $cfg = PVE::Storage::config();
 793     my $vmid = $task->{vmid};
 794     my $plugin = $task->{plugin};
 795
 796     $task->{backup_time} = time();
 797
 798     my $pbs_group_name;
 799     my $pbs_snapshot_name;
 800
 801     my $vmstarttime = time ();
 802
 803     my $logfd;
 804
 805     my $cleanup = {};
 806
 807     my $log_vm_online_again = sub {
 808         return if !defined($task->{vmstoptime});
 809         $task->{vmconttime} //= time();
 810         my $delay = $task->{vmconttime} - $task->{vmstoptime};
 811         $delay = '<1' if $delay < 1;
 812         debugmsg ('info', "guest is online again after $delay seconds", $logfd);
 813     };
 814
 815     eval {
 816         die "unable to find VM '$vmid'\n" if !$plugin;
 817
 818         my $vmtype = $plugin->type();
 819
 820         if ($self->{opts}->{pbs}) {
 821             if ($vmtype eq 'lxc') {
 822                 $pbs_group_name = "ct/$vmid";
 823             } elsif  ($vmtype eq 'qemu') {
 824                 $pbs_group_name = "vm/$vmid";
 825             } else {
 826                 die "pbs backup not implemented for plugin type '$vmtype'\n";
 827             }
 828             my $btime = strftime("%FT%TZ", gmtime($task->{backup_time}));
 829             $pbs_snapshot_name = "$pbs_group_name/$btime";
 830         }
 831
 832         # for now we deny backups of a running ha managed service in *stop* mode
 833         # as it interferes with the HA stack (started services should not stop).
 834         if ($opts->{mode} eq 'stop' &&
 835             PVE::HA::Config::vm_is_ha_managed($vmid, 'started'))
 836         {
 837             die "Cannot execute a backup with stop mode on a HA managed and".
 838                 " enabled Service. Use snapshot mode or disable the Service.\n";
 839         }
 840
 841         my $tmplog = "$logdir/$vmtype-$vmid.log";
 842
 843         my $bkname = "vzdump-$vmtype-$vmid";
 844         my $basename = $bkname . strftime("-%Y_%m_%d-%H_%M_%S", localtime($task->{backup_time}));
 845
 846         my $prune_options = $opts->{'prune-backups'};
 847
 848         my $backup_limit = 0;
 849         if (!$prune_options->{'keep-all'}) {
 850             foreach my $keep (values %{$prune_options}) {
 851                 $backup_limit += $keep;
 852             }
 853         }
 854
 855         if (($backup_limit && !$opts->{remove}) || $opts->{protected}) {
 856             my $count;
 857             my $protected_count;
 858             if (my $storeid = $opts->{storage}) {
 859                 my @backups = grep {
 860                     !$_->{subtype} || $_->{subtype} eq $vmtype
 861                 } PVE::Storage::volume_list($cfg, $storeid, $vmid, 'backup')->@*;
 862
 863                 $count = grep { !$_->{protected} } @backups;
 864                 $protected_count = scalar(@backups) - $count;
 865             } else {
 866                 $count = grep { !$_->{mark} || $_->{mark} ne "protected" } get_backup_file_list($opts->{dumpdir}, $bkname)->@*;
 867             }
 868
 869             if ($opts->{protected}) {
 870                 my $max_protected = PVE::Storage::get_max_protected_backups(
 871                     $opts->{scfg},
 872                     $opts->{storage},
 873                 );
 874                 if ($max_protected > -1 && $protected_count >= $max_protected) {
 875                     die "The number of protected backups per guest is limited to $max_protected ".
 876                         "on storage '$opts->{storage}'\n";
 877                 }
 878             } elsif ($count >= $backup_limit) {
 879                 die "There is a max backup limit of $backup_limit enforced by the target storage ".
 880                     "or the vzdump parameters. Either increase the limit or delete old backups.\n";
 881             }
 882         }
 883
 884         if (!$self->{opts}->{pbs}) {
 885             $task->{logfile} = "$opts->{dumpdir}/$basename.log";
 886         }
 887
 888         my $ext = $vmtype eq 'qemu' ? '.vma' : '.tar';
 889         my ($comp, $comp_ext) = compressor_info($opts);
 890         if ($comp && $comp_ext) {
 891             $ext .= ".${comp_ext}";
 892         }
 893
 894         if ($self->{opts}->{pbs}) {
 895             die "unable to pipe backup to stdout\n" if $opts->{stdout};
 896             $task->{target} = $pbs_snapshot_name;
 897         } else {
 898             if ($opts->{stdout}) {
 899                 $task->{target} = '-';
 900             } else {
 901                 $task->{target} = $task->{tmptar} = "$opts->{dumpdir}/$basename$ext";
 902                 $task->{tmptar} =~ s/\.[^\.]+$/\.dat/;
 903                 unlink $task->{tmptar};
 904             }
 905         }
 906
 907         $task->{vmtype} = $vmtype;
 908
 909         my $pid = $$;
 910         if ($opts->{tmpdir}) {
 911             $task->{tmpdir} = "$opts->{tmpdir}/vzdumptmp${pid}_$vmid/";
 912         } elsif ($self->{opts}->{pbs}) {
 913             $task->{tmpdir} = "/var/tmp/vzdumptmp${pid}_$vmid";
 914         } else {
 915             # dumpdir is posix? then use it as temporary dir
 916             my $info = get_mount_info($opts->{dumpdir});
 917             if ($vmtype eq 'qemu' ||
 918                 grep ($_ eq $info->{fstype}, @posix_filesystems)) {
 919                 $task->{tmpdir} = "$opts->{dumpdir}/$basename.tmp";
 920             } else {
 921                 $task->{tmpdir} = "/var/tmp/vzdumptmp${pid}_$vmid";
 922                 debugmsg ('info', "filesystem type on dumpdir is '$info->{fstype}' -" .
 923                           "using $task->{tmpdir} for temporary files", $logfd);
 924             }
 925         }
 926
 927         rmtree $task->{tmpdir};
 928         mkdir $task->{tmpdir};
 929         -d $task->{tmpdir} ||
 930             die "unable to create temporary directory '$task->{tmpdir}'";
 931
 932         $logfd = IO::File->new (">$tmplog") ||
 933             die "unable to create log file '$tmplog'";
 934
 935         $task->{dumpdir} = $opts->{dumpdir};
 936         $task->{storeid} = $opts->{storage};
 937         $task->{scfg} = $opts->{scfg};
 938         $task->{tmplog} = $tmplog;
 939
 940         unlink $task->{logfile} if defined($task->{logfile});
 941
 942         debugmsg ('info', "Starting Backup of VM $vmid ($vmtype)", $logfd, 1);
 943         debugmsg ('info', "Backup started at " . strftime("%F %H:%M:%S", localtime()));
 944
 945         $plugin->set_logfd ($logfd);
 946
 947         # test is VM is running
 948         my ($running, $status_text) = $plugin->vm_status ($vmid);
 949
 950         debugmsg ('info', "status = ${status_text}", $logfd);
 951
 952         # lock VM (prevent config changes)
 953         $plugin->lock_vm ($vmid);
 954
 955         $cleanup->{unlock} = 1;
 956
 957         # prepare
 958
 959         my $mode = $running ? $task->{mode} : 'stop';
 960
 961         if ($mode eq 'snapshot') {
 962             my %saved_task = %$task;
 963             eval { $plugin->prepare ($task, $vmid, $mode); };
 964             if (my $err = $@) {
 965                 die $err if $err !~ m/^mode failure/;
 966                 debugmsg ('info',  $err, $logfd);
 967                 debugmsg ('info',  "trying 'suspend' mode instead", $logfd);
 968                 $mode = 'suspend'; # so prepare is called again below
 969                 %$task = %saved_task;
 970             }
 971         }
 972
 973         $cleanup->{prepared} = 1;
 974
 975         $task->{mode} = $mode;
 976
 977         debugmsg ('info', "backup mode: $mode", $logfd);
 978         debugmsg ('info', "bandwidth limit: $opts->{bwlimit} KB/s", $logfd)  if $opts->{bwlimit};
 979         debugmsg ('info', "ionice priority: $opts->{ionice}", $logfd);
 980
 981         if ($mode eq 'stop') {
 982             $plugin->prepare ($task, $vmid, $mode);
 983
 984             $self->run_hook_script ('backup-start', $task, $logfd);
 985
 986             if ($running) {
 987                 debugmsg ('info', "stopping virtual guest", $logfd);
 988                 $task->{vmstoptime} = time();
 989                 $self->run_hook_script ('pre-stop', $task, $logfd);
 990                 $plugin->stop_vm ($task, $vmid);
 991                 $cleanup->{restart} = 1;
 992             }
 993
 994
 995         } elsif ($mode eq 'suspend') {
 996             $plugin->prepare ($task, $vmid, $mode);
 997
 998             $self->run_hook_script ('backup-start', $task, $logfd);
 999
1000             if ($vmtype eq 'lxc') {
1001                 # pre-suspend rsync
1002                 $plugin->copy_data_phase1($task, $vmid);
1003             }
1004
1005             debugmsg ('info', "suspending guest", $logfd);
1006             $task->{vmstoptime} = time ();
1007             $self->run_hook_script ('pre-stop', $task, $logfd);
1008             $plugin->suspend_vm ($task, $vmid);
1009             $cleanup->{resume} = 1;
1010
1011             if ($vmtype eq 'lxc') {
1012                 # post-suspend rsync
1013                 $plugin->copy_data_phase2($task, $vmid);
1014
1015                 debugmsg ('info', "resuming guest", $logfd);
1016                 $cleanup->{resume} = 0;
1017                 $self->run_hook_script('pre-restart', $task, $logfd);
1018                 $plugin->resume_vm($task, $vmid);
1019                 $self->run_hook_script('post-restart', $task, $logfd);
1020                 $log_vm_online_again->();
1021             }
1022
1023         } elsif ($mode eq 'snapshot') {
1024             $self->run_hook_script ('backup-start', $task, $logfd);
1025
1026             my $snapshot_count = $task->{snapshot_count} || 0;
1027
1028             $self->run_hook_script ('pre-stop', $task, $logfd);
1029
1030             if ($snapshot_count > 1) {
1031                 debugmsg ('info', "suspend vm to make snapshot", $logfd);
1032                 $task->{vmstoptime} = time ();
1033                 $plugin->suspend_vm ($task, $vmid);
1034                 $cleanup->{resume} = 1;
1035             }
1036
1037             $plugin->snapshot ($task, $vmid);
1038
1039             $self->run_hook_script ('pre-restart', $task, $logfd);
1040
1041             if ($snapshot_count > 1) {
1042                 debugmsg ('info', "resume vm", $logfd);
1043                 $cleanup->{resume} = 0;
1044                 $plugin->resume_vm ($task, $vmid);
1045                 $log_vm_online_again->();
1046             }
1047
1048             $self->run_hook_script ('post-restart', $task, $logfd);
1049
1050         } else {
1051             die "internal error - unknown mode '$mode'\n";
1052         }
1053
1054         # assemble archive image
1055         $plugin->assemble ($task, $vmid);
1056
1057         # produce archive
1058
1059         if ($opts->{stdout}) {
1060             debugmsg ('info', "sending archive to stdout", $logfd);
1061             $plugin->archive($task, $vmid, $task->{tmptar}, $comp);
1062             $self->run_hook_script ('backup-end', $task, $logfd);
1063             return;
1064         }
1065
1066         my $archive_txt = $self->{opts}->{pbs} ? 'Proxmox Backup Server' : 'vzdump';
1067         debugmsg('info', "creating $archive_txt archive '$task->{target}'", $logfd);
1068         $plugin->archive($task, $vmid, $task->{tmptar}, $comp);
1069
1070         if ($self->{opts}->{pbs}) {
1071             # size is added to task struct in guest vzdump plugins
1072         } else {
1073             rename ($task->{tmptar}, $task->{target}) ||
1074                 die "unable to rename '$task->{tmptar}' to '$task->{target}'\n";
1075
1076             # determine size
1077             $task->{size} = (-s $task->{target}) || 0;
1078             my $cs = format_size ($task->{size});
1079             debugmsg ('info', "archive file size: $cs", $logfd);
1080         }
1081
1082         # Mark as protected before pruning.
1083         if (my $storeid = $opts->{storage}) {
1084             my $volname = $opts->{pbs} ? $task->{target} : basename($task->{target});
1085             my $volid = "${storeid}:backup/${volname}";
1086
1087             if ($opts->{'notes-template'} && $opts->{'notes-template'} ne '') {
1088                 debugmsg('info', "adding notes to backup", $logfd);
1089                 my $notes = eval { $generate_notes->($opts->{'notes-template'}, $task); };
1090                 if (my $err = $@) {
1091                     debugmsg('warn', "unable to add notes - $err", $logfd);
1092                 } else {
1093                     eval { PVE::Storage::update_volume_attribute($cfg, $volid, 'notes', $notes) };
1094                     debugmsg('warn', "unable to add notes - $@", $logfd) if $@;
1095                 }
1096             }
1097
1098             if ($opts->{protected}) {
1099                 debugmsg('info', "marking backup as protected", $logfd);
1100                 eval { PVE::Storage::update_volume_attribute($cfg, $volid, 'protected', 1) };
1101                 die "unable to set protected flag - $@\n" if $@;
1102             }
1103         }
1104
1105         if ($opts->{remove}) {
1106             my $keepstr = join(', ', map { "$_=$prune_options->{$_}" } sort keys %$prune_options);
1107             debugmsg ('info', "prune older backups with retention: $keepstr", $logfd);
1108             my $pruned = 0;
1109             if (!defined($opts->{storage})) {
1110                 my $bklist = get_backup_file_list($opts->{dumpdir}, $bkname);
1111
1112                 PVE::Storage::prune_mark_backup_group($bklist, $prune_options);
1113
1114                 foreach my $prune_entry (@{$bklist}) {
1115                     next if $prune_entry->{mark} ne 'remove';
1116                     $pruned++;
1117                     my $archive_path = $prune_entry->{path};
1118                     debugmsg ('info', "delete old backup '$archive_path'", $logfd);
1119                     PVE::Storage::archive_remove($archive_path);
1120                 }
1121             } else {
1122                 my $pruned_list = PVE::Storage::prune_backups(
1123                     $cfg,
1124                     $opts->{storage},
1125                     $prune_options,
1126                     $vmid,
1127                     $vmtype,
1128                     0,
1129                     sub { debugmsg($_[0], $_[1], $logfd) },
1130                 );
1131                 $pruned = scalar(grep { $_->{mark} eq 'remove' } $pruned_list->@*);
1132             }
1133             my $log_pruned_extra = $pruned > 0 ? " not covered by keep-retention policy" : "";
1134             debugmsg ('info', "pruned $pruned backup(s)${log_pruned_extra}", $logfd);
1135         }
1136
1137         $self->run_hook_script ('backup-end', $task, $logfd);
1138     };
1139     my $err = $@;
1140
1141     if ($plugin) {
1142         # clean-up
1143
1144         if ($cleanup->{unlock}) {
1145             eval { $plugin->unlock_vm ($vmid); };
1146             warn $@ if $@;
1147         }
1148
1149         if ($cleanup->{prepared}) {
1150             # only call cleanup when necessary (when prepare was executed)
1151             eval { $plugin->cleanup ($task, $vmid) };
1152             warn $@ if $@;
1153         }
1154
1155         eval { $plugin->set_logfd (undef); };
1156         warn $@ if $@;
1157
1158         if ($cleanup->{resume} || $cleanup->{restart}) {
1159             eval {
1160                 $self->run_hook_script ('pre-restart', $task, $logfd);
1161                 if ($cleanup->{resume}) {
1162                     debugmsg ('info', "resume vm", $logfd);
1163                     $plugin->resume_vm ($task, $vmid);
1164                 } else {
1165                     my $running = $plugin->vm_status($vmid);
1166                     if (!$running) {
1167                         debugmsg ('info', "restarting vm", $logfd);
1168                         $plugin->start_vm ($task, $vmid);
1169                     }
1170                 }
1171                 $self->run_hook_script ('post-restart', $task, $logfd);
1172             };
1173             my $err = $@;
1174             if ($err) {
1175                 warn $err;
1176             } else {
1177                 $log_vm_online_again->();
1178             }
1179         }
1180     }
1181
1182     eval { unlink $task->{tmptar} if $task->{tmptar} && -f $task->{tmptar}; };
1183     warn $@ if $@;
1184
1185     eval { rmtree $task->{tmpdir} if $task->{tmpdir} && -d $task->{tmpdir}; };
1186     warn $@ if $@;
1187
1188     my $delay = $task->{backuptime} = time () - $vmstarttime;
1189
1190     if ($err) {
1191         $task->{state} = 'err';
1192         $task->{msg} = $err;
1193         debugmsg ('err', "Backup of VM $vmid failed - $err", $logfd, 1);
1194         debugmsg ('info', "Failed at " . strftime("%F %H:%M:%S", localtime()));
1195
1196         eval { $self->run_hook_script ('backup-abort', $task, $logfd); };
1197
1198     } else {
1199         $task->{state} = 'ok';
1200         my $tstr = format_time ($delay);
1201         debugmsg ('info', "Finished Backup of VM $vmid ($tstr)", $logfd, 1);
1202         debugmsg ('info', "Backup finished at " . strftime("%F %H:%M:%S", localtime()));
1203     }
1204
1205     close ($logfd) if $logfd;
1206
1207     if ($task->{tmplog}) {
1208         if ($self->{opts}->{pbs}) {
1209             if ($task->{state} eq 'ok') {
1210                 eval {
1211                     PVE::Storage::PBSPlugin::run_raw_client_cmd(
1212                         $opts->{scfg},
1213                         $opts->{storage},
1214                         'upload-log',
1215                         [ $pbs_snapshot_name, $task->{tmplog} ],
1216                         errmsg => "uploading backup task log failed",
1217                         outfunc => sub {},
1218                     );
1219                 };
1220                 debugmsg('warn', "$@") if $@; # $@ contains already error prefix
1221             }
1222         } elsif ($task->{logfile}) {
1223             system {'cp'} 'cp', $task->{tmplog}, $task->{logfile};
1224         }
1225     }
1226
1227     eval { $self->run_hook_script ('log-end', $task); };
1228
1229     die $err if $err && $err =~ m/^interrupted by signal$/;
1230 }
1231
1232 sub exec_backup {
1233     my ($self, $rpcenv, $authuser) = @_;
1234
1235     my $opts = $self->{opts};
1236
1237     debugmsg ('info', "starting new backup job: $self->{cmdline}", undef, 1);
1238
1239     if (scalar(@{$self->{skiplist}})) {
1240         my $skip_string = join(', ', sort { $a <=> $b } @{$self->{skiplist}});
1241         debugmsg ('info', "skip external VMs: $skip_string");
1242     }
1243
1244     my $tasklist = [];
1245     my $vzdump_plugins =  {};
1246     foreach my $plugin (@{$self->{plugins}}) {
1247         my $type = $plugin->type();
1248         next if exists $vzdump_plugins->{$type};
1249         $vzdump_plugins->{$type} = $plugin;
1250     }
1251
1252     my $vmlist = PVE::Cluster::get_vmlist();
1253     my $vmids = [ sort { $a <=> $b } @{$opts->{vmids}} ];
1254     foreach my $vmid (@{$vmids}) {
1255         my $plugin;
1256         if (defined($vmlist->{ids}->{$vmid})) {
1257             my $guest_type = $vmlist->{ids}->{$vmid}->{type};
1258             $plugin = $vzdump_plugins->{$guest_type};
1259             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Backup' ], $opts->{all});
1260         }
1261         push @$tasklist, {
1262             mode => $opts->{mode},
1263             plugin => $plugin,
1264             state => 'todo',
1265             vmid => $vmid,
1266         };
1267     }
1268
1269     # Use in-memory files for the outer hook logs to pass them to sendmail.
1270     my $job_start_log = '';
1271     my $job_end_log = '';
1272     open my $job_start_fd, '>', \$job_start_log;
1273     open my $job_end_fd, '>', \$job_end_log;
1274
1275     my $starttime = time();
1276     my $errcount = 0;
1277     eval {
1278
1279         $self->run_hook_script ('job-start', undef, $job_start_fd);
1280
1281         foreach my $task (@$tasklist) {
1282             $self->exec_backup_task ($task);
1283             $errcount += 1 if $task->{state} ne 'ok';
1284         }
1285
1286         $self->run_hook_script ('job-end', undef, $job_end_fd);
1287     };
1288     my $err = $@;
1289
1290     $self->run_hook_script ('job-abort', undef, $job_end_fd) if $err;
1291
1292     if ($err) {
1293         debugmsg ('err', "Backup job failed - $err", undef, 1);
1294     } else {
1295         if ($errcount) {
1296             debugmsg ('info', "Backup job finished with errors", undef, 1);
1297         } else {
1298             debugmsg ('info', "Backup job finished successfully", undef, 1);
1299         }
1300     }
1301
1302     close $job_start_fd;
1303     close $job_end_fd;
1304
1305     my $totaltime = time() - $starttime;
1306
1307     eval {
1308         $self->sendmail(
1309             $tasklist,
1310             $totaltime,
1311             undef,
1312             $self->{job_init_log} . $job_start_log,
1313             $job_end_log,
1314         );
1315     };
1316     debugmsg ('err', $@) if $@;
1317
1318     die $err if $err;
1319
1320     die "job errors\n" if $errcount;
1321
1322     unlink $pidfile;
1323 }
1324
1325
1326 sub option_exists {
1327     my $key = shift;
1328     return defined($confdesc->{$key});
1329 }
1330
1331 # NOTE it might make sense to merge this and verify_vzdump_parameters(), but one
1332 # needs to adapt command_line() in guest-common's PVE/VZDump/Common.pm and detect
1333 # a second parsing attempt, because verify_vzdump_parameters() is called twice
1334 # during the update_job API call.
1335 sub parse_mailto_exclude_path {
1336     my ($param) = @_;
1337
1338     # exclude-path list need to be 0 separated
1339     if (defined($param->{'exclude-path'})) {
1340         my @expaths = split(/\0/, $param->{'exclude-path'} || '');
1341         $param->{'exclude-path'} = [ @expaths ];
1342     }
1343
1344     if (defined($param->{mailto})) {
1345         my @mailto = PVE::Tools::split_list(extract_param($param, 'mailto'));
1346         $param->{mailto} = [ @mailto ];
1347     }
1348
1349     return;
1350 }
1351
1352 sub verify_vzdump_parameters {
1353     my ($param, $check_missing) = @_;
1354
1355     raise_param_exc({ all => "option conflicts with option 'vmid'"})
1356         if $param->{all} && $param->{vmid};
1357
1358     raise_param_exc({ exclude => "option conflicts with option 'vmid'"})
1359         if $param->{exclude} && $param->{vmid};
1360
1361     raise_param_exc({ pool => "option conflicts with option 'vmid'"})
1362         if $param->{pool} && $param->{vmid};
1363
1364     raise_param_exc({ 'prune-backups' => "option conflicts with option 'maxfiles'"})
1365         if defined($param->{'prune-backups'}) && defined($param->{maxfiles});
1366
1367     $parse_prune_backups_maxfiles->($param, 'CLI parameters');
1368     parse_performance($param);
1369
1370     if (my $template = $param->{'notes-template'}) {
1371         eval { $verify_notes_template->($template); };
1372         raise_param_exc({'notes-template' => $@}) if $@;
1373     }
1374
1375     $param->{all} = 1 if (defined($param->{exclude}) && !$param->{pool});
1376
1377     return if !$check_missing;
1378
1379     raise_param_exc({ vmid => "property is missing"})
1380         if !($param->{all} || $param->{stop} || $param->{pool}) && !$param->{vmid};
1381
1382 }
1383
1384 sub stop_running_backups {
1385     my($self) = @_;
1386
1387     my $upid = PVE::Tools::file_read_firstline($pidfile);
1388     return if !$upid;
1389
1390     my $task = PVE::Tools::upid_decode($upid);
1391
1392     if (PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart}) &&
1393         PVE::ProcFSTools::read_proc_starttime($task->{pid}) == $task->{pstart}) {
1394         kill(15, $task->{pid});
1395         # wait max 15 seconds to shut down (else, do nothing for now)
1396         my $i;
1397         for ($i = 15; $i > 0; $i--) {
1398             last if !PVE::ProcFSTools::check_process_running(($task->{pid}, $task->{pstart}));
1399             sleep (1);
1400         }
1401         die "stopping backup process $task->{pid} failed\n" if $i == 0;
1402     }
1403 }
1404
1405 sub get_included_guests {
1406     my ($job) = @_;
1407
1408     my $vmids = [];
1409     my $vmids_per_node = {};
1410
1411     my $vmlist = PVE::Cluster::get_vmlist();
1412
1413     if ($job->{pool}) {
1414         $vmids = PVE::API2Tools::get_resource_pool_guest_members($job->{pool});
1415     } elsif ($job->{vmid}) {
1416         $vmids = [ split_list($job->{vmid}) ];
1417     } elsif ($job->{all}) {
1418         # all or exclude
1419         my $exclude = check_vmids(split_list($job->{exclude}));
1420         my $excludehash = { map { $_ => 1 } @$exclude };
1421
1422         for my $id (keys %{$vmlist->{ids}}) {
1423             next if $excludehash->{$id};
1424             push @$vmids, $id;
1425         }
1426     } else {
1427         return $vmids_per_node;
1428     }
1429     $vmids = check_vmids(@$vmids);
1430
1431     for my $vmid (@$vmids) {
1432         if (defined($vmlist->{ids}->{$vmid})) {
1433             my $node = $vmlist->{ids}->{$vmid}->{node};
1434             next if (defined $job->{node} && $job->{node} ne $node);
1435
1436             push @{$vmids_per_node->{$node}}, $vmid;
1437         } else {
1438             push @{$vmids_per_node->{''}}, $vmid;
1439         }
1440     }
1441
1442     return $vmids_per_node;
1443 }
1444
1445 1;