PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use IPC::Open3;
  12 use File::Basename;
  13 use File::Path;
  14 use Cwd 'abs_path';
  15 use Socket;
  16 use Time::Local qw(timelocal);
  17
  18 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  19 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  20 use PVE::DataCenterConfig;
  21 use PVE::Exception qw(raise_param_exc raise);
  22 use PVE::JSONSchema;
  23 use PVE::INotify;
  24 use PVE::RPCEnvironment;
  25 use PVE::SSHInfo;
  26
  27 use PVE::Storage::Plugin;
  28 use PVE::Storage::DirPlugin;
  29 use PVE::Storage::LVMPlugin;
  30 use PVE::Storage::LvmThinPlugin;
  31 use PVE::Storage::NFSPlugin;
  32 use PVE::Storage::CIFSPlugin;
  33 use PVE::Storage::ISCSIPlugin;
  34 use PVE::Storage::RBDPlugin;
  35 use PVE::Storage::CephFSPlugin;
  36 use PVE::Storage::ISCSIDirectPlugin;
  37 use PVE::Storage::GlusterfsPlugin;
  38 use PVE::Storage::ZFSPoolPlugin;
  39 use PVE::Storage::ZFSPlugin;
  40 use PVE::Storage::DRBDPlugin;
  41 use PVE::Storage::PBSPlugin;
  42
  43 # Storage API version. Increment it on changes in storage API interface.
  44 use constant APIVER => 8;
  45 # Age is the number of versions we're backward compatible with.
  46 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  47 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  48 use constant APIAGE => 7;
  49
  50 # load standard plugins
  51 PVE::Storage::DirPlugin->register();
  52 PVE::Storage::LVMPlugin->register();
  53 PVE::Storage::LvmThinPlugin->register();
  54 PVE::Storage::NFSPlugin->register();
  55 PVE::Storage::CIFSPlugin->register();
  56 PVE::Storage::ISCSIPlugin->register();
  57 PVE::Storage::RBDPlugin->register();
  58 PVE::Storage::CephFSPlugin->register();
  59 PVE::Storage::ISCSIDirectPlugin->register();
  60 PVE::Storage::GlusterfsPlugin->register();
  61 PVE::Storage::ZFSPoolPlugin->register();
  62 PVE::Storage::ZFSPlugin->register();
  63 PVE::Storage::DRBDPlugin->register();
  64 PVE::Storage::PBSPlugin->register();
  65
  66 # load third-party plugins
  67 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  68     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  69         my ($file) = @_;
  70         my $modname = 'PVE::Storage::Custom::' . $file;
  71         $modname =~ s!\.pm$!!;
  72         $file = 'PVE/Storage/Custom/' . $file;
  73
  74         eval {
  75             require $file;
  76
  77             # Check perl interface:
  78             die "not derived from PVE::Storage::Plugin\n"
  79                 if !$modname->isa('PVE::Storage::Plugin');
  80             die "does not provide an api() method\n"
  81                 if !$modname->can('api');
  82             # Check storage API version and that file is really storage plugin.
  83             my $version = $modname->api();
  84             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  85                 if $version > APIVER;
  86             my $min_version = (APIVER - APIAGE);
  87             die "API version too old, please update the plugin ($version < $min_version)\n"
  88                 if $version < $min_version;
  89             import $file;
  90             $modname->register();
  91
  92             # If we got this far and the API version is not the same, make some
  93             # noise:
  94             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  95                 if $version != APIVER;
  96         };
  97         if ($@) {
  98             warn "Error loading storage plugin \"$modname\": $@";
  99         }
 100     });
 101 }
 102
 103 # initialize all plugins
 104 PVE::Storage::Plugin->init();
 105
 106 my $UDEVADM = '/sbin/udevadm';
 107
 108 our $iso_extension_re = qr/\.(?:iso|img)/i;
 109
 110 #  PVE::Storage utility functions
 111
 112 sub config {
 113     return cfs_read_file("storage.cfg");
 114 }
 115
 116 sub write_config {
 117     my ($cfg) = @_;
 118
 119     cfs_write_file('storage.cfg', $cfg);
 120 }
 121
 122 sub lock_storage_config {
 123     my ($code, $errmsg) = @_;
 124
 125     cfs_lock_file("storage.cfg", undef, $code);
 126     my $err = $@;
 127     if ($err) {
 128         $errmsg ? die "$errmsg: $err" : die $err;
 129     }
 130 }
 131
 132 sub storage_config {
 133     my ($cfg, $storeid, $noerr) = @_;
 134
 135     die "no storage ID specified\n" if !$storeid;
 136
 137     my $scfg = $cfg->{ids}->{$storeid};
 138
 139     die "storage '$storeid' does not exist\n" if (!$noerr && !$scfg);
 140
 141     return $scfg;
 142 }
 143
 144 sub storage_check_node {
 145     my ($cfg, $storeid, $node, $noerr) = @_;
 146
 147     my $scfg = storage_config($cfg, $storeid);
 148
 149     if ($scfg->{nodes}) {
 150         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 151         if (!$scfg->{nodes}->{$node}) {
 152             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 153             return undef;
 154         }
 155     }
 156
 157     return $scfg;
 158 }
 159
 160 sub storage_check_enabled {
 161     my ($cfg, $storeid, $node, $noerr) = @_;
 162
 163     my $scfg = storage_config($cfg, $storeid);
 164
 165     if ($scfg->{disable}) {
 166         die "storage '$storeid' is disabled\n" if !$noerr;
 167         return undef;
 168     }
 169
 170     return storage_check_node($cfg, $storeid, $node, $noerr);
 171 }
 172
 173 # storage_can_replicate:
 174 # return true if storage supports replication
 175 # (volumes alocated with vdisk_alloc() has replication feature)
 176 sub storage_can_replicate {
 177     my ($cfg, $storeid, $format) = @_;
 178
 179     my $scfg = storage_config($cfg, $storeid);
 180     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 181     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 182 }
 183
 184 sub storage_ids {
 185     my ($cfg) = @_;
 186
 187     return keys %{$cfg->{ids}};
 188 }
 189
 190 sub file_size_info {
 191     my ($filename, $timeout) = @_;
 192
 193     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 194 }
 195
 196 sub volume_size_info {
 197     my ($cfg, $volid, $timeout) = @_;
 198
 199     my ($storeid, $volname) = parse_volume_id($volid, 1);
 200     if ($storeid) {
 201         my $scfg = storage_config($cfg, $storeid);
 202         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 203         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 204     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 205         return file_size_info($volid, $timeout);
 206     } else {
 207         return 0;
 208     }
 209 }
 210
 211 sub volume_resize {
 212     my ($cfg, $volid, $size, $running) = @_;
 213
 214     my $padding = (1024 - $size % 1024) % 1024;
 215     $size = $size + $padding;
 216
 217     my ($storeid, $volname) = parse_volume_id($volid, 1);
 218     if ($storeid) {
 219         my $scfg = storage_config($cfg, $storeid);
 220         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 221         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 222     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 223         die "resize file/device '$volid' is not possible\n";
 224     } else {
 225         die "unable to parse volume ID '$volid'\n";
 226     }
 227 }
 228
 229 sub volume_rollback_is_possible {
 230     my ($cfg, $volid, $snap) = @_;
 231
 232     my ($storeid, $volname) = parse_volume_id($volid, 1);
 233     if ($storeid) {
 234         my $scfg = storage_config($cfg, $storeid);
 235         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 236         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 237     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 238         die "snapshot rollback file/device '$volid' is not possible\n";
 239     } else {
 240         die "unable to parse volume ID '$volid'\n";
 241     }
 242 }
 243
 244 sub volume_snapshot {
 245     my ($cfg, $volid, $snap) = @_;
 246
 247     my ($storeid, $volname) = parse_volume_id($volid, 1);
 248     if ($storeid) {
 249         my $scfg = storage_config($cfg, $storeid);
 250         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 251         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 252     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 253         die "snapshot file/device '$volid' is not possible\n";
 254     } else {
 255         die "unable to parse volume ID '$volid'\n";
 256     }
 257 }
 258
 259 sub volume_snapshot_rollback {
 260     my ($cfg, $volid, $snap) = @_;
 261
 262     my ($storeid, $volname) = parse_volume_id($volid, 1);
 263     if ($storeid) {
 264         my $scfg = storage_config($cfg, $storeid);
 265         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 266         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 267         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 268     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 269         die "snapshot rollback file/device '$volid' is not possible\n";
 270     } else {
 271         die "unable to parse volume ID '$volid'\n";
 272     }
 273 }
 274
 275 sub volume_snapshot_delete {
 276     my ($cfg, $volid, $snap, $running) = @_;
 277
 278     my ($storeid, $volname) = parse_volume_id($volid, 1);
 279     if ($storeid) {
 280         my $scfg = storage_config($cfg, $storeid);
 281         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 282         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 283     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 284         die "snapshot delete file/device '$volid' is not possible\n";
 285     } else {
 286         die "unable to parse volume ID '$volid'\n";
 287     }
 288 }
 289
 290 # check if a filesystem on top of a volume needs to flush its journal for
 291 # consistency (see fsfreeze(8)) before a snapshot is taken - needed for
 292 # container mountpoints
 293 sub volume_snapshot_needs_fsfreeze {
 294     my ($cfg, $volid) = @_;
 295
 296     my ($storeid, $volname) = parse_volume_id($volid);
 297     my $scfg = storage_config($cfg, $storeid);
 298     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 299     return $plugin->volume_snapshot_needs_fsfreeze();
 300 }
 301
 302 # check if a volume or snapshot supports a given feature
 303 # $feature - one of:
 304 #            clone - linked clone is possible
 305 #            copy  - full clone is possible
 306 #            replicate - replication is possible
 307 #            snapshot - taking a snapshot is possible
 308 #            sparseinit - volume is sparsely initialized
 309 #            template - conversion to base image is possible
 310 # $snap - check if the feature is supported for a given snapshot
 311 # $running - if the guest owning the volume is running
 312 # $opts - hash with further options:
 313 #         valid_target_formats - list of formats for the target of a copy/clone
 314 #                                operation that the caller could work with. The
 315 #                                format of $volid is always considered valid and if
 316 #                                no list is specified, all formats are considered valid.
 317 sub volume_has_feature {
 318     my ($cfg, $feature, $volid, $snap, $running, $opts) = @_;
 319
 320     my ($storeid, $volname) = parse_volume_id($volid, 1);
 321     if ($storeid) {
 322         my $scfg = storage_config($cfg, $storeid);
 323         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 324         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running, $opts);
 325     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 326         return undef;
 327     } else {
 328         return undef;
 329     }
 330 }
 331
 332 sub volume_snapshot_list {
 333     my ($cfg, $volid) = @_;
 334
 335     my ($storeid, $volname) = parse_volume_id($volid, 1);
 336     if ($storeid) {
 337         my $scfg = storage_config($cfg, $storeid);
 338         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 339         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 340     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 341         die "send file/device '$volid' is not possible\n";
 342     } else {
 343         die "unable to parse volume ID '$volid'\n";
 344     }
 345     # return an empty array if dataset does not exist.
 346 }
 347
 348 sub get_image_dir {
 349     my ($cfg, $storeid, $vmid) = @_;
 350
 351     my $scfg = storage_config($cfg, $storeid);
 352     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 353
 354     my $path = $plugin->get_subdir($scfg, 'images');
 355
 356     return $vmid ? "$path/$vmid" : $path;
 357 }
 358
 359 sub get_private_dir {
 360     my ($cfg, $storeid, $vmid) = @_;
 361
 362     my $scfg = storage_config($cfg, $storeid);
 363     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 364
 365     my $path = $plugin->get_subdir($scfg, 'rootdir');
 366
 367     return $vmid ? "$path/$vmid" : $path;
 368 }
 369
 370 sub get_iso_dir {
 371     my ($cfg, $storeid) = @_;
 372
 373     my $scfg = storage_config($cfg, $storeid);
 374     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 375
 376     return $plugin->get_subdir($scfg, 'iso');
 377 }
 378
 379 sub get_vztmpl_dir {
 380     my ($cfg, $storeid) = @_;
 381
 382     my $scfg = storage_config($cfg, $storeid);
 383     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 384
 385     return $plugin->get_subdir($scfg, 'vztmpl');
 386 }
 387
 388 sub get_backup_dir {
 389     my ($cfg, $storeid) = @_;
 390
 391     my $scfg = storage_config($cfg, $storeid);
 392     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 393
 394     return $plugin->get_subdir($scfg, 'backup');
 395 }
 396
 397 # library implementation
 398
 399 sub parse_vmid {
 400     my $vmid = shift;
 401
 402     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 403
 404     return int($vmid);
 405 }
 406
 407 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 408 # clone -> base reference is not encoded in the volume ID.
 409 # see note in PVE::Storage::LvmThinPlugin for details.
 410 sub parse_volname {
 411     my ($cfg, $volid) = @_;
 412
 413     my ($storeid, $volname) = parse_volume_id($volid);
 414
 415     my $scfg = storage_config($cfg, $storeid);
 416
 417     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 418
 419     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 420
 421     return $plugin->parse_volname($volname);
 422 }
 423
 424 sub parse_volume_id {
 425     my ($volid, $noerr) = @_;
 426
 427     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 428 }
 429
 430 # test if we have read access to volid
 431 sub check_volume_access {
 432     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 433
 434     my ($sid, $volname) = parse_volume_id($volid, 1);
 435     if ($sid) {
 436         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 437         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 438             # require at least read access to storage, (custom) templates/ISOs could be sensitive
 439             $rpcenv->check_any($user, "/storage/$sid", ['Datastore.AllocateSpace', 'Datastore.Audit']);
 440         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 441             # we are owner - allow access
 442         } elsif ($vtype eq 'backup' && $ownervm) {
 443             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 444             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 445         } else {
 446             # allow if we are Datastore administrator
 447             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 448         }
 449     } else {
 450         die "Only root can pass arbitrary filesystem paths."
 451             if $user ne 'root@pam';
 452     }
 453
 454     return undef;
 455 }
 456
 457 my $volume_is_base_and_used__no_lock = sub {
 458     my ($scfg, $storeid, $plugin, $volname) = @_;
 459
 460     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 461         $plugin->parse_volname($volname);
 462
 463     if ($isBase) {
 464         my $vollist = $plugin->list_images($storeid, $scfg);
 465         foreach my $info (@$vollist) {
 466             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 467             my $basename = undef;
 468             my $basevmid = undef;
 469
 470             eval{
 471                 (undef, undef, undef, $basename, $basevmid) =
 472                     $plugin->parse_volname($tmpvolname);
 473             };
 474
 475             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 476                 return 1;
 477             }
 478         }
 479     }
 480     return 0;
 481 };
 482
 483 # NOTE: this check does not work for LVM-thin, where the clone -> base
 484 # reference is not encoded in the volume ID.
 485 # see note in PVE::Storage::LvmThinPlugin for details.
 486 sub volume_is_base_and_used {
 487     my ($cfg, $volid) = @_;
 488
 489     my ($storeid, $volname) = parse_volume_id($volid);
 490     my $scfg = storage_config($cfg, $storeid);
 491     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 492
 493     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 494         return &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 495     });
 496 }
 497
 498 # try to map a filesystem path to a volume identifier
 499 sub path_to_volume_id {
 500     my ($cfg, $path) = @_;
 501
 502     my $ids = $cfg->{ids};
 503
 504     my ($sid, $volname) = parse_volume_id($path, 1);
 505     if ($sid) {
 506         if (my $scfg = $ids->{$sid}) {
 507             if ($scfg->{path}) {
 508                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 509                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 510                 return ($vtype, $path);
 511             }
 512         }
 513         return ('');
 514     }
 515
 516     # Note: abs_path() return undef if $path doesn not exist
 517     # for example when nfs storage is not mounted
 518     $path = abs_path($path) || $path;
 519
 520     foreach my $sid (keys %$ids) {
 521         my $scfg = $ids->{$sid};
 522         next if !$scfg->{path};
 523         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 524         my $imagedir = $plugin->get_subdir($scfg, 'images');
 525         my $isodir = $plugin->get_subdir($scfg, 'iso');
 526         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 527         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 528         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 529         my $snippetsdir = $plugin->get_subdir($scfg, 'snippets');
 530
 531         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 532             my $vmid = $1;
 533             my $name = $2;
 534
 535             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 536             foreach my $info (@$vollist) {
 537                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 538                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 539                 if ($volpath eq $path) {
 540                     return ('images', $info->{volid});
 541                 }
 542             }
 543         } elsif ($path =~ m!^$isodir/([^/]+$iso_extension_re)$!) {
 544             my $name = $1;
 545             return ('iso', "$sid:iso/$name");
 546         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 547             my $name = $1;
 548             return ('vztmpl', "$sid:vztmpl/$name");
 549         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 550             my $vmid = $1;
 551             return ('rootdir', "$sid:rootdir/$vmid");
 552         } elsif ($path =~ m!^$backupdir/([^/]+\.(?:tgz|(?:(?:tar|vma)(?:\.(?:${\PVE::Storage::Plugin::COMPRESSOR_RE}))?)))$!) {
 553             my $name = $1;
 554             return ('backup', "$sid:backup/$name");
 555         } elsif ($path =~ m!^$snippetsdir/([^/]+)$!) {
 556             my $name = $1;
 557             return ('snippets', "$sid:snippets/$name");
 558         }
 559     }
 560
 561     # can't map path to volume id
 562     return ('');
 563 }
 564
 565 sub path {
 566     my ($cfg, $volid, $snapname) = @_;
 567
 568     my ($storeid, $volname) = parse_volume_id($volid);
 569
 570     my $scfg = storage_config($cfg, $storeid);
 571
 572     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 573     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 574     return wantarray ? ($path, $owner, $vtype) : $path;
 575 }
 576
 577 sub abs_filesystem_path {
 578     my ($cfg, $volid) = @_;
 579
 580     my $path;
 581     if (parse_volume_id ($volid, 1)) {
 582         activate_volumes($cfg, [ $volid ]);
 583         $path = PVE::Storage::path($cfg, $volid);
 584     } else {
 585         if (-f $volid) {
 586             my $abspath = abs_path($volid);
 587             if ($abspath && $abspath =~ m|^(/.+)$|) {
 588                 $path = $1; # untaint any path
 589             }
 590         }
 591     }
 592
 593     die "can't find file '$volid'\n" if !($path && -f $path);
 594
 595     return $path;
 596 }
 597
 598 my $volname_for_storage = sub {
 599     my ($cfg, $volid, $target_storeid) = @_;
 600
 601     my (undef, $name, $vmid, undef, undef, undef, $format) = parse_volname($cfg, $volid);
 602     my $target_scfg = storage_config($cfg, $target_storeid);
 603
 604     my (undef, $valid_formats) = PVE::Storage::Plugin::default_format($target_scfg);
 605     my $format_is_valid = grep { $_ eq $format } @$valid_formats;
 606     die "unsupported format '$format' for storage type $target_scfg->{type}\n" if !$format_is_valid;
 607
 608     (my $name_without_extension = $name) =~ s/\.$format$//;
 609
 610     if ($target_scfg->{path}) {
 611        return "$vmid/$name_without_extension.$format";
 612     } else {
 613        return "$name_without_extension";
 614     }
 615 };
 616
 617 sub storage_migrate {
 618     my ($cfg, $volid, $target_sshinfo, $target_storeid, $opts, $logfunc) = @_;
 619
 620     my $base_snapshot = $opts->{base_snapshot};
 621     my $snapshot = $opts->{snapshot};
 622     my $ratelimit_bps = $opts->{ratelimit_bps};
 623     my $insecure = $opts->{insecure};
 624     my $with_snapshots = $opts->{with_snapshots} ? 1 : 0;
 625     my $allow_rename = $opts->{allow_rename} ? 1 : 0;
 626
 627     my ($storeid, $volname) = parse_volume_id($volid);
 628
 629     my $scfg = storage_config($cfg, $storeid);
 630
 631     # no need to migrate shared content
 632     return $volid if $storeid eq $target_storeid && $scfg->{shared};
 633
 634     my $tcfg = storage_config($cfg, $target_storeid);
 635
 636     my $target_volname;
 637     if ($opts->{target_volname}) {
 638         $target_volname = $opts->{target_volname};
 639     } elsif ($scfg->{type} eq $tcfg->{type}) {
 640         $target_volname = $volname;
 641     } else {
 642         $target_volname = $volname_for_storage->($cfg, $volid, $target_storeid);
 643     }
 644
 645     my $target_volid = "${target_storeid}:${target_volname}";
 646
 647     my $target_ip = $target_sshinfo->{ip};
 648
 649     my $ssh = PVE::SSHInfo::ssh_info_to_command($target_sshinfo);
 650     my $ssh_base = PVE::SSHInfo::ssh_info_to_command_base($target_sshinfo);
 651     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 652
 653     my @cstream;
 654     if (defined($ratelimit_bps)) {
 655         @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ]);
 656         $logfunc->("using a bandwidth limit of $ratelimit_bps bps for transferring '$volid'") if $logfunc;
 657     }
 658
 659     my $migration_snapshot;
 660     if (!defined($snapshot)) {
 661         if ($scfg->{type} eq 'zfspool') {
 662             $migration_snapshot = 1;
 663             $snapshot = '__migration__';
 664         }
 665     }
 666
 667     my @formats = volume_transfer_formats($cfg, $volid, $target_volid, $snapshot, $base_snapshot, $with_snapshots);
 668     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 669     my $format = $formats[0];
 670
 671     my $import_fn = '-'; # let pvesm import read from stdin per default
 672     if ($insecure) {
 673         my $net = $target_sshinfo->{network} // $target_sshinfo->{ip};
 674         $import_fn = "tcp://$net";
 675     }
 676
 677     my $target_apiver = 1; # if there is no apiinfo call, assume 1
 678     my $get_api_version = [@$ssh, 'pvesm', 'apiinfo'];
 679     my $match_api_version = sub { $target_apiver = $1 if $_[0] =~ m!^APIVER (\d+)$!; };
 680     eval { run_command($get_api_version, logfunc => $match_api_version); };
 681
 682     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 683     my $recv = [@$ssh, '--', 'pvesm', 'import', $target_volid, $format, $import_fn, '-with-snapshots', $with_snapshots];
 684     if (defined($snapshot)) {
 685         push @$send, '-snapshot', $snapshot
 686     }
 687     if ($migration_snapshot) {
 688         push @$recv, '-delete-snapshot', $snapshot;
 689     }
 690     push @$recv, '-allow-rename', $allow_rename if $target_apiver >= 5;
 691
 692     if (defined($base_snapshot)) {
 693         # Check if the snapshot exists on the remote side:
 694         push @$send, '-base', $base_snapshot;
 695         push @$recv, '-base', $base_snapshot;
 696     }
 697
 698     my $new_volid;
 699     my $pattern = volume_imported_message(undef, 1);
 700     my $match_volid_and_log = sub {
 701         my $line = shift;
 702
 703         $new_volid = $1 if ($line =~ $pattern);
 704
 705         if ($logfunc) {
 706             chomp($line);
 707             $logfunc->($line);
 708         }
 709     };
 710
 711     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 712
 713     if (defined($snapshot)) {
 714         activate_volumes($cfg, [$volid], $snapshot);
 715     } else {
 716         activate_volumes($cfg, [$volid]);
 717     }
 718
 719     eval {
 720         if ($insecure) {
 721             my $input = IO::File->new();
 722             my $info = IO::File->new();
 723             open3($input, $info, $info, @{$recv})
 724                 or die "receive command failed: $!\n";
 725             close($input);
 726
 727             my ($ip) = <$info> =~ /^($PVE::Tools::IPRE)$/ or die "no tunnel IP received\n";
 728             my ($port) = <$info> =~ /^(\d+)$/ or die "no tunnel port received\n";
 729             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 730                 or die "failed to connect to tunnel at $ip:$port\n";
 731             # we won't be reading from the socket
 732             shutdown($socket, 0);
 733
 734             eval { run_command([$send, @cstream], output => '>&'.fileno($socket), errfunc => $logfunc); };
 735             my $send_error = $@;
 736
 737             # don't close the connection entirely otherwise the receiving end
 738             # might not get all buffered data (and fails with 'connection reset by peer')
 739             shutdown($socket, 1);
 740
 741             # wait for the remote process to finish
 742             while (my $line = <$info>) {
 743                 $match_volid_and_log->("[$target_sshinfo->{name}] $line");
 744             }
 745
 746             # now close the socket
 747             close($socket);
 748             if (!close($info)) { # does waitpid()
 749                 die "import failed: $!\n" if $!;
 750                 die "import failed: exit code ".($?>>8)."\n";
 751             }
 752
 753             die $send_error if $send_error;
 754         } else {
 755             run_command([$send, @cstream, $recv], logfunc => $match_volid_and_log);
 756         }
 757
 758         die "unable to get ID of the migrated volume\n"
 759             if !defined($new_volid) && $target_apiver >= 5;
 760     };
 761     my $err = $@;
 762     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 763     if ($migration_snapshot) {
 764         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 765         warn "could not remove source snapshot: $@\n" if $@;
 766     }
 767     die $err if $err;
 768
 769     return $new_volid // $target_volid;
 770 }
 771
 772 sub vdisk_clone {
 773     my ($cfg, $volid, $vmid, $snap) = @_;
 774
 775     my ($storeid, $volname) = parse_volume_id($volid);
 776
 777     my $scfg = storage_config($cfg, $storeid);
 778
 779     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 780
 781     activate_storage($cfg, $storeid);
 782
 783     # lock shared storage
 784     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 785         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 786         return "$storeid:$volname";
 787     });
 788 }
 789
 790 sub vdisk_create_base {
 791     my ($cfg, $volid) = @_;
 792
 793     my ($storeid, $volname) = parse_volume_id($volid);
 794
 795     my $scfg = storage_config($cfg, $storeid);
 796
 797     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 798
 799     activate_storage($cfg, $storeid);
 800
 801     # lock shared storage
 802     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 803         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 804         return "$storeid:$volname";
 805     });
 806 }
 807
 808 sub map_volume {
 809     my ($cfg, $volid, $snapname) = @_;
 810
 811     my ($storeid, $volname) = parse_volume_id($volid);
 812
 813     my $scfg = storage_config($cfg, $storeid);
 814
 815     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 816
 817     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 818 }
 819
 820 sub unmap_volume {
 821     my ($cfg, $volid, $snapname) = @_;
 822
 823     my ($storeid, $volname) = parse_volume_id($volid);
 824
 825     my $scfg = storage_config($cfg, $storeid);
 826
 827     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 828
 829     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 830 }
 831
 832 sub vdisk_alloc {
 833     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 834
 835     die "no storage ID specified\n" if !$storeid;
 836
 837     PVE::JSONSchema::parse_storage_id($storeid);
 838
 839     my $scfg = storage_config($cfg, $storeid);
 840
 841     die "no VMID specified\n" if !$vmid;
 842
 843     $vmid = parse_vmid($vmid);
 844
 845     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 846
 847     $fmt = $defformat if !$fmt;
 848
 849     activate_storage($cfg, $storeid);
 850
 851     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 852
 853     # lock shared storage
 854     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 855         my $old_umask = umask(umask|0037);
 856         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 857         my $err = $@;
 858         umask $old_umask;
 859         die $err if $err;
 860         return "$storeid:$volname";
 861     });
 862 }
 863
 864 sub vdisk_free {
 865     my ($cfg, $volid) = @_;
 866
 867     my ($storeid, $volname) = parse_volume_id($volid);
 868     my $scfg = storage_config($cfg, $storeid);
 869     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 870
 871     activate_storage($cfg, $storeid);
 872
 873     my $cleanup_worker;
 874
 875     # lock shared storage
 876     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 877         # LVM-thin allows deletion of still referenced base volumes!
 878         die "base volume '$volname' is still in use by linked clones\n"
 879             if &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 880
 881         my (undef, undef, undef, undef, undef, $isBase, $format) =
 882             $plugin->parse_volname($volname);
 883         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 884     });
 885
 886     return if !$cleanup_worker;
 887
 888     my $rpcenv = PVE::RPCEnvironment::get();
 889     my $authuser = $rpcenv->get_user();
 890
 891     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 892 }
 893
 894 sub vdisk_list {
 895     my ($cfg, $storeid, $vmid, $vollist) = @_;
 896
 897     my $ids = $cfg->{ids};
 898
 899     storage_check_enabled($cfg, $storeid) if ($storeid);
 900
 901     my $res = {};
 902
 903     # prepare/activate/refresh all storages
 904
 905     my $storage_list = [];
 906     if ($vollist) {
 907         foreach my $volid (@$vollist) {
 908             my ($sid, undef) = parse_volume_id($volid);
 909             next if !defined($ids->{$sid});
 910             next if !storage_check_enabled($cfg, $sid, undef, 1);
 911             push @$storage_list, $sid;
 912         }
 913     } else {
 914         foreach my $sid (keys %$ids) {
 915             next if $storeid && $storeid ne $sid;
 916             next if !storage_check_enabled($cfg, $sid, undef, 1);
 917             my $content = $ids->{$sid}->{content};
 918             next if !($content->{rootdir} || $content->{images});
 919             push @$storage_list, $sid;
 920         }
 921     }
 922
 923     my $cache = {};
 924
 925     activate_storage_list($cfg, $storage_list, $cache);
 926
 927     foreach my $sid (keys %$ids) {
 928         next if $storeid && $storeid ne $sid;
 929         next if !storage_check_enabled($cfg, $sid, undef, 1);
 930
 931         my $scfg = $ids->{$sid};
 932         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 933         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 934         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 935     }
 936
 937     return $res;
 938 }
 939
 940 sub template_list {
 941     my ($cfg, $storeid, $tt) = @_;
 942
 943     die "unknown template type '$tt'\n"
 944         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup' || $tt eq 'snippets');
 945
 946     my $ids = $cfg->{ids};
 947
 948     storage_check_enabled($cfg, $storeid) if ($storeid);
 949
 950     my $res = {};
 951
 952     # query the storage
 953     foreach my $sid (keys %$ids) {
 954         next if $storeid && $storeid ne $sid;
 955
 956         my $scfg = $ids->{$sid};
 957         my $type = $scfg->{type};
 958
 959         next if !$scfg->{content}->{$tt};
 960
 961         next if !storage_check_enabled($cfg, $sid, undef, 1);
 962
 963         $res->{$sid} = volume_list($cfg, $sid, undef, $tt);
 964     }
 965
 966     return $res;
 967 }
 968
 969 sub volume_list {
 970     my ($cfg, $storeid, $vmid, $content) = @_;
 971
 972     my @ctypes = qw(rootdir images vztmpl iso backup snippets);
 973
 974     my $cts = $content ? [ $content ] : [ @ctypes ];
 975
 976     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 977
 978     $cts = [ grep { defined($scfg->{content}->{$_}) } @$cts ];
 979
 980     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 981
 982     activate_storage($cfg, $storeid);
 983
 984     my $res = $plugin->list_volumes($storeid, $scfg, $vmid, $cts);
 985
 986     @$res = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @$res;
 987
 988     return $res;
 989 }
 990
 991 sub uevent_seqnum {
 992
 993     my $filename = "/sys/kernel/uevent_seqnum";
 994
 995     my $seqnum = 0;
 996     if (my $fh = IO::File->new($filename, "r")) {
 997         my $line = <$fh>;
 998         if ($line =~ m/^(\d+)$/) {
 999             $seqnum = int($1);
1000         }
1001         close ($fh);
1002     }
1003     return $seqnum;
1004 }
1005
1006 sub activate_storage {
1007     my ($cfg, $storeid, $cache) = @_;
1008
1009     $cache = {} if !$cache;
1010
1011     my $scfg = storage_check_enabled($cfg, $storeid);
1012
1013     return if $cache->{activated}->{$storeid};
1014
1015     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
1016
1017     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1018
1019     if ($scfg->{base}) {
1020         my ($baseid, undef) = parse_volume_id ($scfg->{base});
1021         activate_storage($cfg, $baseid, $cache);
1022     }
1023
1024     if (!$plugin->check_connection($storeid, $scfg)) {
1025         die "storage '$storeid' is not online\n";
1026     }
1027
1028     $plugin->activate_storage($storeid, $scfg, $cache);
1029
1030     my $newseq = uevent_seqnum ();
1031
1032     # only call udevsettle if there are events
1033     if ($newseq > $cache->{uevent_seqnum}) {
1034         my $timeout = 30;
1035         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
1036         $cache->{uevent_seqnum} = $newseq;
1037     }
1038
1039     $cache->{activated}->{$storeid} = 1;
1040 }
1041
1042 sub activate_storage_list {
1043     my ($cfg, $storeid_list, $cache) = @_;
1044
1045     $cache = {} if !$cache;
1046
1047     foreach my $storeid (@$storeid_list) {
1048         activate_storage($cfg, $storeid, $cache);
1049     }
1050 }
1051
1052 sub deactivate_storage {
1053     my ($cfg, $storeid) = @_;
1054
1055     my $scfg = storage_config ($cfg, $storeid);
1056     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1057
1058     my $cache = {};
1059     $plugin->deactivate_storage($storeid, $scfg, $cache);
1060 }
1061
1062 sub activate_volumes {
1063     my ($cfg, $vollist, $snapname) = @_;
1064
1065     return if !($vollist && scalar(@$vollist));
1066
1067     my $storagehash = {};
1068     foreach my $volid (@$vollist) {
1069         my ($storeid, undef) = parse_volume_id($volid);
1070         $storagehash->{$storeid} = 1;
1071     }
1072
1073     my $cache = {};
1074
1075     activate_storage_list($cfg, [keys %$storagehash], $cache);
1076
1077     foreach my $volid (@$vollist) {
1078         my ($storeid, $volname) = parse_volume_id($volid);
1079         my $scfg = storage_config($cfg, $storeid);
1080         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1081         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
1082     }
1083 }
1084
1085 sub deactivate_volumes {
1086     my ($cfg, $vollist, $snapname) = @_;
1087
1088     return if !($vollist && scalar(@$vollist));
1089
1090     my $cache = {};
1091
1092     my @errlist = ();
1093     foreach my $volid (@$vollist) {
1094         my ($storeid, $volname) = parse_volume_id($volid);
1095
1096         my $scfg = storage_config($cfg, $storeid);
1097         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1098
1099         eval {
1100             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
1101         };
1102         if (my $err = $@) {
1103             warn $err;
1104             push @errlist, $volid;
1105         }
1106     }
1107
1108     die "volume deactivation failed: " . join(' ', @errlist)
1109         if scalar(@errlist);
1110 }
1111
1112 sub storage_info {
1113     my ($cfg, $content, $includeformat) = @_;
1114
1115     my $ids = $cfg->{ids};
1116
1117     my $info = {};
1118
1119     my @ctypes = PVE::Tools::split_list($content);
1120
1121     my $slist = [];
1122     foreach my $storeid (keys %$ids) {
1123         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1124
1125         if (defined($content)) {
1126             my $want_ctype = 0;
1127             foreach my $ctype (@ctypes) {
1128                 if ($ids->{$storeid}->{content}->{$ctype}) {
1129                     $want_ctype = 1;
1130                     last;
1131                 }
1132             }
1133             next if !$want_ctype || !$storage_enabled;
1134         }
1135
1136         my $type = $ids->{$storeid}->{type};
1137
1138         $info->{$storeid} = {
1139             type => $type,
1140             total => 0,
1141             avail => 0,
1142             used => 0,
1143             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1144             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1145             active => 0,
1146             enabled => $storage_enabled ? 1 : 0,
1147         };
1148
1149         push @$slist, $storeid;
1150     }
1151
1152     my $cache = {};
1153
1154     foreach my $storeid (keys %$ids) {
1155         my $scfg = $ids->{$storeid};
1156
1157         next if !$info->{$storeid};
1158         next if !$info->{$storeid}->{enabled};
1159
1160         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1161         if ($includeformat) {
1162             my $pd = $plugin->plugindata();
1163             $info->{$storeid}->{format} = $pd->{format}
1164                 if $pd->{format};
1165             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1166                 if $pd->{select_existing};
1167         }
1168
1169         eval { activate_storage($cfg, $storeid, $cache); };
1170         if (my $err = $@) {
1171             warn $err;
1172             next;
1173         }
1174
1175         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1176         warn $@ if $@;
1177         next if !$active;
1178         $info->{$storeid}->{total} = int($total);
1179         $info->{$storeid}->{avail} = int($avail);
1180         $info->{$storeid}->{used} = int($used);
1181         $info->{$storeid}->{active} = $active;
1182     }
1183
1184     return $info;
1185 }
1186
1187 sub resolv_server {
1188     my ($server) = @_;
1189
1190     my ($packed_ip, $family);
1191     eval {
1192         my @res = PVE::Tools::getaddrinfo_all($server);
1193         $family = $res[0]->{family};
1194         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1195     };
1196     if (defined $packed_ip) {
1197         return Socket::inet_ntop($family, $packed_ip);
1198     }
1199     return undef;
1200 }
1201
1202 sub scan_nfs {
1203     my ($server_in) = @_;
1204
1205     my $server;
1206     if (!($server = resolv_server ($server_in))) {
1207         die "unable to resolve address for server '${server_in}'\n";
1208     }
1209
1210     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1211
1212     my $res = {};
1213     run_command($cmd, outfunc => sub {
1214         my $line = shift;
1215
1216         # note: howto handle white spaces in export path??
1217         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1218             $res->{$1} = $2;
1219         }
1220     });
1221
1222     return $res;
1223 }
1224
1225 sub scan_cifs {
1226     my ($server_in, $user, $password, $domain) = @_;
1227
1228     my $server = resolv_server($server_in);
1229     die "unable to resolve address for server '${server_in}'\n" if !$server;
1230
1231     # we only support Windows 2012 and newer, so just use smb3
1232     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1233     push @$cmd, '-W', $domain if defined($domain);
1234
1235     push @$cmd, '-N' if !defined($password);
1236     local $ENV{USER} = $user if defined($user);
1237     local $ENV{PASSWD} = $password if defined($password);
1238
1239     my $res = {};
1240     my $err = '';
1241     run_command($cmd,
1242         noerr => 1,
1243         errfunc => sub {
1244             $err .= "$_[0]\n"
1245         },
1246         outfunc => sub {
1247             my $line = shift;
1248             if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1249                 $res->{$1} = $2;
1250             } elsif ($line =~ m/(NT_STATUS_(\S+))/) {
1251                 my $status = $1;
1252                 $err .= "unexpected status: $1\n" if uc($1) ne 'SUCCESS';
1253             }
1254         },
1255     );
1256     # only die if we got no share, else it's just some followup check error
1257     # (like workgroup querying)
1258     raise($err) if $err && !%$res;
1259
1260     return $res;
1261 }
1262
1263 sub scan_zfs {
1264
1265     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-Hp', '-o', 'name,avail,used'];
1266
1267     my $res = [];
1268     run_command($cmd, outfunc => sub {
1269         my $line = shift;
1270
1271         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1272             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1273             my $size = $size_str + 0;
1274             my $used = $used_str + 0;
1275             # ignore subvolumes generated by our ZFSPoolPlugin
1276             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1277             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1278             push @$res, { pool => $pool, size => $size, free => $size-$used };
1279         }
1280     });
1281
1282     return $res;
1283 }
1284
1285 sub resolv_portal {
1286     my ($portal, $noerr) = @_;
1287
1288     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1289     if ($server) {
1290         if (my $ip = resolv_server($server)) {
1291             $server = $ip;
1292             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1293             return $port ? "$server:$port" : $server;
1294         }
1295     }
1296     return undef if $noerr;
1297
1298     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1299 }
1300
1301
1302 sub scan_iscsi {
1303     my ($portal_in) = @_;
1304
1305     my $portal;
1306     if (!($portal = resolv_portal($portal_in))) {
1307         die "unable to parse/resolve portal address '${portal_in}'\n";
1308     }
1309
1310     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1311 }
1312
1313 sub storage_default_format {
1314     my ($cfg, $storeid) = @_;
1315
1316     my $scfg = storage_config ($cfg, $storeid);
1317
1318     return PVE::Storage::Plugin::default_format($scfg);
1319 }
1320
1321 sub vgroup_is_used {
1322     my ($cfg, $vgname) = @_;
1323
1324     foreach my $storeid (keys %{$cfg->{ids}}) {
1325         my $scfg = storage_config($cfg, $storeid);
1326         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1327             return 1;
1328         }
1329     }
1330
1331     return undef;
1332 }
1333
1334 sub target_is_used {
1335     my ($cfg, $target) = @_;
1336
1337     foreach my $storeid (keys %{$cfg->{ids}}) {
1338         my $scfg = storage_config($cfg, $storeid);
1339         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1340             return 1;
1341         }
1342     }
1343
1344     return undef;
1345 }
1346
1347 sub volume_is_used {
1348     my ($cfg, $volid) = @_;
1349
1350     foreach my $storeid (keys %{$cfg->{ids}}) {
1351         my $scfg = storage_config($cfg, $storeid);
1352         if ($scfg->{base} && $scfg->{base} eq $volid) {
1353             return 1;
1354         }
1355     }
1356
1357     return undef;
1358 }
1359
1360 sub storage_is_used {
1361     my ($cfg, $storeid) = @_;
1362
1363     foreach my $sid (keys %{$cfg->{ids}}) {
1364         my $scfg = storage_config($cfg, $sid);
1365         next if !$scfg->{base};
1366         my ($st) = parse_volume_id($scfg->{base});
1367         return 1 if $st && $st eq $storeid;
1368     }
1369
1370     return undef;
1371 }
1372
1373 sub foreach_volid {
1374     my ($list, $func) = @_;
1375
1376     return if !$list;
1377
1378     foreach my $sid (keys %$list) {
1379        foreach my $info (@{$list->{$sid}}) {
1380            my $volid = $info->{volid};
1381            my ($sid1, $volname) = parse_volume_id($volid, 1);
1382            if ($sid1 && $sid1 eq $sid) {
1383                &$func ($volid, $sid, $info);
1384            } else {
1385                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1386            }
1387        }
1388     }
1389 }
1390
1391 sub decompressor_info {
1392     my ($format, $comp) = @_;
1393
1394     if ($format eq 'tgz' && !defined($comp)) {
1395         ($format, $comp) = ('tar', 'gz');
1396     }
1397
1398     my $decompressor = {
1399         tar => {
1400             gz => ['tar', '-z'],
1401             lzo => ['tar', '--lzop'],
1402             zst => ['tar', '--zstd'],
1403         },
1404         vma => {
1405             gz => ['zcat'],
1406             lzo => ['lzop', '-d', '-c'],
1407             zst => ['zstd', '-q', '-d', '-c'],
1408         },
1409     };
1410
1411     die "ERROR: archive format not defined\n"
1412         if !defined($decompressor->{$format});
1413
1414     my $decomp = $decompressor->{$format}->{$comp} if $comp;
1415
1416     my $info = {
1417         format => $format,
1418         compression => $comp,
1419         decompressor => $decomp,
1420     };
1421
1422     return $info;
1423 }
1424
1425 sub archive_info {
1426     my ($archive) = shift;
1427     my $info;
1428
1429     my $volid = basename($archive);
1430     if ($volid =~ /^(vzdump-(lxc|openvz|qemu)-.+\.(tgz$|tar|vma)(?:\.(${\PVE::Storage::Plugin::COMPRESSOR_RE}))?)$/) {
1431         my $filename = "$1"; # untaint
1432         my ($type, $format, $comp) = ($2, $3, $4);
1433         my $format_re = defined($comp) ? "$format.$comp" : "$format";
1434         $info = decompressor_info($format, $comp);
1435         $info->{filename} = $filename;
1436         $info->{type} = $type;
1437
1438         if ($volid =~ /^(vzdump-${type}-([1-9][0-9]{2,8})-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2}))\.${format_re}$/) {
1439             $info->{logfilename} = "$1.log";
1440             $info->{vmid} = int($2);
1441             $info->{ctime} = timelocal($8, $7, $6, $5, $4 - 1, $3);
1442             $info->{is_std_name} = 1;
1443         } else {
1444             $info->{is_std_name} = 0;
1445         }
1446     } else {
1447         die "ERROR: couldn't determine archive info from '$archive'\n";
1448     }
1449
1450     return $info;
1451 }
1452
1453 sub archive_remove {
1454     my ($archive_path) = @_;
1455
1456     my $dirname = dirname($archive_path);
1457     my $archive_info = eval { archive_info($archive_path) } // {};
1458     my $logfn = $archive_info->{logfilename};
1459
1460     unlink $archive_path or die "removing archive $archive_path failed: $!\n";
1461
1462     if (defined($logfn)) {
1463         my $logpath = "$dirname/$logfn";
1464         if (-e $logpath) {
1465             unlink $logpath or warn "removing log file $logpath failed: $!\n";
1466         }
1467     }
1468 }
1469
1470 sub extract_vzdump_config_tar {
1471     my ($archive, $conf_re) = @_;
1472
1473     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1474
1475     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1476        die "unable to open file '$archive'\n";
1477
1478     my $file;
1479     while (defined($file = <$fh>)) {
1480         if ($file =~ $conf_re) {
1481             $file = $1; # untaint
1482             last;
1483         }
1484     }
1485
1486     kill 15, $pid;
1487     waitpid $pid, 0;
1488     close $fh;
1489
1490     die "ERROR: archive contains no configuration file\n" if !$file;
1491     chomp $file;
1492
1493     my $raw = '';
1494     my $out = sub {
1495         my $output = shift;
1496         $raw .= "$output\n";
1497     };
1498
1499     run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1500
1501     return wantarray ? ($raw, $file) : $raw;
1502 }
1503
1504 sub extract_vzdump_config_vma {
1505     my ($archive, $comp) = @_;
1506
1507     my $raw = '';
1508     my $out = sub { $raw .= "$_[0]\n"; };
1509
1510     my $info = archive_info($archive);
1511     $comp //= $info->{compression};
1512     my $decompressor = $info->{decompressor};
1513
1514     if ($comp) {
1515         my $cmd = [ [@$decompressor, $archive], ["vma", "config", "-"] ];
1516
1517         # lzop/zcat exits with 1 when the pipe is closed early by vma, detect this and ignore the exit code later
1518         my $broken_pipe;
1519         my $errstring;
1520         my $err = sub {
1521             my $output = shift;
1522             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/ || $output =~ m/zstd: error 70 : Write error : Broken pipe/) {
1523                 $broken_pipe = 1;
1524             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1525                 $errstring = "Failed to extract config from VMA archive: $output\n";
1526             }
1527         };
1528
1529         my $rc = eval { run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1) };
1530         my $rerr = $@;
1531
1532         $broken_pipe ||= $rc == 141; # broken pipe from vma POV
1533
1534         if (!$errstring && !$broken_pipe && $rc != 0) {
1535             die "$rerr\n" if $rerr;
1536             die "config extraction failed with exit code $rc\n";
1537         }
1538         die "$errstring\n" if $errstring;
1539     } else {
1540         run_command(["vma", "config", $archive], outfunc => $out);
1541     }
1542
1543     return wantarray ? ($raw, undef) : $raw;
1544 }
1545
1546 sub extract_vzdump_config {
1547     my ($cfg, $volid) = @_;
1548
1549     my ($storeid, $volname) = parse_volume_id($volid);
1550     if (defined($storeid)) {
1551         my $scfg = storage_config($cfg, $storeid);
1552         if ($scfg->{type} eq 'pbs') {
1553             storage_check_enabled($cfg, $storeid);
1554             return PVE::Storage::PBSPlugin->extract_vzdump_config($scfg, $volname, $storeid);
1555         }
1556     }
1557
1558     my $archive = abs_filesystem_path($cfg, $volid);
1559     my $info = archive_info($archive);
1560     my $format = $info->{format};
1561     my $comp = $info->{compression};
1562     my $type = $info->{type};
1563
1564     if ($type eq 'lxc' || $type eq 'openvz') {
1565         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1566     } elsif ($type eq 'qemu') {
1567         if ($format eq 'tar') {
1568             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1569         } else {
1570             return extract_vzdump_config_vma($archive, $comp);
1571         }
1572     } else {
1573         die "cannot determine backup guest type for backup archive '$volid'\n";
1574     }
1575 }
1576
1577 sub prune_backups {
1578     my ($cfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc) = @_;
1579
1580     my $scfg = storage_config($cfg, $storeid);
1581     die "storage '$storeid' does not support backups\n" if !$scfg->{content}->{backup};
1582
1583     if (!defined($keep)) {
1584         die "no prune-backups options configured for storage '$storeid'\n"
1585             if !defined($scfg->{'prune-backups'});
1586         $keep = PVE::JSONSchema::parse_property_string('prune-backups', $scfg->{'prune-backups'});
1587     }
1588
1589     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1590     return $plugin->prune_backups($scfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc);
1591 }
1592
1593 my $prune_mark = sub {
1594     my ($prune_entries, $keep_count, $id_func) = @_;
1595
1596     return if !$keep_count;
1597
1598     my $already_included = {};
1599     my $newly_included = {};
1600
1601     foreach my $prune_entry (@{$prune_entries}) {
1602         my $mark = $prune_entry->{mark};
1603         my $id = $id_func->($prune_entry->{ctime});
1604
1605         next if $already_included->{$id};
1606
1607         if (defined($mark)) {
1608             $already_included->{$id} = 1 if $mark eq 'keep';
1609             next;
1610         }
1611
1612         if (!$newly_included->{$id}) {
1613             last if scalar(keys %{$newly_included}) >= $keep_count;
1614             $newly_included->{$id} = 1;
1615             $prune_entry->{mark} = 'keep';
1616         } else {
1617             $prune_entry->{mark} = 'remove';
1618         }
1619     }
1620 };
1621
1622 sub prune_mark_backup_group {
1623     my ($backup_group, $keep) = @_;
1624
1625     if (!scalar(grep {$_ > 0} values %{$keep})) {
1626         foreach my $prune_entry (@{$backup_group}) {
1627             $prune_entry->{mark} = 'keep';
1628         }
1629         return;
1630     }
1631
1632     my $prune_list = [ sort { $b->{ctime} <=> $a->{ctime} } @{$backup_group} ];
1633
1634     $prune_mark->($prune_list, $keep->{'keep-last'}, sub {
1635         my ($ctime) = @_;
1636         return $ctime;
1637     });
1638     $prune_mark->($prune_list, $keep->{'keep-hourly'}, sub {
1639         my ($ctime) = @_;
1640         my (undef, undef, $hour, $day, $month, $year) = localtime($ctime);
1641         return "$hour/$day/$month/$year";
1642     });
1643     $prune_mark->($prune_list, $keep->{'keep-daily'}, sub {
1644         my ($ctime) = @_;
1645         my (undef, undef, undef, $day, $month, $year) = localtime($ctime);
1646         return "$day/$month/$year";
1647     });
1648     $prune_mark->($prune_list, $keep->{'keep-weekly'}, sub {
1649         my ($ctime) = @_;
1650         my ($sec, $min, $hour, $day, $month, $year) = localtime($ctime);
1651         my $iso_week = int(strftime("%V", $sec, $min, $hour, $day, $month - 1, $year - 1900));
1652         my $iso_week_year = int(strftime("%G", $sec, $min, $hour, $day, $month - 1, $year - 1900));
1653         return "$iso_week/$iso_week_year";
1654     });
1655     $prune_mark->($prune_list, $keep->{'keep-monthly'}, sub {
1656         my ($ctime) = @_;
1657         my (undef, undef, undef, undef, $month, $year) = localtime($ctime);
1658         return "$month/$year";
1659     });
1660     $prune_mark->($prune_list, $keep->{'keep-yearly'}, sub {
1661         my ($ctime) = @_;
1662         my $year = (localtime($ctime))[5];
1663         return "$year";
1664     });
1665
1666     foreach my $prune_entry (@{$prune_list}) {
1667         $prune_entry->{mark} //= 'remove';
1668     }
1669 }
1670
1671 sub volume_export {
1672     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1673
1674     my ($storeid, $volname) = parse_volume_id($volid, 1);
1675     die "cannot export volume '$volid'\n" if !$storeid;
1676     my $scfg = storage_config($cfg, $storeid);
1677     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1678     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1679                                   $snapshot, $base_snapshot, $with_snapshots);
1680 }
1681
1682 sub volume_import {
1683     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots, $allow_rename) = @_;
1684
1685     my ($storeid, $volname) = parse_volume_id($volid, 1);
1686     die "cannot import into volume '$volid'\n" if !$storeid;
1687     my $scfg = storage_config($cfg, $storeid);
1688     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1689     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1690                                   $base_snapshot, $with_snapshots, $allow_rename) // $volid;
1691 }
1692
1693 sub volume_export_formats {
1694     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1695
1696     my ($storeid, $volname) = parse_volume_id($volid, 1);
1697     return if !$storeid;
1698     my $scfg = storage_config($cfg, $storeid);
1699     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1700     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1701                                           $snapshot, $base_snapshot,
1702                                           $with_snapshots);
1703 }
1704
1705 sub volume_import_formats {
1706     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1707
1708     my ($storeid, $volname) = parse_volume_id($volid, 1);
1709     return if !$storeid;
1710     my $scfg = storage_config($cfg, $storeid);
1711     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1712     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1713                                           $base_snapshot, $with_snapshots);
1714 }
1715
1716 sub volume_transfer_formats {
1717     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1718     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1719     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1720     my %import_hash = map { $_ => 1 } @import_formats;
1721     my @common = grep { $import_hash{$_} } @export_formats;
1722     return @common;
1723 }
1724
1725 sub volume_imported_message {
1726     my ($volid, $want_pattern) = @_;
1727
1728     if ($want_pattern) {
1729         return qr/successfully imported '([^']*)'$/;
1730     } else {
1731         return "successfully imported '$volid'\n";
1732     }
1733 }
1734
1735 # bash completion helper
1736
1737 sub complete_storage {
1738     my ($cmdname, $pname, $cvalue) = @_;
1739
1740     my $cfg = PVE::Storage::config();
1741
1742     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1743 }
1744
1745 sub complete_storage_enabled {
1746     my ($cmdname, $pname, $cvalue) = @_;
1747
1748     my $res = [];
1749
1750     my $cfg = PVE::Storage::config();
1751     foreach my $sid (keys %{$cfg->{ids}}) {
1752         next if !storage_check_enabled($cfg, $sid, undef, 1);
1753         push @$res, $sid;
1754     }
1755     return $res;
1756 }
1757
1758 sub complete_content_type {
1759     my ($cmdname, $pname, $cvalue) = @_;
1760
1761     return [qw(rootdir images vztmpl iso backup snippets)];
1762 }
1763
1764 sub complete_volume {
1765     my ($cmdname, $pname, $cvalue) = @_;
1766
1767     my $cfg = config();
1768
1769     my $storage_list = complete_storage_enabled();
1770
1771     if ($cvalue =~ m/^([^:]+):/) {
1772         $storage_list = [ $1 ];
1773     } else {
1774         if (scalar(@$storage_list) > 1) {
1775             # only list storage IDs to avoid large listings
1776             my $res = [];
1777             foreach my $storeid (@$storage_list) {
1778                 # Hack: simply return 2 artificial values, so that
1779                 # completions does not finish
1780                 push @$res, "$storeid:volname", "$storeid:...";
1781             }
1782             return $res;
1783         }
1784     }
1785
1786     my $res = [];
1787     foreach my $storeid (@$storage_list) {
1788         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1789
1790         foreach my $item (@$vollist) {
1791             push @$res, $item->{volid};
1792         }
1793     }
1794
1795     return $res;
1796 }
1797
1798 # Various io-heavy operations require io/bandwidth limits which can be
1799 # configured on multiple levels: The global defaults in datacenter.cfg, and
1800 # per-storage overrides. When we want to do a restore from storage A to storage
1801 # B, we should take the smaller limit defined for storages A and B, and if no
1802 # such limit was specified, use the one from datacenter.cfg.
1803 sub get_bandwidth_limit {
1804     my ($operation, $storage_list, $override) = @_;
1805
1806     # called for each limit (global, per-storage) with the 'default' and the
1807     # $operation limit and should udpate $override for every limit affecting
1808     # us.
1809     my $use_global_limits = 0;
1810     my $apply_limit = sub {
1811         my ($bwlimit) = @_;
1812         if (defined($bwlimit)) {
1813             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1814             my $limit = $limits->{$operation} // $limits->{default};
1815             if (defined($limit)) {
1816                 if (!$override || $limit < $override) {
1817                     $override = $limit;
1818                 }
1819                 return;
1820             }
1821         }
1822         # If there was no applicable limit, try to apply the global ones.
1823         $use_global_limits = 1;
1824     };
1825
1826     my ($rpcenv, $authuser);
1827     if (defined($override)) {
1828         $rpcenv = PVE::RPCEnvironment->get();
1829         $authuser = $rpcenv->get_user();
1830     }
1831
1832     # Apply per-storage limits - if there are storages involved.
1833     if (defined($storage_list) && @$storage_list) {
1834         my $config = config();
1835
1836         # The Datastore.Allocate permission allows us to modify the per-storage
1837         # limits, therefore it also allows us to override them.
1838         # Since we have most likely multiple storages to check, do a quick check on
1839         # the general '/storage' path to see if we can skip the checks entirely:
1840         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1841
1842         my %done;
1843         foreach my $storage (@$storage_list) {
1844             next if !defined($storage);
1845             # Avoid duplicate checks:
1846             next if $done{$storage};
1847             $done{$storage} = 1;
1848
1849             # Otherwise we may still have individual /storage/$ID permissions:
1850             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1851                 # And if not: apply the limits.
1852                 my $storecfg = storage_config($config, $storage);
1853                 $apply_limit->($storecfg->{bwlimit});
1854             }
1855         }
1856
1857         # Storage limits take precedence over the datacenter defaults, so if
1858         # a limit was applied:
1859         return $override if !$use_global_limits;
1860     }
1861
1862     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1863     # global default limits.
1864     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1865         # So if we cannot modify global limits, apply them to our currently
1866         # requested override.
1867         my $dc = cfs_read_file('datacenter.cfg');
1868         $apply_limit->($dc->{bwlimit});
1869     }
1870
1871     return $override;
1872 }
1873
1874 # checks if the storage id is available and dies if not
1875 sub assert_sid_unused {
1876     my ($sid) = @_;
1877
1878     my $cfg = config();
1879     if (my $scfg = storage_config($cfg, $sid, 1)) {
1880         die "storage ID '$sid' already defined\n";
1881     }
1882
1883     return undef;
1884 }
1885
1886 1;