[mirror_ubuntu-artful-kernel.git] / arch / arc / kernel / ctx_sw_asm.S

/*
 * Copyright (C) 2004, 2007-2010, 2011-2012 Synopsys, Inc. (www.synopsys.com)
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 *
 * Vineetg: Aug 2009
 *  -Moved core context switch macro out of entry.S into this file.
 *  -This is the more "natural" hand written assembler
 */

#include <linux/linkage.h>
#include <asm/entry.h>       /* For the SAVE_* macros */
#include <asm/asm-offsets.h>

#define KSP_WORD_OFF 	((TASK_THREAD + THREAD_KSP) / 4)

;################### Low Level Context Switch ##########################

	.section .sched.text,"ax",@progbits
	.align 4
	.global __switch_to
	.type   __switch_to, @function
__switch_to:

	/* Save regs on kernel mode stack of task */
	st.a    blink, [sp, -4]
	st.a    fp, [sp, -4]
	SAVE_CALLEE_SAVED_KERNEL

	/* Save the now KSP in task->thread.ksp */
#if KSP_WORD_OFF  <= 255
	st.as  sp, [r0, KSP_WORD_OFF]
#else
	/* Workaround for NR_CPUS=4k as ST.as can only take s9 offset */
	add2	r24, r0, KSP_WORD_OFF
	st	sp, [r24]
#endif
	/*
	* Return last task in r0 (return reg)
	* On ARC, Return reg = First Arg reg = r0.
	* Since we already have last task in r0,
	* don't need to do anything special to return it
	*/

	/*
	 * switch to new task, contained in r1
	 * Temp reg r3 is required to get the ptr to store val
	 */
	SET_CURR_TASK_ON_CPU  r1, r3

	/* reload SP with kernel mode stack pointer in task->thread.ksp */
	ld.as  sp, [r1, (TASK_THREAD + THREAD_KSP)/4]

	/* restore the registers */
	RESTORE_CALLEE_SAVED_KERNEL
	ld.ab   fp, [sp, 4]
	ld.ab   blink, [sp, 4]
	j       [blink]

END(__switch_to)
Commit	Line	Data
bf90e1ea VG	1	/*
	2	* Copyright (C) 2004, 2007-2010, 2011-2012 Synopsys, Inc. (www.synopsys.com)
	3	*
	4	* This program is free software; you can redistribute it and/or modify
	5	* it under the terms of the GNU General Public License version 2 as
	6	* published by the Free Software Foundation.
	7	*
	8	* Vineetg: Aug 2009
	9	* -Moved core context switch macro out of entry.S into this file.
	10	* -This is the more "natural" hand written assembler
	11	*/
	12
ba25915f	13	#include <linux/linkage.h>
bf90e1ea VG	14	#include <asm/entry.h> /* For the SAVE_* macros */
bf90e1ea VG	15	#include <asm/asm-offsets.h>
bf90e1ea	16
57e26e57 VG	17	#define KSP_WORD_OFF ((TASK_THREAD + THREAD_KSP) / 4)
57e26e57 VG	18
bf90e1ea VG	19	;################### Low Level Context Switch ##########################
	20
	21	.section .sched.text,"ax",@progbits
	22	.align 4
	23	.global __switch_to
	24	.type __switch_to, @function
	25	__switch_to:
	26
	27	/* Save regs on kernel mode stack of task */
	28	st.a blink, [sp, -4]
	29	st.a fp, [sp, -4]
	30	SAVE_CALLEE_SAVED_KERNEL
	31
	32	/* Save the now KSP in task->thread.ksp */
57e26e57 VG	33	#if KSP_WORD_OFF <= 255
	34	st.as sp, [r0, KSP_WORD_OFF]
	35	#else
	36	/* Workaround for NR_CPUS=4k as ST.as can only take s9 offset */
	37	add2 r24, r0, KSP_WORD_OFF
	38	st sp, [r24]
	39	#endif
bf90e1ea VG	40	/*
	41	* Return last task in r0 (return reg)
	42	* On ARC, Return reg = First Arg reg = r0.
	43	* Since we already have last task in r0,
	44	* don't need to do anything special to return it
	45	*/
	46
bf90e1ea VG	47	/*
	48	* switch to new task, contained in r1
	49	* Temp reg r3 is required to get the ptr to store val
	50	*/
	51	SET_CURR_TASK_ON_CPU r1, r3
	52
	53	/* reload SP with kernel mode stack pointer in task->thread.ksp */
	54	ld.as sp, [r1, (TASK_THREAD + THREAD_KSP)/4]
	55
	56	/* restore the registers */
	57	RESTORE_CALLEE_SAVED_KERNEL
	58	ld.ab fp, [sp, 4]
	59	ld.ab blink, [sp, 4]
	60	j [blink]
	61
ec7ac6af	62	END(__switch_to)