[mirror_ubuntu-hirsute-kernel.git] / arch / arm / lib / backtrace.S

/*
 *  linux/arch/arm/lib/backtrace.S
 *
 *  Copyright (C) 1995, 1996 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 *
 * 27/03/03 Ian Molton Clean up CONFIG_CPU
 *
 */
#include <linux/linkage.h>
#include <asm/assembler.h>
		.text

@ fp is 0 or stack frame

#define frame	r4
#define sv_fp	r5
#define sv_pc	r6
#define mask	r7
#define offset	r8

ENTRY(__backtrace)
		mov	r1, #0x10
		mov	r0, fp

ENTRY(c_backtrace)

#if !defined(CONFIG_FRAME_POINTER) || !defined(CONFIG_PRINTK)
		mov	pc, lr
ENDPROC(__backtrace)
ENDPROC(c_backtrace)
#else
		stmfd	sp!, {r4 - r8, lr}	@ Save an extra register so we have a location...
		movs	frame, r0		@ if frame pointer is zero
		beq	no_frame		@ we have no stack frames

		tst	r1, #0x10		@ 26 or 32-bit mode?
 ARM(		moveq	mask, #0xfc000003	)
 THUMB(		moveq	mask, #0xfc000000	)
 THUMB(		orreq	mask, #0x03		)
		movne	mask, #0		@ mask for 32-bit

1:		stmfd	sp!, {pc}		@ calculate offset of PC stored
		ldr	r0, [sp], #4		@ by stmfd for this CPU
		adr	r1, 1b
		sub	offset, r0, r1

/*
 * Stack frame layout:
 *             optionally saved caller registers (r4 - r10)
 *             saved fp
 *             saved sp
 *             saved lr
 *    frame => saved pc
 *             optionally saved arguments (r0 - r3)
 * saved sp => <next word>
 *
 * Functions start with the following code sequence:
 *                  mov   ip, sp
 *                  stmfd sp!, {r0 - r3} (optional)
 * corrected pc =>  stmfd sp!, {..., fp, ip, lr, pc}
 */
for_each_frame:	tst	frame, mask		@ Check for address exceptions
		bne	no_frame

1001:		ldr	sv_pc, [frame, #0]	@ get saved pc
1002:		ldr	sv_fp, [frame, #-12]	@ get saved fp

		sub	sv_pc, sv_pc, offset	@ Correct PC for prefetching
		bic	sv_pc, sv_pc, mask	@ mask PC/LR for the mode

1003:		ldr	r2, [sv_pc, #-4]	@ if stmfd sp!, {args} exists,
		ldr	r3, .Ldsi+4		@ adjust saved 'pc' back one
		teq	r3, r2, lsr #10		@ instruction
		subne	r0, sv_pc, #4		@ allow for mov
		subeq	r0, sv_pc, #8		@ allow for mov + stmia

		ldr	r1, [frame, #-4]	@ get saved lr
		mov	r2, frame
		bic	r1, r1, mask		@ mask PC/LR for the mode
		bl	dump_backtrace_entry

		ldr	r1, [sv_pc, #-4]	@ if stmfd sp!, {args} exists,
		ldr	r3, .Ldsi+4
		teq	r3, r1, lsr #10
		ldreq	r0, [frame, #-8]	@ get sp
		subeq	r0, r0, #4		@ point at the last arg
		bleq	.Ldumpstm		@ dump saved registers

1004:		ldr	r1, [sv_pc, #0]		@ if stmfd sp!, {..., fp, ip, lr, pc}
		ldr	r3, .Ldsi		@ instruction exists,
		teq	r3, r1, lsr #10
		subeq	r0, frame, #16
		bleq	.Ldumpstm		@ dump saved registers

		teq	sv_fp, #0		@ zero saved fp means
		beq	no_frame		@ no further frames

		cmp	sv_fp, frame		@ next frame must be
		mov	frame, sv_fp		@ above the current frame
		bhi	for_each_frame

1006:		adr	r0, .Lbad
		mov	r1, frame
		bl	printk
no_frame:	ldmfd	sp!, {r4 - r8, pc}
ENDPROC(__backtrace)
ENDPROC(c_backtrace)
		
		.section __ex_table,"a"
		.align	3
		.long	1001b, 1006b
		.long	1002b, 1006b
		.long	1003b, 1006b
		.long	1004b, 1006b
		.previous

#define instr r4
#define reg   r5
#define stack r6

.Ldumpstm:	stmfd	sp!, {instr, reg, stack, r7, lr}
		mov	stack, r0
		mov	instr, r1
		mov	reg, #10
		mov	r7, #0
1:		mov	r3, #1
 ARM(		tst	instr, r3, lsl reg	)
 THUMB(		lsl	r3, reg			)
 THUMB(		tst	instr, r3		)
		beq	2f
		add	r7, r7, #1
		teq	r7, #6
		moveq	r7, #1
		moveq	r1, #'\n'
		movne	r1, #' '
		ldr	r3, [stack], #-4
		mov	r2, reg
		adr	r0, .Lfp
		bl	printk
2:		subs	reg, reg, #1
		bpl	1b
		teq	r7, #0
		adrne	r0, .Lcr
		blne	printk
		ldmfd	sp!, {instr, reg, stack, r7, pc}

.Lfp:		.asciz	"%cr%d:%08x"
.Lcr:		.asciz	"\n"
.Lbad:		.asciz	"Backtrace aborted due to bad frame pointer <%p>\n"
		.align
.Ldsi:		.word	0xe92dd800 >> 10	@ stmfd sp!, {... fp, ip, lr, pc}
		.word	0xe92d0000 >> 10	@ stmfd sp!, {}

#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/lib/backtrace.S
	3	*
	4	* Copyright (C) 1995, 1996 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*
	10	* 27/03/03 Ian Molton Clean up CONFIG_CPU
	11	*
	12	*/
1da177e4 LT	13	#include <linux/linkage.h>
	14	#include <asm/assembler.h>
	15	.text
	16
	17	@ fp is 0 or stack frame
	18
	19	#define frame r4
7ab3f8d5 RK	20	#define sv_fp r5
7ab3f8d5 RK	21	#define sv_pc r6
1da177e4 LT	22	#define mask r7
	23	#define offset r8
	24
	25	ENTRY(__backtrace)
	26	mov r1, #0x10
	27	mov r0, fp
	28
	29	ENTRY(c_backtrace)
	30
3ee357f0	31	#if !defined(CONFIG_FRAME_POINTER) \|\| !defined(CONFIG_PRINTK)
1da177e4	32	mov pc, lr
93ed3970 CM	33	ENDPROC(__backtrace)
93ed3970 CM	34	ENDPROC(c_backtrace)
1da177e4	35	#else
1da177e4	36	stmfd sp!, {r4 - r8, lr} @ Save an extra register so we have a location...
7ab3f8d5 RK	37	movs frame, r0 @ if frame pointer is zero
	38	beq no_frame @ we have no stack frames
	39
	40	tst r1, #0x10 @ 26 or 32-bit mode?
8b592783 CM	41	ARM( moveq mask, #0xfc000003 )
	42	THUMB( moveq mask, #0xfc000000 )
	43	THUMB( orreq mask, #0x03 )
7ab3f8d5 RK	44	movne mask, #0 @ mask for 32-bit
	45
	46	1: stmfd sp!, {pc} @ calculate offset of PC stored
	47	ldr r0, [sp], #4 @ by stmfd for this CPU
	48	adr r1, 1b
1da177e4 LT	49	sub offset, r0, r1
1da177e4 LT	50
7ab3f8d5 RK	51	/*
	52	* Stack frame layout:
	53	* optionally saved caller registers (r4 - r10)
	54	* saved fp
	55	* saved sp
	56	* saved lr
	57	* frame => saved pc
	58	* optionally saved arguments (r0 - r3)
	59	* saved sp => <next word>
	60	*
	61	* Functions start with the following code sequence:
	62	* mov ip, sp
	63	* stmfd sp!, {r0 - r3} (optional)
	64	* corrected pc => stmfd sp!, {..., fp, ip, lr, pc}
	65	*/
	66	for_each_frame: tst frame, mask @ Check for address exceptions
	67	bne no_frame
	68
	69	1001: ldr sv_pc, [frame, #0] @ get saved pc
	70	1002: ldr sv_fp, [frame, #-12] @ get saved fp
1da177e4	71
7ab3f8d5 RK	72	sub sv_pc, sv_pc, offset @ Correct PC for prefetching
	73	bic sv_pc, sv_pc, mask @ mask PC/LR for the mode
	74
	75	1003: ldr r2, [sv_pc, #-4] @ if stmfd sp!, {args} exists,
	76	ldr r3, .Ldsi+4 @ adjust saved 'pc' back one
	77	teq r3, r2, lsr #10 @ instruction
	78	subne r0, sv_pc, #4 @ allow for mov
	79	subeq r0, sv_pc, #8 @ allow for mov + stmia
	80
	81	ldr r1, [frame, #-4] @ get saved lr
	82	mov r2, frame
	83	bic r1, r1, mask @ mask PC/LR for the mode
1da177e4 LT	84	bl dump_backtrace_entry
1da177e4 LT	85
7ab3f8d5 RK	86	ldr r1, [sv_pc, #-4] @ if stmfd sp!, {args} exists,
	87	ldr r3, .Ldsi+4
	88	teq r3, r1, lsr #10
	89	ldreq r0, [frame, #-8] @ get sp
	90	subeq r0, r0, #4 @ point at the last arg
	91	bleq .Ldumpstm @ dump saved registers
1da177e4	92
7ab3f8d5 RK	93	1004: ldr r1, [sv_pc, #0] @ if stmfd sp!, {..., fp, ip, lr, pc}
	94	ldr r3, .Ldsi @ instruction exists,
	95	teq r3, r1, lsr #10
	96	subeq r0, frame, #16
	97	bleq .Ldumpstm @ dump saved registers
	98
	99	teq sv_fp, #0 @ zero saved fp means
	100	beq no_frame @ no further frames
	101
	102	cmp sv_fp, frame @ next frame must be
	103	mov frame, sv_fp @ above the current frame
	104	bhi for_each_frame
	105
	106	1006: adr r0, .Lbad
1da177e4 LT	107	mov r1, frame
1da177e4 LT	108	bl printk
7ab3f8d5	109	no_frame: ldmfd sp!, {r4 - r8, pc}
93ed3970 CM	110	ENDPROC(__backtrace)
93ed3970 CM	111	ENDPROC(c_backtrace)
1da177e4 LT	112
	113	.section __ex_table,"a"
	114	.align 3
7ab3f8d5 RK	115	.long 1001b, 1006b
	116	.long 1002b, 1006b
	117	.long 1003b, 1006b
	118	.long 1004b, 1006b
1da177e4 LT	119	.previous
	120
	121	#define instr r4
	122	#define reg r5
	123	#define stack r6
	124
7ab3f8d5	125	.Ldumpstm: stmfd sp!, {instr, reg, stack, r7, lr}
1da177e4 LT	126	mov stack, r0
1da177e4 LT	127	mov instr, r1
7ab3f8d5	128	mov reg, #10
1da177e4 LT	129	mov r7, #0
1da177e4 LT	130	1: mov r3, #1
8b592783 CM	131	ARM( tst instr, r3, lsl reg )
	132	THUMB( lsl r3, reg )
	133	THUMB( tst instr, r3 )
1da177e4 LT	134	beq 2f
1da177e4 LT	135	add r7, r7, #1
7ab3f8d5 RK	136	teq r7, #6
	137	moveq r7, #1
	138	moveq r1, #'\n'
	139	movne r1, #' '
	140	ldr r3, [stack], #-4
	141	mov r2, reg
1da177e4 LT	142	adr r0, .Lfp
	143	bl printk
	144	2: subs reg, reg, #1
	145	bpl 1b
	146	teq r7, #0
	147	adrne r0, .Lcr
	148	blne printk
7ab3f8d5	149	ldmfd sp!, {instr, reg, stack, r7, pc}
1da177e4	150
7ab3f8d5	151	.Lfp: .asciz "%cr%d:%08x"
1da177e4 LT	152	.Lcr: .asciz "\n"
	153	.Lbad: .asciz "Backtrace aborted due to bad frame pointer <%p>\n"
	154	.align
7ab3f8d5 RK	155	.Ldsi: .word 0xe92dd800 >> 10 @ stmfd sp!, {... fp, ip, lr, pc}
7ab3f8d5 RK	156	.word 0xe92d0000 >> 10 @ stmfd sp!, {}
1da177e4 LT	157
1da177e4 LT	158	#endif