]>
Commit | Line | Data |
---|---|---|
85fda4dd | 1 | package PVE::Storage::ZFSPoolPlugin; |
5bb8e010 DM |
2 | |
3 | use strict; | |
4 | use warnings; | |
5 | use IO::File; | |
6 | use POSIX; | |
7 | use PVE::Tools qw(run_command); | |
8 | use PVE::Storage::Plugin; | |
21430e50 | 9 | use PVE::RPCEnvironment; |
aefe82ea | 10 | use Net::IP; |
5bb8e010 DM |
11 | |
12 | use base qw(PVE::Storage::Plugin); | |
13 | ||
5bb8e010 | 14 | sub type { |
85fda4dd | 15 | return 'zfspool'; |
5bb8e010 DM |
16 | } |
17 | ||
18 | sub plugindata { | |
19 | return { | |
1ccae449 DM |
20 | content => [ {images => 1, rootdir => 1}, {images => 1 , rootdir => 1}], |
21 | format => [ { raw => 1, subvol => 1 } , 'raw' ], | |
5bb8e010 | 22 | }; |
85fda4dd | 23 | } |
5bb8e010 | 24 | |
7730694e DM |
25 | sub properties { |
26 | return { | |
27 | blocksize => { | |
28 | description => "block size", | |
29 | type => 'string', | |
30 | }, | |
31 | sparse => { | |
32 | description => "use sparse volumes", | |
33 | type => 'boolean', | |
34 | }, | |
35 | }; | |
36 | } | |
37 | ||
5bb8e010 DM |
38 | sub options { |
39 | return { | |
7730694e DM |
40 | pool => { fixed => 1 }, |
41 | blocksize => { optional => 1 }, | |
42 | sparse => { optional => 1 }, | |
43 | nodes => { optional => 1 }, | |
5bb8e010 | 44 | disable => { optional => 1 }, |
5bb8e010 | 45 | content => { optional => 1 }, |
9edb99a5 | 46 | bwlimit => { optional => 1 }, |
5bb8e010 DM |
47 | }; |
48 | } | |
49 | ||
7730694e DM |
50 | # static zfs helper methods |
51 | ||
060ef890 DM |
52 | sub zfs_parse_size { |
53 | my ($text) = @_; | |
54 | ||
55 | return 0 if !$text; | |
3824ba88 | 56 | |
060ef890 DM |
57 | if ($text =~ m/^(\d+(\.\d+)?)([TGMK])?$/) { |
58 | ||
59 | my ($size, $reminder, $unit) = ($1, $2, $3); | |
3824ba88 | 60 | |
060ef890 DM |
61 | if ($unit) { |
62 | if ($unit eq 'K') { | |
63 | $size *= 1024; | |
64 | } elsif ($unit eq 'M') { | |
65 | $size *= 1024*1024; | |
66 | } elsif ($unit eq 'G') { | |
67 | $size *= 1024*1024*1024; | |
68 | } elsif ($unit eq 'T') { | |
69 | $size *= 1024*1024*1024*1024; | |
70 | } else { | |
71 | die "got unknown zfs size unit '$unit'\n"; | |
72 | } | |
73 | } | |
74 | ||
75 | if ($reminder) { | |
76 | $size = ceil($size); | |
77 | } | |
3824ba88 | 78 | |
060ef890 | 79 | return $size; |
3824ba88 | 80 | |
060ef890 DM |
81 | } |
82 | ||
83 | warn "unable to parse zfs size '$text'\n"; | |
84 | ||
85 | return 0; | |
86 | } | |
87 | ||
7730694e DM |
88 | sub zfs_parse_zvol_list { |
89 | my ($text) = @_; | |
90 | ||
91 | my $list = (); | |
92 | ||
93 | return $list if !$text; | |
94 | ||
95 | my @lines = split /\n/, $text; | |
96 | foreach my $line (@lines) { | |
1ccae449 DM |
97 | my ($dataset, $size, $origin, $type, $refquota) = split(/\s+/, $line); |
98 | next if !($type eq 'volume' || $type eq 'filesystem'); | |
99 | ||
100 | my $zvol = {}; | |
101 | my @parts = split /\//, $dataset; | |
dec97937 | 102 | next if scalar(@parts) < 2; # we need pool/name |
1ccae449 DM |
103 | my $name = pop @parts; |
104 | my $pool = join('/', @parts); | |
105 | ||
851658c3 | 106 | next unless $name =~ m!^(vm|base|subvol|basevol)-(\d+)-(\S+)$!; |
1ccae449 DM |
107 | $zvol->{owner} = $2; |
108 | ||
1ccae449 DM |
109 | $zvol->{pool} = $pool; |
110 | $zvol->{name} = $name; | |
111 | if ($type eq 'filesystem') { | |
112 | if ($refquota eq 'none') { | |
113 | $zvol->{size} = 0; | |
114 | } else { | |
115 | $zvol->{size} = zfs_parse_size($refquota); | |
7730694e | 116 | } |
1ccae449 DM |
117 | $zvol->{format} = 'subvol'; |
118 | } else { | |
119 | $zvol->{size} = zfs_parse_size($size); | |
120 | $zvol->{format} = 'raw'; | |
7730694e | 121 | } |
1ccae449 DM |
122 | if ($origin !~ /^-$/) { |
123 | $zvol->{origin} = $origin; | |
124 | } | |
125 | push @$list, $zvol; | |
7730694e DM |
126 | } |
127 | ||
128 | return $list; | |
129 | } | |
130 | ||
cc80ed9c WL |
131 | sub parse_volname { |
132 | my ($class, $volname) = @_; | |
133 | ||
8e5b96ca DM |
134 | if ($volname =~ m/^(((base|basevol)-(\d+)-\S+)\/)?((base|basevol|vm|subvol)-(\d+)-\S+)$/) { |
135 | my $format = ($6 eq 'subvol' || $6 eq 'basevol') ? 'subvol' : 'raw'; | |
136 | my $isBase = ($6 eq 'base' || $6 eq 'basevol'); | |
137 | return ('images', $5, $7, $2, $4, $isBase, $format); | |
cc80ed9c WL |
138 | } |
139 | ||
140 | die "unable to parse zfs volume name '$volname'\n"; | |
141 | } | |
142 | ||
7730694e DM |
143 | # virtual zfs methods (subclass can overwrite them) |
144 | ||
f3e632d0 | 145 | sub path { |
e67069eb | 146 | my ($class, $scfg, $volname, $storeid, $snapname) = @_; |
f3e632d0 WL |
147 | |
148 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
149 | ||
150 | my $path = ''; | |
151 | ||
1ccae449 | 152 | if ($vtype eq "images") { |
74b724a6 | 153 | if ($name =~ m/^subvol-/ || $name =~ m/^basevol-/) { |
f482231e | 154 | # fixme: we currently assume standard mount point?! |
851658c3 | 155 | $path = "/$scfg->{pool}/$name"; |
1ccae449 | 156 | } else { |
851658c3 | 157 | $path = "/dev/zvol/$scfg->{pool}/$name"; |
1ccae449 | 158 | } |
f482231e | 159 | $path .= "\@$snapname" if defined($snapname); |
f3e632d0 | 160 | } else { |
85fda4dd | 161 | die "$vtype is not allowed in ZFSPool!"; |
f3e632d0 WL |
162 | } |
163 | ||
164 | return ($path, $vmid, $vtype); | |
165 | } | |
166 | ||
7730694e | 167 | sub zfs_request { |
44257d2e | 168 | my ($class, $scfg, $timeout, $method, @params) = @_; |
7730694e | 169 | |
7730694e DM |
170 | my $cmd = []; |
171 | ||
172 | if ($method eq 'zpool_list') { | |
86d47239 | 173 | push @$cmd, 'zpool', 'list'; |
e2e63801 FG |
174 | } elsif ($method eq 'zpool_import') { |
175 | push @$cmd, 'zpool', 'import'; | |
e9ab8ea3 | 176 | $timeout = 15 if !$timeout || $timeout < 15; |
7730694e DM |
177 | } else { |
178 | push @$cmd, 'zfs', $method; | |
179 | } | |
7730694e | 180 | push @$cmd, @params; |
7730694e | 181 | |
a10695b4 TL |
182 | my $msg = ''; |
183 | my $output = sub { $msg .= "$_[0]\n" }; | |
7730694e | 184 | |
a10695b4 | 185 | $timeout = PVE::RPCEnvironment->is_worker() ? 60*60 : 5 if !$timeout; |
72bdeea1 | 186 | |
1f390a30 | 187 | run_command($cmd, errmsg => "zfs error", outfunc => $output, timeout => $timeout); |
7730694e DM |
188 | |
189 | return $msg; | |
190 | } | |
191 | ||
56362cfb FG |
192 | sub zfs_wait_for_zvol_link { |
193 | my ($class, $scfg, $volname, $timeout) = @_; | |
194 | ||
195 | my $default_timeout = PVE::RPCEnvironment->is_worker() ? 60*5 : 10; | |
196 | $timeout = $default_timeout if !defined($timeout); | |
197 | ||
198 | my ($devname, undef, undef) = $class->path($scfg, $volname); | |
199 | ||
200 | for (my $i = 1; $i <= $timeout; $i++) { | |
201 | last if -b $devname; | |
202 | die "timeout: no zvol device link for '$volname' found after $timeout sec found.\n" | |
203 | if $i == $timeout; | |
204 | ||
205 | sleep(1); | |
206 | } | |
207 | } | |
208 | ||
b3ba95e4 WL |
209 | sub alloc_image { |
210 | my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_; | |
211 | ||
1ccae449 | 212 | my $volname = $name; |
3824ba88 | 213 | |
1ccae449 | 214 | if ($fmt eq 'raw') { |
b3ba95e4 | 215 | |
fc05c9a0 | 216 | die "illegal name '$volname' - should be 'vm-$vmid-*'\n" |
1ccae449 | 217 | if $volname && $volname !~ m/^vm-$vmid-/; |
3824ba88 | 218 | $volname = $class->zfs_find_free_diskname($storeid, $scfg, $vmid, $fmt) |
1ccae449 | 219 | if !$volname; |
b3ba95e4 | 220 | |
1ccae449 | 221 | $class->zfs_create_zvol($scfg, $volname, $size); |
56362cfb | 222 | $class->zfs_wait_for_zvol_link($scfg, $volname); |
82e08809 | 223 | |
1ccae449 | 224 | } elsif ( $fmt eq 'subvol') { |
55525ad2 | 225 | |
fc05c9a0 | 226 | die "illegal name '$volname' - should be 'subvol-$vmid-*'\n" |
55525ad2 | 227 | if $volname && $volname !~ m/^subvol-$vmid-/; |
3824ba88 | 228 | $volname = $class->zfs_find_free_diskname($storeid, $scfg, $vmid, $fmt) |
55525ad2 DM |
229 | if !$volname; |
230 | ||
fc05c9a0 | 231 | die "illegal name '$volname' - should be 'subvol-$vmid-*'\n" |
1ccae449 | 232 | if $volname !~ m/^subvol-$vmid-/; |
76fd7dc7 | 233 | |
3824ba88 FE |
234 | $class->zfs_create_subvol($scfg, $volname, $size); |
235 | ||
1ccae449 DM |
236 | } else { |
237 | die "unsupported format '$fmt'"; | |
238 | } | |
b3ba95e4 | 239 | |
82e08809 | 240 | return $volname; |
b3ba95e4 WL |
241 | } |
242 | ||
e9565df5 WL |
243 | sub free_image { |
244 | my ($class, $storeid, $scfg, $volname, $isBase) = @_; | |
245 | ||
246 | my (undef, $name, undef) = $class->parse_volname($volname); | |
247 | ||
248 | $class->zfs_delete_zvol($scfg, $name); | |
249 | ||
250 | return undef; | |
251 | } | |
252 | ||
ca04180f WL |
253 | sub list_images { |
254 | my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_; | |
255 | ||
256 | $cache->{zfs} = $class->zfs_list_zvol($scfg) if !$cache->{zfs}; | |
257 | my $zfspool = $scfg->{pool}; | |
258 | my $res = []; | |
259 | ||
260 | if (my $dat = $cache->{zfs}->{$zfspool}) { | |
261 | ||
262 | foreach my $image (keys %$dat) { | |
263 | ||
1b83c3d9 | 264 | my $info = $dat->{$image}; |
ca04180f | 265 | |
1b83c3d9 FG |
266 | my $volname = $info->{name}; |
267 | my $parent = $info->{parent}; | |
268 | my $owner = $info->{vmid}; | |
269 | ||
270 | if ($parent && $parent =~ m/^(\S+)\@__base__$/) { | |
ca04180f | 271 | my ($basename) = ($1); |
1b83c3d9 | 272 | $info->{volid} = "$storeid:$basename/$volname"; |
ca04180f | 273 | } else { |
1b83c3d9 | 274 | $info->{volid} = "$storeid:$volname"; |
ca04180f WL |
275 | } |
276 | ||
ca04180f | 277 | if ($vollist) { |
1b83c3d9 | 278 | my $found = grep { $_ eq $info->{volid} } @$vollist; |
ca04180f WL |
279 | next if !$found; |
280 | } else { | |
281 | next if defined ($vmid) && ($owner ne $vmid); | |
282 | } | |
283 | ||
ca04180f WL |
284 | push @$res, $info; |
285 | } | |
286 | } | |
ca04180f WL |
287 | return $res; |
288 | } | |
289 | ||
4966c886 FE |
290 | sub zfs_get_properties { |
291 | my ($class, $scfg, $properties, $dataset, $timeout) = @_; | |
292 | ||
293 | my $result = $class->zfs_request($scfg, $timeout, 'get', '-o', 'value', | |
294 | '-Hp', $properties, $dataset); | |
295 | my @values = split /\n/, $result; | |
296 | return wantarray ? @values : $values[0]; | |
297 | } | |
298 | ||
7730694e DM |
299 | sub zfs_get_pool_stats { |
300 | my ($class, $scfg) = @_; | |
301 | ||
302 | my $available = 0; | |
303 | my $used = 0; | |
304 | ||
4966c886 | 305 | my @lines = $class->zfs_get_properties($scfg, 'available,used', $scfg->{pool}); |
7730694e DM |
306 | |
307 | if($lines[0] =~ /^(\d+)$/) { | |
308 | $available = $1; | |
309 | } | |
310 | ||
311 | if($lines[1] =~ /^(\d+)$/) { | |
312 | $used = $1; | |
313 | } | |
314 | ||
315 | return ($available, $used); | |
316 | } | |
317 | ||
7730694e DM |
318 | sub zfs_create_zvol { |
319 | my ($class, $scfg, $zvol, $size) = @_; | |
cdef3abb ML |
320 | |
321 | # always align size to 1M as workaround until | |
322 | # https://github.com/zfsonlinux/zfs/issues/8541 is solved | |
323 | my $padding = (1024 - $size % 1024) % 1024; | |
324 | $size = $size + $padding; | |
325 | ||
7730694e DM |
326 | my $cmd = ['create']; |
327 | ||
328 | push @$cmd, '-s' if $scfg->{sparse}; | |
329 | ||
330 | push @$cmd, '-b', $scfg->{blocksize} if $scfg->{blocksize}; | |
331 | ||
332 | push @$cmd, '-V', "${size}k", "$scfg->{pool}/$zvol"; | |
333 | ||
44257d2e | 334 | $class->zfs_request($scfg, undef, @$cmd); |
7730694e DM |
335 | } |
336 | ||
1ccae449 DM |
337 | sub zfs_create_subvol { |
338 | my ($class, $scfg, $volname, $size) = @_; | |
339 | ||
340 | my $dataset = "$scfg->{pool}/$volname"; | |
3824ba88 | 341 | |
efaf4017 DM |
342 | my $cmd = ['create', '-o', 'acltype=posixacl', '-o', 'xattr=sa', |
343 | '-o', "refquota=${size}k", $dataset]; | |
1ccae449 | 344 | |
44257d2e | 345 | $class->zfs_request($scfg, undef, @$cmd); |
1ccae449 DM |
346 | } |
347 | ||
7730694e DM |
348 | sub zfs_delete_zvol { |
349 | my ($class, $scfg, $zvol) = @_; | |
350 | ||
1f390a30 WL |
351 | my $err; |
352 | ||
353 | for (my $i = 0; $i < 6; $i++) { | |
354 | ||
44257d2e | 355 | eval { $class->zfs_request($scfg, undef, 'destroy', '-r', "$scfg->{pool}/$zvol"); }; |
1f390a30 WL |
356 | if ($err = $@) { |
357 | if ($err =~ m/^zfs error:(.*): dataset is busy.*/) { | |
358 | sleep(1); | |
27ff0e99 WL |
359 | } elsif ($err =~ m/^zfs error:.*: dataset does not exist.*$/) { |
360 | $err = undef; | |
361 | last; | |
1f390a30 WL |
362 | } else { |
363 | die $err; | |
364 | } | |
365 | } else { | |
366 | last; | |
367 | } | |
368 | } | |
369 | ||
370 | die $err if $err; | |
7730694e DM |
371 | } |
372 | ||
373 | sub zfs_list_zvol { | |
374 | my ($class, $scfg) = @_; | |
375 | ||
44257d2e | 376 | my $text = $class->zfs_request($scfg, 10, 'list', '-o', 'name,volsize,origin,type,refquota', '-t', 'volume,filesystem', '-Hr'); |
7730694e DM |
377 | my $zvols = zfs_parse_zvol_list($text); |
378 | return undef if !$zvols; | |
379 | ||
380 | my $list = (); | |
381 | foreach my $zvol (@$zvols) { | |
1ccae449 DM |
382 | my $pool = $zvol->{pool}; |
383 | my $name = $zvol->{name}; | |
7730694e DM |
384 | my $parent = $zvol->{origin}; |
385 | if($zvol->{origin} && $zvol->{origin} =~ m/^$scfg->{pool}\/(\S+)$/){ | |
386 | $parent = $1; | |
387 | } | |
388 | ||
1ccae449 DM |
389 | $list->{$pool}->{$name} = { |
390 | name => $name, | |
7730694e DM |
391 | size => $zvol->{size}, |
392 | parent => $parent, | |
1ccae449 DM |
393 | format => $zvol->{format}, |
394 | vmid => $zvol->{owner}, | |
7730694e DM |
395 | }; |
396 | } | |
397 | ||
398 | return $list; | |
399 | } | |
400 | ||
401 | sub zfs_find_free_diskname { | |
55525ad2 | 402 | my ($class, $storeid, $scfg, $vmid, $format) = @_; |
7730694e | 403 | |
7730694e | 404 | my $volumes = $class->zfs_list_zvol($scfg); |
7730694e DM |
405 | my $dat = $volumes->{$scfg->{pool}}; |
406 | ||
c4a29df4 SI |
407 | my $disk_list = [ keys %$dat ]; |
408 | return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, $format, $scfg); | |
7730694e DM |
409 | } |
410 | ||
2fc59177 DM |
411 | sub zfs_get_latest_snapshot { |
412 | my ($class, $scfg, $volname) = @_; | |
413 | ||
851658c3 WL |
414 | my $vname = ($class->parse_volname($volname))[1]; |
415 | ||
2fc59177 DM |
416 | # abort rollback if snapshot is not the latest |
417 | my @params = ('-t', 'snapshot', '-o', 'name', '-s', 'creation'); | |
44257d2e | 418 | my $text = $class->zfs_request($scfg, undef, 'list', @params); |
2fc59177 DM |
419 | my @snapshots = split(/\n/, $text); |
420 | ||
421 | my $recentsnap; | |
422 | foreach (@snapshots) { | |
851658c3 | 423 | if (/$scfg->{pool}\/$vname/) { |
2fc59177 DM |
424 | s/^.*@//; |
425 | $recentsnap = $_; | |
426 | } | |
427 | } | |
428 | ||
429 | return $recentsnap; | |
430 | } | |
431 | ||
b5e5f7e3 DM |
432 | sub status { |
433 | my ($class, $storeid, $scfg, $cache) = @_; | |
434 | ||
435 | my $total = 0; | |
436 | my $free = 0; | |
437 | my $used = 0; | |
438 | my $active = 0; | |
439 | ||
440 | eval { | |
441 | ($free, $used) = $class->zfs_get_pool_stats($scfg); | |
442 | $active = 1; | |
443 | $total = $free + $used; | |
444 | }; | |
445 | warn $@ if $@; | |
446 | ||
447 | return ($total, $free, $used, $active); | |
448 | } | |
449 | ||
450 | sub volume_size_info { | |
451 | my ($class, $scfg, $storeid, $volname, $timeout) = @_; | |
452 | ||
851658c3 | 453 | my (undef, $vname, undef, undef, undef, undef, $format) = |
79f2b938 DM |
454 | $class->parse_volname($volname); |
455 | ||
456 | my $attr = $format eq 'subvol' ? 'refquota' : 'volsize'; | |
4966c886 FE |
457 | my $value = $class->zfs_get_properties($scfg, $attr, "$scfg->{pool}/$vname"); |
458 | if ($value =~ /^(\d+)$/) { | |
79f2b938 DM |
459 | return $1; |
460 | } | |
461 | ||
462 | die "Could not get zfs volume size\n"; | |
b5e5f7e3 DM |
463 | } |
464 | ||
465 | sub volume_snapshot { | |
f5640e7d | 466 | my ($class, $scfg, $storeid, $volname, $snap) = @_; |
b5e5f7e3 | 467 | |
851658c3 WL |
468 | my $vname = ($class->parse_volname($volname))[1]; |
469 | ||
44257d2e | 470 | $class->zfs_request($scfg, undef, 'snapshot', "$scfg->{pool}/$vname\@$snap"); |
b5e5f7e3 DM |
471 | } |
472 | ||
473 | sub volume_snapshot_delete { | |
474 | my ($class, $scfg, $storeid, $volname, $snap, $running) = @_; | |
475 | ||
851658c3 WL |
476 | my $vname = ($class->parse_volname($volname))[1]; |
477 | ||
478 | $class->deactivate_volume($storeid, $scfg, $vname, $snap, {}); | |
44257d2e | 479 | $class->zfs_request($scfg, undef, 'destroy', "$scfg->{pool}/$vname\@$snap"); |
b5e5f7e3 DM |
480 | } |
481 | ||
2b40ffae WL |
482 | sub volume_snapshot_rollback { |
483 | my ($class, $scfg, $storeid, $volname, $snap) = @_; | |
484 | ||
851658c3 WL |
485 | my $vname = ($class->parse_volname($volname))[1]; |
486 | ||
44257d2e | 487 | $class->zfs_request($scfg, undef, 'rollback', "$scfg->{pool}/$vname\@$snap"); |
1597f1f9 WL |
488 | } |
489 | ||
490 | sub volume_rollback_is_possible { | |
3824ba88 FE |
491 | my ($class, $scfg, $storeid, $volname, $snap) = @_; |
492 | ||
2fc59177 | 493 | my $recentsnap = $class->zfs_get_latest_snapshot($scfg, $volname); |
2b40ffae | 494 | if ($snap ne $recentsnap) { |
1597f1f9 | 495 | die "can't rollback, more recent snapshots exist\n"; |
2b40ffae WL |
496 | } |
497 | ||
3824ba88 | 498 | return 1; |
2b40ffae WL |
499 | } |
500 | ||
aefe82ea | 501 | sub volume_snapshot_list { |
8b622c2d | 502 | my ($class, $scfg, $storeid, $volname) = @_; |
aefe82ea WL |
503 | |
504 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
505 | ||
506 | my $zpath = "$scfg->{pool}/$name"; | |
507 | ||
aefe82ea WL |
508 | my $snaps = []; |
509 | ||
510 | my $cmd = ['zfs', 'list', '-r', '-H', '-S', 'name', '-t', 'snap', '-o', | |
511 | 'name', $zpath]; | |
512 | ||
aefe82ea WL |
513 | my $outfunc = sub { |
514 | my $line = shift; | |
515 | ||
8b622c2d | 516 | if ($line =~ m/^\Q$zpath\E@(.*)$/) { |
aefe82ea WL |
517 | push @$snaps, $1; |
518 | } | |
519 | }; | |
520 | ||
521 | eval { run_command( [$cmd], outfunc => $outfunc , errfunc => sub{}); }; | |
522 | ||
523 | # return an empty array if dataset does not exist. | |
524 | return $snaps; | |
525 | } | |
526 | ||
0a3d992f DM |
527 | sub activate_storage { |
528 | my ($class, $storeid, $scfg, $cache) = @_; | |
86d47239 | 529 | |
93124ef4 DM |
530 | # Note: $scfg->{pool} can include dataset <pool>/<dataset> |
531 | my $pool = $scfg->{pool}; | |
532 | $pool =~ s!/.*$!!; | |
533 | ||
b5c8278a TL |
534 | my $pool_imported = sub { |
535 | my @param = ('-o', 'name', '-H', "$pool"); | |
536 | my $res = eval { $class->zfs_request($scfg, undef, 'zpool_list', @param) }; | |
dc18abe0 | 537 | if ($@) { |
b5c8278a TL |
538 | warn "$@\n"; |
539 | return undef; | |
540 | } | |
541 | return defined($res) && $res =~ m/$pool/; | |
542 | }; | |
543 | ||
544 | if (!$pool_imported->()) { | |
545 | # import can only be done if not yet imported! | |
546 | my @param = ('-d', '/dev/disk/by-id/', '-o', 'cachefile=none', "$pool"); | |
547 | eval { $class->zfs_request($scfg, undef, 'zpool_import', @param) }; | |
548 | if (my $err = $@) { | |
549 | # just could've raced with another import, so recheck if it is imported | |
550 | die "could not activate storage '$storeid', $@\n" if !$pool_imported->(); | |
dc18abe0 | 551 | } |
86d47239 | 552 | } |
0a3d992f DM |
553 | return 1; |
554 | } | |
555 | ||
556 | sub deactivate_storage { | |
557 | my ($class, $storeid, $scfg, $cache) = @_; | |
558 | return 1; | |
559 | } | |
560 | ||
d4c63dc1 | 561 | sub activate_volume { |
02e797b8 | 562 | my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_; |
56362cfb FG |
563 | |
564 | return 1 if defined($snapname); | |
565 | ||
566 | my (undef, undef, undef, undef, undef, undef, $format) = $class->parse_volname($volname); | |
567 | ||
568 | return 1 if $format ne 'raw'; | |
569 | ||
570 | $class->zfs_wait_for_zvol_link($scfg, $volname); | |
571 | ||
d4c63dc1 WL |
572 | return 1; |
573 | } | |
574 | ||
575 | sub deactivate_volume { | |
02e797b8 | 576 | my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_; |
d4c63dc1 WL |
577 | return 1; |
578 | } | |
5bb8e010 | 579 | |
d3a282e8 WL |
580 | sub clone_image { |
581 | my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_; | |
582 | ||
583 | $snap ||= '__base__'; | |
584 | ||
55525ad2 | 585 | my ($vtype, $basename, $basevmid, undef, undef, $isBase, $format) = |
d3a282e8 WL |
586 | $class->parse_volname($volname); |
587 | ||
588 | die "clone_image only works on base images\n" if !$isBase; | |
589 | ||
55525ad2 | 590 | my $name = $class->zfs_find_free_diskname($storeid, $scfg, $vmid, $format); |
d3a282e8 | 591 | |
851658c3 | 592 | if ($format eq 'subvol') { |
44257d2e | 593 | my $size = $class->zfs_request($scfg, undef, 'list', '-H', '-o', 'refquota', "$scfg->{pool}/$basename"); |
851658c3 | 594 | chomp($size); |
44257d2e | 595 | $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name", '-o', "refquota=$size"); |
851658c3 | 596 | } else { |
44257d2e | 597 | $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name"); |
851658c3 | 598 | } |
d3a282e8 | 599 | |
851658c3 | 600 | return "$basename/$name"; |
d3a282e8 WL |
601 | } |
602 | ||
603 | sub create_base { | |
604 | my ($class, $storeid, $scfg, $volname) = @_; | |
605 | ||
606 | my $snap = '__base__'; | |
607 | ||
851658c3 | 608 | my ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format) = |
d3a282e8 WL |
609 | $class->parse_volname($volname); |
610 | ||
611 | die "create_base not possible with base image\n" if $isBase; | |
612 | ||
613 | my $newname = $name; | |
851658c3 WL |
614 | if ( $format eq 'subvol' ) { |
615 | $newname =~ s/^subvol-/basevol-/; | |
616 | } else { | |
617 | $newname =~ s/^vm-/base-/; | |
618 | } | |
d3a282e8 WL |
619 | my $newvolname = $basename ? "$basename/$newname" : "$newname"; |
620 | ||
44257d2e | 621 | $class->zfs_request($scfg, undef, 'rename', "$scfg->{pool}/$name", "$scfg->{pool}/$newname"); |
d3a282e8 WL |
622 | |
623 | my $running = undef; #fixme : is create_base always offline ? | |
624 | ||
625 | $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running); | |
626 | ||
627 | return $newvolname; | |
628 | } | |
629 | ||
a4034b9f WL |
630 | sub volume_resize { |
631 | my ($class, $scfg, $storeid, $volname, $size, $running) = @_; | |
632 | ||
79f2b938 DM |
633 | my $new_size = int($size/1024); |
634 | ||
851658c3 | 635 | my (undef, $vname, undef, undef, undef, undef, $format) = |
79f2b938 DM |
636 | $class->parse_volname($volname); |
637 | ||
638 | my $attr = $format eq 'subvol' ? 'refquota' : 'volsize'; | |
a4034b9f | 639 | |
44257d2e | 640 | $class->zfs_request($scfg, undef, 'set', "$attr=${new_size}k", "$scfg->{pool}/$vname"); |
a4034b9f WL |
641 | |
642 | return $new_size; | |
643 | } | |
644 | ||
7118dd91 DM |
645 | sub storage_can_replicate { |
646 | my ($class, $scfg, $storeid, $format) = @_; | |
647 | ||
648 | return 1 if $format eq 'raw' || $format eq 'subvol'; | |
649 | ||
650 | return 0; | |
651 | } | |
652 | ||
2b40ffae WL |
653 | sub volume_has_feature { |
654 | my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_; | |
655 | ||
656 | my $features = { | |
657 | snapshot => { current => 1, snap => 1}, | |
658 | clone => { base => 1}, | |
659 | template => { current => 1}, | |
660 | copy => { base => 1, current => 1}, | |
baafddbd | 661 | sparseinit => { base => 1, current => 1}, |
f189504c | 662 | replicate => { base => 1, current => 1}, |
2b40ffae WL |
663 | }; |
664 | ||
665 | my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) = | |
666 | $class->parse_volname($volname); | |
667 | ||
668 | my $key = undef; | |
669 | ||
670 | if ($snapname) { | |
671 | $key = 'snap'; | |
672 | } else { | |
673 | $key = $isBase ? 'base' : 'current'; | |
674 | } | |
675 | ||
676 | return 1 if $features->{$feature}->{$key}; | |
677 | ||
678 | return undef; | |
679 | } | |
680 | ||
47f37b53 WB |
681 | sub volume_export { |
682 | my ($class, $scfg, $storeid, $fh, $volname, $format, $snapshot, $base_snapshot, $with_snapshots) = @_; | |
683 | ||
684 | die "unsupported export stream format for $class: $format\n" | |
685 | if $format ne 'zfs'; | |
686 | ||
687 | die "$class storage can only export snapshots\n" | |
688 | if !defined($snapshot); | |
689 | ||
9a75947b WL |
690 | my $dataset = ($class->parse_volname($volname))[1]; |
691 | ||
47f37b53 WB |
692 | my $fd = fileno($fh); |
693 | die "internal error: invalid file handle for volume_export\n" | |
694 | if !defined($fd); | |
695 | $fd = ">&$fd"; | |
696 | ||
697 | # For zfs we always create a replication stream (-R) which means the remote | |
698 | # side will always delete non-existing source snapshots. This should work | |
699 | # for all our use cases. | |
700 | my $cmd = ['zfs', 'send', '-Rpv']; | |
701 | if (defined($base_snapshot)) { | |
702 | my $arg = $with_snapshots ? '-I' : '-i'; | |
703 | push @$cmd, $arg, $base_snapshot; | |
704 | } | |
9a75947b | 705 | push @$cmd, '--', "$scfg->{pool}/$dataset\@$snapshot"; |
47f37b53 WB |
706 | |
707 | run_command($cmd, output => $fd); | |
708 | ||
709 | return; | |
710 | } | |
711 | ||
d390328b WB |
712 | sub volume_export_formats { |
713 | my ($class, $scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots) = @_; | |
714 | ||
715 | my @formats = ('zfs'); | |
716 | # TODOs: | |
717 | # push @formats, 'fies' if $volname !~ /^(?:basevol|subvol)-/; | |
718 | # push @formats, 'raw' if !$base_snapshot && !$with_snapshots; | |
719 | return @formats; | |
720 | } | |
721 | ||
47f37b53 WB |
722 | sub volume_import { |
723 | my ($class, $scfg, $storeid, $fh, $volname, $format, $base_snapshot, $with_snapshots) = @_; | |
724 | ||
725 | die "unsupported import stream format for $class: $format\n" | |
726 | if $format ne 'zfs'; | |
727 | ||
728 | my $fd = fileno($fh); | |
729 | die "internal error: invalid file handle for volume_import\n" | |
730 | if !defined($fd); | |
731 | ||
9a75947b WL |
732 | my $dataset = ($class->parse_volname($volname))[1]; |
733 | my $zfspath = "$scfg->{pool}/$dataset"; | |
47f37b53 WB |
734 | my $suffix = defined($base_snapshot) ? "\@$base_snapshot" : ''; |
735 | my $exists = 0 == run_command(['zfs', 'get', '-H', 'name', $zfspath.$suffix], | |
736 | noerr => 1, errfunc => sub {}); | |
737 | if (defined($base_snapshot)) { | |
738 | die "base snapshot '$zfspath\@$base_snapshot' doesn't exist\n" if !$exists; | |
739 | } else { | |
740 | die "volume '$zfspath' already exists\n" if $exists; | |
741 | } | |
742 | ||
743 | eval { run_command(['zfs', 'recv', '-F', '--', $zfspath], input => "<&$fd") }; | |
744 | if (my $err = $@) { | |
745 | if (defined($base_snapshot)) { | |
746 | eval { run_command(['zfs', 'rollback', '-r', '--', "$zfspath\@$base_snapshot"]) }; | |
747 | } else { | |
748 | eval { run_command(['zfs', 'destroy', '-r', '--', $zfspath]) }; | |
749 | } | |
750 | die $err; | |
751 | } | |
752 | ||
753 | return; | |
754 | } | |
755 | ||
d390328b WB |
756 | sub volume_import_formats { |
757 | my ($class, $scfg, $storeid, $volname, $base_snapshot, $with_snapshots) = @_; | |
758 | ||
759 | return $class->volume_export_formats($scfg, $storeid, $volname, undef, $base_snapshot, $with_snapshots); | |
760 | } | |
761 | ||
5bb8e010 | 762 | 1; |