PVE/Storage/DirPlugin.pm

   1 package PVE::Storage::DirPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd;
   6 use File::Path;
   7 use PVE::Storage::Plugin;
   8 use PVE::JSONSchema qw(get_standard_option);
   9
  10 use base qw(PVE::Storage::Plugin);
  11
  12 # Configuration
  13
  14 sub type {
  15     return 'dir';
  16 }
  17
  18 sub plugindata {
  19     return {
  20         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1, backup => 1, snippets => 1, none => 1 },
  21                      { images => 1,  rootdir => 1 }],
  22         format => [ { raw => 1, qcow2 => 1, vmdk => 1, subvol => 1 } , 'raw' ],
  23     };
  24 }
  25
  26 sub properties {
  27     return {
  28         path => {
  29             description => "File system path.",
  30             type => 'string', format => 'pve-storage-path',
  31         },
  32         mkdir => {
  33             description => "Create the directory if it doesn't exist.",
  34             type => 'boolean',
  35             default => 'yes',
  36         },
  37         is_mountpoint => {
  38             description =>
  39                 "Assume the given path is an externally managed mountpoint " .
  40                 "and consider the storage offline if it is not mounted. ".
  41                 "Using a boolean (yes/no) value serves as a shortcut to using the target path in this field.",
  42             type => 'string',
  43             default => 'no',
  44         },
  45         bwlimit => get_standard_option('bwlimit'),
  46     };
  47 }
  48
  49 sub options {
  50     return {
  51         path => { fixed => 1 },
  52         nodes => { optional => 1 },
  53         shared => { optional => 1 },
  54         disable => { optional => 1 },
  55         maxfiles => { optional => 1 },
  56         'prune-backups' => { optional => 1 },
  57         content => { optional => 1 },
  58         format => { optional => 1 },
  59         mkdir => { optional => 1 },
  60         is_mountpoint => { optional => 1 },
  61         bwlimit => { optional => 1 },
  62    };
  63 }
  64
  65 # Storage implementation
  66 #
  67
  68 # NOTE: should ProcFSTools::is_mounted accept an optional cache like this?
  69 sub path_is_mounted {
  70     my ($mountpoint, $mountdata) = @_;
  71
  72     $mountpoint = Cwd::realpath($mountpoint); # symlinks
  73     return 0 if !defined($mountpoint); # path does not exist
  74
  75     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  76     return 1 if grep { $_->[1] eq $mountpoint } @$mountdata;
  77     return undef;
  78 }
  79
  80 sub parse_is_mountpoint {
  81     my ($scfg) = @_;
  82     my $is_mp = $scfg->{is_mountpoint};
  83     return undef if !defined $is_mp;
  84     if (defined(my $bool = PVE::JSONSchema::parse_boolean($is_mp))) {
  85         return $bool ? $scfg->{path} : undef;
  86     }
  87     return $is_mp; # contains a path
  88 }
  89
  90 sub get_volume_notes {
  91     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
  92
  93     my $path = $class->filesystem_path($scfg, $volname);
  94     $path .= $class->SUPER::NOTES_EXT;
  95
  96     return PVE::Tools::file_get_contents($path) if -f $path;
  97
  98     return '';
  99 }
 100
 101 sub update_volume_notes {
 102     my ($class, $scfg, $storeid, $volname, $notes, $timeout) = @_;
 103
 104     my ($vtype) = $class->parse_volname($volname);
 105     die "only backups can have notes\n" if $vtype ne 'backup';
 106
 107     my $path = $class->filesystem_path($scfg, $volname);
 108     $path .= $class->SUPER::NOTES_EXT;
 109
 110     if (defined($notes) && $notes ne '') {
 111         PVE::Tools::file_set_contents($path, $notes);
 112     } else {
 113         unlink $path or die "could not delete notes - $!\n";
 114     }
 115     return;
 116 }
 117
 118 sub status {
 119     my ($class, $storeid, $scfg, $cache) = @_;
 120
 121     if (defined(my $mp = parse_is_mountpoint($scfg))) {
 122         $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 123             if !$cache->{mountdata};
 124
 125         return undef if !path_is_mounted($mp, $cache->{mountdata});
 126     }
 127
 128     return $class->SUPER::status($storeid, $scfg, $cache);
 129 }
 130
 131
 132 sub activate_storage {
 133     my ($class, $storeid, $scfg, $cache) = @_;
 134
 135     my $path = $scfg->{path};
 136     if (!defined($scfg->{mkdir}) || $scfg->{mkdir}) {
 137         mkpath $path;
 138     }
 139
 140     my $mp = parse_is_mountpoint($scfg);
 141     if (defined($mp) && !path_is_mounted($mp, $cache->{mountdata})) {
 142         die "unable to activate storage '$storeid' - " .
 143             "directory is expected to be a mount point but is not mounted: '$mp'\n";
 144     }
 145
 146     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 147 }
 148
 149 sub check_config {
 150     my ($self, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 151     my $opts = PVE::SectionConfig::check_config($self, $sectionId, $config, $create, $skipSchemaCheck);
 152     return $opts if !$create;
 153     if ($opts->{path} !~ m@^/[-/a-zA-Z0-9_.]+$@) {
 154         die "illegal path for directory storage: $opts->{path}\n";
 155     }
 156     return $opts;
 157 }
 158
 159 1;