PVE/API2/Qemu.pm

   1 package PVE::API2::Qemu;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd 'abs_path';
   6 use Net::SSLeay;
   7 use UUID;
   8 use POSIX;
   9 use IO::Socket::IP;
  10 use URI::Escape;
  11
  12 use PVE::Cluster qw (cfs_read_file cfs_write_file);;
  13 use PVE::SafeSyslog;
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
  16 use PVE::Storage;
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use PVE::RESTHandler;
  19 use PVE::ReplicationConfig;
  20 use PVE::GuestHelpers;
  21 use PVE::QemuConfig;
  22 use PVE::QemuServer;
  23 use PVE::QemuMigrate;
  24 use PVE::RPCEnvironment;
  25 use PVE::AccessControl;
  26 use PVE::INotify;
  27 use PVE::Network;
  28 use PVE::Firewall;
  29 use PVE::API2::Firewall::VM;
  30 use PVE::API2::Qemu::Agent;
  31
  32 BEGIN {
  33     if (!$ENV{PVE_GENERATING_DOCS}) {
  34         require PVE::HA::Env::PVE2;
  35         import PVE::HA::Env::PVE2;
  36         require PVE::HA::Config;
  37         import PVE::HA::Config;
  38     }
  39 }
  40
  41 use Data::Dumper; # fixme: remove
  42
  43 use base qw(PVE::RESTHandler);
  44
  45 my $opt_force_description = "Force physical removal. Without this, we simple remove the disk from the config file and create an additional configuration entry called 'unused[n]', which contains the volume ID. Unlink of unused[n] always cause physical removal.";
  46
  47 my $resolve_cdrom_alias = sub {
  48     my $param = shift;
  49
  50     if (my $value = $param->{cdrom}) {
  51         $value .= ",media=cdrom" if $value !~ m/media=/;
  52         $param->{ide2} = $value;
  53         delete $param->{cdrom};
  54     }
  55 };
  56
  57 my $NEW_DISK_RE = qr!^(([^/:\s]+):)?(\d+(\.\d+)?)$!;
  58 my $check_storage_access = sub {
  59    my ($rpcenv, $authuser, $storecfg, $vmid, $settings, $default_storage) = @_;
  60
  61    PVE::QemuServer::foreach_drive($settings, sub {
  62         my ($ds, $drive) = @_;
  63
  64         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  65
  66         my $volid = $drive->{file};
  67
  68         if (!$volid || ($volid eq 'none' || $volid eq 'cloudinit')) {
  69             # nothing to check
  70         } elsif ($volid =~ m/^(([^:\s]+):)?(cloudinit)$/) {
  71             # nothing to check
  72         } elsif ($isCDROM && ($volid eq 'cdrom')) {
  73             $rpcenv->check($authuser, "/", ['Sys.Console']);
  74         } elsif (!$isCDROM && ($volid =~ $NEW_DISK_RE)) {
  75             my ($storeid, $size) = ($2 || $default_storage, $3);
  76             die "no storage ID specified (and no default storage)\n" if !$storeid;
  77             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
  78             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  79             raise_param_exc({ storage => "storage '$storeid' does not support vm images"})
  80                 if !$scfg->{content}->{images};
  81         } else {
  82             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
  83         }
  84     });
  85
  86    $rpcenv->check($authuser, "/storage/$settings->{vmstatestorage}", ['Datastore.AllocateSpace'])
  87        if defined($settings->{vmstatestorage});
  88 };
  89
  90 my $check_storage_access_clone = sub {
  91    my ($rpcenv, $authuser, $storecfg, $conf, $storage) = @_;
  92
  93    my $sharedvm = 1;
  94
  95    PVE::QemuServer::foreach_drive($conf, sub {
  96         my ($ds, $drive) = @_;
  97
  98         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  99
 100         my $volid = $drive->{file};
 101
 102         return if !$volid || $volid eq 'none';
 103
 104         if ($isCDROM) {
 105             if ($volid eq 'cdrom') {
 106                 $rpcenv->check($authuser, "/", ['Sys.Console']);
 107             } else {
 108                 # we simply allow access
 109                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 110                 my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 111                 $sharedvm = 0 if !$scfg->{shared};
 112
 113             }
 114         } else {
 115             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 116             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 117             $sharedvm = 0 if !$scfg->{shared};
 118
 119             $sid = $storage if $storage;
 120             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 121         }
 122     });
 123
 124    $rpcenv->check($authuser, "/storage/$conf->{vmstatestorage}", ['Datastore.AllocateSpace'])
 125        if defined($conf->{vmstatestorage});
 126
 127    return $sharedvm;
 128 };
 129
 130 # Note: $pool is only needed when creating a VM, because pool permissions
 131 # are automatically inherited if VM already exists inside a pool.
 132 my $create_disks = sub {
 133     my ($rpcenv, $authuser, $conf, $storecfg, $vmid, $pool, $settings, $default_storage) = @_;
 134
 135     my $vollist = [];
 136
 137     my $res = {};
 138
 139     my $code = sub {
 140         my ($ds, $disk) = @_;
 141
 142         my $volid = $disk->{file};
 143
 144         if (!$volid || $volid eq 'none' || $volid eq 'cdrom') {
 145             delete $disk->{size};
 146             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 147         } elsif ($volid =~ m!^(?:([^/:\s]+):)?cloudinit$!) {
 148             my $storeid = $1 || $default_storage;
 149             die "no storage ID specified (and no default storage)\n" if !$storeid;
 150             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 151             my $name = "vm-$vmid-cloudinit";
 152             my $fmt = undef;
 153             if ($scfg->{path}) {
 154                 $name .= ".qcow2";
 155                 $fmt = 'qcow2';
 156             }else{
 157                 $fmt = 'raw';
 158             }
 159             # FIXME: Reasonable size? qcow2 shouldn't grow if the space isn't used anyway?
 160             my $cloudinit_iso_size = 5; # in MB
 161             my $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid,
 162                                                   $fmt, $name, $cloudinit_iso_size*1024);
 163             $disk->{file} = $volid;
 164             $disk->{media} = 'cdrom';
 165             push @$vollist, $volid;
 166             delete $disk->{format}; # no longer needed
 167             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 168         } elsif ($volid =~ $NEW_DISK_RE) {
 169             my ($storeid, $size) = ($2 || $default_storage, $3);
 170             die "no storage ID specified (and no default storage)\n" if !$storeid;
 171             my $defformat = PVE::Storage::storage_default_format($storecfg, $storeid);
 172             my $fmt = $disk->{format} || $defformat;
 173
 174             $size = PVE::Tools::convert_size($size, 'gb' => 'kb'); # vdisk_alloc uses kb
 175
 176             my $volid;
 177             if ($ds eq 'efidisk0') {
 178                 ($volid, $size) = PVE::QemuServer::create_efidisk($storecfg, $storeid, $vmid, $fmt);
 179             } else {
 180                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, undef, $size);
 181             }
 182             push @$vollist, $volid;
 183             $disk->{file} = $volid;
 184             $disk->{size} = PVE::Tools::convert_size($size, 'kb' => 'b');
 185             delete $disk->{format}; # no longer needed
 186             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 187         } else {
 188
 189             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
 190
 191             my $volid_is_new = 1;
 192
 193             if ($conf->{$ds}) {
 194                 my $olddrive = PVE::QemuServer::parse_drive($ds, $conf->{$ds});
 195                 $volid_is_new = undef if $olddrive->{file} && $olddrive->{file} eq $volid;
 196             }
 197
 198             if ($volid_is_new) {
 199
 200                 my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 201
 202                 PVE::Storage::activate_volumes($storecfg, [ $volid ]) if $storeid;
 203
 204                 my $size = PVE::Storage::volume_size_info($storecfg, $volid);
 205
 206                 die "volume $volid does not exists\n" if !$size;
 207
 208                 $disk->{size} = $size;
 209             }
 210
 211             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 212         }
 213     };
 214
 215     eval { PVE::QemuServer::foreach_drive($settings, $code); };
 216
 217     # free allocated images on error
 218     if (my $err = $@) {
 219         syslog('err', "VM $vmid creating disks failed");
 220         foreach my $volid (@$vollist) {
 221             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 222             warn $@ if $@;
 223         }
 224         die $err;
 225     }
 226
 227     # modify vm config if everything went well
 228     foreach my $ds (keys %$res) {
 229         $conf->{$ds} = $res->{$ds};
 230     }
 231
 232     return $vollist;
 233 };
 234
 235 my $cpuoptions = {
 236     'cores' => 1,
 237     'cpu' => 1,
 238     'cpulimit' => 1,
 239     'cpuunits' => 1,
 240     'numa' => 1,
 241     'smp' => 1,
 242     'sockets' => 1,
 243     'vcpus' => 1,
 244 };
 245
 246 my $memoryoptions = {
 247     'memory' => 1,
 248     'balloon' => 1,
 249     'shares' => 1,
 250 };
 251
 252 my $hwtypeoptions = {
 253     'acpi' => 1,
 254     'hotplug' => 1,
 255     'kvm' => 1,
 256     'machine' => 1,
 257     'scsihw' => 1,
 258     'smbios1' => 1,
 259     'tablet' => 1,
 260     'vga' => 1,
 261     'watchdog' => 1,
 262 };
 263
 264 my $generaloptions = {
 265     'agent' => 1,
 266     'autostart' => 1,
 267     'bios' => 1,
 268     'description' => 1,
 269     'keyboard' => 1,
 270     'localtime' => 1,
 271     'migrate_downtime' => 1,
 272     'migrate_speed' => 1,
 273     'name' => 1,
 274     'onboot' => 1,
 275     'ostype' => 1,
 276     'protection' => 1,
 277     'reboot' => 1,
 278     'startdate' => 1,
 279     'startup' => 1,
 280     'tdf' => 1,
 281     'template' => 1,
 282 };
 283
 284 my $vmpoweroptions = {
 285     'freeze' => 1,
 286 };
 287
 288 my $diskoptions = {
 289     'boot' => 1,
 290     'bootdisk' => 1,
 291     'vmstatestorage' => 1,
 292 };
 293
 294 my $check_vm_modify_config_perm = sub {
 295     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
 296
 297     return 1 if $authuser eq 'root@pam';
 298
 299     foreach my $opt (@$key_list) {
 300         # disk checks need to be done somewhere else
 301         next if PVE::QemuServer::is_valid_drivename($opt);
 302         next if $opt eq 'cdrom';
 303         next if $opt =~ m/^unused\d+$/;
 304
 305         if ($cpuoptions->{$opt} || $opt =~ m/^numa\d+$/) {
 306             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 307         } elsif ($memoryoptions->{$opt}) {
 308             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 309         } elsif ($hwtypeoptions->{$opt}) {
 310             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 311         } elsif ($generaloptions->{$opt}) {
 312             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 313             # special case for startup since it changes host behaviour
 314             if ($opt eq 'startup') {
 315                 $rpcenv->check_full($authuser, "/", ['Sys.Modify']);
 316             }
 317         } elsif ($vmpoweroptions->{$opt}) {
 318             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.PowerMgmt']);
 319         } elsif ($diskoptions->{$opt}) {
 320             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 321         } elsif ($opt =~ m/^(?:net|ipconfig)\d+$/) {
 322             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 323         } else {
 324             # catches usb\d+, hostpci\d+, args, lock, etc.
 325             # new options will be checked here
 326             die "only root can set '$opt' config\n";
 327         }
 328     }
 329
 330     return 1;
 331 };
 332
 333 __PACKAGE__->register_method({
 334     name => 'vmlist',
 335     path => '',
 336     method => 'GET',
 337     description => "Virtual machine index (per node).",
 338     permissions => {
 339         description => "Only list VMs where you have VM.Audit permissons on /vms/<vmid>.",
 340         user => 'all',
 341     },
 342     proxyto => 'node',
 343     protected => 1, # qemu pid files are only readable by root
 344     parameters => {
 345         additionalProperties => 0,
 346         properties => {
 347             node => get_standard_option('pve-node'),
 348             full => {
 349                 type => 'boolean',
 350                 optional => 1,
 351                 description => "Determine the full status of active VMs.",
 352             },
 353         },
 354     },
 355     returns => {
 356         type => 'array',
 357         items => {
 358             type => "object",
 359             properties => {},
 360         },
 361         links => [ { rel => 'child', href => "{vmid}" } ],
 362     },
 363     code => sub {
 364         my ($param) = @_;
 365
 366         my $rpcenv = PVE::RPCEnvironment::get();
 367         my $authuser = $rpcenv->get_user();
 368
 369         my $vmstatus = PVE::QemuServer::vmstatus(undef, $param->{full});
 370
 371         my $res = [];
 372         foreach my $vmid (keys %$vmstatus) {
 373             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
 374
 375             my $data = $vmstatus->{$vmid};
 376             $data->{vmid} = int($vmid);
 377             push @$res, $data;
 378         }
 379
 380         return $res;
 381     }});
 382
 383
 384
 385 __PACKAGE__->register_method({
 386     name => 'create_vm',
 387     path => '',
 388     method => 'POST',
 389     description => "Create or restore a virtual machine.",
 390     permissions => {
 391         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 392             "For restore (option 'archive'), it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 393             "If you create disks you need 'Datastore.AllocateSpace' on any used storage.",
 394         user => 'all', # check inside
 395     },
 396     protected => 1,
 397     proxyto => 'node',
 398     parameters => {
 399         additionalProperties => 0,
 400         properties => PVE::QemuServer::json_config_properties(
 401             {
 402                 node => get_standard_option('pve-node'),
 403                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 404                 archive => {
 405                     description => "The backup file.",
 406                     type => 'string',
 407                     optional => 1,
 408                     maxLength => 255,
 409                     completion => \&PVE::QemuServer::complete_backup_archives,
 410                 },
 411                 storage => get_standard_option('pve-storage-id', {
 412                     description => "Default storage.",
 413                     optional => 1,
 414                     completion => \&PVE::QemuServer::complete_storage,
 415                 }),
 416                 force => {
 417                     optional => 1,
 418                     type => 'boolean',
 419                     description => "Allow to overwrite existing VM.",
 420                     requires => 'archive',
 421                 },
 422                 unique => {
 423                     optional => 1,
 424                     type => 'boolean',
 425                     description => "Assign a unique random ethernet address.",
 426                     requires => 'archive',
 427                 },
 428                 pool => {
 429                     optional => 1,
 430                     type => 'string', format => 'pve-poolid',
 431                     description => "Add the VM to the specified pool.",
 432                 },
 433             }),
 434     },
 435     returns => {
 436         type => 'string',
 437     },
 438     code => sub {
 439         my ($param) = @_;
 440
 441         my $rpcenv = PVE::RPCEnvironment::get();
 442
 443         my $authuser = $rpcenv->get_user();
 444
 445         my $node = extract_param($param, 'node');
 446
 447         my $vmid = extract_param($param, 'vmid');
 448
 449         my $archive = extract_param($param, 'archive');
 450
 451         my $storage = extract_param($param, 'storage');
 452
 453         my $force = extract_param($param, 'force');
 454
 455         my $unique = extract_param($param, 'unique');
 456
 457         my $pool = extract_param($param, 'pool');
 458
 459         my $filename = PVE::QemuConfig->config_file($vmid);
 460
 461         my $storecfg = PVE::Storage::config();
 462
 463         if (defined(my $ssh_keys = $param->{sshkeys})) {
 464                 $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 465                 PVE::Tools::validate_ssh_public_keys($ssh_keys);
 466         }
 467
 468         PVE::Cluster::check_cfs_quorum();
 469
 470         if (defined($pool)) {
 471             $rpcenv->check_pool_exist($pool);
 472         }
 473
 474         $rpcenv->check($authuser, "/storage/$storage", ['Datastore.AllocateSpace'])
 475             if defined($storage);
 476
 477         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 478             # OK
 479         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 480             # OK
 481         } elsif ($archive && $force && (-f $filename) &&
 482                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 483             # OK: user has VM.Backup permissions, and want to restore an existing VM
 484         } else {
 485             raise_perm_exc();
 486         }
 487
 488         if (!$archive) {
 489             &$resolve_cdrom_alias($param);
 490
 491             &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param, $storage);
 492
 493             &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, $pool, [ keys %$param]);
 494
 495             foreach my $opt (keys %$param) {
 496                 if (PVE::QemuServer::is_valid_drivename($opt)) {
 497                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
 498                     raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
 499
 500                     PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
 501                     $param->{$opt} = PVE::QemuServer::print_drive($vmid, $drive);
 502                 }
 503             }
 504
 505             PVE::QemuServer::add_random_macs($param);
 506         } else {
 507             my $keystr = join(' ', keys %$param);
 508             raise_param_exc({ archive => "option conflicts with other options ($keystr)"}) if $keystr;
 509
 510             if ($archive eq '-') {
 511                 die "pipe requires cli environment\n"
 512                     if $rpcenv->{type} ne 'cli';
 513             } else {
 514                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $archive);
 515                 $archive = PVE::Storage::abs_filesystem_path($storecfg, $archive);
 516             }
 517         }
 518
 519         my $restorefn = sub {
 520             my $vmlist = PVE::Cluster::get_vmlist();
 521             if ($vmlist->{ids}->{$vmid}) {
 522                 my $current_node = $vmlist->{ids}->{$vmid}->{node};
 523                 if ($current_node eq $node) {
 524                     my $conf = PVE::QemuConfig->load_config($vmid);
 525
 526                     PVE::QemuConfig->check_protection($conf, "unable to restore VM $vmid");
 527
 528                     die "unable to restore vm $vmid - config file already exists\n"
 529                         if !$force;
 530
 531                     die "unable to restore vm $vmid - vm is running\n"
 532                         if PVE::QemuServer::check_running($vmid);
 533
 534                     die "unable to restore vm $vmid - vm is a template\n"
 535                         if PVE::QemuConfig->is_template($conf);
 536
 537                 } else {
 538                     die "unable to restore vm $vmid - already existing on cluster node '$current_node'\n";
 539                 }
 540             }
 541
 542             my $realcmd = sub {
 543                 PVE::QemuServer::restore_archive($archive, $vmid, $authuser, {
 544                     storage => $storage,
 545                     pool => $pool,
 546                     unique => $unique });
 547
 548                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 549             };
 550
 551             # ensure no old replication state are exists
 552             PVE::ReplicationState::delete_guest_states($vmid);
 553
 554             return $rpcenv->fork_worker('qmrestore', $vmid, $authuser, $realcmd);
 555         };
 556
 557         my $createfn = sub {
 558
 559             # test after locking
 560             PVE::Cluster::check_vmid_unused($vmid);
 561
 562             # ensure no old replication state are exists
 563             PVE::ReplicationState::delete_guest_states($vmid);
 564
 565             my $realcmd = sub {
 566
 567                 my $vollist = [];
 568
 569                 my $conf = $param;
 570
 571                 eval {
 572
 573                     $vollist = &$create_disks($rpcenv, $authuser, $conf, $storecfg, $vmid, $pool, $param, $storage);
 574
 575                     if (!$conf->{bootdisk}) {
 576                         my $firstdisk = PVE::QemuServer::resolve_first_disk($conf);
 577                         $conf->{bootdisk} = $firstdisk if $firstdisk;
 578                     }
 579
 580                     # auto generate uuid if user did not specify smbios1 option
 581                     if (!$conf->{smbios1}) {
 582                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 583                     }
 584
 585                     PVE::QemuConfig->write_config($vmid, $conf);
 586
 587                 };
 588                 my $err = $@;
 589
 590                 if ($err) {
 591                     foreach my $volid (@$vollist) {
 592                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 593                         warn $@ if $@;
 594                     }
 595                     die "create failed - $err";
 596                 }
 597
 598                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 599             };
 600
 601             return $rpcenv->fork_worker('qmcreate', $vmid, $authuser, $realcmd);
 602         };
 603
 604         return PVE::QemuConfig->lock_config_full($vmid, 1, $archive ? $restorefn : $createfn);
 605     }});
 606
 607 __PACKAGE__->register_method({
 608     name => 'vmdiridx',
 609     path => '{vmid}',
 610     method => 'GET',
 611     proxyto => 'node',
 612     description => "Directory index",
 613     permissions => {
 614         user => 'all',
 615     },
 616     parameters => {
 617         additionalProperties => 0,
 618         properties => {
 619             node => get_standard_option('pve-node'),
 620             vmid => get_standard_option('pve-vmid'),
 621         },
 622     },
 623     returns => {
 624         type => 'array',
 625         items => {
 626             type => "object",
 627             properties => {
 628                 subdir => { type => 'string' },
 629             },
 630         },
 631         links => [ { rel => 'child', href => "{subdir}" } ],
 632     },
 633     code => sub {
 634         my ($param) = @_;
 635
 636         my $res = [
 637             { subdir => 'config' },
 638             { subdir => 'pending' },
 639             { subdir => 'status' },
 640             { subdir => 'unlink' },
 641             { subdir => 'vncproxy' },
 642             { subdir => 'termproxy' },
 643             { subdir => 'migrate' },
 644             { subdir => 'resize' },
 645             { subdir => 'move' },
 646             { subdir => 'rrd' },
 647             { subdir => 'rrddata' },
 648             { subdir => 'monitor' },
 649             { subdir => 'agent' },
 650             { subdir => 'snapshot' },
 651             { subdir => 'spiceproxy' },
 652             { subdir => 'sendkey' },
 653             { subdir => 'firewall' },
 654             ];
 655
 656         return $res;
 657     }});
 658
 659 __PACKAGE__->register_method ({
 660     subclass => "PVE::API2::Firewall::VM",
 661     path => '{vmid}/firewall',
 662 });
 663
 664 __PACKAGE__->register_method ({
 665     subclass => "PVE::API2::Qemu::Agent",
 666     path => '{vmid}/agent',
 667 });
 668
 669 __PACKAGE__->register_method({
 670     name => 'rrd',
 671     path => '{vmid}/rrd',
 672     method => 'GET',
 673     protected => 1, # fixme: can we avoid that?
 674     permissions => {
 675         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 676     },
 677     description => "Read VM RRD statistics (returns PNG)",
 678     parameters => {
 679         additionalProperties => 0,
 680         properties => {
 681             node => get_standard_option('pve-node'),
 682             vmid => get_standard_option('pve-vmid'),
 683             timeframe => {
 684                 description => "Specify the time frame you are interested in.",
 685                 type => 'string',
 686                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 687             },
 688             ds => {
 689                 description => "The list of datasources you want to display.",
 690                 type => 'string', format => 'pve-configid-list',
 691             },
 692             cf => {
 693                 description => "The RRD consolidation function",
 694                 type => 'string',
 695                 enum => [ 'AVERAGE', 'MAX' ],
 696                 optional => 1,
 697             },
 698         },
 699     },
 700     returns => {
 701         type => "object",
 702         properties => {
 703             filename => { type => 'string' },
 704         },
 705     },
 706     code => sub {
 707         my ($param) = @_;
 708
 709         return PVE::Cluster::create_rrd_graph(
 710             "pve2-vm/$param->{vmid}", $param->{timeframe},
 711             $param->{ds}, $param->{cf});
 712
 713     }});
 714
 715 __PACKAGE__->register_method({
 716     name => 'rrddata',
 717     path => '{vmid}/rrddata',
 718     method => 'GET',
 719     protected => 1, # fixme: can we avoid that?
 720     permissions => {
 721         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 722     },
 723     description => "Read VM RRD statistics",
 724     parameters => {
 725         additionalProperties => 0,
 726         properties => {
 727             node => get_standard_option('pve-node'),
 728             vmid => get_standard_option('pve-vmid'),
 729             timeframe => {
 730                 description => "Specify the time frame you are interested in.",
 731                 type => 'string',
 732                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 733             },
 734             cf => {
 735                 description => "The RRD consolidation function",
 736                 type => 'string',
 737                 enum => [ 'AVERAGE', 'MAX' ],
 738                 optional => 1,
 739             },
 740         },
 741     },
 742     returns => {
 743         type => "array",
 744         items => {
 745             type => "object",
 746             properties => {},
 747         },
 748     },
 749     code => sub {
 750         my ($param) = @_;
 751
 752         return PVE::Cluster::create_rrd_data(
 753             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 754     }});
 755
 756
 757 __PACKAGE__->register_method({
 758     name => 'vm_config',
 759     path => '{vmid}/config',
 760     method => 'GET',
 761     proxyto => 'node',
 762     description => "Get current virtual machine configuration. This does not include pending configuration changes (see 'pending' API).",
 763     permissions => {
 764         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 765     },
 766     parameters => {
 767         additionalProperties => 0,
 768         properties => {
 769             node => get_standard_option('pve-node'),
 770             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 771             current => {
 772                 description => "Get current values (instead of pending values).",
 773                 optional => 1,
 774                 default => 0,
 775                 type => 'boolean',
 776             },
 777         },
 778     },
 779     returns => {
 780         type => "object",
 781         properties => {
 782             digest => {
 783                 type => 'string',
 784                 description => 'SHA1 digest of configuration file. This can be used to prevent concurrent modifications.',
 785             }
 786         },
 787     },
 788     code => sub {
 789         my ($param) = @_;
 790
 791         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 792
 793         delete $conf->{snapshots};
 794
 795         if (!$param->{current}) {
 796             foreach my $opt (keys %{$conf->{pending}}) {
 797                 next if $opt eq 'delete';
 798                 my $value = $conf->{pending}->{$opt};
 799                 next if ref($value); # just to be sure
 800                 $conf->{$opt} = $value;
 801             }
 802             my $pending_delete_hash = PVE::QemuServer::split_flagged_list($conf->{pending}->{delete});
 803             foreach my $opt (keys %$pending_delete_hash) {
 804                 delete $conf->{$opt} if $conf->{$opt};
 805             }
 806         }
 807
 808         delete $conf->{pending};
 809
 810         return $conf;
 811     }});
 812
 813 __PACKAGE__->register_method({
 814     name => 'vm_pending',
 815     path => '{vmid}/pending',
 816     method => 'GET',
 817     proxyto => 'node',
 818     description => "Get virtual machine configuration, including pending changes.",
 819     permissions => {
 820         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 821     },
 822     parameters => {
 823         additionalProperties => 0,
 824         properties => {
 825             node => get_standard_option('pve-node'),
 826             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 827         },
 828     },
 829     returns => {
 830         type => "array",
 831         items => {
 832             type => "object",
 833             properties => {
 834                 key => {
 835                     description => "Configuration option name.",
 836                     type => 'string',
 837                 },
 838                 value => {
 839                     description => "Current value.",
 840                     type => 'string',
 841                     optional => 1,
 842                 },
 843                 pending => {
 844                     description => "Pending value.",
 845                     type => 'string',
 846                     optional => 1,
 847                 },
 848                 delete => {
 849                     description => "Indicates a pending delete request if present and not 0. " .
 850                                    "The value 2 indicates a force-delete request.",
 851                     type => 'integer',
 852                     minimum => 0,
 853                     maximum => 2,
 854                     optional => 1,
 855                 },
 856             },
 857         },
 858     },
 859     code => sub {
 860         my ($param) = @_;
 861
 862         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 863
 864         my $pending_delete_hash = PVE::QemuServer::split_flagged_list($conf->{pending}->{delete});
 865
 866         my $res = [];
 867
 868         foreach my $opt (keys %$conf) {
 869             next if ref($conf->{$opt});
 870             my $item = { key => $opt };
 871             $item->{value} = $conf->{$opt} if defined($conf->{$opt});
 872             $item->{pending} = $conf->{pending}->{$opt} if defined($conf->{pending}->{$opt});
 873             $item->{delete} = ($pending_delete_hash->{$opt} ? 2 : 1) if exists $pending_delete_hash->{$opt};
 874             push @$res, $item;
 875         }
 876
 877         foreach my $opt (keys %{$conf->{pending}}) {
 878             next if $opt eq 'delete';
 879             next if ref($conf->{pending}->{$opt}); # just to be sure
 880             next if defined($conf->{$opt});
 881             my $item = { key => $opt };
 882             $item->{pending} = $conf->{pending}->{$opt};
 883             push @$res, $item;
 884         }
 885
 886         while (my ($opt, $force) = each %$pending_delete_hash) {
 887             next if $conf->{pending}->{$opt}; # just to be sure
 888             next if $conf->{$opt};
 889             my $item = { key => $opt, delete => ($force ? 2 : 1)};
 890             push @$res, $item;
 891         }
 892
 893         return $res;
 894     }});
 895
 896 # POST/PUT {vmid}/config implementation
 897 #
 898 # The original API used PUT (idempotent) an we assumed that all operations
 899 # are fast. But it turned out that almost any configuration change can
 900 # involve hot-plug actions, or disk alloc/free. Such actions can take long
 901 # time to complete and have side effects (not idempotent).
 902 #
 903 # The new implementation uses POST and forks a worker process. We added
 904 # a new option 'background_delay'. If specified we wait up to
 905 # 'background_delay' second for the worker task to complete. It returns null
 906 # if the task is finished within that time, else we return the UPID.
 907
 908 my $update_vm_api  = sub {
 909     my ($param, $sync) = @_;
 910
 911     my $rpcenv = PVE::RPCEnvironment::get();
 912
 913     my $authuser = $rpcenv->get_user();
 914
 915     my $node = extract_param($param, 'node');
 916
 917     my $vmid = extract_param($param, 'vmid');
 918
 919     my $digest = extract_param($param, 'digest');
 920
 921     my $background_delay = extract_param($param, 'background_delay');
 922
 923
 924     my @paramarr = (); # used for log message
 925     foreach my $key (sort keys %$param) {
 926         push @paramarr, "-$key", $param->{$key};
 927     }
 928
 929     my $skiplock = extract_param($param, 'skiplock');
 930     raise_param_exc({ skiplock => "Only root may use this option." })
 931         if $skiplock && $authuser ne 'root@pam';
 932
 933     my $delete_str = extract_param($param, 'delete');
 934
 935     my $revert_str = extract_param($param, 'revert');
 936
 937     my $force = extract_param($param, 'force');
 938
 939     if (defined(my $ssh_keys = $param->{sshkeys})) {
 940             $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 941             PVE::Tools::validate_ssh_public_keys($ssh_keys);
 942     }
 943
 944     die "no options specified\n" if !$delete_str && !$revert_str && !scalar(keys %$param);
 945
 946     my $storecfg = PVE::Storage::config();
 947
 948     my $defaults = PVE::QemuServer::load_defaults();
 949
 950     &$resolve_cdrom_alias($param);
 951
 952     # now try to verify all parameters
 953
 954     my $revert = {};
 955     foreach my $opt (PVE::Tools::split_list($revert_str)) {
 956         if (!PVE::QemuServer::option_exists($opt)) {
 957             raise_param_exc({ revert => "unknown option '$opt'" });
 958         }
 959
 960         raise_param_exc({ delete => "you can't use '-$opt' and " .
 961                               "-revert $opt' at the same time" })
 962             if defined($param->{$opt});
 963
 964         $revert->{$opt} = 1;
 965     }
 966
 967     my @delete = ();
 968     foreach my $opt (PVE::Tools::split_list($delete_str)) {
 969         $opt = 'ide2' if $opt eq 'cdrom';
 970
 971         raise_param_exc({ delete => "you can't use '-$opt' and " .
 972                               "-delete $opt' at the same time" })
 973             if defined($param->{$opt});
 974
 975         raise_param_exc({ revert => "you can't use '-delete $opt' and " .
 976                               "-revert $opt' at the same time" })
 977             if $revert->{$opt};
 978
 979         if (!PVE::QemuServer::option_exists($opt)) {
 980             raise_param_exc({ delete => "unknown option '$opt'" });
 981         }
 982
 983         push @delete, $opt;
 984     }
 985
 986     my $repl_conf = PVE::ReplicationConfig->new();
 987     my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
 988     my $check_replication = sub {
 989         my ($drive) = @_;
 990         return if !$is_replicated;
 991         my $volid = $drive->{file};
 992         return if !$volid || !($drive->{replicate}//1);
 993         return if PVE::QemuServer::drive_is_cdrom($drive);
 994         my ($storeid, $format);
 995         if ($volid =~ $NEW_DISK_RE) {
 996             $storeid = $2;
 997             $format = $drive->{format} || PVE::Storage::storage_default_format($storecfg, $storeid);
 998         } else {
 999             ($storeid, undef) = PVE::Storage::parse_volume_id($volid, 1);
1000             $format = (PVE::Storage::parse_volname($storecfg, $volid))[6];
1001         }
1002         return if PVE::Storage::storage_can_replicate($storecfg, $storeid, $format);
1003         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
1004         return if $scfg->{shared};
1005         die "cannot add non-replicatable volume to a replicated VM\n";
1006     };
1007
1008     foreach my $opt (keys %$param) {
1009         if (PVE::QemuServer::is_valid_drivename($opt)) {
1010             # cleanup drive path
1011             my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1012             raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
1013             PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
1014             $check_replication->($drive);
1015             $param->{$opt} = PVE::QemuServer::print_drive($vmid, $drive);
1016         } elsif ($opt =~ m/^net(\d+)$/) {
1017             # add macaddr
1018             my $net = PVE::QemuServer::parse_net($param->{$opt});
1019             $param->{$opt} = PVE::QemuServer::print_net($net);
1020         }
1021     }
1022
1023     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [@delete]);
1024
1025     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [keys %$param]);
1026
1027     &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param);
1028
1029     my $updatefn =  sub {
1030
1031         my $conf = PVE::QemuConfig->load_config($vmid);
1032
1033         die "checksum missmatch (file change by other user?)\n"
1034             if $digest && $digest ne $conf->{digest};
1035
1036         PVE::QemuConfig->check_lock($conf) if !$skiplock;
1037
1038         foreach my $opt (keys %$revert) {
1039             if (defined($conf->{$opt})) {
1040                 $param->{$opt} = $conf->{$opt};
1041             } elsif (defined($conf->{pending}->{$opt})) {
1042                 push @delete, $opt;
1043             }
1044         }
1045
1046         if ($param->{memory} || defined($param->{balloon})) {
1047             my $maxmem = $param->{memory} || $conf->{pending}->{memory} || $conf->{memory} || $defaults->{memory};
1048             my $balloon = defined($param->{balloon}) ? $param->{balloon} : $conf->{pending}->{balloon} || $conf->{balloon};
1049
1050             die "balloon value too large (must be smaller than assigned memory)\n"
1051                 if $balloon && $balloon > $maxmem;
1052         }
1053
1054         PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: " . join (' ', @paramarr));
1055
1056         my $worker = sub {
1057
1058             print "update VM $vmid: " . join (' ', @paramarr) . "\n";
1059
1060             # write updates to pending section
1061
1062             my $modified = {}; # record what $option we modify
1063
1064             foreach my $opt (@delete) {
1065                 $modified->{$opt} = 1;
1066                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1067                 if (!defined($conf->{$opt}) && !defined($conf->{pending}->{$opt})) {
1068                     warn "cannot delete '$opt' - not set in current configuration!\n";
1069                     $modified->{$opt} = 0;
1070                     next;
1071                 }
1072
1073                 if ($opt =~ m/^unused/) {
1074                     my $drive = PVE::QemuServer::parse_drive($opt, $conf->{$opt});
1075                     PVE::QemuConfig->check_protection($conf, "can't remove unused disk '$drive->{file}'");
1076                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1077                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, $drive, $rpcenv, $authuser)) {
1078                         delete $conf->{$opt};
1079                         PVE::QemuConfig->write_config($vmid, $conf);
1080                     }
1081                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
1082                     PVE::QemuConfig->check_protection($conf, "can't remove drive '$opt'");
1083                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1084                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1085                         if defined($conf->{pending}->{$opt});
1086                     PVE::QemuServer::vmconfig_delete_pending_option($conf, $opt, $force);
1087                     PVE::QemuConfig->write_config($vmid, $conf);
1088                 } else {
1089                     PVE::QemuServer::vmconfig_delete_pending_option($conf, $opt, $force);
1090                     PVE::QemuConfig->write_config($vmid, $conf);
1091                 }
1092             }
1093
1094             foreach my $opt (keys %$param) { # add/change
1095                 $modified->{$opt} = 1;
1096                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1097                 next if defined($conf->{pending}->{$opt}) && ($param->{$opt} eq $conf->{pending}->{$opt}); # skip if nothing changed
1098
1099                 if (PVE::QemuServer::is_valid_drivename($opt)) {
1100                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1101                     if (PVE::QemuServer::drive_is_cdrom($drive)) { # CDROM
1102                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1103                     } else {
1104                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1105                     }
1106                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1107                         if defined($conf->{pending}->{$opt});
1108
1109                     &$create_disks($rpcenv, $authuser, $conf->{pending}, $storecfg, $vmid, undef, {$opt => $param->{$opt}});
1110                 } else {
1111                     $conf->{pending}->{$opt} = $param->{$opt};
1112                 }
1113                 PVE::QemuServer::vmconfig_undelete_pending_option($conf, $opt);
1114                 PVE::QemuConfig->write_config($vmid, $conf);
1115             }
1116
1117             # remove pending changes when nothing changed
1118             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1119             my $changes = PVE::QemuServer::vmconfig_cleanup_pending($conf);
1120             PVE::QemuConfig->write_config($vmid, $conf) if $changes;
1121
1122             return if !scalar(keys %{$conf->{pending}});
1123
1124             my $running = PVE::QemuServer::check_running($vmid);
1125
1126             # apply pending changes
1127
1128             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1129
1130             if ($running) {
1131                 my $errors = {};
1132                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $conf, $storecfg, $modified, $errors);
1133                 raise_param_exc($errors) if scalar(keys %$errors);
1134             } else {
1135                 PVE::QemuServer::vmconfig_apply_pending($vmid, $conf, $storecfg, $running);
1136             }
1137
1138             return;
1139         };
1140
1141         if ($sync) {
1142             &$worker();
1143             return undef;
1144         } else {
1145             my $upid = $rpcenv->fork_worker('qmconfig', $vmid, $authuser, $worker);
1146
1147             if ($background_delay) {
1148
1149                 # Note: It would be better to do that in the Event based HTTPServer
1150                 # to avoid blocking call to sleep.
1151
1152                 my $end_time = time() + $background_delay;
1153
1154                 my $task = PVE::Tools::upid_decode($upid);
1155
1156                 my $running = 1;
1157                 while (time() < $end_time) {
1158                     $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
1159                     last if !$running;
1160                     sleep(1); # this gets interrupted when child process ends
1161                 }
1162
1163                 if (!$running) {
1164                     my $status = PVE::Tools::upid_read_status($upid);
1165                     return undef if $status eq 'OK';
1166                     die $status;
1167                 }
1168             }
1169
1170             return $upid;
1171         }
1172     };
1173
1174     return PVE::QemuConfig->lock_config($vmid, $updatefn);
1175 };
1176
1177 my $vm_config_perm_list = [
1178             'VM.Config.Disk',
1179             'VM.Config.CDROM',
1180             'VM.Config.CPU',
1181             'VM.Config.Memory',
1182             'VM.Config.Network',
1183             'VM.Config.HWType',
1184             'VM.Config.Options',
1185     ];
1186
1187 __PACKAGE__->register_method({
1188     name => 'update_vm_async',
1189     path => '{vmid}/config',
1190     method => 'POST',
1191     protected => 1,
1192     proxyto => 'node',
1193     description => "Set virtual machine options (asynchrounous API).",
1194     permissions => {
1195         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1196     },
1197     parameters => {
1198         additionalProperties => 0,
1199         properties => PVE::QemuServer::json_config_properties(
1200             {
1201                 node => get_standard_option('pve-node'),
1202                 vmid => get_standard_option('pve-vmid'),
1203                 skiplock => get_standard_option('skiplock'),
1204                 delete => {
1205                     type => 'string', format => 'pve-configid-list',
1206                     description => "A list of settings you want to delete.",
1207                     optional => 1,
1208                 },
1209                 revert => {
1210                     type => 'string', format => 'pve-configid-list',
1211                     description => "Revert a pending change.",
1212                     optional => 1,
1213                 },
1214                 force => {
1215                     type => 'boolean',
1216                     description => $opt_force_description,
1217                     optional => 1,
1218                     requires => 'delete',
1219                 },
1220                 digest => {
1221                     type => 'string',
1222                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1223                     maxLength => 40,
1224                     optional => 1,
1225                 },
1226                 background_delay => {
1227                     type => 'integer',
1228                     description => "Time to wait for the task to finish. We return 'null' if the task finish within that time.",
1229                     minimum => 1,
1230                     maximum => 30,
1231                     optional => 1,
1232                 },
1233             }),
1234     },
1235     returns => {
1236         type => 'string',
1237         optional => 1,
1238     },
1239     code => $update_vm_api,
1240 });
1241
1242 __PACKAGE__->register_method({
1243     name => 'update_vm',
1244     path => '{vmid}/config',
1245     method => 'PUT',
1246     protected => 1,
1247     proxyto => 'node',
1248     description => "Set virtual machine options (synchrounous API) - You should consider using the POST method instead for any actions involving hotplug or storage allocation.",
1249     permissions => {
1250         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1251     },
1252     parameters => {
1253         additionalProperties => 0,
1254         properties => PVE::QemuServer::json_config_properties(
1255             {
1256                 node => get_standard_option('pve-node'),
1257                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1258                 skiplock => get_standard_option('skiplock'),
1259                 delete => {
1260                     type => 'string', format => 'pve-configid-list',
1261                     description => "A list of settings you want to delete.",
1262                     optional => 1,
1263                 },
1264                 revert => {
1265                     type => 'string', format => 'pve-configid-list',
1266                     description => "Revert a pending change.",
1267                     optional => 1,
1268                 },
1269                 force => {
1270                     type => 'boolean',
1271                     description => $opt_force_description,
1272                     optional => 1,
1273                     requires => 'delete',
1274                 },
1275                 digest => {
1276                     type => 'string',
1277                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1278                     maxLength => 40,
1279                     optional => 1,
1280                 },
1281             }),
1282     },
1283     returns => { type => 'null' },
1284     code => sub {
1285         my ($param) = @_;
1286         &$update_vm_api($param, 1);
1287         return undef;
1288     }
1289 });
1290
1291
1292 __PACKAGE__->register_method({
1293     name => 'destroy_vm',
1294     path => '{vmid}',
1295     method => 'DELETE',
1296     protected => 1,
1297     proxyto => 'node',
1298     description => "Destroy the vm (also delete all used/owned volumes).",
1299     permissions => {
1300         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1301     },
1302     parameters => {
1303         additionalProperties => 0,
1304         properties => {
1305             node => get_standard_option('pve-node'),
1306             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1307             skiplock => get_standard_option('skiplock'),
1308         },
1309     },
1310     returns => {
1311         type => 'string',
1312     },
1313     code => sub {
1314         my ($param) = @_;
1315
1316         my $rpcenv = PVE::RPCEnvironment::get();
1317
1318         my $authuser = $rpcenv->get_user();
1319
1320         my $vmid = $param->{vmid};
1321
1322         my $skiplock = $param->{skiplock};
1323         raise_param_exc({ skiplock => "Only root may use this option." })
1324             if $skiplock && $authuser ne 'root@pam';
1325
1326         # test if VM exists
1327         my $conf = PVE::QemuConfig->load_config($vmid);
1328
1329         my $storecfg = PVE::Storage::config();
1330
1331         PVE::QemuConfig->check_protection($conf, "can't remove VM $vmid");
1332
1333         die "unable to remove VM $vmid - used in HA resources\n"
1334             if PVE::HA::Config::vm_is_ha_managed($vmid);
1335
1336         # do not allow destroy if there are replication jobs
1337         my $repl_conf = PVE::ReplicationConfig->new();
1338         $repl_conf->check_for_existing_jobs($vmid);
1339
1340         # early tests (repeat after locking)
1341         die "VM $vmid is running - destroy failed\n"
1342             if PVE::QemuServer::check_running($vmid);
1343
1344         my $realcmd = sub {
1345             my $upid = shift;
1346
1347             syslog('info', "destroy VM $vmid: $upid\n");
1348
1349             PVE::QemuServer::vm_destroy($storecfg, $vmid, $skiplock);
1350
1351             PVE::AccessControl::remove_vm_access($vmid);
1352
1353             PVE::Firewall::remove_vmfw_conf($vmid);
1354         };
1355
1356         return $rpcenv->fork_worker('qmdestroy', $vmid, $authuser, $realcmd);
1357     }});
1358
1359 __PACKAGE__->register_method({
1360     name => 'unlink',
1361     path => '{vmid}/unlink',
1362     method => 'PUT',
1363     protected => 1,
1364     proxyto => 'node',
1365     description => "Unlink/delete disk images.",
1366     permissions => {
1367         check => [ 'perm', '/vms/{vmid}', ['VM.Config.Disk']],
1368     },
1369     parameters => {
1370         additionalProperties => 0,
1371         properties => {
1372             node => get_standard_option('pve-node'),
1373             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1374             idlist => {
1375                 type => 'string', format => 'pve-configid-list',
1376                 description => "A list of disk IDs you want to delete.",
1377             },
1378             force => {
1379                 type => 'boolean',
1380                 description => $opt_force_description,
1381                 optional => 1,
1382             },
1383         },
1384     },
1385     returns => { type => 'null'},
1386     code => sub {
1387         my ($param) = @_;
1388
1389         $param->{delete} = extract_param($param, 'idlist');
1390
1391         __PACKAGE__->update_vm($param);
1392
1393         return undef;
1394     }});
1395
1396 my $sslcert;
1397
1398 __PACKAGE__->register_method({
1399     name => 'vncproxy',
1400     path => '{vmid}/vncproxy',
1401     method => 'POST',
1402     protected => 1,
1403     permissions => {
1404         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1405     },
1406     description => "Creates a TCP VNC proxy connections.",
1407     parameters => {
1408         additionalProperties => 0,
1409         properties => {
1410             node => get_standard_option('pve-node'),
1411             vmid => get_standard_option('pve-vmid'),
1412             websocket => {
1413                 optional => 1,
1414                 type => 'boolean',
1415                 description => "starts websockify instead of vncproxy",
1416             },
1417         },
1418     },
1419     returns => {
1420         additionalProperties => 0,
1421         properties => {
1422             user => { type => 'string' },
1423             ticket => { type => 'string' },
1424             cert => { type => 'string' },
1425             port => { type => 'integer' },
1426             upid => { type => 'string' },
1427         },
1428     },
1429     code => sub {
1430         my ($param) = @_;
1431
1432         my $rpcenv = PVE::RPCEnvironment::get();
1433
1434         my $authuser = $rpcenv->get_user();
1435
1436         my $vmid = $param->{vmid};
1437         my $node = $param->{node};
1438         my $websocket = $param->{websocket};
1439
1440         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1441
1442         my $authpath = "/vms/$vmid";
1443
1444         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1445
1446         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
1447             if !$sslcert;
1448
1449         my ($remip, $family);
1450         my $remcmd = [];
1451
1452         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1453             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
1454             # NOTE: kvm VNC traffic is already TLS encrypted or is known unsecure
1455             $remcmd = ['/usr/bin/ssh', '-e', 'none', '-T', '-o', 'BatchMode=yes', $remip];
1456         } else {
1457             $family = PVE::Tools::get_host_address_family($node);
1458         }
1459
1460         my $port = PVE::Tools::next_vnc_port($family);
1461
1462         my $timeout = 10;
1463
1464         my $realcmd = sub {
1465             my $upid = shift;
1466
1467             syslog('info', "starting vnc proxy $upid\n");
1468
1469             my $cmd;
1470
1471             if ($conf->{vga} && ($conf->{vga} =~ m/^serial\d+$/)) {
1472
1473
1474                 my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-iface', $conf->{vga}, '-escape', '0' ];
1475
1476                 $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
1477                         '-timeout', $timeout, '-authpath', $authpath,
1478                         '-perm', 'Sys.Console'];
1479
1480                 if ($param->{websocket}) {
1481                     $ENV{PVE_VNC_TICKET} = $ticket; # pass ticket to vncterm
1482                     push @$cmd, '-notls', '-listen', 'localhost';
1483                 }
1484
1485                 push @$cmd, '-c', @$remcmd, @$termcmd;
1486
1487                 PVE::Tools::run_command($cmd);
1488
1489             } else {
1490
1491                 $ENV{LC_PVE_TICKET} = $ticket if $websocket; # set ticket with "qm vncproxy"
1492
1493                 $cmd = [@$remcmd, "/usr/sbin/qm", 'vncproxy', $vmid];
1494
1495                 my $sock = IO::Socket::IP->new(
1496                     ReuseAddr => 1,
1497                     Listen => 1,
1498                     LocalPort => $port,
1499                     Proto => 'tcp',
1500                     GetAddrInfoFlags => 0,
1501                     ) or die "failed to create socket: $!\n";
1502                 # Inside the worker we shouldn't have any previous alarms
1503                 # running anyway...:
1504                 alarm(0);
1505                 local $SIG{ALRM} = sub { die "connection timed out\n" };
1506                 alarm $timeout;
1507                 accept(my $cli, $sock) or die "connection failed: $!\n";
1508                 alarm(0);
1509                 close($sock);
1510                 if (PVE::Tools::run_command($cmd,
1511                     output => '>&'.fileno($cli),
1512                     input => '<&'.fileno($cli),
1513                     noerr => 1) != 0)
1514                 {
1515                     die "Failed to run vncproxy.\n";
1516                 }
1517             }
1518
1519             return;
1520         };
1521
1522         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1523
1524         PVE::Tools::wait_for_vnc_port($port);
1525
1526         return {
1527             user => $authuser,
1528             ticket => $ticket,
1529             port => $port,
1530             upid => $upid,
1531             cert => $sslcert,
1532         };
1533     }});
1534
1535 __PACKAGE__->register_method({
1536     name => 'termproxy',
1537     path => '{vmid}/termproxy',
1538     method => 'POST',
1539     protected => 1,
1540     permissions => {
1541         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1542     },
1543     description => "Creates a TCP proxy connections.",
1544     parameters => {
1545         additionalProperties => 0,
1546         properties => {
1547             node => get_standard_option('pve-node'),
1548             vmid => get_standard_option('pve-vmid'),
1549             serial=> {
1550                 optional => 1,
1551                 type => 'string',
1552                 enum => [qw(serial0 serial1 serial2 serial3)],
1553                 description => "opens a serial terminal (defaults to display)",
1554             },
1555         },
1556     },
1557     returns => {
1558         additionalProperties => 0,
1559         properties => {
1560             user => { type => 'string' },
1561             ticket => { type => 'string' },
1562             port => { type => 'integer' },
1563             upid => { type => 'string' },
1564         },
1565     },
1566     code => sub {
1567         my ($param) = @_;
1568
1569         my $rpcenv = PVE::RPCEnvironment::get();
1570
1571         my $authuser = $rpcenv->get_user();
1572
1573         my $vmid = $param->{vmid};
1574         my $node = $param->{node};
1575         my $serial = $param->{serial};
1576
1577         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1578
1579         if (!defined($serial)) {
1580             if ($conf->{vga} && $conf->{vga} =~ m/^serial\d+$/) {
1581                 $serial = $conf->{vga};
1582             }
1583         }
1584
1585         my $authpath = "/vms/$vmid";
1586
1587         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1588
1589         my ($remip, $family);
1590
1591         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1592             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
1593         } else {
1594             $family = PVE::Tools::get_host_address_family($node);
1595         }
1596
1597         my $port = PVE::Tools::next_vnc_port($family);
1598
1599         my $remcmd = $remip ?
1600             ['/usr/bin/ssh', '-e', 'none', '-t', $remip, '--'] : [];
1601
1602         my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-escape', '0'];
1603         push @$termcmd, '-iface', $serial if $serial;
1604
1605         my $realcmd = sub {
1606             my $upid = shift;
1607
1608             syslog('info', "starting qemu termproxy $upid\n");
1609
1610             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
1611                        '--perm', 'VM.Console', '--'];
1612             push @$cmd, @$remcmd, @$termcmd;
1613
1614             PVE::Tools::run_command($cmd);
1615         };
1616
1617         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1618
1619         PVE::Tools::wait_for_vnc_port($port);
1620
1621         return {
1622             user => $authuser,
1623             ticket => $ticket,
1624             port => $port,
1625             upid => $upid,
1626         };
1627     }});
1628
1629 __PACKAGE__->register_method({
1630     name => 'vncwebsocket',
1631     path => '{vmid}/vncwebsocket',
1632     method => 'GET',
1633     permissions => {
1634         description => "You also need to pass a valid ticket (vncticket).",
1635         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1636     },
1637     description => "Opens a weksocket for VNC traffic.",
1638     parameters => {
1639         additionalProperties => 0,
1640         properties => {
1641             node => get_standard_option('pve-node'),
1642             vmid => get_standard_option('pve-vmid'),
1643             vncticket => {
1644                 description => "Ticket from previous call to vncproxy.",
1645                 type => 'string',
1646                 maxLength => 512,
1647             },
1648             port => {
1649                 description => "Port number returned by previous vncproxy call.",
1650                 type => 'integer',
1651                 minimum => 5900,
1652                 maximum => 5999,
1653             },
1654         },
1655     },
1656     returns => {
1657         type => "object",
1658         properties => {
1659             port => { type => 'string' },
1660         },
1661     },
1662     code => sub {
1663         my ($param) = @_;
1664
1665         my $rpcenv = PVE::RPCEnvironment::get();
1666
1667         my $authuser = $rpcenv->get_user();
1668
1669         my $vmid = $param->{vmid};
1670         my $node = $param->{node};
1671
1672         my $authpath = "/vms/$vmid";
1673
1674         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
1675
1676         my $conf = PVE::QemuConfig->load_config($vmid, $node); # VM exists ?
1677
1678         # Note: VNC ports are acessible from outside, so we do not gain any
1679         # security if we verify that $param->{port} belongs to VM $vmid. This
1680         # check is done by verifying the VNC ticket (inside VNC protocol).
1681
1682         my $port = $param->{port};
1683
1684         return { port => $port };
1685     }});
1686
1687 __PACKAGE__->register_method({
1688     name => 'spiceproxy',
1689     path => '{vmid}/spiceproxy',
1690     method => 'POST',
1691     protected => 1,
1692     proxyto => 'node',
1693     permissions => {
1694         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1695     },
1696     description => "Returns a SPICE configuration to connect to the VM.",
1697     parameters => {
1698         additionalProperties => 0,
1699         properties => {
1700             node => get_standard_option('pve-node'),
1701             vmid => get_standard_option('pve-vmid'),
1702             proxy => get_standard_option('spice-proxy', { optional => 1 }),
1703         },
1704     },
1705     returns => get_standard_option('remote-viewer-config'),
1706     code => sub {
1707         my ($param) = @_;
1708
1709         my $rpcenv = PVE::RPCEnvironment::get();
1710
1711         my $authuser = $rpcenv->get_user();
1712
1713         my $vmid = $param->{vmid};
1714         my $node = $param->{node};
1715         my $proxy = $param->{proxy};
1716
1717         my $conf = PVE::QemuConfig->load_config($vmid, $node);
1718         my $title = "VM $vmid";
1719         $title .= " - ". $conf->{name} if $conf->{name};
1720
1721         my $port = PVE::QemuServer::spice_port($vmid);
1722
1723         my ($ticket, undef, $remote_viewer_config) =
1724             PVE::AccessControl::remote_viewer_config($authuser, $vmid, $node, $proxy, $title, $port);
1725
1726         PVE::QemuServer::vm_mon_cmd($vmid, "set_password", protocol => 'spice', password => $ticket);
1727         PVE::QemuServer::vm_mon_cmd($vmid, "expire_password", protocol => 'spice', time => "+30");
1728
1729         return $remote_viewer_config;
1730     }});
1731
1732 __PACKAGE__->register_method({
1733     name => 'vmcmdidx',
1734     path => '{vmid}/status',
1735     method => 'GET',
1736     proxyto => 'node',
1737     description => "Directory index",
1738     permissions => {
1739         user => 'all',
1740     },
1741     parameters => {
1742         additionalProperties => 0,
1743         properties => {
1744             node => get_standard_option('pve-node'),
1745             vmid => get_standard_option('pve-vmid'),
1746         },
1747     },
1748     returns => {
1749         type => 'array',
1750         items => {
1751             type => "object",
1752             properties => {
1753                 subdir => { type => 'string' },
1754             },
1755         },
1756         links => [ { rel => 'child', href => "{subdir}" } ],
1757     },
1758     code => sub {
1759         my ($param) = @_;
1760
1761         # test if VM exists
1762         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1763
1764         my $res = [
1765             { subdir => 'current' },
1766             { subdir => 'start' },
1767             { subdir => 'stop' },
1768             ];
1769
1770         return $res;
1771     }});
1772
1773 __PACKAGE__->register_method({
1774     name => 'vm_status',
1775     path => '{vmid}/status/current',
1776     method => 'GET',
1777     proxyto => 'node',
1778     protected => 1, # qemu pid files are only readable by root
1779     description => "Get virtual machine status.",
1780     permissions => {
1781         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1782     },
1783     parameters => {
1784         additionalProperties => 0,
1785         properties => {
1786             node => get_standard_option('pve-node'),
1787             vmid => get_standard_option('pve-vmid'),
1788         },
1789     },
1790     returns => { type => 'object' },
1791     code => sub {
1792         my ($param) = @_;
1793
1794         # test if VM exists
1795         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1796
1797         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
1798         my $status = $vmstatus->{$param->{vmid}};
1799
1800         $status->{ha} = PVE::HA::Config::get_service_status("vm:$param->{vmid}");
1801
1802         $status->{spice} = 1 if PVE::QemuServer::vga_conf_has_spice($conf->{vga});
1803
1804         $status->{agent} = 1 if $conf->{agent};
1805
1806         return $status;
1807     }});
1808
1809 __PACKAGE__->register_method({
1810     name => 'vm_start',
1811     path => '{vmid}/status/start',
1812     method => 'POST',
1813     protected => 1,
1814     proxyto => 'node',
1815     description => "Start virtual machine.",
1816     permissions => {
1817         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
1818     },
1819     parameters => {
1820         additionalProperties => 0,
1821         properties => {
1822             node => get_standard_option('pve-node'),
1823             vmid => get_standard_option('pve-vmid',
1824                                         { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1825             skiplock => get_standard_option('skiplock'),
1826             stateuri => get_standard_option('pve-qm-stateuri'),
1827             migratedfrom => get_standard_option('pve-node',{ optional => 1 }),
1828             migration_type => {
1829                 type => 'string',
1830                 enum => ['secure', 'insecure'],
1831                 description => "Migration traffic is encrypted using an SSH " .
1832                   "tunnel by default. On secure, completely private networks " .
1833                   "this can be disabled to increase performance.",
1834                 optional => 1,
1835             },
1836             migration_network => {
1837                 type => 'string', format => 'CIDR',
1838                 description => "CIDR of the (sub) network that is used for migration.",
1839                 optional => 1,
1840             },
1841             machine => get_standard_option('pve-qm-machine'),
1842             targetstorage => {
1843                 description => "Target storage for the migration. (Can be '1' to use the same storage id as on the source node.)",
1844                 type => 'string',
1845                 optional => 1
1846             }
1847         },
1848     },
1849     returns => {
1850         type => 'string',
1851     },
1852     code => sub {
1853         my ($param) = @_;
1854
1855         my $rpcenv = PVE::RPCEnvironment::get();
1856
1857         my $authuser = $rpcenv->get_user();
1858
1859         my $node = extract_param($param, 'node');
1860
1861         my $vmid = extract_param($param, 'vmid');
1862
1863         my $machine = extract_param($param, 'machine');
1864
1865         my $stateuri = extract_param($param, 'stateuri');
1866         raise_param_exc({ stateuri => "Only root may use this option." })
1867             if $stateuri && $authuser ne 'root@pam';
1868
1869         my $skiplock = extract_param($param, 'skiplock');
1870         raise_param_exc({ skiplock => "Only root may use this option." })
1871             if $skiplock && $authuser ne 'root@pam';
1872
1873         my $migratedfrom = extract_param($param, 'migratedfrom');
1874         raise_param_exc({ migratedfrom => "Only root may use this option." })
1875             if $migratedfrom && $authuser ne 'root@pam';
1876
1877         my $migration_type = extract_param($param, 'migration_type');
1878         raise_param_exc({ migration_type => "Only root may use this option." })
1879             if $migration_type && $authuser ne 'root@pam';
1880
1881         my $migration_network = extract_param($param, 'migration_network');
1882         raise_param_exc({ migration_network => "Only root may use this option." })
1883             if $migration_network && $authuser ne 'root@pam';
1884
1885         my $targetstorage = extract_param($param, 'targetstorage');
1886         raise_param_exc({ targetstorage => "Only root may use this option." })
1887             if $targetstorage && $authuser ne 'root@pam';
1888
1889         raise_param_exc({ targetstorage => "targetstorage can only by used with migratedfrom." })
1890             if $targetstorage && !$migratedfrom;
1891
1892         # read spice ticket from STDIN
1893         my $spice_ticket;
1894         if ($stateuri && ($stateuri eq 'tcp') && $migratedfrom && ($rpcenv->{type} eq 'cli')) {
1895             if (defined(my $line = <STDIN>)) {
1896                 chomp $line;
1897                 $spice_ticket = $line;
1898             }
1899         }
1900
1901         PVE::Cluster::check_cfs_quorum();
1902
1903         my $storecfg = PVE::Storage::config();
1904
1905         if (PVE::HA::Config::vm_is_ha_managed($vmid) && !$stateuri &&
1906             $rpcenv->{type} ne 'ha') {
1907
1908             my $hacmd = sub {
1909                 my $upid = shift;
1910
1911                 my $service = "vm:$vmid";
1912
1913                 my $cmd = ['ha-manager', 'set', $service, '--state', 'started'];
1914
1915                 print "Requesting HA start for VM $vmid\n";
1916
1917                 PVE::Tools::run_command($cmd);
1918
1919                 return;
1920             };
1921
1922             return $rpcenv->fork_worker('hastart', $vmid, $authuser, $hacmd);
1923
1924         } else {
1925
1926             my $realcmd = sub {
1927                 my $upid = shift;
1928
1929                 syslog('info', "start VM $vmid: $upid\n");
1930
1931                 PVE::QemuServer::vm_start($storecfg, $vmid, $stateuri, $skiplock, $migratedfrom, undef,
1932                                           $machine, $spice_ticket, $migration_network, $migration_type, $targetstorage);
1933
1934                 return;
1935             };
1936
1937             return $rpcenv->fork_worker('qmstart', $vmid, $authuser, $realcmd);
1938         }
1939     }});
1940
1941 __PACKAGE__->register_method({
1942     name => 'vm_stop',
1943     path => '{vmid}/status/stop',
1944     method => 'POST',
1945     protected => 1,
1946     proxyto => 'node',
1947     description => "Stop virtual machine. The qemu process will exit immediately. This" .
1948         "is akin to pulling the power plug of a running computer and may damage the VM data",
1949     permissions => {
1950         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
1951     },
1952     parameters => {
1953         additionalProperties => 0,
1954         properties => {
1955             node => get_standard_option('pve-node'),
1956             vmid => get_standard_option('pve-vmid',
1957                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
1958             skiplock => get_standard_option('skiplock'),
1959             migratedfrom => get_standard_option('pve-node', { optional => 1 }),
1960             timeout => {
1961                 description => "Wait maximal timeout seconds.",
1962                 type => 'integer',
1963                 minimum => 0,
1964                 optional => 1,
1965             },
1966             keepActive => {
1967                 description => "Do not deactivate storage volumes.",
1968                 type => 'boolean',
1969                 optional => 1,
1970                 default => 0,
1971             }
1972         },
1973     },
1974     returns => {
1975         type => 'string',
1976     },
1977     code => sub {
1978         my ($param) = @_;
1979
1980         my $rpcenv = PVE::RPCEnvironment::get();
1981
1982         my $authuser = $rpcenv->get_user();
1983
1984         my $node = extract_param($param, 'node');
1985
1986         my $vmid = extract_param($param, 'vmid');
1987
1988         my $skiplock = extract_param($param, 'skiplock');
1989         raise_param_exc({ skiplock => "Only root may use this option." })
1990             if $skiplock && $authuser ne 'root@pam';
1991
1992         my $keepActive = extract_param($param, 'keepActive');
1993         raise_param_exc({ keepActive => "Only root may use this option." })
1994             if $keepActive && $authuser ne 'root@pam';
1995
1996         my $migratedfrom = extract_param($param, 'migratedfrom');
1997         raise_param_exc({ migratedfrom => "Only root may use this option." })
1998             if $migratedfrom && $authuser ne 'root@pam';
1999
2000
2001         my $storecfg = PVE::Storage::config();
2002
2003         if (PVE::HA::Config::vm_is_ha_managed($vmid) && ($rpcenv->{type} ne 'ha') && !defined($migratedfrom)) {
2004
2005             my $hacmd = sub {
2006                 my $upid = shift;
2007
2008                 my $service = "vm:$vmid";
2009
2010                 my $cmd = ['ha-manager', 'set', $service, '--state', 'stopped'];
2011
2012                 print "Requesting HA stop for VM $vmid\n";
2013
2014                 PVE::Tools::run_command($cmd);
2015
2016                 return;
2017             };
2018
2019             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2020
2021         } else {
2022             my $realcmd = sub {
2023                 my $upid = shift;
2024
2025                 syslog('info', "stop VM $vmid: $upid\n");
2026
2027                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0,
2028                                          $param->{timeout}, 0, 1, $keepActive, $migratedfrom);
2029
2030                 return;
2031             };
2032
2033             return $rpcenv->fork_worker('qmstop', $vmid, $authuser, $realcmd);
2034         }
2035     }});
2036
2037 __PACKAGE__->register_method({
2038     name => 'vm_reset',
2039     path => '{vmid}/status/reset',
2040     method => 'POST',
2041     protected => 1,
2042     proxyto => 'node',
2043     description => "Reset virtual machine.",
2044     permissions => {
2045         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2046     },
2047     parameters => {
2048         additionalProperties => 0,
2049         properties => {
2050             node => get_standard_option('pve-node'),
2051             vmid => get_standard_option('pve-vmid',
2052                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2053             skiplock => get_standard_option('skiplock'),
2054         },
2055     },
2056     returns => {
2057         type => 'string',
2058     },
2059     code => sub {
2060         my ($param) = @_;
2061
2062         my $rpcenv = PVE::RPCEnvironment::get();
2063
2064         my $authuser = $rpcenv->get_user();
2065
2066         my $node = extract_param($param, 'node');
2067
2068         my $vmid = extract_param($param, 'vmid');
2069
2070         my $skiplock = extract_param($param, 'skiplock');
2071         raise_param_exc({ skiplock => "Only root may use this option." })
2072             if $skiplock && $authuser ne 'root@pam';
2073
2074         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2075
2076         my $realcmd = sub {
2077             my $upid = shift;
2078
2079             PVE::QemuServer::vm_reset($vmid, $skiplock);
2080
2081             return;
2082         };
2083
2084         return $rpcenv->fork_worker('qmreset', $vmid, $authuser, $realcmd);
2085     }});
2086
2087 __PACKAGE__->register_method({
2088     name => 'vm_shutdown',
2089     path => '{vmid}/status/shutdown',
2090     method => 'POST',
2091     protected => 1,
2092     proxyto => 'node',
2093     description => "Shutdown virtual machine. This is similar to pressing the power button on a physical machine." .
2094         "This will send an ACPI event for the guest OS, which should then proceed to a clean shutdown.",
2095     permissions => {
2096         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2097     },
2098     parameters => {
2099         additionalProperties => 0,
2100         properties => {
2101             node => get_standard_option('pve-node'),
2102             vmid => get_standard_option('pve-vmid',
2103                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2104             skiplock => get_standard_option('skiplock'),
2105             timeout => {
2106                 description => "Wait maximal timeout seconds.",
2107                 type => 'integer',
2108                 minimum => 0,
2109                 optional => 1,
2110             },
2111             forceStop => {
2112                 description => "Make sure the VM stops.",
2113                 type => 'boolean',
2114                 optional => 1,
2115                 default => 0,
2116             },
2117             keepActive => {
2118                 description => "Do not deactivate storage volumes.",
2119                 type => 'boolean',
2120                 optional => 1,
2121                 default => 0,
2122             }
2123         },
2124     },
2125     returns => {
2126         type => 'string',
2127     },
2128     code => sub {
2129         my ($param) = @_;
2130
2131         my $rpcenv = PVE::RPCEnvironment::get();
2132
2133         my $authuser = $rpcenv->get_user();
2134
2135         my $node = extract_param($param, 'node');
2136
2137         my $vmid = extract_param($param, 'vmid');
2138
2139         my $skiplock = extract_param($param, 'skiplock');
2140         raise_param_exc({ skiplock => "Only root may use this option." })
2141             if $skiplock && $authuser ne 'root@pam';
2142
2143         my $keepActive = extract_param($param, 'keepActive');
2144         raise_param_exc({ keepActive => "Only root may use this option." })
2145             if $keepActive && $authuser ne 'root@pam';
2146
2147         my $storecfg = PVE::Storage::config();
2148
2149         my $shutdown = 1;
2150
2151         # if vm is paused, do not shutdown (but stop if forceStop = 1)
2152         # otherwise, we will infer a shutdown command, but run into the timeout,
2153         # then when the vm is resumed, it will instantly shutdown
2154         #
2155         # checking the qmp status here to get feedback to the gui/cli/api
2156         # and the status query should not take too long
2157         my $qmpstatus;
2158         eval {
2159             $qmpstatus = PVE::QemuServer::vm_qmp_command($vmid, { execute => "query-status" }, 0);
2160         };
2161         my $err = $@ if $@;
2162
2163         if (!$err && $qmpstatus->{status} eq "paused") {
2164             if ($param->{forceStop}) {
2165                 warn "VM is paused - stop instead of shutdown\n";
2166                 $shutdown = 0;
2167             } else {
2168                 die "VM is paused - cannot shutdown\n";
2169             }
2170         }
2171
2172         if (PVE::HA::Config::vm_is_ha_managed($vmid) &&
2173             ($rpcenv->{type} ne 'ha')) {
2174
2175             my $hacmd = sub {
2176                 my $upid = shift;
2177
2178                 my $service = "vm:$vmid";
2179
2180                 my $cmd = ['ha-manager', 'set', $service, '--state', 'stopped'];
2181
2182                 print "Requesting HA stop for VM $vmid\n";
2183
2184                 PVE::Tools::run_command($cmd);
2185
2186                 return;
2187             };
2188
2189             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2190
2191         } else {
2192
2193             my $realcmd = sub {
2194                 my $upid = shift;
2195
2196                 syslog('info', "shutdown VM $vmid: $upid\n");
2197
2198                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0, $param->{timeout},
2199                                          $shutdown, $param->{forceStop}, $keepActive);
2200
2201                 return;
2202             };
2203
2204             return $rpcenv->fork_worker('qmshutdown', $vmid, $authuser, $realcmd);
2205         }
2206     }});
2207
2208 __PACKAGE__->register_method({
2209     name => 'vm_suspend',
2210     path => '{vmid}/status/suspend',
2211     method => 'POST',
2212     protected => 1,
2213     proxyto => 'node',
2214     description => "Suspend virtual machine.",
2215     permissions => {
2216         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2217     },
2218     parameters => {
2219         additionalProperties => 0,
2220         properties => {
2221             node => get_standard_option('pve-node'),
2222             vmid => get_standard_option('pve-vmid',
2223                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2224             skiplock => get_standard_option('skiplock'),
2225         },
2226     },
2227     returns => {
2228         type => 'string',
2229     },
2230     code => sub {
2231         my ($param) = @_;
2232
2233         my $rpcenv = PVE::RPCEnvironment::get();
2234
2235         my $authuser = $rpcenv->get_user();
2236
2237         my $node = extract_param($param, 'node');
2238
2239         my $vmid = extract_param($param, 'vmid');
2240
2241         my $skiplock = extract_param($param, 'skiplock');
2242         raise_param_exc({ skiplock => "Only root may use this option." })
2243             if $skiplock && $authuser ne 'root@pam';
2244
2245         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2246
2247         my $realcmd = sub {
2248             my $upid = shift;
2249
2250             syslog('info', "suspend VM $vmid: $upid\n");
2251
2252             PVE::QemuServer::vm_suspend($vmid, $skiplock);
2253
2254             return;
2255         };
2256
2257         return $rpcenv->fork_worker('qmsuspend', $vmid, $authuser, $realcmd);
2258     }});
2259
2260 __PACKAGE__->register_method({
2261     name => 'vm_resume',
2262     path => '{vmid}/status/resume',
2263     method => 'POST',
2264     protected => 1,
2265     proxyto => 'node',
2266     description => "Resume virtual machine.",
2267     permissions => {
2268         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2269     },
2270     parameters => {
2271         additionalProperties => 0,
2272         properties => {
2273             node => get_standard_option('pve-node'),
2274             vmid => get_standard_option('pve-vmid',
2275                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2276             skiplock => get_standard_option('skiplock'),
2277             nocheck => { type => 'boolean', optional => 1 },
2278
2279         },
2280     },
2281     returns => {
2282         type => 'string',
2283     },
2284     code => sub {
2285         my ($param) = @_;
2286
2287         my $rpcenv = PVE::RPCEnvironment::get();
2288
2289         my $authuser = $rpcenv->get_user();
2290
2291         my $node = extract_param($param, 'node');
2292
2293         my $vmid = extract_param($param, 'vmid');
2294
2295         my $skiplock = extract_param($param, 'skiplock');
2296         raise_param_exc({ skiplock => "Only root may use this option." })
2297             if $skiplock && $authuser ne 'root@pam';
2298
2299         my $nocheck = extract_param($param, 'nocheck');
2300
2301         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid, $nocheck);
2302
2303         my $realcmd = sub {
2304             my $upid = shift;
2305
2306             syslog('info', "resume VM $vmid: $upid\n");
2307
2308             PVE::QemuServer::vm_resume($vmid, $skiplock, $nocheck);
2309
2310             return;
2311         };
2312
2313         return $rpcenv->fork_worker('qmresume', $vmid, $authuser, $realcmd);
2314     }});
2315
2316 __PACKAGE__->register_method({
2317     name => 'vm_sendkey',
2318     path => '{vmid}/sendkey',
2319     method => 'PUT',
2320     protected => 1,
2321     proxyto => 'node',
2322     description => "Send key event to virtual machine.",
2323     permissions => {
2324         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2325     },
2326     parameters => {
2327         additionalProperties => 0,
2328         properties => {
2329             node => get_standard_option('pve-node'),
2330             vmid => get_standard_option('pve-vmid',
2331                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2332             skiplock => get_standard_option('skiplock'),
2333             key => {
2334                 description => "The key (qemu monitor encoding).",
2335                 type => 'string'
2336             }
2337         },
2338     },
2339     returns => { type => 'null'},
2340     code => sub {
2341         my ($param) = @_;
2342
2343         my $rpcenv = PVE::RPCEnvironment::get();
2344
2345         my $authuser = $rpcenv->get_user();
2346
2347         my $node = extract_param($param, 'node');
2348
2349         my $vmid = extract_param($param, 'vmid');
2350
2351         my $skiplock = extract_param($param, 'skiplock');
2352         raise_param_exc({ skiplock => "Only root may use this option." })
2353             if $skiplock && $authuser ne 'root@pam';
2354
2355         PVE::QemuServer::vm_sendkey($vmid, $skiplock, $param->{key});
2356
2357         return;
2358     }});
2359
2360 __PACKAGE__->register_method({
2361     name => 'vm_feature',
2362     path => '{vmid}/feature',
2363     method => 'GET',
2364     proxyto => 'node',
2365     protected => 1,
2366     description => "Check if feature for virtual machine is available.",
2367     permissions => {
2368         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2369     },
2370     parameters => {
2371         additionalProperties => 0,
2372         properties => {
2373             node => get_standard_option('pve-node'),
2374             vmid => get_standard_option('pve-vmid'),
2375             feature => {
2376                 description => "Feature to check.",
2377                 type => 'string',
2378                 enum => [ 'snapshot', 'clone', 'copy' ],
2379             },
2380             snapname => get_standard_option('pve-snapshot-name', {
2381                 optional => 1,
2382             }),
2383         },
2384     },
2385     returns => {
2386         type => "object",
2387         properties => {
2388             hasFeature => { type => 'boolean' },
2389             nodes => {
2390                 type => 'array',
2391                 items => { type => 'string' },
2392             }
2393         },
2394     },
2395     code => sub {
2396         my ($param) = @_;
2397
2398         my $node = extract_param($param, 'node');
2399
2400         my $vmid = extract_param($param, 'vmid');
2401
2402         my $snapname = extract_param($param, 'snapname');
2403
2404         my $feature = extract_param($param, 'feature');
2405
2406         my $running = PVE::QemuServer::check_running($vmid);
2407
2408         my $conf = PVE::QemuConfig->load_config($vmid);
2409
2410         if($snapname){
2411             my $snap = $conf->{snapshots}->{$snapname};
2412             die "snapshot '$snapname' does not exist\n" if !defined($snap);
2413             $conf = $snap;
2414         }
2415         my $storecfg = PVE::Storage::config();
2416
2417         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
2418         my $hasFeature = PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
2419
2420         return {
2421             hasFeature => $hasFeature,
2422             nodes => [ keys %$nodelist ],
2423         };
2424     }});
2425
2426 __PACKAGE__->register_method({
2427     name => 'clone_vm',
2428     path => '{vmid}/clone',
2429     method => 'POST',
2430     protected => 1,
2431     proxyto => 'node',
2432     description => "Create a copy of virtual machine/template.",
2433     permissions => {
2434         description => "You need 'VM.Clone' permissions on /vms/{vmid}, and 'VM.Allocate' permissions " .
2435             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
2436             "'Datastore.AllocateSpace' on any used storage.",
2437         check =>
2438         [ 'and',
2439           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
2440           [ 'or',
2441             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
2442             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
2443           ],
2444         ]
2445     },
2446     parameters => {
2447         additionalProperties => 0,
2448         properties => {
2449             node => get_standard_option('pve-node'),
2450             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2451             newid => get_standard_option('pve-vmid', { description => 'VMID for the clone.' }),
2452             name => {
2453                 optional => 1,
2454                 type => 'string', format => 'dns-name',
2455                 description => "Set a name for the new VM.",
2456             },
2457             description => {
2458                 optional => 1,
2459                 type => 'string',
2460                 description => "Description for the new VM.",
2461             },
2462             pool => {
2463                 optional => 1,
2464                 type => 'string', format => 'pve-poolid',
2465                 description => "Add the new VM to the specified pool.",
2466             },
2467             snapname => get_standard_option('pve-snapshot-name', {
2468                 optional => 1,
2469             }),
2470             storage => get_standard_option('pve-storage-id', {
2471                 description => "Target storage for full clone.",
2472                 requires => 'full',
2473                 optional => 1,
2474             }),
2475             'format' => {
2476                 description => "Target format for file storage.",
2477                 requires => 'full',
2478                 type => 'string',
2479                 optional => 1,
2480                 enum => [ 'raw', 'qcow2', 'vmdk'],
2481             },
2482             full => {
2483                 optional => 1,
2484                 type => 'boolean',
2485                 description => "Create a full copy of all disk. This is always done when " .
2486                     "you clone a normal VM. For VM templates, we try to create a linked clone by default.",
2487                 default => 0,
2488             },
2489             target => get_standard_option('pve-node', {
2490                 description => "Target node. Only allowed if the original VM is on shared storage.",
2491                 optional => 1,
2492             }),
2493         },
2494     },
2495     returns => {
2496         type => 'string',
2497     },
2498     code => sub {
2499         my ($param) = @_;
2500
2501         my $rpcenv = PVE::RPCEnvironment::get();
2502
2503         my $authuser = $rpcenv->get_user();
2504
2505         my $node = extract_param($param, 'node');
2506
2507         my $vmid = extract_param($param, 'vmid');
2508
2509         my $newid = extract_param($param, 'newid');
2510
2511         my $pool = extract_param($param, 'pool');
2512
2513         if (defined($pool)) {
2514             $rpcenv->check_pool_exist($pool);
2515         }
2516
2517         my $snapname = extract_param($param, 'snapname');
2518
2519         my $storage = extract_param($param, 'storage');
2520
2521         my $format = extract_param($param, 'format');
2522
2523         my $target = extract_param($param, 'target');
2524
2525         my $localnode = PVE::INotify::nodename();
2526
2527         undef $target if $target && ($target eq $localnode || $target eq 'localhost');
2528
2529         PVE::Cluster::check_node_exists($target) if $target;
2530
2531         my $storecfg = PVE::Storage::config();
2532
2533         if ($storage) {
2534             # check if storage is enabled on local node
2535             PVE::Storage::storage_check_enabled($storecfg, $storage);
2536             if ($target) {
2537                 # check if storage is available on target node
2538                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
2539                 # clone only works if target storage is shared
2540                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2541                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
2542             }
2543         }
2544
2545         PVE::Cluster::check_cfs_quorum();
2546
2547         my $running = PVE::QemuServer::check_running($vmid) || 0;
2548
2549         # exclusive lock if VM is running - else shared lock is enough;
2550         my $shared_lock = $running ? 0 : 1;
2551
2552         my $clonefn = sub {
2553
2554             # do all tests after lock
2555             # we also try to do all tests before we fork the worker
2556
2557             my $conf = PVE::QemuConfig->load_config($vmid);
2558
2559             PVE::QemuConfig->check_lock($conf);
2560
2561             my $verify_running = PVE::QemuServer::check_running($vmid) || 0;
2562
2563             die "unexpected state change\n" if $verify_running != $running;
2564
2565             die "snapshot '$snapname' does not exist\n"
2566                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
2567
2568             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
2569
2570             my $sharedvm = &$check_storage_access_clone($rpcenv, $authuser, $storecfg, $oldconf, $storage);
2571
2572             die "can't clone VM to node '$target' (VM uses local storage)\n" if $target && !$sharedvm;
2573
2574             my $conffile = PVE::QemuConfig->config_file($newid);
2575
2576             die "unable to create VM $newid: config file already exists\n"
2577                 if -f $conffile;
2578
2579             my $newconf = { lock => 'clone' };
2580             my $drives = {};
2581             my $fullclone = {};
2582             my $vollist = [];
2583
2584             foreach my $opt (keys %$oldconf) {
2585                 my $value = $oldconf->{$opt};
2586
2587                 # do not copy snapshot related info
2588                 next if $opt eq 'snapshots' ||  $opt eq 'parent' || $opt eq 'snaptime' ||
2589                     $opt eq 'vmstate' || $opt eq 'snapstate';
2590
2591                 # no need to copy unused images, because VMID(owner) changes anyways
2592                 next if $opt =~ m/^unused\d+$/;
2593
2594                 # always change MAC! address
2595                 if ($opt =~ m/^net(\d+)$/) {
2596                     my $net = PVE::QemuServer::parse_net($value);
2597                     my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
2598                     $net->{macaddr} =  PVE::Tools::random_ether_addr($dc->{mac_prefix});
2599                     $newconf->{$opt} = PVE::QemuServer::print_net($net);
2600                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
2601                     my $drive = PVE::QemuServer::parse_drive($opt, $value);
2602                     die "unable to parse drive options for '$opt'\n" if !$drive;
2603                     if (PVE::QemuServer::drive_is_cdrom($drive)) {
2604                         $newconf->{$opt} = $value; # simply copy configuration
2605                     } else {
2606                         if ($param->{full}) {
2607                             die "Full clone feature is not supported for drive '$opt'\n"
2608                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $drive->{file}, $snapname, $running);
2609                             $fullclone->{$opt} = 1;
2610                         } else {
2611                             # not full means clone instead of copy
2612                             die "Linked clone feature is not supported for drive '$opt'\n"
2613                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $drive->{file}, $snapname, $running);
2614                         }
2615                         $drives->{$opt} = $drive;
2616                         push @$vollist, $drive->{file};
2617                     }
2618                 } else {
2619                     # copy everything else
2620                     $newconf->{$opt} = $value;
2621                 }
2622             }
2623
2624             # auto generate a new uuid
2625             my ($uuid, $uuid_str);
2626             UUID::generate($uuid);
2627             UUID::unparse($uuid, $uuid_str);
2628             my $smbios1 = PVE::QemuServer::parse_smbios1($newconf->{smbios1} || '');
2629             $smbios1->{uuid} = $uuid_str;
2630             $newconf->{smbios1} = PVE::QemuServer::print_smbios1($smbios1);
2631
2632             delete $newconf->{template};
2633
2634             if ($param->{name}) {
2635                 $newconf->{name} = $param->{name};
2636             } else {
2637                 if ($oldconf->{name}) {
2638                     $newconf->{name} = "Copy-of-$oldconf->{name}";
2639                 } else {
2640                     $newconf->{name} = "Copy-of-VM-$vmid";
2641                 }
2642             }
2643
2644             if ($param->{description}) {
2645                 $newconf->{description} = $param->{description};
2646             }
2647
2648             # create empty/temp config - this fails if VM already exists on other node
2649             PVE::Tools::file_set_contents($conffile, "# qmclone temporary file\nlock: clone\n");
2650
2651             my $realcmd = sub {
2652                 my $upid = shift;
2653
2654                 my $newvollist = [];
2655                 my $jobs = {};
2656
2657                 eval {
2658                     local $SIG{INT} =
2659                         local $SIG{TERM} =
2660                         local $SIG{QUIT} =
2661                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
2662
2663                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
2664
2665                     my $total_jobs = scalar(keys %{$drives});
2666                     my $i = 1;
2667
2668                     foreach my $opt (keys %$drives) {
2669                         my $drive = $drives->{$opt};
2670                         my $skipcomplete = ($total_jobs != $i); # finish after last drive
2671
2672                         my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $opt, $drive, $snapname,
2673                                                                    $newid, $storage, $format, $fullclone->{$opt}, $newvollist,
2674                                                                    $jobs, $skipcomplete, $oldconf->{agent});
2675
2676                         $newconf->{$opt} = PVE::QemuServer::print_drive($vmid, $newdrive);
2677
2678                         PVE::QemuConfig->write_config($newid, $newconf);
2679                         $i++;
2680                     }
2681
2682                     delete $newconf->{lock};
2683                     PVE::QemuConfig->write_config($newid, $newconf);
2684
2685                     if ($target) {
2686                         # always deactivate volumes - avoid lvm LVs to be active on several nodes
2687                         PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
2688                         PVE::Storage::deactivate_volumes($storecfg, $newvollist);
2689
2690                         my $newconffile = PVE::QemuConfig->config_file($newid, $target);
2691                         die "Failed to move config to node '$target' - rename failed: $!\n"
2692                             if !rename($conffile, $newconffile);
2693                     }
2694
2695                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
2696                 };
2697                 if (my $err = $@) {
2698                     unlink $conffile;
2699
2700                     eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $jobs) };
2701
2702                     sleep 1; # some storage like rbd need to wait before release volume - really?
2703
2704                     foreach my $volid (@$newvollist) {
2705                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2706                         warn $@ if $@;
2707                     }
2708                     die "clone failed: $err";
2709                 }
2710
2711                 return;
2712             };
2713
2714             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
2715
2716             return $rpcenv->fork_worker('qmclone', $vmid, $authuser, $realcmd);
2717         };
2718
2719         return PVE::QemuConfig->lock_config_mode($vmid, 1, $shared_lock, sub {
2720             # Aquire exclusive lock lock for $newid
2721             return PVE::QemuConfig->lock_config_full($newid, 1, $clonefn);
2722         });
2723
2724     }});
2725
2726 __PACKAGE__->register_method({
2727     name => 'move_vm_disk',
2728     path => '{vmid}/move_disk',
2729     method => 'POST',
2730     protected => 1,
2731     proxyto => 'node',
2732     description => "Move volume to different storage.",
2733     permissions => {
2734         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, and 'Datastore.AllocateSpace' permissions on the storage.",
2735         check => [ 'and',
2736                    ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
2737                    ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
2738             ],
2739     },
2740     parameters => {
2741         additionalProperties => 0,
2742         properties => {
2743             node => get_standard_option('pve-node'),
2744             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2745             disk => {
2746                 type => 'string',
2747                 description => "The disk you want to move.",
2748                 enum => [ PVE::QemuServer::valid_drive_names() ],
2749             },
2750             storage => get_standard_option('pve-storage-id', {
2751                 description => "Target storage.",
2752                 completion => \&PVE::QemuServer::complete_storage,
2753             }),
2754             'format' => {
2755                 type => 'string',
2756                 description => "Target Format.",
2757                 enum => [ 'raw', 'qcow2', 'vmdk' ],
2758                 optional => 1,
2759             },
2760             delete => {
2761                 type => 'boolean',
2762                 description => "Delete the original disk after successful copy. By default the original disk is kept as unused disk.",
2763                 optional => 1,
2764                 default => 0,
2765             },
2766             digest => {
2767                 type => 'string',
2768                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
2769                 maxLength => 40,
2770                 optional => 1,
2771             },
2772         },
2773     },
2774     returns => {
2775         type => 'string',
2776         description => "the task ID.",
2777     },
2778     code => sub {
2779         my ($param) = @_;
2780
2781         my $rpcenv = PVE::RPCEnvironment::get();
2782
2783         my $authuser = $rpcenv->get_user();
2784
2785         my $node = extract_param($param, 'node');
2786
2787         my $vmid = extract_param($param, 'vmid');
2788
2789         my $digest = extract_param($param, 'digest');
2790
2791         my $disk = extract_param($param, 'disk');
2792
2793         my $storeid = extract_param($param, 'storage');
2794
2795         my $format = extract_param($param, 'format');
2796
2797         my $storecfg = PVE::Storage::config();
2798
2799         my $updatefn =  sub {
2800
2801             my $conf = PVE::QemuConfig->load_config($vmid);
2802
2803             PVE::QemuConfig->check_lock($conf);
2804
2805             die "checksum missmatch (file change by other user?)\n"
2806                 if $digest && $digest ne $conf->{digest};
2807
2808             die "disk '$disk' does not exist\n" if !$conf->{$disk};
2809
2810             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
2811
2812             my $old_volid = $drive->{file} || die "disk '$disk' has no associated volume\n";
2813
2814             die "you can't move a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
2815
2816             my $oldfmt;
2817             my ($oldstoreid, $oldvolname) = PVE::Storage::parse_volume_id($old_volid);
2818             if ($oldvolname =~ m/\.(raw|qcow2|vmdk)$/){
2819                 $oldfmt = $1;
2820             }
2821
2822             die "you can't move on the same storage with same format\n" if $oldstoreid eq $storeid &&
2823                 (!$format || !$oldfmt || $oldfmt eq $format);
2824
2825             # this only checks snapshots because $disk is passed!
2826             my $snapshotted = PVE::QemuServer::is_volume_in_use($storecfg, $conf, $disk, $old_volid);
2827             die "you can't move a disk with snapshots and delete the source\n"
2828                 if $snapshotted && $param->{delete};
2829
2830             PVE::Cluster::log_msg('info', $authuser, "move disk VM $vmid: move --disk $disk --storage $storeid");
2831
2832             my $running = PVE::QemuServer::check_running($vmid);
2833
2834             PVE::Storage::activate_volumes($storecfg, [ $drive->{file} ]);
2835
2836             my $realcmd = sub {
2837
2838                 my $newvollist = [];
2839
2840                 eval {
2841                     local $SIG{INT} =
2842                         local $SIG{TERM} =
2843                         local $SIG{QUIT} =
2844                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
2845
2846                     warn "moving disk with snapshots, snapshots will not be moved!\n"
2847                         if $snapshotted;
2848
2849                     my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $disk, $drive, undef,
2850                                                                $vmid, $storeid, $format, 1, $newvollist);
2851
2852                     $conf->{$disk} = PVE::QemuServer::print_drive($vmid, $newdrive);
2853
2854                     PVE::QemuConfig->add_unused_volume($conf, $old_volid) if !$param->{delete};
2855
2856                     # convert moved disk to base if part of template
2857                     PVE::QemuServer::template_create($vmid, $conf, $disk)
2858                         if PVE::QemuConfig->is_template($conf);
2859
2860                     PVE::QemuConfig->write_config($vmid, $conf);
2861
2862                     eval {
2863                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
2864                         PVE::Storage::deactivate_volumes($storecfg, [ $newdrive->{file} ])
2865                             if !$running;
2866                     };
2867                     warn $@ if $@;
2868                 };
2869                 if (my $err = $@) {
2870
2871                    foreach my $volid (@$newvollist) {
2872                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2873                         warn $@ if $@;
2874                     }
2875                     die "storage migration failed: $err";
2876                 }
2877
2878                 if ($param->{delete}) {
2879                     eval {
2880                         PVE::Storage::deactivate_volumes($storecfg, [$old_volid]);
2881                         PVE::Storage::vdisk_free($storecfg, $old_volid);
2882                     };
2883                     warn $@ if $@;
2884                 }
2885             };
2886
2887             return $rpcenv->fork_worker('qmmove', $vmid, $authuser, $realcmd);
2888         };
2889
2890         return PVE::QemuConfig->lock_config($vmid, $updatefn);
2891     }});
2892
2893 __PACKAGE__->register_method({
2894     name => 'migrate_vm',
2895     path => '{vmid}/migrate',
2896     method => 'POST',
2897     protected => 1,
2898     proxyto => 'node',
2899     description => "Migrate virtual machine. Creates a new migration task.",
2900     permissions => {
2901         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
2902     },
2903     parameters => {
2904         additionalProperties => 0,
2905         properties => {
2906             node => get_standard_option('pve-node'),
2907             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2908             target => get_standard_option('pve-node', {
2909                 description => "Target node.",
2910                 completion =>  \&PVE::Cluster::complete_migration_target,
2911             }),
2912             online => {
2913                 type => 'boolean',
2914                 description => "Use online/live migration.",
2915                 optional => 1,
2916             },
2917             force => {
2918                 type => 'boolean',
2919                 description => "Allow to migrate VMs which use local devices. Only root may use this option.",
2920                 optional => 1,
2921             },
2922             migration_type => {
2923                 type => 'string',
2924                 enum => ['secure', 'insecure'],
2925                 description => "Migration traffic is encrypted using an SSH tunnel by default. On secure, completely private networks this can be disabled to increase performance.",
2926                 optional => 1,
2927             },
2928             migration_network => {
2929                 type => 'string', format => 'CIDR',
2930                 description => "CIDR of the (sub) network that is used for migration.",
2931                 optional => 1,
2932             },
2933             "with-local-disks" => {
2934                 type => 'boolean',
2935                 description => "Enable live storage migration for local disk",
2936                 optional => 1,
2937             },
2938             targetstorage => get_standard_option('pve-storage-id', {
2939                 description => "Default target storage.",
2940                 optional => 1,
2941                 completion => \&PVE::QemuServer::complete_storage,
2942             }),
2943         },
2944     },
2945     returns => {
2946         type => 'string',
2947         description => "the task ID.",
2948     },
2949     code => sub {
2950         my ($param) = @_;
2951
2952         my $rpcenv = PVE::RPCEnvironment::get();
2953
2954         my $authuser = $rpcenv->get_user();
2955
2956         my $target = extract_param($param, 'target');
2957
2958         my $localnode = PVE::INotify::nodename();
2959         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
2960
2961         PVE::Cluster::check_cfs_quorum();
2962
2963         PVE::Cluster::check_node_exists($target);
2964
2965         my $targetip = PVE::Cluster::remote_node_ip($target);
2966
2967         my $vmid = extract_param($param, 'vmid');
2968
2969         raise_param_exc({ targetstorage => "Live storage migration can only be done online." })
2970             if !$param->{online} && $param->{targetstorage};
2971
2972         raise_param_exc({ force => "Only root may use this option." })
2973             if $param->{force} && $authuser ne 'root@pam';
2974
2975         raise_param_exc({ migration_type => "Only root may use this option." })
2976             if $param->{migration_type} && $authuser ne 'root@pam';
2977
2978         # allow root only until better network permissions are available
2979         raise_param_exc({ migration_network => "Only root may use this option." })
2980             if $param->{migration_network} && $authuser ne 'root@pam';
2981
2982         # test if VM exists
2983         my $conf = PVE::QemuConfig->load_config($vmid);
2984
2985         # try to detect errors early
2986
2987         PVE::QemuConfig->check_lock($conf);
2988
2989         if (PVE::QemuServer::check_running($vmid)) {
2990             die "cant migrate running VM without --online\n"
2991                 if !$param->{online};
2992         }
2993
2994         my $storecfg = PVE::Storage::config();
2995
2996         if( $param->{targetstorage}) {
2997             PVE::Storage::storage_check_node($storecfg, $param->{targetstorage}, $target);
2998         } else {
2999             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target);
3000         }
3001
3002         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
3003
3004             my $hacmd = sub {
3005                 my $upid = shift;
3006
3007                 my $service = "vm:$vmid";
3008
3009                 my $cmd = ['ha-manager', 'migrate', $service, $target];
3010
3011                 print "Requesting HA migration for VM $vmid to node $target\n";
3012
3013                 PVE::Tools::run_command($cmd);
3014
3015                 return;
3016             };
3017
3018             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
3019
3020         } else {
3021
3022             my $realcmd = sub {
3023                 PVE::QemuMigrate->migrate($target, $targetip, $vmid, $param);
3024             };
3025
3026             my $worker = sub {
3027                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3028             };
3029
3030             return $rpcenv->fork_worker('qmigrate', $vmid, $authuser, $worker);
3031         }
3032
3033     }});
3034
3035 __PACKAGE__->register_method({
3036     name => 'monitor',
3037     path => '{vmid}/monitor',
3038     method => 'POST',
3039     protected => 1,
3040     proxyto => 'node',
3041     description => "Execute Qemu monitor commands.",
3042     permissions => {
3043         description => "Sys.Modify is required for (sub)commands which are not read-only ('info *' and 'help')",
3044         check => ['perm', '/vms/{vmid}', [ 'VM.Monitor' ]],
3045     },
3046     parameters => {
3047         additionalProperties => 0,
3048         properties => {
3049             node => get_standard_option('pve-node'),
3050             vmid => get_standard_option('pve-vmid'),
3051             command => {
3052                 type => 'string',
3053                 description => "The monitor command.",
3054             }
3055         },
3056     },
3057     returns => { type => 'string'},
3058     code => sub {
3059         my ($param) = @_;
3060
3061         my $rpcenv = PVE::RPCEnvironment::get();
3062         my $authuser = $rpcenv->get_user();
3063
3064         my $is_ro = sub {
3065             my $command = shift;
3066             return $command =~ m/^\s*info(\s+|$)/
3067                 || $command =~ m/^\s*help\s*$/;
3068         };
3069
3070         $rpcenv->check_full($authuser, "/", ['Sys.Modify'])
3071             if !&$is_ro($param->{command});
3072
3073         my $vmid = $param->{vmid};
3074
3075         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
3076
3077         my $res = '';
3078         eval {
3079             $res = PVE::QemuServer::vm_human_monitor_command($vmid, $param->{command});
3080         };
3081         $res = "ERROR: $@" if $@;
3082
3083         return $res;
3084     }});
3085
3086 __PACKAGE__->register_method({
3087     name => 'resize_vm',
3088     path => '{vmid}/resize',
3089     method => 'PUT',
3090     protected => 1,
3091     proxyto => 'node',
3092     description => "Extend volume size.",
3093     permissions => {
3094         check => ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3095     },
3096     parameters => {
3097         additionalProperties => 0,
3098         properties => {
3099             node => get_standard_option('pve-node'),
3100             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3101             skiplock => get_standard_option('skiplock'),
3102             disk => {
3103                 type => 'string',
3104                 description => "The disk you want to resize.",
3105                 enum => [PVE::QemuServer::valid_drive_names()],
3106             },
3107             size => {
3108                 type => 'string',
3109                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
3110                 description => "The new size. With the `+` sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
3111             },
3112             digest => {
3113                 type => 'string',
3114                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3115                 maxLength => 40,
3116                 optional => 1,
3117             },
3118         },
3119     },
3120     returns => { type => 'null'},
3121     code => sub {
3122         my ($param) = @_;
3123
3124         my $rpcenv = PVE::RPCEnvironment::get();
3125
3126         my $authuser = $rpcenv->get_user();
3127
3128         my $node = extract_param($param, 'node');
3129
3130         my $vmid = extract_param($param, 'vmid');
3131
3132         my $digest = extract_param($param, 'digest');
3133
3134         my $disk = extract_param($param, 'disk');
3135
3136         my $sizestr = extract_param($param, 'size');
3137
3138         my $skiplock = extract_param($param, 'skiplock');
3139         raise_param_exc({ skiplock => "Only root may use this option." })
3140             if $skiplock && $authuser ne 'root@pam';
3141
3142         my $storecfg = PVE::Storage::config();
3143
3144         my $updatefn =  sub {
3145
3146             my $conf = PVE::QemuConfig->load_config($vmid);
3147
3148             die "checksum missmatch (file change by other user?)\n"
3149                 if $digest && $digest ne $conf->{digest};
3150             PVE::QemuConfig->check_lock($conf) if !$skiplock;
3151
3152             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3153
3154             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3155
3156             my (undef, undef, undef, undef, undef, undef, $format) =
3157                 PVE::Storage::parse_volname($storecfg, $drive->{file});
3158
3159             die "can't resize volume: $disk if snapshot exists\n"
3160                 if %{$conf->{snapshots}} && $format eq 'qcow2';
3161
3162             my $volid = $drive->{file};
3163
3164             die "disk '$disk' has no associated volume\n" if !$volid;
3165
3166             die "you can't resize a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
3167
3168             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
3169
3170             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
3171
3172             PVE::Storage::activate_volumes($storecfg, [$volid]);
3173             my $size = PVE::Storage::volume_size_info($storecfg, $volid, 5);
3174
3175             die "internal error" if $sizestr !~ m/^(\+)?(\d+(\.\d+)?)([KMGT])?$/;
3176             my ($ext, $newsize, $unit) = ($1, $2, $4);
3177             if ($unit) {
3178                 if ($unit eq 'K') {
3179                     $newsize = $newsize * 1024;
3180                 } elsif ($unit eq 'M') {
3181                     $newsize = $newsize * 1024 * 1024;
3182                 } elsif ($unit eq 'G') {
3183                     $newsize = $newsize * 1024 * 1024 * 1024;
3184                 } elsif ($unit eq 'T') {
3185                     $newsize = $newsize * 1024 * 1024 * 1024 * 1024;
3186                 }
3187             }
3188             $newsize += $size if $ext;
3189             $newsize = int($newsize);
3190
3191             die "shrinking disks is not supported\n" if $newsize < $size;
3192
3193             return if $size == $newsize;
3194
3195             PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: resize --disk $disk --size $sizestr");
3196
3197             PVE::QemuServer::qemu_block_resize($vmid, "drive-$disk", $storecfg, $volid, $newsize);
3198
3199             $drive->{size} = $newsize;
3200             $conf->{$disk} = PVE::QemuServer::print_drive($vmid, $drive);
3201
3202             PVE::QemuConfig->write_config($vmid, $conf);
3203         };
3204
3205         PVE::QemuConfig->lock_config($vmid, $updatefn);
3206         return undef;
3207     }});
3208
3209 __PACKAGE__->register_method({
3210     name => 'snapshot_list',
3211     path => '{vmid}/snapshot',
3212     method => 'GET',
3213     description => "List all snapshots.",
3214     permissions => {
3215         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
3216     },
3217     proxyto => 'node',
3218     protected => 1, # qemu pid files are only readable by root
3219     parameters => {
3220         additionalProperties => 0,
3221         properties => {
3222             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3223             node => get_standard_option('pve-node'),
3224         },
3225     },
3226     returns => {
3227         type => 'array',
3228         items => {
3229             type => "object",
3230             properties => {},
3231         },
3232         links => [ { rel => 'child', href => "{name}" } ],
3233     },
3234     code => sub {
3235         my ($param) = @_;
3236
3237         my $vmid = $param->{vmid};
3238
3239         my $conf = PVE::QemuConfig->load_config($vmid);
3240         my $snaphash = $conf->{snapshots} || {};
3241
3242         my $res = [];
3243
3244         foreach my $name (keys %$snaphash) {
3245             my $d = $snaphash->{$name};
3246             my $item = {
3247                 name => $name,
3248                 snaptime => $d->{snaptime} || 0,
3249                 vmstate => $d->{vmstate} ? 1 : 0,
3250                 description => $d->{description} || '',
3251             };
3252             $item->{parent} = $d->{parent} if $d->{parent};
3253             $item->{snapstate} = $d->{snapstate} if $d->{snapstate};
3254             push @$res, $item;
3255         }
3256
3257         my $running = PVE::QemuServer::check_running($vmid, 1) ? 1 : 0;
3258         my $current = { name => 'current', digest => $conf->{digest}, running => $running };
3259         $current->{parent} = $conf->{parent} if $conf->{parent};
3260
3261         push @$res, $current;
3262
3263         return $res;
3264     }});
3265
3266 __PACKAGE__->register_method({
3267     name => 'snapshot',
3268     path => '{vmid}/snapshot',
3269     method => 'POST',
3270     protected => 1,
3271     proxyto => 'node',
3272     description => "Snapshot a VM.",
3273     permissions => {
3274         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3275     },
3276     parameters => {
3277         additionalProperties => 0,
3278         properties => {
3279             node => get_standard_option('pve-node'),
3280             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3281             snapname => get_standard_option('pve-snapshot-name'),
3282             vmstate => {
3283                 optional => 1,
3284                 type => 'boolean',
3285                 description => "Save the vmstate",
3286             },
3287             description => {
3288                 optional => 1,
3289                 type => 'string',
3290                 description => "A textual description or comment.",
3291             },
3292         },
3293     },
3294     returns => {
3295         type => 'string',
3296         description => "the task ID.",
3297     },
3298     code => sub {
3299         my ($param) = @_;
3300
3301         my $rpcenv = PVE::RPCEnvironment::get();
3302
3303         my $authuser = $rpcenv->get_user();
3304
3305         my $node = extract_param($param, 'node');
3306
3307         my $vmid = extract_param($param, 'vmid');
3308
3309         my $snapname = extract_param($param, 'snapname');
3310
3311         die "unable to use snapshot name 'current' (reserved name)\n"
3312             if $snapname eq 'current';
3313
3314         my $realcmd = sub {
3315             PVE::Cluster::log_msg('info', $authuser, "snapshot VM $vmid: $snapname");
3316             PVE::QemuConfig->snapshot_create($vmid, $snapname, $param->{vmstate},
3317                                              $param->{description});
3318         };
3319
3320         return $rpcenv->fork_worker('qmsnapshot', $vmid, $authuser, $realcmd);
3321     }});
3322
3323 __PACKAGE__->register_method({
3324     name => 'snapshot_cmd_idx',
3325     path => '{vmid}/snapshot/{snapname}',
3326     description => '',
3327     method => 'GET',
3328     permissions => {
3329         user => 'all',
3330     },
3331     parameters => {
3332         additionalProperties => 0,
3333         properties => {
3334             vmid => get_standard_option('pve-vmid'),
3335             node => get_standard_option('pve-node'),
3336             snapname => get_standard_option('pve-snapshot-name'),
3337         },
3338     },
3339     returns => {
3340         type => 'array',
3341         items => {
3342             type => "object",
3343             properties => {},
3344         },
3345         links => [ { rel => 'child', href => "{cmd}" } ],
3346     },
3347     code => sub {
3348         my ($param) = @_;
3349
3350         my $res = [];
3351
3352         push @$res, { cmd => 'rollback' };
3353         push @$res, { cmd => 'config' };
3354
3355         return $res;
3356     }});
3357
3358 __PACKAGE__->register_method({
3359     name => 'update_snapshot_config',
3360     path => '{vmid}/snapshot/{snapname}/config',
3361     method => 'PUT',
3362     protected => 1,
3363     proxyto => 'node',
3364     description => "Update snapshot metadata.",
3365     permissions => {
3366         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3367     },
3368     parameters => {
3369         additionalProperties => 0,
3370         properties => {
3371             node => get_standard_option('pve-node'),
3372             vmid => get_standard_option('pve-vmid'),
3373             snapname => get_standard_option('pve-snapshot-name'),
3374             description => {
3375                 optional => 1,
3376                 type => 'string',
3377                 description => "A textual description or comment.",
3378             },
3379         },
3380     },
3381     returns => { type => 'null' },
3382     code => sub {
3383         my ($param) = @_;
3384
3385         my $rpcenv = PVE::RPCEnvironment::get();
3386
3387         my $authuser = $rpcenv->get_user();
3388
3389         my $vmid = extract_param($param, 'vmid');
3390
3391         my $snapname = extract_param($param, 'snapname');
3392
3393         return undef if !defined($param->{description});
3394
3395         my $updatefn =  sub {
3396
3397             my $conf = PVE::QemuConfig->load_config($vmid);
3398
3399             PVE::QemuConfig->check_lock($conf);
3400
3401             my $snap = $conf->{snapshots}->{$snapname};
3402
3403             die "snapshot '$snapname' does not exist\n" if !defined($snap);
3404
3405             $snap->{description} = $param->{description} if defined($param->{description});
3406
3407              PVE::QemuConfig->write_config($vmid, $conf);
3408         };
3409
3410         PVE::QemuConfig->lock_config($vmid, $updatefn);
3411
3412         return undef;
3413     }});
3414
3415 __PACKAGE__->register_method({
3416     name => 'get_snapshot_config',
3417     path => '{vmid}/snapshot/{snapname}/config',
3418     method => 'GET',
3419     proxyto => 'node',
3420     description => "Get snapshot configuration",
3421     permissions => {
3422         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3423     },
3424     parameters => {
3425         additionalProperties => 0,
3426         properties => {
3427             node => get_standard_option('pve-node'),
3428             vmid => get_standard_option('pve-vmid'),
3429             snapname => get_standard_option('pve-snapshot-name'),
3430         },
3431     },
3432     returns => { type => "object" },
3433     code => sub {
3434         my ($param) = @_;
3435
3436         my $rpcenv = PVE::RPCEnvironment::get();
3437
3438         my $authuser = $rpcenv->get_user();
3439
3440         my $vmid = extract_param($param, 'vmid');
3441
3442         my $snapname = extract_param($param, 'snapname');
3443
3444         my $conf = PVE::QemuConfig->load_config($vmid);
3445
3446         my $snap = $conf->{snapshots}->{$snapname};
3447
3448         die "snapshot '$snapname' does not exist\n" if !defined($snap);
3449
3450         return $snap;
3451     }});
3452
3453 __PACKAGE__->register_method({
3454     name => 'rollback',
3455     path => '{vmid}/snapshot/{snapname}/rollback',
3456     method => 'POST',
3457     protected => 1,
3458     proxyto => 'node',
3459     description => "Rollback VM state to specified snapshot.",
3460     permissions => {
3461         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3462     },
3463     parameters => {
3464         additionalProperties => 0,
3465         properties => {
3466             node => get_standard_option('pve-node'),
3467             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3468             snapname => get_standard_option('pve-snapshot-name'),
3469         },
3470     },
3471     returns => {
3472         type => 'string',
3473         description => "the task ID.",
3474     },
3475     code => sub {
3476         my ($param) = @_;
3477
3478         my $rpcenv = PVE::RPCEnvironment::get();
3479
3480         my $authuser = $rpcenv->get_user();
3481
3482         my $node = extract_param($param, 'node');
3483
3484         my $vmid = extract_param($param, 'vmid');
3485
3486         my $snapname = extract_param($param, 'snapname');
3487
3488         my $realcmd = sub {
3489             PVE::Cluster::log_msg('info', $authuser, "rollback snapshot VM $vmid: $snapname");
3490             PVE::QemuConfig->snapshot_rollback($vmid, $snapname);
3491         };
3492
3493         my $worker = sub {
3494             # hold migration lock, this makes sure that nobody create replication snapshots
3495             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3496         };
3497
3498         return $rpcenv->fork_worker('qmrollback', $vmid, $authuser, $worker);
3499     }});
3500
3501 __PACKAGE__->register_method({
3502     name => 'delsnapshot',
3503     path => '{vmid}/snapshot/{snapname}',
3504     method => 'DELETE',
3505     protected => 1,
3506     proxyto => 'node',
3507     description => "Delete a VM snapshot.",
3508     permissions => {
3509         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3510     },
3511     parameters => {
3512         additionalProperties => 0,
3513         properties => {
3514             node => get_standard_option('pve-node'),
3515             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3516             snapname => get_standard_option('pve-snapshot-name'),
3517             force => {
3518                 optional => 1,
3519                 type => 'boolean',
3520                 description => "For removal from config file, even if removing disk snapshots fails.",
3521             },
3522         },
3523     },
3524     returns => {
3525         type => 'string',
3526         description => "the task ID.",
3527     },
3528     code => sub {
3529         my ($param) = @_;
3530
3531         my $rpcenv = PVE::RPCEnvironment::get();
3532
3533         my $authuser = $rpcenv->get_user();
3534
3535         my $node = extract_param($param, 'node');
3536
3537         my $vmid = extract_param($param, 'vmid');
3538
3539         my $snapname = extract_param($param, 'snapname');
3540
3541         my $realcmd = sub {
3542             PVE::Cluster::log_msg('info', $authuser, "delete snapshot VM $vmid: $snapname");
3543             PVE::QemuConfig->snapshot_delete($vmid, $snapname, $param->{force});
3544         };
3545
3546         return $rpcenv->fork_worker('qmdelsnapshot', $vmid, $authuser, $realcmd);
3547     }});
3548
3549 __PACKAGE__->register_method({
3550     name => 'template',
3551     path => '{vmid}/template',
3552     method => 'POST',
3553     protected => 1,
3554     proxyto => 'node',
3555     description => "Create a Template.",
3556     permissions => {
3557         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
3558         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
3559     },
3560     parameters => {
3561         additionalProperties => 0,
3562         properties => {
3563             node => get_standard_option('pve-node'),
3564             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
3565             disk => {
3566                 optional => 1,
3567                 type => 'string',
3568                 description => "If you want to convert only 1 disk to base image.",
3569                 enum => [PVE::QemuServer::valid_drive_names()],
3570             },
3571
3572         },
3573     },
3574     returns => { type => 'null'},
3575     code => sub {
3576         my ($param) = @_;
3577
3578         my $rpcenv = PVE::RPCEnvironment::get();
3579
3580         my $authuser = $rpcenv->get_user();
3581
3582         my $node = extract_param($param, 'node');
3583
3584         my $vmid = extract_param($param, 'vmid');
3585
3586         my $disk = extract_param($param, 'disk');
3587
3588         my $updatefn =  sub {
3589
3590             my $conf = PVE::QemuConfig->load_config($vmid);
3591
3592             PVE::QemuConfig->check_lock($conf);
3593
3594             die "unable to create template, because VM contains snapshots\n"
3595                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
3596
3597             die "you can't convert a template to a template\n"
3598                 if PVE::QemuConfig->is_template($conf) && !$disk;
3599
3600             die "you can't convert a VM to template if VM is running\n"
3601                 if PVE::QemuServer::check_running($vmid);
3602
3603             my $realcmd = sub {
3604                 PVE::QemuServer::template_create($vmid, $conf, $disk);
3605             };
3606
3607             $conf->{template} = 1;
3608             PVE::QemuConfig->write_config($vmid, $conf);
3609
3610             return $rpcenv->fork_worker('qmtemplate', $vmid, $authuser, $realcmd);
3611         };
3612
3613         PVE::QemuConfig->lock_config($vmid, $updatefn);
3614         return undef;
3615     }});
3616
3617 1;