]>
Commit | Line | Data |
---|---|---|
064af421 BP |
1 | # -*- autoconf -*- |
2 | ||
416e7132 | 3 | # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc. |
064af421 | 4 | # |
a14bc59f BP |
5 | # Licensed under the Apache License, Version 2.0 (the "License"); |
6 | # you may not use this file except in compliance with the License. | |
7 | # You may obtain a copy of the License at: | |
064af421 | 8 | # |
a14bc59f BP |
9 | # http://www.apache.org/licenses/LICENSE-2.0 |
10 | # | |
11 | # Unless required by applicable law or agreed to in writing, software | |
12 | # distributed under the License is distributed on an "AS IS" BASIS, | |
13 | # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. | |
14 | # See the License for the specific language governing permissions and | |
15 | # limitations under the License. | |
064af421 | 16 | |
a64e37a1 BP |
17 | dnl OVS_ENABLE_WERROR |
18 | AC_DEFUN([OVS_ENABLE_WERROR], | |
19 | [AC_ARG_ENABLE( | |
20 | [Werror], | |
21 | [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])], | |
22 | [], [enable_Werror=no]) | |
23 | AC_CONFIG_COMMANDS_PRE( | |
24 | [if test "X$enable_Werror" = Xyes; then | |
95626395 | 25 | OVS_CFLAGS="$OVS_CFLAGS -Werror" |
a64e37a1 BP |
26 | fi])]) |
27 | ||
e3438006 | 28 | dnl OVS_CHECK_LINUX |
064af421 BP |
29 | dnl |
30 | dnl Configure linux kernel source tree | |
e3438006 | 31 | AC_DEFUN([OVS_CHECK_LINUX], [ |
8a2d6596 BP |
32 | AC_ARG_WITH([linux], |
33 | [AC_HELP_STRING([--with-linux=/path/to/linux], | |
34 | [Specify the Linux kernel build directory])]) | |
35 | AC_ARG_WITH([linux-source], | |
36 | [AC_HELP_STRING([--with-linux-source=/path/to/linux-source], | |
37 | [Specify the Linux kernel source directory | |
a0903134 YT |
38 | (usually figured out automatically from build |
39 | directory)])]) | |
8a2d6596 BP |
40 | |
41 | # Deprecated equivalents to --with-linux, --with-linux-source. | |
42 | AC_ARG_WITH([l26]) | |
43 | AC_ARG_WITH([l26-source]) | |
44 | ||
45 | if test X"$with_linux" != X; then | |
46 | KBUILD=$with_linux | |
47 | elif test X"$with_l26" != X; then | |
48 | KBUILD=$with_l26 | |
49 | AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead]) | |
50 | else | |
51 | KBUILD= | |
52 | fi | |
53 | ||
54 | if test X"$KBUILD" != X; then | |
55 | if test X"$with_linux_source" != X; then | |
56 | KSRC=$with_linux_source | |
57 | elif test X"$with_l26_source" != X; then | |
58 | KSRC=$with_l26_source | |
59 | AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead]) | |
0a89c170 BP |
60 | else |
61 | KSRC= | |
8a2d6596 BP |
62 | fi |
63 | elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then | |
64 | AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory]) | |
65 | fi | |
66 | ||
e3438006 BP |
67 | if test -n "$KBUILD"; then |
68 | KBUILD=`eval echo "$KBUILD"` | |
69 | case $KBUILD in | |
0b6d72fc | 70 | /*) ;; |
e3438006 | 71 | *) KBUILD=`pwd`/$KBUILD ;; |
0b6d72fc | 72 | esac |
064af421 | 73 | |
7c9e113b BP |
74 | # The build directory is what the user provided. |
75 | # Make sure that it exists. | |
8a2d6596 | 76 | AC_MSG_CHECKING([for Linux build directory]) |
e3438006 | 77 | if test -d "$KBUILD"; then |
a0903134 YT |
78 | AC_MSG_RESULT([$KBUILD]) |
79 | AC_SUBST(KBUILD) | |
064af421 | 80 | else |
a0903134 YT |
81 | AC_MSG_RESULT([no]) |
82 | AC_ERROR([source dir $KBUILD doesn't exist]) | |
064af421 BP |
83 | fi |
84 | ||
7c9e113b | 85 | # Debian breaks kernel headers into "source" header and "build" headers. |
e3438006 | 86 | # We want the source headers, but $KBUILD gives us the "build" headers. |
7c9e113b | 87 | # Use heuristics to find the source headers. |
8a2d6596 | 88 | AC_MSG_CHECKING([for Linux source directory]) |
e3438006 BP |
89 | if test -n "$KSRC"; then |
90 | KSRC=`eval echo "$KSRC"` | |
91 | case $KSRC in | |
f5fb5de6 | 92 | /*) ;; |
e3438006 | 93 | *) KSRC=`pwd`/$KSRC ;; |
b57f675c | 94 | esac |
e3438006 | 95 | if test ! -e $KSRC/include/linux/kernel.h; then |
53319f95 | 96 | AC_MSG_ERROR([$KSRC is not a kernel source directory]) |
f5fb5de6 BP |
97 | fi |
98 | else | |
e3438006 BP |
99 | KSRC=$KBUILD |
100 | if test ! -e $KSRC/include/linux/kernel.h; then | |
fe0731b1 BP |
101 | # Debian kernel build Makefiles tend to include a line of the form: |
102 | # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486 | |
103 | # First try to extract the source directory from this line. | |
104 | KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile` | |
105 | if test ! -e "$KSRC"/include/linux/kernel.h; then | |
106 | # Didn't work. Fall back to name-based heuristics that used to work. | |
107 | case `echo "$KBUILD" | sed 's,/*$,,'` in # ( | |
108 | */build) | |
109 | KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'` | |
110 | ;; # ( | |
111 | *) | |
112 | KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'` | |
113 | ;; | |
114 | esac | |
115 | fi | |
f5fb5de6 | 116 | fi |
fe0731b1 | 117 | if test ! -e "$KSRC"/include/linux/kernel.h; then |
8a2d6596 | 118 | AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)]) |
7c9e113b BP |
119 | fi |
120 | fi | |
e3438006 | 121 | AC_MSG_RESULT([$KSRC]) |
7c9e113b BP |
122 | |
123 | AC_MSG_CHECKING([for kernel version]) | |
71fe9970 | 124 | version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"` |
e3438006 BP |
125 | patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"` |
126 | sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"` | |
71fe9970 | 127 | if test X"$version" = X || test X"$patchlevel" = X; then |
7c9e113b | 128 | AC_ERROR([cannot determine kernel version]) |
71fe9970 BP |
129 | elif test X"$sublevel" = X; then |
130 | kversion=$version.$patchlevel | |
131 | else | |
132 | kversion=$version.$patchlevel.$sublevel | |
7c9e113b | 133 | fi |
71fe9970 BP |
134 | AC_MSG_RESULT([$kversion]) |
135 | ||
3afcde43 | 136 | if test "$version" -ge 4; then |
fdce83a3 | 137 | if test "$version" = 4 && test "$patchlevel" -le 2; then |
3afcde43 | 138 | : # Linux 4.x |
d76aabea | 139 | else |
fdce83a3 | 140 | AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.2.x is not supported (please refer to the FAQ for advice)]) |
d76aabea | 141 | fi |
3afcde43 JS |
142 | elif test "$version" = 3; then |
143 | : # Linux 3.x | |
71fe9970 | 144 | else |
d76aabea PS |
145 | if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then |
146 | AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required]) | |
7c9e113b | 147 | else |
d76aabea | 148 | : # Linux 2.6.x |
7c9e113b | 149 | fi |
064af421 | 150 | fi |
2520f452 IY |
151 | if (test ! -e "$KBUILD"/include/linux/version.h && \ |
152 | test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \ | |
e3438006 BP |
153 | (test ! -e "$KBUILD"/include/linux/autoconf.h && \ |
154 | test ! -e "$KBUILD"/include/generated/autoconf.h); then | |
a0903134 | 155 | AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured]) |
064af421 | 156 | fi |
e3438006 | 157 | OVS_CHECK_LINUX_COMPAT |
064af421 | 158 | fi |
e3438006 | 159 | AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD") |
064af421 BP |
160 | ]) |
161 | ||
8a9562d2 PS |
162 | dnl OVS_CHECK_DPDK |
163 | dnl | |
164 | dnl Configure DPDK source tree | |
165 | AC_DEFUN([OVS_CHECK_DPDK], [ | |
166 | AC_ARG_WITH([dpdk], | |
167 | [AC_HELP_STRING([--with-dpdk=/path/to/dpdk], | |
e2e54517 | 168 | [Specify the DPDK build directory])]) |
8a9562d2 PS |
169 | |
170 | if test X"$with_dpdk" != X; then | |
171 | RTE_SDK=$with_dpdk | |
172 | ||
173 | DPDK_INCLUDE=$RTE_SDK/include | |
174 | DPDK_LIB_DIR=$RTE_SDK/lib | |
18f777b2 | 175 | DPDK_LIB="-ldpdk" |
10d01ad2 | 176 | DPDK_EXTRA_LIB="" |
613750ab | 177 | RTE_SDK_FULL=`readlink -f $RTE_SDK` |
10d01ad2 | 178 | |
693e1138 | 179 | AC_COMPILE_IFELSE( |
613750ab | 180 | [AC_LANG_PROGRAM([#include <$RTE_SDK_FULL/include/rte_config.h> |
693e1138 GM |
181 | #if !RTE_LIBRTE_VHOST_USER |
182 | #error | |
183 | #endif], [])], | |
10d01ad2 DDP |
184 | [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.]) |
185 | DPDK_EXTRA_LIB="-lfuse"]) | |
8a9562d2 | 186 | |
95626395 TG |
187 | ovs_save_CFLAGS="$CFLAGS" |
188 | ovs_save_LDFLAGS="$LDFLAGS" | |
c1223b11 DDP |
189 | LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR" |
190 | CFLAGS="$CFLAGS -I$DPDK_INCLUDE" | |
191 | ||
192 | # On some systems we have to add -ldl to link with dpdk | |
193 | # | |
194 | # This code, at first, tries to link without -ldl (""), | |
195 | # then adds it and tries again. | |
196 | # Before each attempt the search cache must be unset, | |
197 | # otherwise autoconf will stick with the old result | |
198 | ||
199 | found=false | |
200 | save_LIBS=$LIBS | |
201 | for extras in "" "-ldl"; do | |
3c94676c | 202 | LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB" |
c1223b11 DDP |
203 | AC_LINK_IFELSE( |
204 | [AC_LANG_PROGRAM([#include <rte_config.h> | |
205 | #include <rte_eal.h>], | |
206 | [int rte_argc; char ** rte_argv; | |
207 | rte_eal_init(rte_argc, rte_argv);])], | |
208 | [found=true]) | |
209 | if $found; then | |
210 | break | |
211 | fi | |
212 | done | |
213 | if $found; then :; else | |
214 | AC_MSG_ERROR([cannot link with dpdk]) | |
215 | fi | |
95626395 TG |
216 | CFLAGS="$ovs_save_CFLAGS" |
217 | LDFLAGS="$ovs_save_LDFLAGS" | |
218 | OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR" | |
543342a4 | 219 | OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3" |
8a9562d2 | 220 | |
3c94676c | 221 | # DPDK pmd drivers are not linked unless --whole-archive is used. |
d7310583 DDP |
222 | # |
223 | # This happens because the rest of the DPDK code doesn't use any symbol in | |
224 | # the pmd driver objects, and the drivers register themselves using an | |
225 | # __attribute__((constructor)) function. | |
226 | # | |
227 | # These options are specified inside a single -Wl directive to prevent | |
228 | # autotools from reordering them. | |
3c94676c | 229 | DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive |
9475dfeb | 230 | AC_SUBST([DPDK_vswitchd_LDFLAGS]) |
8a9562d2 | 231 | AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.]) |
7d1ced01 | 232 | |
8a9562d2 PS |
233 | else |
234 | RTE_SDK= | |
235 | fi | |
236 | ||
237 | AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK") | |
238 | ]) | |
239 | ||
8828e5c7 | 240 | dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH]) |
064af421 BP |
241 | dnl |
242 | dnl Greps FILE for REGEX. If it matches, runs IF-MATCH, otherwise IF-NO-MATCH. | |
8828e5c7 BP |
243 | dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with |
244 | dnl <REGEX> translated to uppercase. | |
064af421 BP |
245 | AC_DEFUN([OVS_GREP_IFELSE], [ |
246 | AC_MSG_CHECKING([whether $2 matches in $1]) | |
7507ec48 JG |
247 | if test -f $1; then |
248 | grep '$2' $1 >/dev/null 2>&1 | |
249 | status=$? | |
250 | case $status in | |
251 | 0) | |
252 | AC_MSG_RESULT([yes]) | |
8828e5c7 | 253 | m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3]) |
7507ec48 JG |
254 | ;; |
255 | 1) | |
256 | AC_MSG_RESULT([no]) | |
257 | $4 | |
258 | ;; | |
259 | *) | |
260 | AC_MSG_ERROR([grep exited with status $status]) | |
261 | ;; | |
262 | esac | |
263 | else | |
264 | AC_MSG_RESULT([file not found]) | |
265 | $4 | |
266 | fi | |
064af421 BP |
267 | ]) |
268 | ||
13dd4a97 JS |
269 | dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH]) |
270 | dnl | |
271 | dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the | |
272 | dnl structure definition. If this is successful, runs IF-MATCH, otherwise | |
273 | dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to | |
274 | dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX> | |
275 | dnl translated to uppercase. | |
276 | AC_DEFUN([OVS_FIND_FIELD_IFELSE], [ | |
277 | AC_MSG_CHECKING([whether $2 has member $3 in $1]) | |
278 | if test -f $1; then | |
83a27884 | 279 | awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null |
13dd4a97 JS |
280 | status=$? |
281 | case $status in | |
282 | 0) | |
283 | AC_MSG_RESULT([yes]) | |
284 | m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4]) | |
285 | ;; | |
286 | 1) | |
287 | AC_MSG_RESULT([no]) | |
288 | $5 | |
289 | ;; | |
290 | *) | |
291 | AC_MSG_ERROR([grep exited with status $status]) | |
292 | ;; | |
293 | esac | |
294 | else | |
295 | AC_MSG_RESULT([file not found]) | |
296 | $5 | |
297 | fi | |
298 | ]) | |
299 | ||
064af421 BP |
300 | dnl OVS_DEFINE(NAME) |
301 | dnl | |
302 | dnl Defines NAME to 1 in kcompat.h. | |
303 | AC_DEFUN([OVS_DEFINE], [ | |
22bcc0e7 | 304 | echo '#define $1 1' >> datapath/linux/kcompat.h.new |
064af421 BP |
305 | ]) |
306 | ||
e3438006 | 307 | dnl OVS_CHECK_LINUX_COMPAT |
064af421 BP |
308 | dnl |
309 | dnl Runs various Autoconf checks on the Linux 2.6 kernel source in | |
e3438006 BP |
310 | dnl the directory in $KBUILD. |
311 | AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [ | |
22bcc0e7 JG |
312 | rm -f datapath/linux/kcompat.h.new |
313 | mkdir -p datapath/linux | |
314 | : > datapath/linux/kcompat.h.new | |
4aa13c0c | 315 | |
e3438006 | 316 | OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,], |
25fb3596 JG |
317 | [OVS_DEFINE([HAVE_CSUM_COPY_DBG])]) |
318 | ||
e3438006 | 319 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST]) |
4303ec34 | 320 | OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL]) |
4aa13c0c | 321 | |
d923a695 | 322 | OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random]) |
e2f3178f | 323 | OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy]) |
d923a695 JG |
324 | |
325 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto]) | |
ec96e663 | 326 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside]) |
d923a695 | 327 | |
e3438006 | 328 | OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast]) |
46d69d18 | 329 | OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset]) |
2ea82414 PS |
330 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry], |
331 | [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])]) | |
13dd4a97 JS |
332 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net], |
333 | [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])]) | |
920fc091 | 334 | OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment]) |
4aa13c0c | 335 | |
fdce83a3 PS |
336 | OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net], |
337 | [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])]) | |
e3438006 BP |
338 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro]) |
339 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats]) | |
340 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu]) | |
42d5dd95 TG |
341 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment]) |
342 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol]) | |
d1890de5 | 343 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t]) |
e2f3178f | 344 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats]) |
572e54fa FL |
345 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_rx_handler_register]) |
346 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_extended]) | |
347 | OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [rx_handler_func_t.*pskb], | |
348 | [OVS_DEFINE([HAVE_RX_HANDLER_PSKB])]) | |
cd7330d0 PS |
349 | OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops], |
350 | [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])]) | |
e2f3178f PK |
351 | |
352 | OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32]) | |
4aa13c0c | 353 | |
e3438006 BP |
354 | OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [], |
355 | [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], | |
cf6cb3a2 | 356 | [rcu_read_lock_held])]) |
8fa52250 | 357 | OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held]) |
cf6cb3a2 | 358 | |
6a33828d BP |
359 | # Check for the proto_data_valid member in struct sk_buff. The [^@] |
360 | # is necessary because some versions of this header remove the | |
361 | # member but retain the kerneldoc comment that describes it (which | |
362 | # starts with @). The brackets must be doubled because of m4 | |
363 | # quoting rules. | |
e3438006 | 364 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid], |
6a33828d | 365 | [OVS_DEFINE([HAVE_PROTO_DATA_VALID])]) |
ccb75a28 | 366 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset]) |
d23239a2 | 367 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list]) |
60c4904f | 368 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash]) |
5640cbd8 JG |
369 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash], |
370 | [OVS_DEFINE([HAVE_U16_RXHASH])]) | |
e3438006 | 371 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(], |
85444c3f | 372 | [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])]) |
e3438006 | 373 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], |
8828e5c7 | 374 | [skb_copy_from_linear_data_offset]) |
b9c15df9 PS |
375 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], |
376 | [skb_reset_tail_pointer]) | |
e3438006 BP |
377 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head]) |
378 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header], | |
4aa13c0c | 379 | [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])]) |
e3438006 | 380 | OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr], |
d31f1109 | 381 | [OVS_DEFINE([HAVE_ICMP6_HDR])]) |
e3438006 | 382 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro], |
4aa13c0c | 383 | [OVS_DEFINE([HAVE_SKB_WARN_LRO])]) |
e3438006 | 384 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb]) |
6c4ea27c | 385 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page]) |
da4bbeb7 | 386 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list]) |
0aa6fda7 | 387 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc]) |
d923a695 | 388 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len]) |
dc0d542d | 389 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone]) |
1edc458d | 390 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags]) |
e2f3178f PK |
391 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash]) |
392 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash]) | |
705e9260 PS |
393 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(], |
394 | [OVS_DEFINE([HAVE_SKB_ZEROCOPY])]) | |
75e93287 FL |
395 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash], |
396 | [OVS_DEFINE([HAVE_L4_RXHASH])]) | |
5cce04b6 | 397 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable]) |
97894370 TG |
398 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop]) |
399 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push]) | |
4aa13c0c | 400 | |
e3438006 | 401 | OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool], |
4aa13c0c | 402 | [OVS_DEFINE([HAVE_BOOL_TYPE])]) |
e3438006 | 403 | OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum], |
e215ebca | 404 | [OVS_DEFINE([HAVE_CSUM_TYPES])]) |
8dbe1f9f PS |
405 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum], |
406 | [OVS_DEFINE([HAVE_CSUM_TYPES])]) | |
4aa13c0c | 407 | |
e3438006 BP |
408 | OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4]) |
409 | OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold]) | |
4aa13c0c | 410 | |
114fce23 SG |
411 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners]) |
412 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset]) | |
14002a59 | 413 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops]) |
705e9260 | 414 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast]) |
6233a1bd TG |
415 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock], |
416 | [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])]) | |
c623ba49 | 417 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse]) |
13dd4a97 JS |
418 | OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family], |
419 | [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])]) | |
420 | ||
421 | OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], | |
422 | [genl_multicast_group], [id]) | |
fdce83a3 | 423 | OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr]) |
13dd4a97 | 424 | |
cc1d0dea | 425 | OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register]) |
8abaa53c | 426 | OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH]) |
e3438006 | 427 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16]) |
42d5dd95 TG |
428 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16]) |
429 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32]) | |
430 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64]) | |
dd693f9b | 431 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr]) |
e3438006 | 432 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested]) |
0fcc086d | 433 | OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last]) |
4aa13c0c | 434 | |
c4e976db JG |
435 | OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum]) |
436 | ||
e3438006 | 437 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD], |
431488e6 | 438 | [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])]) |
1f649f1c | 439 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto]) |
17e3889f TG |
440 | OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag]) |
441 | ||
431488e6 | 442 | |
09f27436 JG |
443 | OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq]) |
444 | ||
f285d3e7 TG |
445 | OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook], |
446 | [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])]) | |
3174a818 TG |
447 | OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata], |
448 | [OVS_DEFINE([HAVE_VXLAN_METADATA])]) | |
f6a0c895 | 449 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port], |
13dd4a97 JS |
450 | [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net], |
451 | [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])]) | |
452 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check]) | |
453 | OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum]) | |
f6a0c895 TG |
454 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1], |
455 | [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])]) | |
13dd4a97 JS |
456 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM], |
457 | [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])]) | |
458 | OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM], | |
459 | [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])]) | |
f6a0c895 TG |
460 | OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN], |
461 | [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])]) | |
f285d3e7 | 462 | |
21a719d6 FL |
463 | OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6], |
464 | [OVS_DEFINE([HAVE_RHEL6_PER_CPU])]) | |
465 | ||
22bcc0e7 JG |
466 | if cmp -s datapath/linux/kcompat.h.new \ |
467 | datapath/linux/kcompat.h >/dev/null 2>&1; then | |
468 | rm datapath/linux/kcompat.h.new | |
064af421 | 469 | else |
22bcc0e7 | 470 | mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h |
064af421 BP |
471 | fi |
472 | ]) | |
473 | ||
474 | dnl Checks for net/if_packet.h. | |
475 | AC_DEFUN([OVS_CHECK_IF_PACKET], | |
476 | [AC_CHECK_HEADER([net/if_packet.h], | |
477 | [HAVE_IF_PACKET=yes], | |
478 | [HAVE_IF_PACKET=no]) | |
479 | AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes]) | |
480 | if test "$HAVE_IF_PACKET" = yes; then | |
481 | AC_DEFINE([HAVE_IF_PACKET], [1], | |
482 | [Define to 1 if net/if_packet.h is available.]) | |
483 | fi]) | |
484 | ||
f6eb6b20 | 485 | dnl Checks for net/if_dl.h. |
d30e714c | 486 | dnl |
d23fa2ed YT |
487 | dnl (We use this as a proxy for checking whether we're building on FreeBSD |
488 | dnl or NetBSD.) | |
9360d9b7 EM |
489 | AC_DEFUN([OVS_CHECK_IF_DL], |
490 | [AC_CHECK_HEADER([net/if_dl.h], | |
491 | [HAVE_IF_DL=yes], | |
492 | [HAVE_IF_DL=no]) | |
493 | AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes]) | |
494 | if test "$HAVE_IF_DL" = yes; then | |
495 | AC_DEFINE([HAVE_IF_DL], [1], | |
496 | [Define to 1 if net/if_dl.h is available.]) | |
d30e714c | 497 | |
d23fa2ed | 498 | # On these platforms we use libpcap to access network devices. |
d30e714c | 499 | AC_SEARCH_LIBS([pcap_open_live], [pcap]) |
9360d9b7 EM |
500 | fi]) |
501 | ||
e50097d2 BP |
502 | dnl Checks for buggy strtok_r. |
503 | dnl | |
504 | dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling | |
505 | dnl with optimization that can cause segfaults: | |
506 | dnl | |
507 | dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614. | |
508 | AC_DEFUN([OVS_CHECK_STRTOK_R], | |
509 | [AC_CACHE_CHECK( | |
510 | [whether strtok_r macro segfaults on some inputs], | |
511 | [ovs_cv_strtok_r_bug], | |
512 | [AC_RUN_IFELSE( | |
513 | [AC_LANG_PROGRAM([#include <stdio.h> | |
514 | #include <string.h> | |
515 | ], | |
416e7132 BP |
516 | [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8 |
517 | /* Assume bug is present, because relatively minor | |
518 | changes in compiler settings (e.g. optimization | |
519 | level) can make it crop up. */ | |
520 | return 1; | |
521 | #else | |
522 | char string[] = ":::"; | |
e50097d2 BP |
523 | char *save_ptr = (char *) 0xc0ffee; |
524 | char *token1, *token2; | |
525 | token1 = strtok_r(string, ":", &save_ptr); | |
526 | token2 = strtok_r(NULL, ":", &save_ptr); | |
5819a7cd | 527 | freopen ("/dev/null", "w", stdout); |
e50097d2 BP |
528 | printf ("%s %s\n", token1, token2); |
529 | return 0; | |
416e7132 | 530 | #endif |
e50097d2 BP |
531 | ]])], |
532 | [ovs_cv_strtok_r_bug=no], | |
533 | [ovs_cv_strtok_r_bug=yes], | |
534 | [ovs_cv_strtok_r_bug=yes])]) | |
535 | if test $ovs_cv_strtok_r_bug = yes; then | |
536 | AC_DEFINE([HAVE_STRTOK_R_BUG], [1], | |
537 | [Define if strtok_r macro segfaults on some inputs]) | |
538 | fi | |
539 | ]) | |
540 | ||
064af421 BP |
541 | dnl ---------------------------------------------------------------------- |
542 | dnl These macros are from GNU PSPP, with the following original license: | |
543 | dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc. | |
544 | dnl This file is free software; the Free Software Foundation | |
545 | dnl gives unlimited permission to copy and/or distribute it, | |
546 | dnl with or without modifications, as long as this notice is preserved. | |
547 | ||
50194820 | 548 | AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl |
7c96151e | 549 | m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl |
064af421 BP |
550 | AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name], |
551 | [ovs_save_CFLAGS="$CFLAGS" | |
50194820 BP |
552 | dnl Include -Werror in the compiler options, because without -Werror |
553 | dnl clang's GCC-compatible compiler driver does not return a failure | |
554 | dnl exit status even though it complains about options it does not | |
555 | dnl understand. | |
c2deac54 YT |
556 | dnl |
557 | dnl Also, check stderr as gcc exits with status 0 for options | |
558 | dnl rejected at getopt level. | |
559 | dnl % touch /tmp/a.c | |
560 | dnl % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $? | |
561 | dnl gcc: unrecognized option '-Qunused-arguments' | |
562 | dnl 0 | |
563 | dnl % | |
50194820 | 564 | CFLAGS="$CFLAGS $WERROR $1" |
c2deac54 | 565 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no]) |
064af421 BP |
566 | CFLAGS="$ovs_save_CFLAGS"]) |
567 | if test $ovs_cv_name = yes; then | |
83f6c050 | 568 | m4_if([$2], [], [:], [$2]) |
064af421 BP |
569 | else |
570 | m4_if([$3], [], [:], [$3]) | |
571 | fi | |
572 | ]) | |
573 | ||
50194820 BP |
574 | dnl OVS_CHECK_WERROR |
575 | dnl | |
576 | dnl Check whether the C compiler accepts -Werror. | |
577 | dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string. | |
578 | AC_DEFUN([OVS_CHECK_WERROR], | |
579 | [WERROR= | |
580 | _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])]) | |
581 | ||
582 | dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED]) | |
583 | dnl Check whether the given C compiler OPTION is accepted. | |
584 | dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED. | |
585 | AC_DEFUN([OVS_CHECK_CC_OPTION], | |
586 | [AC_REQUIRE([OVS_CHECK_WERROR]) | |
587 | _OVS_CHECK_CC_OPTION([$1], [$2], [$3])]) | |
588 | ||
064af421 BP |
589 | dnl OVS_ENABLE_OPTION([OPTION]) |
590 | dnl Check whether the given C compiler OPTION is accepted. | |
d161c099 | 591 | dnl If so, add it to WARNING_FLAGS. |
064af421 BP |
592 | dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement]) |
593 | AC_DEFUN([OVS_ENABLE_OPTION], | |
d161c099 BP |
594 | [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"]) |
595 | AC_SUBST([WARNING_FLAGS])]) | |
c72e245a BP |
596 | |
597 | dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL]) | |
598 | dnl Check whether the given C compiler OPTION is accepted. | |
599 | dnl If so, enable the given Automake CONDITIONAL. | |
600 | ||
601 | dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED]) | |
602 | AC_DEFUN([OVS_CONDITIONAL_CC_OPTION], | |
603 | [OVS_CHECK_CC_OPTION( | |
604 | [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no]) | |
605 | AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])]) | |
064af421 | 606 | dnl ---------------------------------------------------------------------- |
ed2d4f6a BP |
607 | |
608 | dnl Check for too-old XenServer. | |
609 | AC_DEFUN([OVS_CHECK_XENSERVER_VERSION], | |
610 | [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion], | |
611 | [if test -e /etc/redhat-release; then | |
612 | ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release` | |
613 | fi | |
614 | if test -z "$ovs_cv_xsversion"; then | |
615 | ovs_cv_xsversion=none | |
616 | fi]) | |
617 | case $ovs_cv_xsversion in | |
618 | none) | |
619 | ;; | |
620 | ||
621 | [[1-9]][[0-9]]* | dnl XenServer 10 or later | |
622 | [[6-9]]* | dnl XenServer 6 or later | |
623 | 5.[[7-9]]* | dnl XenServer 5.7 or later | |
624 | 5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.1000 or later | |
625 | 5.6.[[2-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.200 or later | |
626 | 5.6.1[[0-9]][[0-9]]) dnl Xenserver 5.6.100 or later | |
627 | ;; | |
628 | ||
629 | *) | |
630 | AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported. (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)]) | |
631 | ;; | |
632 | esac]) | |
29d935d6 BP |
633 | |
634 | dnl OVS_MAKE_HAS_IF([if-true], [if-false]) | |
635 | dnl | |
636 | dnl Checks whether make has the GNU make $(if condition,then,else) extension. | |
637 | dnl Runs 'if-true' if so, 'if-false' otherwise. | |
372d58a4 | 638 | AC_DEFUN([OVS_CHECK_MAKE_IF], |
29d935d6 BP |
639 | [AC_CACHE_CHECK( |
640 | [whether ${MAKE-make} has GNU make \$(if) extension], | |
641 | [ovs_cv_gnu_make_if], | |
642 | [cat <<'EOF' > conftest.mk | |
643 | conftest.out: | |
380f86e4 | 644 | echo $(if x,y,z) > conftest.out |
29d935d6 BP |
645 | .PHONY: all |
646 | EOF | |
647 | rm -f conftest.out | |
648 | AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1 | |
649 | ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1 | |
650 | AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1 | |
651 | cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1 | |
652 | result=`cat conftest.out` | |
653 | rm -f conftest.mk conftest.out | |
654 | if test "X$result" = "Xy"; then | |
655 | ovs_cv_gnu_make_if=yes | |
656 | else | |
657 | ovs_cv_gnu_make_if=no | |
372d58a4 | 658 | fi])]) |
29d935d6 | 659 | |
b4e1bf8b BP |
660 | dnl OVS_CHECK_GNU_MAKE |
661 | dnl | |
662 | dnl Checks whether make is GNU make (because Linux kernel Makefiles | |
663 | dnl only work with GNU make). | |
664 | AC_DEFUN([OVS_CHECK_GNU_MAKE], | |
665 | [AC_CACHE_CHECK( | |
666 | [whether ${MAKE-make} is GNU make], | |
667 | [ovs_cv_gnu_make], | |
668 | [rm -f conftest.out | |
669 | AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1 | |
670 | ${MAKE-make} --version >conftest.out 2>&1 | |
671 | cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1 | |
672 | result=`cat conftest.out` | |
673 | rm -f conftest.mk conftest.out | |
674 | ||
675 | case $result in # ( | |
676 | GNU*) ovs_cv_gnu_make=yes ;; # ( | |
677 | *) ovs_cv_gnu_make=no ;; | |
678 | esac]) | |
679 | AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])]) | |
680 | ||
643c0c34 BP |
681 | dnl OVS_CHECK_SPARSE_TARGET |
682 | dnl | |
683 | dnl The "cgcc" script from "sparse" isn't very good at detecting the | |
684 | dnl target for which the code is being built. This helps it out. | |
685 | AC_DEFUN([OVS_CHECK_SPARSE_TARGET], | |
686 | [AC_CACHE_CHECK( | |
687 | [target hint for cgcc], | |
688 | [ac_cv_sparse_target], | |
689 | [AS_CASE([`$CC -dumpmachine 2>/dev/null`], | |
690 | [i?86-* | athlon-*], [ac_cv_sparse_target=x86], | |
691 | [x86_64-*], [ac_cv_sparse_target=x86_64], | |
692 | [ac_cv_sparse_target=other])]) | |
693 | AS_CASE([$ac_cv_sparse_target], | |
694 | [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86], | |
695 | [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64], | |
696 | [SPARSEFLAGS= CGCCFLAGS=]) | |
697 | AC_SUBST([SPARSEFLAGS]) | |
698 | AC_SUBST([CGCCFLAGS])]) | |
699 | ||
32e96ab7 AZ |
700 | dnl OVS_SPARSE_EXTRA_INCLUDES |
701 | dnl | |
702 | dnl The cgcc script from "sparse" does not search gcc's default | |
703 | dnl search path. Get the default search path from GCC and pass | |
704 | dnl them to sparse. | |
705 | AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES], | |
706 | AC_SUBST([SPARSE_EXTRA_INCLUDES], | |
707 | [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] )) | |
708 | ||
29d935d6 BP |
709 | dnl OVS_ENABLE_SPARSE |
710 | AC_DEFUN([OVS_ENABLE_SPARSE], | |
643c0c34 | 711 | [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET]) |
372d58a4 | 712 | AC_REQUIRE([OVS_CHECK_MAKE_IF]) |
32e96ab7 | 713 | AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES]) |
372d58a4 BP |
714 | : ${SPARSE=sparse} |
715 | AC_SUBST([SPARSE]) | |
716 | AC_CONFIG_COMMANDS_PRE( | |
717 | [if test $ovs_cv_gnu_make_if = yes; then | |
38b7a52b | 718 | CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')' |
372d58a4 | 719 | fi])]) |
8a8cd0ac BP |
720 | |
721 | dnl OVS_PTHREAD_SET_NAME | |
722 | dnl | |
723 | dnl This checks for three known variants of pthreads functions for setting | |
724 | dnl the name of the current thread: | |
725 | dnl | |
726 | dnl glibc: int pthread_setname_np(pthread_t, const char *name); | |
727 | dnl NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg); | |
728 | dnl FreeBSD: int pthread_set_name_np(pthread_t, const char *name); | |
729 | dnl | |
730 | dnl For glibc and FreeBSD, the arguments are just a thread and its name. For | |
731 | dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to | |
732 | dnl provide to it. | |
733 | dnl | |
734 | dnl This macro defines: | |
735 | dnl | |
736 | dnl glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP | |
737 | dnl NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP | |
738 | dnl FreeBSD: HAVE_PTHREAD_SET_NAME_NP | |
739 | AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME], | |
740 | [AC_CHECK_FUNCS([pthread_set_name_np]) | |
741 | if test $ac_cv_func_pthread_set_name_np != yes; then | |
742 | AC_CACHE_CHECK( | |
743 | [for pthread_setname_np() variant], | |
744 | [ovs_cv_pthread_setname_np], | |
745 | [AC_LINK_IFELSE( | |
a0903134 | 746 | [AC_LANG_PROGRAM([#include <pthread.h> |
8a8cd0ac | 747 | ], [pthread_setname_np(pthread_self(), "name");])], |
a0903134 | 748 | [ovs_cv_pthread_setname_np=glibc], |
8a8cd0ac | 749 | [AC_LINK_IFELSE( |
a0903134 | 750 | [AC_LANG_PROGRAM([#include <pthread.h> |
8a8cd0ac BP |
751 | ], [pthread_setname_np(pthread_self(), "%s", "name");])], |
752 | [ovs_cv_pthread_setname_np=netbsd], | |
a0903134 | 753 | [ovs_cv_pthread_setname_np=none])])]) |
8a8cd0ac BP |
754 | case $ovs_cv_pthread_setname_np in # ( |
755 | glibc) | |
a0903134 YT |
756 | AC_DEFINE( |
757 | [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1], | |
758 | [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).]) | |
759 | ;; # ( | |
8a8cd0ac | 760 | netbsd) |
a0903134 YT |
761 | AC_DEFINE( |
762 | [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1], | |
763 | [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).]) | |
764 | ;; | |
8a8cd0ac BP |
765 | esac |
766 | fi]) | |
5020f5f0 BP |
767 | |
768 | dnl OVS_CHECK_LINUX_HOST. | |
769 | dnl | |
770 | dnl Checks whether we're building for a Linux host, based on the presence of | |
771 | dnl the __linux__ preprocessor symbol, and sets up an Automake conditional | |
772 | dnl LINUX based on the result. | |
773 | AC_DEFUN([OVS_CHECK_LINUX_HOST], | |
774 | [AC_CACHE_CHECK( | |
775 | [whether __linux__ is defined], | |
776 | [ovs_cv_linux], | |
777 | [AC_COMPILE_IFELSE( | |
778 | [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])], | |
779 | [ovs_cv_linux=true], | |
780 | [ovs_cv_linux=false])]) | |
781 | AM_CONDITIONAL([LINUX], [$ovs_cv_linux])]) |