PVE/CLI/qm.pm

   1 package PVE::CLI::qm;
   2
   3 use strict;
   4 use warnings;
   5
   6 # Note: disable '+' prefix for Getopt::Long (for resize command)
   7 use Getopt::Long qw(:config no_getopt_compat);
   8
   9 use Fcntl ':flock';
  10 use File::Path;
  11 use IO::Socket::UNIX;
  12 use IO::Select;
  13
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Cluster;
  16 use PVE::SafeSyslog;
  17 use PVE::INotify;
  18 use PVE::RPCEnvironment;
  19 use PVE::QemuServer;
  20 use PVE::QemuServer::ImportDisk;
  21 use PVE::API2::Qemu;
  22 use JSON;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use Term::ReadLine;
  25
  26 use PVE::CLIHandler;
  27
  28 use base qw(PVE::CLIHandler);
  29
  30 my $upid_exit = sub {
  31     my $upid = shift;
  32     my $status = PVE::Tools::upid_read_status($upid);
  33     exit($status eq 'OK' ? 0 : -1);
  34 };
  35
  36 my $nodename = PVE::INotify::nodename();
  37
  38 sub setup_environment {
  39     PVE::RPCEnvironment->setup_default_cli_env();
  40 }
  41
  42 sub run_vnc_proxy {
  43     my ($path) = @_;
  44
  45     my $c;
  46     while ( ++$c < 10 && !-e $path ) { sleep(1); }
  47
  48     my $s = IO::Socket::UNIX->new(Peer => $path, Timeout => 120);
  49
  50     die "unable to connect to socket '$path' - $!" if !$s;
  51
  52     my $select = new IO::Select;
  53
  54     $select->add(\*STDIN);
  55     $select->add($s);
  56
  57     my $timeout = 60*15; # 15 minutes
  58
  59     my @handles;
  60     while ($select->count &&
  61            scalar(@handles = $select->can_read ($timeout))) {
  62         foreach my $h (@handles) {
  63             my $buf;
  64             my $n = $h->sysread($buf, 4096);
  65
  66             if ($h == \*STDIN) {
  67                 if ($n) {
  68                     syswrite($s, $buf);
  69                 } else {
  70                     exit(0);
  71                 }
  72             } elsif ($h == $s) {
  73                 if ($n) {
  74                     syswrite(\*STDOUT, $buf);
  75                 } else {
  76                     exit(0);
  77                 }
  78             }
  79         }
  80     }
  81     exit(0);
  82 }
  83
  84 sub print_recursive_hash {
  85     my ($prefix, $hash, $key) = @_;
  86
  87     if (ref($hash) eq 'HASH') {
  88         if (defined($key)) {
  89             print "$prefix$key:\n";
  90         }
  91         foreach my $itemkey (keys %$hash) {
  92             print_recursive_hash("\t$prefix", $hash->{$itemkey}, $itemkey);
  93         }
  94     } elsif (ref($hash) eq 'ARRAY') {
  95         if (defined($key)) {
  96             print "$prefix$key:\n";
  97         }
  98         foreach my $item (@$hash) {
  99             print_recursive_hash("\t$prefix", $item);
 100         }
 101     } elsif (!ref($hash) && defined($hash)) {
 102         if (defined($key)) {
 103             print "$prefix$key: $hash\n";
 104         } else {
 105             print "$prefix$hash\n";
 106         }
 107     }
 108 }
 109
 110 __PACKAGE__->register_method ({
 111     name => 'showcmd',
 112     path => 'showcmd',
 113     method => 'GET',
 114     description => "Show command line which is used to start the VM (debug info).",
 115     parameters => {
 116         additionalProperties => 0,
 117         properties => {
 118             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 119         },
 120     },
 121     returns => { type => 'null'},
 122     code => sub {
 123         my ($param) = @_;
 124
 125         my $storecfg = PVE::Storage::config();
 126         print PVE::QemuServer::vm_commandline($storecfg, $param->{vmid}) . "\n";
 127
 128         return undef;
 129     }});
 130
 131 __PACKAGE__->register_method ({
 132     name => 'status',
 133     path => 'status',
 134     method => 'GET',
 135     description => "Show VM status.",
 136     parameters => {
 137         additionalProperties => 0,
 138         properties => {
 139             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 140             verbose => {
 141                 description => "Verbose output format",
 142                 type => 'boolean',
 143                 optional => 1,
 144             }
 145         },
 146     },
 147     returns => { type => 'null'},
 148     code => sub {
 149         my ($param) = @_;
 150
 151         # test if VM exists
 152         my $conf = PVE::QemuConfig->load_config ($param->{vmid});
 153
 154         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
 155         my $stat = $vmstatus->{$param->{vmid}};
 156         if ($param->{verbose}) {
 157             foreach my $k (sort (keys %$stat)) {
 158                 next if $k eq 'cpu' || $k eq 'relcpu'; # always 0
 159                 my $v = $stat->{$k};
 160                 print_recursive_hash("", $v, $k);
 161             }
 162         } else {
 163             my $status = $stat->{qmpstatus} || 'unknown';
 164             print "status: $status\n";
 165         }
 166
 167         return undef;
 168     }});
 169
 170 __PACKAGE__->register_method ({
 171     name => 'vncproxy',
 172     path => 'vncproxy',
 173     method => 'PUT',
 174     description => "Proxy VM VNC traffic to stdin/stdout",
 175     parameters => {
 176         additionalProperties => 0,
 177         properties => {
 178             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 179         },
 180     },
 181     returns => { type => 'null'},
 182     code => sub {
 183         my ($param) = @_;
 184
 185         my $vmid = $param->{vmid};
 186         my $vnc_socket = PVE::QemuServer::vnc_socket($vmid);
 187
 188         if (my $ticket = $ENV{LC_PVE_TICKET}) {  # NOTE: ssh on debian only pass LC_* variables
 189             PVE::QemuServer::vm_mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,password");
 190             PVE::QemuServer::vm_mon_cmd($vmid, "set_password", protocol => 'vnc', password => $ticket);
 191             PVE::QemuServer::vm_mon_cmd($vmid, "expire_password", protocol => 'vnc', time => "+30");
 192         } else {
 193             PVE::QemuServer::vm_mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,x509,password");
 194         }
 195
 196         run_vnc_proxy($vnc_socket);
 197
 198         return undef;
 199     }});
 200
 201 __PACKAGE__->register_method ({
 202     name => 'unlock',
 203     path => 'unlock',
 204     method => 'PUT',
 205     description => "Unlock the VM.",
 206     parameters => {
 207         additionalProperties => 0,
 208         properties => {
 209             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 210         },
 211     },
 212     returns => { type => 'null'},
 213     code => sub {
 214         my ($param) = @_;
 215
 216         my $vmid = $param->{vmid};
 217
 218         PVE::QemuConfig->lock_config ($vmid, sub {
 219             my $conf = PVE::QemuConfig->load_config($vmid);
 220             delete $conf->{lock};
 221             delete $conf->{pending}->{lock} if $conf->{pending}; # just to be sure
 222             PVE::QemuConfig->write_config($vmid, $conf);
 223         });
 224
 225         return undef;
 226     }});
 227
 228 __PACKAGE__->register_method ({
 229     name => 'nbdstop',
 230     path => 'nbdstop',
 231     method => 'PUT',
 232     description => "Stop embedded nbd server.",
 233     parameters => {
 234         additionalProperties => 0,
 235         properties => {
 236             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 237         },
 238     },
 239     returns => { type => 'null'},
 240     code => sub {
 241         my ($param) = @_;
 242
 243         my $vmid = $param->{vmid};
 244
 245         PVE::QemuServer::nbd_stop($vmid);
 246
 247         return undef;
 248     }});
 249
 250 __PACKAGE__->register_method ({
 251     name => 'mtunnel',
 252     path => 'mtunnel',
 253     method => 'POST',
 254     description => "Used by qmigrate - do not use manually.",
 255     parameters => {
 256         additionalProperties => 0,
 257         properties => {},
 258     },
 259     returns => { type => 'null'},
 260     code => sub {
 261         my ($param) = @_;
 262
 263         if (!PVE::Cluster::check_cfs_quorum(1)) {
 264             print "no quorum\n";
 265             return undef;
 266         }
 267
 268         print "tunnel online\n";
 269         *STDOUT->flush();
 270
 271         print "ver 1\n";
 272         *STDOUT->flush();
 273
 274         while (my $line = <>) {
 275             chomp $line;
 276             last if $line =~ m/^quit$/;
 277         }
 278
 279         return undef;
 280     }});
 281
 282 __PACKAGE__->register_method ({
 283     name => 'wait',
 284     path => 'wait',
 285     method => 'GET',
 286     description => "Wait until the VM is stopped.",
 287     parameters => {
 288         additionalProperties => 0,
 289         properties => {
 290             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 291             timeout => {
 292                 description => "Timeout in seconds. Default is to wait forever.",
 293                 type => 'integer',
 294                 minimum => 1,
 295                 optional => 1,
 296             }
 297         },
 298     },
 299     returns => { type => 'null'},
 300     code => sub {
 301         my ($param) = @_;
 302
 303         my $vmid = $param->{vmid};
 304         my $timeout = $param->{timeout};
 305
 306         my $pid = PVE::QemuServer::check_running ($vmid);
 307         return if !$pid;
 308
 309         print "waiting until VM $vmid stopps (PID $pid)\n";
 310
 311         my $count = 0;
 312         while ((!$timeout || ($count < $timeout)) && PVE::QemuServer::check_running ($vmid)) {
 313             $count++;
 314             sleep 1;
 315         }
 316
 317         die "wait failed - got timeout\n" if PVE::QemuServer::check_running ($vmid);
 318
 319         return undef;
 320     }});
 321
 322 __PACKAGE__->register_method ({
 323     name => 'monitor',
 324     path => 'monitor',
 325     method => 'POST',
 326     description => "Enter Qemu Monitor interface.",
 327     parameters => {
 328         additionalProperties => 0,
 329         properties => {
 330             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 331         },
 332     },
 333     returns => { type => 'null'},
 334     code => sub {
 335         my ($param) = @_;
 336
 337         my $vmid = $param->{vmid};
 338
 339         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 340
 341         print "Entering Qemu Monitor for VM $vmid - type 'help' for help\n";
 342
 343         my $term = new Term::ReadLine ('qm');
 344
 345         my $input;
 346         while (defined ($input = $term->readline('qm> '))) {
 347             chomp $input;
 348
 349             next if $input =~ m/^\s*$/;
 350
 351             last if $input =~ m/^\s*q(uit)?\s*$/;
 352
 353             eval {
 354                 print PVE::QemuServer::vm_human_monitor_command ($vmid, $input);
 355             };
 356             print "ERROR: $@" if $@;
 357         }
 358
 359         return undef;
 360
 361     }});
 362
 363 __PACKAGE__->register_method ({
 364     name => 'rescan',
 365     path => 'rescan',
 366     method => 'POST',
 367     description => "Rescan all storages and update disk sizes and unused disk images.",
 368     parameters => {
 369         additionalProperties => 0,
 370         properties => {
 371             vmid => get_standard_option('pve-vmid', {
 372                 optional => 1,
 373                 completion => \&PVE::QemuServer::complete_vmid,
 374             }),
 375         },
 376     },
 377     returns => { type => 'null'},
 378     code => sub {
 379         my ($param) = @_;
 380
 381         PVE::QemuServer::rescan($param->{vmid});
 382
 383         return undef;
 384     }});
 385
 386 __PACKAGE__->register_method ({
 387     name => 'importdisk',
 388     path => 'importdisk',
 389     method => 'POST',
 390     description => "Import an external disk image as an unused disk in a VM. The
 391  image format has to be supported by qemu-img(1).",
 392     parameters => {
 393         additionalProperties => 0,
 394         properties => {
 395             vmid => get_standard_option('pve-vmid', {completion => \&PVE::QemuServer::complete_vmid}),
 396             source => {
 397                 description => 'Path to the disk image to import',
 398                 type => 'string',
 399                 optional => 0,
 400             },
 401             storage => get_standard_option('pve-storage-id', {
 402                 description => 'Target storage ID',
 403                 completion => \&PVE::QemuServer::complete_storage,
 404                 optional => 0,
 405             }),
 406             format => {
 407                 type => 'string',
 408                 description => 'Target format',
 409                 enum => [ 'raw', 'qcow2', 'vmdk' ],
 410                 optional => 1,
 411             },
 412         },
 413     },
 414     returns => { type => 'null'},
 415     code => sub {
 416         my ($param) = @_;
 417
 418         my $vmid = extract_param($param, 'vmid');
 419         my $source = extract_param($param, 'source');
 420         my $storeid = extract_param($param, 'storage');
 421         my $format = extract_param($param, 'format');
 422
 423         my $vm_conf = PVE::QemuConfig->load_config($vmid);
 424         PVE::QemuConfig->check_lock($vm_conf);
 425         die "$source: non-existent or non-regular file\n" if (! -f $source);
 426
 427         my $storecfg = PVE::Storage::config();
 428         PVE::Storage::storage_check_enabled($storecfg, $storeid);
 429
 430         my $target_storage_config =
 431             PVE::Storage::storage_config($storecfg, $storeid);
 432         die "storage $storeid does not support vm images\n"
 433             if !$target_storage_config->{content}->{images};
 434
 435         PVE::QemuServer::ImportDisk::do_import($source, $vmid, $storeid, { format => $format });
 436
 437         return undef;
 438     }});
 439
 440 __PACKAGE__->register_method ({
 441     name => 'terminal',
 442     path => 'terminal',
 443     method => 'POST',
 444     description => "Open a terminal using a serial device (The VM need to have a serial device configured, for example 'serial0: socket')",
 445     parameters => {
 446         additionalProperties => 0,
 447         properties => {
 448             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 449             iface => {
 450                 description => "Select the serial device. By default we simply use the first suitable device.",
 451                 type => 'string',
 452                 optional => 1,
 453                 enum => [qw(serial0 serial1 serial2 serial3)],
 454             }
 455         },
 456     },
 457     returns => { type => 'null'},
 458     code => sub {
 459         my ($param) = @_;
 460
 461         my $vmid = $param->{vmid};
 462
 463         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 464
 465         my $iface = $param->{iface};
 466
 467         if ($iface) {
 468             die "serial interface '$iface' is not configured\n" if !$conf->{$iface};
 469             die "wrong serial type on interface '$iface'\n" if $conf->{$iface} ne 'socket';
 470         } else {
 471             foreach my $opt (qw(serial0 serial1 serial2 serial3)) {
 472                 if ($conf->{$opt} && ($conf->{$opt} eq 'socket')) {
 473                     $iface = $opt;
 474                     last;
 475                 }
 476             }
 477             die "unable to find a serial interface\n" if !$iface;
 478         }
 479
 480         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
 481
 482         my $socket = "/var/run/qemu-server/${vmid}.$iface";
 483
 484         my $cmd = "socat UNIX-CONNECT:$socket STDIO,raw,echo=0,escape=0x0f";
 485
 486         print "starting serial terminal on interface $iface (press control-O to exit)\n";
 487
 488         system($cmd);
 489
 490         return undef;
 491     }});
 492
 493
 494 my $print_agent_result = sub {
 495     my ($data) = @_;
 496
 497     my $result = $data->{result};
 498     return if !defined($result);
 499
 500     my $class = ref($result);
 501
 502     if (!$class) {
 503         chomp $result;
 504         return if $result =~ m/^\s*$/;
 505         print "$result\n";
 506         return;
 507     }
 508
 509     if (($class eq 'HASH') && !scalar(keys %$result)) { # empty hash
 510         return;
 511     }
 512
 513     print to_json($result, { pretty => 1, canonical => 1});
 514 };
 515
 516 our $cmddef = {
 517     list => [ "PVE::API2::Qemu", 'vmlist', [],
 518              { node => $nodename }, sub {
 519                  my $vmlist = shift;
 520
 521                  exit 0 if (!scalar(@$vmlist));
 522
 523                  printf "%10s %-20s %-10s %-10s %12s %-10s\n",
 524                  qw(VMID NAME STATUS MEM(MB) BOOTDISK(GB) PID);
 525
 526                  foreach my $rec (sort { $a->{vmid} <=> $b->{vmid} } @$vmlist) {
 527                      printf "%10s %-20s %-10s %-10s %12.2f %-10s\n", $rec->{vmid}, $rec->{name},
 528                      $rec->{qmpstatus} || $rec->{status},
 529                      ($rec->{maxmem} || 0)/(1024*1024),
 530                      ($rec->{maxdisk} || 0)/(1024*1024*1024),
 531                      $rec->{pid}||0;
 532                  }
 533
 534
 535               } ],
 536
 537     create => [ "PVE::API2::Qemu", 'create_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 538
 539     destroy => [ "PVE::API2::Qemu", 'destroy_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 540
 541     clone => [ "PVE::API2::Qemu", 'clone_vm', ['vmid', 'newid'], { node => $nodename }, $upid_exit ],
 542
 543     migrate => [ "PVE::API2::Qemu", 'migrate_vm', ['vmid', 'target'], { node => $nodename }, $upid_exit ],
 544
 545     set => [ "PVE::API2::Qemu", 'update_vm', ['vmid'], { node => $nodename } ],
 546
 547     resize => [ "PVE::API2::Qemu", 'resize_vm', ['vmid', 'disk', 'size'], { node => $nodename } ],
 548
 549     move_disk => [ "PVE::API2::Qemu", 'move_vm_disk', ['vmid', 'disk', 'storage'], { node => $nodename }, $upid_exit ],
 550
 551     unlink => [ "PVE::API2::Qemu", 'unlink', ['vmid'], { node => $nodename } ],
 552
 553     config => [ "PVE::API2::Qemu", 'vm_config', ['vmid'],
 554                 { node => $nodename }, sub {
 555                     my $config = shift;
 556                     foreach my $k (sort (keys %$config)) {
 557                         next if $k eq 'digest';
 558                         my $v = $config->{$k};
 559                         if ($k eq 'description') {
 560                             $v = PVE::Tools::encode_text($v);
 561                         }
 562                         print "$k: $v\n";
 563                     }
 564                 }],
 565
 566     pending => [ "PVE::API2::Qemu", 'vm_pending', ['vmid'],
 567                 { node => $nodename }, sub {
 568                     my $data = shift;
 569                     foreach my $item (sort { $a->{key} cmp $b->{key}} @$data) {
 570                         my $k = $item->{key};
 571                         next if $k eq 'digest';
 572                         my $v = $item->{value};
 573                         my $p = $item->{pending};
 574                         if ($k eq 'description') {
 575                             $v = PVE::Tools::encode_text($v) if defined($v);
 576                             $p = PVE::Tools::encode_text($p) if defined($p);
 577                         }
 578                         if (defined($v)) {
 579                             if ($item->{delete}) {
 580                                 print "del $k: $v\n";
 581                             } elsif (defined($p)) {
 582                                 print "cur $k: $v\n";
 583                                 print "new $k: $p\n";
 584                             } else {
 585                                 print "cur $k: $v\n";
 586                             }
 587                         } elsif (defined($p)) {
 588                             print "new $k: $p\n";
 589                         }
 590                     }
 591                 }],
 592
 593     showcmd => [ __PACKAGE__, 'showcmd', ['vmid']],
 594
 595     status => [ __PACKAGE__, 'status', ['vmid']],
 596
 597     snapshot => [ "PVE::API2::Qemu", 'snapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 598
 599     delsnapshot => [ "PVE::API2::Qemu", 'delsnapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 600
 601     listsnapshot => [ "PVE::API2::Qemu", 'snapshot_list', ['vmid'], { node => $nodename },
 602                     sub {
 603                         my $res = shift;
 604                         foreach my $e (@$res) {
 605                             my $headline = $e->{description} || 'no-description';
 606                             $headline =~ s/\n.*//sg;
 607                             my $parent = $e->{parent} // 'no-parent';
 608                             printf("%-20s %-20s %s\n", $e->{name}, $parent, $headline);
 609                         }
 610                     }],
 611
 612     rollback => [ "PVE::API2::Qemu", 'rollback', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 613
 614     template => [ "PVE::API2::Qemu", 'template', ['vmid'], { node => $nodename }],
 615
 616     start => [ "PVE::API2::Qemu", 'vm_start', ['vmid'], { node => $nodename } , $upid_exit ],
 617
 618     stop => [ "PVE::API2::Qemu", 'vm_stop', ['vmid'], { node => $nodename }, $upid_exit ],
 619
 620     reset => [ "PVE::API2::Qemu", 'vm_reset', ['vmid'], { node => $nodename }, $upid_exit ],
 621
 622     shutdown => [ "PVE::API2::Qemu", 'vm_shutdown', ['vmid'], { node => $nodename }, $upid_exit ],
 623
 624     suspend => [ "PVE::API2::Qemu", 'vm_suspend', ['vmid'], { node => $nodename }, $upid_exit ],
 625
 626     resume => [ "PVE::API2::Qemu", 'vm_resume', ['vmid'], { node => $nodename }, $upid_exit ],
 627
 628     sendkey => [ "PVE::API2::Qemu", 'vm_sendkey', ['vmid', 'key'], { node => $nodename } ],
 629
 630     vncproxy => [ __PACKAGE__, 'vncproxy', ['vmid']],
 631
 632     wait => [ __PACKAGE__, 'wait', ['vmid']],
 633
 634     unlock => [ __PACKAGE__, 'unlock', ['vmid']],
 635
 636     rescan  => [ __PACKAGE__, 'rescan', []],
 637
 638     monitor  => [ __PACKAGE__, 'monitor', ['vmid']],
 639
 640     agent  => [ "PVE::API2::Qemu", 'agent', ['vmid', 'command'],
 641                 { node => $nodename }, $print_agent_result ],
 642
 643     mtunnel => [ __PACKAGE__, 'mtunnel', []],
 644
 645     nbdstop => [ __PACKAGE__, 'nbdstop', ['vmid']],
 646
 647     terminal => [ __PACKAGE__, 'terminal', ['vmid']],
 648
 649     importdisk => [ __PACKAGE__, 'importdisk', ['vmid', 'source', 'storage']],
 650 };
 651
 652 1;