PVE/Diskmanage.pm

   1 package PVE::Diskmanage;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::ProcFSTools;
   7 use Data::Dumper;
   8 use Cwd qw(abs_path);
   9 use Fcntl ':mode';
  10 use File::stat;
  11 use JSON;
  12
  13 use PVE::Tools qw(extract_param run_command file_get_contents file_read_firstline dir_glob_regex dir_glob_foreach trim);
  14
  15 my $SMARTCTL = "/usr/sbin/smartctl";
  16 my $ZPOOL = "/sbin/zpool";
  17 my $SGDISK = "/sbin/sgdisk";
  18 my $PVS = "/sbin/pvs";
  19 my $LVS = "/sbin/lvs";
  20 my $LSBLK = "/bin/lsblk";
  21
  22 sub verify_blockdev_path {
  23     my ($rel_path) = @_;
  24
  25     die "missing path" if !$rel_path;
  26     my $path = abs_path($rel_path);
  27     die "failed to get absolute path to $rel_path\n" if !$path;
  28
  29     die "got unusual device path '$path'\n" if $path !~  m|^/dev/(.*)$|;
  30
  31     $path = "/dev/$1"; # untaint
  32
  33     assert_blockdev($path);
  34
  35     return $path;
  36 }
  37
  38 sub assert_blockdev {
  39     my ($dev, $noerr) = @_;
  40
  41     if ($dev !~ m|^/dev/| || !(-b $dev)) {
  42         return undef if $noerr;
  43         die "not a valid block device\n";
  44     }
  45
  46     return 1;
  47 }
  48
  49 sub init_disk {
  50     my ($disk, $uuid) = @_;
  51
  52     assert_blockdev($disk);
  53
  54     # we should already have checked if it is in use in the api call
  55     # but we check again for safety
  56     die "disk $disk is already in use\n" if disk_is_used($disk);
  57
  58     my $id = $uuid || 'R';
  59     run_command([$SGDISK, $disk, '-U', $id]);
  60     return 1;
  61 }
  62
  63 sub disk_is_used {
  64     my ($disk) = @_;
  65
  66     my $dev = $disk;
  67     $dev =~ s|^/dev/||;
  68
  69     my $disklist = get_disks($dev, 1);
  70
  71     die "'$disk' is not a valid local disk\n" if !defined($disklist->{$dev});
  72     return 1 if $disklist->{$dev}->{used};
  73
  74     return 0;
  75 }
  76
  77 sub get_smart_data {
  78     my ($disk, $healthonly) = @_;
  79
  80     assert_blockdev($disk);
  81     my $smartdata = {};
  82     my $type;
  83
  84     my $returncode = 0;
  85
  86     if ($disk =~ m!^/dev/(nvme\d+n\d+)$!) {
  87         my $info = get_sysdir_info("/sys/block/$1");
  88         $disk = "/dev/".($info->{device}
  89             or die "failed to get nvme controller device for $disk\n");
  90     }
  91
  92     my $cmd = [$SMARTCTL, '-H'];
  93     push @$cmd, '-A', '-f', 'brief' if !$healthonly;
  94     push @$cmd, $disk;
  95
  96     eval {
  97         $returncode = run_command($cmd, noerr => 1, outfunc => sub{
  98             my ($line) = @_;
  99
 100 # ATA SMART attributes, e.g.:
 101 # ID# ATTRIBUTE_NAME          FLAGS    VALUE WORST THRESH FAIL RAW_VALUE
 102 #   1 Raw_Read_Error_Rate     POSR-K   100   100   000    -    0
 103 #
 104 # SAS and NVME disks, e.g.:
 105 # Data Units Written:                 5,584,952 [2.85 TB]
 106 # Accumulated start-stop cycles:  34
 107
 108             if (defined($type) && $type eq 'ata' && $line =~ m/^([ \d]{2}\d)\s+(\S+)\s+(\S{6})\s+(\d+)\s+(\d+)\s+(\S+)\s+(\S+)\s+(.*)$/) {
 109                 my $entry = {};
 110
 111                 $entry->{name} = $2 if defined $2;
 112                 $entry->{flags} = $3 if defined $3;
 113                 # the +0 makes a number out of the strings
 114                 $entry->{value} = $4+0 if defined $4;
 115                 $entry->{worst} = $5+0 if defined $5;
 116                 # some disks report the default threshold as --- instead of 000
 117                 if (defined($6) && $6 eq '---') {
 118                     $entry->{threshold} = 0;
 119                 } else {
 120                     $entry->{threshold} = $6+0 if defined $6;
 121                 }
 122                 $entry->{fail} = $7 if defined $7;
 123                 $entry->{raw} = $8 if defined $8;
 124                 $entry->{id} = $1 if defined $1;
 125                 push @{$smartdata->{attributes}}, $entry;
 126             } elsif ($line =~ m/(?:Health Status|self\-assessment test result): (.*)$/ ) {
 127                 $smartdata->{health} = $1;
 128             } elsif ($line =~ m/Vendor Specific SMART Attributes with Thresholds:/) {
 129                 $type = 'ata';
 130                 delete $smartdata->{text};
 131             } elsif ($line =~ m/=== START OF (READ )?SMART DATA SECTION ===/) {
 132                 $type = 'text';
 133             } elsif (defined($type) && $type eq 'text') {
 134                 $smartdata->{text} = '' if !defined $smartdata->{text};
 135                 $smartdata->{text} .= "$line\n";
 136                 # extract wearout from nvme/sas text, allow for decimal values
 137                 if ($line =~ m/Percentage Used(?: endurance indicator)?:\s*(\d+(?:\.\d+)?)\%/i) {
 138                     $smartdata->{wearout} = 100 - $1;
 139                 }
 140             } elsif ($line =~ m/SMART Disabled/) {
 141                 $smartdata->{health} = "SMART Disabled";
 142             }
 143         });
 144     };
 145     my $err = $@;
 146
 147     # bit 0 and 1 mark an severe smartctl error
 148     # all others are for disk status, so ignore them
 149     # see smartctl(8)
 150     if ((defined($returncode) && ($returncode & 0b00000011)) || $err) {
 151         die "Error getting S.M.A.R.T. data: Exit code: $returncode\n";
 152     }
 153
 154     $smartdata->{type} = $type;
 155
 156     return $smartdata;
 157 }
 158
 159 sub get_parttype_info() {
 160     my $cmd = [$LSBLK, '--json', '-o', 'path,parttype'];
 161     my $output = "";
 162     my $res = {};
 163     eval {
 164         run_command($cmd, outfunc => sub {
 165             my ($line) = @_;
 166             $output .= "$line\n";
 167         });
 168     };
 169     warn "$@\n" if $@;
 170     return $res if $output eq '';
 171
 172     my $parsed = eval { decode_json($output) };
 173     warn "$@\n" if $@;
 174     my $list = $parsed->{blockdevices} // [];
 175
 176     foreach my $dev (@$list) {
 177         next if !($dev->{parttype});
 178         my $type = $dev->{parttype};
 179         $res->{$type} = [] if !defined($res->{$type});
 180         push @{$res->{$type}}, $dev->{path};
 181     }
 182
 183     return $res;
 184 }
 185
 186 my $get_devices_by_partuuid = sub {
 187     my ($parttype_map, $uuids, $res) = @_;
 188
 189     $res = {} if !defined($res);
 190
 191     foreach my $uuid (sort keys %$uuids) {
 192        map { $res->{$_} = $uuids->{$uuid} } @{$parttype_map->{$uuid}};
 193     }
 194
 195     return $res;
 196 };
 197
 198 sub get_zfs_devices {
 199     my ($parttype_map) = @_;
 200     my $res = {};
 201
 202     return {} if ! -x $ZPOOL;
 203
 204     # use zpool and parttype uuid,
 205     # because log and cache do not have
 206     # zfs type uuid
 207     eval {
 208         run_command([$ZPOOL, 'list', '-HPLv'], outfunc => sub {
 209              my ($line) = @_;
 210
 211              if ($line =~ m|^\t([^\t]+)\t|) {
 212                 $res->{$1} = 1;
 213              }
 214         });
 215     };
 216
 217     # only warn here,
 218     # because maybe zfs tools are not installed
 219     warn "$@\n" if $@;
 220
 221     my $uuids = {
 222         "6a898cc3-1dd2-11b2-99a6-080020736631" => 1, # apple
 223         "516e7cba-6ecf-11d6-8ff8-00022d09712b" => 1, # bsd
 224     };
 225
 226
 227     $res = $get_devices_by_partuuid->($parttype_map, $uuids, $res);
 228
 229     return $res;
 230 }
 231
 232 sub get_lvm_devices {
 233     my ($parttype_map) = @_;
 234     my $res = {};
 235     eval {
 236         run_command([$PVS, '--noheadings', '--readonly', '-o', 'pv_name'], outfunc => sub{
 237             my ($line) = @_;
 238             $line = trim($line);
 239             if ($line =~ m|^/dev/|) {
 240                 $res->{$line} = 1;
 241             }
 242         });
 243     };
 244
 245     # if something goes wrong, we do not want
 246     # to give up, but indicate an error has occured
 247     warn "$@\n" if $@;
 248
 249     my $uuids = {
 250         "e6d6d379-f507-44c2-a23c-238f2a3df928" => 1,
 251     };
 252
 253     $res = $get_devices_by_partuuid->($parttype_map, $uuids, $res);
 254
 255     return $res;
 256 }
 257
 258 sub get_ceph_journals {
 259     my ($parttype_map) = @_;
 260     my $res = {};
 261
 262     my $uuids = {
 263         '45b0969e-9b03-4f30-b4c6-b4b80ceff106' => 1, # journal
 264         '30cd0809-c2b2-499c-8879-2d6b78529876' => 2, # db
 265         '5ce17fce-4087-4169-b7ff-056cc58473f9' => 3, # wal
 266         'cafecafe-9b03-4f30-b4c6-b4b80ceff106' => 4, # block
 267     };
 268
 269     $res = $get_devices_by_partuuid->($parttype_map, $uuids, $res);
 270
 271     return $res;
 272 }
 273
 274 # reads the lv_tags and matches them with the devices
 275 sub get_ceph_volume_infos {
 276     my $result = {};
 277
 278     my $cmd = [ $LVS, '-S', 'lv_name=~^osd-', '-o', 'devices,lv_name,lv_tags',
 279                '--noheadings', '--readonly', '--separator', ';' ];
 280
 281     run_command($cmd, outfunc => sub {
 282         my $line = shift;
 283         $line =~ s/(?:^\s+)|(?:\s+$)//g; # trim whitespaces
 284
 285         my $fields = [ split(';', $line) ];
 286
 287         # lvs syntax is /dev/sdX(Y) where Y is the start (which we do not need)
 288         my ($dev) = $fields->[0] =~ m|^(/dev/[a-z]+)|;
 289         if ($fields->[1] =~ m|^osd-([^-]+)-|) {
 290             my $type = $1;
 291             # $result autovivification is wanted, to not creating empty hashes
 292             if (($type eq 'block' || $type eq 'data') && $fields->[2] =~ m/ceph.osd_id=([^,]+)/) {
 293                 $result->{$dev}->{osdid} = $1;
 294                 $result->{$dev}->{bluestore} = ($type eq 'block');
 295                 if ($fields->[2] =~ m/ceph\.encrypted=1/) {
 296                     $result->{$dev}->{encrypted} = 1;
 297                 }
 298             } else {
 299                 # undef++ becomes '1' (see `perldoc perlop`: Auto-increment)
 300                 $result->{$dev}->{$type}++;
 301             }
 302         }
 303     });
 304
 305     return $result;
 306 }
 307
 308 sub get_udev_info {
 309     my ($dev) = @_;
 310
 311     my $info = "";
 312     my $data = {};
 313     eval {
 314         run_command(['udevadm', 'info', '-p', $dev, '--query', 'all'], outfunc => sub {
 315             my ($line) = @_;
 316             $info .= "$line\n";
 317         });
 318     };
 319     warn $@ if $@;
 320     return undef if !$info;
 321
 322     return undef if $info !~ m/^E: DEVTYPE=disk$/m;
 323     return undef if $info =~ m/^E: ID_CDROM/m;
 324
 325     # we use this, because some disks are not simply in /dev
 326     # e.g. /dev/cciss/c0d0
 327     if ($info =~ m/^E: DEVNAME=(\S+)$/m) {
 328         $data->{devpath} = $1;
 329     }
 330     return if !defined($data->{devpath});
 331
 332     $data->{serial} = 'unknown';
 333     if ($info =~ m/^E: ID_SERIAL_SHORT=(\S+)$/m) {
 334         $data->{serial} = $1;
 335     }
 336
 337     $data->{gpt} = 0;
 338     if ($info =~ m/^E: ID_PART_TABLE_TYPE=gpt$/m) {
 339         $data->{gpt} = 1;
 340     }
 341
 342     # detect SSD
 343     $data->{rpm} = -1;
 344     if ($info =~ m/^E: ID_ATA_ROTATION_RATE_RPM=(\d+)$/m) {
 345         $data->{rpm} = $1;
 346     }
 347
 348     if ($info =~ m/^E: ID_BUS=usb$/m) {
 349         $data->{usb} = 1;
 350     }
 351
 352     if ($info =~ m/^E: ID_MODEL=(.+)$/m) {
 353         $data->{model} = $1;
 354     }
 355
 356     $data->{wwn} = 'unknown';
 357     if ($info =~ m/^E: ID_WWN=(.*)$/m) {
 358         $data->{wwn} = $1;
 359     }
 360
 361     if ($info =~ m/^E: DEVLINKS=(.+)$/m) {
 362         my @devlinks = grep(m#^/dev/disk/by-id/(ata|scsi|nvme(?!-eui))#, split (/ /, $1));
 363         $data->{by_id_link} = $devlinks[0] if defined($devlinks[0]);
 364     }
 365
 366     return $data;
 367 }
 368
 369 sub get_sysdir_info {
 370     my ($sysdir) = @_;
 371
 372     return undef if ! -d "$sysdir/device";
 373
 374     my $data = {};
 375
 376     my $size = file_read_firstline("$sysdir/size");
 377     return undef if !$size;
 378
 379     # linux always considers sectors to be 512 bytes,
 380     # independently of real block size
 381     $data->{size} = $size * 512;
 382
 383     # dir/queue/rotational should be 1 for hdd, 0 for ssd
 384     $data->{rotational} = file_read_firstline("$sysdir/queue/rotational") // -1;
 385
 386     $data->{vendor} = file_read_firstline("$sysdir/device/vendor") || 'unknown';
 387     $data->{model} = file_read_firstline("$sysdir/device/model") || 'unknown';
 388
 389     if (defined(my $device = readlink("$sysdir/device"))) {
 390         # strip directory and untaint:
 391         ($data->{device}) = $device =~ m!([^/]+)$!;
 392     }
 393
 394     return $data;
 395 }
 396
 397 sub get_wear_leveling_info {
 398     my ($smartdata) = @_;
 399     my $attributes = $smartdata->{attributes};
 400
 401     if (defined($smartdata->{wearout})) {
 402         return $smartdata->{wearout};
 403     }
 404
 405     my $wearout;
 406
 407     # Common register names that represent percentage values of potential
 408     # failure indicators used in drivedb.h of smartmontool's. Order matters,
 409     # as some drives may have multiple definitions
 410     my @wearoutregisters = (
 411         "Media_Wearout_Indicator",
 412         "SSD_Life_Left",
 413         "Wear_Leveling_Count",
 414         "Perc_Write\/Erase_Ct_BC",
 415         "Perc_Rated_Life_Remain",
 416         "Remaining_Lifetime_Perc",
 417         "Percent_Lifetime_Remain",
 418         "Lifetime_Left",
 419         "PCT_Life_Remaining",
 420         "Lifetime_Remaining",
 421         "Percent_Life_Remaining",
 422         "Percent_Lifetime_Used",
 423         "Perc_Rated_Life_Used"
 424     );
 425
 426     # Search for S.M.A.R.T. attributes for known register
 427     foreach my $register (@wearoutregisters) {
 428         last if defined $wearout;
 429         foreach my $attr (@$attributes) {
 430            next if $attr->{name} !~ m/$register/;
 431            $wearout = $attr->{value};
 432            last;
 433         }
 434     }
 435
 436     return $wearout;
 437 }
 438
 439 sub dir_is_empty {
 440     my ($dir) = @_;
 441
 442     my $dh = IO::Dir->new ($dir);
 443     return 1 if !$dh;
 444
 445     while (defined(my $tmp = $dh->read)) {
 446         next if $tmp eq '.' || $tmp eq '..';
 447         $dh->close;
 448         return 0;
 449     }
 450     $dh->close;
 451     return 1;
 452 }
 453
 454 sub is_iscsi {
 455     my ($sysdir) = @_;
 456
 457     if (-l $sysdir && readlink($sysdir) =~ m|host[^/]*/session[^/]*|) {
 458         return 1;
 459     }
 460
 461     return 0;
 462 }
 463
 464 my sub is_ssdlike {
 465     my ($type) = @_;
 466     return $type eq 'ssd' || $type eq 'nvme';
 467 }
 468
 469 sub get_disks {
 470     my ($disks, $nosmart) = @_;
 471     my $disklist = {};
 472
 473     my $mounted = {};
 474
 475     my $mounts = PVE::ProcFSTools::parse_proc_mounts();
 476
 477     foreach my $mount (@$mounts) {
 478         next if $mount->[0] !~ m|^/dev/|;
 479         $mounted->{abs_path($mount->[0])} = $mount->[1];
 480     };
 481
 482     my $parttype_map = get_parttype_info();
 483
 484     my $journalhash = get_ceph_journals($parttype_map);
 485     my $ceph_volume_infos = get_ceph_volume_infos();
 486
 487     my $zfshash = get_zfs_devices($parttype_map);
 488
 489     my $lvmhash = get_lvm_devices($parttype_map);
 490
 491     my $disk_regex = ".*";
 492     if (defined($disks)) {
 493         if (!ref($disks)) {
 494             $disks = [ $disks ];
 495         } elsif (ref($disks) ne 'ARRAY') {
 496             die "disks is not a string or array reference\n";
 497         }
 498         # we get cciss/c0d0 but need cciss!c0d0
 499         $_ =~ s|cciss/|cciss!| for @$disks;
 500
 501         $disk_regex = "(?:" . join('|', @$disks) . ")";
 502     }
 503
 504     dir_glob_foreach('/sys/block', $disk_regex, sub {
 505         my ($dev) = @_;
 506         # whitelisting following devices
 507         # hdX: ide block device
 508         # sdX: sd block device
 509         # vdX: virtual block device
 510         # xvdX: xen virtual block device
 511         # nvmeXnY: nvme devices
 512         # cciss!cXnY: cciss devices
 513         return if $dev !~ m/^(h|s|x?v)d[a-z]+$/ &&
 514                   $dev !~ m/^nvme\d+n\d+$/ &&
 515                   $dev !~ m/^cciss\!c\d+d\d+$/;
 516
 517         my $data = get_udev_info("/sys/block/$dev");
 518         return if !defined($data);
 519         my $devpath = $data->{devpath};
 520
 521         my $sysdir = "/sys/block/$dev";
 522
 523         # we do not want iscsi devices
 524         return if is_iscsi($sysdir);
 525
 526         my $sysdata = get_sysdir_info($sysdir);
 527         return if !defined($sysdata);
 528
 529         my $type = 'unknown';
 530
 531         if ($sysdata->{rotational} == 0) {
 532             $type = 'ssd';
 533             $type = 'nvme' if $dev =~ m/^nvme\d+n\d+$/;
 534             $data->{rpm} = 0;
 535         } elsif ($sysdata->{rotational} == 1) {
 536             if ($data->{rpm} != -1) {
 537                 $type = 'hdd';
 538             } elsif ($data->{usb}) {
 539                 $type = 'usb';
 540                 $data->{rpm} = 0;
 541             }
 542         }
 543
 544         my $health = 'UNKNOWN';
 545         my $wearout = 'N/A';
 546
 547         if (!$nosmart) {
 548             eval {
 549                 my $smartdata = get_smart_data($devpath, !is_ssdlike($type));
 550                 $health = $smartdata->{health} if $smartdata->{health};
 551
 552                 if (is_ssdlike($type)) {
 553                     # if we have an ssd we try to get the wearout indicator
 554                     my $wearval = get_wear_leveling_info($smartdata);
 555                     $wearout = $wearval if defined($wearval);
 556                 }
 557             };
 558         }
 559
 560         my $used;
 561
 562         $used = 'LVM' if $lvmhash->{$devpath};
 563
 564         $used = 'mounted' if $mounted->{$devpath};
 565
 566         $used = 'ZFS' if $zfshash->{$devpath};
 567
 568         # we replaced cciss/ with cciss! above
 569         # but in the result we need cciss/ again
 570         # because the caller might want to check the
 571         # result again with the original parameter
 572         if ($dev =~ m|^cciss!|) {
 573             $dev =~ s|^cciss!|cciss/|;
 574         }
 575
 576         $disklist->{$dev} = {
 577             vendor => $sysdata->{vendor},
 578             model => $data->{model} || $sysdata->{model},
 579             size => $sysdata->{size},
 580             serial => $data->{serial},
 581             gpt => $data->{gpt},
 582             rpm => $data->{rpm},
 583             type =>  $type,
 584             wwn => $data->{wwn},
 585             health => $health,
 586             devpath => $devpath,
 587             wearout => $wearout,
 588         };
 589
 590         my $by_id_link = $data->{by_id_link};
 591         $disklist->{$dev}->{by_id_link} = $by_id_link if defined($by_id_link);
 592
 593         my $osdid = -1;
 594         my $bluestore = 0;
 595         my $osdencrypted = 0;
 596
 597         my $journal_count = 0;
 598         my $db_count = 0;
 599         my $wal_count = 0;
 600
 601         my $found_partitions;
 602         my $found_lvm;
 603         my $found_mountpoints;
 604         my $found_zfs;
 605         my $found_dm;
 606         my $partpath = $devpath;
 607
 608         # remove part after last / to
 609         # get the base path for the partitions
 610         # e.g. from /dev/cciss/c0d0 get /dev/cciss
 611         $partpath =~ s/\/[^\/]+$//;
 612
 613         dir_glob_foreach("$sysdir", "$dev.+", sub {
 614             my ($part) = @_;
 615
 616             $found_partitions = 1;
 617
 618             if (my $mp = $mounted->{"$partpath/$part"}) {
 619                 $found_mountpoints = 1;
 620                 if ($mp =~ m|^/var/lib/ceph/osd/ceph-(\d+)$|) {
 621                     $osdid = $1;
 622                 }
 623             }
 624
 625             if ($lvmhash->{"$partpath/$part"}) {
 626                 $found_lvm = 1;
 627             }
 628
 629             if ($zfshash->{"$partpath/$part"}) {
 630                 $found_zfs = 1;
 631             }
 632
 633             if (my $journal_part = $journalhash->{"$partpath/$part"}) {
 634                 $journal_count++ if $journal_part == 1;
 635                 $db_count++ if $journal_part == 2;
 636                 $wal_count++ if $journal_part == 3;
 637                 $bluestore = 1 if $journal_part == 4;
 638             }
 639
 640             if (!dir_is_empty("$sysdir/$part/holders") && !$found_lvm)  {
 641                 $found_dm = 1;
 642             }
 643         });
 644
 645         if (my $ceph_volume = $ceph_volume_infos->{$devpath}) {
 646             $journal_count += $ceph_volume->{journal} // 0;
 647             $db_count += $ceph_volume->{db} // 0;
 648             $wal_count += $ceph_volume->{wal} // 0;
 649             if (defined($ceph_volume->{osdid})) {
 650                 $osdid = $ceph_volume->{osdid};
 651                 $bluestore = 1 if $ceph_volume->{bluestore};
 652                 $osdencrypted = 1 if $ceph_volume->{encrypted};
 653             }
 654         }
 655
 656         $used = 'mounted' if $found_mountpoints && !$used;
 657         $used = 'LVM' if $found_lvm && !$used;
 658         $used = 'ZFS' if $found_zfs && !$used;
 659         $used = 'Device Mapper' if $found_dm && !$used;
 660         $used = 'partitions' if $found_partitions && !$used;
 661
 662         # multipath, software raid, etc.
 663         # this check comes in last, to show more specific info
 664         # if we have it
 665         $used = 'Device Mapper' if !$used && !dir_is_empty("$sysdir/holders");
 666
 667         $disklist->{$dev}->{used} = $used if $used;
 668         $disklist->{$dev}->{osdid} = $osdid;
 669         $disklist->{$dev}->{journals} = $journal_count if $journal_count;
 670         $disklist->{$dev}->{bluestore} = $bluestore if $osdid != -1;
 671         $disklist->{$dev}->{osdencrypted} = $osdencrypted if $osdid != -1;
 672         $disklist->{$dev}->{db} = $db_count if $db_count;
 673         $disklist->{$dev}->{wal} = $wal_count if $wal_count;
 674     });
 675
 676     return $disklist;
 677
 678 }
 679
 680 sub get_partnum {
 681     my ($part_path) = @_;
 682
 683     my $st = stat($part_path);
 684
 685     next if !$st->mode || !S_ISBLK($st->mode) || !$st->rdev;
 686     my $major = PVE::Tools::dev_t_major($st->rdev);
 687     my $minor = PVE::Tools::dev_t_minor($st->rdev);
 688     my $partnum_path = "/sys/dev/block/$major:$minor/";
 689
 690     my $partnum;
 691
 692     $partnum = file_read_firstline("${partnum_path}partition");
 693
 694     die "Partition does not exist\n" if !defined($partnum);
 695
 696     #untaint and ensure it is a int
 697     if ($partnum =~ m/(\d+)/) {
 698         $partnum = $1;
 699         die "Partition number $partnum is invalid\n" if $partnum > 128;
 700     } else {
 701         die "Failed to get partition number\n";
 702     }
 703
 704     return $partnum;
 705 }
 706
 707 sub get_blockdev {
 708     my ($part_path) = @_;
 709
 710     my ($dev, $block_dev);
 711     if ($part_path =~ m|^/dev/(.*)$|) {
 712         $dev = $1;
 713         my $link = readlink "/sys/class/block/$dev";
 714         $block_dev = $1 if $link =~ m|([^/]*)/$dev$|;
 715     }
 716
 717     die "Can't parse parent device\n" if !defined($block_dev);
 718     die "No valid block device\n" if index($dev, $block_dev) == -1;
 719
 720     $block_dev = "/dev/$block_dev";
 721     die "Block device does not exsists\n" if !(-b $block_dev);
 722
 723     return $block_dev;
 724 }
 725
 726 sub locked_disk_action {
 727     my ($sub) = @_;
 728     my $res = PVE::Tools::lock_file('/run/lock/pve-diskmanage.lck', undef, $sub);
 729     die $@ if $@;
 730     return $res;
 731 }
 732
 733 sub assert_disk_unused {
 734     my ($dev) = @_;
 735
 736     die "device '$dev' is already in use\n" if disk_is_used($dev);
 737
 738     return undef;
 739 }
 740
 741 sub append_partition {
 742     my ($dev, $size) = @_;
 743
 744     my $devname = $dev;
 745     $devname =~ s|^/dev/||;
 746
 747     my $newpartid = 1;
 748     dir_glob_foreach("/sys/block/$devname", qr/\Q$devname\E.*?(\d+)/, sub {
 749         my ($part, $partid) = @_;
 750
 751         if ($partid >= $newpartid) {
 752             $newpartid = $partid + 1;
 753         }
 754     });
 755
 756     $size = PVE::Tools::convert_size($size, 'b' => 'mb');
 757
 758     run_command([ $SGDISK, '-n', "$newpartid:0:+${size}M", $dev ],
 759                 errmsg => "error creating partition '$newpartid' on '$dev'");
 760
 761     my $partition;
 762
 763     # loop again to detect the real partiton device which does not always follow
 764     # a strict $devname$partition scheme like /dev/nvme0n1 -> /dev/nvme0n1p1
 765     dir_glob_foreach("/sys/block/$devname", qr/\Q$devname\E.*$newpartid/, sub {
 766         my ($part) = @_;
 767
 768         $partition = "/dev/$part";
 769     });
 770
 771     return $partition;
 772 }
 773
 774 1;