PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use File::Basename;
  12 use File::Path;
  13 use Cwd 'abs_path';
  14 use Socket;
  15
  16 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  17 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  18 use PVE::Exception qw(raise_param_exc);
  19 use PVE::JSONSchema;
  20 use PVE::INotify;
  21 use PVE::RPCEnvironment;
  22
  23 use PVE::Storage::Plugin;
  24 use PVE::Storage::DirPlugin;
  25 use PVE::Storage::LVMPlugin;
  26 use PVE::Storage::LvmThinPlugin;
  27 use PVE::Storage::NFSPlugin;
  28 use PVE::Storage::CIFSPlugin;
  29 use PVE::Storage::ISCSIPlugin;
  30 use PVE::Storage::RBDPlugin;
  31 use PVE::Storage::CephFSPlugin;
  32 use PVE::Storage::SheepdogPlugin;
  33 use PVE::Storage::ISCSIDirectPlugin;
  34 use PVE::Storage::GlusterfsPlugin;
  35 use PVE::Storage::ZFSPoolPlugin;
  36 use PVE::Storage::ZFSPlugin;
  37 use PVE::Storage::DRBDPlugin;
  38
  39 # Storage API version. Icrement it on changes in storage API interface.
  40 use constant APIVER => 2;
  41 # Age is the number of versions we're backward compatible with.
  42 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  43 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  44 use constant APIAGE => 1;
  45
  46 # load standard plugins
  47 PVE::Storage::DirPlugin->register();
  48 PVE::Storage::LVMPlugin->register();
  49 PVE::Storage::LvmThinPlugin->register();
  50 PVE::Storage::NFSPlugin->register();
  51 PVE::Storage::CIFSPlugin->register();
  52 PVE::Storage::ISCSIPlugin->register();
  53 PVE::Storage::RBDPlugin->register();
  54 PVE::Storage::CephFSPlugin->register();
  55 PVE::Storage::SheepdogPlugin->register();
  56 PVE::Storage::ISCSIDirectPlugin->register();
  57 PVE::Storage::GlusterfsPlugin->register();
  58 PVE::Storage::ZFSPoolPlugin->register();
  59 PVE::Storage::ZFSPlugin->register();
  60 PVE::Storage::DRBDPlugin->register();
  61
  62 # load third-party plugins
  63 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  64     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  65         my ($file) = @_;
  66         my $modname = 'PVE::Storage::Custom::' . $file;
  67         $modname =~ s!\.pm$!!;
  68         $file = 'PVE/Storage/Custom/' . $file;
  69
  70         eval {
  71             require $file;
  72
  73             # Check perl interface:
  74             die "not derived from PVE::Storage::Plugin\n"
  75                 if !$modname->isa('PVE::Storage::Plugin');
  76             die "does not provide an api() method\n"
  77                 if !$modname->can('api');
  78             # Check storage API version and that file is really storage plugin.
  79             my $version = $modname->api();
  80             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  81                 if $version > APIVER;
  82             my $min_version = (APIVER - APIAGE);
  83             die "API version too old, please update the plugin ($version < $min_version)\n"
  84                 if $version < $min_version;
  85             import $file;
  86             $modname->register();
  87
  88             # If we got this far and the API version is not the same, make some
  89             # noise:
  90             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  91                 if $version != APIVER;
  92         };
  93         if ($@) {
  94             warn "Error loading storage plugin \"$modname\": $@";
  95         }
  96     });
  97 }
  98
  99 # initialize all plugins
 100 PVE::Storage::Plugin->init();
 101
 102 my $UDEVADM = '/sbin/udevadm';
 103
 104 #  PVE::Storage utility functions
 105
 106 sub config {
 107     return cfs_read_file("storage.cfg");
 108 }
 109
 110 sub write_config {
 111     my ($cfg) = @_;
 112
 113     cfs_write_file('storage.cfg', $cfg);
 114 }
 115
 116 sub lock_storage_config {
 117     my ($code, $errmsg) = @_;
 118
 119     cfs_lock_file("storage.cfg", undef, $code);
 120     my $err = $@;
 121     if ($err) {
 122         $errmsg ? die "$errmsg: $err" : die $err;
 123     }
 124 }
 125
 126 sub storage_config {
 127     my ($cfg, $storeid, $noerr) = @_;
 128
 129     die "no storage ID specified\n" if !$storeid;
 130
 131     my $scfg = $cfg->{ids}->{$storeid};
 132
 133     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
 134
 135     return $scfg;
 136 }
 137
 138 sub storage_check_node {
 139     my ($cfg, $storeid, $node, $noerr) = @_;
 140
 141     my $scfg = storage_config($cfg, $storeid);
 142
 143     if ($scfg->{nodes}) {
 144         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 145         if (!$scfg->{nodes}->{$node}) {
 146             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 147             return undef;
 148         }
 149     }
 150
 151     return $scfg;
 152 }
 153
 154 sub storage_check_enabled {
 155     my ($cfg, $storeid, $node, $noerr) = @_;
 156
 157     my $scfg = storage_config($cfg, $storeid);
 158
 159     if ($scfg->{disable}) {
 160         die "storage '$storeid' is disabled\n" if !$noerr;
 161         return undef;
 162     }
 163
 164     return storage_check_node($cfg, $storeid, $node, $noerr);
 165 }
 166
 167 # storage_can_replicate:
 168 # return true if storage supports replication
 169 # (volumes alocated with vdisk_alloc() has replication feature)
 170 sub storage_can_replicate {
 171     my ($cfg, $storeid, $format) = @_;
 172
 173     my $scfg = storage_config($cfg, $storeid);
 174     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 175     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 176 }
 177
 178 sub storage_ids {
 179     my ($cfg) = @_;
 180
 181     return keys %{$cfg->{ids}};
 182 }
 183
 184 sub file_size_info {
 185     my ($filename, $timeout) = @_;
 186
 187     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 188 }
 189
 190 sub volume_size_info {
 191     my ($cfg, $volid, $timeout) = @_;
 192
 193     my ($storeid, $volname) = parse_volume_id($volid, 1);
 194     if ($storeid) {
 195         my $scfg = storage_config($cfg, $storeid);
 196         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 197         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 198     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 199         return file_size_info($volid, $timeout);
 200     } else {
 201         return 0;
 202     }
 203 }
 204
 205 sub volume_resize {
 206     my ($cfg, $volid, $size, $running) = @_;
 207
 208     my ($storeid, $volname) = parse_volume_id($volid, 1);
 209     if ($storeid) {
 210         my $scfg = storage_config($cfg, $storeid);
 211         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 212         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 213     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 214         die "resize file/device '$volid' is not possible\n";
 215     } else {
 216         die "unable to parse volume ID '$volid'\n";
 217     }
 218 }
 219
 220 sub volume_rollback_is_possible {
 221     my ($cfg, $volid, $snap) = @_;
 222
 223     my ($storeid, $volname) = parse_volume_id($volid, 1);
 224     if ($storeid) {
 225         my $scfg = storage_config($cfg, $storeid);
 226         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 227         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 228     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 229         die "snapshot rollback file/device '$volid' is not possible\n";
 230     } else {
 231         die "unable to parse volume ID '$volid'\n";
 232     }
 233 }
 234
 235 sub volume_snapshot {
 236     my ($cfg, $volid, $snap) = @_;
 237
 238     my ($storeid, $volname) = parse_volume_id($volid, 1);
 239     if ($storeid) {
 240         my $scfg = storage_config($cfg, $storeid);
 241         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 242         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 243     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 244         die "snapshot file/device '$volid' is not possible\n";
 245     } else {
 246         die "unable to parse volume ID '$volid'\n";
 247     }
 248 }
 249
 250 sub volume_snapshot_rollback {
 251     my ($cfg, $volid, $snap) = @_;
 252
 253     my ($storeid, $volname) = parse_volume_id($volid, 1);
 254     if ($storeid) {
 255         my $scfg = storage_config($cfg, $storeid);
 256         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 257         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 258         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 259     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 260         die "snapshot rollback file/device '$volid' is not possible\n";
 261     } else {
 262         die "unable to parse volume ID '$volid'\n";
 263     }
 264 }
 265
 266 sub volume_snapshot_delete {
 267     my ($cfg, $volid, $snap, $running) = @_;
 268
 269     my ($storeid, $volname) = parse_volume_id($volid, 1);
 270     if ($storeid) {
 271         my $scfg = storage_config($cfg, $storeid);
 272         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 273         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 274     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 275         die "snapshot delete file/device '$volid' is not possible\n";
 276     } else {
 277         die "unable to parse volume ID '$volid'\n";
 278     }
 279 }
 280
 281 sub volume_has_feature {
 282     my ($cfg, $feature, $volid, $snap, $running) = @_;
 283
 284     my ($storeid, $volname) = parse_volume_id($volid, 1);
 285     if ($storeid) {
 286         my $scfg = storage_config($cfg, $storeid);
 287         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 288         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 289     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 290         return undef;
 291     } else {
 292         return undef;
 293     }
 294 }
 295
 296 sub volume_snapshot_list {
 297     my ($cfg, $volid) = @_;
 298
 299     my ($storeid, $volname) = parse_volume_id($volid, 1);
 300     if ($storeid) {
 301         my $scfg = storage_config($cfg, $storeid);
 302         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 303         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 304     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 305         die "send file/device '$volid' is not possible\n";
 306     } else {
 307         die "unable to parse volume ID '$volid'\n";
 308     }
 309     # return an empty array if dataset does not exist.
 310 }
 311
 312 sub get_image_dir {
 313     my ($cfg, $storeid, $vmid) = @_;
 314
 315     my $scfg = storage_config($cfg, $storeid);
 316     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 317
 318     my $path = $plugin->get_subdir($scfg, 'images');
 319
 320     return $vmid ? "$path/$vmid" : $path;
 321 }
 322
 323 sub get_private_dir {
 324     my ($cfg, $storeid, $vmid) = @_;
 325
 326     my $scfg = storage_config($cfg, $storeid);
 327     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 328
 329     my $path = $plugin->get_subdir($scfg, 'rootdir');
 330
 331     return $vmid ? "$path/$vmid" : $path;
 332 }
 333
 334 sub get_iso_dir {
 335     my ($cfg, $storeid) = @_;
 336
 337     my $scfg = storage_config($cfg, $storeid);
 338     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 339
 340     return $plugin->get_subdir($scfg, 'iso');
 341 }
 342
 343 sub get_vztmpl_dir {
 344     my ($cfg, $storeid) = @_;
 345
 346     my $scfg = storage_config($cfg, $storeid);
 347     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 348
 349     return $plugin->get_subdir($scfg, 'vztmpl');
 350 }
 351
 352 sub get_backup_dir {
 353     my ($cfg, $storeid) = @_;
 354
 355     my $scfg = storage_config($cfg, $storeid);
 356     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 357
 358     return $plugin->get_subdir($scfg, 'backup');
 359 }
 360
 361 # library implementation
 362
 363 sub parse_vmid {
 364     my $vmid = shift;
 365
 366     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 367
 368     return int($vmid);
 369 }
 370
 371 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 372 # clone -> base reference is not encoded in the volume ID.
 373 # see note in PVE::Storage::LvmThinPlugin for details.
 374 sub parse_volname {
 375     my ($cfg, $volid) = @_;
 376
 377     my ($storeid, $volname) = parse_volume_id($volid);
 378
 379     my $scfg = storage_config($cfg, $storeid);
 380
 381     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 382
 383     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 384
 385     return $plugin->parse_volname($volname);
 386 }
 387
 388 sub parse_volume_id {
 389     my ($volid, $noerr) = @_;
 390
 391     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 392 }
 393
 394 # test if we have read access to volid
 395 sub check_volume_access {
 396     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 397
 398     my ($sid, $volname) = parse_volume_id($volid, 1);
 399     if ($sid) {
 400         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 401         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 402             # we simply allow access
 403         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 404             # we are owner - allow access
 405         } elsif ($vtype eq 'backup' && $ownervm) {
 406             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 407             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 408         } else {
 409             # allow if we are Datastore administrator
 410             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 411         }
 412     } else {
 413         die "Only root can pass arbitrary filesystem paths."
 414             if $user ne 'root@pam';
 415     }
 416
 417     return undef;
 418 }
 419
 420 my $volume_is_base_and_used__no_lock = sub {
 421     my ($scfg, $storeid, $plugin, $volname) = @_;
 422
 423     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 424         $plugin->parse_volname($volname);
 425
 426     if ($isBase) {
 427         my $vollist = $plugin->list_images($storeid, $scfg);
 428         foreach my $info (@$vollist) {
 429             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 430             my $basename = undef;
 431             my $basevmid = undef;
 432
 433             eval{
 434                 (undef, undef, undef, $basename, $basevmid) =
 435                     $plugin->parse_volname($tmpvolname);
 436             };
 437
 438             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 439                 return 1;
 440             }
 441         }
 442     }
 443     return 0;
 444 };
 445
 446 # NOTE: this check does not work for LVM-thin, where the clone -> base
 447 # reference is not encoded in the volume ID.
 448 # see note in PVE::Storage::LvmThinPlugin for details.
 449 sub volume_is_base_and_used {
 450     my ($cfg, $volid) = @_;
 451
 452     my ($storeid, $volname) = parse_volume_id($volid);
 453     my $scfg = storage_config($cfg, $storeid);
 454     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 455
 456     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 457         return &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 458     });
 459 }
 460
 461 # try to map a filesystem path to a volume identifier
 462 sub path_to_volume_id {
 463     my ($cfg, $path) = @_;
 464
 465     my $ids = $cfg->{ids};
 466
 467     my ($sid, $volname) = parse_volume_id($path, 1);
 468     if ($sid) {
 469         if (my $scfg = $ids->{$sid}) {
 470             if ($scfg->{path}) {
 471                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 472                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 473                 return ($vtype, $path);
 474             }
 475         }
 476         return ('');
 477     }
 478
 479     # Note: abs_path() return undef if $path doesn not exist
 480     # for example when nfs storage is not mounted
 481     $path = abs_path($path) || $path;
 482
 483     foreach my $sid (keys %$ids) {
 484         my $scfg = $ids->{$sid};
 485         next if !$scfg->{path};
 486         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 487         my $imagedir = $plugin->get_subdir($scfg, 'images');
 488         my $isodir = $plugin->get_subdir($scfg, 'iso');
 489         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 490         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 491         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 492
 493         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 494             my $vmid = $1;
 495             my $name = $2;
 496
 497             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 498             foreach my $info (@$vollist) {
 499                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 500                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 501                 if ($volpath eq $path) {
 502                     return ('images', $info->{volid});
 503                 }
 504             }
 505         } elsif ($path =~ m!^$isodir/([^/]+\.[Ii][Ss][Oo])$!) {
 506             my $name = $1;
 507             return ('iso', "$sid:iso/$name");
 508         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 509             my $name = $1;
 510             return ('vztmpl', "$sid:vztmpl/$name");
 511         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 512             my $vmid = $1;
 513             return ('rootdir', "$sid:rootdir/$vmid");
 514         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 515             my $name = $1;
 516             return ('iso', "$sid:backup/$name");
 517         }
 518     }
 519
 520     # can't map path to volume id
 521     return ('');
 522 }
 523
 524 sub path {
 525     my ($cfg, $volid, $snapname) = @_;
 526
 527     my ($storeid, $volname) = parse_volume_id($volid);
 528
 529     my $scfg = storage_config($cfg, $storeid);
 530
 531     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 532     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 533     return wantarray ? ($path, $owner, $vtype) : $path;
 534 }
 535
 536 sub abs_filesystem_path {
 537     my ($cfg, $volid) = @_;
 538
 539     my $path;
 540     if (PVE::Storage::parse_volume_id ($volid, 1)) {
 541         PVE::Storage::activate_volumes($cfg, [ $volid ]);
 542         $path = PVE::Storage::path($cfg, $volid);
 543     } else {
 544         if (-f $volid) {
 545             my $abspath = abs_path($volid);
 546             if ($abspath && $abspath =~ m|^(/.+)$|) {
 547                 $path = $1; # untaint any path
 548             }
 549         }
 550     }
 551
 552     die "can't find file '$volid'\n" if !($path && -f $path);
 553
 554     return $path;
 555 }
 556
 557 sub storage_migrate {
 558     my ($cfg, $volid, $target_sshinfo, $target_storeid, $target_volname, $base_snapshot, $snapshot, $ratelimit_bps, $insecure, $with_snapshots, $logfunc) = @_;
 559
 560     my ($storeid, $volname) = parse_volume_id($volid);
 561     $target_volname = $volname if !$target_volname;
 562
 563     my $scfg = storage_config($cfg, $storeid);
 564
 565     # no need to migrate shared content
 566     return if $storeid eq $target_storeid && $scfg->{shared};
 567
 568     my $tcfg = storage_config($cfg, $target_storeid);
 569
 570     my $target_volid = "${target_storeid}:${target_volname}";
 571
 572     my $target_ip = $target_sshinfo->{ip};
 573     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_sshinfo->{name}'";
 574
 575     my $ssh = PVE::Cluster::ssh_info_to_command($target_sshinfo);
 576     my $ssh_base = PVE::Cluster::ssh_info_to_command_base($target_sshinfo);
 577     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 578
 579     my @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ])
 580         if defined($ratelimit_bps);
 581
 582     my $migration_snapshot;
 583     if (!defined($snapshot)) {
 584         if ($scfg->{type} eq 'zfspool') {
 585             $migration_snapshot = 1;
 586             $snapshot = '__migration__';
 587         }
 588     }
 589
 590     my @formats = volume_transfer_formats($cfg, $volid, $volid, $snapshot, $base_snapshot, $with_snapshots);
 591     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 592     my $format = $formats[0];
 593
 594     my @insecurecmd;
 595     if ($insecure) {
 596         @insecurecmd = ('pvecm', 'mtunnel', '-run-command', 1);
 597         if (my $network = $target_sshinfo->{network}) {
 598             push @insecurecmd, '-migration_network', $network;
 599         }
 600     }
 601
 602     $with_snapshots = $with_snapshots ? 1 : 0; # sanitize for passing as cli parameter
 603     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 604     my $recv = [@$ssh, @insecurecmd, '--', 'pvesm', 'import', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 605     if (defined($snapshot)) {
 606         push @$send, '-snapshot', $snapshot
 607     }
 608     if ($migration_snapshot) {
 609         push @$recv, '-delete-snapshot', $snapshot;
 610     }
 611
 612     if (defined($base_snapshot)) {
 613         # Check if the snapshot exists on the remote side:
 614         push @$send, '-base', $base_snapshot;
 615         push @$recv, '-base', $base_snapshot;
 616     }
 617
 618     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 619     eval {
 620         if ($insecure) {
 621             open(my $info, '-|', @$recv)
 622                 or die "receive command failed: $!\n";
 623             my ($ip) = <$info> =~ /^($PVE::Tools::IPRE)$/ or die "no tunnel IP received\n";
 624             my ($port) = <$info> =~ /^(\d+)$/ or die "no tunnel port received\n";
 625             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 626                 or die "failed to connect to tunnel at $ip:$port\n";
 627             # we won't be reading from the socket
 628             shutdown($socket, 0);
 629             run_command([$send, @cstream], output => '>&'.fileno($socket));
 630             # don't close the connection entirely otherwise the receiving end
 631             # might not get all buffered data (and fails with 'connection reset by peer')
 632             shutdown($socket, 1);
 633             1 while <$info>; # wait for the remote process to finish
 634             # now close the socket
 635             close($socket);
 636             if (!close($info)) { # does waitpid()
 637                 die "import failed: $!\n" if $!;
 638                 die "import failed: exit code ".($?>>8)."\n";
 639             }
 640         } else {
 641             run_command([$send, @cstream, $recv], logfunc => $logfunc);
 642         }
 643     };
 644     my $err = $@;
 645     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 646     if ($migration_snapshot) {
 647         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 648         warn "could not remove source snapshot: $@\n" if $@;
 649     }
 650     die $err if $err;
 651 }
 652
 653 sub vdisk_clone {
 654     my ($cfg, $volid, $vmid, $snap) = @_;
 655
 656     my ($storeid, $volname) = parse_volume_id($volid);
 657
 658     my $scfg = storage_config($cfg, $storeid);
 659
 660     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 661
 662     activate_storage($cfg, $storeid);
 663
 664     # lock shared storage
 665     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 666         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 667         return "$storeid:$volname";
 668     });
 669 }
 670
 671 sub vdisk_create_base {
 672     my ($cfg, $volid) = @_;
 673
 674     my ($storeid, $volname) = parse_volume_id($volid);
 675
 676     my $scfg = storage_config($cfg, $storeid);
 677
 678     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 679
 680     activate_storage($cfg, $storeid);
 681
 682     # lock shared storage
 683     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 684         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 685         return "$storeid:$volname";
 686     });
 687 }
 688
 689 sub map_volume {
 690     my ($cfg, $volid, $snapname) = @_;
 691
 692     my ($storeid, $volname) = parse_volume_id($volid);
 693
 694     my $scfg = storage_config($cfg, $storeid);
 695
 696     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 697
 698     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 699 }
 700
 701 sub unmap_volume {
 702     my ($cfg, $volid, $snapname) = @_;
 703
 704     my ($storeid, $volname) = parse_volume_id($volid);
 705
 706     my $scfg = storage_config($cfg, $storeid);
 707
 708     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 709
 710     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 711 }
 712
 713 sub vdisk_alloc {
 714     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 715
 716     die "no storage ID specified\n" if !$storeid;
 717
 718     PVE::JSONSchema::parse_storage_id($storeid);
 719
 720     my $scfg = storage_config($cfg, $storeid);
 721
 722     die "no VMID specified\n" if !$vmid;
 723
 724     $vmid = parse_vmid($vmid);
 725
 726     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 727
 728     $fmt = $defformat if !$fmt;
 729
 730     activate_storage($cfg, $storeid);
 731
 732     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 733
 734     # lock shared storage
 735     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 736         my $old_umask = umask(umask|0037);
 737         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 738         my $err = $@;
 739         umask $old_umask;
 740         die $err if $err;
 741         return "$storeid:$volname";
 742     });
 743 }
 744
 745 sub vdisk_free {
 746     my ($cfg, $volid) = @_;
 747
 748     my ($storeid, $volname) = parse_volume_id($volid);
 749     my $scfg = storage_config($cfg, $storeid);
 750     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 751
 752     activate_storage($cfg, $storeid);
 753
 754     my $cleanup_worker;
 755
 756     # lock shared storage
 757     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 758         # LVM-thin allows deletion of still referenced base volumes!
 759         die "base volume '$volname' is still in use by linked clones\n"
 760             if &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 761
 762         my (undef, undef, undef, undef, undef, $isBase, $format) =
 763             $plugin->parse_volname($volname);
 764         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 765     });
 766
 767     return if !$cleanup_worker;
 768
 769     my $rpcenv = PVE::RPCEnvironment::get();
 770     my $authuser = $rpcenv->get_user();
 771
 772     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 773 }
 774
 775 #list iso or openvz template ($tt = <iso|vztmpl|backup>)
 776 sub template_list {
 777     my ($cfg, $storeid, $tt) = @_;
 778
 779     die "unknown template type '$tt'\n"
 780         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup');
 781
 782     my $ids = $cfg->{ids};
 783
 784     storage_check_enabled($cfg, $storeid) if ($storeid);
 785
 786     my $res = {};
 787
 788     # query the storage
 789
 790     foreach my $sid (keys %$ids) {
 791         next if $storeid && $storeid ne $sid;
 792
 793         my $scfg = $ids->{$sid};
 794         my $type = $scfg->{type};
 795
 796         next if !storage_check_enabled($cfg, $sid, undef, 1);
 797
 798         next if $tt eq 'iso' && !$scfg->{content}->{iso};
 799         next if $tt eq 'vztmpl' && !$scfg->{content}->{vztmpl};
 800         next if $tt eq 'backup' && !$scfg->{content}->{backup};
 801
 802         activate_storage($cfg, $sid);
 803
 804         if ($scfg->{path}) {
 805             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 806
 807             my $path = $plugin->get_subdir($scfg, $tt);
 808
 809             foreach my $fn (<$path/*>) {
 810
 811                 my $info;
 812
 813                 if ($tt eq 'iso') {
 814                     next if $fn !~ m!/([^/]+\.[Ii][Ss][Oo])$!;
 815
 816                     $info = { volid => "$sid:iso/$1", format => 'iso' };
 817
 818                 } elsif ($tt eq 'vztmpl') {
 819                     next if $fn !~ m!/([^/]+\.tar\.([gx]z))$!;
 820
 821                     $info = { volid => "$sid:vztmpl/$1", format => "t$2" };
 822
 823                 } elsif ($tt eq 'backup') {
 824                     next if $fn !~ m!/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!;
 825
 826                     $info = { volid => "$sid:backup/$1", format => $2 };
 827                 }
 828
 829                 $info->{size} = -s $fn;
 830
 831                 push @{$res->{$sid}}, $info;
 832             }
 833
 834         }
 835
 836         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 837     }
 838
 839     return $res;
 840 }
 841
 842
 843 sub vdisk_list {
 844     my ($cfg, $storeid, $vmid, $vollist) = @_;
 845
 846     my $ids = $cfg->{ids};
 847
 848     storage_check_enabled($cfg, $storeid) if ($storeid);
 849
 850     my $res = {};
 851
 852     # prepare/activate/refresh all storages
 853
 854     my $storage_list = [];
 855     if ($vollist) {
 856         foreach my $volid (@$vollist) {
 857             my ($sid, undef) = parse_volume_id($volid);
 858             next if !defined($ids->{$sid});
 859             next if !storage_check_enabled($cfg, $sid, undef, 1);
 860             push @$storage_list, $sid;
 861         }
 862     } else {
 863         foreach my $sid (keys %$ids) {
 864             next if $storeid && $storeid ne $sid;
 865             next if !storage_check_enabled($cfg, $sid, undef, 1);
 866             push @$storage_list, $sid;
 867         }
 868     }
 869
 870     my $cache = {};
 871
 872     activate_storage_list($cfg, $storage_list, $cache);
 873
 874     foreach my $sid (keys %$ids) {
 875         next if $storeid && $storeid ne $sid;
 876         next if !storage_check_enabled($cfg, $sid, undef, 1);
 877
 878         my $scfg = $ids->{$sid};
 879         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 880         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 881         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 882     }
 883
 884     return $res;
 885 }
 886
 887 sub volume_list {
 888     my ($cfg, $storeid, $vmid, $content) = @_;
 889
 890     my @ctypes = qw(images vztmpl iso backup);
 891
 892     my $cts = $content ? [ $content ] : [ @ctypes ];
 893
 894     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 895
 896     my $res = [];
 897     foreach my $ct (@$cts) {
 898         my $data;
 899         if ($ct eq 'images') {
 900             $data = vdisk_list($cfg, $storeid, $vmid);
 901         } elsif ($ct eq 'iso' && !defined($vmid)) {
 902             $data = template_list($cfg, $storeid, 'iso');
 903         } elsif ($ct eq 'vztmpl'&& !defined($vmid)) {
 904             $data = template_list ($cfg, $storeid, 'vztmpl');
 905         } elsif ($ct eq 'backup') {
 906             $data = template_list ($cfg, $storeid, 'backup');
 907             foreach my $item (@{$data->{$storeid}}) {
 908                 if (defined($vmid)) {
 909                     @{$data->{$storeid}} = grep { $_->{volid} =~ m/\S+-$vmid-\S+/ } @{$data->{$storeid}};
 910                 }
 911             }
 912         }
 913
 914         next if !$data || !$data->{$storeid};
 915
 916         foreach my $item (@{$data->{$storeid}}) {
 917             $item->{content} = $ct;
 918             push @$res, $item;
 919         }
 920     }
 921
 922     return $res;
 923 }
 924
 925 sub uevent_seqnum {
 926
 927     my $filename = "/sys/kernel/uevent_seqnum";
 928
 929     my $seqnum = 0;
 930     if (my $fh = IO::File->new($filename, "r")) {
 931         my $line = <$fh>;
 932         if ($line =~ m/^(\d+)$/) {
 933             $seqnum = int($1);
 934         }
 935         close ($fh);
 936     }
 937     return $seqnum;
 938 }
 939
 940 sub activate_storage {
 941     my ($cfg, $storeid, $cache) = @_;
 942
 943     $cache = {} if !$cache;
 944
 945     my $scfg = storage_check_enabled($cfg, $storeid);
 946
 947     return if $cache->{activated}->{$storeid};
 948
 949     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 950
 951     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 952
 953     if ($scfg->{base}) {
 954         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 955         activate_storage($cfg, $baseid, $cache);
 956     }
 957
 958     if (!$plugin->check_connection($storeid, $scfg)) {
 959         die "storage '$storeid' is not online\n";
 960     }
 961
 962     $plugin->activate_storage($storeid, $scfg, $cache);
 963
 964     my $newseq = uevent_seqnum ();
 965
 966     # only call udevsettle if there are events
 967     if ($newseq > $cache->{uevent_seqnum}) {
 968         my $timeout = 30;
 969         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
 970         $cache->{uevent_seqnum} = $newseq;
 971     }
 972
 973     $cache->{activated}->{$storeid} = 1;
 974 }
 975
 976 sub activate_storage_list {
 977     my ($cfg, $storeid_list, $cache) = @_;
 978
 979     $cache = {} if !$cache;
 980
 981     foreach my $storeid (@$storeid_list) {
 982         activate_storage($cfg, $storeid, $cache);
 983     }
 984 }
 985
 986 sub deactivate_storage {
 987     my ($cfg, $storeid) = @_;
 988
 989     my $scfg = storage_config ($cfg, $storeid);
 990     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 991
 992     my $cache = {};
 993     $plugin->deactivate_storage($storeid, $scfg, $cache);
 994 }
 995
 996 sub activate_volumes {
 997     my ($cfg, $vollist, $snapname) = @_;
 998
 999     return if !($vollist && scalar(@$vollist));
1000
1001     my $storagehash = {};
1002     foreach my $volid (@$vollist) {
1003         my ($storeid, undef) = parse_volume_id($volid);
1004         $storagehash->{$storeid} = 1;
1005     }
1006
1007     my $cache = {};
1008
1009     activate_storage_list($cfg, [keys %$storagehash], $cache);
1010
1011     foreach my $volid (@$vollist) {
1012         my ($storeid, $volname) = parse_volume_id($volid);
1013         my $scfg = storage_config($cfg, $storeid);
1014         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1015         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
1016     }
1017 }
1018
1019 sub deactivate_volumes {
1020     my ($cfg, $vollist, $snapname) = @_;
1021
1022     return if !($vollist && scalar(@$vollist));
1023
1024     my $cache = {};
1025
1026     my @errlist = ();
1027     foreach my $volid (@$vollist) {
1028         my ($storeid, $volname) = parse_volume_id($volid);
1029
1030         my $scfg = storage_config($cfg, $storeid);
1031         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1032
1033         eval {
1034             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
1035         };
1036         if (my $err = $@) {
1037             warn $err;
1038             push @errlist, $volid;
1039         }
1040     }
1041
1042     die "volume deactivation failed: " . join(' ', @errlist)
1043         if scalar(@errlist);
1044 }
1045
1046 sub storage_info {
1047     my ($cfg, $content, $includeformat) = @_;
1048
1049     my $ids = $cfg->{ids};
1050
1051     my $info = {};
1052
1053     my @ctypes = PVE::Tools::split_list($content);
1054
1055     my $slist = [];
1056     foreach my $storeid (keys %$ids) {
1057         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1058
1059         if (defined($content)) {
1060             my $want_ctype = 0;
1061             foreach my $ctype (@ctypes) {
1062                 if ($ids->{$storeid}->{content}->{$ctype}) {
1063                     $want_ctype = 1;
1064                     last;
1065                 }
1066             }
1067             next if !$want_ctype || !$storage_enabled;
1068         }
1069
1070         my $type = $ids->{$storeid}->{type};
1071
1072         $info->{$storeid} = {
1073             type => $type,
1074             total => 0,
1075             avail => 0,
1076             used => 0,
1077             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1078             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1079             active => 0,
1080             enabled => $storage_enabled ? 1 : 0,
1081         };
1082
1083         push @$slist, $storeid;
1084     }
1085
1086     my $cache = {};
1087
1088     foreach my $storeid (keys %$ids) {
1089         my $scfg = $ids->{$storeid};
1090
1091         next if !$info->{$storeid};
1092         next if !$info->{$storeid}->{enabled};
1093
1094         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1095         if ($includeformat) {
1096             my $pd = $plugin->plugindata();
1097             $info->{$storeid}->{format} = $pd->{format}
1098                 if $pd->{format};
1099             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1100                 if $pd->{select_existing};
1101         }
1102
1103         eval { activate_storage($cfg, $storeid, $cache); };
1104         if (my $err = $@) {
1105             warn $err;
1106             next;
1107         }
1108
1109         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1110         warn $@ if $@;
1111         next if !$active;
1112         $info->{$storeid}->{total} = int($total);
1113         $info->{$storeid}->{avail} = int($avail);
1114         $info->{$storeid}->{used} = int($used);
1115         $info->{$storeid}->{active} = $active;
1116     }
1117
1118     return $info;
1119 }
1120
1121 sub resolv_server {
1122     my ($server) = @_;
1123
1124     my ($packed_ip, $family);
1125     eval {
1126         my @res = PVE::Tools::getaddrinfo_all($server);
1127         $family = $res[0]->{family};
1128         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1129     };
1130     if (defined $packed_ip) {
1131         return Socket::inet_ntop($family, $packed_ip);
1132     }
1133     return undef;
1134 }
1135
1136 sub scan_nfs {
1137     my ($server_in) = @_;
1138
1139     my $server;
1140     if (!($server = resolv_server ($server_in))) {
1141         die "unable to resolve address for server '${server_in}'\n";
1142     }
1143
1144     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1145
1146     my $res = {};
1147     run_command($cmd, outfunc => sub {
1148         my $line = shift;
1149
1150         # note: howto handle white spaces in export path??
1151         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1152             $res->{$1} = $2;
1153         }
1154     });
1155
1156     return $res;
1157 }
1158
1159 sub scan_cifs {
1160     my ($server_in, $user, $password, $domain) = @_;
1161
1162     my $server;
1163     if (!($server = resolv_server ($server_in))) {
1164         die "unable to resolve address for server '${server_in}'\n";
1165     }
1166
1167     # we support only Windows grater than 2012 cifsscan so use smb3
1168     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1169     if (defined($user)) {
1170         die "password is required" if !defined($password);
1171         push @$cmd, '-U', "$user\%$password";
1172         push @$cmd, '-W', $domain if defined($domain);
1173     } else {
1174         push @$cmd, '-N';
1175     }
1176
1177     my $res = {};
1178     run_command($cmd,
1179                 outfunc => sub {
1180                     my $line = shift;
1181                     if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1182                         $res->{$1} = $2;
1183                     } elsif ($line =~ m/(NT_STATUS_(\S*))/) {
1184                         $res->{$1} = '';
1185                     }
1186                 },
1187                 errfunc => sub {},
1188                 noerr => 1
1189     );
1190
1191     return $res;
1192 }
1193
1194 sub scan_zfs {
1195
1196     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-H', '-o', 'name,avail,used'];
1197
1198     my $res = [];
1199     run_command($cmd, outfunc => sub {
1200         my $line = shift;
1201
1202         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1203             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1204             my $size = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($size_str);
1205             my $used = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($used_str);
1206             # ignore subvolumes generated by our ZFSPoolPlugin
1207             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1208             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1209             push @$res, { pool => $pool, size => $size, free => $size-$used };
1210         }
1211     });
1212
1213     return $res;
1214 }
1215
1216 sub resolv_portal {
1217     my ($portal, $noerr) = @_;
1218
1219     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1220     if ($server) {
1221         if (my $ip = resolv_server($server)) {
1222             $server = $ip;
1223             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1224             return $port ? "$server:$port" : $server;
1225         }
1226     }
1227     return undef if $noerr;
1228
1229     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1230 }
1231
1232
1233 sub scan_iscsi {
1234     my ($portal_in) = @_;
1235
1236     my $portal;
1237     if (!($portal = resolv_portal($portal_in))) {
1238         die "unable to parse/resolve portal address '${portal_in}'\n";
1239     }
1240
1241     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1242 }
1243
1244 sub storage_default_format {
1245     my ($cfg, $storeid) = @_;
1246
1247     my $scfg = storage_config ($cfg, $storeid);
1248
1249     return PVE::Storage::Plugin::default_format($scfg);
1250 }
1251
1252 sub vgroup_is_used {
1253     my ($cfg, $vgname) = @_;
1254
1255     foreach my $storeid (keys %{$cfg->{ids}}) {
1256         my $scfg = storage_config($cfg, $storeid);
1257         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1258             return 1;
1259         }
1260     }
1261
1262     return undef;
1263 }
1264
1265 sub target_is_used {
1266     my ($cfg, $target) = @_;
1267
1268     foreach my $storeid (keys %{$cfg->{ids}}) {
1269         my $scfg = storage_config($cfg, $storeid);
1270         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1271             return 1;
1272         }
1273     }
1274
1275     return undef;
1276 }
1277
1278 sub volume_is_used {
1279     my ($cfg, $volid) = @_;
1280
1281     foreach my $storeid (keys %{$cfg->{ids}}) {
1282         my $scfg = storage_config($cfg, $storeid);
1283         if ($scfg->{base} && $scfg->{base} eq $volid) {
1284             return 1;
1285         }
1286     }
1287
1288     return undef;
1289 }
1290
1291 sub storage_is_used {
1292     my ($cfg, $storeid) = @_;
1293
1294     foreach my $sid (keys %{$cfg->{ids}}) {
1295         my $scfg = storage_config($cfg, $sid);
1296         next if !$scfg->{base};
1297         my ($st) = parse_volume_id($scfg->{base});
1298         return 1 if $st && $st eq $storeid;
1299     }
1300
1301     return undef;
1302 }
1303
1304 sub foreach_volid {
1305     my ($list, $func) = @_;
1306
1307     return if !$list;
1308
1309     foreach my $sid (keys %$list) {
1310        foreach my $info (@{$list->{$sid}}) {
1311            my $volid = $info->{volid};
1312            my ($sid1, $volname) = parse_volume_id($volid, 1);
1313            if ($sid1 && $sid1 eq $sid) {
1314                &$func ($volid, $sid, $info);
1315            } else {
1316                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1317            }
1318        }
1319     }
1320 }
1321
1322 sub extract_vzdump_config_tar {
1323     my ($archive, $conf_re) = @_;
1324
1325     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1326
1327     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1328        die "unable to open file '$archive'\n";
1329
1330     my $file;
1331     while (defined($file = <$fh>)) {
1332         if ($file =~ $conf_re) {
1333             $file = $1; # untaint
1334             last;
1335         }
1336     }
1337
1338     kill 15, $pid;
1339     waitpid $pid, 0;
1340     close $fh;
1341
1342     die "ERROR: archive contains no configuration file\n" if !$file;
1343     chomp $file;
1344
1345     my $raw = '';
1346     my $out = sub {
1347         my $output = shift;
1348         $raw .= "$output\n";
1349     };
1350
1351     PVE::Tools::run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1352
1353     return wantarray ? ($raw, $file) : $raw;
1354 }
1355
1356 sub extract_vzdump_config_vma {
1357     my ($archive, $comp) = @_;
1358
1359     my $cmd;
1360     my $raw = '';
1361     my $out = sub {
1362         my $output = shift;
1363         $raw .= "$output\n";
1364     };
1365
1366
1367     if ($comp) {
1368         my $uncomp;
1369         if ($comp eq 'gz') {
1370             $uncomp = ["zcat", $archive];
1371         } elsif ($comp eq 'lzo') {
1372             $uncomp = ["lzop", "-d", "-c", $archive];
1373         } else {
1374             die "unknown compression method '$comp'\n";
1375         }
1376         $cmd = [$uncomp, ["vma", "config", "-"]];
1377
1378         # in some cases, lzop/zcat exits with 1 when its stdout pipe is
1379         # closed early by vma, detect this and ignore the exit code later
1380         my $broken_pipe;
1381         my $errstring;
1382         my $err = sub {
1383             my $output = shift;
1384             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/) {
1385                 $broken_pipe = 1;
1386             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1387                 $errstring = "Failed to extract config from VMA archive: $output\n";
1388             }
1389         };
1390
1391         # in other cases, the pipeline will exit with exit code 141
1392         # because of the broken pipe, handle / ignore this as well
1393         my $rc;
1394         eval {
1395             $rc = PVE::Tools::run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1);
1396         };
1397         my $rerr = $@;
1398
1399         # use exit code if no stderr output and not just broken pipe
1400         if (!$errstring && !$broken_pipe && $rc != 0 && $rc != 141) {
1401             die "$rerr\n" if $rerr;
1402             die "config extraction failed with exit code $rc\n";
1403         }
1404         die "$errstring\n" if $errstring;
1405     } else {
1406         # simple case without compression and weird piping behaviour
1407         PVE::Tools::run_command(["vma", "config", $archive], outfunc => $out);
1408     }
1409
1410     return wantarray ? ($raw, undef) : $raw;
1411 }
1412
1413 sub extract_vzdump_config {
1414     my ($cfg, $volid) = @_;
1415
1416     my $archive = abs_filesystem_path($cfg, $volid);
1417
1418     if ($volid =~ /vzdump-(lxc|openvz)-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|(tar(\.(gz|lzo))?))$/) {
1419         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1420     } elsif ($volid =~ /vzdump-qemu-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|((tar|vma)(\.(gz|lzo))?))$/) {
1421         my $format;
1422         my $comp;
1423         if ($7 eq 'tgz') {
1424             $format = 'tar';
1425             $comp = 'gz';
1426         } else {
1427             $format = $9;
1428             $comp = $11 if defined($11);
1429         }
1430
1431         if ($format eq 'tar') {
1432             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1433         } else {
1434             return extract_vzdump_config_vma($archive, $comp);
1435         }
1436     } else {
1437         die "cannot determine backup guest type for backup archive '$volid'\n";
1438     }
1439 }
1440
1441 sub volume_export {
1442     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1443
1444     my ($storeid, $volname) = parse_volume_id($volid, 1);
1445     die "cannot export volume '$volid'\n" if !$storeid;
1446     my $scfg = storage_config($cfg, $storeid);
1447     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1448     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1449                                   $snapshot, $base_snapshot, $with_snapshots);
1450 }
1451
1452 sub volume_import {
1453     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots) = @_;
1454
1455     my ($storeid, $volname) = parse_volume_id($volid, 1);
1456     die "cannot import into volume '$volid'\n" if !$storeid;
1457     my $scfg = storage_config($cfg, $storeid);
1458     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1459     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1460                                   $base_snapshot, $with_snapshots);
1461 }
1462
1463 sub volume_export_formats {
1464     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1465
1466     my ($storeid, $volname) = parse_volume_id($volid, 1);
1467     return if !$storeid;
1468     my $scfg = storage_config($cfg, $storeid);
1469     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1470     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1471                                           $snapshot, $base_snapshot,
1472                                           $with_snapshots);
1473 }
1474
1475 sub volume_import_formats {
1476     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1477
1478     my ($storeid, $volname) = parse_volume_id($volid, 1);
1479     return if !$storeid;
1480     my $scfg = storage_config($cfg, $storeid);
1481     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1482     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1483                                           $base_snapshot, $with_snapshots);
1484 }
1485
1486 sub volume_transfer_formats {
1487     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1488     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1489     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1490     my %import_hash = map { $_ => 1 } @import_formats;
1491     my @common = grep { $import_hash{$_} } @export_formats;
1492     return @common;
1493 }
1494
1495 # bash completion helper
1496
1497 sub complete_storage {
1498     my ($cmdname, $pname, $cvalue) = @_;
1499
1500     my $cfg = PVE::Storage::config();
1501
1502     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1503 }
1504
1505 sub complete_storage_enabled {
1506     my ($cmdname, $pname, $cvalue) = @_;
1507
1508     my $res = [];
1509
1510     my $cfg = PVE::Storage::config();
1511     foreach my $sid (keys %{$cfg->{ids}}) {
1512         next if !storage_check_enabled($cfg, $sid, undef, 1);
1513         push @$res, $sid;
1514     }
1515     return $res;
1516 }
1517
1518 sub complete_content_type {
1519     my ($cmdname, $pname, $cvalue) = @_;
1520
1521     return [qw(rootdir images vztmpl iso backup)];
1522 }
1523
1524 sub complete_volume {
1525     my ($cmdname, $pname, $cvalue) = @_;
1526
1527     my $cfg = config();
1528
1529     my $storage_list = complete_storage_enabled();
1530
1531     if ($cvalue =~ m/^([^:]+):/) {
1532         $storage_list = [ $1 ];
1533     } else {
1534         if (scalar(@$storage_list) > 1) {
1535             # only list storage IDs to avoid large listings
1536             my $res = [];
1537             foreach my $storeid (@$storage_list) {
1538                 # Hack: simply return 2 artificial values, so that
1539                 # completions does not finish
1540                 push @$res, "$storeid:volname", "$storeid:...";
1541             }
1542             return $res;
1543         }
1544     }
1545
1546     my $res = [];
1547     foreach my $storeid (@$storage_list) {
1548         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1549
1550         foreach my $item (@$vollist) {
1551             push @$res, $item->{volid};
1552         }
1553     }
1554
1555     return $res;
1556 }
1557
1558 # Various io-heavy operations require io/bandwidth limits which can be
1559 # configured on multiple levels: The global defaults in datacenter.cfg, and
1560 # per-storage overrides. When we want to do a restore from storage A to storage
1561 # B, we should take the smaller limit defined for storages A and B, and if no
1562 # such limit was specified, use the one from datacenter.cfg.
1563 sub get_bandwidth_limit {
1564     my ($operation, $storage_list, $override) = @_;
1565
1566     # called for each limit (global, per-storage) with the 'default' and the
1567     # $operation limit and should udpate $override for every limit affecting
1568     # us.
1569     my $use_global_limits = 0;
1570     my $apply_limit = sub {
1571         my ($bwlimit) = @_;
1572         if (defined($bwlimit)) {
1573             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1574             my $limit = $limits->{$operation} // $limits->{default};
1575             if (defined($limit)) {
1576                 if (!$override || $limit < $override) {
1577                     $override = $limit;
1578                 }
1579                 return;
1580             }
1581         }
1582         # If there was no applicable limit, try to apply the global ones.
1583         $use_global_limits = 1;
1584     };
1585
1586     my ($rpcenv, $authuser);
1587     if (defined($override)) {
1588         $rpcenv = PVE::RPCEnvironment->get();
1589         $authuser = $rpcenv->get_user();
1590     }
1591
1592     # Apply per-storage limits - if there are storages involved.
1593     if (@$storage_list) {
1594         my $config = config();
1595
1596         # The Datastore.Allocate permission allows us to modify the per-storage
1597         # limits, therefore it also allows us to override them.
1598         # Since we have most likely multiple storages to check, do a quick check on
1599         # the general '/storage' path to see if we can skip the checks entirely:
1600         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1601
1602         my %done;
1603         foreach my $storage (@$storage_list) {
1604             # Avoid duplicate checks:
1605             next if $done{$storage};
1606             $done{$storage} = 1;
1607
1608             # Otherwise we may still have individual /storage/$ID permissions:
1609             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1610                 # And if not: apply the limits.
1611                 my $storecfg = storage_config($config, $storage);
1612                 $apply_limit->($storecfg->{bwlimit});
1613             }
1614         }
1615
1616         # Storage limits take precedence over the datacenter defaults, so if
1617         # a limit was applied:
1618         return $override if !$use_global_limits;
1619     }
1620
1621     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1622     # global default limits.
1623     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1624         # So if we cannot modify global limits, apply them to our currently
1625         # requested override.
1626         my $dc = cfs_read_file('datacenter.cfg');
1627         $apply_limit->($dc->{bwlimit});
1628     }
1629
1630     return $override;
1631 }
1632
1633 # checks if the storage id is available and dies if not
1634 sub assert_sid_unused {
1635     my ($sid) = @_;
1636
1637     my $cfg = config();
1638     if (my $scfg = storage_config($cfg, $sid, 1)) {
1639         die "storage ID '$sid' already defined\n";
1640     }
1641
1642     return undef;
1643 }
1644
1645 1;