PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $ssh_forward_info) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$ssh_forward_info) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if (my $unix_sockets = $tunnel->{unix_sockets}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @$unix_sockets];
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     PVE::QemuConfig->check_lock($conf);
 224
 225     my $running = 0;
 226     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 227         die "can't migrate running VM without --online\n" if !$online;
 228         $running = $pid;
 229
 230         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 231
 232         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 233         # Since the parameter itself contains no reference to a custom model,
 234         # this makes migration independent of changes to "cpu-models.conf".
 235         if ($conf->{cpu}) {
 236             my $cpuconf = PVE::QemuServer::CPUConfig::parse_cpu_conf_basic($conf->{cpu});
 237             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 238                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 239             }
 240         }
 241     }
 242
 243     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 244     if (scalar @$loc_res) {
 245         if ($self->{running} || !$self->{opts}->{force}) {
 246             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 247         } else {
 248             $self->log('info', "migrating VM which uses local devices");
 249         }
 250     }
 251
 252     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 253
 254     my $need_activate = [];
 255     foreach my $volid (@$vollist) {
 256         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 257
 258         # check if storage is available on both nodes
 259         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 260
 261         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 262         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 263
 264         if ($scfg->{shared}) {
 265             # PVE::Storage::activate_storage checks this for non-shared storages
 266             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 267             warn "Used shared storage '$sid' is not online on source node!\n"
 268                 if !$plugin->check_connection($sid, $scfg);
 269         } else {
 270             # only activate if not shared
 271             next if ($volid =~ m/vm-\d+-cloudinit/);
 272             push @$need_activate, $volid;
 273         }
 274     }
 275
 276     # activate volumes
 277     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 278
 279     # test ssh connection
 280     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 281     eval { $self->cmd_quiet($cmd); };
 282     die "Can't connect to destination address using public key\n" if $@;
 283
 284     return $running;
 285 }
 286
 287 sub sync_disks {
 288     my ($self, $vmid) = @_;
 289
 290     my $conf = $self->{vmconf};
 291
 292     # local volumes which have been copied
 293     # and their old_id => new_id pairs
 294     $self->{volumes} = [];
 295     $self->{volume_map} = {};
 296
 297     my $storecfg = $self->{storecfg};
 298     eval {
 299
 300         # found local volumes and their origin
 301         my $local_volumes = {};
 302         my $local_volumes_errors = {};
 303         my $other_errors = [];
 304         my $abort = 0;
 305
 306         my $log_error = sub {
 307             my ($msg, $volid) = @_;
 308
 309             if (defined($volid)) {
 310                 $local_volumes_errors->{$volid} = $msg;
 311             } else {
 312                 push @$other_errors, $msg;
 313             }
 314             $abort = 1;
 315         };
 316
 317         my @sids = PVE::Storage::storage_ids($storecfg);
 318         foreach my $storeid (@sids) {
 319             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 320             next if $scfg->{shared};
 321             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 322
 323             # get list from PVE::Storage (for unused volumes)
 324             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 325
 326             next if @{$dl->{$storeid}} == 0;
 327
 328             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 329             # check if storage is available on target node
 330             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 331
 332             # grandfather in existing mismatches
 333             if ($targetsid ne $storeid) {
 334                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 335                 die "content type 'images' is not available on storage '$targetsid'\n"
 336                     if !$target_scfg->{content}->{images};
 337             }
 338
 339             PVE::Storage::foreach_volid($dl, sub {
 340                 my ($volid, $sid, $volinfo) = @_;
 341
 342                 $local_volumes->{$volid}->{ref} = 'storage';
 343
 344                 # If with_snapshots is not set for storage migrate, it tries to use
 345                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 346                 # back to qcow2 is currently not possible.
 347                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 348                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 349             });
 350         }
 351
 352         my $rep_cfg = PVE::ReplicationConfig->new();
 353         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 354         my $replicatable_volumes = !$replication_jobcfg ? {}
 355             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 356
 357         my $test_volid = sub {
 358             my ($volid, $attr) = @_;
 359
 360             if ($volid =~ m|^/|) {
 361                 return if $attr->{shared};
 362                 $local_volumes->{$volid}->{ref} = 'config';
 363                 die "local file/device\n";
 364             }
 365
 366             my $snaprefs = $attr->{referenced_in_snapshot};
 367
 368             if ($attr->{cdrom}) {
 369                 if ($volid eq 'cdrom') {
 370                     my $msg = "can't migrate local cdrom drive";
 371                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 372                         my $snapnames = join(', ', sort keys %$snaprefs);
 373                         $msg .= " (referenced in snapshot - $snapnames)";
 374                     }
 375                     &$log_error("$msg\n");
 376                     return;
 377                 }
 378                 return if $volid eq 'none';
 379             }
 380
 381             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 382
 383             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 384             # check if storage is available on both nodes
 385             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 386             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 387
 388             return if $scfg->{shared};
 389
 390             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 391             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 392
 393             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 394
 395             if ($attr->{cdrom}) {
 396                 if ($volid =~ /vm-\d+-cloudinit/) {
 397                     $local_volumes->{$volid}->{ref} = 'generated';
 398                     return;
 399                 }
 400                 die "local cdrom image\n";
 401             }
 402
 403             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 404
 405             die "owned by other VM (owner = VM $owner)\n"
 406                 if !$owner || ($owner != $vmid);
 407
 408             return if $attr->{is_vmstate};
 409
 410             if (defined($snaprefs)) {
 411                 $local_volumes->{$volid}->{snapshots} = 1;
 412
 413                 # we cannot migrate shapshots on local storage
 414                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 415
 416                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 417                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 418                     die "non-migratable snapshot exists\n";
 419                 }
 420             }
 421
 422             die "referenced by linked clone(s)\n"
 423                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 424         };
 425
 426         PVE::QemuServer::foreach_volid($conf, sub {
 427             my ($volid, $attr) = @_;
 428             eval { $test_volid->($volid, $attr); };
 429             if (my $err = $@) {
 430                 &$log_error($err, $volid);
 431             }
 432         });
 433
 434         foreach my $vol (sort keys %$local_volumes) {
 435             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 436             my $ref = $local_volumes->{$vol}->{ref};
 437             if ($ref eq 'storage') {
 438                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 439             } elsif ($ref eq 'config') {
 440                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 441                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 442                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 443             } elsif ($ref eq 'snapshot') {
 444                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 445             } elsif ($ref eq 'generated') {
 446                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 447             } else {
 448                 $self->log('info', "found $type disk '$vol'\n");
 449             }
 450         }
 451
 452         foreach my $vol (sort keys %$local_volumes_errors) {
 453             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 454         }
 455         foreach my $err (@$other_errors) {
 456             $self->log('warn', "$err");
 457         }
 458
 459         if ($abort) {
 460             die "can't migrate VM - check log\n";
 461         }
 462
 463         # additional checks for local storage
 464         foreach my $volid (keys %$local_volumes) {
 465             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 466             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 467
 468             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 469
 470             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 471                 if !$migratable;
 472
 473             # image is a linked clone on local storage, se we can't migrate.
 474             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 475                 die "can't migrate '$volid' as it's a clone of '$basename'";
 476             }
 477         }
 478
 479         if ($replication_jobcfg) {
 480             if ($self->{running}) {
 481
 482                 my $version = PVE::QemuServer::kvm_user_version();
 483                 if (!min_version($version, 4, 2)) {
 484                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 485                 }
 486
 487                 my $live_replicatable_volumes = {};
 488                 PVE::QemuConfig->foreach_volume($conf, sub {
 489                     my ($ds, $drive) = @_;
 490
 491                     my $volid = $drive->{file};
 492                     $live_replicatable_volumes->{$ds} = $volid
 493                         if defined($replicatable_volumes->{$volid});
 494                 });
 495                 foreach my $drive (keys %$live_replicatable_volumes) {
 496                     my $volid = $live_replicatable_volumes->{$drive};
 497
 498                     my $bitmap = "repl_$drive";
 499
 500                     # start tracking before replication to get full delta + a few duplicates
 501                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 502                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 503
 504                     # other info comes from target node in phase 2
 505                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 506                 }
 507             }
 508             $self->log('info', "replicating disk images");
 509
 510             my $start_time = time();
 511             my $logfunc = sub { $self->log('info', shift) };
 512             $self->{replicated_volumes} = PVE::Replication::run_replication(
 513                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 514         }
 515
 516         # sizes in config have to be accurate for remote node to correctly
 517         # allocate disks, rescan to be sure
 518         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 519         PVE::QemuConfig->foreach_volume($conf, sub {
 520             my ($key, $drive) = @_;
 521             return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 522
 523             my $volid = $drive->{file};
 524             return if !defined($local_volumes->{$volid}); # only update sizes for local volumes
 525             return if !defined($volid_hash->{$volid});
 526
 527             my ($updated, $msg) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash->{$volid}->{size});
 528             if (defined($updated)) {
 529                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 530                 $self->log('info', "drive '$key': $msg");
 531             }
 532         });
 533
 534         # we want to set the efidisk size in the config to the size of the
 535         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 536         if (defined($conf->{efidisk0})) {
 537             PVE::QemuServer::update_efidisk_size($conf);
 538         }
 539
 540         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 541
 542         foreach my $volid (keys %$local_volumes) {
 543             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 544             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 545             my $ref = $local_volumes->{$volid}->{ref};
 546             if ($self->{running} && $ref eq 'config') {
 547                 push @{$self->{online_local_volumes}}, $volid;
 548             } elsif ($ref eq 'generated') {
 549                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 550                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 551                 push @{$self->{volumes}}, $volid;
 552                 next;
 553             } else {
 554                 next if $self->{replicated_volumes}->{$volid};
 555                 push @{$self->{volumes}}, $volid;
 556                 my $opts = $self->{opts};
 557                 # use 'migrate' limit for transfer to other node
 558                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 559                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 560                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 561
 562                 my $storage_migrate_opts = {
 563                     'bwlimit' => $bwlimit,
 564                     'insecure' => $opts->{migration_type} eq 'insecure',
 565                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 566                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 567                 };
 568
 569                 my $logfunc = sub { $self->log('info', $_[0]); };
 570                 my $new_volid = eval {
 571                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 572                                                   $targetsid, $storage_migrate_opts, $logfunc);
 573                 };
 574                 if (my $err = $@) {
 575                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 576                 }
 577
 578                 $self->{volume_map}->{$volid} = $new_volid;
 579                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 580             }
 581         }
 582     };
 583     die "Failed to sync data - $@" if $@;
 584 }
 585
 586 sub cleanup_remotedisks {
 587     my ($self) = @_;
 588
 589     foreach my $target_drive (keys %{$self->{target_drive}}) {
 590         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 591         next if !defined($drivestr);
 592
 593         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 594
 595         # don't clean up replicated disks!
 596         next if defined($self->{replicated_volumes}->{$drive->{file}});
 597
 598         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 599
 600         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 601
 602         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 603         if (my $err = $@) {
 604             $self->log('err', $err);
 605             $self->{errors} = 1;
 606         }
 607     }
 608 }
 609
 610 sub cleanup_bitmaps {
 611     my ($self) = @_;
 612     foreach my $drive (keys %{$self->{target_drive}}) {
 613         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 614         next if !$bitmap;
 615         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 616         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 617     }
 618 }
 619
 620 sub phase1 {
 621     my ($self, $vmid) = @_;
 622
 623     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 624
 625     my $conf = $self->{vmconf};
 626
 627     # set migrate lock in config file
 628     $conf->{lock} = 'migrate';
 629     PVE::QemuConfig->write_config($vmid, $conf);
 630
 631     sync_disks($self, $vmid);
 632
 633     # sync_disks fixes disk sizes to match their actual size, write changes so
 634     # target allocates correct volumes
 635     PVE::QemuConfig->write_config($vmid, $conf);
 636 };
 637
 638 sub phase1_cleanup {
 639     my ($self, $vmid, $err) = @_;
 640
 641     $self->log('info', "aborting phase 1 - cleanup resources");
 642
 643     my $conf = $self->{vmconf};
 644     delete $conf->{lock};
 645     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 646     if (my $err = $@) {
 647         $self->log('err', $err);
 648     }
 649
 650     if ($self->{volumes}) {
 651         foreach my $volid (@{$self->{volumes}}) {
 652             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 653             # fixme: try to remove ?
 654         }
 655     }
 656
 657     eval { $self->cleanup_bitmaps() };
 658     if (my $err =$@) {
 659         $self->log('err', $err);
 660     }
 661
 662 }
 663
 664 sub phase2 {
 665     my ($self, $vmid) = @_;
 666
 667     my $conf = $self->{vmconf};
 668
 669     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 670
 671     my $raddr;
 672     my $rport;
 673     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 674     my $nodename = PVE::INotify::nodename();
 675
 676     ## start on remote node
 677     my $cmd = [@{$self->{rem_ssh}}];
 678
 679     my $spice_ticket;
 680     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 681         my $res = mon_cmd($vmid, 'query-spice');
 682         $spice_ticket = $res->{ticket};
 683     }
 684
 685     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 686
 687     my $migration_type = $self->{opts}->{migration_type};
 688
 689     push @$cmd, '--migration_type', $migration_type;
 690
 691     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 692       if $self->{opts}->{migration_network};
 693
 694     if ($migration_type eq 'insecure') {
 695         push @$cmd, '--stateuri', 'tcp';
 696     } else {
 697         push @$cmd, '--stateuri', 'unix';
 698     }
 699
 700     if ($self->{forcemachine}) {
 701         push @$cmd, '--machine', $self->{forcemachine};
 702     }
 703
 704     if ($self->{forcecpu}) {
 705         push @$cmd, '--force-cpu', $self->{forcecpu};
 706     }
 707
 708     if ($self->{online_local_volumes}) {
 709         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 710     }
 711
 712     my $spice_port;
 713     my $unix_socket_info = {};
 714     # version > 0 for unix socket support
 715     my $nbd_protocol_version = 1;
 716     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 717     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 718     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 719
 720     my $number_of_online_replicated_volumes = 0;
 721
 722     # prevent auto-vivification
 723     if ($self->{online_local_volumes}) {
 724         foreach my $volid (@{$self->{online_local_volumes}}) {
 725             next if !$self->{replicated_volumes}->{$volid};
 726             $number_of_online_replicated_volumes++;
 727             $input .= "replicated_volume: $volid\n";
 728         }
 729     }
 730
 731     my $target_replicated_volumes = {};
 732
 733     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 734     # instead we pipe it through STDIN
 735     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 736         my $line = shift;
 737
 738         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 739             $raddr = $1;
 740             $rport = int($2);
 741             $ruri = "tcp:$raddr:$rport";
 742         }
 743         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 744             $raddr = $1;
 745             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 746             $ruri = "unix:$raddr";
 747         }
 748         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 749             $raddr = "localhost";
 750             $rport = int($1);
 751             $ruri = "tcp:$raddr:$rport";
 752         }
 753         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 754             $spice_port = int($1);
 755         }
 756         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 757             my $drivestr = $4;
 758             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 759             my $targetdrive = $3;
 760             $targetdrive =~ s/drive-//g;
 761
 762             $self->{stopnbd} = 1;
 763             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 764             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 765         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 766             my $drivestr = $4;
 767             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 768             my $nbd_unix_addr = $1;
 769             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 770             my $targetdrive = $3;
 771             $targetdrive =~ s/drive-//g;
 772
 773             $self->{stopnbd} = 1;
 774             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 775             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 776             $unix_socket_info->{$nbd_unix_addr} = 1;
 777         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 778             my $drive = $1;
 779             my $volid = $2;
 780             $target_replicated_volumes->{$volid} = $drive;
 781         } elsif ($line =~ m/^QEMU: (.*)$/) {
 782             $self->log('info', "[$self->{node}] $1\n");
 783         }
 784     }, errfunc => sub {
 785         my $line = shift;
 786         $self->log('info', "[$self->{node}] $line");
 787     }, noerr => 1);
 788
 789     die "remote command failed with exit code $exitcode\n" if $exitcode;
 790
 791     die "unable to detect remote migration address\n" if !$raddr;
 792
 793     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 794         die "number of replicated disks on source and target node do not match - target node too old?\n"
 795     }
 796
 797     $self->log('info', "start remote tunnel");
 798
 799     if ($migration_type eq 'secure') {
 800
 801         if ($ruri =~ /^unix:/) {
 802             my $ssh_forward_info = ["$raddr:$raddr"];
 803             $unix_socket_info->{$raddr} = 1;
 804
 805             my $unix_sockets = [ keys %$unix_socket_info ];
 806             for my $sock (@$unix_sockets) {
 807                 push @$ssh_forward_info, "$sock:$sock";
 808                 unlink $sock;
 809             }
 810
 811             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 812
 813             my $unix_socket_try = 0; # wait for the socket to become ready
 814             while ($unix_socket_try <= 100) {
 815                 $unix_socket_try++;
 816                 my $available = 0;
 817                 foreach my $sock (@$unix_sockets) {
 818                     if (-S $sock) {
 819                         $available++;
 820                     }
 821                 }
 822
 823                 if ($available == @$unix_sockets) {
 824                     last;
 825                 }
 826
 827                 usleep(50000);
 828             }
 829             if ($unix_socket_try > 100) {
 830                 $self->{errors} = 1;
 831                 $self->finish_tunnel($self->{tunnel});
 832                 die "Timeout, migration socket $ruri did not get ready";
 833             }
 834             $self->{tunnel}->{unix_sockets} = $unix_sockets if (@$unix_sockets);
 835
 836         } elsif ($ruri =~ /^tcp:/) {
 837             my $ssh_forward_info = [];
 838             if ($raddr eq "localhost") {
 839                 # for backwards compatibility with older qemu-server versions
 840                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 841                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 842                 push @$ssh_forward_info, "$lport:localhost:$rport";
 843             }
 844
 845             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 846
 847         } else {
 848             die "unsupported protocol in migration URI: $ruri\n";
 849         }
 850     } else {
 851         #fork tunnel for insecure migration, to send faster commands like resume
 852         $self->{tunnel} = $self->fork_tunnel();
 853     }
 854     my $start = time();
 855
 856     my $opt_bwlimit = $self->{opts}->{bwlimit};
 857
 858     if (defined($self->{online_local_volumes})) {
 859         $self->{storage_migration} = 1;
 860         $self->{storage_migration_jobs} = {};
 861         $self->log('info', "starting storage migration");
 862
 863         die "The number of local disks does not match between the source and the destination.\n"
 864             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 865         foreach my $drive (keys %{$self->{target_drive}}){
 866             my $target = $self->{target_drive}->{$drive};
 867             my $nbd_uri = $target->{nbd_uri};
 868
 869             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 870             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 871
 872             my $source_volid = $source_drive->{file};
 873             my $target_volid = $target_drive->{file};
 874
 875             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 876             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 877
 878             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 879             my $bitmap = $target->{bitmap};
 880
 881             $self->log('info', "$drive: start migration to $nbd_uri");
 882             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 883
 884             $self->{volume_map}->{$source_volid} = $target_volid;
 885             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 886         }
 887     }
 888
 889     $self->log('info', "starting online/live migration on $ruri");
 890     $self->{livemigration} = 1;
 891
 892     # load_defaults
 893     my $defaults = PVE::QemuServer::load_defaults();
 894
 895     $self->log('info', "set migration_caps");
 896     eval {
 897         PVE::QemuServer::set_migration_caps($vmid);
 898     };
 899     warn $@ if $@;
 900
 901     my $qemu_migrate_params = {};
 902
 903     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 904     # migrate_speed parameter in qm.conf - take the lower of the two.
 905     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 906     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 907     # migrate_speed is in MB/s, bwlimit in KB/s
 908     $migrate_speed *= 1024;
 909
 910     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 911
 912     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 913     # default of 8192m which is basically unlimited
 914     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 915
 916     # qmp takes migrate_speed in B/s.
 917     $migrate_speed *= 1024;
 918     $self->log('info', "migration speed limit: $migrate_speed B/s");
 919     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 920
 921     my $migrate_downtime = $defaults->{migrate_downtime};
 922     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 923     # migrate-set-parameters expects limit in ms
 924     $migrate_downtime *= 1000;
 925     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 926     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 927
 928     # set cachesize to 10% of the total memory
 929     my $memory =  $conf->{memory} || $defaults->{memory};
 930     my $cachesize = int($memory * 1048576 / 10);
 931     $cachesize = round_powerof2($cachesize);
 932
 933     $self->log('info', "migration cachesize: $cachesize B");
 934     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 935
 936     $self->log('info', "set migration parameters");
 937     eval {
 938         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 939     };
 940     $self->log('info', "migrate-set-parameters error: $@") if $@;
 941
 942     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 943         my $rpcenv = PVE::RPCEnvironment::get();
 944         my $authuser = $rpcenv->get_user();
 945
 946         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 947
 948         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 949         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 950
 951         $self->log('info', "spice client_migrate_info");
 952
 953         eval {
 954             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 955                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 956                                                 'cert-subject' => $subject);
 957         };
 958         $self->log('info', "client_migrate_info error: $@") if $@;
 959
 960     }
 961
 962     $self->log('info', "start migrate command to $ruri");
 963     eval {
 964         mon_cmd($vmid, "migrate", uri => $ruri);
 965     };
 966     my $merr = $@;
 967     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 968
 969     my $lstat = 0;
 970     my $usleep = 1000000;
 971     my $i = 0;
 972     my $err_count = 0;
 973     my $lastrem = undef;
 974     my $downtimecounter = 0;
 975     while (1) {
 976         $i++;
 977         my $avglstat = $lstat/$i if $lstat;
 978
 979         usleep($usleep);
 980         my $stat;
 981         eval {
 982             $stat = mon_cmd($vmid, "query-migrate");
 983         };
 984         if (my $err = $@) {
 985             $err_count++;
 986             warn "query migrate failed: $err\n";
 987             $self->log('info', "query migrate failed: $err");
 988             if ($err_count <= 5) {
 989                 usleep(1000000);
 990                 next;
 991             }
 992             die "too many query migrate failures - aborting\n";
 993         }
 994
 995         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 996             sleep(1);
 997             next;
 998         }
 999
1000         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
1001             $merr = undef;
1002             $err_count = 0;
1003             if ($stat->{status} eq 'completed') {
1004                 my $delay = time() - $start;
1005                 if ($delay > 0) {
1006                     my $mbps = sprintf "%.2f", $memory / $delay;
1007                     my $downtime = $stat->{downtime} || 0;
1008                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
1009                 }
1010             }
1011
1012             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
1013                 $self->log('info', "migration status error: $stat->{status}");
1014                 die "aborting\n"
1015             }
1016
1017             if ($stat->{status} ne 'active') {
1018                 $self->log('info', "migration status: $stat->{status}");
1019                 last;
1020             }
1021
1022             if ($stat->{ram}->{transferred} ne $lstat) {
1023                 my $trans = $stat->{ram}->{transferred} || 0;
1024                 my $rem = $stat->{ram}->{remaining} || 0;
1025                 my $total = $stat->{ram}->{total} || 0;
1026                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1027                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1028                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1029                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1030                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1031                 # reduce sleep if remainig memory is lower than the average transfer speed
1032                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1033
1034                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1035                            "remaining ${rem}), total ${total})");
1036
1037                 if (${xbzrlecachesize}) {
1038                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1039                 }
1040
1041                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1042                     $downtimecounter++;
1043                 }
1044                 $lastrem = $rem;
1045
1046                 if ($downtimecounter > 5) {
1047                     $downtimecounter = 0;
1048                     $migrate_downtime *= 2;
1049                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1050                     eval {
1051                         # migrate-set-parameters does not touch values not
1052                         # specified, so this only changes downtime-limit
1053                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1054                     };
1055                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1056                 }
1057
1058             }
1059
1060
1061             $lstat = $stat->{ram}->{transferred};
1062
1063         } else {
1064             die $merr if $merr;
1065             die "unable to parse migration status '$stat->{status}' - aborting\n";
1066         }
1067     }
1068 }
1069
1070 sub phase2_cleanup {
1071     my ($self, $vmid, $err) = @_;
1072
1073     return if !$self->{errors};
1074     $self->{phase2errors} = 1;
1075
1076     $self->log('info', "aborting phase 2 - cleanup resources");
1077
1078     $self->log('info', "migrate_cancel");
1079     eval {
1080         mon_cmd($vmid, "migrate_cancel");
1081     };
1082     $self->log('info', "migrate_cancel error: $@") if $@;
1083
1084     my $conf = $self->{vmconf};
1085     delete $conf->{lock};
1086     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1087     if (my $err = $@) {
1088         $self->log('err', $err);
1089     }
1090
1091     # cleanup ressources on target host
1092     if ($self->{storage_migration}) {
1093         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1094         if (my $err = $@) {
1095             $self->log('err', $err);
1096         }
1097     }
1098
1099     eval { $self->cleanup_bitmaps() };
1100     if (my $err =$@) {
1101         $self->log('err', $err);
1102     }
1103
1104     my $nodename = PVE::INotify::nodename();
1105
1106     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1107     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1108     if (my $err = $@) {
1109         $self->log('err', $err);
1110         $self->{errors} = 1;
1111     }
1112
1113     # cleanup after stopping, otherwise disks might be in-use by target VM!
1114     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1115     if (my $err = $@) {
1116         $self->log('err', $err);
1117     }
1118
1119
1120     if ($self->{tunnel}) {
1121         eval { finish_tunnel($self, $self->{tunnel});  };
1122         if (my $err = $@) {
1123             $self->log('err', $err);
1124             $self->{errors} = 1;
1125         }
1126     }
1127 }
1128
1129 sub phase3 {
1130     my ($self, $vmid) = @_;
1131
1132     my $volids = $self->{volumes};
1133     return if $self->{phase2errors};
1134
1135     # destroy local copies
1136     foreach my $volid (@$volids) {
1137         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1138         if (my $err = $@) {
1139             $self->log('err', "removing local copy of '$volid' failed - $err");
1140             $self->{errors} = 1;
1141             last if $err =~ /^interrupted by signal$/;
1142         }
1143     }
1144 }
1145
1146 sub phase3_cleanup {
1147     my ($self, $vmid, $err) = @_;
1148
1149     my $conf = $self->{vmconf};
1150     return if $self->{phase2errors};
1151
1152     my $tunnel = $self->{tunnel};
1153
1154     if ($self->{storage_migration}) {
1155         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1156         # to avoid it trying to re-establish it. We are in blockjob ready state,
1157         # thus, this command changes to it to blockjob complete (see qapi docs)
1158         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1159
1160         if (my $err = $@) {
1161             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1162             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1163             die "Failed to complete storage migration: $err\n";
1164         }
1165     }
1166
1167     if ($self->{volume_map}) {
1168         my $target_drives = $self->{target_drive};
1169
1170         # FIXME: for NBD storage migration we now only update the volid, and
1171         # not the full drivestr from the target node. Workaround that until we
1172         # got some real rescan, to avoid things like wrong format in the drive
1173         delete $conf->{$_} for keys %$target_drives;
1174         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1175
1176         for my $drive (keys %$target_drives) {
1177             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1178         }
1179         PVE::QemuConfig->write_config($vmid, $conf);
1180     }
1181
1182     # transfer replication state before move config
1183     $self->transfer_replication_state() if $self->{replicated_volumes};
1184
1185     # move config to remote node
1186     my $conffile = PVE::QemuConfig->config_file($vmid);
1187     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1188
1189     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1190         if !rename($conffile, $newconffile);
1191
1192     $self->switch_replication_job_target() if $self->{replicated_volumes};
1193
1194     if ($self->{livemigration}) {
1195         if ($self->{stopnbd}) {
1196             $self->log('info', "stopping NBD storage migration server on target.");
1197             # stop nbd server on remote vm - requirement for resume since 2.9
1198             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1199
1200             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1201             if (my $err = $@) {
1202                 $self->log('err', $err);
1203                 $self->{errors} = 1;
1204             }
1205         }
1206
1207         # config moved and nbd server stopped - now we can resume vm on target
1208         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1209             eval {
1210                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1211             };
1212             if (my $err = $@) {
1213                 $self->log('err', $err);
1214                 $self->{errors} = 1;
1215             }
1216         } else {
1217             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1218             my $logf = sub {
1219                 my $line = shift;
1220                 $self->log('err', $line);
1221             };
1222             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1223             if (my $err = $@) {
1224                 $self->log('err', $err);
1225                 $self->{errors} = 1;
1226             }
1227         }
1228
1229         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1230             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1231             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1232         }
1233     }
1234
1235     # close tunnel on successful migration, on error phase2_cleanup closed it
1236     if ($tunnel) {
1237         eval { finish_tunnel($self, $tunnel);  };
1238         if (my $err = $@) {
1239             $self->log('err', $err);
1240             $self->{errors} = 1;
1241         }
1242     }
1243
1244     eval {
1245         my $timer = 0;
1246         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1247             $self->log('info', "Waiting for spice server migration");
1248             while (1) {
1249                 my $res = mon_cmd($vmid, 'query-spice');
1250                 last if int($res->{'migrated'}) == 1;
1251                 last if $timer > 50;
1252                 $timer ++;
1253                 usleep(200000);
1254             }
1255         }
1256     };
1257
1258     # always stop local VM
1259     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1260     if (my $err = $@) {
1261         $self->log('err', "stopping vm failed - $err");
1262         $self->{errors} = 1;
1263     }
1264
1265     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1266     eval {
1267         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1268         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1269     };
1270     if (my $err = $@) {
1271         $self->log('err', $err);
1272         $self->{errors} = 1;
1273     }
1274
1275     if($self->{storage_migration}) {
1276         # destroy local copies
1277         my $volids = $self->{online_local_volumes};
1278
1279         foreach my $volid (@$volids) {
1280             # keep replicated volumes!
1281             next if $self->{replicated_volumes}->{$volid};
1282
1283             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1284             if (my $err = $@) {
1285                 $self->log('err', "removing local copy of '$volid' failed - $err");
1286                 $self->{errors} = 1;
1287                 last if $err =~ /^interrupted by signal$/;
1288             }
1289         }
1290
1291     }
1292
1293     # clear migrate lock
1294     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1295     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1296 }
1297
1298 sub final_cleanup {
1299     my ($self, $vmid) = @_;
1300
1301     # nothing to do
1302 }
1303
1304 sub round_powerof2 {
1305     return 1 if $_[0] < 2;
1306     return 2 << int(log($_[0]-1)/log(2));
1307 }
1308
1309 1;