PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use File::Basename;
  12 use File::Path;
  13 use Cwd 'abs_path';
  14 use Socket;
  15
  16 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  17 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  18 use PVE::Exception qw(raise_param_exc);
  19 use PVE::JSONSchema;
  20 use PVE::INotify;
  21 use PVE::RPCEnvironment;
  22
  23 use PVE::Storage::Plugin;
  24 use PVE::Storage::DirPlugin;
  25 use PVE::Storage::LVMPlugin;
  26 use PVE::Storage::LvmThinPlugin;
  27 use PVE::Storage::NFSPlugin;
  28 use PVE::Storage::CIFSPlugin;
  29 use PVE::Storage::ISCSIPlugin;
  30 use PVE::Storage::RBDPlugin;
  31 use PVE::Storage::CephFSPlugin;
  32 use PVE::Storage::ISCSIDirectPlugin;
  33 use PVE::Storage::GlusterfsPlugin;
  34 use PVE::Storage::ZFSPoolPlugin;
  35 use PVE::Storage::ZFSPlugin;
  36 use PVE::Storage::DRBDPlugin;
  37
  38 # Storage API version. Icrement it on changes in storage API interface.
  39 use constant APIVER => 2;
  40 # Age is the number of versions we're backward compatible with.
  41 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  42 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  43 use constant APIAGE => 1;
  44
  45 # load standard plugins
  46 PVE::Storage::DirPlugin->register();
  47 PVE::Storage::LVMPlugin->register();
  48 PVE::Storage::LvmThinPlugin->register();
  49 PVE::Storage::NFSPlugin->register();
  50 PVE::Storage::CIFSPlugin->register();
  51 PVE::Storage::ISCSIPlugin->register();
  52 PVE::Storage::RBDPlugin->register();
  53 PVE::Storage::CephFSPlugin->register();
  54 PVE::Storage::ISCSIDirectPlugin->register();
  55 PVE::Storage::GlusterfsPlugin->register();
  56 PVE::Storage::ZFSPoolPlugin->register();
  57 PVE::Storage::ZFSPlugin->register();
  58 PVE::Storage::DRBDPlugin->register();
  59
  60 # load third-party plugins
  61 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  62     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  63         my ($file) = @_;
  64         my $modname = 'PVE::Storage::Custom::' . $file;
  65         $modname =~ s!\.pm$!!;
  66         $file = 'PVE/Storage/Custom/' . $file;
  67
  68         eval {
  69             require $file;
  70
  71             # Check perl interface:
  72             die "not derived from PVE::Storage::Plugin\n"
  73                 if !$modname->isa('PVE::Storage::Plugin');
  74             die "does not provide an api() method\n"
  75                 if !$modname->can('api');
  76             # Check storage API version and that file is really storage plugin.
  77             my $version = $modname->api();
  78             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  79                 if $version > APIVER;
  80             my $min_version = (APIVER - APIAGE);
  81             die "API version too old, please update the plugin ($version < $min_version)\n"
  82                 if $version < $min_version;
  83             import $file;
  84             $modname->register();
  85
  86             # If we got this far and the API version is not the same, make some
  87             # noise:
  88             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  89                 if $version != APIVER;
  90         };
  91         if ($@) {
  92             warn "Error loading storage plugin \"$modname\": $@";
  93         }
  94     });
  95 }
  96
  97 # initialize all plugins
  98 PVE::Storage::Plugin->init();
  99
 100 my $UDEVADM = '/sbin/udevadm';
 101
 102 #  PVE::Storage utility functions
 103
 104 sub config {
 105     return cfs_read_file("storage.cfg");
 106 }
 107
 108 sub write_config {
 109     my ($cfg) = @_;
 110
 111     cfs_write_file('storage.cfg', $cfg);
 112 }
 113
 114 sub lock_storage_config {
 115     my ($code, $errmsg) = @_;
 116
 117     cfs_lock_file("storage.cfg", undef, $code);
 118     my $err = $@;
 119     if ($err) {
 120         $errmsg ? die "$errmsg: $err" : die $err;
 121     }
 122 }
 123
 124 sub storage_config {
 125     my ($cfg, $storeid, $noerr) = @_;
 126
 127     die "no storage ID specified\n" if !$storeid;
 128
 129     my $scfg = $cfg->{ids}->{$storeid};
 130
 131     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
 132
 133     return $scfg;
 134 }
 135
 136 sub storage_check_node {
 137     my ($cfg, $storeid, $node, $noerr) = @_;
 138
 139     my $scfg = storage_config($cfg, $storeid);
 140
 141     if ($scfg->{nodes}) {
 142         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 143         if (!$scfg->{nodes}->{$node}) {
 144             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 145             return undef;
 146         }
 147     }
 148
 149     return $scfg;
 150 }
 151
 152 sub storage_check_enabled {
 153     my ($cfg, $storeid, $node, $noerr) = @_;
 154
 155     my $scfg = storage_config($cfg, $storeid);
 156
 157     if ($scfg->{disable}) {
 158         die "storage '$storeid' is disabled\n" if !$noerr;
 159         return undef;
 160     }
 161
 162     return storage_check_node($cfg, $storeid, $node, $noerr);
 163 }
 164
 165 # storage_can_replicate:
 166 # return true if storage supports replication
 167 # (volumes alocated with vdisk_alloc() has replication feature)
 168 sub storage_can_replicate {
 169     my ($cfg, $storeid, $format) = @_;
 170
 171     my $scfg = storage_config($cfg, $storeid);
 172     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 173     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 174 }
 175
 176 sub storage_ids {
 177     my ($cfg) = @_;
 178
 179     return keys %{$cfg->{ids}};
 180 }
 181
 182 sub file_size_info {
 183     my ($filename, $timeout) = @_;
 184
 185     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 186 }
 187
 188 sub volume_size_info {
 189     my ($cfg, $volid, $timeout) = @_;
 190
 191     my ($storeid, $volname) = parse_volume_id($volid, 1);
 192     if ($storeid) {
 193         my $scfg = storage_config($cfg, $storeid);
 194         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 195         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 196     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 197         return file_size_info($volid, $timeout);
 198     } else {
 199         return 0;
 200     }
 201 }
 202
 203 sub volume_resize {
 204     my ($cfg, $volid, $size, $running) = @_;
 205
 206     my ($storeid, $volname) = parse_volume_id($volid, 1);
 207     if ($storeid) {
 208         my $scfg = storage_config($cfg, $storeid);
 209         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 210         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 211     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 212         die "resize file/device '$volid' is not possible\n";
 213     } else {
 214         die "unable to parse volume ID '$volid'\n";
 215     }
 216 }
 217
 218 sub volume_rollback_is_possible {
 219     my ($cfg, $volid, $snap) = @_;
 220
 221     my ($storeid, $volname) = parse_volume_id($volid, 1);
 222     if ($storeid) {
 223         my $scfg = storage_config($cfg, $storeid);
 224         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 225         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 226     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 227         die "snapshot rollback file/device '$volid' is not possible\n";
 228     } else {
 229         die "unable to parse volume ID '$volid'\n";
 230     }
 231 }
 232
 233 sub volume_snapshot {
 234     my ($cfg, $volid, $snap) = @_;
 235
 236     my ($storeid, $volname) = parse_volume_id($volid, 1);
 237     if ($storeid) {
 238         my $scfg = storage_config($cfg, $storeid);
 239         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 240         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 241     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 242         die "snapshot file/device '$volid' is not possible\n";
 243     } else {
 244         die "unable to parse volume ID '$volid'\n";
 245     }
 246 }
 247
 248 sub volume_snapshot_rollback {
 249     my ($cfg, $volid, $snap) = @_;
 250
 251     my ($storeid, $volname) = parse_volume_id($volid, 1);
 252     if ($storeid) {
 253         my $scfg = storage_config($cfg, $storeid);
 254         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 255         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 256         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 257     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 258         die "snapshot rollback file/device '$volid' is not possible\n";
 259     } else {
 260         die "unable to parse volume ID '$volid'\n";
 261     }
 262 }
 263
 264 sub volume_snapshot_delete {
 265     my ($cfg, $volid, $snap, $running) = @_;
 266
 267     my ($storeid, $volname) = parse_volume_id($volid, 1);
 268     if ($storeid) {
 269         my $scfg = storage_config($cfg, $storeid);
 270         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 271         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 272     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 273         die "snapshot delete file/device '$volid' is not possible\n";
 274     } else {
 275         die "unable to parse volume ID '$volid'\n";
 276     }
 277 }
 278
 279 sub volume_has_feature {
 280     my ($cfg, $feature, $volid, $snap, $running) = @_;
 281
 282     my ($storeid, $volname) = parse_volume_id($volid, 1);
 283     if ($storeid) {
 284         my $scfg = storage_config($cfg, $storeid);
 285         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 286         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 287     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 288         return undef;
 289     } else {
 290         return undef;
 291     }
 292 }
 293
 294 sub volume_snapshot_list {
 295     my ($cfg, $volid) = @_;
 296
 297     my ($storeid, $volname) = parse_volume_id($volid, 1);
 298     if ($storeid) {
 299         my $scfg = storage_config($cfg, $storeid);
 300         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 301         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 302     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 303         die "send file/device '$volid' is not possible\n";
 304     } else {
 305         die "unable to parse volume ID '$volid'\n";
 306     }
 307     # return an empty array if dataset does not exist.
 308 }
 309
 310 sub get_image_dir {
 311     my ($cfg, $storeid, $vmid) = @_;
 312
 313     my $scfg = storage_config($cfg, $storeid);
 314     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 315
 316     my $path = $plugin->get_subdir($scfg, 'images');
 317
 318     return $vmid ? "$path/$vmid" : $path;
 319 }
 320
 321 sub get_private_dir {
 322     my ($cfg, $storeid, $vmid) = @_;
 323
 324     my $scfg = storage_config($cfg, $storeid);
 325     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 326
 327     my $path = $plugin->get_subdir($scfg, 'rootdir');
 328
 329     return $vmid ? "$path/$vmid" : $path;
 330 }
 331
 332 sub get_iso_dir {
 333     my ($cfg, $storeid) = @_;
 334
 335     my $scfg = storage_config($cfg, $storeid);
 336     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 337
 338     return $plugin->get_subdir($scfg, 'iso');
 339 }
 340
 341 sub get_vztmpl_dir {
 342     my ($cfg, $storeid) = @_;
 343
 344     my $scfg = storage_config($cfg, $storeid);
 345     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 346
 347     return $plugin->get_subdir($scfg, 'vztmpl');
 348 }
 349
 350 sub get_backup_dir {
 351     my ($cfg, $storeid) = @_;
 352
 353     my $scfg = storage_config($cfg, $storeid);
 354     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 355
 356     return $plugin->get_subdir($scfg, 'backup');
 357 }
 358
 359 # library implementation
 360
 361 sub parse_vmid {
 362     my $vmid = shift;
 363
 364     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 365
 366     return int($vmid);
 367 }
 368
 369 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 370 # clone -> base reference is not encoded in the volume ID.
 371 # see note in PVE::Storage::LvmThinPlugin for details.
 372 sub parse_volname {
 373     my ($cfg, $volid) = @_;
 374
 375     my ($storeid, $volname) = parse_volume_id($volid);
 376
 377     my $scfg = storage_config($cfg, $storeid);
 378
 379     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 380
 381     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 382
 383     return $plugin->parse_volname($volname);
 384 }
 385
 386 sub parse_volume_id {
 387     my ($volid, $noerr) = @_;
 388
 389     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 390 }
 391
 392 # test if we have read access to volid
 393 sub check_volume_access {
 394     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 395
 396     my ($sid, $volname) = parse_volume_id($volid, 1);
 397     if ($sid) {
 398         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 399         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 400             # require at least read access to storage, (custom) templates/ISOs could be sensitive
 401             $rpcenv->check_any($user, "/storage/$sid", ['Datastore.AllocateSpace', 'Datastore.Audit']);
 402         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 403             # we are owner - allow access
 404         } elsif ($vtype eq 'backup' && $ownervm) {
 405             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 406             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 407         } else {
 408             # allow if we are Datastore administrator
 409             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 410         }
 411     } else {
 412         die "Only root can pass arbitrary filesystem paths."
 413             if $user ne 'root@pam';
 414     }
 415
 416     return undef;
 417 }
 418
 419 my $volume_is_base_and_used__no_lock = sub {
 420     my ($scfg, $storeid, $plugin, $volname) = @_;
 421
 422     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 423         $plugin->parse_volname($volname);
 424
 425     if ($isBase) {
 426         my $vollist = $plugin->list_images($storeid, $scfg);
 427         foreach my $info (@$vollist) {
 428             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 429             my $basename = undef;
 430             my $basevmid = undef;
 431
 432             eval{
 433                 (undef, undef, undef, $basename, $basevmid) =
 434                     $plugin->parse_volname($tmpvolname);
 435             };
 436
 437             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 438                 return 1;
 439             }
 440         }
 441     }
 442     return 0;
 443 };
 444
 445 # NOTE: this check does not work for LVM-thin, where the clone -> base
 446 # reference is not encoded in the volume ID.
 447 # see note in PVE::Storage::LvmThinPlugin for details.
 448 sub volume_is_base_and_used {
 449     my ($cfg, $volid) = @_;
 450
 451     my ($storeid, $volname) = parse_volume_id($volid);
 452     my $scfg = storage_config($cfg, $storeid);
 453     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 454
 455     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 456         return &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 457     });
 458 }
 459
 460 # try to map a filesystem path to a volume identifier
 461 sub path_to_volume_id {
 462     my ($cfg, $path) = @_;
 463
 464     my $ids = $cfg->{ids};
 465
 466     my ($sid, $volname) = parse_volume_id($path, 1);
 467     if ($sid) {
 468         if (my $scfg = $ids->{$sid}) {
 469             if ($scfg->{path}) {
 470                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 471                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 472                 return ($vtype, $path);
 473             }
 474         }
 475         return ('');
 476     }
 477
 478     # Note: abs_path() return undef if $path doesn not exist
 479     # for example when nfs storage is not mounted
 480     $path = abs_path($path) || $path;
 481
 482     foreach my $sid (keys %$ids) {
 483         my $scfg = $ids->{$sid};
 484         next if !$scfg->{path};
 485         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 486         my $imagedir = $plugin->get_subdir($scfg, 'images');
 487         my $isodir = $plugin->get_subdir($scfg, 'iso');
 488         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 489         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 490         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 491
 492         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 493             my $vmid = $1;
 494             my $name = $2;
 495
 496             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 497             foreach my $info (@$vollist) {
 498                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 499                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 500                 if ($volpath eq $path) {
 501                     return ('images', $info->{volid});
 502                 }
 503             }
 504         } elsif ($path =~ m!^$isodir/([^/]+\.[Ii][Ss][Oo])$!) {
 505             my $name = $1;
 506             return ('iso', "$sid:iso/$name");
 507         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 508             my $name = $1;
 509             return ('vztmpl', "$sid:vztmpl/$name");
 510         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 511             my $vmid = $1;
 512             return ('rootdir', "$sid:rootdir/$vmid");
 513         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 514             my $name = $1;
 515             return ('iso', "$sid:backup/$name");
 516         }
 517     }
 518
 519     # can't map path to volume id
 520     return ('');
 521 }
 522
 523 sub path {
 524     my ($cfg, $volid, $snapname) = @_;
 525
 526     my ($storeid, $volname) = parse_volume_id($volid);
 527
 528     my $scfg = storage_config($cfg, $storeid);
 529
 530     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 531     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 532     return wantarray ? ($path, $owner, $vtype) : $path;
 533 }
 534
 535 sub abs_filesystem_path {
 536     my ($cfg, $volid) = @_;
 537
 538     my $path;
 539     if (PVE::Storage::parse_volume_id ($volid, 1)) {
 540         PVE::Storage::activate_volumes($cfg, [ $volid ]);
 541         $path = PVE::Storage::path($cfg, $volid);
 542     } else {
 543         if (-f $volid) {
 544             my $abspath = abs_path($volid);
 545             if ($abspath && $abspath =~ m|^(/.+)$|) {
 546                 $path = $1; # untaint any path
 547             }
 548         }
 549     }
 550
 551     die "can't find file '$volid'\n" if !($path && -f $path);
 552
 553     return $path;
 554 }
 555
 556 sub storage_migrate {
 557     my ($cfg, $volid, $target_sshinfo, $target_storeid, $target_volname, $base_snapshot, $snapshot, $ratelimit_bps, $insecure, $with_snapshots, $logfunc) = @_;
 558
 559     my ($storeid, $volname) = parse_volume_id($volid);
 560     $target_volname = $volname if !$target_volname;
 561
 562     my $scfg = storage_config($cfg, $storeid);
 563
 564     # no need to migrate shared content
 565     return if $storeid eq $target_storeid && $scfg->{shared};
 566
 567     my $tcfg = storage_config($cfg, $target_storeid);
 568
 569     my $target_volid = "${target_storeid}:${target_volname}";
 570
 571     my $target_ip = $target_sshinfo->{ip};
 572     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_sshinfo->{name}'";
 573
 574     my $ssh = PVE::Cluster::ssh_info_to_command($target_sshinfo);
 575     my $ssh_base = PVE::Cluster::ssh_info_to_command_base($target_sshinfo);
 576     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 577
 578     my @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ])
 579         if defined($ratelimit_bps);
 580
 581     my $migration_snapshot;
 582     if (!defined($snapshot)) {
 583         if ($scfg->{type} eq 'zfspool') {
 584             $migration_snapshot = 1;
 585             $snapshot = '__migration__';
 586         }
 587     }
 588
 589     my @formats = volume_transfer_formats($cfg, $volid, $volid, $snapshot, $base_snapshot, $with_snapshots);
 590     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 591     my $format = $formats[0];
 592
 593     my $import_fn = '-'; # let pvesm import read from stdin per default
 594     if ($insecure) {
 595         my $net = $target_sshinfo->{network} // $target_sshinfo->{ip};
 596         $import_fn = "tcp://$net";
 597     }
 598
 599     $with_snapshots = $with_snapshots ? 1 : 0; # sanitize for passing as cli parameter
 600     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 601     my $recv = [@$ssh, '--', 'pvesm', 'import', $volid, $format, $import_fn, '-with-snapshots', $with_snapshots];
 602     if (defined($snapshot)) {
 603         push @$send, '-snapshot', $snapshot
 604     }
 605     if ($migration_snapshot) {
 606         push @$recv, '-delete-snapshot', $snapshot;
 607     }
 608
 609     if (defined($base_snapshot)) {
 610         # Check if the snapshot exists on the remote side:
 611         push @$send, '-base', $base_snapshot;
 612         push @$recv, '-base', $base_snapshot;
 613     }
 614
 615     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 616     eval {
 617         if ($insecure) {
 618             open(my $info, '-|', @$recv)
 619                 or die "receive command failed: $!\n";
 620             my ($ip) = <$info> =~ /^($PVE::Tools::IPRE)$/ or die "no tunnel IP received\n";
 621             my ($port) = <$info> =~ /^(\d+)$/ or die "no tunnel port received\n";
 622             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 623                 or die "failed to connect to tunnel at $ip:$port\n";
 624             # we won't be reading from the socket
 625             shutdown($socket, 0);
 626             run_command([$send, @cstream], output => '>&'.fileno($socket));
 627             # don't close the connection entirely otherwise the receiving end
 628             # might not get all buffered data (and fails with 'connection reset by peer')
 629             shutdown($socket, 1);
 630             1 while <$info>; # wait for the remote process to finish
 631             # now close the socket
 632             close($socket);
 633             if (!close($info)) { # does waitpid()
 634                 die "import failed: $!\n" if $!;
 635                 die "import failed: exit code ".($?>>8)."\n";
 636             }
 637         } else {
 638             run_command([$send, @cstream, $recv], logfunc => $logfunc);
 639         }
 640     };
 641     my $err = $@;
 642     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 643     if ($migration_snapshot) {
 644         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 645         warn "could not remove source snapshot: $@\n" if $@;
 646     }
 647     die $err if $err;
 648 }
 649
 650 sub vdisk_clone {
 651     my ($cfg, $volid, $vmid, $snap) = @_;
 652
 653     my ($storeid, $volname) = parse_volume_id($volid);
 654
 655     my $scfg = storage_config($cfg, $storeid);
 656
 657     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 658
 659     activate_storage($cfg, $storeid);
 660
 661     # lock shared storage
 662     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 663         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 664         return "$storeid:$volname";
 665     });
 666 }
 667
 668 sub vdisk_create_base {
 669     my ($cfg, $volid) = @_;
 670
 671     my ($storeid, $volname) = parse_volume_id($volid);
 672
 673     my $scfg = storage_config($cfg, $storeid);
 674
 675     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 676
 677     activate_storage($cfg, $storeid);
 678
 679     # lock shared storage
 680     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 681         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 682         return "$storeid:$volname";
 683     });
 684 }
 685
 686 sub map_volume {
 687     my ($cfg, $volid, $snapname) = @_;
 688
 689     my ($storeid, $volname) = parse_volume_id($volid);
 690
 691     my $scfg = storage_config($cfg, $storeid);
 692
 693     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 694
 695     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 696 }
 697
 698 sub unmap_volume {
 699     my ($cfg, $volid, $snapname) = @_;
 700
 701     my ($storeid, $volname) = parse_volume_id($volid);
 702
 703     my $scfg = storage_config($cfg, $storeid);
 704
 705     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 706
 707     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 708 }
 709
 710 sub vdisk_alloc {
 711     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 712
 713     die "no storage ID specified\n" if !$storeid;
 714
 715     PVE::JSONSchema::parse_storage_id($storeid);
 716
 717     my $scfg = storage_config($cfg, $storeid);
 718
 719     die "no VMID specified\n" if !$vmid;
 720
 721     $vmid = parse_vmid($vmid);
 722
 723     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 724
 725     $fmt = $defformat if !$fmt;
 726
 727     activate_storage($cfg, $storeid);
 728
 729     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 730
 731     # lock shared storage
 732     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 733         my $old_umask = umask(umask|0037);
 734         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 735         my $err = $@;
 736         umask $old_umask;
 737         die $err if $err;
 738         return "$storeid:$volname";
 739     });
 740 }
 741
 742 sub vdisk_free {
 743     my ($cfg, $volid) = @_;
 744
 745     my ($storeid, $volname) = parse_volume_id($volid);
 746     my $scfg = storage_config($cfg, $storeid);
 747     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 748
 749     activate_storage($cfg, $storeid);
 750
 751     my $cleanup_worker;
 752
 753     # lock shared storage
 754     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 755         # LVM-thin allows deletion of still referenced base volumes!
 756         die "base volume '$volname' is still in use by linked clones\n"
 757             if &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 758
 759         my (undef, undef, undef, undef, undef, $isBase, $format) =
 760             $plugin->parse_volname($volname);
 761         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 762     });
 763
 764     return if !$cleanup_worker;
 765
 766     my $rpcenv = PVE::RPCEnvironment::get();
 767     my $authuser = $rpcenv->get_user();
 768
 769     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 770 }
 771
 772 # lists all files in the snippets directory
 773 sub snippets_list {
 774     my ($cfg, $storeid) = @_;
 775
 776     my $ids = $cfg->{ids};
 777
 778     storage_check_enabled($cfg, $storeid) if ($storeid);
 779
 780     my $res = {};
 781
 782     foreach my $sid (keys %$ids) {
 783         next if $storeid && $storeid ne $sid;
 784         next if !storage_check_enabled($cfg, $sid, undef, 1);
 785
 786         my $scfg = $ids->{$sid};
 787         next if !$scfg->{content}->{snippets};
 788
 789         activate_storage($cfg, $sid);
 790
 791         if ($scfg->{path}) {
 792             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 793             my $path = $plugin->get_subdir($scfg, 'snippets');
 794
 795             foreach my $fn (<$path/*>) {
 796                 next if -d $fn;
 797
 798                 push @{$res->{$sid}}, {
 799                     volid => "$sid:snippets/". basename($fn),
 800                     format => 'snippet',
 801                     size => -s $fn // 0,
 802                 };
 803             }
 804         }
 805
 806         if ($res->{$sid}) {
 807             @{$res->{$sid}} = sort {$a->{volid} cmp $b->{volid} } @{$res->{$sid}};
 808         }
 809     }
 810
 811     return $res;
 812 }
 813
 814 #list iso or openvz template ($tt = <iso|vztmpl|backup>)
 815 sub template_list {
 816     my ($cfg, $storeid, $tt) = @_;
 817
 818     die "unknown template type '$tt'\n"
 819         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup');
 820
 821     my $ids = $cfg->{ids};
 822
 823     storage_check_enabled($cfg, $storeid) if ($storeid);
 824
 825     my $res = {};
 826
 827     # query the storage
 828
 829     foreach my $sid (keys %$ids) {
 830         next if $storeid && $storeid ne $sid;
 831
 832         my $scfg = $ids->{$sid};
 833         my $type = $scfg->{type};
 834
 835         next if !storage_check_enabled($cfg, $sid, undef, 1);
 836
 837         next if $tt eq 'iso' && !$scfg->{content}->{iso};
 838         next if $tt eq 'vztmpl' && !$scfg->{content}->{vztmpl};
 839         next if $tt eq 'backup' && !$scfg->{content}->{backup};
 840
 841         activate_storage($cfg, $sid);
 842
 843         if ($scfg->{path}) {
 844             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 845
 846             my $path = $plugin->get_subdir($scfg, $tt);
 847
 848             foreach my $fn (<$path/*>) {
 849
 850                 my $info;
 851
 852                 if ($tt eq 'iso') {
 853                     next if $fn !~ m!/([^/]+\.[Ii][Ss][Oo])$!;
 854
 855                     $info = { volid => "$sid:iso/$1", format => 'iso' };
 856
 857                 } elsif ($tt eq 'vztmpl') {
 858                     next if $fn !~ m!/([^/]+\.tar\.([gx]z))$!;
 859
 860                     $info = { volid => "$sid:vztmpl/$1", format => "t$2" };
 861
 862                 } elsif ($tt eq 'backup') {
 863                     next if $fn !~ m!/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!;
 864
 865                     $info = { volid => "$sid:backup/$1", format => $2 };
 866                 }
 867
 868                 $info->{size} = -s $fn // 0;
 869
 870                 push @{$res->{$sid}}, $info;
 871             }
 872
 873         }
 874
 875         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 876     }
 877
 878     return $res;
 879 }
 880
 881
 882 sub vdisk_list {
 883     my ($cfg, $storeid, $vmid, $vollist) = @_;
 884
 885     my $ids = $cfg->{ids};
 886
 887     storage_check_enabled($cfg, $storeid) if ($storeid);
 888
 889     my $res = {};
 890
 891     # prepare/activate/refresh all storages
 892
 893     my $storage_list = [];
 894     if ($vollist) {
 895         foreach my $volid (@$vollist) {
 896             my ($sid, undef) = parse_volume_id($volid);
 897             next if !defined($ids->{$sid});
 898             next if !storage_check_enabled($cfg, $sid, undef, 1);
 899             push @$storage_list, $sid;
 900         }
 901     } else {
 902         foreach my $sid (keys %$ids) {
 903             next if $storeid && $storeid ne $sid;
 904             next if !storage_check_enabled($cfg, $sid, undef, 1);
 905             push @$storage_list, $sid;
 906         }
 907     }
 908
 909     my $cache = {};
 910
 911     activate_storage_list($cfg, $storage_list, $cache);
 912
 913     foreach my $sid (keys %$ids) {
 914         next if $storeid && $storeid ne $sid;
 915         next if !storage_check_enabled($cfg, $sid, undef, 1);
 916
 917         my $scfg = $ids->{$sid};
 918         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 919         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 920         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 921     }
 922
 923     return $res;
 924 }
 925
 926 sub volume_list {
 927     my ($cfg, $storeid, $vmid, $content) = @_;
 928
 929     my @ctypes = qw(images vztmpl iso backup snippets);
 930
 931     my $cts = $content ? [ $content ] : [ @ctypes ];
 932
 933     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 934
 935     my $res = [];
 936     foreach my $ct (@$cts) {
 937         my $data;
 938         if ($ct eq 'images') {
 939             $data = vdisk_list($cfg, $storeid, $vmid);
 940         } elsif ($ct eq 'iso' && !defined($vmid)) {
 941             $data = template_list($cfg, $storeid, 'iso');
 942         } elsif ($ct eq 'vztmpl'&& !defined($vmid)) {
 943             $data = template_list ($cfg, $storeid, 'vztmpl');
 944         } elsif ($ct eq 'backup') {
 945             $data = template_list ($cfg, $storeid, 'backup');
 946             foreach my $item (@{$data->{$storeid}}) {
 947                 if (defined($vmid)) {
 948                     @{$data->{$storeid}} = grep { $_->{volid} =~ m/\S+-$vmid-\S+/ } @{$data->{$storeid}};
 949                 }
 950             }
 951         } elsif ($ct eq 'snippets') {
 952             $data = snippets_list($cfg, $storeid);
 953         }
 954
 955         next if !$data || !$data->{$storeid};
 956
 957         foreach my $item (@{$data->{$storeid}}) {
 958             $item->{content} = $ct;
 959             push @$res, $item;
 960         }
 961     }
 962
 963     return $res;
 964 }
 965
 966 sub uevent_seqnum {
 967
 968     my $filename = "/sys/kernel/uevent_seqnum";
 969
 970     my $seqnum = 0;
 971     if (my $fh = IO::File->new($filename, "r")) {
 972         my $line = <$fh>;
 973         if ($line =~ m/^(\d+)$/) {
 974             $seqnum = int($1);
 975         }
 976         close ($fh);
 977     }
 978     return $seqnum;
 979 }
 980
 981 sub activate_storage {
 982     my ($cfg, $storeid, $cache) = @_;
 983
 984     $cache = {} if !$cache;
 985
 986     my $scfg = storage_check_enabled($cfg, $storeid);
 987
 988     return if $cache->{activated}->{$storeid};
 989
 990     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 991
 992     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 993
 994     if ($scfg->{base}) {
 995         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 996         activate_storage($cfg, $baseid, $cache);
 997     }
 998
 999     if (!$plugin->check_connection($storeid, $scfg)) {
1000         die "storage '$storeid' is not online\n";
1001     }
1002
1003     $plugin->activate_storage($storeid, $scfg, $cache);
1004
1005     my $newseq = uevent_seqnum ();
1006
1007     # only call udevsettle if there are events
1008     if ($newseq > $cache->{uevent_seqnum}) {
1009         my $timeout = 30;
1010         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
1011         $cache->{uevent_seqnum} = $newseq;
1012     }
1013
1014     $cache->{activated}->{$storeid} = 1;
1015 }
1016
1017 sub activate_storage_list {
1018     my ($cfg, $storeid_list, $cache) = @_;
1019
1020     $cache = {} if !$cache;
1021
1022     foreach my $storeid (@$storeid_list) {
1023         activate_storage($cfg, $storeid, $cache);
1024     }
1025 }
1026
1027 sub deactivate_storage {
1028     my ($cfg, $storeid) = @_;
1029
1030     my $scfg = storage_config ($cfg, $storeid);
1031     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1032
1033     my $cache = {};
1034     $plugin->deactivate_storage($storeid, $scfg, $cache);
1035 }
1036
1037 sub activate_volumes {
1038     my ($cfg, $vollist, $snapname) = @_;
1039
1040     return if !($vollist && scalar(@$vollist));
1041
1042     my $storagehash = {};
1043     foreach my $volid (@$vollist) {
1044         my ($storeid, undef) = parse_volume_id($volid);
1045         $storagehash->{$storeid} = 1;
1046     }
1047
1048     my $cache = {};
1049
1050     activate_storage_list($cfg, [keys %$storagehash], $cache);
1051
1052     foreach my $volid (@$vollist) {
1053         my ($storeid, $volname) = parse_volume_id($volid);
1054         my $scfg = storage_config($cfg, $storeid);
1055         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1056         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
1057     }
1058 }
1059
1060 sub deactivate_volumes {
1061     my ($cfg, $vollist, $snapname) = @_;
1062
1063     return if !($vollist && scalar(@$vollist));
1064
1065     my $cache = {};
1066
1067     my @errlist = ();
1068     foreach my $volid (@$vollist) {
1069         my ($storeid, $volname) = parse_volume_id($volid);
1070
1071         my $scfg = storage_config($cfg, $storeid);
1072         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1073
1074         eval {
1075             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
1076         };
1077         if (my $err = $@) {
1078             warn $err;
1079             push @errlist, $volid;
1080         }
1081     }
1082
1083     die "volume deactivation failed: " . join(' ', @errlist)
1084         if scalar(@errlist);
1085 }
1086
1087 sub storage_info {
1088     my ($cfg, $content, $includeformat) = @_;
1089
1090     my $ids = $cfg->{ids};
1091
1092     my $info = {};
1093
1094     my @ctypes = PVE::Tools::split_list($content);
1095
1096     my $slist = [];
1097     foreach my $storeid (keys %$ids) {
1098         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1099
1100         if (defined($content)) {
1101             my $want_ctype = 0;
1102             foreach my $ctype (@ctypes) {
1103                 if ($ids->{$storeid}->{content}->{$ctype}) {
1104                     $want_ctype = 1;
1105                     last;
1106                 }
1107             }
1108             next if !$want_ctype || !$storage_enabled;
1109         }
1110
1111         my $type = $ids->{$storeid}->{type};
1112
1113         $info->{$storeid} = {
1114             type => $type,
1115             total => 0,
1116             avail => 0,
1117             used => 0,
1118             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1119             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1120             active => 0,
1121             enabled => $storage_enabled ? 1 : 0,
1122         };
1123
1124         push @$slist, $storeid;
1125     }
1126
1127     my $cache = {};
1128
1129     foreach my $storeid (keys %$ids) {
1130         my $scfg = $ids->{$storeid};
1131
1132         next if !$info->{$storeid};
1133         next if !$info->{$storeid}->{enabled};
1134
1135         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1136         if ($includeformat) {
1137             my $pd = $plugin->plugindata();
1138             $info->{$storeid}->{format} = $pd->{format}
1139                 if $pd->{format};
1140             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1141                 if $pd->{select_existing};
1142         }
1143
1144         eval { activate_storage($cfg, $storeid, $cache); };
1145         if (my $err = $@) {
1146             warn $err;
1147             next;
1148         }
1149
1150         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1151         warn $@ if $@;
1152         next if !$active;
1153         $info->{$storeid}->{total} = int($total);
1154         $info->{$storeid}->{avail} = int($avail);
1155         $info->{$storeid}->{used} = int($used);
1156         $info->{$storeid}->{active} = $active;
1157     }
1158
1159     return $info;
1160 }
1161
1162 sub resolv_server {
1163     my ($server) = @_;
1164
1165     my ($packed_ip, $family);
1166     eval {
1167         my @res = PVE::Tools::getaddrinfo_all($server);
1168         $family = $res[0]->{family};
1169         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1170     };
1171     if (defined $packed_ip) {
1172         return Socket::inet_ntop($family, $packed_ip);
1173     }
1174     return undef;
1175 }
1176
1177 sub scan_nfs {
1178     my ($server_in) = @_;
1179
1180     my $server;
1181     if (!($server = resolv_server ($server_in))) {
1182         die "unable to resolve address for server '${server_in}'\n";
1183     }
1184
1185     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1186
1187     my $res = {};
1188     run_command($cmd, outfunc => sub {
1189         my $line = shift;
1190
1191         # note: howto handle white spaces in export path??
1192         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1193             $res->{$1} = $2;
1194         }
1195     });
1196
1197     return $res;
1198 }
1199
1200 sub scan_cifs {
1201     my ($server_in, $user, $password, $domain) = @_;
1202
1203     my $server;
1204     if (!($server = resolv_server ($server_in))) {
1205         die "unable to resolve address for server '${server_in}'\n";
1206     }
1207
1208     # we support only Windows grater than 2012 cifsscan so use smb3
1209     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1210     if (defined($user)) {
1211         die "password is required" if !defined($password);
1212         push @$cmd, '-U', "$user\%$password";
1213         push @$cmd, '-W', $domain if defined($domain);
1214     } else {
1215         push @$cmd, '-N';
1216     }
1217
1218     my $res = {};
1219     run_command($cmd,
1220                 outfunc => sub {
1221                     my $line = shift;
1222                     if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1223                         $res->{$1} = $2;
1224                     } elsif ($line =~ m/(NT_STATUS_(\S*))/) {
1225                         $res->{$1} = '';
1226                     }
1227                 },
1228                 errfunc => sub {},
1229                 noerr => 1
1230     );
1231
1232     return $res;
1233 }
1234
1235 sub scan_zfs {
1236
1237     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-H', '-o', 'name,avail,used'];
1238
1239     my $res = [];
1240     run_command($cmd, outfunc => sub {
1241         my $line = shift;
1242
1243         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1244             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1245             my $size = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($size_str);
1246             my $used = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($used_str);
1247             # ignore subvolumes generated by our ZFSPoolPlugin
1248             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1249             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1250             push @$res, { pool => $pool, size => $size, free => $size-$used };
1251         }
1252     });
1253
1254     return $res;
1255 }
1256
1257 sub resolv_portal {
1258     my ($portal, $noerr) = @_;
1259
1260     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1261     if ($server) {
1262         if (my $ip = resolv_server($server)) {
1263             $server = $ip;
1264             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1265             return $port ? "$server:$port" : $server;
1266         }
1267     }
1268     return undef if $noerr;
1269
1270     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1271 }
1272
1273
1274 sub scan_iscsi {
1275     my ($portal_in) = @_;
1276
1277     my $portal;
1278     if (!($portal = resolv_portal($portal_in))) {
1279         die "unable to parse/resolve portal address '${portal_in}'\n";
1280     }
1281
1282     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1283 }
1284
1285 sub storage_default_format {
1286     my ($cfg, $storeid) = @_;
1287
1288     my $scfg = storage_config ($cfg, $storeid);
1289
1290     return PVE::Storage::Plugin::default_format($scfg);
1291 }
1292
1293 sub vgroup_is_used {
1294     my ($cfg, $vgname) = @_;
1295
1296     foreach my $storeid (keys %{$cfg->{ids}}) {
1297         my $scfg = storage_config($cfg, $storeid);
1298         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1299             return 1;
1300         }
1301     }
1302
1303     return undef;
1304 }
1305
1306 sub target_is_used {
1307     my ($cfg, $target) = @_;
1308
1309     foreach my $storeid (keys %{$cfg->{ids}}) {
1310         my $scfg = storage_config($cfg, $storeid);
1311         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1312             return 1;
1313         }
1314     }
1315
1316     return undef;
1317 }
1318
1319 sub volume_is_used {
1320     my ($cfg, $volid) = @_;
1321
1322     foreach my $storeid (keys %{$cfg->{ids}}) {
1323         my $scfg = storage_config($cfg, $storeid);
1324         if ($scfg->{base} && $scfg->{base} eq $volid) {
1325             return 1;
1326         }
1327     }
1328
1329     return undef;
1330 }
1331
1332 sub storage_is_used {
1333     my ($cfg, $storeid) = @_;
1334
1335     foreach my $sid (keys %{$cfg->{ids}}) {
1336         my $scfg = storage_config($cfg, $sid);
1337         next if !$scfg->{base};
1338         my ($st) = parse_volume_id($scfg->{base});
1339         return 1 if $st && $st eq $storeid;
1340     }
1341
1342     return undef;
1343 }
1344
1345 sub foreach_volid {
1346     my ($list, $func) = @_;
1347
1348     return if !$list;
1349
1350     foreach my $sid (keys %$list) {
1351        foreach my $info (@{$list->{$sid}}) {
1352            my $volid = $info->{volid};
1353            my ($sid1, $volname) = parse_volume_id($volid, 1);
1354            if ($sid1 && $sid1 eq $sid) {
1355                &$func ($volid, $sid, $info);
1356            } else {
1357                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1358            }
1359        }
1360     }
1361 }
1362
1363 sub extract_vzdump_config_tar {
1364     my ($archive, $conf_re) = @_;
1365
1366     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1367
1368     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1369        die "unable to open file '$archive'\n";
1370
1371     my $file;
1372     while (defined($file = <$fh>)) {
1373         if ($file =~ $conf_re) {
1374             $file = $1; # untaint
1375             last;
1376         }
1377     }
1378
1379     kill 15, $pid;
1380     waitpid $pid, 0;
1381     close $fh;
1382
1383     die "ERROR: archive contains no configuration file\n" if !$file;
1384     chomp $file;
1385
1386     my $raw = '';
1387     my $out = sub {
1388         my $output = shift;
1389         $raw .= "$output\n";
1390     };
1391
1392     PVE::Tools::run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1393
1394     return wantarray ? ($raw, $file) : $raw;
1395 }
1396
1397 sub extract_vzdump_config_vma {
1398     my ($archive, $comp) = @_;
1399
1400     my $cmd;
1401     my $raw = '';
1402     my $out = sub {
1403         my $output = shift;
1404         $raw .= "$output\n";
1405     };
1406
1407
1408     if ($comp) {
1409         my $uncomp;
1410         if ($comp eq 'gz') {
1411             $uncomp = ["zcat", $archive];
1412         } elsif ($comp eq 'lzo') {
1413             $uncomp = ["lzop", "-d", "-c", $archive];
1414         } else {
1415             die "unknown compression method '$comp'\n";
1416         }
1417         $cmd = [$uncomp, ["vma", "config", "-"]];
1418
1419         # in some cases, lzop/zcat exits with 1 when its stdout pipe is
1420         # closed early by vma, detect this and ignore the exit code later
1421         my $broken_pipe;
1422         my $errstring;
1423         my $err = sub {
1424             my $output = shift;
1425             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/) {
1426                 $broken_pipe = 1;
1427             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1428                 $errstring = "Failed to extract config from VMA archive: $output\n";
1429             }
1430         };
1431
1432         # in other cases, the pipeline will exit with exit code 141
1433         # because of the broken pipe, handle / ignore this as well
1434         my $rc;
1435         eval {
1436             $rc = PVE::Tools::run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1);
1437         };
1438         my $rerr = $@;
1439
1440         # use exit code if no stderr output and not just broken pipe
1441         if (!$errstring && !$broken_pipe && $rc != 0 && $rc != 141) {
1442             die "$rerr\n" if $rerr;
1443             die "config extraction failed with exit code $rc\n";
1444         }
1445         die "$errstring\n" if $errstring;
1446     } else {
1447         # simple case without compression and weird piping behaviour
1448         PVE::Tools::run_command(["vma", "config", $archive], outfunc => $out);
1449     }
1450
1451     return wantarray ? ($raw, undef) : $raw;
1452 }
1453
1454 sub extract_vzdump_config {
1455     my ($cfg, $volid) = @_;
1456
1457     my $archive = abs_filesystem_path($cfg, $volid);
1458
1459     if ($volid =~ /vzdump-(lxc|openvz)-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|(tar(\.(gz|lzo))?))$/) {
1460         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1461     } elsif ($volid =~ /vzdump-qemu-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|((tar|vma)(\.(gz|lzo))?))$/) {
1462         my $format;
1463         my $comp;
1464         if ($7 eq 'tgz') {
1465             $format = 'tar';
1466             $comp = 'gz';
1467         } else {
1468             $format = $9;
1469             $comp = $11 if defined($11);
1470         }
1471
1472         if ($format eq 'tar') {
1473             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1474         } else {
1475             return extract_vzdump_config_vma($archive, $comp);
1476         }
1477     } else {
1478         die "cannot determine backup guest type for backup archive '$volid'\n";
1479     }
1480 }
1481
1482 sub volume_export {
1483     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1484
1485     my ($storeid, $volname) = parse_volume_id($volid, 1);
1486     die "cannot export volume '$volid'\n" if !$storeid;
1487     my $scfg = storage_config($cfg, $storeid);
1488     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1489     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1490                                   $snapshot, $base_snapshot, $with_snapshots);
1491 }
1492
1493 sub volume_import {
1494     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots) = @_;
1495
1496     my ($storeid, $volname) = parse_volume_id($volid, 1);
1497     die "cannot import into volume '$volid'\n" if !$storeid;
1498     my $scfg = storage_config($cfg, $storeid);
1499     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1500     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1501                                   $base_snapshot, $with_snapshots);
1502 }
1503
1504 sub volume_export_formats {
1505     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1506
1507     my ($storeid, $volname) = parse_volume_id($volid, 1);
1508     return if !$storeid;
1509     my $scfg = storage_config($cfg, $storeid);
1510     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1511     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1512                                           $snapshot, $base_snapshot,
1513                                           $with_snapshots);
1514 }
1515
1516 sub volume_import_formats {
1517     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1518
1519     my ($storeid, $volname) = parse_volume_id($volid, 1);
1520     return if !$storeid;
1521     my $scfg = storage_config($cfg, $storeid);
1522     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1523     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1524                                           $base_snapshot, $with_snapshots);
1525 }
1526
1527 sub volume_transfer_formats {
1528     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1529     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1530     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1531     my %import_hash = map { $_ => 1 } @import_formats;
1532     my @common = grep { $import_hash{$_} } @export_formats;
1533     return @common;
1534 }
1535
1536 # bash completion helper
1537
1538 sub complete_storage {
1539     my ($cmdname, $pname, $cvalue) = @_;
1540
1541     my $cfg = PVE::Storage::config();
1542
1543     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1544 }
1545
1546 sub complete_storage_enabled {
1547     my ($cmdname, $pname, $cvalue) = @_;
1548
1549     my $res = [];
1550
1551     my $cfg = PVE::Storage::config();
1552     foreach my $sid (keys %{$cfg->{ids}}) {
1553         next if !storage_check_enabled($cfg, $sid, undef, 1);
1554         push @$res, $sid;
1555     }
1556     return $res;
1557 }
1558
1559 sub complete_content_type {
1560     my ($cmdname, $pname, $cvalue) = @_;
1561
1562     return [qw(rootdir images vztmpl iso backup snippets)];
1563 }
1564
1565 sub complete_volume {
1566     my ($cmdname, $pname, $cvalue) = @_;
1567
1568     my $cfg = config();
1569
1570     my $storage_list = complete_storage_enabled();
1571
1572     if ($cvalue =~ m/^([^:]+):/) {
1573         $storage_list = [ $1 ];
1574     } else {
1575         if (scalar(@$storage_list) > 1) {
1576             # only list storage IDs to avoid large listings
1577             my $res = [];
1578             foreach my $storeid (@$storage_list) {
1579                 # Hack: simply return 2 artificial values, so that
1580                 # completions does not finish
1581                 push @$res, "$storeid:volname", "$storeid:...";
1582             }
1583             return $res;
1584         }
1585     }
1586
1587     my $res = [];
1588     foreach my $storeid (@$storage_list) {
1589         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1590
1591         foreach my $item (@$vollist) {
1592             push @$res, $item->{volid};
1593         }
1594     }
1595
1596     return $res;
1597 }
1598
1599 # Various io-heavy operations require io/bandwidth limits which can be
1600 # configured on multiple levels: The global defaults in datacenter.cfg, and
1601 # per-storage overrides. When we want to do a restore from storage A to storage
1602 # B, we should take the smaller limit defined for storages A and B, and if no
1603 # such limit was specified, use the one from datacenter.cfg.
1604 sub get_bandwidth_limit {
1605     my ($operation, $storage_list, $override) = @_;
1606
1607     # called for each limit (global, per-storage) with the 'default' and the
1608     # $operation limit and should udpate $override for every limit affecting
1609     # us.
1610     my $use_global_limits = 0;
1611     my $apply_limit = sub {
1612         my ($bwlimit) = @_;
1613         if (defined($bwlimit)) {
1614             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1615             my $limit = $limits->{$operation} // $limits->{default};
1616             if (defined($limit)) {
1617                 if (!$override || $limit < $override) {
1618                     $override = $limit;
1619                 }
1620                 return;
1621             }
1622         }
1623         # If there was no applicable limit, try to apply the global ones.
1624         $use_global_limits = 1;
1625     };
1626
1627     my ($rpcenv, $authuser);
1628     if (defined($override)) {
1629         $rpcenv = PVE::RPCEnvironment->get();
1630         $authuser = $rpcenv->get_user();
1631     }
1632
1633     # Apply per-storage limits - if there are storages involved.
1634     if (defined($storage_list) && @$storage_list) {
1635         my $config = config();
1636
1637         # The Datastore.Allocate permission allows us to modify the per-storage
1638         # limits, therefore it also allows us to override them.
1639         # Since we have most likely multiple storages to check, do a quick check on
1640         # the general '/storage' path to see if we can skip the checks entirely:
1641         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1642
1643         my %done;
1644         foreach my $storage (@$storage_list) {
1645             next if !defined($storage);
1646             # Avoid duplicate checks:
1647             next if $done{$storage};
1648             $done{$storage} = 1;
1649
1650             # Otherwise we may still have individual /storage/$ID permissions:
1651             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1652                 # And if not: apply the limits.
1653                 my $storecfg = storage_config($config, $storage);
1654                 $apply_limit->($storecfg->{bwlimit});
1655             }
1656         }
1657
1658         # Storage limits take precedence over the datacenter defaults, so if
1659         # a limit was applied:
1660         return $override if !$use_global_limits;
1661     }
1662
1663     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1664     # global default limits.
1665     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1666         # So if we cannot modify global limits, apply them to our currently
1667         # requested override.
1668         my $dc = cfs_read_file('datacenter.cfg');
1669         $apply_limit->($dc->{bwlimit});
1670     }
1671
1672     return $override;
1673 }
1674
1675 # checks if the storage id is available and dies if not
1676 sub assert_sid_unused {
1677     my ($sid) = @_;
1678
1679     my $cfg = config();
1680     if (my $scfg = storage_config($cfg, $sid, 1)) {
1681         die "storage ID '$sid' already defined\n";
1682     }
1683
1684     return undef;
1685 }
1686
1687 1;