[mirror_ubuntu-zesty-kernel.git] / arch / arm26 / kernel / vmlinux-arm26.lds.in

/* ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
 * borrowed from Russels ARM port by Ian Molton and subsequently modified.
 */

#include <asm-generic/vmlinux.lds.h>

OUTPUT_ARCH(arm)
ENTRY(stext)
jiffies = jiffies_64;
SECTIONS
{
	. = TEXTADDR;
	.init : {			/* Init code and data		*/
		_stext = .;
		__init_begin = .;
			_sinittext = .;
			*(.init.text)
			_einittext = .;
		__proc_info_begin = .;
			*(.proc.info)
		__proc_info_end = .;
		__arch_info_begin = .;
			*(.arch.info)
		__arch_info_end = .;
		__tagtable_begin = .;
			*(.taglist)
		__tagtable_end = .;
			*(.init.data)
		. = ALIGN(16);
		__setup_start = .;
			*(.init.setup)
		__setup_end = .;
		__early_begin = .;
			*(__early_param)
		__early_end = .;
		__initcall_start = .;
			*(.initcall1.init)
			*(.initcall2.init)
			*(.initcall3.init)
			*(.initcall4.init)
			*(.initcall5.init)
			*(.initcall6.init)
			*(.initcall7.init)
		__initcall_end = .;
		__con_initcall_start = .;
			*(.con_initcall.init)
		__con_initcall_end = .;
#ifdef CONFIG_BLK_DEV_INITRD
		. = ALIGN(32);
		__initramfs_start = .;
			usr/built-in.o(.init.ramfs)
		__initramfs_end = .;
#endif
		. = ALIGN(32768);
		__init_end = .;
	}

	/DISCARD/ : {			/* Exit code and data		*/
		*(.exit.text)
		*(.exit.data)
		*(.exitcall.exit)
	}

	.text : {			/* Real text segment		*/
		_text = .;		/* Text and read-only data	*/
			*(.text)
			SCHED_TEXT
			LOCK_TEXT
			*(.fixup)
			*(.gnu.warning)
			*(.rodata)
			*(.rodata.*)
			*(.glue_7)
			*(.glue_7t)
		*(.got)			/* Global offset table		*/

		_etext = .;		/* End of text section		*/
	}

	. = ALIGN(16);
	__ex_table : {			/* Exception table		*/
		__start___ex_table = .;
			*(__ex_table)
		__stop___ex_table = .;
	}

	RODATA

	. = ALIGN(8192);

	.data : {
		/*
		 * first, the init task union, aligned
		 * to an 8192 byte boundary. (see arm26/kernel/init_task.c)
		 */
		*(.init.task)

		/*
		 * The cacheline aligned data
		 */
		. = ALIGN(32);
		*(.data.cacheline_aligned)

		/*
		 * and the usual data section
		 */
		*(.data)
		CONSTRUCTORS

		_edata = .;
	}

	.bss : {
		__bss_start = .;	/* BSS				*/
		*(.bss)
		*(COMMON)
		_end = . ;
	}
					/* Stabs debugging sections.	*/
	.stab 0 : { *(.stab) }
	.stabstr 0 : { *(.stabstr) }
	.stab.excl 0 : { *(.stab.excl) }
	.stab.exclstr 0 : { *(.stab.exclstr) }
	.stab.index 0 : { *(.stab.index) }
	.stab.indexstr 0 : { *(.stab.indexstr) }
	.comment 0 : { *(.comment) }
}
Commit	Line	Data
1da177e4 LT	1	/* ld script to make ARM Linux kernel
	2	* taken from the i386 version by Russell King
	3	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
	4	* borrowed from Russels ARM port by Ian Molton and subsequently modified.
	5	*/
	6
	7	#include <asm-generic/vmlinux.lds.h>
	8
	9	OUTPUT_ARCH(arm)
	10	ENTRY(stext)
	11	jiffies = jiffies_64;
	12	SECTIONS
	13	{
	14	. = TEXTADDR;
	15	.init : { /* Init code and data */
	16	_stext = .;
	17	__init_begin = .;
	18	_sinittext = .;
	19	*(.init.text)
	20	_einittext = .;
	21	__proc_info_begin = .;
	22	*(.proc.info)
	23	__proc_info_end = .;
	24	__arch_info_begin = .;
	25	*(.arch.info)
	26	__arch_info_end = .;
	27	__tagtable_begin = .;
	28	*(.taglist)
	29	__tagtable_end = .;
	30	*(.init.data)
	31	. = ALIGN(16);
	32	__setup_start = .;
	33	*(.init.setup)
	34	__setup_end = .;
	35	__early_begin = .;
	36	*(__early_param)
	37	__early_end = .;
	38	__initcall_start = .;
	39	*(.initcall1.init)
	40	*(.initcall2.init)
	41	*(.initcall3.init)
	42	*(.initcall4.init)
	43	*(.initcall5.init)
	44	*(.initcall6.init)
	45	*(.initcall7.init)
	46	__initcall_end = .;
	47	__con_initcall_start = .;
	48	*(.con_initcall.init)
	49	__con_initcall_end = .;
67d38229	50	#ifdef CONFIG_BLK_DEV_INITRD
1da177e4 LT	51	. = ALIGN(32);
	52	__initramfs_start = .;
	53	usr/built-in.o(.init.ramfs)
	54	__initramfs_end = .;
67d38229	55	#endif
1da177e4 LT	56	. = ALIGN(32768);
	57	__init_end = .;
	58	}
	59
	60	/DISCARD/ : { /* Exit code and data */
	61	*(.exit.text)
	62	*(.exit.data)
	63	*(.exitcall.exit)
	64	}
	65
	66	.text : { /* Real text segment */
	67	_text = .; /* Text and read-only data */
	68	*(.text)
	69	SCHED_TEXT
	70	LOCK_TEXT
	71	*(.fixup)
	72	*(.gnu.warning)
	73	*(.rodata)
	74	(.rodata.)
	75	*(.glue_7)
	76	*(.glue_7t)
	77	(.got) / Global offset table */
	78
	79	_etext = .; /* End of text section */
	80	}
	81
	82	. = ALIGN(16);
	83	__ex_table : { /* Exception table */
	84	__start___ex_table = .;
	85	*(__ex_table)
	86	__stop___ex_table = .;
	87	}
	88
	89	RODATA
	90
	91	. = ALIGN(8192);
	92
	93	.data : {
	94	/*
	95	* first, the init task union, aligned
	96	* to an 8192 byte boundary. (see arm26/kernel/init_task.c)
	97	*/
	98	*(.init.task)
	99
	100	/*
	101	* The cacheline aligned data
	102	*/
	103	. = ALIGN(32);
	104	*(.data.cacheline_aligned)
	105
	106	/*
	107	* and the usual data section
	108	*/
	109	*(.data)
	110	CONSTRUCTORS
	111
	112	_edata = .;
	113	}
	114
	115	.bss : {
	116	__bss_start = .; /* BSS */
	117	*(.bss)
	118	*(COMMON)
	119	_end = . ;
120	}
121	/* Stabs debugging sections. */
122	.stab 0 : { *(.stab) }
123	.stabstr 0 : { *(.stabstr) }
124	.stab.excl 0 : { *(.stab.excl) }
125	.stab.exclstr 0 : { *(.stab.exclstr) }
126	.stab.index 0 : { *(.stab.index) }
127	.stab.indexstr 0 : { *(.stab.indexstr) }
128	.comment 0 : { *(.comment) }
129	}