PVE/CLI/qm.pm

   1 package PVE::CLI::qm;
   2
   3 use strict;
   4 use warnings;
   5
   6 # Note: disable '+' prefix for Getopt::Long (for resize command)
   7 use Getopt::Long qw(:config no_getopt_compat);
   8
   9 use Fcntl ':flock';
  10 use File::Path;
  11 use IO::Select;
  12 use IO::Socket::UNIX;
  13 use JSON;
  14 use POSIX qw(strftime);
  15 use Term::ReadLine;
  16 use URI::Escape;
  17
  18 use PVE::Cluster;
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::GuestHelpers;
  21 use PVE::INotify;
  22 use PVE::JSONSchema qw(get_standard_option);
  23 use PVE::Network;
  24 use PVE::RPCEnvironment;
  25 use PVE::SafeSyslog;
  26 use PVE::Tools qw(extract_param);
  27
  28 use PVE::API2::Qemu::Agent;
  29 use PVE::API2::Qemu;
  30 use PVE::QemuConfig;
  31 use PVE::QemuServer::Drive;
  32 use PVE::QemuServer::Helpers;
  33 use PVE::QemuServer::Agent qw(agent_available);
  34 use PVE::QemuServer::ImportDisk;
  35 use PVE::QemuServer::Monitor qw(mon_cmd);
  36 use PVE::QemuServer::OVF;
  37 use PVE::QemuServer;
  38
  39 use PVE::CLIHandler;
  40 use base qw(PVE::CLIHandler);
  41
  42 my $upid_exit = sub {
  43     my $upid = shift;
  44     my $status = PVE::Tools::upid_read_status($upid);
  45     exit($status eq 'OK' ? 0 : -1);
  46 };
  47
  48 my $nodename = PVE::INotify::nodename();
  49
  50 sub setup_environment {
  51     PVE::RPCEnvironment->setup_default_cli_env();
  52 }
  53
  54 sub run_vnc_proxy {
  55     my ($path) = @_;
  56
  57     my $c;
  58     while ( ++$c < 10 && !-e $path ) { sleep(1); }
  59
  60     my $s = IO::Socket::UNIX->new(Peer => $path, Timeout => 120);
  61
  62     die "unable to connect to socket '$path' - $!" if !$s;
  63
  64     my $select = IO::Select->new();
  65
  66     $select->add(\*STDIN);
  67     $select->add($s);
  68
  69     my $timeout = 60*15; # 15 minutes
  70
  71     my @handles;
  72     while ($select->count &&
  73            scalar(@handles = $select->can_read ($timeout))) {
  74         foreach my $h (@handles) {
  75             my $buf;
  76             my $n = $h->sysread($buf, 4096);
  77
  78             if ($h == \*STDIN) {
  79                 if ($n) {
  80                     syswrite($s, $buf);
  81                 } else {
  82                     exit(0);
  83                 }
  84             } elsif ($h == $s) {
  85                 if ($n) {
  86                     syswrite(\*STDOUT, $buf);
  87                 } else {
  88                     exit(0);
  89                 }
  90             }
  91         }
  92     }
  93     exit(0);
  94 }
  95
  96 sub print_recursive_hash {
  97     my ($prefix, $hash, $key) = @_;
  98
  99     if (ref($hash) eq 'HASH') {
 100         if (defined($key)) {
 101             print "$prefix$key:\n";
 102         }
 103         foreach my $itemkey (keys %$hash) {
 104             print_recursive_hash("\t$prefix", $hash->{$itemkey}, $itemkey);
 105         }
 106     } elsif (ref($hash) eq 'ARRAY') {
 107         if (defined($key)) {
 108             print "$prefix$key:\n";
 109         }
 110         foreach my $item (@$hash) {
 111             print_recursive_hash("\t$prefix", $item);
 112         }
 113     } elsif (!ref($hash) && defined($hash)) {
 114         if (defined($key)) {
 115             print "$prefix$key: $hash\n";
 116         } else {
 117             print "$prefix$hash\n";
 118         }
 119     }
 120 }
 121
 122 __PACKAGE__->register_method ({
 123     name => 'showcmd',
 124     path => 'showcmd',
 125     method => 'GET',
 126     description => "Show command line which is used to start the VM (debug info).",
 127     parameters => {
 128         additionalProperties => 0,
 129         properties => {
 130             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 131             pretty => {
 132                 description => "Puts each option on a new line to enhance human readability",
 133                 type => 'boolean',
 134                 optional => 1,
 135                 default => 0,
 136             },
 137             snapshot => get_standard_option('pve-snapshot-name', {
 138                 description => "Fetch config values from given snapshot.",
 139                 optional => 1,
 140                 completion => sub {
 141                     my ($cmd, $pname, $cur, $args) = @_;
 142                     PVE::QemuConfig->snapshot_list($args->[0]);
 143                 }
 144             }),
 145         },
 146     },
 147     returns => { type => 'null'},
 148     code => sub {
 149         my ($param) = @_;
 150
 151         my $storecfg = PVE::Storage::config();
 152         my $cmdline = PVE::QemuServer::vm_commandline($storecfg, $param->{vmid}, $param->{snapshot});
 153
 154         $cmdline =~ s/ -/ \\\n  -/g if $param->{pretty};
 155
 156         print "$cmdline\n";
 157
 158         return;
 159     }});
 160
 161 __PACKAGE__->register_method ({
 162     name => 'status',
 163     path => 'status',
 164     method => 'GET',
 165     description => "Show VM status.",
 166     parameters => {
 167         additionalProperties => 0,
 168         properties => {
 169             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 170             verbose => {
 171                 description => "Verbose output format",
 172                 type => 'boolean',
 173                 optional => 1,
 174             }
 175         },
 176     },
 177     returns => { type => 'null'},
 178     code => sub {
 179         my ($param) = @_;
 180
 181         # test if VM exists
 182         my $conf = PVE::QemuConfig->load_config ($param->{vmid});
 183
 184         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
 185         my $stat = $vmstatus->{$param->{vmid}};
 186         if ($param->{verbose}) {
 187             foreach my $k (sort (keys %$stat)) {
 188                 next if $k eq 'cpu' || $k eq 'relcpu'; # always 0
 189                 my $v = $stat->{$k};
 190                 print_recursive_hash("", $v, $k);
 191             }
 192         } else {
 193             my $status = $stat->{qmpstatus} || 'unknown';
 194             print "status: $status\n";
 195         }
 196
 197         return;
 198     }});
 199
 200 __PACKAGE__->register_method ({
 201     name => 'vncproxy',
 202     path => 'vncproxy',
 203     method => 'PUT',
 204     description => "Proxy VM VNC traffic to stdin/stdout",
 205     parameters => {
 206         additionalProperties => 0,
 207         properties => {
 208             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 209         },
 210     },
 211     returns => { type => 'null'},
 212     code => sub {
 213         my ($param) = @_;
 214
 215         my $vmid = $param->{vmid};
 216         PVE::QemuConfig::assert_config_exists_on_node($vmid);
 217         my $vnc_socket = PVE::QemuServer::Helpers::vnc_socket($vmid);
 218
 219         if (my $ticket = $ENV{LC_PVE_TICKET}) {  # NOTE: ssh on debian only pass LC_* variables
 220             mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,password");
 221             mon_cmd($vmid, "set_password", protocol => 'vnc', password => $ticket);
 222             mon_cmd($vmid, "expire_password", protocol => 'vnc', time => "+30");
 223         } else {
 224             # FIXME: remove or allow to add tls-creds object, as x509 vnc param is removed with qemu 4??
 225             mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,password");
 226         }
 227
 228         run_vnc_proxy($vnc_socket);
 229
 230         return;
 231     }});
 232
 233 __PACKAGE__->register_method ({
 234     name => 'unlock',
 235     path => 'unlock',
 236     method => 'PUT',
 237     description => "Unlock the VM.",
 238     parameters => {
 239         additionalProperties => 0,
 240         properties => {
 241             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 242         },
 243     },
 244     returns => { type => 'null'},
 245     code => sub {
 246         my ($param) = @_;
 247
 248         my $vmid = $param->{vmid};
 249
 250         PVE::QemuConfig->lock_config ($vmid, sub {
 251             my $conf = PVE::QemuConfig->load_config($vmid);
 252             delete $conf->{lock};
 253             delete $conf->{pending}->{lock} if $conf->{pending}; # just to be sure
 254             PVE::QemuConfig->write_config($vmid, $conf);
 255         });
 256
 257         return;
 258     }});
 259
 260 __PACKAGE__->register_method ({
 261     name => 'nbdstop',
 262     path => 'nbdstop',
 263     method => 'PUT',
 264     description => "Stop embedded nbd server.",
 265     parameters => {
 266         additionalProperties => 0,
 267         properties => {
 268             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 269         },
 270     },
 271     returns => { type => 'null'},
 272     code => sub {
 273         my ($param) = @_;
 274
 275         my $vmid = $param->{vmid};
 276
 277         eval { PVE::QemuServer::nbd_stop($vmid) };
 278         warn $@ if $@;
 279
 280         return;
 281     }});
 282
 283 __PACKAGE__->register_method ({
 284     name => 'mtunnel',
 285     path => 'mtunnel',
 286     method => 'POST',
 287     description => "Used by qmigrate - do not use manually.",
 288     parameters => {
 289         additionalProperties => 0,
 290         properties => {},
 291     },
 292     returns => { type => 'null'},
 293     code => sub {
 294         my ($param) = @_;
 295
 296         if (!PVE::Cluster::check_cfs_quorum(1)) {
 297             print "no quorum\n";
 298             return;
 299         }
 300
 301         my $tunnel_write = sub {
 302             my $text = shift;
 303             chomp $text;
 304             print "$text\n";
 305             *STDOUT->flush();
 306         };
 307
 308         $tunnel_write->("tunnel online");
 309         $tunnel_write->("ver 1");
 310
 311         while (my $line = <STDIN>) {
 312             chomp $line;
 313             if ($line =~ /^quit$/) {
 314                 $tunnel_write->("OK");
 315                 last;
 316             } elsif ($line =~ /^resume (\d+)$/) {
 317                 my $vmid = $1;
 318                 if (PVE::QemuServer::check_running($vmid, 1)) {
 319                     eval { PVE::QemuServer::vm_resume($vmid, 1, 1); };
 320                     if ($@) {
 321                         $tunnel_write->("ERR: resume failed - $@");
 322                     } else {
 323                         $tunnel_write->("OK");
 324                     }
 325                 } else {
 326                     $tunnel_write->("ERR: resume failed - VM $vmid not running");
 327                 }
 328             }
 329         }
 330
 331         return;
 332     }});
 333
 334 __PACKAGE__->register_method ({
 335     name => 'wait',
 336     path => 'wait',
 337     method => 'GET',
 338     description => "Wait until the VM is stopped.",
 339     parameters => {
 340         additionalProperties => 0,
 341         properties => {
 342             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 343             timeout => {
 344                 description => "Timeout in seconds. Default is to wait forever.",
 345                 type => 'integer',
 346                 minimum => 1,
 347                 optional => 1,
 348             }
 349         },
 350     },
 351     returns => { type => 'null'},
 352     code => sub {
 353         my ($param) = @_;
 354
 355         my $vmid = $param->{vmid};
 356         my $timeout = $param->{timeout};
 357
 358         my $pid = PVE::QemuServer::check_running ($vmid);
 359         return if !$pid;
 360
 361         print "waiting until VM $vmid stopps (PID $pid)\n";
 362
 363         my $count = 0;
 364         while ((!$timeout || ($count < $timeout)) && PVE::QemuServer::check_running ($vmid)) {
 365             $count++;
 366             sleep 1;
 367         }
 368
 369         die "wait failed - got timeout\n" if PVE::QemuServer::check_running ($vmid);
 370
 371         return;
 372     }});
 373
 374 __PACKAGE__->register_method ({
 375     name => 'monitor',
 376     path => 'monitor',
 377     method => 'POST',
 378     description => "Enter Qemu Monitor interface.",
 379     parameters => {
 380         additionalProperties => 0,
 381         properties => {
 382             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 383         },
 384     },
 385     returns => { type => 'null'},
 386     code => sub {
 387         my ($param) = @_;
 388
 389         my $vmid = $param->{vmid};
 390
 391         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 392
 393         print "Entering Qemu Monitor for VM $vmid - type 'help' for help\n";
 394
 395         my $term = Term::ReadLine->new('qm');
 396
 397         while (defined(my $input = $term->readline('qm> '))) {
 398             chomp $input;
 399             next if $input =~ m/^\s*$/;
 400             last if $input =~ m/^\s*q(uit)?\s*$/;
 401
 402             eval { print PVE::QemuServer::Monitor::hmp_cmd($vmid, $input) };
 403             print "ERROR: $@" if $@;
 404         }
 405
 406         return;
 407
 408     }});
 409
 410 __PACKAGE__->register_method ({
 411     name => 'rescan',
 412     path => 'rescan',
 413     method => 'POST',
 414     description => "Rescan all storages and update disk sizes and unused disk images.",
 415     parameters => {
 416         additionalProperties => 0,
 417         properties => {
 418             vmid => get_standard_option('pve-vmid', {
 419                 optional => 1,
 420                 completion => \&PVE::QemuServer::complete_vmid,
 421             }),
 422             dryrun => {
 423                 type => 'boolean',
 424                 optional => 1,
 425                 default => 0,
 426                 description => 'Do not actually write changes out to VM config(s).',
 427             },
 428         },
 429     },
 430     returns => { type => 'null'},
 431     code => sub {
 432         my ($param) = @_;
 433
 434         my $dryrun = $param->{dryrun};
 435
 436         print "NOTE: running in dry-run mode, won't write changes out!\n" if $dryrun;
 437
 438         PVE::QemuServer::rescan($param->{vmid}, 0, $dryrun);
 439
 440         return;
 441     }});
 442
 443 __PACKAGE__->register_method ({
 444     name => 'importdisk',
 445     path => 'importdisk',
 446     method => 'POST',
 447     description => "Import an external disk image as an unused disk in a VM. The
 448  image format has to be supported by qemu-img(1).",
 449     parameters => {
 450         additionalProperties => 0,
 451         properties => {
 452             vmid => get_standard_option('pve-vmid', {completion => \&PVE::QemuServer::complete_vmid}),
 453             source => {
 454                 description => 'Path to the disk image to import',
 455                 type => 'string',
 456                 optional => 0,
 457             },
 458             storage => get_standard_option('pve-storage-id', {
 459                 description => 'Target storage ID',
 460                 completion => \&PVE::QemuServer::complete_storage,
 461                 optional => 0,
 462             }),
 463             format => {
 464                 type => 'string',
 465                 description => 'Target format',
 466                 enum => [ 'raw', 'qcow2', 'vmdk' ],
 467                 optional => 1,
 468             },
 469         },
 470     },
 471     returns => { type => 'null'},
 472     code => sub {
 473         my ($param) = @_;
 474
 475         my $vmid = extract_param($param, 'vmid');
 476         my $source = extract_param($param, 'source');
 477         my $storeid = extract_param($param, 'storage');
 478         my $format = extract_param($param, 'format');
 479
 480         my $vm_conf = PVE::QemuConfig->load_config($vmid);
 481         PVE::QemuConfig->check_lock($vm_conf);
 482         die "$source: non-existent or non-regular file\n" if (! -f $source);
 483
 484         my $storecfg = PVE::Storage::config();
 485         PVE::Storage::storage_check_enabled($storecfg, $storeid);
 486
 487         my $target_storage_config =  PVE::Storage::storage_config($storecfg, $storeid);
 488         die "storage $storeid does not support vm images\n"
 489             if !$target_storage_config->{content}->{images};
 490
 491         print "importing disk '$source' to VM $vmid ...\n";
 492         my ($drive_id, $volid) = PVE::QemuServer::ImportDisk::do_import($source, $vmid, $storeid, { format => $format });
 493         print "Successfully imported disk as '$drive_id:$volid'\n";
 494
 495         return;
 496     }});
 497
 498 __PACKAGE__->register_method ({
 499     name => 'terminal',
 500     path => 'terminal',
 501     method => 'POST',
 502     description => "Open a terminal using a serial device (The VM need to have a serial device configured, for example 'serial0: socket')",
 503     parameters => {
 504         additionalProperties => 0,
 505         properties => {
 506             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 507             iface => {
 508                 description => "Select the serial device. By default we simply use the first suitable device.",
 509                 type => 'string',
 510                 optional => 1,
 511                 enum => [qw(serial0 serial1 serial2 serial3)],
 512             },
 513             escape => {
 514                 description => "Escape character.",
 515                 type => 'string',
 516                 optional => 1,
 517                 default => '^O',
 518             },
 519         },
 520     },
 521     returns => { type => 'null'},
 522     code => sub {
 523         my ($param) = @_;
 524
 525         my $vmid = $param->{vmid};
 526
 527         my $escape = $param->{escape} // '^O';
 528         if ($escape =~ /^\^([\x40-\x7a])$/) {
 529             $escape = ord($1) & 0x1F;
 530         } elsif ($escape =~ /^0x[0-9a-f]+$/i) {
 531             $escape = hex($escape);
 532         } elsif ($escape =~ /^[0-9]+$/) {
 533             $escape = int($escape);
 534         } else {
 535             die "invalid escape character definition: $escape\n";
 536         }
 537         my $escapemsg = '';
 538         if ($escape) {
 539             $escapemsg = sprintf(' (press Ctrl+%c to exit)', $escape+0x40);
 540             $escape = sprintf(',escape=0x%x', $escape);
 541         } else {
 542             $escape = '';
 543         }
 544
 545         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 546
 547         my $iface = $param->{iface};
 548
 549         if ($iface) {
 550             die "serial interface '$iface' is not configured\n" if !$conf->{$iface};
 551             die "wrong serial type on interface '$iface'\n" if $conf->{$iface} ne 'socket';
 552         } else {
 553             foreach my $opt (qw(serial0 serial1 serial2 serial3)) {
 554                 if ($conf->{$opt} && ($conf->{$opt} eq 'socket')) {
 555                     $iface = $opt;
 556                     last;
 557                 }
 558             }
 559             die "unable to find a serial interface\n" if !$iface;
 560         }
 561
 562         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
 563
 564         my $socket = "/var/run/qemu-server/${vmid}.$iface";
 565
 566         my $cmd = "socat UNIX-CONNECT:$socket STDIO,raw,echo=0$escape";
 567
 568         print "starting serial terminal on interface ${iface}${escapemsg}\n";
 569
 570         system($cmd);
 571
 572         return;
 573     }});
 574
 575 __PACKAGE__->register_method ({
 576     name => 'importovf',
 577     path => 'importovf',
 578     description => "Create a new VM using parameters read from an OVF manifest",
 579     parameters => {
 580         additionalProperties => 0,
 581         properties => {
 582             vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 583             manifest => {
 584                 type => 'string',
 585                 description => 'path to the ovf file',
 586                 },
 587             storage => get_standard_option('pve-storage-id', {
 588                 description => 'Target storage ID',
 589                 completion => \&PVE::QemuServer::complete_storage,
 590                 optional => 0,
 591             }),
 592             format => {
 593                 type => 'string',
 594                 description => 'Target format',
 595                 enum => [ 'raw', 'qcow2', 'vmdk' ],
 596                 optional => 1,
 597             },
 598             dryrun => {
 599                 type => 'boolean',
 600                 description => 'Print a parsed representation of the extracted OVF parameters, but do not create a VM',
 601                 optional => 1,
 602             }
 603         },
 604     },
 605     returns => { type => 'null' },
 606     code => sub {
 607         my ($param) = @_;
 608
 609         my $vmid = PVE::Tools::extract_param($param, 'vmid');
 610         my $ovf_file = PVE::Tools::extract_param($param, 'manifest');
 611         my $storeid = PVE::Tools::extract_param($param, 'storage');
 612         my $format = PVE::Tools::extract_param($param, 'format');
 613         my $dryrun = PVE::Tools::extract_param($param, 'dryrun');
 614
 615         die "$ovf_file: non-existent or non-regular file\n" if (! -f $ovf_file);
 616         my $storecfg = PVE::Storage::config();
 617         PVE::Storage::storage_check_enabled($storecfg, $storeid);
 618
 619         my $parsed = PVE::QemuServer::OVF::parse_ovf($ovf_file);
 620
 621         if ($dryrun) {
 622             print to_json($parsed, { pretty => 1, canonical => 1});
 623             return;
 624         }
 625
 626         eval { PVE::QemuConfig->create_and_lock_config($vmid) };
 627         die "Reserving empty config for OVF import to VM $vmid failed: $@" if $@;
 628
 629         my $conf = PVE::QemuConfig->load_config($vmid);
 630         die "Internal error: Expected 'create' lock in config of VM $vmid!"
 631             if !PVE::QemuConfig->has_lock($conf, "create");
 632
 633         $conf->{name} = $parsed->{qm}->{name} if defined($parsed->{qm}->{name});
 634         $conf->{memory} = $parsed->{qm}->{memory} if defined($parsed->{qm}->{memory});
 635         $conf->{cores} = $parsed->{qm}->{cores} if defined($parsed->{qm}->{cores});
 636
 637         eval {
 638             # order matters, as do_import() will load_config() internally
 639             $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 640             $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 641             PVE::QemuConfig->write_config($vmid, $conf);
 642
 643             foreach my $disk (@{ $parsed->{disks} }) {
 644                 my ($file, $drive) = ($disk->{backing_file}, $disk->{disk_address});
 645                 PVE::QemuServer::ImportDisk::do_import($file, $vmid, $storeid, {
 646                     drive_name => $drive,
 647                     format => $format,
 648                     skiplock => 1,
 649                 });
 650             }
 651
 652             # reload after disks entries have been created
 653             $conf = PVE::QemuConfig->load_config($vmid);
 654             my $devs = PVE::QemuServer::get_default_bootdevices($conf);
 655             $conf->{boot} = PVE::QemuServer::print_bootorder($devs);
 656             PVE::QemuConfig->write_config($vmid, $conf);
 657         };
 658
 659         my $err = $@;
 660         if ($err) {
 661             my $skiplock = 1;
 662             # eval for additional safety in error path
 663             eval { PVE::QemuServer::destroy_vm($storecfg, $vmid, $skiplock) };
 664             warn "Could not destroy VM $vmid: $@" if "$@";
 665             die "import failed - $err";
 666         }
 667
 668         PVE::QemuConfig->remove_lock($vmid, "create");
 669
 670         return;
 671
 672     }
 673 });
 674
 675 __PACKAGE__->register_method({
 676     name => 'exec',
 677     path => 'exec',
 678     method => 'POST',
 679     protected => 1,
 680     description => "Executes the given command via the guest agent",
 681     parameters => {
 682         additionalProperties => 0,
 683         properties => {
 684             node => get_standard_option('pve-node'),
 685             vmid => get_standard_option('pve-vmid', {
 686                     completion => \&PVE::QemuServer::complete_vmid_running }),
 687             synchronous => {
 688                 type => 'boolean',
 689                 optional => 1,
 690                 default => 1,
 691                 description => "If set to off, returns the pid immediately instead of waiting for the commmand to finish or the timeout.",
 692             },
 693             'timeout' => {
 694                 type => 'integer',
 695                 description => "The maximum time to wait synchronously for the command to finish. If reached, the pid gets returned. Set to 0 to deactivate",
 696                 minimum => 0,
 697                 optional => 1,
 698                 default => 30,
 699             },
 700             'pass-stdin' => {
 701                 type => 'boolean',
 702                 description => "When set, read STDIN until EOF and forward to guest agent via 'input-data' (usually treated as STDIN to process launched by guest agent). Allows maximal 1 MiB.",
 703                 optional => 1,
 704                 default => 0,
 705             },
 706             'extra-args' => get_standard_option('extra-args'),
 707         },
 708     },
 709     returns => {
 710         type => 'object',
 711     },
 712     code => sub {
 713         my ($param) = @_;
 714
 715         my $vmid = $param->{vmid};
 716         my $sync = $param->{synchronous} // 1;
 717         my $pass_stdin = $param->{'pass-stdin'};
 718         if (defined($param->{timeout}) && !$sync) {
 719             raise_param_exc({ synchronous => "needs to be set for 'timeout'"});
 720         }
 721
 722         my $input_data = undef;
 723         if ($pass_stdin) {
 724             $input_data = '';
 725             while (my $line = <STDIN>) {
 726                 $input_data .= $line;
 727                 if (length($input_data) > 1024*1024) {
 728                     # not sure how QEMU handles large amounts of data being
 729                     # passed into the QMP socket, so limit to be safe
 730                     die "'input-data' (STDIN) is limited to 1 MiB, aborting\n";
 731                 }
 732             }
 733         }
 734
 735         my $args = $param->{'extra-args'};
 736         $args = undef if !$args || !@$args;
 737
 738         my $res = PVE::QemuServer::Agent::qemu_exec($vmid, $input_data, $args);
 739
 740         if ($sync) {
 741             my $pid = $res->{pid};
 742             my $timeout = $param->{timeout} // 30;
 743             my $starttime = time();
 744
 745             while ($timeout == 0 || (time() - $starttime) < $timeout) {
 746                 my $out = PVE::QemuServer::Agent::qemu_exec_status($vmid, $pid);
 747                 if ($out->{exited}) {
 748                     $res = $out;
 749                     last;
 750                 }
 751                 sleep 1;
 752             }
 753
 754             if (!$res->{exited}) {
 755                 warn "timeout reached, returning pid\n";
 756             }
 757         }
 758
 759         return { result => $res };
 760     }});
 761
 762 __PACKAGE__->register_method({
 763     name => 'cleanup',
 764     path => 'cleanup',
 765     method => 'POST',
 766     protected => 1,
 767     description => "Cleans up resources like tap devices, vgpus, etc. Called after a vm shuts down, crashes, etc.",
 768     parameters => {
 769         additionalProperties => 0,
 770         properties => {
 771             node => get_standard_option('pve-node'),
 772             vmid => get_standard_option('pve-vmid', {
 773                     completion => \&PVE::QemuServer::complete_vmid_running }),
 774             'clean-shutdown' => {
 775                 type => 'boolean',
 776                 description => "Indicates if qemu shutdown cleanly.",
 777             },
 778             'guest-requested' => {
 779                 type => 'boolean',
 780                 description => "Indicates if the shutdown was requested by the guest or via qmp.",
 781             },
 782         },
 783     },
 784     returns => { type => 'null', },
 785     code => sub {
 786         my ($param) = @_;
 787
 788         my $vmid = $param->{vmid};
 789         my $clean = $param->{'clean-shutdown'};
 790         my $guest = $param->{'guest-requested'};
 791         my $restart = 0;
 792
 793         # return if we do not have the config anymore
 794         return if !-f PVE::QemuConfig->config_file($vmid);
 795
 796         my $storecfg = PVE::Storage::config();
 797         warn "Starting cleanup for $vmid\n";
 798
 799         PVE::QemuConfig->lock_config($vmid, sub {
 800             my $conf = PVE::QemuConfig->load_config ($vmid);
 801             my $pid = PVE::QemuServer::check_running ($vmid);
 802             die "vm still running\n" if $pid;
 803
 804             if (!$clean) {
 805                 # we have to cleanup the tap devices after a crash
 806
 807                 foreach my $opt (keys %$conf) {
 808                     next if $opt !~  m/^net(\d)+$/;
 809                     my $interface = $1;
 810                     PVE::Network::tap_unplug("tap${vmid}i${interface}");
 811                 }
 812             }
 813
 814             if (!$clean || $guest) {
 815                 # vm was shutdown from inside the guest or crashed, doing api cleanup
 816                 PVE::QemuServer::vm_stop_cleanup($storecfg, $vmid, $conf, 0, 0);
 817             }
 818             PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-stop');
 819
 820             $restart = eval { PVE::QemuServer::clear_reboot_request($vmid) };
 821             warn $@ if $@;
 822         });
 823
 824         warn "Finished cleanup for $vmid\n";
 825
 826         if ($restart) {
 827             warn "Restarting VM $vmid\n";
 828             PVE::API2::Qemu->vm_start({
 829                 vmid => $vmid,
 830                 node => $nodename,
 831             });
 832         }
 833
 834         return;
 835     }});
 836
 837 my $print_agent_result = sub {
 838     my ($data) = @_;
 839
 840     my $result = $data->{result} // $data;
 841     return if !defined($result);
 842
 843     my $class = ref($result);
 844
 845     if (!$class) {
 846         chomp $result;
 847         return if $result =~ m/^\s*$/;
 848         print "$result\n";
 849         return;
 850     }
 851
 852     if (($class eq 'HASH') && !scalar(keys %$result)) { # empty hash
 853         return;
 854     }
 855
 856     print to_json($result, { pretty => 1, canonical => 1});
 857 };
 858
 859 sub param_mapping {
 860     my ($name) = @_;
 861
 862     my $ssh_key_map = ['sshkeys', sub {
 863         return URI::Escape::uri_escape(PVE::Tools::file_get_contents($_[0]));
 864     }];
 865     my $cipassword_map = PVE::CLIHandler::get_standard_mapping('pve-password', { name => 'cipassword' });
 866     my $password_map = PVE::CLIHandler::get_standard_mapping('pve-password');
 867     my $mapping = {
 868         'update_vm' => [$ssh_key_map, $cipassword_map],
 869         'create_vm' => [$ssh_key_map, $cipassword_map],
 870         'set-user-password' => [$password_map],
 871     };
 872
 873     return $mapping->{$name};
 874 }
 875
 876 our $cmddef = {
 877     list => [ "PVE::API2::Qemu", 'vmlist', [],
 878              { node => $nodename }, sub {
 879                  my $vmlist = shift;
 880
 881                  exit 0 if (!scalar(@$vmlist));
 882
 883                  printf "%10s %-20s %-10s %-10s %12s %-10s\n",
 884                  qw(VMID NAME STATUS MEM(MB) BOOTDISK(GB) PID);
 885
 886                  foreach my $rec (sort { $a->{vmid} <=> $b->{vmid} } @$vmlist) {
 887                      printf "%10s %-20s %-10s %-10s %12.2f %-10s\n", $rec->{vmid}, $rec->{name},
 888                      $rec->{qmpstatus} || $rec->{status},
 889                      ($rec->{maxmem} || 0)/(1024*1024),
 890                      ($rec->{maxdisk} || 0)/(1024*1024*1024),
 891                      $rec->{pid}||0;
 892                  }
 893
 894
 895               } ],
 896
 897     create => [ "PVE::API2::Qemu", 'create_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 898
 899     destroy => [ "PVE::API2::Qemu", 'destroy_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 900
 901     clone => [ "PVE::API2::Qemu", 'clone_vm', ['vmid', 'newid'], { node => $nodename }, $upid_exit ],
 902
 903     migrate => [ "PVE::API2::Qemu", 'migrate_vm', ['vmid', 'target'], { node => $nodename }, $upid_exit ],
 904
 905     set => [ "PVE::API2::Qemu", 'update_vm', ['vmid'], { node => $nodename } ],
 906
 907     resize => [ "PVE::API2::Qemu", 'resize_vm', ['vmid', 'disk', 'size'], { node => $nodename } ],
 908
 909     move_disk => [ "PVE::API2::Qemu", 'move_vm_disk', ['vmid', 'disk', 'storage'], { node => $nodename }, $upid_exit ],
 910
 911     unlink => [ "PVE::API2::Qemu", 'unlink', ['vmid'], { node => $nodename } ],
 912
 913     config => [ "PVE::API2::Qemu", 'vm_config', ['vmid'],
 914                 { node => $nodename }, sub {
 915                     my $config = shift;
 916                     foreach my $k (sort (keys %$config)) {
 917                         next if $k eq 'digest';
 918                         my $v = $config->{$k};
 919                         if ($k eq 'description') {
 920                             $v = PVE::Tools::encode_text($v);
 921                         }
 922                         print "$k: $v\n";
 923                     }
 924                 }],
 925
 926     pending => [ "PVE::API2::Qemu", 'vm_pending', ['vmid'], { node => $nodename }, \&PVE::GuestHelpers::format_pending ],
 927     showcmd => [ __PACKAGE__, 'showcmd', ['vmid']],
 928
 929     status => [ __PACKAGE__, 'status', ['vmid']],
 930
 931     snapshot => [ "PVE::API2::Qemu", 'snapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 932
 933     delsnapshot => [ "PVE::API2::Qemu", 'delsnapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 934
 935     listsnapshot => [ "PVE::API2::Qemu", 'snapshot_list', ['vmid'], { node => $nodename }, \&PVE::GuestHelpers::print_snapshot_tree],
 936
 937     rollback => [ "PVE::API2::Qemu", 'rollback', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 938
 939     template => [ "PVE::API2::Qemu", 'template', ['vmid'], { node => $nodename }],
 940
 941     start => [ "PVE::API2::Qemu", 'vm_start', ['vmid'], { node => $nodename } , $upid_exit ],
 942
 943     stop => [ "PVE::API2::Qemu", 'vm_stop', ['vmid'], { node => $nodename }, $upid_exit ],
 944
 945     reset => [ "PVE::API2::Qemu", 'vm_reset', ['vmid'], { node => $nodename }, $upid_exit ],
 946
 947     shutdown => [ "PVE::API2::Qemu", 'vm_shutdown', ['vmid'], { node => $nodename }, $upid_exit ],
 948
 949     reboot => [ "PVE::API2::Qemu", 'vm_reboot', ['vmid'], { node => $nodename }, $upid_exit ],
 950
 951     suspend => [ "PVE::API2::Qemu", 'vm_suspend', ['vmid'], { node => $nodename }, $upid_exit ],
 952
 953     resume => [ "PVE::API2::Qemu", 'vm_resume', ['vmid'], { node => $nodename }, $upid_exit ],
 954
 955     sendkey => [ "PVE::API2::Qemu", 'vm_sendkey', ['vmid', 'key'], { node => $nodename } ],
 956
 957     vncproxy => [ __PACKAGE__, 'vncproxy', ['vmid']],
 958
 959     wait => [ __PACKAGE__, 'wait', ['vmid']],
 960
 961     unlock => [ __PACKAGE__, 'unlock', ['vmid']],
 962
 963     rescan  => [ __PACKAGE__, 'rescan', []],
 964
 965     monitor  => [ __PACKAGE__, 'monitor', ['vmid']],
 966
 967     agent  => { alias => 'guest cmd' },
 968
 969     guest => {
 970         cmd  => [ "PVE::API2::Qemu::Agent", 'agent', ['vmid', 'command'], { node => $nodename }, $print_agent_result ],
 971         passwd => [ "PVE::API2::Qemu::Agent", 'set-user-password', [ 'vmid', 'username' ], { node => $nodename }],
 972         exec => [ __PACKAGE__, 'exec', [ 'vmid', 'extra-args' ], { node => $nodename }, $print_agent_result],
 973         'exec-status' => [ "PVE::API2::Qemu::Agent", 'exec-status', [ 'vmid', 'pid' ], { node => $nodename }, $print_agent_result],
 974     },
 975
 976     mtunnel => [ __PACKAGE__, 'mtunnel', []],
 977
 978     nbdstop => [ __PACKAGE__, 'nbdstop', ['vmid']],
 979
 980     terminal => [ __PACKAGE__, 'terminal', ['vmid']],
 981
 982     importdisk => [ __PACKAGE__, 'importdisk', ['vmid', 'source', 'storage']],
 983
 984     importovf => [ __PACKAGE__, 'importovf', ['vmid', 'manifest', 'storage']],
 985
 986     cleanup => [ __PACKAGE__, 'cleanup', ['vmid', 'clean-shutdown', 'guest-requested'], { node => $nodename }],
 987
 988     cloudinit => {
 989         dump => [ "PVE::API2::Qemu", 'cloudinit_generated_config_dump', ['vmid', 'type'], { node => $nodename }, sub {
 990                 my $data = shift;
 991                 print "$data\n";
 992             }],
 993     },
 994
 995 };
 996
 997 1;