]> git.proxmox.com Git - mirror_ovs.git/blame - acinclude.m4
projects / mirror_ovs.git / blame
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (incremental) | history | HEAD
Include headers where ovs_rundir is used.
[mirror_ovs.git] / acinclude.m4
CommitLineData
064af421
BP		 1# -*- autoconf -*-
2
416e7132 3# Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
064af421 4#
a14bc59f
BP		 5# Licensed under the Apache License, Version 2.0 (the "License");
6# you may not use this file except in compliance with the License.
7# You may obtain a copy of the License at:
064af421 8#
a14bc59f
BP		 9# http://www.apache.org/licenses/LICENSE-2.0
10#
11# Unless required by applicable law or agreed to in writing, software
12# distributed under the License is distributed on an "AS IS" BASIS,
13# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14# See the License for the specific language governing permissions and
15# limitations under the License.
064af421 16
a64e37a1
BP		 17dnl OVS_ENABLE_WERROR
18AC_DEFUN([OVS_ENABLE_WERROR],
19 [AC_ARG_ENABLE(
20 [Werror],
21 [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
22 [], [enable_Werror=no])
23 AC_CONFIG_COMMANDS_PRE(
24 [if test "X$enable_Werror" = Xyes; then
95626395 25 OVS_CFLAGS="$OVS_CFLAGS -Werror"
a64e37a1
BP		 26 fi])])
27
e3438006 28dnl OVS_CHECK_LINUX
064af421
BP		 29dnl
30dnl Configure linux kernel source tree
e3438006 31AC_DEFUN([OVS_CHECK_LINUX], [
8a2d6596
BP		 32 AC_ARG_WITH([linux],
33 [AC_HELP_STRING([--with-linux=/path/to/linux],
34 [Specify the Linux kernel build directory])])
35 AC_ARG_WITH([linux-source],
36 [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
37 [Specify the Linux kernel source directory
a0903134
YT		 38 (usually figured out automatically from build
39 directory)])])
8a2d6596
BP		 40
41 # Deprecated equivalents to --with-linux, --with-linux-source.
42 AC_ARG_WITH([l26])
43 AC_ARG_WITH([l26-source])
44
45 if test X"$with_linux" != X; then
46 KBUILD=$with_linux
47 elif test X"$with_l26" != X; then
48 KBUILD=$with_l26
49 AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
50 else
51 KBUILD=
52 fi
53
54 if test X"$KBUILD" != X; then
55 if test X"$with_linux_source" != X; then
56 KSRC=$with_linux_source
57 elif test X"$with_l26_source" != X; then
58 KSRC=$with_l26_source
59 AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
0a89c170
BP		 60 else
61 KSRC=
8a2d6596
BP		 62 fi
63 elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
64 AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
65 fi
66
e3438006
BP		 67 if test -n "$KBUILD"; then
68 KBUILD=`eval echo "$KBUILD"`
69 case $KBUILD in
0b6d72fc 70 /*) ;;
e3438006 71 *) KBUILD=`pwd`/$KBUILD ;;
0b6d72fc 72 esac
064af421 73
7c9e113b
BP		 74 # The build directory is what the user provided.
75 # Make sure that it exists.
8a2d6596 76 AC_MSG_CHECKING([for Linux build directory])
e3438006 77 if test -d "$KBUILD"; then
a0903134
YT		 78 AC_MSG_RESULT([$KBUILD])
79 AC_SUBST(KBUILD)
064af421 80 else
a0903134
YT		 81 AC_MSG_RESULT([no])
82 AC_ERROR([source dir $KBUILD doesn't exist])
064af421
BP		 83 fi
84
7c9e113b 85 # Debian breaks kernel headers into "source" header and "build" headers.
e3438006 86 # We want the source headers, but $KBUILD gives us the "build" headers.
7c9e113b 87 # Use heuristics to find the source headers.
8a2d6596 88 AC_MSG_CHECKING([for Linux source directory])
e3438006
BP		 89 if test -n "$KSRC"; then
90 KSRC=`eval echo "$KSRC"`
91 case $KSRC in
f5fb5de6 92 /*) ;;
e3438006 93 *) KSRC=`pwd`/$KSRC ;;
b57f675c 94 esac
e3438006 95 if test ! -e $KSRC/include/linux/kernel.h; then
53319f95 96 AC_MSG_ERROR([$KSRC is not a kernel source directory])
f5fb5de6
BP		 97 fi
98 else
e3438006
BP		 99 KSRC=$KBUILD
100 if test ! -e $KSRC/include/linux/kernel.h; then
fe0731b1
BP		 101 # Debian kernel build Makefiles tend to include a line of the form:
102 # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
103 # First try to extract the source directory from this line.
104 KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
105 if test ! -e "$KSRC"/include/linux/kernel.h; then
106 # Didn't work. Fall back to name-based heuristics that used to work.
107 case `echo "$KBUILD" | sed 's,/*$,,'` in # (
108 */build)
109 KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
110 ;; # (
111 *)
112 KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
113 ;;
114 esac
115 fi
f5fb5de6 116 fi
fe0731b1 117 if test ! -e "$KSRC"/include/linux/kernel.h; then
8a2d6596 118 AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
7c9e113b
BP		 119 fi
120 fi
e3438006 121 AC_MSG_RESULT([$KSRC])
7c9e113b
BP		 122
123 AC_MSG_CHECKING([for kernel version])
71fe9970 124 version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
e3438006
BP		 125 patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
126 sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
71fe9970 127 if test X"$version" = X || test X"$patchlevel" = X; then
7c9e113b 128 AC_ERROR([cannot determine kernel version])
71fe9970
BP		 129 elif test X"$sublevel" = X; then
130 kversion=$version.$patchlevel
131 else
132 kversion=$version.$patchlevel.$sublevel
7c9e113b 133 fi
71fe9970
BP		 134 AC_MSG_RESULT([$kversion])
135
3afcde43 136 if test "$version" -ge 4; then
c0cddcec 137 if test "$version" = 4 && test "$patchlevel" -le 1; then
3afcde43 138 : # Linux 4.x
d76aabea 139 else
c0cddcec 140 AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.1.x is not supported (please refer to the FAQ for advice)])
d76aabea 141 fi
3afcde43
JS		 142 elif test "$version" = 3; then
143 : # Linux 3.x
71fe9970 144 else
d76aabea
PS		 145 if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
146 AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
7c9e113b 147 else
d76aabea 148 : # Linux 2.6.x
7c9e113b 149 fi
064af421 150 fi
2520f452
IY		 151 if (test ! -e "$KBUILD"/include/linux/version.h && \
152 test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
e3438006
BP		 153 (test ! -e "$KBUILD"/include/linux/autoconf.h && \
154 test ! -e "$KBUILD"/include/generated/autoconf.h); then
a0903134 155 AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
064af421 156 fi
e3438006 157 OVS_CHECK_LINUX_COMPAT
064af421 158 fi
e3438006 159 AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
064af421
BP		 160])
161
8a9562d2
PS		 162dnl OVS_CHECK_DPDK
163dnl
164dnl Configure DPDK source tree
165AC_DEFUN([OVS_CHECK_DPDK], [
166 AC_ARG_WITH([dpdk],
167 [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
e2e54517 168 [Specify the DPDK build directory])])
8a9562d2
PS		 169
170 if test X"$with_dpdk" != X; then
171 RTE_SDK=$with_dpdk
172
173 DPDK_INCLUDE=$RTE_SDK/include
174 DPDK_LIB_DIR=$RTE_SDK/lib
18f777b2 175 DPDK_LIB="-ldpdk"
10d01ad2 176 DPDK_EXTRA_LIB=""
613750ab 177 RTE_SDK_FULL=`readlink -f $RTE_SDK`
10d01ad2 178
693e1138 179 AC_COMPILE_IFELSE(
613750ab 180 [AC_LANG_PROGRAM([#include <$RTE_SDK_FULL/include/rte_config.h>
693e1138
GM		 181#if !RTE_LIBRTE_VHOST_USER
182#error
183#endif], [])],
10d01ad2
DDP		 184 [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
185 DPDK_EXTRA_LIB="-lfuse"])
8a9562d2 186
95626395
TG		 187 ovs_save_CFLAGS="$CFLAGS"
188 ovs_save_LDFLAGS="$LDFLAGS"
c1223b11
DDP		 189 LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
190 CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
191
192 # On some systems we have to add -ldl to link with dpdk
193 #
194 # This code, at first, tries to link without -ldl (""),
195 # then adds it and tries again.
196 # Before each attempt the search cache must be unset,
197 # otherwise autoconf will stick with the old result
198
199 found=false
200 save_LIBS=$LIBS
201 for extras in "" "-ldl"; do
3c94676c 202 LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
c1223b11
DDP		 203 AC_LINK_IFELSE(
204 [AC_LANG_PROGRAM([#include <rte_config.h>
205 #include <rte_eal.h>],
206 [int rte_argc; char ** rte_argv;
207 rte_eal_init(rte_argc, rte_argv);])],
208 [found=true])
209 if $found; then
210 break
211 fi
212 done
213 if $found; then :; else
214 AC_MSG_ERROR([cannot link with dpdk])
215 fi
95626395
TG		 216 CFLAGS="$ovs_save_CFLAGS"
217 LDFLAGS="$ovs_save_LDFLAGS"
218 OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
543342a4 219 OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
8a9562d2 220
3c94676c 221 # DPDK pmd drivers are not linked unless --whole-archive is used.
d7310583
DDP		 222 #
223 # This happens because the rest of the DPDK code doesn't use any symbol in
224 # the pmd driver objects, and the drivers register themselves using an
225 # __attribute__((constructor)) function.
226 #
227 # These options are specified inside a single -Wl directive to prevent
228 # autotools from reordering them.
3c94676c 229 DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
9475dfeb 230 AC_SUBST([DPDK_vswitchd_LDFLAGS])
8a9562d2 231 AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
7d1ced01 232
8a9562d2
PS		 233 else
234 RTE_SDK=
235 fi
236
237 AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
238])
239
8828e5c7 240dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
064af421
BP		 241dnl
242dnl Greps FILE for REGEX. If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
8828e5c7
BP		 243dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
244dnl <REGEX> translated to uppercase.
064af421
BP		 245AC_DEFUN([OVS_GREP_IFELSE], [
246 AC_MSG_CHECKING([whether $2 matches in $1])
7507ec48
JG		 247 if test -f $1; then
248 grep '$2' $1 >/dev/null 2>&1
249 status=$?
250 case $status in
251 0)
252 AC_MSG_RESULT([yes])
8828e5c7 253 m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
7507ec48
JG		 254 ;;
255 1)
256 AC_MSG_RESULT([no])
257 $4
258 ;;
259 *)
260 AC_MSG_ERROR([grep exited with status $status])
261 ;;
262 esac
263 else
264 AC_MSG_RESULT([file not found])
265 $4
266 fi
064af421
BP		 267])
268
13dd4a97
JS		 269dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
270dnl
271dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
272dnl structure definition. If this is successful, runs IF-MATCH, otherwise
273dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
274dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
275dnl translated to uppercase.
276AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
277 AC_MSG_CHECKING([whether $2 has member $3 in $1])
278 if test -f $1; then
83a27884 279 awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
13dd4a97
JS		 280 status=$?
281 case $status in
282 0)
283 AC_MSG_RESULT([yes])
284 m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
285 ;;
286 1)
287 AC_MSG_RESULT([no])
288 $5
289 ;;
290 *)
291 AC_MSG_ERROR([grep exited with status $status])
292 ;;
293 esac
294 else
295 AC_MSG_RESULT([file not found])
296 $5
297 fi
298])
299
064af421
BP		 300dnl OVS_DEFINE(NAME)
301dnl
302dnl Defines NAME to 1 in kcompat.h.
303AC_DEFUN([OVS_DEFINE], [
22bcc0e7 304 echo '#define $1 1' >> datapath/linux/kcompat.h.new
064af421
BP		 305])
306
e3438006 307dnl OVS_CHECK_LINUX_COMPAT
064af421
BP		 308dnl
309dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
e3438006
BP		 310dnl the directory in $KBUILD.
311AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
22bcc0e7
JG		 312 rm -f datapath/linux/kcompat.h.new
313 mkdir -p datapath/linux
314 : > datapath/linux/kcompat.h.new
4aa13c0c 315
e3438006 316 OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
25fb3596
JG		 317 [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
318
e3438006 319 OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
4303ec34 320 OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
4aa13c0c 321
d923a695 322 OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
e2f3178f 323 OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
d923a695
JG		 324
325 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
ec96e663 326 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
d923a695 327
e3438006 328 OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
46d69d18 329 OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
2ea82414
PS		 330 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
331 [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
13dd4a97
JS		 332 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
333 [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
920fc091 334 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment])
4aa13c0c 335
e3438006
BP		 336 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
337 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
338 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
42d5dd95
TG		 339 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
340 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
d1890de5 341 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
e2f3178f 342 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
572e54fa
FL		 343 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_rx_handler_register])
344 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_extended])
345 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [rx_handler_func_t.*pskb],
346 [OVS_DEFINE([HAVE_RX_HANDLER_PSKB])])
cd7330d0
PS		 347 OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
348 [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
e2f3178f
PK		 349
350 OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
4aa13c0c 351
e3438006
BP		 352 OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
353 [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
cf6cb3a2 354 [rcu_read_lock_held])])
8fa52250 355 OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
cf6cb3a2 356
6a33828d
BP		 357 # Check for the proto_data_valid member in struct sk_buff. The [^@]
358 # is necessary because some versions of this header remove the
359 # member but retain the kerneldoc comment that describes it (which
360 # starts with @). The brackets must be doubled because of m4
361 # quoting rules.
e3438006 362 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
6a33828d 363 [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
d23239a2 364 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
60c4904f 365 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
5640cbd8
JG		 366 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
367 [OVS_DEFINE([HAVE_U16_RXHASH])])
e3438006 368 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
85444c3f 369 [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
e3438006 370 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
8828e5c7 371 [skb_copy_from_linear_data_offset])
b9c15df9
PS		 372 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
373 [skb_reset_tail_pointer])
e3438006
BP		 374 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
375 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
4aa13c0c 376 [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
e3438006 377 OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
d31f1109 378 [OVS_DEFINE([HAVE_ICMP6_HDR])])
e3438006 379 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
4aa13c0c 380 [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
e3438006 381 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
6c4ea27c 382 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
da4bbeb7 383 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
0aa6fda7 384 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
d923a695 385 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
dc0d542d 386 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
1edc458d 387 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
e2f3178f
PK		 388 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
389 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
705e9260
PS		 390 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
391 [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
75e93287
FL		 392 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
393 [OVS_DEFINE([HAVE_L4_RXHASH])])
5cce04b6 394 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
97894370
TG		 395 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
396 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
4aa13c0c 397
e3438006 398 OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
4aa13c0c 399 [OVS_DEFINE([HAVE_BOOL_TYPE])])
e3438006 400 OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
e215ebca 401 [OVS_DEFINE([HAVE_CSUM_TYPES])])
8dbe1f9f
PS		 402 OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
403 [OVS_DEFINE([HAVE_CSUM_TYPES])])
4aa13c0c 404
e3438006
BP		 405 OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
406 OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
4aa13c0c 407
114fce23
SG		 408 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
409 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
14002a59 410 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
705e9260 411 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
6233a1bd
TG		 412 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
413 [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
c623ba49 414 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
13dd4a97
JS		 415 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
416 [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
417
418 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
419 [genl_multicast_group], [id])
420
cc1d0dea 421 OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
8abaa53c 422 OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
e3438006 423 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
42d5dd95
TG		 424 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
425 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
426 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
dd693f9b 427 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
e3438006 428 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
0fcc086d 429 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
4aa13c0c 430
c4e976db
JG		 431 OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
432
e3438006 433 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
431488e6 434 [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
1f649f1c 435 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
17e3889f
TG		 436 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
437
431488e6 438
09f27436
JG		 439 OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
440
f285d3e7
TG		 441 OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
442 [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
3174a818
TG		 443 OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
444 [OVS_DEFINE([HAVE_VXLAN_METADATA])])
f6a0c895 445 OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
13dd4a97
JS		 446 [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
447 [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
448 OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
449 OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
f6a0c895
TG		 450 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
451 [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
13dd4a97
JS		 452 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
453 [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
454 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
455 [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
f6a0c895
TG		 456 OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
457 [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
f285d3e7 458
21a719d6
FL		 459 OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
460 [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
461
22bcc0e7
JG		 462 if cmp -s datapath/linux/kcompat.h.new \
463 datapath/linux/kcompat.h >/dev/null 2>&1; then
464 rm datapath/linux/kcompat.h.new
064af421 465 else
22bcc0e7 466 mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
064af421
BP		 467 fi
468])
469
470dnl Checks for net/if_packet.h.
471AC_DEFUN([OVS_CHECK_IF_PACKET],
472 [AC_CHECK_HEADER([net/if_packet.h],
473 [HAVE_IF_PACKET=yes],
474 [HAVE_IF_PACKET=no])
475 AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
476 if test "$HAVE_IF_PACKET" = yes; then
477 AC_DEFINE([HAVE_IF_PACKET], [1],
478 [Define to 1 if net/if_packet.h is available.])
479 fi])
480
f6eb6b20 481dnl Checks for net/if_dl.h.
d30e714c 482dnl
d23fa2ed
YT		 483dnl (We use this as a proxy for checking whether we're building on FreeBSD
484dnl or NetBSD.)
9360d9b7
EM		 485AC_DEFUN([OVS_CHECK_IF_DL],
486 [AC_CHECK_HEADER([net/if_dl.h],
487 [HAVE_IF_DL=yes],
488 [HAVE_IF_DL=no])
489 AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
490 if test "$HAVE_IF_DL" = yes; then
491 AC_DEFINE([HAVE_IF_DL], [1],
492 [Define to 1 if net/if_dl.h is available.])
d30e714c 493
d23fa2ed 494 # On these platforms we use libpcap to access network devices.
d30e714c 495 AC_SEARCH_LIBS([pcap_open_live], [pcap])
9360d9b7
EM		 496 fi])
497
e50097d2
BP		 498dnl Checks for buggy strtok_r.
499dnl
500dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
501dnl with optimization that can cause segfaults:
502dnl
503dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
504AC_DEFUN([OVS_CHECK_STRTOK_R],
505 [AC_CACHE_CHECK(
506 [whether strtok_r macro segfaults on some inputs],
507 [ovs_cv_strtok_r_bug],
508 [AC_RUN_IFELSE(
509 [AC_LANG_PROGRAM([#include <stdio.h>
510 #include <string.h>
511 ],
416e7132
BP		 512 [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
513 /* Assume bug is present, because relatively minor
514 changes in compiler settings (e.g. optimization
515 level) can make it crop up. */
516 return 1;
517 #else
518 char string[] = ":::";
e50097d2
BP		 519 char *save_ptr = (char *) 0xc0ffee;
520 char *token1, *token2;
521 token1 = strtok_r(string, ":", &save_ptr);
522 token2 = strtok_r(NULL, ":", &save_ptr);
5819a7cd 523 freopen ("/dev/null", "w", stdout);
e50097d2
BP		 524 printf ("%s %s\n", token1, token2);
525 return 0;
416e7132 526 #endif
e50097d2
BP		 527 ]])],
528 [ovs_cv_strtok_r_bug=no],
529 [ovs_cv_strtok_r_bug=yes],
530 [ovs_cv_strtok_r_bug=yes])])
531 if test $ovs_cv_strtok_r_bug = yes; then
532 AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
533 [Define if strtok_r macro segfaults on some inputs])
534 fi
535])
536
064af421
BP		 537dnl ----------------------------------------------------------------------
538dnl These macros are from GNU PSPP, with the following original license:
539dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
540dnl This file is free software; the Free Software Foundation
541dnl gives unlimited permission to copy and/or distribute it,
542dnl with or without modifications, as long as this notice is preserved.
543
50194820 544AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
7c96151e 545 m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
064af421
BP		 546 AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
547 [ovs_save_CFLAGS="$CFLAGS"
50194820
BP		 548 dnl Include -Werror in the compiler options, because without -Werror
549 dnl clang's GCC-compatible compiler driver does not return a failure
550 dnl exit status even though it complains about options it does not
551 dnl understand.
c2deac54
YT		 552 dnl
553 dnl Also, check stderr as gcc exits with status 0 for options
554 dnl rejected at getopt level.
555 dnl % touch /tmp/a.c
556 dnl % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
557 dnl gcc: unrecognized option '-Qunused-arguments'
558 dnl 0
559 dnl %
50194820 560 CFLAGS="$CFLAGS $WERROR $1"
c2deac54 561 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
064af421
BP		 562 CFLAGS="$ovs_save_CFLAGS"])
563 if test $ovs_cv_name = yes; then
83f6c050 564 m4_if([$2], [], [:], [$2])
064af421
BP		 565 else
566 m4_if([$3], [], [:], [$3])
567 fi
568])
569
50194820
BP		 570dnl OVS_CHECK_WERROR
571dnl
572dnl Check whether the C compiler accepts -Werror.
573dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
574AC_DEFUN([OVS_CHECK_WERROR],
575 [WERROR=
576 _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
577
578dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
579dnl Check whether the given C compiler OPTION is accepted.
580dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
581AC_DEFUN([OVS_CHECK_CC_OPTION],
582 [AC_REQUIRE([OVS_CHECK_WERROR])
583 _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
584
064af421
BP		 585dnl OVS_ENABLE_OPTION([OPTION])
586dnl Check whether the given C compiler OPTION is accepted.
d161c099 587dnl If so, add it to WARNING_FLAGS.
064af421
BP		 588dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
589AC_DEFUN([OVS_ENABLE_OPTION],
d161c099
BP		 590 [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
591 AC_SUBST([WARNING_FLAGS])])
c72e245a
BP		 592
593dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
594dnl Check whether the given C compiler OPTION is accepted.
595dnl If so, enable the given Automake CONDITIONAL.
596
597dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
598AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
599 [OVS_CHECK_CC_OPTION(
600 [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
601 AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
064af421 602dnl ----------------------------------------------------------------------
ed2d4f6a
BP		 603
604dnl Check for too-old XenServer.
605AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
606 [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
607 [if test -e /etc/redhat-release; then
608 ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
609 fi
610 if test -z "$ovs_cv_xsversion"; then
611 ovs_cv_xsversion=none
612 fi])
613 case $ovs_cv_xsversion in
614 none)
615 ;;
616
617 [[1-9]][[0-9]]* | dnl XenServer 10 or later
618 [[6-9]]* | dnl XenServer 6 or later
619 5.[[7-9]]* | dnl XenServer 5.7 or later
620 5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.1000 or later
621 5.6.[[2-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.200 or later
622 5.6.1[[0-9]][[0-9]]) dnl Xenserver 5.6.100 or later
623 ;;
624
625 *)
626 AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported. (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
627 ;;
628 esac])
29d935d6
BP		 629
630dnl OVS_MAKE_HAS_IF([if-true], [if-false])
631dnl
632dnl Checks whether make has the GNU make $(if condition,then,else) extension.
633dnl Runs 'if-true' if so, 'if-false' otherwise.
372d58a4 634AC_DEFUN([OVS_CHECK_MAKE_IF],
29d935d6
BP		 635 [AC_CACHE_CHECK(
636 [whether ${MAKE-make} has GNU make \$(if) extension],
637 [ovs_cv_gnu_make_if],
638 [cat <<'EOF' > conftest.mk
639conftest.out:
380f86e4 640 echo $(if x,y,z) > conftest.out
29d935d6
BP		 641.PHONY: all
642EOF
643 rm -f conftest.out
644 AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
645 ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
646 AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
647 cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
648 result=`cat conftest.out`
649 rm -f conftest.mk conftest.out
650 if test "X$result" = "Xy"; then
651 ovs_cv_gnu_make_if=yes
652 else
653 ovs_cv_gnu_make_if=no
372d58a4 654 fi])])
29d935d6 655
b4e1bf8b
BP		 656dnl OVS_CHECK_GNU_MAKE
657dnl
658dnl Checks whether make is GNU make (because Linux kernel Makefiles
659dnl only work with GNU make).
660AC_DEFUN([OVS_CHECK_GNU_MAKE],
661 [AC_CACHE_CHECK(
662 [whether ${MAKE-make} is GNU make],
663 [ovs_cv_gnu_make],
664 [rm -f conftest.out
665 AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
666 ${MAKE-make} --version >conftest.out 2>&1
667 cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
668 result=`cat conftest.out`
669 rm -f conftest.mk conftest.out
670
671 case $result in # (
672 GNU*) ovs_cv_gnu_make=yes ;; # (
673 *) ovs_cv_gnu_make=no ;;
674 esac])
675 AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
676
643c0c34
BP		 677dnl OVS_CHECK_SPARSE_TARGET
678dnl
679dnl The "cgcc" script from "sparse" isn't very good at detecting the
680dnl target for which the code is being built. This helps it out.
681AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
682 [AC_CACHE_CHECK(
683 [target hint for cgcc],
684 [ac_cv_sparse_target],
685 [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
686 [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
687 [x86_64-*], [ac_cv_sparse_target=x86_64],
688 [ac_cv_sparse_target=other])])
689 AS_CASE([$ac_cv_sparse_target],
690 [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
691 [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
692 [SPARSEFLAGS= CGCCFLAGS=])
693 AC_SUBST([SPARSEFLAGS])
694 AC_SUBST([CGCCFLAGS])])
695
32e96ab7
AZ		 696dnl OVS_SPARSE_EXTRA_INCLUDES
697dnl
698dnl The cgcc script from "sparse" does not search gcc's default
699dnl search path. Get the default search path from GCC and pass
700dnl them to sparse.
701AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
702 AC_SUBST([SPARSE_EXTRA_INCLUDES],
703 [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
704
29d935d6
BP		 705dnl OVS_ENABLE_SPARSE
706AC_DEFUN([OVS_ENABLE_SPARSE],
643c0c34 707 [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
372d58a4 708 AC_REQUIRE([OVS_CHECK_MAKE_IF])
32e96ab7 709 AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
372d58a4
BP		 710 : ${SPARSE=sparse}
711 AC_SUBST([SPARSE])
712 AC_CONFIG_COMMANDS_PRE(
713 [if test $ovs_cv_gnu_make_if = yes; then
38b7a52b 714 CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
372d58a4 715 fi])])
8a8cd0ac
BP		 716
717dnl OVS_PTHREAD_SET_NAME
718dnl
719dnl This checks for three known variants of pthreads functions for setting
720dnl the name of the current thread:
721dnl
722dnl glibc: int pthread_setname_np(pthread_t, const char *name);
723dnl NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
724dnl FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
725dnl
726dnl For glibc and FreeBSD, the arguments are just a thread and its name. For
727dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
728dnl provide to it.
729dnl
730dnl This macro defines:
731dnl
732dnl glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
733dnl NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
734dnl FreeBSD: HAVE_PTHREAD_SET_NAME_NP
735AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
736 [AC_CHECK_FUNCS([pthread_set_name_np])
737 if test $ac_cv_func_pthread_set_name_np != yes; then
738 AC_CACHE_CHECK(
739 [for pthread_setname_np() variant],
740 [ovs_cv_pthread_setname_np],
741 [AC_LINK_IFELSE(
a0903134 742 [AC_LANG_PROGRAM([#include <pthread.h>
8a8cd0ac 743 ], [pthread_setname_np(pthread_self(), "name");])],
a0903134 744 [ovs_cv_pthread_setname_np=glibc],
8a8cd0ac 745 [AC_LINK_IFELSE(
a0903134 746 [AC_LANG_PROGRAM([#include <pthread.h>
8a8cd0ac
BP		 747], [pthread_setname_np(pthread_self(), "%s", "name");])],
748 [ovs_cv_pthread_setname_np=netbsd],
a0903134 749 [ovs_cv_pthread_setname_np=none])])])
8a8cd0ac
BP		 750 case $ovs_cv_pthread_setname_np in # (
751 glibc)
a0903134
YT		 752 AC_DEFINE(
753 [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
754 [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
755 ;; # (
8a8cd0ac 756 netbsd)
a0903134
YT		 757 AC_DEFINE(
758 [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
759 [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
760 ;;
8a8cd0ac
BP		 761 esac
762 fi])
5020f5f0
BP		 763
764dnl OVS_CHECK_LINUX_HOST.
765dnl
766dnl Checks whether we're building for a Linux host, based on the presence of
767dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
768dnl LINUX based on the result.
769AC_DEFUN([OVS_CHECK_LINUX_HOST],
770 [AC_CACHE_CHECK(
771 [whether __linux__ is defined],
772 [ovs_cv_linux],
773 [AC_COMPILE_IFELSE(
774 [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
775 [ovs_cv_linux=true],
776 [ovs_cv_linux=false])])
777 AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])
openvswitch mirror