[libgit2.git] / CMakeLists.txt

# CMake build script for the libgit2 project
#
# Building (out of source build):
# > mkdir build && cd build
# > cmake .. [-DSETTINGS=VALUE]
# > cmake --build .
#
# Testing:
# > ctest -V
#
# Install:
# > cmake --build . --target install

PROJECT(libgit2 C)
CMAKE_MINIMUM_REQUIRED(VERSION 2.6)

# Add find modules to the path
SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")

INCLUDE(CheckLibraryExists)
INCLUDE(AddCFlagIfSupported)

# Build options
#
OPTION( SONAME				"Set the (SO)VERSION of the target"		ON  )
OPTION( BUILD_SHARED_LIBS	"Build Shared Library (OFF for Static)"	ON  )
OPTION( THREADSAFE			"Build libgit2 as threadsafe"			OFF )
OPTION( BUILD_CLAR			"Build Tests using the Clar suite"		ON  )
OPTION( BUILD_EXAMPLES		"Build library usage example apps"		OFF )
OPTION( TAGS				"Generate tags"							OFF )
OPTION( PROFILE				"Generate profiling information"		OFF )
OPTION( ENABLE_TRACE		"Enables tracing support"				OFF )
OPTION( LIBGIT2_FILENAME	"Name of the produced binary"			OFF )

OPTION( ANDROID				"Build for android NDK"	 				OFF )

OPTION( USE_ICONV			"Link with and use iconv library" 		OFF )
OPTION( USE_SSH				"Link with libssh to enable SSH support" ON )
OPTION( VALGRIND			"Configure build for valgrind"			OFF )

IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
	SET( USE_ICONV ON )
ENDIF()

IF(MSVC)
	# This option is only available when building with MSVC. By default, libgit2
	# is build using the cdecl calling convention, which is useful if you're
	# writing C. However, the CLR and Win32 API both expect stdcall.
	#
	# If you are writing a CLR program and want to link to libgit2, you'll want
	# to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
	OPTION( STDCALL			"Build libgit2 with the __stdcall convention"	OFF  )

	# This option must match the settings used in your program, in particular if you
	# are linking statically
	OPTION( STATIC_CRT		"Link the static CRT libraries"	ON  )

	# By default, libgit2 is built with WinHTTP.  To use the built-in
	# HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
	OPTION( WINHTTP			"Use Win32 WinHTTP routines"	ON  )

	ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
	ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
	ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
ENDIF()

# This variable will contain the libraries we need to put into
# libgit2.pc's Requires.private. That is, what we're linking to or
# what someone who's statically linking us needs to link to.
SET(LIBGIT2_PC_REQUIRES "")
# This will be set later if we use the system's http-parser library or
# use iconv (OSX) and will be written to the Libs.private field in the
# pc file.
SET(LIBGIT2_PC_LIBS "")

# Installation paths
#
SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")

FUNCTION(TARGET_OS_LIBRARIES target)
	IF(WIN32)
		TARGET_LINK_LIBRARIES(${target} ws2_32)
	ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
		TARGET_LINK_LIBRARIES(${target} socket nsl)
		SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lsocket -lnsl" PARENT_SCOPE)
	ENDIF()
	CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
	IF(NEED_LIBRT)
		TARGET_LINK_LIBRARIES(${target} rt)
		SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lrt" PARENT_SCOPE)
	ENDIF()

	IF(THREADSAFE)
		TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
	ENDIF()
ENDFUNCTION()

# For the MSVC IDE, this function splits up the source files like windows
# explorer does. This is esp. useful with the libgit2_clar project, were
# usually 2 or more files share the same name.  Sadly, this file grouping
# is a per-directory option in cmake and not per-target, resulting in
# empty virtual folders "tests" for the git2.dll
FUNCTION(MSVC_SPLIT_SOURCES target)
	IF(MSVC_IDE)
		GET_TARGET_PROPERTY(sources ${target} SOURCES)
		FOREACH(source ${sources})
			IF(source MATCHES ".*/")
				STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
				IF(rel)
					STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
					IF(rel)
						STRING(REPLACE "/" "\\\\" rel ${rel})
						SOURCE_GROUP(${rel} FILES ${source})
					ENDIF()
				ENDIF()
			ENDIF()
		ENDFOREACH()
	ENDIF()
ENDFUNCTION()

FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")

STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"([0-9]+).*$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_MINOR  "${GIT2_HEADER}")
STRING(REGEX REPLACE "^.*LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).*$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")

# Find required dependencies
INCLUDE_DIRECTORIES(src include)

IF (WIN32 AND WINHTTP AND NOT MINGW)
	ADD_DEFINITIONS(-DGIT_WINHTTP)
	INCLUDE_DIRECTORIES(deps/http-parser)
	FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
ELSE ()
	IF (NOT AMIGA)
		FIND_PACKAGE(OpenSSL)
	ENDIF ()

	FIND_PACKAGE(HTTP_Parser)
	IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
		INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
		LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
		SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lhttp_parser")
	ELSE()
		MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
		INCLUDE_DIRECTORIES(deps/http-parser)
		FILE(GLOB SRC_HTTP deps/http-parser/*.c deps/http-parser/*.h)
	ENDIF()
ENDIF()

# Specify sha1 implementation
IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
	ADD_DEFINITIONS(-DWIN32_SHA1)
	FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
	ADD_DEFINITIONS(-DOPENSSL_SHA1)
	IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
		SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lssl")
	ELSE()
		SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
	ENDIF ()
ELSE()
	FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
ENDIF()

# Enable tracing
IF (ENABLE_TRACE STREQUAL "ON")
	ADD_DEFINITIONS(-DGIT_TRACE)
ENDIF()

# Include POSIX regex when it is required
IF(WIN32 OR AMIGA OR ANDROID OR CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
	INCLUDE_DIRECTORIES(deps/regex)
	SET(SRC_REGEX deps/regex/regex.c)
ENDIF()

# Optional external dependency: zlib
FIND_PACKAGE(ZLIB)
IF (ZLIB_FOUND)
	INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
	LINK_LIBRARIES(${ZLIB_LIBRARIES})
	IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
		SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lz")
	ELSE()
		SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
	ENDIF()
ELSE()
	MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
	INCLUDE_DIRECTORIES(deps/zlib)
	ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
	FILE(GLOB SRC_ZLIB deps/zlib/*.c deps/zlib/*.h)
ENDIF()

# Optional external dependency: libssh2
IF (USE_SSH)
	FIND_PACKAGE(LIBSSH2)
ENDIF()
IF (LIBSSH2_FOUND)
	ADD_DEFINITIONS(-DGIT_SSH)
	INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIR})
	SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} libssh2")
	SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
ENDIF()

# Optional external dependency: iconv
IF (USE_ICONV)
	FIND_PACKAGE(ICONV)
ENDIF()
IF (ICONV_FOUND)
	ADD_DEFINITIONS(-DGIT_USE_ICONV)
	INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${ICONV_LIBRARIES}")
ENDIF()

# Platform specific compilation flags
IF (MSVC)

	STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")

	# /GF - String pooling
	# /MP - Parallel build
	SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")

	IF (STDCALL)
		# /Gz - stdcall calling convention
		SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
	ENDIF ()

	IF (STATIC_CRT)
		SET(CRT_FLAG_DEBUG "/MTd")
		SET(CRT_FLAG_RELEASE "/MT")
	ELSE()
		SET(CRT_FLAG_DEBUG "/MDd")
		SET(CRT_FLAG_RELEASE "/MD")
	ENDIF()

	# /Zi - Create debugging information
	# /Od - Disable optimization
	# /D_DEBUG - #define _DEBUG
	# /MTd - Statically link the multithreaded debug version of the CRT
	# /MDd - Dynamically link the multithreaded debug version of the CRT
	# /RTC1 - Run time checks
	SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")

	# /DNDEBUG - Disables asserts
	# /MT - Statically link the multithreaded release version of the CRT
	# /MD - Dynamically link the multithreaded release version of the CRT
	# /O2 - Optimize for speed
	# /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
	# /GL - Link time code generation (whole program optimization)
	# /Gy - Function-level linking
	SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")

	# /Oy- - Disable frame pointer omission (FPO)
	SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")

	# /O1 - Optimize for size
	SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")

	# /DYNAMICBASE - Address space load randomization (ASLR)
	# /NXCOMPAT - Data execution prevention (DEP)
	# /LARGEADDRESSAWARE - >2GB user address space on x86
	# /VERSION - Embed version information in PE header
	SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")

	# /DEBUG - Create a PDB
	# /LTCG - Link time code generation (whole program optimization)
	# /OPT:REF /OPT:ICF - Fold out duplicate code at link step
	# /INCREMENTAL:NO - Required to use /LTCG
	# /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
	SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
	SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
	SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
	SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")

	# Same linker settings for DLL as EXE
	SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
	SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
	SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
	SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
	SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")

	SET(WIN_RC "src/win32/git2.rc")

   # Precompiled headers

ELSE ()
	SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")

	IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris|SunOS)")
		SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
	ENDIF()

	IF (WIN32 AND NOT CYGWIN)
		SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
	ENDIF ()

	IF (MINGW) # MinGW always does PIC and complains if we tell it to
		STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
		# MinGW >= 3.14 uses the C99-style stdio functions
		# automatically, but forks like mingw-w64 still want
		# us to define this in order to use them
		ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)

	ELSEIF (BUILD_SHARED_LIBS)
		ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)

		SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
	ENDIF ()

	ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
	ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
	ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
	ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
	ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
	ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)

	IF (APPLE) # Apple deprecated OpenSSL
		ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
	ENDIF()

	IF (PROFILE)
		SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
		SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
	ENDIF ()
ENDIF()

IF( NOT CMAKE_CONFIGURATION_TYPES )
	# Build Debug by default
	IF (NOT CMAKE_BUILD_TYPE)
		SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
	ENDIF ()
ELSE()
	# Using a multi-configuration generator eg MSVC or Xcode
	# that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
ENDIF()

IF (OPENSSL_FOUND)
  ADD_DEFINITIONS(-DGIT_SSL)
  INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
  SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
ENDIF()

IF (THREADSAFE)
	IF (NOT WIN32)
		FIND_PACKAGE(Threads REQUIRED)
	ENDIF()

	ADD_DEFINITIONS(-DGIT_THREADS)
ENDIF()

ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)

# Collect sourcefiles
FILE(GLOB SRC_H include/git2.h include/git2/*.h include/git2/sys/*.h)

# On Windows use specific platform sources
IF (WIN32 AND NOT CYGWIN)
	ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
	FILE(GLOB SRC_OS src/win32/*.c src/win32/*.h)
ELSEIF (AMIGA)
	ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
ELSE()
	IF (VALGRIND)
		ADD_DEFINITIONS(-DNO_MMAP)
	ENDIF()
	FILE(GLOB SRC_OS src/unix/*.c src/unix/*.h)
ENDIF()
FILE(GLOB SRC_GIT2 src/*.c src/*.h src/transports/*.c src/transports/*.h src/xdiff/*.c src/xdiff/*.h)

# Determine architecture of the machine
IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
	ADD_DEFINITIONS(-DGIT_ARCH_64)
ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
	ADD_DEFINITIONS(-DGIT_ARCH_32)
ELSE()
	MESSAGE(FATAL_ERROR "Unsupported architecture")
ENDIF()

# Compile and link libgit2
ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1} ${WIN_RC})
TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
TARGET_OS_LIBRARIES(git2)

# Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
# Win64+MSVC+static libs = linker error
IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
  SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
ENDIF()

MSVC_SPLIT_SOURCES(git2)

IF (SONAME)
	SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
	SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_VERSION_MAJOR})
	IF (LIBGIT2_FILENAME)
		ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
		SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
	ENDIF()
ENDIF()
CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)

IF (MSVC_IDE)
   # Precompiled headers
   SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
   SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
ENDIF ()

# Install
INSTALL(TARGETS git2
	RUNTIME DESTINATION ${BIN_INSTALL_DIR}
	LIBRARY DESTINATION ${LIB_INSTALL_DIR}
	ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
)
INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )

# Tests
IF (BUILD_CLAR)
	FIND_PACKAGE(PythonInterp REQUIRED)

	SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
	SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
	SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
	ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
	ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")

	INCLUDE_DIRECTORIES(${CLAR_PATH})
	FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}/*/*.c ${CLAR_PATH}/*/*.h)
	SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar.c")

	ADD_CUSTOM_COMMAND(
		OUTPUT ${CLAR_PATH}/clar.suite
		COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
		DEPENDS ${SRC_TEST}
		WORKING_DIRECTORY ${CLAR_PATH}
	)

	SET_SOURCE_FILES_PROPERTIES(
		${CLAR_PATH}/clar.c
		PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)

	ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1})

	TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
	TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
	TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
	TARGET_OS_LIBRARIES(libgit2_clar)
	MSVC_SPLIT_SOURCES(libgit2_clar)

	IF (MSVC_IDE)
		# Precompiled headers
		SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
	ENDIF ()

	ENABLE_TESTING()
	ADD_TEST(libgit2_clar libgit2_clar -ionline)
ENDIF ()

IF (TAGS)
	FIND_PROGRAM(CTAGS ctags)
	IF (NOT CTAGS)
		MESSAGE(FATAL_ERROR "Could not find ctags command")
	ENDIF ()

	FILE(GLOB_RECURSE SRC_ALL *.[ch])

	ADD_CUSTOM_COMMAND(
		OUTPUT tags
		COMMAND ${CTAGS} -a ${SRC_ALL}
		DEPENDS ${SRC_ALL}
	)
	ADD_CUSTOM_TARGET(
		do_tags ALL
		DEPENDS tags
	)
ENDIF ()

IF (BUILD_EXAMPLES)
	ADD_SUBDIRECTORY(examples)
ENDIF ()
Commit	Line	Data
583cf169	1	# CMake build script for the libgit2 project
73c46d53	2	#
bfe0658e	3	# Building (out of source build):
73c46d53	4	# > mkdir build && cd build
bfe0658e PD	5	# > cmake .. [-DSETTINGS=VALUE]
bfe0658e PD	6	# > cmake --build .
932d1baf	7	#
73c46d53 PD	8	# Testing:
	9	# > ctest -V
	10	#
	11	# Install:
bfe0658e	12	# > cmake --build . --target install
73c46d53	13
583cf169 PD	14	PROJECT(libgit2 C)
	15	CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
	16
7a6e0281	17	# Add find modules to the path
7f0de93a	18	SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
7369b3c3	19
5bda607c	20	INCLUDE(CheckLibraryExists)
5c8d5eac	21	INCLUDE(AddCFlagIfSupported)
5bda607c	22
19a766a2 SC	23	# Build options
19a766a2 SC	24	#
058956ce	25	OPTION( SONAME "Set the (SO)VERSION of the target" ON )
19a766a2 SC	26	OPTION( BUILD_SHARED_LIBS "Build Shared Library (OFF for Static)" ON )
	27	OPTION( THREADSAFE "Build libgit2 as threadsafe" OFF )
	28	OPTION( BUILD_CLAR "Build Tests using the Clar suite" ON )
	29	OPTION( BUILD_EXAMPLES "Build library usage example apps" OFF )
	30	OPTION( TAGS "Generate tags" OFF )
	31	OPTION( PROFILE "Generate profiling information" OFF )
b5ec5430	32	OPTION( ENABLE_TRACE "Enables tracing support" OFF )
92dac975	33	OPTION( LIBGIT2_FILENAME "Name of the produced binary" OFF )
c1cf1af4	34
92dac975 RB	35	OPTION( ANDROID "Build for android NDK" OFF )
	36
	37	OPTION( USE_ICONV "Link with and use iconv library" OFF )
73291aff	38	OPTION( USE_SSH "Link with libssh to enable SSH support" ON )
7697e541	39	OPTION( VALGRIND "Configure build for valgrind" OFF )
73291aff	40
726b75d1	41	IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
92dac975 RB	42	SET( USE_ICONV ON )
92dac975 RB	43	ENDIF()
82b2fc2c	44
19a766a2	45	IF(MSVC)
275d8d55	46	# This option is only available when building with MSVC. By default, libgit2
e49dc687 BS	47	# is build using the cdecl calling convention, which is useful if you're
e49dc687 BS	48	# writing C. However, the CLR and Win32 API both expect stdcall.
19a766a2	49	#
e49dc687 BS	50	# If you are writing a CLR program and want to link to libgit2, you'll want
	51	# to turn this on by invoking CMake with the "-DSTDCALL=ON" argument.
	52	OPTION( STDCALL "Build libgit2 with the __stdcall convention" OFF )
08f32085 Q	53
	54	# This option must match the settings used in your program, in particular if you
	55	# are linking statically
	56	OPTION( STATIC_CRT "Link the static CRT libraries" ON )
1bfe7133 ET	57
	58	# By default, libgit2 is built with WinHTTP. To use the built-in
	59	# HTTP transport, invoke CMake with the "-DWINHTTP=OFF" argument.
	60	OPTION( WINHTTP "Use Win32 WinHTTP routines" ON )
300f4412	61
6874cafd	62	ADD_DEFINITIONS(-D_SCL_SECURE_NO_WARNINGS)
300f4412 M	63	ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
300f4412 M	64	ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
19a766a2 SC	65	ENDIF()
19a766a2 SC	66
1ecda61e CMN	67	# This variable will contain the libraries we need to put into
	68	# libgit2.pc's Requires.private. That is, what we're linking to or
	69	# what someone who's statically linking us needs to link to.
	70	SET(LIBGIT2_PC_REQUIRES "")
	71	# This will be set later if we use the system's http-parser library or
	72	# use iconv (OSX) and will be written to the Libs.private field in the
	73	# pc file.
	74	SET(LIBGIT2_PC_LIBS "")
	75
19a766a2 SC	76	# Installation paths
	77	#
	78	SET(BIN_INSTALL_DIR bin CACHE PATH "Where to install binaries to.")
	79	SET(LIB_INSTALL_DIR lib CACHE PATH "Where to install libraries to.")
	80	SET(INCLUDE_INSTALL_DIR include CACHE PATH "Where to install headers to.")
	81
94243295 SC	82	FUNCTION(TARGET_OS_LIBRARIES target)
	83	IF(WIN32)
	84	TARGET_LINK_LIBRARIES(${target} ws2_32)
	85	ELSEIF(CMAKE_SYSTEM_NAME MATCHES "(Solaris\|SunOS)")
	86	TARGET_LINK_LIBRARIES(${target} socket nsl)
474c8cf8	87	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lsocket -lnsl" PARENT_SCOPE)
5bda607c TM	88	ENDIF()
	89	CHECK_LIBRARY_EXISTS(rt clock_gettime "time.h" NEED_LIBRT)
	90	IF(NEED_LIBRT)
b176eded	91	TARGET_LINK_LIBRARIES(${target} rt)
474c8cf8	92	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lrt" PARENT_SCOPE)
92dac975 RB	93	ENDIF()
92dac975 RB	94
94243295 SC	95	IF(THREADSAFE)
	96	TARGET_LINK_LIBRARIES(${target} ${CMAKE_THREAD_LIBS_INIT})
	97	ENDIF()
	98	ENDFUNCTION()
	99
d335e73a ET	100	# For the MSVC IDE, this function splits up the source files like windows
	101	# explorer does. This is esp. useful with the libgit2_clar project, were
	102	# usually 2 or more files share the same name. Sadly, this file grouping
	103	# is a per-directory option in cmake and not per-target, resulting in
83e1efbf	104	# empty virtual folders "tests" for the git2.dll
523a3ae5 SC	105	FUNCTION(MSVC_SPLIT_SOURCES target)
	106	IF(MSVC_IDE)
	107	GET_TARGET_PROPERTY(sources ${target} SOURCES)
	108	FOREACH(source ${sources})
	109	IF(source MATCHES ".*/")
	110	STRING(REPLACE ${CMAKE_CURRENT_SOURCE_DIR}/ "" rel ${source})
	111	IF(rel)
	112	STRING(REGEX REPLACE "/([^/]*)$" "" rel ${rel})
	113	IF(rel)
	114	STRING(REPLACE "/" "\\\\" rel ${rel})
	115	SOURCE_GROUP(${rel} FILES ${source})
	116	ENDIF()
	117	ENDIF()
	118	ENDIF()
	119	ENDFOREACH()
	120	ENDIF()
	121	ENDFUNCTION()
	122
96fab093	123	FILE(STRINGS "include/git2/version.h" GIT2_HEADER REGEX "^#define LIBGIT2_VERSION \"[^\"]*\"$")
9d1dcca2 VM	124
	125	STRING(REGEX REPLACE "^.LIBGIT2_VERSION \"([0-9]+).$" "\\1" LIBGIT2_VERSION_MAJOR "${GIT2_HEADER}")
	126	STRING(REGEX REPLACE "^.LIBGIT2_VERSION \"[0-9]+\\.([0-9]+).$" "\\1" LIBGIT2_VERSION_MINOR "${GIT2_HEADER}")
	127	STRING(REGEX REPLACE "^.LIBGIT2_VERSION \"[0-9]+\\.[0-9]+\\.([0-9]+).$" "\\1" LIBGIT2_VERSION_REV "${GIT2_HEADER}")
	128	SET(LIBGIT2_VERSION_STRING "${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}.${LIBGIT2_VERSION_REV}")
	129
7cbdaf7f	130	# Find required dependencies
8d457891	131	INCLUDE_DIRECTORIES(src include)
20e83aa4	132
1bfe7133	133	IF (WIN32 AND WINHTTP AND NOT MINGW)
3ce22c74	134	ADD_DEFINITIONS(-DGIT_WINHTTP)
2d1feaa2 BS	135	INCLUDE_DIRECTORIES(deps/http-parser)
2d1feaa2 BS	136	FILE(GLOB SRC_HTTP deps/http-parser/.c deps/http-parser/.h)
3ce22c74	137	ELSE ()
c57c4af3 SB	138	IF (NOT AMIGA)
	139	FIND_PACKAGE(OpenSSL)
	140	ENDIF ()
7a6e0281	141
04739e9f	142	FIND_PACKAGE(HTTP_Parser)
7a6e0281 VP	143	IF (HTTP_PARSER_FOUND AND HTTP_PARSER_VERSION_MAJOR EQUAL 2)
	144	INCLUDE_DIRECTORIES(${HTTP_PARSER_INCLUDE_DIRS})
	145	LINK_LIBRARIES(${HTTP_PARSER_LIBRARIES})
1ecda61e	146	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lhttp_parser")
7a6e0281	147	ELSE()
86f92b74	148	MESSAGE(STATUS "http-parser was not found or is too old; using bundled 3rd-party sources.")
7a6e0281	149	INCLUDE_DIRECTORIES(deps/http-parser)
cdacd3d9	150	FILE(GLOB SRC_HTTP deps/http-parser/.c deps/http-parser/.h)
7a6e0281	151	ENDIF()
3ce22c74	152	ENDIF()
20e83aa4	153
c3f7a938	154	# Specify sha1 implementation
8f09f464	155	IF (WIN32 AND NOT MINGW AND NOT SHA1_TYPE STREQUAL "builtin")
ccf1a2ba	156	ADD_DEFINITIONS(-DWIN32_SHA1)
ccf1a2ba	157	FILE(GLOB SRC_SHA1 src/hash/hash_win32.c)
d6fb0924 ET	158	ELSEIF (OPENSSL_FOUND AND NOT SHA1_TYPE STREQUAL "builtin")
d6fb0924 ET	159	ADD_DEFINITIONS(-DOPENSSL_SHA1)
096ac799 TWL	160	IF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
	161	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lssl")
	162	ELSE()
	163	SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} openssl")
	164	ENDIF ()
d6fb0924 ET	165	ELSE()
d6fb0924 ET	166	FILE(GLOB SRC_SHA1 src/hash/hash_generic.c)
c3f7a938 CY	167	ENDIF()
c3f7a938 CY	168
b5ec5430 ET	169	# Enable tracing
	170	IF (ENABLE_TRACE STREQUAL "ON")
	171	ADD_DEFINITIONS(-DGIT_TRACE)
	172	ENDIF()
	173
3d007f4f	174	# Include POSIX regex when it is required
98b8fcff	175	IF(WIN32 OR AMIGA OR ANDROID OR CMAKE_SYSTEM_NAME MATCHES "(Solaris\|SunOS)")
c17b1d00 CMN	176	INCLUDE_DIRECTORIES(deps/regex)
c17b1d00 CMN	177	SET(SRC_REGEX deps/regex/regex.c)
1f4f4d17	178	ENDIF()
f443a879	179
b53671ae	180	# Optional external dependency: zlib
04739e9f	181	FIND_PACKAGE(ZLIB)
1f4f4d17 TH	182	IF (ZLIB_FOUND)
	183	INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIRS})
	184	LINK_LIBRARIES(${ZLIB_LIBRARIES})
096ac799	185	IF(APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
474c8cf8 CMN	186	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} -lz")
	187	ELSE()
	188	SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} zlib")
	189	ENDIF()
c41281ad	190	ELSE()
86f92b74	191	MESSAGE(STATUS "zlib was not found; using bundled 3rd-party sources." )
1f4f4d17 TH	192	INCLUDE_DIRECTORIES(deps/zlib)
1f4f4d17 TH	193	ADD_DEFINITIONS(-DNO_VIZ -DSTDC -DNO_GZIP)
cdacd3d9	194	FILE(GLOB SRC_ZLIB deps/zlib/.c deps/zlib/.h)
c9f79972	195	ENDIF()
f443a879	196
726b75d1	197	# Optional external dependency: libssh2
f5fc63bc	198	IF (USE_SSH)
04739e9f	199	FIND_PACKAGE(LIBSSH2)
5be622fb	200	ENDIF()
7369b3c3 BM	201	IF (LIBSSH2_FOUND)
	202	ADD_DEFINITIONS(-DGIT_SSH)
	203	INCLUDE_DIRECTORIES(${LIBSSH2_INCLUDE_DIR})
1ecda61e	204	SET(LIBGIT2_PC_REQUIRES "${LIBGIT2_PC_REQUIRES} libssh2")
7369b3c3 BM	205	SET(SSH_LIBRARIES ${LIBSSH2_LIBRARIES})
	206	ENDIF()
	207
726b75d1 RB	208	# Optional external dependency: iconv
726b75d1 RB	209	IF (USE_ICONV)
04739e9f	210	FIND_PACKAGE(ICONV)
726b75d1 RB	211	ENDIF()
	212	IF (ICONV_FOUND)
	213	ADD_DEFINITIONS(-DGIT_USE_ICONV)
6e0ff093	214	INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
4bc94eb5	215	SET(LIBGIT2_PC_LIBS "${LIBGIT2_PC_LIBS} ${ICONV_LIBRARIES}")
726b75d1	216	ENDIF()
d10de8bd	217
502dd2da	218	# Platform specific compilation flags
dcd62cb2	219	IF (MSVC)
dcd62cb2	220
ccf1a2ba	221	STRING(REPLACE "/Zm1000" " " CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
94155e2f	222
19be3f9e PK	223	# /GF - String pooling
	224	# /MP - Parallel build
	225	SET(CMAKE_C_FLAGS "/GF /MP /nologo ${CMAKE_C_FLAGS}")
	226
1b5078f6	227	IF (STDCALL)
19be3f9e PK	228	# /Gz - stdcall calling convention
19be3f9e PK	229	SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Gz")
1b5078f6	230	ENDIF ()
19be3f9e	231
08f32085 Q	232	IF (STATIC_CRT)
	233	SET(CRT_FLAG_DEBUG "/MTd")
	234	SET(CRT_FLAG_RELEASE "/MT")
	235	ELSE()
ccf1a2ba	236	SET(CRT_FLAG_DEBUG "/MDd")
08f32085 Q	237	SET(CRT_FLAG_RELEASE "/MD")
	238	ENDIF()
	239
19be3f9e PK	240	# /Zi - Create debugging information
	241	# /Od - Disable optimization
	242	# /D_DEBUG - #define _DEBUG
	243	# /MTd - Statically link the multithreaded debug version of the CRT
08f32085	244	# /MDd - Dynamically link the multithreaded debug version of the CRT
19be3f9e	245	# /RTC1 - Run time checks
08f32085	246	SET(CMAKE_C_FLAGS_DEBUG "/Zi /Od /D_DEBUG /RTC1 ${CRT_FLAG_DEBUG}")
19be3f9e	247
69c28b75	248	# /DNDEBUG - Disables asserts
19be3f9e	249	# /MT - Statically link the multithreaded release version of the CRT
08f32085	250	# /MD - Dynamically link the multithreaded release version of the CRT
19be3f9e PK	251	# /O2 - Optimize for speed
	252	# /Oy - Enable frame pointer omission (FPO) (otherwise CMake will automatically turn it off)
	253	# /GL - Link time code generation (whole program optimization)
	254	# /Gy - Function-level linking
08f32085	255	SET(CMAKE_C_FLAGS_RELEASE "/DNDEBUG /O2 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
19be3f9e PK	256
19be3f9e PK	257	# /Oy- - Disable frame pointer omission (FPO)
08f32085	258	SET(CMAKE_C_FLAGS_RELWITHDEBINFO "/DNDEBUG /Zi /O2 /Oy- /GL /Gy ${CRT_FLAG_RELEASE}")
19be3f9e PK	259
19be3f9e PK	260	# /O1 - Optimize for size
08f32085	261	SET(CMAKE_C_FLAGS_MINSIZEREL "/DNDEBUG /O1 /Oy /GL /Gy ${CRT_FLAG_RELEASE}")
19be3f9e PK	262
	263	# /DYNAMICBASE - Address space load randomization (ASLR)
	264	# /NXCOMPAT - Data execution prevention (DEP)
	265	# /LARGEADDRESSAWARE - >2GB user address space on x86
	266	# /VERSION - Embed version information in PE header
	267	SET(CMAKE_EXE_LINKER_FLAGS "/DYNAMICBASE /NXCOMPAT /LARGEADDRESSAWARE /VERSION:${LIBGIT2_VERSION_MAJOR}.${LIBGIT2_VERSION_MINOR}")
	268
	269	# /DEBUG - Create a PDB
	270	# /LTCG - Link time code generation (whole program optimization)
	271	# /OPT:REF /OPT:ICF - Fold out duplicate code at link step
	272	# /INCREMENTAL:NO - Required to use /LTCG
	273	# /DEBUGTYPE:cv,fixup - Additional data embedded in the PDB (requires /INCREMENTAL:NO, so not on for Debug)
	274	SET(CMAKE_EXE_LINKER_FLAGS_DEBUG "/DEBUG")
	275	SET(CMAKE_EXE_LINKER_FLAGS_RELEASE "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
	276	SET(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/DEBUG /RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO /DEBUGTYPE:cv,fixup")
	277	SET(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/RELEASE /LTCG /OPT:REF /OPT:ICF /INCREMENTAL:NO")
	278
	279	# Same linker settings for DLL as EXE
	280	SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
	281	SET(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
	282	SET(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
	283	SET(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
	284	SET(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
	285
502dd2da	286	SET(WIN_RC "src/win32/git2.rc")
9f75a9ce BS	287
9f75a9ce BS	288	# Precompiled headers
94155e2f	289
e233fa6f	290	ELSE ()
c6cd3f8b	291	SET(CMAKE_C_FLAGS "-D_GNU_SOURCE -Wall -Wextra ${CMAKE_C_FLAGS}")
19be3f9e	292
98b8fcff JG	293	IF (CMAKE_SYSTEM_NAME MATCHES "(Solaris\|SunOS)")
	294	SET(CMAKE_C_FLAGS "-std=c99 -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_POSIX_PTHREAD_SEMANTICS ${CMAKE_C_FLAGS}")
	295	ENDIF()
	296
19be3f9e PK	297	IF (WIN32 AND NOT CYGWIN)
	298	SET(CMAKE_C_FLAGS_DEBUG "-D_DEBUG")
	299	ENDIF ()
	300
2eb18449 SG	301	IF (MINGW) # MinGW always does PIC and complains if we tell it to
2eb18449 SG	302	STRING(REGEX REPLACE "-fPIC" "" CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}")
0887b580 CMN	303	# MinGW >= 3.14 uses the C99-style stdio functions
	304	# automatically, but forks like mingw-w64 still want
	305	# us to define this in order to use them
	306	ADD_DEFINITIONS(-D__USE_MINGW_ANSI_STDIO=1)
	307
b41e24a6	308	ELSEIF (BUILD_SHARED_LIBS)
5c8d5eac	309	ADD_C_FLAG_IF_SUPPORTED(-fvisibility=hidden)
c6cd3f8b JG	310
c6cd3f8b JG	311	SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
39cdf272	312	ENDIF ()
c6cd3f8b	313
5c8d5eac JG	314	ADD_C_FLAG_IF_SUPPORTED(-Wno-missing-field-initializers)
	315	ADD_C_FLAG_IF_SUPPORTED(-Wstrict-aliasing=2)
	316	ADD_C_FLAG_IF_SUPPORTED(-Wstrict-prototypes)
	317	ADD_C_FLAG_IF_SUPPORTED(-Wdeclaration-after-statement)
	318	ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-const-variable)
	319	ADD_C_FLAG_IF_SUPPORTED(-Wno-unused-function)
c6cd3f8b	320
364ef528	321	IF (APPLE) # Apple deprecated OpenSSL
5c8d5eac	322	ADD_C_FLAG_IF_SUPPORTED(-Wno-deprecated-declarations)
c6cd3f8b	323	ENDIF()
823c0e9c	324
706a9974 RB	325	IF (PROFILE)
	326	SET(CMAKE_C_FLAGS "-pg ${CMAKE_C_FLAGS}")
	327	SET(CMAKE_EXE_LINKER_FLAGS "-pg ${CMAKE_EXE_LINKER_FLAGS}")
	328	ENDIF ()
90412507	329	ENDIF()
5b8bb8e7	330
88149fae PT	331	IF( NOT CMAKE_CONFIGURATION_TYPES )
	332	# Build Debug by default
	333	IF (NOT CMAKE_BUILD_TYPE)
	334	SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
	335	ENDIF ()
	336	ELSE()
	337	# Using a multi-configuration generator eg MSVC or Xcode
	338	# that uses CMAKE_CONFIGURATION_TYPES and not CMAKE_BUILD_TYPE
	339	ENDIF()
583cf169	340
96ef3d84 CY	341	IF (OPENSSL_FOUND)
	342	ADD_DEFINITIONS(-DGIT_SSL)
	343	INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
	344	SET(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
41cbbea8	345	ENDIF()
66024c7c	346
70236bab VM	347	IF (THREADSAFE)
70236bab VM	348	IF (NOT WIN32)
48ce93e0	349	FIND_PACKAGE(Threads REQUIRED)
70236bab VM	350	ENDIF()
	351
	352	ADD_DEFINITIONS(-DGIT_THREADS)
	353	ENDIF()
	354
678e9e04 VM	355	ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
678e9e04 VM	356
583cf169	357	# Collect sourcefiles
cdacd3d9	358	FILE(GLOB SRC_H include/git2.h include/git2/.h include/git2/sys/.h)
583cf169 PD	359
583cf169 PD	360	# On Windows use specific platform sources
5b8bb8e7	361	IF (WIN32 AND NOT CYGWIN)
19be3f9e	362	ADD_DEFINITIONS(-DWIN32 -D_WIN32_WINNT=0x0501)
cdacd3d9	363	FILE(GLOB SRC_OS src/win32/.c src/win32/.h)
96ef3d84	364	ELSEIF (AMIGA)
7697e541	365	ADD_DEFINITIONS(-DNO_ADDRINFO -DNO_READDIR_R -DNO_MMAP)
678e9e04	366	ELSE()
7697e541 RB	367	IF (VALGRIND)
	368	ADD_DEFINITIONS(-DNO_MMAP)
	369	ENDIF()
cdacd3d9	370	FILE(GLOB SRC_OS src/unix/.c src/unix/.h)
521479b1	371	ENDIF()
cdacd3d9	372	FILE(GLOB SRC_GIT2 src/.c src/.h src/transports/.c src/transports/.h src/xdiff/.c src/xdiff/.h)
5b8bb8e7	373
eb63fda2 ET	374	# Determine architecture of the machine
	375	IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
	376	ADD_DEFINITIONS(-DGIT_ARCH_64)
	377	ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
	378	ADD_DEFINITIONS(-DGIT_ARCH_32)
	379	ELSE()
48ce93e0	380	MESSAGE(FATAL_ERROR "Unsupported architecture")
eb63fda2 ET	381	ENDIF()
eb63fda2 ET	382
583cf169	383	# Compile and link libgit2
cdacd3d9	384	ADD_LIBRARY(git2 ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1} ${WIN_RC})
94243295	385	TARGET_LINK_LIBRARIES(git2 ${SSL_LIBRARIES})
7369b3c3	386	TARGET_LINK_LIBRARIES(git2 ${SSH_LIBRARIES})
726b75d1	387	TARGET_LINK_LIBRARIES(git2 ${ICONV_LIBRARIES})
94243295	388	TARGET_OS_LIBRARIES(git2)
39cdf272	389
d66a7c06 Q	390	# Workaround for Cmake bug #0011240 (see http://public.kitware.com/Bug/view.php?id=11240)
d66a7c06 Q	391	# Win64+MSVC+static libs = linker error
ac1d85cf	392	IF(MSVC AND GIT_ARCH_64 AND NOT BUILD_SHARED_LIBS)
d66a7c06 Q	393	SET_TARGET_PROPERTIES(git2 PROPERTIES STATIC_LIBRARY_FLAGS "/MACHINE:x64")
	394	ENDIF()
	395
523a3ae5 SC	396	MSVC_SPLIT_SOURCES(git2)
523a3ae5 SC	397
e7da9acd NO	398	IF (SONAME)
	399	SET_TARGET_PROPERTIES(git2 PROPERTIES VERSION ${LIBGIT2_VERSION_STRING})
	400	SET_TARGET_PROPERTIES(git2 PROPERTIES SOVERSION ${LIBGIT2_VERSION_MAJOR})
c1cf1af4	401	IF (LIBGIT2_FILENAME)
	402	ADD_DEFINITIONS(-DLIBGIT2_FILENAME=\"${LIBGIT2_FILENAME}\")
	403	SET_TARGET_PROPERTIES(git2 PROPERTIES OUTPUT_NAME ${LIBGIT2_FILENAME})
3bbc87d6	404	ENDIF()
e7da9acd	405	ENDIF()
4fd486e0	406	CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libgit2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc @ONLY)
583cf169	407
26d9e317	408	IF (MSVC_IDE)
73aaf674 BS	409	# Precompiled headers
	410	SET_TARGET_PROPERTIES(git2 PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
	411	SET_SOURCE_FILES_PROPERTIES(src/win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
	412	ENDIF ()
	413
583cf169	414	# Install
932d1baf	415	INSTALL(TARGETS git2
9795a40f	416	RUNTIME DESTINATION ${BIN_INSTALL_DIR}
b3237ac3 ICQ	417	LIBRARY DESTINATION ${LIB_INSTALL_DIR}
b3237ac3 ICQ	418	ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
583cf169	419	)
b3237ac3	420	INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgit2.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
9795a40f VP	421	INSTALL(DIRECTORY include/git2 DESTINATION ${INCLUDE_INSTALL_DIR} )
9795a40f VP	422	INSTALL(FILES include/git2.h DESTINATION ${INCLUDE_INSTALL_DIR} )
583cf169 PD	423
583cf169 PD	424	# Tests
3fd1520c	425	IF (BUILD_CLAR)
86a459a8 CB	426	FIND_PACKAGE(PythonInterp REQUIRED)
86a459a8 CB	427
83e1efbf BS	428	SET(CLAR_FIXTURES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources/")
	429	SET(CLAR_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests")
	430	SET(CLAR_RESOURCES "${CMAKE_CURRENT_SOURCE_DIR}/tests/resources" CACHE PATH "Path to test resources.")
3fd1520c	431	ADD_DEFINITIONS(-DCLAR_FIXTURE_PATH=\"${CLAR_FIXTURES}\")
e0799b6c	432	ADD_DEFINITIONS(-DCLAR_RESOURCES=\"${TEST_RESOURCES}\")
11385c3c	433
3fd1520c	434	INCLUDE_DIRECTORIES(${CLAR_PATH})
cdacd3d9	435	FILE(GLOB_RECURSE SRC_TEST ${CLAR_PATH}//.c ${CLAR_PATH}//.h)
2e6f06a8	436	SET(SRC_CLAR "${CLAR_PATH}/main.c" "${CLAR_PATH}/clar_libgit2.c" "${CLAR_PATH}/clar.c")
f1558d9b	437
86a459a8	438	ADD_CUSTOM_COMMAND(
156cfec0	439	OUTPUT ${CLAR_PATH}/clar.suite
e8242022	440	COMMAND ${PYTHON_EXECUTABLE} generate.py -f -xonline -xstress .
39444bea	441	DEPENDS ${SRC_TEST}
3fd1520c	442	WORKING_DIRECTORY ${CLAR_PATH}
86a459a8	443	)
156cfec0	444
5c2d3f6d	445	SET_SOURCE_FILES_PROPERTIES(
2e6f06a8	446	${CLAR_PATH}/clar.c
5c2d3f6d VM	447	PROPERTIES OBJECT_DEPENDS ${CLAR_PATH}/clar.suite)
5c2d3f6d VM	448
cdacd3d9	449	ADD_EXECUTABLE(libgit2_clar ${SRC_H} ${SRC_GIT2} ${SRC_OS} ${SRC_CLAR} ${SRC_TEST} ${SRC_ZLIB} ${SRC_HTTP} ${SRC_REGEX} ${SRC_SHA1})
5c2d3f6d	450
94243295	451	TARGET_LINK_LIBRARIES(libgit2_clar ${SSL_LIBRARIES})
7369b3c3	452	TARGET_LINK_LIBRARIES(libgit2_clar ${SSH_LIBRARIES})
726b75d1	453	TARGET_LINK_LIBRARIES(libgit2_clar ${ICONV_LIBRARIES})
94243295	454	TARGET_OS_LIBRARIES(libgit2_clar)
523a3ae5	455	MSVC_SPLIT_SOURCES(libgit2_clar)
73aaf674	456
156cfec0 VM	457	IF (MSVC_IDE)
	458	# Precompiled headers
	459	SET_TARGET_PROPERTIES(libgit2_clar PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
	460	ENDIF ()
73aaf674	461
f1558d9b	462	ENABLE_TESTING()
2c7f7a66	463	ADD_TEST(libgit2_clar libgit2_clar -ionline)
f1558d9b	464	ENDIF ()
e632f687 CB	465
	466	IF (TAGS)
	467	FIND_PROGRAM(CTAGS ctags)
	468	IF (NOT CTAGS)
48ce93e0	469	MESSAGE(FATAL_ERROR "Could not find ctags command")
e632f687 CB	470	ENDIF ()
	471
	472	FILE(GLOB_RECURSE SRC_ALL *.[ch])
	473
	474	ADD_CUSTOM_COMMAND(
	475	OUTPUT tags
	476	COMMAND ${CTAGS} -a ${SRC_ALL}
	477	DEPENDS ${SRC_ALL}
	478	)
	479	ADD_CUSTOM_TARGET(
	480	do_tags ALL
	481	DEPENDS tags
	482	)
	483	ENDIF ()
62986ff6 SG	484
62986ff6 SG	485	IF (BUILD_EXAMPLES)
60ee53df	486	ADD_SUBDIRECTORY(examples)
583cf169	487	ENDIF ()