[mirror_ovs.git] / acinclude.m4

# -*- autoconf -*-

# Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

dnl OVS_ENABLE_WERROR
AC_DEFUN([OVS_ENABLE_WERROR],
  [AC_ARG_ENABLE(
     [Werror],
     [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
     [], [enable_Werror=no])
   AC_CONFIG_COMMANDS_PRE(
     [if test "X$enable_Werror" = Xyes; then
        CFLAGS="$CFLAGS -Werror"
      fi])])

dnl OVS_CHECK_LINUX
dnl
dnl Configure linux kernel source tree 
AC_DEFUN([OVS_CHECK_LINUX], [
  AC_ARG_WITH([linux],
              [AC_HELP_STRING([--with-linux=/path/to/linux],
                              [Specify the Linux kernel build directory])])
  AC_ARG_WITH([linux-source],
              [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
                              [Specify the Linux kernel source directory
			       (usually figured out automatically from build
			       directory)])])

  # Deprecated equivalents to --with-linux, --with-linux-source.
  AC_ARG_WITH([l26])
  AC_ARG_WITH([l26-source])

  if test X"$with_linux" != X; then
    KBUILD=$with_linux
  elif test X"$with_l26" != X; then
    KBUILD=$with_l26
    AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  else
    KBUILD=
  fi

  if test X"$KBUILD" != X; then
    if test X"$with_linux_source" != X; then
      KSRC=$with_linux_source
    elif test X"$with_l26_source" != X; then
      KSRC=$with_l26_source
      AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
    else
      KSRC=
    fi
  elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
    AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  fi

  if test -n "$KBUILD"; then
    KBUILD=`eval echo "$KBUILD"`
    case $KBUILD in
        /*) ;;
        *) KBUILD=`pwd`/$KBUILD ;;
    esac

    # The build directory is what the user provided.
    # Make sure that it exists.
    AC_MSG_CHECKING([for Linux build directory])
    if test -d "$KBUILD"; then
	AC_MSG_RESULT([$KBUILD])
	AC_SUBST(KBUILD)
    else
	AC_MSG_RESULT([no])
	AC_ERROR([source dir $KBUILD doesn't exist])
    fi

    # Debian breaks kernel headers into "source" header and "build" headers.
    # We want the source headers, but $KBUILD gives us the "build" headers.
    # Use heuristics to find the source headers.
    AC_MSG_CHECKING([for Linux source directory])
    if test -n "$KSRC"; then
      KSRC=`eval echo "$KSRC"`
      case $KSRC in
          /*) ;;
          *) KSRC=`pwd`/$KSRC ;;
      esac
      if test ! -e $KSRC/include/linux/kernel.h; then
        AC_MSG_ERROR([$KSRC is not a kernel source directory])
      fi
    else
      KSRC=$KBUILD
      if test ! -e $KSRC/include/linux/kernel.h; then
        # Debian kernel build Makefiles tend to include a line of the form:
        # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
        # First try to extract the source directory from this line.
        KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
        if test ! -e "$KSRC"/include/linux/kernel.h; then
          # Didn't work.  Fall back to name-based heuristics that used to work.
          case `echo "$KBUILD" | sed 's,/*$,,'` in # (
            */build)
              KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
              ;; # (
            *)
              KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
              ;;
          esac
        fi
      fi
      if test ! -e "$KSRC"/include/linux/kernel.h; then
        AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
      fi
    fi
    AC_MSG_RESULT([$KSRC])

    AC_MSG_CHECKING([for kernel version])
    version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
    patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
    sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
    if test X"$version" = X || test X"$patchlevel" = X; then
       AC_ERROR([cannot determine kernel version])
    elif test X"$sublevel" = X; then
       kversion=$version.$patchlevel
    else
       kversion=$version.$patchlevel.$sublevel
    fi
    AC_MSG_RESULT([$kversion])

    if test "$version" -ge 3; then
       : # Linux 3.x
    elif test "$version" = 2 && test "$patchlevel" -ge 6; then
       : # Linux 2.6.x
    else
       if test "$KBUILD" = "$KSRC"; then
         AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
       else
         AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
       fi
    fi
    if (test ! -e "$KBUILD"/include/linux/version.h && \
        test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
       (test ! -e "$KBUILD"/include/linux/autoconf.h && \
        test ! -e "$KBUILD"/include/generated/autoconf.h); then
	AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
    fi
    OVS_CHECK_LINUX_COMPAT
  fi
  AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
])

dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
dnl
dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
dnl <REGEX> translated to uppercase.
AC_DEFUN([OVS_GREP_IFELSE], [
  AC_MSG_CHECKING([whether $2 matches in $1])
  if test -f $1; then
    grep '$2' $1 >/dev/null 2>&1
    status=$?
    case $status in
      0) 
        AC_MSG_RESULT([yes])
        m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
        ;;
      1) 
        AC_MSG_RESULT([no])
        $4
        ;;
      *) 
        AC_MSG_ERROR([grep exited with status $status])
        ;;
    esac
  else
    AC_MSG_RESULT([file not found])
    $4
  fi
])

dnl OVS_DEFINE(NAME)
dnl
dnl Defines NAME to 1 in kcompat.h.
AC_DEFUN([OVS_DEFINE], [
  echo '#define $1 1' >> datapath/linux/kcompat.h.new
])

AC_DEFUN([OVS_CHECK_LOG2_H], [
  AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
  if test -e $KSRC/include/linux/log2.h; then
    AC_MSG_RESULT([yes])
    OVS_DEFINE([HAVE_LOG2_H])
  else
    AC_MSG_RESULT([no])
  fi
])

dnl OVS_CHECK_LINUX_COMPAT
dnl
dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
dnl the directory in $KBUILD.
AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
  rm -f datapath/linux/kcompat.h.new
  mkdir -p datapath/linux
  : > datapath/linux/kcompat.h.new

  OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
                  [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])

  OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])

  OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])

  OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
  OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
  OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])

  OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
                  [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
                                   [rcu_read_lock_held])])
  
  # Check for the proto_data_valid member in struct sk_buff.  The [^@]
  # is necessary because some versions of this header remove the
  # member but retain the kerneldoc comment that describes it (which
  # starts with @).  The brackets must be doubled because of m4
  # quoting rules.
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
                  [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
                  [OVS_DEFINE([HAVE_MAC_RAW])])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
                  [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], 
                  [skb_copy_from_linear_data_offset])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
                  [skb_reset_tail_pointer])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
                  [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
  OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
                  [OVS_DEFINE([HAVE_ICMP6_HDR])])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
                  [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
  OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])

  OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
                  [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])

  OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
                  [OVS_DEFINE([HAVE_BOOL_TYPE])])
  OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
                  [OVS_DEFINE([HAVE_CSUM_TYPES])])

  OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
  OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])

  OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
  OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
  OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])

  OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
                  [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])

  OVS_CHECK_LOG2_H

  if cmp -s datapath/linux/kcompat.h.new \
            datapath/linux/kcompat.h >/dev/null 2>&1; then
    rm datapath/linux/kcompat.h.new
  else
    mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
  fi
])

dnl Checks for net/if_packet.h.
AC_DEFUN([OVS_CHECK_IF_PACKET],
  [AC_CHECK_HEADER([net/if_packet.h],
                   [HAVE_IF_PACKET=yes],
                   [HAVE_IF_PACKET=no])
   AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
   if test "$HAVE_IF_PACKET" = yes; then
      AC_DEFINE([HAVE_IF_PACKET], [1],
                [Define to 1 if net/if_packet.h is available.])
   fi])

dnl Checks for net/if_dl.h.
AC_DEFUN([OVS_CHECK_IF_DL],
  [AC_CHECK_HEADER([net/if_dl.h],
                   [HAVE_IF_DL=yes],
                   [HAVE_IF_DL=no])
   AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
   if test "$HAVE_IF_DL" = yes; then
      AC_DEFINE([HAVE_IF_DL], [1],
                [Define to 1 if net/if_dl.h is available.])
   fi])

dnl Checks for buggy strtok_r.
dnl
dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
dnl with optimization that can cause segfaults:
dnl
dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
AC_DEFUN([OVS_CHECK_STRTOK_R],
  [AC_CACHE_CHECK(
     [whether strtok_r macro segfaults on some inputs],
     [ovs_cv_strtok_r_bug],
     [AC_RUN_IFELSE(
        [AC_LANG_PROGRAM([#include <stdio.h>
                          #include <string.h>
                         ],
                         [[char string[] = ":::";
                           char *save_ptr = (char *) 0xc0ffee;
                           char *token1, *token2;
                           token1 = strtok_r(string, ":", &save_ptr);
                           token2 = strtok_r(NULL, ":", &save_ptr);
                           freopen ("/dev/null", "w", stdout);
                           printf ("%s %s\n", token1, token2);
                           return 0;
                          ]])],
        [ovs_cv_strtok_r_bug=no],
        [ovs_cv_strtok_r_bug=yes],
        [ovs_cv_strtok_r_bug=yes])])
   if test $ovs_cv_strtok_r_bug = yes; then
     AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
               [Define if strtok_r macro segfaults on some inputs])
   fi
])

dnl ----------------------------------------------------------------------
dnl These macros are from GNU PSPP, with the following original license:
dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
dnl Check whether the given C compiler OPTION is accepted.
dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
AC_DEFUN([OVS_CHECK_CC_OPTION],
[
  m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
  AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name], 
    [ovs_save_CFLAGS="$CFLAGS"
     CFLAGS="$CFLAGS $1"
     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
     CFLAGS="$ovs_save_CFLAGS"])
  if test $ovs_cv_name = yes; then
    m4_if([$2], [], [:], [$2])
  else
    m4_if([$3], [], [:], [$3])
  fi
])

dnl OVS_ENABLE_OPTION([OPTION])
dnl Check whether the given C compiler OPTION is accepted.
dnl If so, add it to WARNING_FLAGS.
dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
AC_DEFUN([OVS_ENABLE_OPTION], 
  [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
   AC_SUBST([WARNING_FLAGS])])

dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
dnl Check whether the given C compiler OPTION is accepted.
dnl If so, enable the given Automake CONDITIONAL.

dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
  [OVS_CHECK_CC_OPTION(
    [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
   AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
dnl ----------------------------------------------------------------------

dnl Check for too-old XenServer.
AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
  [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
    [if test -e /etc/redhat-release; then
       ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
     fi
     if test -z "$ovs_cv_xsversion"; then
       ovs_cv_xsversion=none
     fi])
  case $ovs_cv_xsversion in
    none)
      ;;

    [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
    [[6-9]]* |                           dnl XenServer 6 or later
    5.[[7-9]]* |                         dnl XenServer 5.7 or later
    5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
    5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
    5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
      ;;

    *)
      AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
      ;;
  esac])

dnl OVS_MAKE_HAS_IF([if-true], [if-false])
dnl
dnl Checks whether make has the GNU make $(if condition,then,else) extension.
dnl Runs 'if-true' if so, 'if-false' otherwise.
AC_DEFUN([OVS_CHECK_MAKE_IF],
  [AC_CACHE_CHECK(
     [whether ${MAKE-make} has GNU make \$(if) extension],
     [ovs_cv_gnu_make_if],
     [cat <<'EOF' > conftest.mk
conftest.out:
	echo $(if x,y,z) > conftest.out
.PHONY: all
EOF
      rm -f conftest.out
      AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
      ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
      AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
      cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
      result=`cat conftest.out`
      rm -f conftest.mk conftest.out
      if test "X$result" = "Xy"; then
        ovs_cv_gnu_make_if=yes
      else
        ovs_cv_gnu_make_if=no
      fi])])

dnl OVS_CHECK_GNU_MAKE
dnl
dnl Checks whether make is GNU make (because Linux kernel Makefiles
dnl only work with GNU make).
AC_DEFUN([OVS_CHECK_GNU_MAKE],
  [AC_CACHE_CHECK(
     [whether ${MAKE-make} is GNU make],
     [ovs_cv_gnu_make],
     [rm -f conftest.out
      AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
      ${MAKE-make} --version >conftest.out 2>&1
      cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
      result=`cat conftest.out`
      rm -f conftest.mk conftest.out

      case $result in # (
        GNU*) ovs_cv_gnu_make=yes ;; # (
        *) ovs_cv_gnu_make=no ;;
      esac])
   AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])

dnl OVS_CHECK_SPARSE_TARGET
dnl
dnl The "cgcc" script from "sparse" isn't very good at detecting the
dnl target for which the code is being built.  This helps it out.
AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
  [AC_CACHE_CHECK(
    [target hint for cgcc],
    [ac_cv_sparse_target],
    [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
       [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
       [x86_64-*], [ac_cv_sparse_target=x86_64],
       [ac_cv_sparse_target=other])])
   AS_CASE([$ac_cv_sparse_target],
     [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
     [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
     [SPARSEFLAGS= CGCCFLAGS=])
   AC_SUBST([SPARSEFLAGS])
   AC_SUBST([CGCCFLAGS])])

dnl OVS_ENABLE_SPARSE
AC_DEFUN([OVS_ENABLE_SPARSE],
  [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
   AC_REQUIRE([OVS_CHECK_MAKE_IF])
   : ${SPARSE=sparse}
   AC_SUBST([SPARSE])
   AC_CONFIG_COMMANDS_PRE(
     [if test $ovs_cv_gnu_make_if = yes; then
        CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'
      fi])])
Commit	Line	Data
064af421 BP	1	# -- autoconf --
064af421 BP	2
e0edde6f	3	# Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
064af421	4	#
a14bc59f BP	5	# Licensed under the Apache License, Version 2.0 (the "License");
	6	# you may not use this file except in compliance with the License.
	7	# You may obtain a copy of the License at:
064af421	8	#
a14bc59f BP	9	# http://www.apache.org/licenses/LICENSE-2.0
	10	#
	11	# Unless required by applicable law or agreed to in writing, software
	12	# distributed under the License is distributed on an "AS IS" BASIS,
	13	# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
	14	# See the License for the specific language governing permissions and
	15	# limitations under the License.
064af421	16
a64e37a1 BP	17	dnl OVS_ENABLE_WERROR
	18	AC_DEFUN([OVS_ENABLE_WERROR],
	19	[AC_ARG_ENABLE(
	20	[Werror],
	21	[AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
	22	[], [enable_Werror=no])
	23	AC_CONFIG_COMMANDS_PRE(
	24	[if test "X$enable_Werror" = Xyes; then
	25	CFLAGS="$CFLAGS -Werror"
	26	fi])])
	27
e3438006	28	dnl OVS_CHECK_LINUX
064af421 BP	29	dnl
064af421 BP	30	dnl Configure linux kernel source tree
e3438006	31	AC_DEFUN([OVS_CHECK_LINUX], [
8a2d6596 BP	32	AC_ARG_WITH([linux],
	33	[AC_HELP_STRING([--with-linux=/path/to/linux],
	34	[Specify the Linux kernel build directory])])
	35	AC_ARG_WITH([linux-source],
	36	[AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
	37	[Specify the Linux kernel source directory
f5fb5de6	38	(usually figured out automatically from build
8a2d6596 BP	39	directory)])])
	40
	41	# Deprecated equivalents to --with-linux, --with-linux-source.
	42	AC_ARG_WITH([l26])
	43	AC_ARG_WITH([l26-source])
	44
	45	if test X"$with_linux" != X; then
	46	KBUILD=$with_linux
	47	elif test X"$with_l26" != X; then
	48	KBUILD=$with_l26
	49	AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
	50	else
	51	KBUILD=
	52	fi
	53
	54	if test X"$KBUILD" != X; then
	55	if test X"$with_linux_source" != X; then
	56	KSRC=$with_linux_source
	57	elif test X"$with_l26_source" != X; then
	58	KSRC=$with_l26_source
	59	AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
0a89c170 BP	60	else
0a89c170 BP	61	KSRC=
8a2d6596 BP	62	fi
	63	elif test X"$with_linux_source" != X \|\| test X"$with_l26_source" != X; then
	64	AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
	65	fi
	66
e3438006 BP	67	if test -n "$KBUILD"; then
	68	KBUILD=`eval echo "$KBUILD"`
	69	case $KBUILD in
0b6d72fc	70	/*) ;;
e3438006	71	*) KBUILD=`pwd`/$KBUILD ;;
0b6d72fc	72	esac
064af421	73
7c9e113b BP	74	# The build directory is what the user provided.
7c9e113b BP	75	# Make sure that it exists.
8a2d6596	76	AC_MSG_CHECKING([for Linux build directory])
e3438006 BP	77	if test -d "$KBUILD"; then
	78	AC_MSG_RESULT([$KBUILD])
	79	AC_SUBST(KBUILD)
064af421 BP	80	else
064af421 BP	81	AC_MSG_RESULT([no])
e3438006	82	AC_ERROR([source dir $KBUILD doesn't exist])
064af421 BP	83	fi
064af421 BP	84
7c9e113b	85	# Debian breaks kernel headers into "source" header and "build" headers.
e3438006	86	# We want the source headers, but $KBUILD gives us the "build" headers.
7c9e113b	87	# Use heuristics to find the source headers.
8a2d6596	88	AC_MSG_CHECKING([for Linux source directory])
e3438006 BP	89	if test -n "$KSRC"; then
	90	KSRC=`eval echo "$KSRC"`
	91	case $KSRC in
f5fb5de6	92	/*) ;;
e3438006	93	*) KSRC=`pwd`/$KSRC ;;
b57f675c	94	esac
e3438006	95	if test ! -e $KSRC/include/linux/kernel.h; then
53319f95	96	AC_MSG_ERROR([$KSRC is not a kernel source directory])
f5fb5de6 BP	97	fi
f5fb5de6 BP	98	else
e3438006 BP	99	KSRC=$KBUILD
e3438006 BP	100	if test ! -e $KSRC/include/linux/kernel.h; then
fe0731b1 BP	101	# Debian kernel build Makefiles tend to include a line of the form:
	102	# MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
	103	# First try to extract the source directory from this line.
	104	KSRC=`sed -n 's/.-C \([[^ ]]\).*/\1/p' "$KBUILD"/Makefile`
	105	if test ! -e "$KSRC"/include/linux/kernel.h; then
	106	# Didn't work. Fall back to name-based heuristics that used to work.
	107	case `echo "$KBUILD" \| sed 's,/*$,,'` in # (
	108	*/build)
	109	KSRC=`echo "$KBUILD" \| sed 's,/build/*$,/source,'`
	110	;; # (
	111	*)
	112	KSRC=`(cd $KBUILD && pwd -P) \| sed 's,-[[^-]]*$,-common,'`
	113	;;
	114	esac
	115	fi
f5fb5de6	116	fi
fe0731b1	117	if test ! -e "$KSRC"/include/linux/kernel.h; then
8a2d6596	118	AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
7c9e113b BP	119	fi
7c9e113b BP	120	fi
e3438006	121	AC_MSG_RESULT([$KSRC])
7c9e113b BP	122
7c9e113b BP	123	AC_MSG_CHECKING([for kernel version])
71fe9970	124	version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
e3438006 BP	125	patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
e3438006 BP	126	sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
71fe9970	127	if test X"$version" = X \|\| test X"$patchlevel" = X; then
7c9e113b	128	AC_ERROR([cannot determine kernel version])
71fe9970 BP	129	elif test X"$sublevel" = X; then
	130	kversion=$version.$patchlevel
	131	else
	132	kversion=$version.$patchlevel.$sublevel
7c9e113b	133	fi
71fe9970 BP	134	AC_MSG_RESULT([$kversion])
	135
	136	if test "$version" -ge 3; then
	137	: # Linux 3.x
	138	elif test "$version" = 2 && test "$patchlevel" -ge 6; then
	139	: # Linux 2.6.x
	140	else
e3438006	141	if test "$KBUILD" = "$KSRC"; then
71fe9970	142	AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
7c9e113b	143	else
71fe9970	144	AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
7c9e113b	145	fi
064af421	146	fi
2520f452 IY	147	if (test ! -e "$KBUILD"/include/linux/version.h && \
2520f452 IY	148	test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)\|\| \
e3438006 BP	149	(test ! -e "$KBUILD"/include/linux/autoconf.h && \
	150	test ! -e "$KBUILD"/include/generated/autoconf.h); then
	151	AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
064af421	152	fi
e3438006	153	OVS_CHECK_LINUX_COMPAT
064af421	154	fi
e3438006	155	AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
064af421 BP	156	])
064af421 BP	157
8828e5c7	158	dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
064af421 BP	159	dnl
064af421 BP	160	dnl Greps FILE for REGEX. If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
8828e5c7 BP	161	dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
8828e5c7 BP	162	dnl <REGEX> translated to uppercase.
064af421 BP	163	AC_DEFUN([OVS_GREP_IFELSE], [
064af421 BP	164	AC_MSG_CHECKING([whether $2 matches in $1])
7507ec48 JG	165	if test -f $1; then
	166	grep '$2' $1 >/dev/null 2>&1
	167	status=$?
	168	case $status in
	169	0)
	170	AC_MSG_RESULT([yes])
8828e5c7	171	m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
7507ec48 JG	172	;;
	173	1)
	174	AC_MSG_RESULT([no])
	175	$4
	176	;;
	177	*)
	178	AC_MSG_ERROR([grep exited with status $status])
	179	;;
	180	esac
	181	else
	182	AC_MSG_RESULT([file not found])
	183	$4
	184	fi
064af421 BP	185	])
	186
	187	dnl OVS_DEFINE(NAME)
	188	dnl
	189	dnl Defines NAME to 1 in kcompat.h.
	190	AC_DEFUN([OVS_DEFINE], [
22bcc0e7	191	echo '#define $1 1' >> datapath/linux/kcompat.h.new
064af421 BP	192	])
064af421 BP	193
064af421	194	AC_DEFUN([OVS_CHECK_LOG2_H], [
e3438006 BP	195	AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
e3438006 BP	196	if test -e $KSRC/include/linux/log2.h; then
064af421 BP	197	AC_MSG_RESULT([yes])
	198	OVS_DEFINE([HAVE_LOG2_H])
	199	else
	200	AC_MSG_RESULT([no])
	201	fi
	202	])
	203
e3438006	204	dnl OVS_CHECK_LINUX_COMPAT
064af421 BP	205	dnl
064af421 BP	206	dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
e3438006 BP	207	dnl the directory in $KBUILD.
e3438006 BP	208	AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
22bcc0e7 JG	209	rm -f datapath/linux/kcompat.h.new
	210	mkdir -p datapath/linux
	211	: > datapath/linux/kcompat.h.new
4aa13c0c	212
e3438006	213	OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
25fb3596 JG	214	[OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
25fb3596 JG	215
e3438006	216	OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
4aa13c0c	217
e3438006	218	OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
4aa13c0c	219
e3438006 BP	220	OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
	221	OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
	222	OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
4aa13c0c	223
e3438006 BP	224	OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
e3438006 BP	225	[OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
cf6cb3a2 JG	226	[rcu_read_lock_held])])
cf6cb3a2 JG	227
6a33828d BP	228	# Check for the proto_data_valid member in struct sk_buff. The [^@]
	229	# is necessary because some versions of this header remove the
	230	# member but retain the kerneldoc comment that describes it (which
	231	# starts with @). The brackets must be doubled because of m4
	232	# quoting rules.
e3438006	233	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
6a33828d	234	[OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
e3438006	235	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
4aa13c0c	236	[OVS_DEFINE([HAVE_MAC_RAW])])
e3438006	237	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
85444c3f	238	[OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
e3438006	239	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
8828e5c7	240	[skb_copy_from_linear_data_offset])
b9c15df9 PS	241	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
b9c15df9 PS	242	[skb_reset_tail_pointer])
e3438006 BP	243	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
e3438006 BP	244	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
4aa13c0c	245	[OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
e3438006	246	OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
d31f1109	247	[OVS_DEFINE([HAVE_ICMP6_HDR])])
e3438006	248	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
4aa13c0c	249	[OVS_DEFINE([HAVE_SKB_WARN_LRO])])
e3438006	250	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
6c4ea27c	251	OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
4aa13c0c	252
e3438006 BP	253	OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
e3438006 BP	254	[OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
4aa13c0c	255
e3438006	256	OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
4aa13c0c	257	[OVS_DEFINE([HAVE_BOOL_TYPE])])
e3438006	258	OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
e215ebca	259	[OVS_DEFINE([HAVE_CSUM_TYPES])])
4aa13c0c	260
e3438006 BP	261	OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
e3438006 BP	262	OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
4aa13c0c	263
e3438006 BP	264	OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
	265	OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
	266	OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
4aa13c0c	267
e3438006	268	OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
431488e6 BP	269	[OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
431488e6 BP	270
064af421	271	OVS_CHECK_LOG2_H
4aa13c0c	272
22bcc0e7 JG	273	if cmp -s datapath/linux/kcompat.h.new \
	274	datapath/linux/kcompat.h >/dev/null 2>&1; then
	275	rm datapath/linux/kcompat.h.new
064af421	276	else
22bcc0e7	277	mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
064af421 BP	278	fi
	279	])
	280
	281	dnl Checks for net/if_packet.h.
	282	AC_DEFUN([OVS_CHECK_IF_PACKET],
	283	[AC_CHECK_HEADER([net/if_packet.h],
	284	[HAVE_IF_PACKET=yes],
	285	[HAVE_IF_PACKET=no])
	286	AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
	287	if test "$HAVE_IF_PACKET" = yes; then
	288	AC_DEFINE([HAVE_IF_PACKET], [1],
	289	[Define to 1 if net/if_packet.h is available.])
	290	fi])
	291
f6eb6b20	292	dnl Checks for net/if_dl.h.
9360d9b7 EM	293	AC_DEFUN([OVS_CHECK_IF_DL],
	294	[AC_CHECK_HEADER([net/if_dl.h],
	295	[HAVE_IF_DL=yes],
	296	[HAVE_IF_DL=no])
	297	AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
	298	if test "$HAVE_IF_DL" = yes; then
	299	AC_DEFINE([HAVE_IF_DL], [1],
	300	[Define to 1 if net/if_dl.h is available.])
	301	fi])
	302
e50097d2 BP	303	dnl Checks for buggy strtok_r.
	304	dnl
	305	dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
	306	dnl with optimization that can cause segfaults:
	307	dnl
	308	dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
	309	AC_DEFUN([OVS_CHECK_STRTOK_R],
	310	[AC_CACHE_CHECK(
	311	[whether strtok_r macro segfaults on some inputs],
	312	[ovs_cv_strtok_r_bug],
	313	[AC_RUN_IFELSE(
	314	[AC_LANG_PROGRAM([#include <stdio.h>
	315	#include <string.h>
	316	],
	317	[[char string[] = ":::";
	318	char save_ptr = (char ) 0xc0ffee;
	319	char token1, token2;
	320	token1 = strtok_r(string, ":", &save_ptr);
	321	token2 = strtok_r(NULL, ":", &save_ptr);
5819a7cd	322	freopen ("/dev/null", "w", stdout);
e50097d2 BP	323	printf ("%s %s\n", token1, token2);
	324	return 0;
	325	]])],
	326	[ovs_cv_strtok_r_bug=no],
	327	[ovs_cv_strtok_r_bug=yes],
	328	[ovs_cv_strtok_r_bug=yes])])
	329	if test $ovs_cv_strtok_r_bug = yes; then
	330	AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
	331	[Define if strtok_r macro segfaults on some inputs])
	332	fi
	333	])
	334
064af421 BP	335	dnl ----------------------------------------------------------------------
	336	dnl These macros are from GNU PSPP, with the following original license:
	337	dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
	338	dnl This file is free software; the Free Software Foundation
	339	dnl gives unlimited permission to copy and/or distribute it,
	340	dnl with or without modifications, as long as this notice is preserved.
	341
	342	dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
	343	dnl Check whether the given C compiler OPTION is accepted.
	344	dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
	345	AC_DEFUN([OVS_CHECK_CC_OPTION],
	346	[
	347	m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
	348	AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
	349	[ovs_save_CFLAGS="$CFLAGS"
	350	CFLAGS="$CFLAGS $1"
	351	AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
	352	CFLAGS="$ovs_save_CFLAGS"])
	353	if test $ovs_cv_name = yes; then
83f6c050	354	m4_if([$2], [], [:], [$2])
064af421 BP	355	else
	356	m4_if([$3], [], [:], [$3])
	357	fi
	358	])
	359
	360	dnl OVS_ENABLE_OPTION([OPTION])
	361	dnl Check whether the given C compiler OPTION is accepted.
d161c099	362	dnl If so, add it to WARNING_FLAGS.
064af421 BP	363	dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
064af421 BP	364	AC_DEFUN([OVS_ENABLE_OPTION],
d161c099 BP	365	[OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
d161c099 BP	366	AC_SUBST([WARNING_FLAGS])])
c72e245a BP	367
	368	dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
	369	dnl Check whether the given C compiler OPTION is accepted.
	370	dnl If so, enable the given Automake CONDITIONAL.
	371
	372	dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
	373	AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
	374	[OVS_CHECK_CC_OPTION(
	375	[$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
	376	AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
064af421	377	dnl ----------------------------------------------------------------------
ed2d4f6a BP	378
	379	dnl Check for too-old XenServer.
	380	AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
	381	[AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
	382	[if test -e /etc/redhat-release; then
	383	ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]\)-./\1/p' /etc/redhat-release`
	384	fi
	385	if test -z "$ovs_cv_xsversion"; then
	386	ovs_cv_xsversion=none
	387	fi])
	388	case $ovs_cv_xsversion in
	389	none)
	390	;;
	391
	392	[[1-9]][[0-9]]* \| dnl XenServer 10 or later
	393	[[6-9]]* \| dnl XenServer 6 or later
	394	5.[[7-9]]* \| dnl XenServer 5.7 or later
	395	5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* \| dnl XenServer 5.6.1000 or later
	396	5.6.[[2-9]][[0-9]][[0-9]]* \| dnl XenServer 5.6.200 or later
	397	5.6.1[[0-9]][[0-9]]) dnl Xenserver 5.6.100 or later
	398	;;
	399
	400	*)
	401	AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported. (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
	402	;;
	403	esac])
29d935d6 BP	404
	405	dnl OVS_MAKE_HAS_IF([if-true], [if-false])
	406	dnl
	407	dnl Checks whether make has the GNU make $(if condition,then,else) extension.
	408	dnl Runs 'if-true' if so, 'if-false' otherwise.
372d58a4	409	AC_DEFUN([OVS_CHECK_MAKE_IF],
29d935d6 BP	410	[AC_CACHE_CHECK(
	411	[whether ${MAKE-make} has GNU make \$(if) extension],
	412	[ovs_cv_gnu_make_if],
	413	[cat <<'EOF' > conftest.mk
	414	conftest.out:
	415	echo $(if x,y,z) > conftest.out
	416	.PHONY: all
	417	EOF
	418	rm -f conftest.out
	419	AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
	420	${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
	421	AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
	422	cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
	423	result=`cat conftest.out`
	424	rm -f conftest.mk conftest.out
	425	if test "X$result" = "Xy"; then
	426	ovs_cv_gnu_make_if=yes
	427	else
	428	ovs_cv_gnu_make_if=no
372d58a4	429	fi])])
29d935d6	430
b4e1bf8b BP	431	dnl OVS_CHECK_GNU_MAKE
	432	dnl
	433	dnl Checks whether make is GNU make (because Linux kernel Makefiles
	434	dnl only work with GNU make).
	435	AC_DEFUN([OVS_CHECK_GNU_MAKE],
	436	[AC_CACHE_CHECK(
	437	[whether ${MAKE-make} is GNU make],
	438	[ovs_cv_gnu_make],
	439	[rm -f conftest.out
	440	AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
	441	${MAKE-make} --version >conftest.out 2>&1
	442	cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
	443	result=`cat conftest.out`
	444	rm -f conftest.mk conftest.out
	445
	446	case $result in # (
	447	GNU*) ovs_cv_gnu_make=yes ;; # (
	448	*) ovs_cv_gnu_make=no ;;
	449	esac])
	450	AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
	451
643c0c34 BP	452	dnl OVS_CHECK_SPARSE_TARGET
	453	dnl
	454	dnl The "cgcc" script from "sparse" isn't very good at detecting the
	455	dnl target for which the code is being built. This helps it out.
	456	AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
	457	[AC_CACHE_CHECK(
	458	[target hint for cgcc],
	459	[ac_cv_sparse_target],
	460	[AS_CASE([`$CC -dumpmachine 2>/dev/null`],
	461	[i?86-* \| athlon-*], [ac_cv_sparse_target=x86],
	462	[x86_64-*], [ac_cv_sparse_target=x86_64],
	463	[ac_cv_sparse_target=other])])
	464	AS_CASE([$ac_cv_sparse_target],
	465	[x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
	466	[x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
	467	[SPARSEFLAGS= CGCCFLAGS=])
	468	AC_SUBST([SPARSEFLAGS])
	469	AC_SUBST([CGCCFLAGS])])
	470
29d935d6 BP	471	dnl OVS_ENABLE_SPARSE
29d935d6 BP	472	AC_DEFUN([OVS_ENABLE_SPARSE],
643c0c34	473	[AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
372d58a4 BP	474	AC_REQUIRE([OVS_CHECK_MAKE_IF])
	475	: ${SPARSE=sparse}
	476	AC_SUBST([SPARSE])
	477	AC_CONFIG_COMMANDS_PRE(
	478	[if test $ovs_cv_gnu_make_if = yes; then
	479	CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'
	480	fi])])