PVE/Storage/GlusterfsPlugin.pm

   1 package PVE::Storage::GlusterfsPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use File::Path;
   7 use PVE::Tools qw(run_command);
   8 use PVE::ProcFSTools;
   9 use PVE::Network;
  10 use PVE::Storage::Plugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 use base qw(PVE::Storage::Plugin);
  14
  15 # Glusterfs helper functions
  16
  17 my $server_test_results = {};
  18
  19 my $get_active_server = sub {
  20     my ($scfg, $return_default_if_offline) = @_;
  21
  22     my $defaultserver = $scfg->{server} ? $scfg->{server} : 'localhost';
  23
  24     if ($return_default_if_offline && !defined($scfg->{server2})) {
  25         # avoid delays (there is no backup server anyways)
  26         return $defaultserver;
  27     }
  28
  29     my $serverlist = [ $defaultserver ];
  30     push @$serverlist, $scfg->{server2} if $scfg->{server2};
  31
  32     my $ctime = time();
  33     foreach my $server (@$serverlist) {
  34         my $stat = $server_test_results->{$server};
  35         return $server if $stat && $stat->{active} && (($ctime - $stat->{time}) <= 2);
  36     }
  37
  38     foreach my $server (@$serverlist) {
  39         my $status = 0;
  40
  41         if ($server && $server ne 'localhost' && $server ne '127.0.0.1' && $server ne '::1') {
  42             # ping the gluster daemon default port (24007) as heuristic
  43             $status = PVE::Network::tcp_ping($server, 24007, 2);
  44
  45         } else {
  46
  47             my $parser = sub {
  48                 my $line = shift;
  49
  50                 if ($line =~ m/Status: Started$/) {
  51                     $status = 1;
  52                 }
  53             };
  54
  55             my $cmd = ['/usr/sbin/gluster', 'volume', 'info', $scfg->{volume}];
  56
  57             run_command($cmd, errmsg => "glusterfs error", errfunc => sub {}, outfunc => $parser);
  58         }
  59
  60         $server_test_results->{$server} = { time => time(), active => $status };
  61         return $server if $status;
  62     }
  63
  64     return $defaultserver if $return_default_if_offline;
  65
  66     return undef;
  67 };
  68
  69 sub glusterfs_is_mounted {
  70     my ($volume, $mountpoint, $mountdata) = @_;
  71
  72     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  73
  74     return $mountpoint if grep {
  75         $_->[2] eq 'fuse.glusterfs' &&
  76         $_->[0] =~ /^\S+:\Q$volume\E$/ &&
  77         $_->[1] eq $mountpoint
  78     } @$mountdata;
  79     return undef;
  80 }
  81
  82 sub glusterfs_mount {
  83     my ($server, $volume, $mountpoint) = @_;
  84
  85     my $source = "$server:$volume";
  86
  87     my $cmd = ['/bin/mount', '-t', 'glusterfs', $source, $mountpoint];
  88
  89     run_command($cmd, errmsg => "mount error");
  90 }
  91
  92 # Configuration
  93
  94 sub type {
  95     return 'glusterfs';
  96 }
  97
  98 sub plugindata {
  99     return {
 100         content => [ { images => 1, vztmpl => 1, iso => 1, backup => 1, snippets => 1},
 101                      { images => 1 }],
 102         format => [ { raw => 1, qcow2 => 1, vmdk => 1 } , 'raw' ],
 103     };
 104 }
 105
 106 sub properties {
 107     return {
 108         volume => {
 109             description => "Glusterfs Volume.",
 110             type => 'string',
 111         },
 112         server2 => {
 113             description => "Backup volfile server IP or DNS name.",
 114             type => 'string', format => 'pve-storage-server',
 115             requires => 'server',
 116         },
 117         transport => {
 118             description => "Gluster transport: tcp or rdma",
 119             type => 'string',
 120             enum => ['tcp', 'rdma', 'unix'],
 121         },
 122     };
 123 }
 124
 125 sub options {
 126     return {
 127         path => { fixed => 1 },
 128         server => { optional => 1 },
 129         server2 => { optional => 1 },
 130         volume => { fixed => 1 },
 131         transport => { optional => 1 },
 132         nodes => { optional => 1 },
 133         disable => { optional => 1 },
 134         maxfiles => { optional => 1 },
 135         'prune-backups' => { optional => 1 },
 136         content => { optional => 1 },
 137         format => { optional => 1 },
 138         mkdir => { optional => 1 },
 139         bwlimit => { optional => 1 },
 140     };
 141 }
 142
 143
 144 sub check_config {
 145     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 146
 147     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
 148
 149     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
 150 }
 151
 152 # Storage implementation
 153
 154 sub parse_name_dir {
 155     my $name = shift;
 156
 157     if ($name =~ m!^((base-)?[^/\s]+\.(raw|qcow2|vmdk))$!) {
 158         return ($1, $3, $2);
 159     }
 160
 161     die "unable to parse volume filename '$name'\n";
 162 }
 163
 164 sub path {
 165     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 166
 167     my ($vtype, $name, $vmid, undef, undef, $isBase, $format) =
 168         $class->parse_volname($volname);
 169
 170     # Note: qcow2/qed has internal snapshot, so path is always
 171     # the same (with or without snapshot => same file).
 172     die "can't snapshot this image format\n"
 173         if defined($snapname) && $format !~ m/^(qcow2|qed)$/;
 174
 175     my $path = undef;
 176     if ($vtype eq 'images') {
 177
 178         my $server = &$get_active_server($scfg, 1);
 179         my $glustervolume = $scfg->{volume};
 180         my $transport = $scfg->{transport};
 181         my $protocol = "gluster";
 182
 183         if ($transport) {
 184             $protocol = "gluster+$transport";
 185         }
 186
 187         $path = "$protocol://$server/$glustervolume/images/$vmid/$name";
 188
 189     } else {
 190         my $dir = $class->get_subdir($scfg, $vtype);
 191         $path = "$dir/$name";
 192     }
 193
 194     return wantarray ? ($path, $vmid, $vtype) : $path;
 195 }
 196
 197 sub clone_image {
 198     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 199
 200     die "storage definintion has no path\n" if !$scfg->{path};
 201
 202     my ($vtype, $basename, $basevmid, undef, undef, $isBase, $format) =
 203         $class->parse_volname($volname);
 204
 205     die "clone_image on wrong vtype '$vtype'\n" if $vtype ne 'images';
 206
 207     die "this storage type does not support clone_image on snapshot\n" if $snap;
 208
 209     die "this storage type does not support clone_image on subvolumes\n" if $format eq 'subvol';
 210
 211     die "clone_image only works on base images\n" if !$isBase;
 212
 213     my $imagedir = $class->get_subdir($scfg, 'images');
 214     $imagedir .= "/$vmid";
 215
 216     mkpath $imagedir;
 217
 218     my $name = $class->find_free_diskname($imagedir, $scfg, $vmid, "qcow2", 1);
 219
 220     warn "clone $volname: $vtype, $name, $vmid to $name (base=../$basevmid/$basename)\n";
 221
 222     my $path = "$imagedir/$name";
 223
 224     die "disk image '$path' already exists\n" if -e $path;
 225
 226     my $server = &$get_active_server($scfg, 1);
 227     my $glustervolume = $scfg->{volume};
 228     my $volumepath = "gluster://$server/$glustervolume/images/$vmid/$name";
 229
 230     my $cmd = ['/usr/bin/qemu-img', 'create', '-b', "../$basevmid/$basename",
 231                '-f', 'qcow2', $volumepath];
 232
 233     run_command($cmd, errmsg => "unable to create image");
 234
 235     return "$basevmid/$basename/$vmid/$name";
 236 }
 237
 238 sub alloc_image {
 239     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 240
 241     my $imagedir = $class->get_subdir($scfg, 'images');
 242     $imagedir .= "/$vmid";
 243
 244     mkpath $imagedir;
 245
 246     $name = $class->find_free_diskname($imagedir, $scfg, $vmid, $fmt, 1) if !$name;
 247
 248     my (undef, $tmpfmt) = parse_name_dir($name);
 249
 250     die "illegal name '$name' - wrong extension for format ('$tmpfmt != '$fmt')\n"
 251         if $tmpfmt ne $fmt;
 252
 253     my $path = "$imagedir/$name";
 254
 255     die "disk image '$path' already exists\n" if -e $path;
 256
 257     my $server = &$get_active_server($scfg, 1);
 258     my $glustervolume = $scfg->{volume};
 259     my $volumepath = "gluster://$server/$glustervolume/images/$vmid/$name";
 260
 261     my $cmd = ['/usr/bin/qemu-img', 'create'];
 262
 263     push @$cmd, '-o', 'preallocation=metadata' if $fmt eq 'qcow2';
 264
 265     push @$cmd, '-f', $fmt, $volumepath, "${size}K";
 266
 267     eval { run_command($cmd, errmsg => "unable to create image"); };
 268     if ($@) {
 269         unlink $path;
 270         rmdir $imagedir;
 271         die "$@";
 272     }
 273
 274     return "$vmid/$name";
 275 }
 276
 277 sub status {
 278     my ($class, $storeid, $scfg, $cache) = @_;
 279
 280     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 281         if !$cache->{mountdata};
 282
 283     my $path = $scfg->{path};
 284
 285     my $volume = $scfg->{volume};
 286
 287     return undef if !glusterfs_is_mounted($volume, $path, $cache->{mountdata});
 288
 289     return $class->SUPER::status($storeid, $scfg, $cache);
 290 }
 291
 292 sub activate_storage {
 293     my ($class, $storeid, $scfg, $cache) = @_;
 294
 295     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 296         if !$cache->{mountdata};
 297
 298     my $path = $scfg->{path};
 299     my $volume = $scfg->{volume};
 300
 301     if (!glusterfs_is_mounted($volume, $path, $cache->{mountdata})) {
 302
 303         mkpath $path if !(defined($scfg->{mkdir}) && !$scfg->{mkdir});
 304
 305         die "unable to activate storage '$storeid' - " .
 306             "directory '$path' does not exist\n" if ! -d $path;
 307
 308         my $server = &$get_active_server($scfg, 1);
 309
 310         glusterfs_mount($server, $volume, $path);
 311     }
 312
 313     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 314 }
 315
 316 sub deactivate_storage {
 317     my ($class, $storeid, $scfg, $cache) = @_;
 318
 319     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 320         if !$cache->{mountdata};
 321
 322     my $path = $scfg->{path};
 323     my $volume = $scfg->{volume};
 324
 325     if (glusterfs_is_mounted($volume, $path, $cache->{mountdata})) {
 326         my $cmd = ['/bin/umount', $path];
 327         run_command($cmd, errmsg => 'umount error');
 328     }
 329 }
 330
 331 sub activate_volume {
 332     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 333
 334     # do nothing by default
 335 }
 336
 337 sub deactivate_volume {
 338     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 339
 340     # do nothing by default
 341 }
 342
 343 sub check_connection {
 344     my ($class, $storeid, $scfg, $cache) = @_;
 345
 346     my $server = &$get_active_server($scfg);
 347
 348     return defined($server) ? 1 : 0;
 349 }
 350
 351 1;