[mirror_ubuntu-hirsute-kernel.git] / arch / arm / lib / io-readsl.S

/* SPDX-License-Identifier: GPL-2.0-only */
/*
 *  linux/arch/arm/lib/io-readsl.S
 *
 *  Copyright (C) 1995-2000 Russell King
 */
#include <linux/linkage.h>
#include <asm/assembler.h>

ENTRY(__raw_readsl)
		teq	r2, #0		@ do we have to check for the zero len?
		reteq	lr
		ands	ip, r1, #3
		bne	3f

		subs	r2, r2, #4
		bmi	2f
		stmfd	sp!, {r4, lr}
1:		ldr	r3, [r0, #0]
		ldr	r4, [r0, #0]
		ldr	ip, [r0, #0]
		ldr	lr, [r0, #0]
		subs	r2, r2, #4
		stmia	r1!, {r3, r4, ip, lr}
		bpl	1b
		ldmfd	sp!, {r4, lr}
2:		movs	r2, r2, lsl #31
		ldrcs	r3, [r0, #0]
		ldrcs	ip, [r0, #0]
		stmiacs	r1!, {r3, ip}
		ldrne	r3, [r0, #0]
		strne	r3, [r1, #0]
		ret	lr

3:		ldr	r3, [r0]
		cmp	ip, #2
		mov	ip, r3, get_byte_0
		strb	ip, [r1], #1
		bgt	6f
		mov	ip, r3, get_byte_1
		strb	ip, [r1], #1
		beq	5f
		mov	ip, r3, get_byte_2
		strb	ip, [r1], #1

4:		subs	r2, r2, #1
		mov	ip, r3, lspull #24
		ldrne	r3, [r0]
		orrne	ip, ip, r3, lspush #8
		strne	ip, [r1], #4
		bne	4b
		b	8f

5:		subs	r2, r2, #1
		mov	ip, r3, lspull #16
		ldrne	r3, [r0]
		orrne	ip, ip, r3, lspush #16
		strne	ip, [r1], #4
		bne	5b
		b	7f

6:		subs	r2, r2, #1
		mov	ip, r3, lspull #8
		ldrne	r3, [r0]
		orrne	ip, ip, r3, lspush #24
		strne	ip, [r1], #4
		bne	6b

		mov	r3, ip, get_byte_2
		strb	r3, [r1, #2]
7:		mov	r3, ip, get_byte_1
		strb	r3, [r1, #1]
8:		mov	r3, ip, get_byte_0
		strb	r3, [r1, #0]
		ret	lr
ENDPROC(__raw_readsl)
Commit	Line	Data
d2912cb1	1	/* SPDX-License-Identifier: GPL-2.0-only */
1da177e4 LT	2	/*
	3	* linux/arch/arm/lib/io-readsl.S
	4	*
	5	* Copyright (C) 1995-2000 Russell King
1da177e4 LT	6	*/
	7	#include <linux/linkage.h>
	8	#include <asm/assembler.h>
	9
	10	ENTRY(__raw_readsl)
	11	teq r2, #0 @ do we have to check for the zero len?
6ebbf2ce	12	reteq lr
1da177e4 LT	13	ands ip, r1, #3
	14	bne 3f
	15
	16	subs r2, r2, #4
	17	bmi 2f
	18	stmfd sp!, {r4, lr}
	19	1: ldr r3, [r0, #0]
	20	ldr r4, [r0, #0]
	21	ldr ip, [r0, #0]
	22	ldr lr, [r0, #0]
	23	subs r2, r2, #4
	24	stmia r1!, {r3, r4, ip, lr}
	25	bpl 1b
	26	ldmfd sp!, {r4, lr}
	27	2: movs r2, r2, lsl #31
	28	ldrcs r3, [r0, #0]
	29	ldrcs ip, [r0, #0]
e44fc388	30	stmiacs r1!, {r3, ip}
1da177e4 LT	31	ldrne r3, [r0, #0]
1da177e4 LT	32	strne r3, [r1, #0]
6ebbf2ce	33	ret lr
1da177e4 LT	34
	35	3: ldr r3, [r0]
	36	cmp ip, #2
	37	mov ip, r3, get_byte_0
	38	strb ip, [r1], #1
	39	bgt 6f
	40	mov ip, r3, get_byte_1
	41	strb ip, [r1], #1
	42	beq 5f
	43	mov ip, r3, get_byte_2
	44	strb ip, [r1], #1
	45
	46	4: subs r2, r2, #1
d98b90ea	47	mov ip, r3, lspull #24
1da177e4	48	ldrne r3, [r0]
d98b90ea	49	orrne ip, ip, r3, lspush #8
1da177e4 LT	50	strne ip, [r1], #4
	51	bne 4b
	52	b 8f
	53
	54	5: subs r2, r2, #1
d98b90ea	55	mov ip, r3, lspull #16
1da177e4	56	ldrne r3, [r0]
d98b90ea	57	orrne ip, ip, r3, lspush #16
1da177e4 LT	58	strne ip, [r1], #4
	59	bne 5b
	60	b 7f
	61
	62	6: subs r2, r2, #1
d98b90ea	63	mov ip, r3, lspull #8
1da177e4	64	ldrne r3, [r0]
d98b90ea	65	orrne ip, ip, r3, lspush #24
1da177e4 LT	66	strne ip, [r1], #4
	67	bne 6b
	68
	69	mov r3, ip, get_byte_2
	70	strb r3, [r1, #2]
	71	7: mov r3, ip, get_byte_1
	72	strb r3, [r1, #1]
	73	8: mov r3, ip, get_byte_0
	74	strb r3, [r1, #0]
6ebbf2ce	75	ret lr
93ed3970	76	ENDPROC(__raw_readsl)