PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use JSON;
   8 use Net::IP;
   9
  10 use PVE::CephConfig;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use PVE::ProcFSTools;
  13 use PVE::RADOS;
  14 use PVE::Storage::Plugin;
  15 use PVE::Tools qw(run_command trim);
  16
  17 use base qw(PVE::Storage::Plugin);
  18
  19 my $get_parent_image_name = sub {
  20     my ($parent) = @_;
  21     return undef if !$parent;
  22     return $parent->{image} . "@" . $parent->{snapshot};
  23 };
  24
  25 my sub get_rbd_path {
  26     my ($scfg, $volume) = @_;
  27     my $path = $scfg->{pool} ? $scfg->{pool} : 'rbd';
  28     $path .= "/$scfg->{namespace}" if defined($scfg->{namespace});
  29     $path .= "/$volume" if defined($volume);
  30     return $path;
  31 };
  32
  33 my $build_cmd = sub {
  34     my ($binary, $scfg, $storeid, $op, @options) = @_;
  35
  36     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  37     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  38
  39     my $cmd = [$binary, '-p', $pool];
  40
  41     if (defined(my $namespace = $scfg->{namespace})) {
  42         # some subcommands will fail if the --namespace parameter is present
  43         my $no_namespace_parameter = {
  44             unmap => 1,
  45         };
  46         push @$cmd, '--namespace', "$namespace" if !$no_namespace_parameter->{$op};
  47     }
  48     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  49     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  50     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  51     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  52     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  53
  54     push @$cmd, $op;
  55
  56     push @$cmd, @options if scalar(@options);
  57
  58     return $cmd;
  59 };
  60
  61 my $rbd_cmd = sub {
  62     my ($scfg, $storeid, $op, @options) = @_;
  63
  64     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  65 };
  66
  67 my $rados_cmd = sub {
  68     my ($scfg, $storeid, $op, @options) = @_;
  69
  70     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  71 };
  72
  73 my $librados_connect = sub {
  74     my ($scfg, $storeid, $options) = @_;
  75
  76     my $librados_config = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  77
  78     my $rados = PVE::RADOS->new(%$librados_config);
  79
  80     return $rados;
  81 };
  82
  83 # needed for volumes created using ceph jewel (or higher)
  84 my $krbd_feature_update = sub {
  85     my ($scfg, $storeid, $name) = @_;
  86
  87     my (@disable, @enable);
  88     my ($kmajor, $kminor) = PVE::ProcFSTools::kernel_version();
  89
  90     if ($kmajor > 5 || $kmajor == 5 && $kminor >= 3) {
  91         # 'deep-flatten' can only be disabled, not enabled after image creation
  92         push @enable, 'fast-diff', 'object-map';
  93     } else {
  94         push @disable, 'fast-diff', 'object-map', 'deep-flatten';
  95     }
  96
  97     if ($kmajor >= 5) {
  98         push @enable, 'exclusive-lock';
  99     } else {
 100         push @disable, 'exclusive-lock';
 101     }
 102
 103     my $active_features_list = (rbd_volume_info($scfg, $storeid, $name))[4];
 104     my $active_features = { map { $_ => 1 } @$active_features_list };
 105
 106     my $to_disable = join(',', grep {  $active_features->{$_} } @disable);
 107     my $to_enable  = join(',', grep { !$active_features->{$_} } @enable );
 108
 109     if ($to_disable) {
 110         print "disable RBD image features this kernel RBD drivers is not compatible with: $to_disable\n";
 111         my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'disable', $name, $to_disable);
 112         run_rbd_command(
 113             $cmd,
 114             errmsg => "could not disable krbd-incompatible image features '$to_disable' for rbd image: $name",
 115         );
 116     }
 117     if ($to_enable) {
 118         print "enable RBD image features this kernel RBD drivers supports: $to_enable\n";
 119         eval {
 120             my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'enable', $name, $to_enable);
 121             run_rbd_command(
 122                 $cmd,
 123                 errmsg => "could not enable krbd-compatible image features '$to_enable' for rbd image: $name",
 124             );
 125         };
 126         warn "$@" if $@;
 127     }
 128 };
 129
 130 sub run_rbd_command {
 131     my ($cmd, %args) = @_;
 132
 133     my $lasterr;
 134     my $errmsg = $args{errmsg} . ": " || "";
 135     if (!exists($args{errfunc})) {
 136         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 137         # at least 1 child(ren) in pool cephstor1
 138         $args{errfunc} = sub {
 139             my $line = shift;
 140             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 141                 $lasterr = "$1\n";
 142             } else {
 143                 $lasterr = $line;
 144             }
 145             print STDERR $lasterr;
 146             *STDERR->flush();
 147         };
 148     }
 149
 150     eval { run_command($cmd, %args); };
 151     if (my $err = $@) {
 152         die $errmsg . $lasterr if length($lasterr);
 153         die $err;
 154     }
 155
 156     return undef;
 157 }
 158
 159 sub rbd_ls {
 160     my ($scfg, $storeid) = @_;
 161
 162     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 163     $pool .= "/$scfg->{namespace}" if defined($scfg->{namespace});
 164
 165     my $raw = '';
 166     my $parser = sub { $raw .= shift };
 167
 168     my $cmd = $rbd_cmd->($scfg, $storeid, 'ls', '-l', '--format', 'json');
 169     eval {
 170         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 171     };
 172     my $err = $@;
 173
 174     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 175
 176     my $result;
 177     if ($raw eq '') {
 178         $result = [];
 179     } elsif ($raw =~ m/^(\[.*\])$/s) { # untaint
 180         $result = JSON::decode_json($1);
 181     } else {
 182         die "got unexpected data from rbd ls: '$raw'\n";
 183     }
 184
 185     my $list = {};
 186
 187     foreach my $el (@$result) {
 188         next if defined($el->{snapshot});
 189
 190         my $image = $el->{image};
 191
 192         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 193         next if !defined($owner);
 194
 195         $list->{$pool}->{$image} = {
 196             name => $image,
 197             size => $el->{size},
 198             parent => $get_parent_image_name->($el->{parent}),
 199             vmid => $owner
 200         };
 201     }
 202
 203     return $list;
 204 }
 205
 206 sub rbd_ls_snap {
 207     my ($scfg, $storeid, $name) = @_;
 208
 209     my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'ls', $name, '--format', 'json');
 210
 211     my $raw = '';
 212     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => sub { $raw .= shift; });
 213
 214     my $list;
 215     if ($raw =~ m/^(\[.*\])$/s) { # untaint
 216         $list = eval { JSON::decode_json($1) };
 217         die "invalid JSON output from 'rbd snap ls $name': $@\n" if $@;
 218     } else {
 219         die "got unexpected data from 'rbd snap ls $name': '$raw'\n";
 220     }
 221
 222     $list = [] if !defined($list);
 223
 224     my $res = {};
 225     foreach my $el (@$list) {
 226         my $snap = $el->{name};
 227         my $protected = defined($el->{protected}) && $el->{protected} eq "true" ? 1 : undef;
 228         $res->{$snap} = {
 229             name => $snap,
 230             id => $el->{id} // undef,
 231             size => $el->{size} // 0,
 232             protected => $protected,
 233         };
 234     }
 235     return $res;
 236 }
 237
 238 sub rbd_volume_info {
 239     my ($scfg, $storeid, $volname, $snap) = @_;
 240
 241     my $cmd = undef;
 242
 243     my @options = ('info', $volname, '--format', 'json');
 244     if ($snap) {
 245         push @options, '--snap', $snap;
 246     }
 247
 248     $cmd = $rbd_cmd->($scfg, $storeid, @options);
 249
 250     my $raw = '';
 251     my $parser = sub { $raw .= shift };
 252
 253     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 254
 255     my $volume;
 256     if ($raw eq '') {
 257         $volume = {};
 258     } elsif ($raw =~ m/^(\{.*\})$/s) { # untaint
 259         $volume = JSON::decode_json($1);
 260     } else {
 261         die "got unexpected data from rbd info: '$raw'\n";
 262     }
 263
 264     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 265     $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
 266
 267     return $volume->@{qw(size parent format protected features)};
 268 }
 269
 270 # Configuration
 271
 272 sub type {
 273     return 'rbd';
 274 }
 275
 276 sub plugindata {
 277     return {
 278         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 279     };
 280 }
 281
 282 sub properties {
 283     return {
 284         monhost => {
 285             description => "IP addresses of monitors (for external clusters).",
 286             type => 'string', format => 'pve-storage-portal-dns-list',
 287         },
 288         pool => {
 289             description => "Pool.",
 290             type => 'string',
 291         },
 292         namespace => {
 293             description => "RBD Namespace.",
 294             type => 'string',
 295         },
 296         username => {
 297             description => "RBD Id.",
 298             type => 'string',
 299         },
 300         authsupported => {
 301             description => "Authsupported.",
 302             type => 'string',
 303         },
 304         krbd => {
 305             description => "Always access rbd through krbd kernel module.",
 306             type => 'boolean',
 307         },
 308     };
 309 }
 310
 311 sub options {
 312     return {
 313         nodes => { optional => 1 },
 314         disable => { optional => 1 },
 315         monhost => { optional => 1},
 316         pool => { optional => 1 },
 317         namespace => { optional => 1 },
 318         username => { optional => 1 },
 319         content => { optional => 1 },
 320         krbd => { optional => 1 },
 321         bwlimit => { optional => 1 },
 322     };
 323 }
 324
 325 # Storage implementation
 326
 327 sub on_add_hook {
 328     my ($class, $storeid, $scfg, %param) = @_;
 329
 330     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 331
 332     PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid);
 333
 334     return;
 335 }
 336
 337 sub on_delete_hook {
 338     my ($class, $storeid, $scfg) = @_;
 339
 340     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 341
 342     PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid);
 343
 344     return;
 345 }
 346
 347 sub parse_volname {
 348     my ($class, $volname) = @_;
 349
 350     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 351         return ('images', $4, $7, $2, $3, $5, 'raw');
 352     }
 353
 354     die "unable to parse rbd volume name '$volname'\n";
 355 }
 356
 357 sub path {
 358     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 359
 360     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
 361     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 362     $name .= '@'.$snapname if $snapname;
 363
 364     my $rbd_path = get_rbd_path($scfg, $name);
 365     return ("/dev/rbd/${rbd_path}", $vmid, $vtype) if $scfg->{krbd};
 366
 367     my $path = "rbd:${rbd_path}";
 368
 369     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 370     if (defined($scfg->{monhost})) {
 371         my $monhost = PVE::CephConfig::hostlist($scfg->{monhost}, ';');
 372         $monhost =~ s/:/\\:/g;
 373         $path .= ":mon_host=$monhost";
 374         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 375     }
 376
 377     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 378
 379     return ($path, $vmid, $vtype);
 380 }
 381
 382 sub find_free_diskname {
 383     my ($class, $storeid, $scfg, $vmid, $fmt, $add_fmt_suffix) = @_;
 384
 385     my $cmd = $rbd_cmd->($scfg, $storeid, 'ls');
 386
 387     my $disk_list = [];
 388
 389     my $parser = sub {
 390         my $line = shift;
 391         if ($line =~ m/^(.*)$/) { # untaint
 392             push @$disk_list, $1;
 393         }
 394     };
 395
 396     eval {
 397         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 398     };
 399     my $err = $@;
 400
 401     die $err if $err && $err !~ m/doesn't contain rbd images/;
 402
 403     return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, undef, $scfg);
 404 }
 405
 406 sub create_base {
 407     my ($class, $storeid, $scfg, $volname) = @_;
 408
 409     my $snap = '__base__';
 410
 411     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 412         $class->parse_volname($volname);
 413
 414     die "create_base not possible with base image\n" if $isBase;
 415
 416     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 417     die "rbd volume info on '$name' failed\n" if !($size);
 418
 419     die "rbd image must be at format V2" if $format ne "2";
 420
 421     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 422         if $basename && (!$parent || $parent ne $basename."@".$snap);
 423
 424     my $newname = $name;
 425     $newname =~ s/^vm-/base-/;
 426
 427     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 428
 429     my $cmd = $rbd_cmd->(
 430         $scfg,
 431         $storeid,
 432         'rename',
 433         get_rbd_path($scfg, $name),
 434         get_rbd_path($scfg, $newname),
 435     );
 436     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 437
 438     my $running  = undef; #fixme : is create_base always offline ?
 439
 440     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 441
 442     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 443
 444     if (!$protected){
 445         my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 446         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 447     }
 448
 449     return $newvolname;
 450
 451 }
 452
 453 sub clone_image {
 454     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 455
 456     my $snap = '__base__';
 457     $snap = $snapname if length $snapname;
 458
 459     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 460         $class->parse_volname($volname);
 461
 462     die "$volname is not a base image and snapname is not provided\n"
 463         if !$isBase && !length($snapname);
 464
 465     my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
 466
 467     warn "clone $volname: $basename snapname $snap to $name\n";
 468
 469     if (length($snapname)) {
 470         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 471
 472         if (!$protected) {
 473             my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 474             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 475         }
 476     }
 477
 478     my $newvol = "$basename/$name";
 479     $newvol = $name if length($snapname);
 480
 481     my $cmd = $rbd_cmd->(
 482         $scfg,
 483         $storeid,
 484         'clone',
 485         get_rbd_path($scfg, $basename),
 486         '--snap',
 487         $snap,
 488         get_rbd_path($scfg, $name),
 489     );
 490
 491     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 492
 493     return $newvol;
 494 }
 495
 496 sub alloc_image {
 497     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 498
 499
 500     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 501         if  $name && $name !~ m/^vm-$vmid-/;
 502
 503     $name = $class->find_free_diskname($storeid, $scfg, $vmid) if !$name;
 504
 505     my $cmd = $rbd_cmd->($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 506     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 507
 508     return $name;
 509 }
 510
 511 sub free_image {
 512     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 513
 514     my ($vtype, $name, $vmid, undef, undef, undef) =
 515         $class->parse_volname($volname);
 516
 517
 518     my $snaps = rbd_ls_snap($scfg, $storeid, $name);
 519     foreach my $snap (keys %$snaps) {
 520         if ($snaps->{$snap}->{protected}) {
 521             my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 522             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 523         }
 524     }
 525
 526     $class->deactivate_volume($storeid, $scfg, $volname);
 527
 528     my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'purge',  $name);
 529     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 530
 531     $cmd = $rbd_cmd->($scfg, $storeid, 'rm', $name);
 532     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 533
 534     return undef;
 535 }
 536
 537 sub list_images {
 538     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 539
 540     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 541
 542     my $dat = $cache->{rbd}->{get_rbd_path($scfg)};
 543     return [] if !$dat; # nothing found
 544
 545     my $res = [];
 546     for my $image (sort keys %$dat) {
 547         my $info = $dat->{$image};
 548         my ($volname, $parent, $owner) = $info->@{'name', 'parent', 'vmid'};
 549
 550         if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 551             $info->{volid} = "$storeid:$1/$volname";
 552         } else {
 553             $info->{volid} = "$storeid:$volname";
 554         }
 555
 556         if ($vollist) {
 557             my $found = grep { $_ eq $info->{volid} } @$vollist;
 558             next if !$found;
 559         } else {
 560             next if defined ($vmid) && ($owner ne $vmid);
 561         }
 562
 563         $info->{format} = 'raw';
 564
 565         push @$res, $info;
 566     }
 567
 568     return $res;
 569 }
 570
 571 sub status {
 572     my ($class, $storeid, $scfg, $cache) = @_;
 573
 574     my $rados = $librados_connect->($scfg, $storeid);
 575     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 576
 577     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 578
 579     # max_avail -> max available space for data w/o replication in the pool
 580     # bytes_used -> data w/o replication in the pool
 581     my $free = $d->{stats}->{max_avail};
 582     my $used = $d->{stats}->{stored} // $d->{stats}->{bytes_used};
 583     my $total = $used + $free;
 584     my $active = 1;
 585
 586     return ($total, $free, $used, $active);
 587 }
 588
 589 sub activate_storage {
 590     my ($class, $storeid, $scfg, $cache) = @_;
 591     return 1;
 592 }
 593
 594 sub deactivate_storage {
 595     my ($class, $storeid, $scfg, $cache) = @_;
 596     return 1;
 597 }
 598
 599 my sub get_kernel_device_path {
 600     my ($scfg, $name) = @_;
 601     return "/dev/rbd/" . get_rbd_path($scfg, $name);
 602 };
 603
 604 sub map_volume {
 605     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 606
 607     my ($vtype, $img_name, $vmid) = $class->parse_volname($volname);
 608
 609     my $name = $img_name;
 610     $name .= '@'.$snapname if $snapname;
 611
 612     my $kerneldev = get_kernel_device_path($scfg, $name);
 613
 614     return $kerneldev if -b $kerneldev; # already mapped
 615
 616     # features can only be enabled/disabled for image, not for snapshot!
 617     $krbd_feature_update->($scfg, $storeid, $img_name);
 618
 619     my $cmd = $rbd_cmd->($scfg, $storeid, 'map', $name);
 620     run_rbd_command($cmd, errmsg => "can't map rbd volume $name");
 621
 622     return $kerneldev;
 623 }
 624
 625 sub unmap_volume {
 626     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 627
 628     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 629     $name .= '@'.$snapname if $snapname;
 630
 631     my $kerneldev = get_kernel_device_path($scfg, $name);
 632
 633     if (-b $kerneldev) {
 634         my $cmd = $rbd_cmd->($scfg, $storeid, 'unmap', $kerneldev);
 635         run_rbd_command($cmd, errmsg => "can't unmap rbd device $kerneldev");
 636     }
 637
 638     return 1;
 639 }
 640
 641 sub activate_volume {
 642     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 643
 644     $class->map_volume($storeid, $scfg, $volname, $snapname) if $scfg->{krbd};
 645
 646     return 1;
 647 }
 648
 649 sub deactivate_volume {
 650     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 651
 652     $class->unmap_volume($storeid, $scfg, $volname, $snapname);
 653
 654     return 1;
 655 }
 656
 657 sub volume_size_info {
 658     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 659
 660     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 661     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 662     return $size;
 663 }
 664
 665 sub volume_resize {
 666     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 667
 668     return 1 if $running && !$scfg->{krbd}; # FIXME???
 669
 670     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 671
 672     my $cmd = $rbd_cmd->($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 673     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 674     return undef;
 675 }
 676
 677 sub volume_snapshot {
 678     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 679
 680     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 681
 682     my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 683     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 684     return undef;
 685 }
 686
 687 sub volume_snapshot_rollback {
 688     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 689
 690     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 691
 692     my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 693     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 694 }
 695
 696 sub volume_snapshot_delete {
 697     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 698
 699     return 1 if $running && !$scfg->{krbd}; # FIXME: ????
 700
 701     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 702
 703     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 704
 705     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 706     if ($protected){
 707         my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 708         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 709     }
 710
 711     my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 712
 713     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 714
 715     return undef;
 716 }
 717
 718 sub volume_snapshot_needs_fsfreeze {
 719     return 1;
 720 }
 721
 722 sub volume_has_feature {
 723     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 724
 725    my $features = {
 726         snapshot => { current => 1, snap => 1},
 727         clone => { base => 1, snap => 1},
 728         template => { current => 1},
 729         copy => { base => 1, current => 1, snap => 1},
 730         sparseinit => { base => 1, current => 1},
 731     };
 732
 733     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) = $class->parse_volname($volname);
 734
 735     my $key = undef;
 736     if ($snapname){
 737         $key = 'snap';
 738     } else {
 739         $key = $isBase ? 'base' : 'current';
 740     }
 741     return 1 if $features->{$feature}->{$key};
 742
 743     return undef;
 744 }
 745
 746 1;