PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use File::Basename;
  12 use File::Path;
  13 use Cwd 'abs_path';
  14 use Socket;
  15 use Time::Local qw(timelocal);
  16
  17 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  18 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  19 use PVE::DataCenterConfig;
  20 use PVE::Exception qw(raise_param_exc raise);
  21 use PVE::JSONSchema;
  22 use PVE::INotify;
  23 use PVE::RPCEnvironment;
  24 use PVE::SSHInfo;
  25
  26 use PVE::Storage::Plugin;
  27 use PVE::Storage::DirPlugin;
  28 use PVE::Storage::LVMPlugin;
  29 use PVE::Storage::LvmThinPlugin;
  30 use PVE::Storage::NFSPlugin;
  31 use PVE::Storage::CIFSPlugin;
  32 use PVE::Storage::ISCSIPlugin;
  33 use PVE::Storage::RBDPlugin;
  34 use PVE::Storage::CephFSPlugin;
  35 use PVE::Storage::ISCSIDirectPlugin;
  36 use PVE::Storage::GlusterfsPlugin;
  37 use PVE::Storage::ZFSPoolPlugin;
  38 use PVE::Storage::ZFSPlugin;
  39 use PVE::Storage::DRBDPlugin;
  40 use PVE::Storage::PBSPlugin;
  41
  42 # Storage API version. Icrement it on changes in storage API interface.
  43 use constant APIVER => 5;
  44 # Age is the number of versions we're backward compatible with.
  45 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  46 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  47 use constant APIAGE => 4;
  48
  49 # load standard plugins
  50 PVE::Storage::DirPlugin->register();
  51 PVE::Storage::LVMPlugin->register();
  52 PVE::Storage::LvmThinPlugin->register();
  53 PVE::Storage::NFSPlugin->register();
  54 PVE::Storage::CIFSPlugin->register();
  55 PVE::Storage::ISCSIPlugin->register();
  56 PVE::Storage::RBDPlugin->register();
  57 PVE::Storage::CephFSPlugin->register();
  58 PVE::Storage::ISCSIDirectPlugin->register();
  59 PVE::Storage::GlusterfsPlugin->register();
  60 PVE::Storage::ZFSPoolPlugin->register();
  61 PVE::Storage::ZFSPlugin->register();
  62 PVE::Storage::DRBDPlugin->register();
  63 PVE::Storage::PBSPlugin->register();
  64
  65 # load third-party plugins
  66 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  67     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  68         my ($file) = @_;
  69         my $modname = 'PVE::Storage::Custom::' . $file;
  70         $modname =~ s!\.pm$!!;
  71         $file = 'PVE/Storage/Custom/' . $file;
  72
  73         eval {
  74             require $file;
  75
  76             # Check perl interface:
  77             die "not derived from PVE::Storage::Plugin\n"
  78                 if !$modname->isa('PVE::Storage::Plugin');
  79             die "does not provide an api() method\n"
  80                 if !$modname->can('api');
  81             # Check storage API version and that file is really storage plugin.
  82             my $version = $modname->api();
  83             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  84                 if $version > APIVER;
  85             my $min_version = (APIVER - APIAGE);
  86             die "API version too old, please update the plugin ($version < $min_version)\n"
  87                 if $version < $min_version;
  88             import $file;
  89             $modname->register();
  90
  91             # If we got this far and the API version is not the same, make some
  92             # noise:
  93             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  94                 if $version != APIVER;
  95         };
  96         if ($@) {
  97             warn "Error loading storage plugin \"$modname\": $@";
  98         }
  99     });
 100 }
 101
 102 # initialize all plugins
 103 PVE::Storage::Plugin->init();
 104
 105 my $UDEVADM = '/sbin/udevadm';
 106
 107 our $iso_extension_re = qr/\.(?:iso|img)/i;
 108
 109 #  PVE::Storage utility functions
 110
 111 sub config {
 112     return cfs_read_file("storage.cfg");
 113 }
 114
 115 sub write_config {
 116     my ($cfg) = @_;
 117
 118     cfs_write_file('storage.cfg', $cfg);
 119 }
 120
 121 sub lock_storage_config {
 122     my ($code, $errmsg) = @_;
 123
 124     cfs_lock_file("storage.cfg", undef, $code);
 125     my $err = $@;
 126     if ($err) {
 127         $errmsg ? die "$errmsg: $err" : die $err;
 128     }
 129 }
 130
 131 sub storage_config {
 132     my ($cfg, $storeid, $noerr) = @_;
 133
 134     die "no storage ID specified\n" if !$storeid;
 135
 136     my $scfg = $cfg->{ids}->{$storeid};
 137
 138     die "storage '$storeid' does not exist\n" if (!$noerr && !$scfg);
 139
 140     return $scfg;
 141 }
 142
 143 sub storage_check_node {
 144     my ($cfg, $storeid, $node, $noerr) = @_;
 145
 146     my $scfg = storage_config($cfg, $storeid);
 147
 148     if ($scfg->{nodes}) {
 149         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 150         if (!$scfg->{nodes}->{$node}) {
 151             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 152             return undef;
 153         }
 154     }
 155
 156     return $scfg;
 157 }
 158
 159 sub storage_check_enabled {
 160     my ($cfg, $storeid, $node, $noerr) = @_;
 161
 162     my $scfg = storage_config($cfg, $storeid);
 163
 164     if ($scfg->{disable}) {
 165         die "storage '$storeid' is disabled\n" if !$noerr;
 166         return undef;
 167     }
 168
 169     return storage_check_node($cfg, $storeid, $node, $noerr);
 170 }
 171
 172 # storage_can_replicate:
 173 # return true if storage supports replication
 174 # (volumes alocated with vdisk_alloc() has replication feature)
 175 sub storage_can_replicate {
 176     my ($cfg, $storeid, $format) = @_;
 177
 178     my $scfg = storage_config($cfg, $storeid);
 179     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 180     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 181 }
 182
 183 sub storage_ids {
 184     my ($cfg) = @_;
 185
 186     return keys %{$cfg->{ids}};
 187 }
 188
 189 sub file_size_info {
 190     my ($filename, $timeout) = @_;
 191
 192     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 193 }
 194
 195 sub volume_size_info {
 196     my ($cfg, $volid, $timeout) = @_;
 197
 198     my ($storeid, $volname) = parse_volume_id($volid, 1);
 199     if ($storeid) {
 200         my $scfg = storage_config($cfg, $storeid);
 201         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 202         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 203     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 204         return file_size_info($volid, $timeout);
 205     } else {
 206         return 0;
 207     }
 208 }
 209
 210 sub volume_resize {
 211     my ($cfg, $volid, $size, $running) = @_;
 212
 213     my $padding = (1024 - $size % 1024) % 1024;
 214     $size = $size + $padding;
 215
 216     my ($storeid, $volname) = parse_volume_id($volid, 1);
 217     if ($storeid) {
 218         my $scfg = storage_config($cfg, $storeid);
 219         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 220         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 221     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 222         die "resize file/device '$volid' is not possible\n";
 223     } else {
 224         die "unable to parse volume ID '$volid'\n";
 225     }
 226 }
 227
 228 sub volume_rollback_is_possible {
 229     my ($cfg, $volid, $snap) = @_;
 230
 231     my ($storeid, $volname) = parse_volume_id($volid, 1);
 232     if ($storeid) {
 233         my $scfg = storage_config($cfg, $storeid);
 234         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 235         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 236     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 237         die "snapshot rollback file/device '$volid' is not possible\n";
 238     } else {
 239         die "unable to parse volume ID '$volid'\n";
 240     }
 241 }
 242
 243 sub volume_snapshot {
 244     my ($cfg, $volid, $snap) = @_;
 245
 246     my ($storeid, $volname) = parse_volume_id($volid, 1);
 247     if ($storeid) {
 248         my $scfg = storage_config($cfg, $storeid);
 249         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 250         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 251     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 252         die "snapshot file/device '$volid' is not possible\n";
 253     } else {
 254         die "unable to parse volume ID '$volid'\n";
 255     }
 256 }
 257
 258 sub volume_snapshot_rollback {
 259     my ($cfg, $volid, $snap) = @_;
 260
 261     my ($storeid, $volname) = parse_volume_id($volid, 1);
 262     if ($storeid) {
 263         my $scfg = storage_config($cfg, $storeid);
 264         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 265         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 266         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 267     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 268         die "snapshot rollback file/device '$volid' is not possible\n";
 269     } else {
 270         die "unable to parse volume ID '$volid'\n";
 271     }
 272 }
 273
 274 sub volume_snapshot_delete {
 275     my ($cfg, $volid, $snap, $running) = @_;
 276
 277     my ($storeid, $volname) = parse_volume_id($volid, 1);
 278     if ($storeid) {
 279         my $scfg = storage_config($cfg, $storeid);
 280         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 281         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 282     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 283         die "snapshot delete file/device '$volid' is not possible\n";
 284     } else {
 285         die "unable to parse volume ID '$volid'\n";
 286     }
 287 }
 288
 289 # check if a volume or snapshot supports a given feature
 290 # $feature - one of:
 291 #            clone - linked clone is possible
 292 #            copy  - full clone is possible
 293 #            replicate - replication is possible
 294 #            snapshot - taking a snapshot is possible
 295 #            sparseinit - volume is sparsely initialized
 296 #            template - conversion to base image is possible
 297 # $snap - check if the feature is supported for a given snapshot
 298 # $running - if the guest owning the volume is running
 299 # $opts - hash with further options:
 300 #         valid_target_formats - list of formats for the target of a copy/clone
 301 #                                operation that the caller could work with. The
 302 #                                format of $volid is always considered valid and if
 303 #                                no list is specified, all formats are considered valid.
 304 sub volume_has_feature {
 305     my ($cfg, $feature, $volid, $snap, $running, $opts) = @_;
 306
 307     my ($storeid, $volname) = parse_volume_id($volid, 1);
 308     if ($storeid) {
 309         my $scfg = storage_config($cfg, $storeid);
 310         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 311         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running, $opts);
 312     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 313         return undef;
 314     } else {
 315         return undef;
 316     }
 317 }
 318
 319 sub volume_snapshot_list {
 320     my ($cfg, $volid) = @_;
 321
 322     my ($storeid, $volname) = parse_volume_id($volid, 1);
 323     if ($storeid) {
 324         my $scfg = storage_config($cfg, $storeid);
 325         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 326         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 327     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 328         die "send file/device '$volid' is not possible\n";
 329     } else {
 330         die "unable to parse volume ID '$volid'\n";
 331     }
 332     # return an empty array if dataset does not exist.
 333 }
 334
 335 sub get_image_dir {
 336     my ($cfg, $storeid, $vmid) = @_;
 337
 338     my $scfg = storage_config($cfg, $storeid);
 339     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 340
 341     my $path = $plugin->get_subdir($scfg, 'images');
 342
 343     return $vmid ? "$path/$vmid" : $path;
 344 }
 345
 346 sub get_private_dir {
 347     my ($cfg, $storeid, $vmid) = @_;
 348
 349     my $scfg = storage_config($cfg, $storeid);
 350     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 351
 352     my $path = $plugin->get_subdir($scfg, 'rootdir');
 353
 354     return $vmid ? "$path/$vmid" : $path;
 355 }
 356
 357 sub get_iso_dir {
 358     my ($cfg, $storeid) = @_;
 359
 360     my $scfg = storage_config($cfg, $storeid);
 361     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 362
 363     return $plugin->get_subdir($scfg, 'iso');
 364 }
 365
 366 sub get_vztmpl_dir {
 367     my ($cfg, $storeid) = @_;
 368
 369     my $scfg = storage_config($cfg, $storeid);
 370     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 371
 372     return $plugin->get_subdir($scfg, 'vztmpl');
 373 }
 374
 375 sub get_backup_dir {
 376     my ($cfg, $storeid) = @_;
 377
 378     my $scfg = storage_config($cfg, $storeid);
 379     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 380
 381     return $plugin->get_subdir($scfg, 'backup');
 382 }
 383
 384 # library implementation
 385
 386 sub parse_vmid {
 387     my $vmid = shift;
 388
 389     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 390
 391     return int($vmid);
 392 }
 393
 394 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 395 # clone -> base reference is not encoded in the volume ID.
 396 # see note in PVE::Storage::LvmThinPlugin for details.
 397 sub parse_volname {
 398     my ($cfg, $volid) = @_;
 399
 400     my ($storeid, $volname) = parse_volume_id($volid);
 401
 402     my $scfg = storage_config($cfg, $storeid);
 403
 404     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 405
 406     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 407
 408     return $plugin->parse_volname($volname);
 409 }
 410
 411 sub parse_volume_id {
 412     my ($volid, $noerr) = @_;
 413
 414     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 415 }
 416
 417 # test if we have read access to volid
 418 sub check_volume_access {
 419     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 420
 421     my ($sid, $volname) = parse_volume_id($volid, 1);
 422     if ($sid) {
 423         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 424         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 425             # require at least read access to storage, (custom) templates/ISOs could be sensitive
 426             $rpcenv->check_any($user, "/storage/$sid", ['Datastore.AllocateSpace', 'Datastore.Audit']);
 427         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 428             # we are owner - allow access
 429         } elsif ($vtype eq 'backup' && $ownervm) {
 430             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 431             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 432         } else {
 433             # allow if we are Datastore administrator
 434             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 435         }
 436     } else {
 437         die "Only root can pass arbitrary filesystem paths."
 438             if $user ne 'root@pam';
 439     }
 440
 441     return undef;
 442 }
 443
 444 my $volume_is_base_and_used__no_lock = sub {
 445     my ($scfg, $storeid, $plugin, $volname) = @_;
 446
 447     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 448         $plugin->parse_volname($volname);
 449
 450     if ($isBase) {
 451         my $vollist = $plugin->list_images($storeid, $scfg);
 452         foreach my $info (@$vollist) {
 453             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 454             my $basename = undef;
 455             my $basevmid = undef;
 456
 457             eval{
 458                 (undef, undef, undef, $basename, $basevmid) =
 459                     $plugin->parse_volname($tmpvolname);
 460             };
 461
 462             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 463                 return 1;
 464             }
 465         }
 466     }
 467     return 0;
 468 };
 469
 470 # NOTE: this check does not work for LVM-thin, where the clone -> base
 471 # reference is not encoded in the volume ID.
 472 # see note in PVE::Storage::LvmThinPlugin for details.
 473 sub volume_is_base_and_used {
 474     my ($cfg, $volid) = @_;
 475
 476     my ($storeid, $volname) = parse_volume_id($volid);
 477     my $scfg = storage_config($cfg, $storeid);
 478     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 479
 480     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 481         return &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 482     });
 483 }
 484
 485 # try to map a filesystem path to a volume identifier
 486 sub path_to_volume_id {
 487     my ($cfg, $path) = @_;
 488
 489     my $ids = $cfg->{ids};
 490
 491     my ($sid, $volname) = parse_volume_id($path, 1);
 492     if ($sid) {
 493         if (my $scfg = $ids->{$sid}) {
 494             if ($scfg->{path}) {
 495                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 496                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 497                 return ($vtype, $path);
 498             }
 499         }
 500         return ('');
 501     }
 502
 503     # Note: abs_path() return undef if $path doesn not exist
 504     # for example when nfs storage is not mounted
 505     $path = abs_path($path) || $path;
 506
 507     foreach my $sid (keys %$ids) {
 508         my $scfg = $ids->{$sid};
 509         next if !$scfg->{path};
 510         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 511         my $imagedir = $plugin->get_subdir($scfg, 'images');
 512         my $isodir = $plugin->get_subdir($scfg, 'iso');
 513         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 514         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 515         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 516         my $snippetsdir = $plugin->get_subdir($scfg, 'snippets');
 517
 518         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 519             my $vmid = $1;
 520             my $name = $2;
 521
 522             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 523             foreach my $info (@$vollist) {
 524                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 525                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 526                 if ($volpath eq $path) {
 527                     return ('images', $info->{volid});
 528                 }
 529             }
 530         } elsif ($path =~ m!^$isodir/([^/]+$iso_extension_re)$!) {
 531             my $name = $1;
 532             return ('iso', "$sid:iso/$name");
 533         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 534             my $name = $1;
 535             return ('vztmpl', "$sid:vztmpl/$name");
 536         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 537             my $vmid = $1;
 538             return ('rootdir', "$sid:rootdir/$vmid");
 539         } elsif ($path =~ m!^$backupdir/([^/]+\.(?:tgz|(?:(?:tar|vma)(?:\.(?:${\PVE::Storage::Plugin::COMPRESSOR_RE}))?)))$!) {
 540             my $name = $1;
 541             return ('backup', "$sid:backup/$name");
 542         } elsif ($path =~ m!^$snippetsdir/([^/]+)$!) {
 543             my $name = $1;
 544             return ('snippets', "$sid:snippets/$name");
 545         }
 546     }
 547
 548     # can't map path to volume id
 549     return ('');
 550 }
 551
 552 sub path {
 553     my ($cfg, $volid, $snapname) = @_;
 554
 555     my ($storeid, $volname) = parse_volume_id($volid);
 556
 557     my $scfg = storage_config($cfg, $storeid);
 558
 559     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 560     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 561     return wantarray ? ($path, $owner, $vtype) : $path;
 562 }
 563
 564 sub abs_filesystem_path {
 565     my ($cfg, $volid) = @_;
 566
 567     my $path;
 568     if (parse_volume_id ($volid, 1)) {
 569         activate_volumes($cfg, [ $volid ]);
 570         $path = PVE::Storage::path($cfg, $volid);
 571     } else {
 572         if (-f $volid) {
 573             my $abspath = abs_path($volid);
 574             if ($abspath && $abspath =~ m|^(/.+)$|) {
 575                 $path = $1; # untaint any path
 576             }
 577         }
 578     }
 579
 580     die "can't find file '$volid'\n" if !($path && -f $path);
 581
 582     return $path;
 583 }
 584
 585 my $volname_for_storage = sub {
 586     my ($cfg, $volid, $target_storeid) = @_;
 587
 588     my (undef, $name, $vmid, undef, undef, undef, $format) = parse_volname($cfg, $volid);
 589     my $target_scfg = storage_config($cfg, $target_storeid);
 590
 591     my (undef, $valid_formats) = PVE::Storage::Plugin::default_format($target_scfg);
 592     my $format_is_valid = grep { $_ eq $format } @$valid_formats;
 593     die "unsupported format '$format' for storage type $target_scfg->{type}\n" if !$format_is_valid;
 594
 595     (my $name_without_extension = $name) =~ s/\.$format$//;
 596
 597     if ($target_scfg->{path}) {
 598        return "$vmid/$name_without_extension.$format";
 599     } else {
 600        return "$name_without_extension";
 601     }
 602 };
 603
 604 sub storage_migrate {
 605     my ($cfg, $volid, $target_sshinfo, $target_storeid, $opts, $logfunc) = @_;
 606
 607     my $base_snapshot = $opts->{base_snapshot};
 608     my $snapshot = $opts->{snapshot};
 609     my $ratelimit_bps = $opts->{ratelimit_bps};
 610     my $insecure = $opts->{insecure};
 611     my $with_snapshots = $opts->{with_snapshots} ? 1 : 0;
 612     my $allow_rename = $opts->{allow_rename} ? 1 : 0;
 613
 614     my ($storeid, $volname) = parse_volume_id($volid);
 615
 616     my $scfg = storage_config($cfg, $storeid);
 617
 618     # no need to migrate shared content
 619     return $volid if $storeid eq $target_storeid && $scfg->{shared};
 620
 621     my $tcfg = storage_config($cfg, $target_storeid);
 622
 623     my $target_volname;
 624     if ($opts->{target_volname}) {
 625         $target_volname = $opts->{target_volname};
 626     } elsif ($scfg->{type} eq $tcfg->{type}) {
 627         $target_volname = $volname;
 628     } else {
 629         $target_volname = $volname_for_storage->($cfg, $volid, $target_storeid);
 630     }
 631
 632     my $target_volid = "${target_storeid}:${target_volname}";
 633
 634     my $target_ip = $target_sshinfo->{ip};
 635
 636     my $ssh = PVE::SSHInfo::ssh_info_to_command($target_sshinfo);
 637     my $ssh_base = PVE::SSHInfo::ssh_info_to_command_base($target_sshinfo);
 638     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 639
 640     my @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ])
 641         if defined($ratelimit_bps);
 642
 643     my $migration_snapshot;
 644     if (!defined($snapshot)) {
 645         if ($scfg->{type} eq 'zfspool') {
 646             $migration_snapshot = 1;
 647             $snapshot = '__migration__';
 648         }
 649     }
 650
 651     my @formats = volume_transfer_formats($cfg, $volid, $target_volid, $snapshot, $base_snapshot, $with_snapshots);
 652     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 653     my $format = $formats[0];
 654
 655     my $import_fn = '-'; # let pvesm import read from stdin per default
 656     if ($insecure) {
 657         my $net = $target_sshinfo->{network} // $target_sshinfo->{ip};
 658         $import_fn = "tcp://$net";
 659     }
 660
 661     my $target_apiver = 1; # if there is no apiinfo call, assume 1
 662     my $get_api_version = [@$ssh, 'pvesm', 'apiinfo'];
 663     my $match_api_version = sub { $target_apiver = $1 if $_[0] =~ m!^APIVER (\d+)$!; };
 664     eval { run_command($get_api_version, logfunc => $match_api_version); };
 665
 666     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 667     my $recv = [@$ssh, '--', 'pvesm', 'import', $target_volid, $format, $import_fn, '-with-snapshots', $with_snapshots];
 668     if (defined($snapshot)) {
 669         push @$send, '-snapshot', $snapshot
 670     }
 671     if ($migration_snapshot) {
 672         push @$recv, '-delete-snapshot', $snapshot;
 673     }
 674     push @$recv, '-allow-rename', $allow_rename if $target_apiver >= 5;
 675
 676     if (defined($base_snapshot)) {
 677         # Check if the snapshot exists on the remote side:
 678         push @$send, '-base', $base_snapshot;
 679         push @$recv, '-base', $base_snapshot;
 680     }
 681
 682     my $new_volid;
 683     my $pattern = volume_imported_message(undef, 1);
 684     my $match_volid_and_log = sub {
 685         my $line = shift;
 686
 687         $new_volid = $1 if ($line =~ $pattern);
 688
 689         if ($logfunc) {
 690             chomp($line);
 691             $logfunc->($line);
 692         }
 693     };
 694
 695     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 696     eval {
 697         if ($insecure) {
 698             open(my $info, '-|', @$recv)
 699                 or die "receive command failed: $!\n";
 700             my ($ip) = <$info> =~ /^($PVE::Tools::IPRE)$/ or die "no tunnel IP received\n";
 701             my ($port) = <$info> =~ /^(\d+)$/ or die "no tunnel port received\n";
 702             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 703                 or die "failed to connect to tunnel at $ip:$port\n";
 704             # we won't be reading from the socket
 705             shutdown($socket, 0);
 706             run_command([$send, @cstream], output => '>&'.fileno($socket), errfunc => $logfunc);
 707             # don't close the connection entirely otherwise the receiving end
 708             # might not get all buffered data (and fails with 'connection reset by peer')
 709             shutdown($socket, 1);
 710
 711             # wait for the remote process to finish
 712             while (my $line = <$info>) {
 713                 $match_volid_and_log->("[$target_sshinfo->{name}] $line");
 714             }
 715
 716             # now close the socket
 717             close($socket);
 718             if (!close($info)) { # does waitpid()
 719                 die "import failed: $!\n" if $!;
 720                 die "import failed: exit code ".($?>>8)."\n";
 721             }
 722         } else {
 723             run_command([$send, @cstream, $recv], logfunc => $match_volid_and_log);
 724         }
 725
 726         die "unable to get ID of the migrated volume\n"
 727             if !defined($new_volid) && $target_apiver >= 5;
 728     };
 729     my $err = $@;
 730     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 731     if ($migration_snapshot) {
 732         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 733         warn "could not remove source snapshot: $@\n" if $@;
 734     }
 735     die $err if $err;
 736
 737     return $new_volid // $target_volid;
 738 }
 739
 740 sub vdisk_clone {
 741     my ($cfg, $volid, $vmid, $snap) = @_;
 742
 743     my ($storeid, $volname) = parse_volume_id($volid);
 744
 745     my $scfg = storage_config($cfg, $storeid);
 746
 747     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 748
 749     activate_storage($cfg, $storeid);
 750
 751     # lock shared storage
 752     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 753         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 754         return "$storeid:$volname";
 755     });
 756 }
 757
 758 sub vdisk_create_base {
 759     my ($cfg, $volid) = @_;
 760
 761     my ($storeid, $volname) = parse_volume_id($volid);
 762
 763     my $scfg = storage_config($cfg, $storeid);
 764
 765     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 766
 767     activate_storage($cfg, $storeid);
 768
 769     # lock shared storage
 770     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 771         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 772         return "$storeid:$volname";
 773     });
 774 }
 775
 776 sub map_volume {
 777     my ($cfg, $volid, $snapname) = @_;
 778
 779     my ($storeid, $volname) = parse_volume_id($volid);
 780
 781     my $scfg = storage_config($cfg, $storeid);
 782
 783     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 784
 785     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 786 }
 787
 788 sub unmap_volume {
 789     my ($cfg, $volid, $snapname) = @_;
 790
 791     my ($storeid, $volname) = parse_volume_id($volid);
 792
 793     my $scfg = storage_config($cfg, $storeid);
 794
 795     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 796
 797     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 798 }
 799
 800 sub vdisk_alloc {
 801     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 802
 803     die "no storage ID specified\n" if !$storeid;
 804
 805     PVE::JSONSchema::parse_storage_id($storeid);
 806
 807     my $scfg = storage_config($cfg, $storeid);
 808
 809     die "no VMID specified\n" if !$vmid;
 810
 811     $vmid = parse_vmid($vmid);
 812
 813     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 814
 815     $fmt = $defformat if !$fmt;
 816
 817     activate_storage($cfg, $storeid);
 818
 819     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 820
 821     # lock shared storage
 822     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 823         my $old_umask = umask(umask|0037);
 824         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 825         my $err = $@;
 826         umask $old_umask;
 827         die $err if $err;
 828         return "$storeid:$volname";
 829     });
 830 }
 831
 832 sub vdisk_free {
 833     my ($cfg, $volid) = @_;
 834
 835     my ($storeid, $volname) = parse_volume_id($volid);
 836     my $scfg = storage_config($cfg, $storeid);
 837     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 838
 839     activate_storage($cfg, $storeid);
 840
 841     my $cleanup_worker;
 842
 843     # lock shared storage
 844     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 845         # LVM-thin allows deletion of still referenced base volumes!
 846         die "base volume '$volname' is still in use by linked clones\n"
 847             if &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 848
 849         my (undef, undef, undef, undef, undef, $isBase, $format) =
 850             $plugin->parse_volname($volname);
 851         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 852     });
 853
 854     return if !$cleanup_worker;
 855
 856     my $rpcenv = PVE::RPCEnvironment::get();
 857     my $authuser = $rpcenv->get_user();
 858
 859     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 860 }
 861
 862 sub vdisk_list {
 863     my ($cfg, $storeid, $vmid, $vollist) = @_;
 864
 865     my $ids = $cfg->{ids};
 866
 867     storage_check_enabled($cfg, $storeid) if ($storeid);
 868
 869     my $res = {};
 870
 871     # prepare/activate/refresh all storages
 872
 873     my $storage_list = [];
 874     if ($vollist) {
 875         foreach my $volid (@$vollist) {
 876             my ($sid, undef) = parse_volume_id($volid);
 877             next if !defined($ids->{$sid});
 878             next if !storage_check_enabled($cfg, $sid, undef, 1);
 879             push @$storage_list, $sid;
 880         }
 881     } else {
 882         foreach my $sid (keys %$ids) {
 883             next if $storeid && $storeid ne $sid;
 884             next if !storage_check_enabled($cfg, $sid, undef, 1);
 885             push @$storage_list, $sid;
 886         }
 887     }
 888
 889     my $cache = {};
 890
 891     activate_storage_list($cfg, $storage_list, $cache);
 892
 893     foreach my $sid (keys %$ids) {
 894         next if $storeid && $storeid ne $sid;
 895         next if !storage_check_enabled($cfg, $sid, undef, 1);
 896
 897         my $scfg = $ids->{$sid};
 898         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 899         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 900         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 901     }
 902
 903     return $res;
 904 }
 905
 906 sub template_list {
 907     my ($cfg, $storeid, $tt) = @_;
 908
 909     die "unknown template type '$tt'\n"
 910         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup' || $tt eq 'snippets');
 911
 912     my $ids = $cfg->{ids};
 913
 914     storage_check_enabled($cfg, $storeid) if ($storeid);
 915
 916     my $res = {};
 917
 918     # query the storage
 919     foreach my $sid (keys %$ids) {
 920         next if $storeid && $storeid ne $sid;
 921
 922         my $scfg = $ids->{$sid};
 923         my $type = $scfg->{type};
 924
 925         next if !$scfg->{content}->{$tt};
 926
 927         next if !storage_check_enabled($cfg, $sid, undef, 1);
 928
 929         $res->{$sid} = volume_list($cfg, $sid, undef, $tt);
 930     }
 931
 932     return $res;
 933 }
 934
 935 sub volume_list {
 936     my ($cfg, $storeid, $vmid, $content) = @_;
 937
 938     my @ctypes = qw(rootdir images vztmpl iso backup snippets);
 939
 940     my $cts = $content ? [ $content ] : [ @ctypes ];
 941
 942     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 943
 944     $cts = [ grep { defined($scfg->{content}->{$_}) } @$cts ];
 945
 946     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 947
 948     activate_storage($cfg, $storeid);
 949
 950     my $res = $plugin->list_volumes($storeid, $scfg, $vmid, $cts);
 951
 952     @$res = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @$res;
 953
 954     return $res;
 955 }
 956
 957 sub uevent_seqnum {
 958
 959     my $filename = "/sys/kernel/uevent_seqnum";
 960
 961     my $seqnum = 0;
 962     if (my $fh = IO::File->new($filename, "r")) {
 963         my $line = <$fh>;
 964         if ($line =~ m/^(\d+)$/) {
 965             $seqnum = int($1);
 966         }
 967         close ($fh);
 968     }
 969     return $seqnum;
 970 }
 971
 972 sub activate_storage {
 973     my ($cfg, $storeid, $cache) = @_;
 974
 975     $cache = {} if !$cache;
 976
 977     my $scfg = storage_check_enabled($cfg, $storeid);
 978
 979     return if $cache->{activated}->{$storeid};
 980
 981     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 982
 983     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 984
 985     if ($scfg->{base}) {
 986         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 987         activate_storage($cfg, $baseid, $cache);
 988     }
 989
 990     if (!$plugin->check_connection($storeid, $scfg)) {
 991         die "storage '$storeid' is not online\n";
 992     }
 993
 994     $plugin->activate_storage($storeid, $scfg, $cache);
 995
 996     my $newseq = uevent_seqnum ();
 997
 998     # only call udevsettle if there are events
 999     if ($newseq > $cache->{uevent_seqnum}) {
1000         my $timeout = 30;
1001         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
1002         $cache->{uevent_seqnum} = $newseq;
1003     }
1004
1005     $cache->{activated}->{$storeid} = 1;
1006 }
1007
1008 sub activate_storage_list {
1009     my ($cfg, $storeid_list, $cache) = @_;
1010
1011     $cache = {} if !$cache;
1012
1013     foreach my $storeid (@$storeid_list) {
1014         activate_storage($cfg, $storeid, $cache);
1015     }
1016 }
1017
1018 sub deactivate_storage {
1019     my ($cfg, $storeid) = @_;
1020
1021     my $scfg = storage_config ($cfg, $storeid);
1022     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1023
1024     my $cache = {};
1025     $plugin->deactivate_storage($storeid, $scfg, $cache);
1026 }
1027
1028 sub activate_volumes {
1029     my ($cfg, $vollist, $snapname) = @_;
1030
1031     return if !($vollist && scalar(@$vollist));
1032
1033     my $storagehash = {};
1034     foreach my $volid (@$vollist) {
1035         my ($storeid, undef) = parse_volume_id($volid);
1036         $storagehash->{$storeid} = 1;
1037     }
1038
1039     my $cache = {};
1040
1041     activate_storage_list($cfg, [keys %$storagehash], $cache);
1042
1043     foreach my $volid (@$vollist) {
1044         my ($storeid, $volname) = parse_volume_id($volid);
1045         my $scfg = storage_config($cfg, $storeid);
1046         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1047         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
1048     }
1049 }
1050
1051 sub deactivate_volumes {
1052     my ($cfg, $vollist, $snapname) = @_;
1053
1054     return if !($vollist && scalar(@$vollist));
1055
1056     my $cache = {};
1057
1058     my @errlist = ();
1059     foreach my $volid (@$vollist) {
1060         my ($storeid, $volname) = parse_volume_id($volid);
1061
1062         my $scfg = storage_config($cfg, $storeid);
1063         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1064
1065         eval {
1066             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
1067         };
1068         if (my $err = $@) {
1069             warn $err;
1070             push @errlist, $volid;
1071         }
1072     }
1073
1074     die "volume deactivation failed: " . join(' ', @errlist)
1075         if scalar(@errlist);
1076 }
1077
1078 sub storage_info {
1079     my ($cfg, $content, $includeformat) = @_;
1080
1081     my $ids = $cfg->{ids};
1082
1083     my $info = {};
1084
1085     my @ctypes = PVE::Tools::split_list($content);
1086
1087     my $slist = [];
1088     foreach my $storeid (keys %$ids) {
1089         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1090
1091         if (defined($content)) {
1092             my $want_ctype = 0;
1093             foreach my $ctype (@ctypes) {
1094                 if ($ids->{$storeid}->{content}->{$ctype}) {
1095                     $want_ctype = 1;
1096                     last;
1097                 }
1098             }
1099             next if !$want_ctype || !$storage_enabled;
1100         }
1101
1102         my $type = $ids->{$storeid}->{type};
1103
1104         $info->{$storeid} = {
1105             type => $type,
1106             total => 0,
1107             avail => 0,
1108             used => 0,
1109             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1110             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1111             active => 0,
1112             enabled => $storage_enabled ? 1 : 0,
1113         };
1114
1115         push @$slist, $storeid;
1116     }
1117
1118     my $cache = {};
1119
1120     foreach my $storeid (keys %$ids) {
1121         my $scfg = $ids->{$storeid};
1122
1123         next if !$info->{$storeid};
1124         next if !$info->{$storeid}->{enabled};
1125
1126         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1127         if ($includeformat) {
1128             my $pd = $plugin->plugindata();
1129             $info->{$storeid}->{format} = $pd->{format}
1130                 if $pd->{format};
1131             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1132                 if $pd->{select_existing};
1133         }
1134
1135         eval { activate_storage($cfg, $storeid, $cache); };
1136         if (my $err = $@) {
1137             warn $err;
1138             next;
1139         }
1140
1141         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1142         warn $@ if $@;
1143         next if !$active;
1144         $info->{$storeid}->{total} = int($total);
1145         $info->{$storeid}->{avail} = int($avail);
1146         $info->{$storeid}->{used} = int($used);
1147         $info->{$storeid}->{active} = $active;
1148     }
1149
1150     return $info;
1151 }
1152
1153 sub resolv_server {
1154     my ($server) = @_;
1155
1156     my ($packed_ip, $family);
1157     eval {
1158         my @res = PVE::Tools::getaddrinfo_all($server);
1159         $family = $res[0]->{family};
1160         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1161     };
1162     if (defined $packed_ip) {
1163         return Socket::inet_ntop($family, $packed_ip);
1164     }
1165     return undef;
1166 }
1167
1168 sub scan_nfs {
1169     my ($server_in) = @_;
1170
1171     my $server;
1172     if (!($server = resolv_server ($server_in))) {
1173         die "unable to resolve address for server '${server_in}'\n";
1174     }
1175
1176     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1177
1178     my $res = {};
1179     run_command($cmd, outfunc => sub {
1180         my $line = shift;
1181
1182         # note: howto handle white spaces in export path??
1183         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1184             $res->{$1} = $2;
1185         }
1186     });
1187
1188     return $res;
1189 }
1190
1191 sub scan_cifs {
1192     my ($server_in, $user, $password, $domain) = @_;
1193
1194     my $server = resolv_server($server_in);
1195     die "unable to resolve address for server '${server_in}'\n" if !$server;
1196
1197     # we only support Windows 2012 and newer, so just use smb3
1198     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1199     push @$cmd, '-W', $domain if defined($domain);
1200
1201     push @$cmd, '-N' if !defined($password);
1202     local $ENV{USER} = $user if defined($user);
1203     local $ENV{PASSWD} = $password if defined($password);
1204
1205     my $res = {};
1206     my $err = '';
1207     run_command($cmd,
1208         noerr => 1,
1209         errfunc => sub {
1210             $err .= "$_[0]\n"
1211         },
1212         outfunc => sub {
1213             my $line = shift;
1214             if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1215                 $res->{$1} = $2;
1216             } elsif ($line =~ m/(NT_STATUS_(\S+))/) {
1217                 my $status = $1;
1218                 $err .= "unexpected status: $1\n" if uc($1) ne 'SUCCESS';
1219             }
1220         },
1221     );
1222     # only die if we got no share, else it's just some followup check error
1223     # (like workgroup querying)
1224     raise($err) if $err && !%$res;
1225
1226     return $res;
1227 }
1228
1229 sub scan_zfs {
1230
1231     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-Hp', '-o', 'name,avail,used'];
1232
1233     my $res = [];
1234     run_command($cmd, outfunc => sub {
1235         my $line = shift;
1236
1237         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1238             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1239             my $size = $size_str + 0;
1240             my $used = $used_str + 0;
1241             # ignore subvolumes generated by our ZFSPoolPlugin
1242             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1243             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1244             push @$res, { pool => $pool, size => $size, free => $size-$used };
1245         }
1246     });
1247
1248     return $res;
1249 }
1250
1251 sub resolv_portal {
1252     my ($portal, $noerr) = @_;
1253
1254     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1255     if ($server) {
1256         if (my $ip = resolv_server($server)) {
1257             $server = $ip;
1258             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1259             return $port ? "$server:$port" : $server;
1260         }
1261     }
1262     return undef if $noerr;
1263
1264     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1265 }
1266
1267
1268 sub scan_iscsi {
1269     my ($portal_in) = @_;
1270
1271     my $portal;
1272     if (!($portal = resolv_portal($portal_in))) {
1273         die "unable to parse/resolve portal address '${portal_in}'\n";
1274     }
1275
1276     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1277 }
1278
1279 sub storage_default_format {
1280     my ($cfg, $storeid) = @_;
1281
1282     my $scfg = storage_config ($cfg, $storeid);
1283
1284     return PVE::Storage::Plugin::default_format($scfg);
1285 }
1286
1287 sub vgroup_is_used {
1288     my ($cfg, $vgname) = @_;
1289
1290     foreach my $storeid (keys %{$cfg->{ids}}) {
1291         my $scfg = storage_config($cfg, $storeid);
1292         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1293             return 1;
1294         }
1295     }
1296
1297     return undef;
1298 }
1299
1300 sub target_is_used {
1301     my ($cfg, $target) = @_;
1302
1303     foreach my $storeid (keys %{$cfg->{ids}}) {
1304         my $scfg = storage_config($cfg, $storeid);
1305         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1306             return 1;
1307         }
1308     }
1309
1310     return undef;
1311 }
1312
1313 sub volume_is_used {
1314     my ($cfg, $volid) = @_;
1315
1316     foreach my $storeid (keys %{$cfg->{ids}}) {
1317         my $scfg = storage_config($cfg, $storeid);
1318         if ($scfg->{base} && $scfg->{base} eq $volid) {
1319             return 1;
1320         }
1321     }
1322
1323     return undef;
1324 }
1325
1326 sub storage_is_used {
1327     my ($cfg, $storeid) = @_;
1328
1329     foreach my $sid (keys %{$cfg->{ids}}) {
1330         my $scfg = storage_config($cfg, $sid);
1331         next if !$scfg->{base};
1332         my ($st) = parse_volume_id($scfg->{base});
1333         return 1 if $st && $st eq $storeid;
1334     }
1335
1336     return undef;
1337 }
1338
1339 sub foreach_volid {
1340     my ($list, $func) = @_;
1341
1342     return if !$list;
1343
1344     foreach my $sid (keys %$list) {
1345        foreach my $info (@{$list->{$sid}}) {
1346            my $volid = $info->{volid};
1347            my ($sid1, $volname) = parse_volume_id($volid, 1);
1348            if ($sid1 && $sid1 eq $sid) {
1349                &$func ($volid, $sid, $info);
1350            } else {
1351                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1352            }
1353        }
1354     }
1355 }
1356
1357 sub decompressor_info {
1358     my ($format, $comp) = @_;
1359
1360     if ($format eq 'tgz' && !defined($comp)) {
1361         ($format, $comp) = ('tar', 'gz');
1362     }
1363
1364     my $decompressor = {
1365         tar => {
1366             gz => ['tar', '-z'],
1367             lzo => ['tar', '--lzop'],
1368             zst => ['tar', '--zstd'],
1369         },
1370         vma => {
1371             gz => ['zcat'],
1372             lzo => ['lzop', '-d', '-c'],
1373             zst => ['zstd', '-q', '-d', '-c'],
1374         },
1375     };
1376
1377     die "ERROR: archive format not defined\n"
1378         if !defined($decompressor->{$format});
1379
1380     my $decomp = $decompressor->{$format}->{$comp} if $comp;
1381
1382     my $info = {
1383         format => $format,
1384         compression => $comp,
1385         decompressor => $decomp,
1386     };
1387
1388     return $info;
1389 }
1390
1391 sub archive_info {
1392     my ($archive) = shift;
1393     my $info;
1394
1395     my $volid = basename($archive);
1396     if ($volid =~ /^(vzdump-(lxc|openvz|qemu)-\d+-.+\.(tgz$|tar|vma)(?:\.(${\PVE::Storage::Plugin::COMPRESSOR_RE}))?)$/) {
1397         my $filename = "$1"; # untaint
1398         my ($type, $format, $comp) = ($2, $3, $4);
1399         my $format_re = defined($comp) ? "$format.$comp" : "$format";
1400         $info = decompressor_info($format, $comp);
1401         $info->{filename} = $filename;
1402         $info->{type} = $type;
1403
1404         if ($volid =~ /^(vzdump-${type}-([1-9][0-9]{2,8})-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2}))\.${format_re}$/) {
1405             $info->{logfilename} = "$1.log";
1406             $info->{vmid} = int($2);
1407             $info->{ctime} = timelocal($8, $7, $6, $5, $4 - 1, $3 - 1900);
1408             $info->{is_std_name} = 1;
1409         } else {
1410             $info->{is_std_name} = 0;
1411         }
1412     } else {
1413         die "ERROR: couldn't determine archive info from '$archive'\n";
1414     }
1415
1416     return $info;
1417 }
1418
1419 sub archive_remove {
1420     my ($archive_path) = @_;
1421
1422     my $dirname = dirname($archive_path);
1423     my $archive_info = eval { archive_info($archive_path) } // {};
1424     my $logfn = $archive_info->{logfilename};
1425
1426     unlink $archive_path or die "removing archive $archive_path failed: $!\n";
1427
1428     if (defined($logfn)) {
1429         my $logpath = "$dirname/$logfn";
1430         if (-e $logpath) {
1431             unlink $logpath or warn "removing log file $logpath failed: $!\n";
1432         }
1433     }
1434 }
1435
1436 sub extract_vzdump_config_tar {
1437     my ($archive, $conf_re) = @_;
1438
1439     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1440
1441     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1442        die "unable to open file '$archive'\n";
1443
1444     my $file;
1445     while (defined($file = <$fh>)) {
1446         if ($file =~ $conf_re) {
1447             $file = $1; # untaint
1448             last;
1449         }
1450     }
1451
1452     kill 15, $pid;
1453     waitpid $pid, 0;
1454     close $fh;
1455
1456     die "ERROR: archive contains no configuration file\n" if !$file;
1457     chomp $file;
1458
1459     my $raw = '';
1460     my $out = sub {
1461         my $output = shift;
1462         $raw .= "$output\n";
1463     };
1464
1465     run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1466
1467     return wantarray ? ($raw, $file) : $raw;
1468 }
1469
1470 sub extract_vzdump_config_vma {
1471     my ($archive, $comp) = @_;
1472
1473     my $raw = '';
1474     my $out = sub { $raw .= "$_[0]\n"; };
1475
1476     my $info = archive_info($archive);
1477     $comp //= $info->{compression};
1478     my $decompressor = $info->{decompressor};
1479
1480     if ($comp) {
1481         my $cmd = [ [@$decompressor, $archive], ["vma", "config", "-"] ];
1482
1483         # lzop/zcat exits with 1 when the pipe is closed early by vma, detect this and ignore the exit code later
1484         my $broken_pipe;
1485         my $errstring;
1486         my $err = sub {
1487             my $output = shift;
1488             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/ || $output =~ m/zstd: error 70 : Write error : Broken pipe/) {
1489                 $broken_pipe = 1;
1490             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1491                 $errstring = "Failed to extract config from VMA archive: $output\n";
1492             }
1493         };
1494
1495         my $rc = eval { run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1) };
1496         my $rerr = $@;
1497
1498         $broken_pipe ||= $rc == 141; # broken pipe from vma POV
1499
1500         if (!$errstring && !$broken_pipe && $rc != 0) {
1501             die "$rerr\n" if $rerr;
1502             die "config extraction failed with exit code $rc\n";
1503         }
1504         die "$errstring\n" if $errstring;
1505     } else {
1506         run_command(["vma", "config", $archive], outfunc => $out);
1507     }
1508
1509     return wantarray ? ($raw, undef) : $raw;
1510 }
1511
1512 sub extract_vzdump_config {
1513     my ($cfg, $volid) = @_;
1514
1515     my ($storeid, $volname) = parse_volume_id($volid);
1516     if (defined($storeid)) {
1517         my $scfg = storage_config($cfg, $storeid);
1518         if ($scfg->{type} eq 'pbs') {
1519             storage_check_enabled($cfg, $storeid);
1520             return PVE::Storage::PBSPlugin->extract_vzdump_config($scfg, $volname, $storeid);
1521         }
1522     }
1523
1524     my $archive = abs_filesystem_path($cfg, $volid);
1525     my $info = archive_info($archive);
1526     my $format = $info->{format};
1527     my $comp = $info->{compression};
1528     my $type = $info->{type};
1529
1530     if ($type eq 'lxc' || $type eq 'openvz') {
1531         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1532     } elsif ($type eq 'qemu') {
1533         if ($format eq 'tar') {
1534             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1535         } else {
1536             return extract_vzdump_config_vma($archive, $comp);
1537         }
1538     } else {
1539         die "cannot determine backup guest type for backup archive '$volid'\n";
1540     }
1541 }
1542
1543 sub volume_export {
1544     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1545
1546     my ($storeid, $volname) = parse_volume_id($volid, 1);
1547     die "cannot export volume '$volid'\n" if !$storeid;
1548     my $scfg = storage_config($cfg, $storeid);
1549     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1550     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1551                                   $snapshot, $base_snapshot, $with_snapshots);
1552 }
1553
1554 sub volume_import {
1555     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots, $allow_rename) = @_;
1556
1557     my ($storeid, $volname) = parse_volume_id($volid, 1);
1558     die "cannot import into volume '$volid'\n" if !$storeid;
1559     my $scfg = storage_config($cfg, $storeid);
1560     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1561     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1562                                   $base_snapshot, $with_snapshots, $allow_rename) // $volid;
1563 }
1564
1565 sub volume_export_formats {
1566     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1567
1568     my ($storeid, $volname) = parse_volume_id($volid, 1);
1569     return if !$storeid;
1570     my $scfg = storage_config($cfg, $storeid);
1571     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1572     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1573                                           $snapshot, $base_snapshot,
1574                                           $with_snapshots);
1575 }
1576
1577 sub volume_import_formats {
1578     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1579
1580     my ($storeid, $volname) = parse_volume_id($volid, 1);
1581     return if !$storeid;
1582     my $scfg = storage_config($cfg, $storeid);
1583     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1584     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1585                                           $base_snapshot, $with_snapshots);
1586 }
1587
1588 sub volume_transfer_formats {
1589     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1590     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1591     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1592     my %import_hash = map { $_ => 1 } @import_formats;
1593     my @common = grep { $import_hash{$_} } @export_formats;
1594     return @common;
1595 }
1596
1597 sub volume_imported_message {
1598     my ($volid, $want_pattern) = @_;
1599
1600     if ($want_pattern) {
1601         return qr/successfully imported '([^']*)'$/;
1602     } else {
1603         return "successfully imported '$volid'\n";
1604     }
1605 }
1606
1607 # bash completion helper
1608
1609 sub complete_storage {
1610     my ($cmdname, $pname, $cvalue) = @_;
1611
1612     my $cfg = PVE::Storage::config();
1613
1614     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1615 }
1616
1617 sub complete_storage_enabled {
1618     my ($cmdname, $pname, $cvalue) = @_;
1619
1620     my $res = [];
1621
1622     my $cfg = PVE::Storage::config();
1623     foreach my $sid (keys %{$cfg->{ids}}) {
1624         next if !storage_check_enabled($cfg, $sid, undef, 1);
1625         push @$res, $sid;
1626     }
1627     return $res;
1628 }
1629
1630 sub complete_content_type {
1631     my ($cmdname, $pname, $cvalue) = @_;
1632
1633     return [qw(rootdir images vztmpl iso backup snippets)];
1634 }
1635
1636 sub complete_volume {
1637     my ($cmdname, $pname, $cvalue) = @_;
1638
1639     my $cfg = config();
1640
1641     my $storage_list = complete_storage_enabled();
1642
1643     if ($cvalue =~ m/^([^:]+):/) {
1644         $storage_list = [ $1 ];
1645     } else {
1646         if (scalar(@$storage_list) > 1) {
1647             # only list storage IDs to avoid large listings
1648             my $res = [];
1649             foreach my $storeid (@$storage_list) {
1650                 # Hack: simply return 2 artificial values, so that
1651                 # completions does not finish
1652                 push @$res, "$storeid:volname", "$storeid:...";
1653             }
1654             return $res;
1655         }
1656     }
1657
1658     my $res = [];
1659     foreach my $storeid (@$storage_list) {
1660         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1661
1662         foreach my $item (@$vollist) {
1663             push @$res, $item->{volid};
1664         }
1665     }
1666
1667     return $res;
1668 }
1669
1670 # Various io-heavy operations require io/bandwidth limits which can be
1671 # configured on multiple levels: The global defaults in datacenter.cfg, and
1672 # per-storage overrides. When we want to do a restore from storage A to storage
1673 # B, we should take the smaller limit defined for storages A and B, and if no
1674 # such limit was specified, use the one from datacenter.cfg.
1675 sub get_bandwidth_limit {
1676     my ($operation, $storage_list, $override) = @_;
1677
1678     # called for each limit (global, per-storage) with the 'default' and the
1679     # $operation limit and should udpate $override for every limit affecting
1680     # us.
1681     my $use_global_limits = 0;
1682     my $apply_limit = sub {
1683         my ($bwlimit) = @_;
1684         if (defined($bwlimit)) {
1685             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1686             my $limit = $limits->{$operation} // $limits->{default};
1687             if (defined($limit)) {
1688                 if (!$override || $limit < $override) {
1689                     $override = $limit;
1690                 }
1691                 return;
1692             }
1693         }
1694         # If there was no applicable limit, try to apply the global ones.
1695         $use_global_limits = 1;
1696     };
1697
1698     my ($rpcenv, $authuser);
1699     if (defined($override)) {
1700         $rpcenv = PVE::RPCEnvironment->get();
1701         $authuser = $rpcenv->get_user();
1702     }
1703
1704     # Apply per-storage limits - if there are storages involved.
1705     if (defined($storage_list) && @$storage_list) {
1706         my $config = config();
1707
1708         # The Datastore.Allocate permission allows us to modify the per-storage
1709         # limits, therefore it also allows us to override them.
1710         # Since we have most likely multiple storages to check, do a quick check on
1711         # the general '/storage' path to see if we can skip the checks entirely:
1712         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1713
1714         my %done;
1715         foreach my $storage (@$storage_list) {
1716             next if !defined($storage);
1717             # Avoid duplicate checks:
1718             next if $done{$storage};
1719             $done{$storage} = 1;
1720
1721             # Otherwise we may still have individual /storage/$ID permissions:
1722             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1723                 # And if not: apply the limits.
1724                 my $storecfg = storage_config($config, $storage);
1725                 $apply_limit->($storecfg->{bwlimit});
1726             }
1727         }
1728
1729         # Storage limits take precedence over the datacenter defaults, so if
1730         # a limit was applied:
1731         return $override if !$use_global_limits;
1732     }
1733
1734     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1735     # global default limits.
1736     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1737         # So if we cannot modify global limits, apply them to our currently
1738         # requested override.
1739         my $dc = cfs_read_file('datacenter.cfg');
1740         $apply_limit->($dc->{bwlimit});
1741     }
1742
1743     return $override;
1744 }
1745
1746 # checks if the storage id is available and dies if not
1747 sub assert_sid_unused {
1748     my ($sid) = @_;
1749
1750     my $cfg = config();
1751     if (my $scfg = storage_config($cfg, $sid, 1)) {
1752         die "storage ID '$sid' already defined\n";
1753     }
1754
1755     return undef;
1756 }
1757
1758 1;